src/code/fd-stream.lisp

   1 ;;;; streams for UNIX file descriptors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; buffer manipulation routines
  15
  16 ;;; FIXME: Is it really good to maintain this pool separate from the
  17 ;;; GC and the C malloc logic?
  18 (defvar *available-buffers* ()
  19   #!+sb-doc
  20   "List of available buffers. Each buffer is an sap pointing to
  21   bytes-per-buffer of memory.")
  22
  23 (defconstant bytes-per-buffer (* 4 1024)
  24   #!+sb-doc
  25   "Number of bytes per buffer.")
  26
  27 ;;; Return the next available buffer, creating one if necessary.
  28 #!-sb-fluid (declaim (inline next-available-buffer))
  29 (defun next-available-buffer ()
  30   (if *available-buffers*
  31       (pop *available-buffers*)
  32       (allocate-system-memory bytes-per-buffer)))
  33 \f
  34 ;;;; the FILE-STREAM structure
  35
  36 (defstruct (file-stream
  37             (:constructor %make-fd-stream)
  38             ;; KLUDGE: in an ideal world, maybe we'd rewrite
  39             ;; everything to use FILE-STREAM rather than simply
  40             ;; providing this hack for compatibility with the old
  41             ;; code.  However, CVS doesn't deal terribly well with
  42             ;; file renaming, so for now we use this
  43             ;; backward-compatibility feature.
  44             (:conc-name fd-stream-)
  45             (:predicate fd-stream-p)
  46             (:include ansi-stream
  47                       (misc #'fd-stream-misc-routine))
  48             (:copier nil))
  49
  50   ;; the name of this stream
  51   (name nil)
  52   ;; the file this stream is for
  53   (file nil)
  54   ;; the backup file namestring for the old file, for :IF-EXISTS
  55   ;; :RENAME or :RENAME-AND-DELETE.
  56   (original nil :type (or simple-string null))
  57   (delete-original nil)       ; for :if-exists :rename-and-delete
  58   ;;; the number of bytes per element
  59   (element-size 1 :type index)
  60   ;; the type of element being transfered
  61   (element-type 'base-char)
  62   ;; the Unix file descriptor
  63   (fd -1 :type fixnum)
  64   ;; controls when the output buffer is flushed
  65   (buffering :full :type (member :full :line :none))
  66   ;; character position (if known)
  67   (char-pos nil :type (or index null))
  68   ;; T if input is waiting on FD. :EOF if we hit EOF.
  69   (listen nil :type (member nil t :eof))
  70
  71   ;; the input buffer
  72   (unread nil)
  73   (ibuf-sap nil :type (or system-area-pointer null))
  74   (ibuf-length nil :type (or index null))
  75   (ibuf-head 0 :type index)
  76   (ibuf-tail 0 :type index)
  77
  78   ;; the output buffer
  79   (obuf-sap nil :type (or system-area-pointer null))
  80   (obuf-length nil :type (or index null))
  81   (obuf-tail 0 :type index)
  82
  83   ;; output flushed, but not written due to non-blocking io?
  84   (output-later nil)
  85   (handler nil)
  86   ;; timeout specified for this stream, or NIL if none
  87   (timeout nil :type (or index null))
  88   ;; pathname of the file this stream is opened to (returned by PATHNAME)
  89   (pathname nil :type (or pathname null)))
  90 (def!method print-object ((fd-stream file-stream) stream)
  91   (declare (type stream stream))
  92   (print-unreadable-object (fd-stream stream :type t :identity t)
  93     (format stream "for ~S" (fd-stream-name fd-stream))))
  94 \f
  95 ;;;; output routines and related noise
  96
  97 (defvar *output-routines* ()
  98   #!+sb-doc
  99   "List of all available output routines. Each element is a list of the
 100   element-type output, the kind of buffering, the function name, and the number
 101   of bytes per element.")
 102
 103 ;;; common idioms for reporting low-level stream and file problems
 104 (defun simple-stream-perror (note-format stream errno)
 105   (error 'simple-stream-error
 106          :stream stream
 107          :format-control "~@<~?: ~2I~_~A~:>"
 108          :format-arguments (list note-format (list stream) (strerror errno))))
 109 (defun simple-file-perror (note-format pathname errno)
 110   (error 'simple-file-error
 111          :pathname pathname
 112          :format-control "~@<~?: ~2I~_~A~:>"
 113          :format-arguments
 114          (list note-format (list pathname) (strerror errno))))
 115
 116 ;;; This is called by the server when we can write to the given file
 117 ;;; descriptor. Attempt to write the data again. If it worked, remove
 118 ;;; the data from the OUTPUT-LATER list. If it didn't work, something
 119 ;;; is wrong.
 120 (defun frob-output-later (stream)
 121   (let* ((stuff (pop (fd-stream-output-later stream)))
 122          (base (car stuff))
 123          (start (cadr stuff))
 124          (end (caddr stuff))
 125          (reuse-sap (cadddr stuff))
 126          (length (- end start)))
 127     (declare (type index start end length))
 128     (multiple-value-bind (count errno)
 129         (sb!unix:unix-write (fd-stream-fd stream)
 130                             base
 131                             start
 132                             length)
 133       (cond ((not count)
 134              (if (= errno sb!unix:ewouldblock)
 135                  (error "Write would have blocked, but SERVER told us to go.")
 136                  (simple-stream-perror "couldn't write to ~S" stream errno)))
 137             ((eql count length) ; Hot damn, it worked.
 138              (when reuse-sap
 139                (push base *available-buffers*)))
 140             ((not (null count)) ; sorta worked..
 141              (push (list base
 142                          (the index (+ start count))
 143                          end)
 144                    (fd-stream-output-later stream))))))
 145   (unless (fd-stream-output-later stream)
 146     (sb!sys:remove-fd-handler (fd-stream-handler stream))
 147     (setf (fd-stream-handler stream) nil)))
 148
 149 ;;; Arange to output the string when we can write on the file descriptor.
 150 (defun output-later (stream base start end reuse-sap)
 151   (cond ((null (fd-stream-output-later stream))
 152          (setf (fd-stream-output-later stream)
 153                (list (list base start end reuse-sap)))
 154          (setf (fd-stream-handler stream)
 155                (sb!sys:add-fd-handler (fd-stream-fd stream)
 156                                       :output
 157                                       (lambda (fd)
 158                                         (declare (ignore fd))
 159                                         (frob-output-later stream)))))
 160         (t
 161          (nconc (fd-stream-output-later stream)
 162                 (list (list base start end reuse-sap)))))
 163   (when reuse-sap
 164     (let ((new-buffer (next-available-buffer)))
 165       (setf (fd-stream-obuf-sap stream) new-buffer)
 166       (setf (fd-stream-obuf-length stream) bytes-per-buffer))))
 167
 168 ;;; Output the given noise. Check to see whether there are any pending
 169 ;;; writes. If so, just queue this one. Otherwise, try to write it. If
 170 ;;; this would block, queue it.
 171 (defun frob-output (stream base start end reuse-sap)
 172   (declare (type file-stream stream)
 173            (type (or system-area-pointer (simple-array * (*))) base)
 174            (type index start end))
 175   (if (not (null (fd-stream-output-later stream))) ; something buffered.
 176       (progn
 177         (output-later stream base start end reuse-sap)
 178         ;; ### check to see whether any of this noise can be output
 179         )
 180       (let ((length (- end start)))
 181         (multiple-value-bind (count errno)
 182             (sb!unix:unix-write (fd-stream-fd stream) base start length)
 183           (cond ((not count)
 184                  (if (= errno sb!unix:ewouldblock)
 185                      (output-later stream base start end reuse-sap)
 186                      (simple-stream-perror "couldn't write to ~S"
 187                                            stream
 188                                            errno)))
 189                 ((not (eql count length))
 190                  (output-later stream base (the index (+ start count))
 191                                end reuse-sap)))))))
 192
 193 ;;; Flush any data in the output buffer.
 194 (defun flush-output-buffer (stream)
 195   (let ((length (fd-stream-obuf-tail stream)))
 196     (unless (= length 0)
 197       (frob-output stream (fd-stream-obuf-sap stream) 0 length t)
 198       (setf (fd-stream-obuf-tail stream) 0))))
 199
 200 (defmacro output-wrapper ((stream size buffering) &body body)
 201   (let ((stream-var (gensym)))
 202     `(let ((,stream-var ,stream))
 203       ,(unless (eq (car buffering) :none)
 204          `(when (< (fd-stream-obuf-length ,stream-var)
 205                    (+ (fd-stream-obuf-tail ,stream-var)
 206                        ,size))
 207             (flush-output-buffer ,stream-var)))
 208       ,(unless (eq (car buffering) :none)
 209          `(when (> (fd-stream-ibuf-tail ,stream-var)
 210                    (fd-stream-ibuf-head ,stream-var))
 211             (file-position ,stream-var (file-position ,stream-var))))
 212
 213       ,@body
 214       (incf (fd-stream-obuf-tail ,stream-var) ,size)
 215       ,(ecase (car buffering)
 216          (:none
 217           `(flush-output-buffer ,stream-var))
 218          (:line
 219           `(when (eq (char-code byte) (char-code #\Newline))
 220              (flush-output-buffer ,stream-var)))
 221          (:full))
 222     (values))))
 223
 224 ;;; Define output routines that output numbers SIZE bytes long for the
 225 ;;; given bufferings. Use BODY to do the actual output.
 226 (defmacro def-output-routines ((name-fmt size &rest bufferings) &body body)
 227   (declare (optimize (speed 1)))
 228   (cons 'progn
 229         (mapcar
 230             (lambda (buffering)
 231               (let ((function
 232                      (intern (let ((*print-case* :upcase))
 233                                (format nil name-fmt (car buffering))))))
 234                 `(progn
 235                    (defun ,function (stream byte)
 236                      (output-wrapper (stream ,size ,buffering)
 237                        ,@body))
 238                    (setf *output-routines*
 239                          (nconc *output-routines*
 240                                 ',(mapcar
 241                                    (lambda (type)
 242                                      (list type
 243                                            (car buffering)
 244                                            function
 245                                            size))
 246                                    (cdr buffering)))))))
 247             bufferings)))
 248
 249 (def-output-routines ("OUTPUT-CHAR-~A-BUFFERED"
 250                       1
 251                       (:none character)
 252                       (:line character)
 253                       (:full character))
 254   (if (and (base-char-p byte) (char= byte #\Newline))
 255       (setf (fd-stream-char-pos stream) 0)
 256       (incf (fd-stream-char-pos stream)))
 257   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 258         (char-code byte)))
 259
 260 (def-output-routines ("OUTPUT-UNSIGNED-BYTE-~A-BUFFERED"
 261                       1
 262                       (:none (unsigned-byte 8))
 263                       (:full (unsigned-byte 8)))
 264   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 265         byte))
 266
 267 (def-output-routines ("OUTPUT-SIGNED-BYTE-~A-BUFFERED"
 268                       1
 269                       (:none (signed-byte 8))
 270                       (:full (signed-byte 8)))
 271   (setf (signed-sap-ref-8 (fd-stream-obuf-sap stream)
 272                           (fd-stream-obuf-tail stream))
 273         byte))
 274
 275 (def-output-routines ("OUTPUT-UNSIGNED-SHORT-~A-BUFFERED"
 276                       2
 277                       (:none (unsigned-byte 16))
 278                       (:full (unsigned-byte 16)))
 279   (setf (sap-ref-16 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 280         byte))
 281
 282 (def-output-routines ("OUTPUT-SIGNED-SHORT-~A-BUFFERED"
 283                       2
 284                       (:none (signed-byte 16))
 285                       (:full (signed-byte 16)))
 286   (setf (signed-sap-ref-16 (fd-stream-obuf-sap stream)
 287                            (fd-stream-obuf-tail stream))
 288         byte))
 289
 290 (def-output-routines ("OUTPUT-UNSIGNED-LONG-~A-BUFFERED"
 291                       4
 292                       (:none (unsigned-byte 32))
 293                       (:full (unsigned-byte 32)))
 294   (setf (sap-ref-32 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 295         byte))
 296
 297 (def-output-routines ("OUTPUT-SIGNED-LONG-~A-BUFFERED"
 298                       4
 299                       (:none (signed-byte 32))
 300                       (:full (signed-byte 32)))
 301   (setf (signed-sap-ref-32 (fd-stream-obuf-sap stream)
 302                            (fd-stream-obuf-tail stream))
 303         byte))
 304
 305 ;;; Do the actual output. If there is space to buffer the string,
 306 ;;; buffer it. If the string would normally fit in the buffer, but
 307 ;;; doesn't because of other stuff in the buffer, flush the old noise
 308 ;;; out of the buffer and put the string in it. Otherwise we have a
 309 ;;; very long string, so just send it directly (after flushing the
 310 ;;; buffer, of course).
 311 (defun output-raw-bytes (fd-stream thing &optional start end)
 312   #!+sb-doc
 313   "Output THING to FD-STREAM. THING can be any kind of vector or a SAP. If
 314   THING is a SAP, END must be supplied (as length won't work)."
 315   (let ((start (or start 0))
 316         (end (or end (length (the (simple-array * (*)) thing)))))
 317     (declare (type index start end))
 318     (when (> (fd-stream-ibuf-tail fd-stream)
 319              (fd-stream-ibuf-head fd-stream))
 320       (file-position fd-stream (file-position fd-stream)))
 321     (let* ((len (fd-stream-obuf-length fd-stream))
 322            (tail (fd-stream-obuf-tail fd-stream))
 323            (space (- len tail))
 324            (bytes (- end start))
 325            (newtail (+ tail bytes)))
 326       (cond ((minusp bytes) ; error case
 327              (error ":END before :START!"))
 328             ((zerop bytes)) ; easy case
 329             ((<= bytes space)
 330              (if (system-area-pointer-p thing)
 331                  (system-area-copy thing
 332                                    (* start sb!vm:n-byte-bits)
 333                                    (fd-stream-obuf-sap fd-stream)
 334                                    (* tail sb!vm:n-byte-bits)
 335                                    (* bytes sb!vm:n-byte-bits))
 336                  ;; FIXME: There should be some type checking somewhere to
 337                  ;; verify that THING here is a vector, not just <not a SAP>.
 338                  (copy-to-system-area thing
 339                                       (+ (* start sb!vm:n-byte-bits)
 340                                          (* sb!vm:vector-data-offset
 341                                             sb!vm:n-word-bits))
 342                                       (fd-stream-obuf-sap fd-stream)
 343                                       (* tail sb!vm:n-byte-bits)
 344                                       (* bytes sb!vm:n-byte-bits)))
 345              (setf (fd-stream-obuf-tail fd-stream) newtail))
 346             ((<= bytes len)
 347              (flush-output-buffer fd-stream)
 348              (if (system-area-pointer-p thing)
 349                  (system-area-copy thing
 350                                    (* start sb!vm:n-byte-bits)
 351                                    (fd-stream-obuf-sap fd-stream)
 352                                    0
 353                                    (* bytes sb!vm:n-byte-bits))
 354                  ;; FIXME: There should be some type checking somewhere to
 355                  ;; verify that THING here is a vector, not just <not a SAP>.
 356                  (copy-to-system-area thing
 357                                       (+ (* start sb!vm:n-byte-bits)
 358                                          (* sb!vm:vector-data-offset
 359                                             sb!vm:n-word-bits))
 360                                       (fd-stream-obuf-sap fd-stream)
 361                                       0
 362                                       (* bytes sb!vm:n-byte-bits)))
 363              (setf (fd-stream-obuf-tail fd-stream) bytes))
 364             (t
 365              (flush-output-buffer fd-stream)
 366              (frob-output fd-stream thing start end nil))))))
 367
 368 ;;; the routine to use to output a string. If the stream is
 369 ;;; unbuffered, slam the string down the file descriptor, otherwise
 370 ;;; use OUTPUT-RAW-BYTES to buffer the string. Update charpos by
 371 ;;; checking to see where the last newline was.
 372 ;;;
 373 ;;; Note: some bozos (the FASL dumper) call write-string with things
 374 ;;; other than strings. Therefore, we must make sure we have a string
 375 ;;; before calling POSITION on it.
 376 ;;; KLUDGE: It would be better to fix the bozos instead of trying to
 377 ;;; cover for them here. -- WHN 20000203
 378 (defun fd-sout (stream thing start end)
 379   (let ((start (or start 0))
 380         (end (or end (length (the vector thing)))))
 381     (declare (fixnum start end))
 382     (if (stringp thing)
 383         (let ((last-newline (and (find #\newline (the simple-string thing)
 384                                        :start start :end end)
 385                                  ;; FIXME why do we need both calls?
 386                                  ;; Is find faster forwards than
 387                                  ;; position is backwards?
 388                                  (position #\newline (the simple-string thing)
 389                                            :from-end t
 390                                            :start start
 391                                            :end end))))
 392           (ecase (fd-stream-buffering stream)
 393             (:full
 394              (output-raw-bytes stream thing start end))
 395             (:line
 396              (output-raw-bytes stream thing start end)
 397              (when last-newline
 398                (flush-output-buffer stream)))
 399             (:none
 400              (frob-output stream thing start end nil)))
 401           (if last-newline
 402               (setf (fd-stream-char-pos stream)
 403                     (- end last-newline 1))
 404               (incf (fd-stream-char-pos stream)
 405                     (- end start))))
 406         (ecase (fd-stream-buffering stream)
 407           ((:line :full)
 408            (output-raw-bytes stream thing start end))
 409           (:none
 410            (frob-output stream thing start end nil))))))
 411
 412 ;;; Find an output routine to use given the type and buffering. Return
 413 ;;; as multiple values the routine, the real type transfered, and the
 414 ;;; number of bytes per element.
 415 (defun pick-output-routine (type buffering)
 416   (dolist (entry *output-routines*)
 417     (when (and (subtypep type (car entry))
 418                (eq buffering (cadr entry)))
 419       (return-from pick-output-routine
 420         (values (symbol-function (caddr entry))
 421                 (car entry)
 422                 (cadddr entry)))))
 423   ;; KLUDGE: dealing with the buffering here leads to excessive code
 424   ;; explosion.
 425   ;;
 426   ;; KLUDGE: also see comments in PICK-INPUT-ROUTINE
 427   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 428         if (subtypep type `(unsigned-byte ,i))
 429         do (return-from pick-output-routine
 430              (values
 431               (ecase buffering
 432                 (:none
 433                  (lambda (stream byte)
 434                    (output-wrapper (stream (/ i 8) (:none))
 435                      (loop for j from 0 below (/ i 8)
 436                            do (setf (sap-ref-8
 437                                      (fd-stream-obuf-sap stream)
 438                                      (+ j (fd-stream-obuf-tail stream)))
 439                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 440                 (:full
 441                  (lambda (stream byte)
 442                    (output-wrapper (stream (/ i 8) (:full))
 443                      (loop for j from 0 below (/ i 8)
 444                            do (setf (sap-ref-8
 445                                      (fd-stream-obuf-sap stream)
 446                                      (+ j (fd-stream-obuf-tail stream)))
 447                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 448               `(unsigned-byte ,i)
 449               (/ i 8))))
 450   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 451         if (subtypep type `(signed-byte ,i))
 452         do (return-from pick-output-routine
 453              (values
 454               (ecase buffering
 455                 (:none
 456                  (lambda (stream byte)
 457                    (output-wrapper (stream (/ i 8) (:none))
 458                      (loop for j from 0 below (/ i 8)
 459                            do (setf (sap-ref-8
 460                                      (fd-stream-obuf-sap stream)
 461                                      (+ j (fd-stream-obuf-tail stream)))
 462                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 463                 (:full
 464                  (lambda (stream byte)
 465                    (output-wrapper (stream (/ i 8) (:full))
 466                      (loop for j from 0 below (/ i 8)
 467                            do (setf (sap-ref-8
 468                                      (fd-stream-obuf-sap stream)
 469                                      (+ j (fd-stream-obuf-tail stream)))
 470                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 471               `(signed-byte ,i)
 472               (/ i 8)))))
 473 \f
 474 ;;;; input routines and related noise
 475
 476 ;;; a list of all available input routines. Each element is a list of
 477 ;;; the element-type input, the function name, and the number of bytes
 478 ;;; per element.
 479 (defvar *input-routines* ())
 480
 481 ;;; Fill the input buffer, and return the first character. Throw to
 482 ;;; EOF-INPUT-CATCHER if the eof was reached. Drop into SYSTEM:SERVER
 483 ;;; if necessary.
 484 (defun frob-input (stream)
 485   (let ((fd (fd-stream-fd stream))
 486         (ibuf-sap (fd-stream-ibuf-sap stream))
 487         (buflen (fd-stream-ibuf-length stream))
 488         (head (fd-stream-ibuf-head stream))
 489         (tail (fd-stream-ibuf-tail stream)))
 490     (declare (type index head tail))
 491     (unless (zerop head)
 492       (cond ((eql head tail)
 493              (setf head 0)
 494              (setf tail 0)
 495              (setf (fd-stream-ibuf-head stream) 0)
 496              (setf (fd-stream-ibuf-tail stream) 0))
 497             (t
 498              (decf tail head)
 499              (system-area-copy ibuf-sap (* head sb!vm:n-byte-bits)
 500                                ibuf-sap 0 (* tail sb!vm:n-byte-bits))
 501              (setf head 0)
 502              (setf (fd-stream-ibuf-head stream) 0)
 503              (setf (fd-stream-ibuf-tail stream) tail))))
 504     (setf (fd-stream-listen stream) nil)
 505     (multiple-value-bind (count errno)
 506         ;; FIXME: Judging from compiler warnings, this WITH-ALIEN form expands
 507         ;; into something which uses the not-yet-defined type
 508         ;;   (SB!ALIEN-INTERNALS:ALIEN (* (SB!ALIEN:STRUCT SB!UNIX:FD-SET))).
 509         ;; This is probably inefficient and unsafe and generally bad, so
 510         ;; try to find some way to make that type known before
 511         ;; this is compiled.
 512         (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set)))
 513           (sb!unix:fd-zero read-fds)
 514           (sb!unix:fd-set fd read-fds)
 515           (sb!unix:unix-fast-select (1+ fd)
 516                                     (sb!alien:addr read-fds)
 517                                     nil
 518                                     nil
 519                                     0
 520                                     0))
 521       (case count
 522         (1)
 523         (0
 524          (unless (sb!sys:wait-until-fd-usable
 525                   fd :input (fd-stream-timeout stream))
 526            (error 'io-timeout :stream stream :direction :read)))
 527         (t
 528          (simple-stream-perror "couldn't check whether ~S is readable"
 529                                stream
 530                                errno))))
 531     (multiple-value-bind (count errno)
 532         (sb!unix:unix-read fd
 533                            (sb!sys:int-sap (+ (sb!sys:sap-int ibuf-sap) tail))
 534                            (- buflen tail))
 535       (cond ((null count)
 536              (if (eql errno sb!unix:ewouldblock)
 537                  (progn
 538                    (unless (sb!sys:wait-until-fd-usable
 539                             fd :input (fd-stream-timeout stream))
 540                      (error 'io-timeout :stream stream :direction :read))
 541                    (frob-input stream))
 542                  (simple-stream-perror "couldn't read from ~S" stream errno)))
 543             ((zerop count)
 544              (setf (fd-stream-listen stream) :eof)
 545              (/show0 "THROWing EOF-INPUT-CATCHER")
 546              (throw 'eof-input-catcher nil))
 547             (t
 548              (incf (fd-stream-ibuf-tail stream) count))))))
 549
 550 ;;; Make sure there are at least BYTES number of bytes in the input
 551 ;;; buffer. Keep calling FROB-INPUT until that condition is met.
 552 (defmacro input-at-least (stream bytes)
 553   (let ((stream-var (gensym))
 554         (bytes-var (gensym)))
 555     `(let ((,stream-var ,stream)
 556            (,bytes-var ,bytes))
 557        (loop
 558          (when (>= (- (fd-stream-ibuf-tail ,stream-var)
 559                       (fd-stream-ibuf-head ,stream-var))
 560                    ,bytes-var)
 561            (return))
 562          (frob-input ,stream-var)))))
 563
 564 ;;; a macro to wrap around all input routines to handle EOF-ERROR noise
 565 (defmacro input-wrapper ((stream bytes eof-error eof-value) &body read-forms)
 566   (let ((stream-var (gensym))
 567         (element-var (gensym)))
 568     `(let ((,stream-var ,stream))
 569        (if (fd-stream-unread ,stream-var)
 570            (prog1
 571                (fd-stream-unread ,stream-var)
 572              (setf (fd-stream-unread ,stream-var) nil)
 573              (setf (fd-stream-listen ,stream-var) nil))
 574            (let ((,element-var
 575                   (catch 'eof-input-catcher
 576                     (input-at-least ,stream-var ,bytes)
 577                     (locally ,@read-forms))))
 578              (cond (,element-var
 579                     (incf (fd-stream-ibuf-head ,stream-var) ,bytes)
 580                     ,element-var)
 581                    (t
 582                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
 583
 584 (defmacro def-input-routine (name
 585                              (type size sap head)
 586                              &rest body)
 587   `(progn
 588      (defun ,name (stream eof-error eof-value)
 589        (input-wrapper (stream ,size eof-error eof-value)
 590          (let ((,sap (fd-stream-ibuf-sap stream))
 591                (,head (fd-stream-ibuf-head stream)))
 592            ,@body)))
 593      (setf *input-routines*
 594            (nconc *input-routines*
 595                   (list (list ',type ',name ',size))))))
 596
 597 ;;; STREAM-IN routine for reading a string char
 598 (def-input-routine input-character
 599                    (character 1 sap head)
 600   (code-char (sap-ref-8 sap head)))
 601
 602 ;;; STREAM-IN routine for reading an unsigned 8 bit number
 603 (def-input-routine input-unsigned-8bit-byte
 604                    ((unsigned-byte 8) 1 sap head)
 605   (sap-ref-8 sap head))
 606
 607 ;;; STREAM-IN routine for reading a signed 8 bit number
 608 (def-input-routine input-signed-8bit-number
 609                    ((signed-byte 8) 1 sap head)
 610   (signed-sap-ref-8 sap head))
 611
 612 ;;; STREAM-IN routine for reading an unsigned 16 bit number
 613 (def-input-routine input-unsigned-16bit-byte
 614                    ((unsigned-byte 16) 2 sap head)
 615   (sap-ref-16 sap head))
 616
 617 ;;; STREAM-IN routine for reading a signed 16 bit number
 618 (def-input-routine input-signed-16bit-byte
 619                    ((signed-byte 16) 2 sap head)
 620   (signed-sap-ref-16 sap head))
 621
 622 ;;; STREAM-IN routine for reading a unsigned 32 bit number
 623 (def-input-routine input-unsigned-32bit-byte
 624                    ((unsigned-byte 32) 4 sap head)
 625   (sap-ref-32 sap head))
 626
 627 ;;; STREAM-IN routine for reading a signed 32 bit number
 628 (def-input-routine input-signed-32bit-byte
 629                    ((signed-byte 32) 4 sap head)
 630   (signed-sap-ref-32 sap head))
 631
 632 ;;; Find an input routine to use given the type. Return as multiple
 633 ;;; values the routine, the real type transfered, and the number of
 634 ;;; bytes per element.
 635 (defun pick-input-routine (type)
 636   (dolist (entry *input-routines*)
 637     (when (subtypep type (car entry))
 638       (return-from pick-input-routine
 639         (values (symbol-function (cadr entry))
 640                 (car entry)
 641                 (caddr entry)))))
 642   ;; FIXME: let's do it the hard way, then (but ignore things like
 643   ;; endianness, efficiency, and the necessary coupling between these
 644   ;; and the output routines).  -- CSR, 2004-02-09
 645   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
 646         if (subtypep type `(unsigned-byte ,i))
 647         do (return-from pick-input-routine
 648              (values
 649               (lambda (stream eof-error eof-value)
 650                 (input-wrapper (stream (/ i 8) eof-error eof-value)
 651                   (let ((sap (fd-stream-ibuf-sap stream))
 652                         (head (fd-stream-ibuf-head stream)))
 653                     (loop for j from 0 below (/ i 8)
 654                           with result = 0
 655                           do (setf result
 656                                    (+ (* 256 result)
 657                                       (sap-ref-8 sap (+ head j))))
 658                           finally (return result)))))
 659               `(unsigned-byte ,i)
 660               (/ i 8))))
 661   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
 662         if (subtypep type `(signed-byte ,i))
 663         do (return-from pick-input-routine
 664              (values
 665               (lambda (stream eof-error eof-value)
 666                 (input-wrapper (stream (/ i 8) eof-error eof-value)
 667                   (let ((sap (fd-stream-ibuf-sap stream))
 668                         (head (fd-stream-ibuf-head stream)))
 669                     (loop for j from 0 below (/ i 8)
 670                           with result = 0
 671                           do (setf result
 672                                    (+ (* 256 result)
 673                                       (sap-ref-8 sap (+ head j))))
 674                           finally (return (dpb result (byte i 0) -1))))))
 675               `(signed-byte ,i)
 676               (/ i 8)))))
 677
 678 ;;; Return a string constructed from SAP, START, and END.
 679 (defun string-from-sap (sap start end)
 680   (declare (type index start end))
 681   (let* ((length (- end start))
 682          (string (make-string length)))
 683     (copy-from-system-area sap (* start sb!vm:n-byte-bits)
 684                            string (* sb!vm:vector-data-offset
 685                                      sb!vm:n-word-bits)
 686                            (* length sb!vm:n-byte-bits))
 687     string))
 688
 689 ;;; the N-BIN method for FD-STREAMs
 690 ;;;
 691 ;;; Note that this blocks in UNIX-READ. It is generally used where
 692 ;;; there is a definite amount of reading to be done, so blocking
 693 ;;; isn't too problematical.
 694 (defun fd-stream-read-n-bytes (stream buffer start requested eof-error-p
 695                                &aux (total-copied 0))
 696   (declare (type file-stream stream))
 697   (declare (type index start requested total-copied))
 698   (let ((unread (fd-stream-unread stream)))
 699     (when unread
 700       ;; AVERs designed to fail when we have more complicated
 701       ;; character representations.
 702       (aver (typep unread 'base-char))
 703       (aver (= (fd-stream-element-size stream) 1))
 704       ;; KLUDGE: this is a slightly-unrolled-and-inlined version of
 705       ;; %BYTE-BLT
 706       (etypecase buffer
 707         (system-area-pointer
 708          (setf (sap-ref-8 buffer start) (char-code unread)))
 709         ((simple-unboxed-array (*))
 710          (setf (aref buffer start) unread)))
 711       (setf (fd-stream-unread stream) nil)
 712       (setf (fd-stream-listen stream) nil)
 713       (incf total-copied)))
 714   (do ()
 715       (nil)
 716     (let* ((remaining-request (- requested total-copied))
 717            (head (fd-stream-ibuf-head stream))
 718            (tail (fd-stream-ibuf-tail stream))
 719            (available (- tail head))
 720            (n-this-copy (min remaining-request available))
 721            (this-start (+ start total-copied))
 722            (this-end (+ this-start n-this-copy))
 723            (sap (fd-stream-ibuf-sap stream)))
 724       (declare (type index remaining-request head tail available))
 725       (declare (type index n-this-copy))
 726       ;; Copy data from stream buffer into user's buffer.
 727       (%byte-blt sap head buffer this-start this-end)
 728       (incf (fd-stream-ibuf-head stream) n-this-copy)
 729       (incf total-copied n-this-copy)
 730       ;; Maybe we need to refill the stream buffer.
 731       (cond (;; If there were enough data in the stream buffer, we're done.
 732              (= total-copied requested)
 733              (return total-copied))
 734             (;; If EOF, we're done in another way.
 735              (zerop (refill-fd-stream-buffer stream))
 736              (if eof-error-p
 737                  (error 'end-of-file :stream stream)
 738                  (return total-copied)))
 739             ;; Otherwise we refilled the stream buffer, so fall
 740             ;; through into another pass of the loop.
 741             ))))
 742
 743 ;;; Try to refill the stream buffer. Return the number of bytes read.
 744 ;;; (For EOF, the return value will be zero, otherwise positive.)
 745 (defun refill-fd-stream-buffer (stream)
 746   ;; We don't have any logic to preserve leftover bytes in the buffer,
 747   ;; so we should only be called when the buffer is empty.
 748   (aver (= (fd-stream-ibuf-head stream) (fd-stream-ibuf-tail stream)))
 749   (multiple-value-bind (count err)
 750       (sb!unix:unix-read (fd-stream-fd stream)
 751                          (fd-stream-ibuf-sap stream)
 752                          (fd-stream-ibuf-length stream))
 753     (declare (type (or index null) count))
 754     (when (null count)
 755       (simple-stream-perror "couldn't read from ~S" stream err))
 756     (setf (fd-stream-listen stream) nil
 757           (fd-stream-ibuf-head stream) 0
 758           (fd-stream-ibuf-tail stream) count)
 759     count))
 760 \f
 761 ;;;; utility functions (misc routines, etc)
 762
 763 ;;; Fill in the various routine slots for the given type. INPUT-P and
 764 ;;; OUTPUT-P indicate what slots to fill. The buffering slot must be
 765 ;;; set prior to calling this routine.
 766 (defun set-fd-stream-routines (fd-stream type input-p output-p buffer-p)
 767   (let ((target-type (case type
 768                        ((:default unsigned-byte)
 769                         '(unsigned-byte 8))
 770                        (signed-byte
 771                         '(signed-byte 8))
 772                        (t
 773                         type)))
 774         (input-type nil)
 775         (output-type nil)
 776         (input-size nil)
 777         (output-size nil))
 778
 779     (when (fd-stream-obuf-sap fd-stream)
 780       (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 781       (setf (fd-stream-obuf-sap fd-stream) nil))
 782     (when (fd-stream-ibuf-sap fd-stream)
 783       (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 784       (setf (fd-stream-ibuf-sap fd-stream) nil))
 785
 786     (when input-p
 787       (multiple-value-bind (routine type size)
 788           (pick-input-routine target-type)
 789         (unless routine
 790           (error "could not find any input routine for ~S" target-type))
 791         (setf (fd-stream-ibuf-sap fd-stream) (next-available-buffer))
 792         (setf (fd-stream-ibuf-length fd-stream) bytes-per-buffer)
 793         (setf (fd-stream-ibuf-tail fd-stream) 0)
 794         (if (subtypep type 'character)
 795             (setf (fd-stream-in fd-stream) routine
 796                   (fd-stream-bin fd-stream) #'ill-bin)
 797             (setf (fd-stream-in fd-stream) #'ill-in
 798                   (fd-stream-bin fd-stream) routine))
 799         (when (eql size 1)
 800           (setf (fd-stream-n-bin fd-stream) #'fd-stream-read-n-bytes)
 801           (when (and buffer-p
 802                      ;; We only create this buffer for streams of type
 803                      ;; (unsigned-byte 8).  Because there's no buffer, the
 804                      ;; other element-types will dispatch to the appropriate
 805                      ;; input (output) routine in fast-read-byte.
 806                      (equal target-type '(unsigned-byte 8))
 807                      #+nil
 808                      (or (eq type 'unsigned-byte)
 809                          (eq type :default)))
 810             (setf (ansi-stream-in-buffer fd-stream)
 811                   (make-array +ansi-stream-in-buffer-length+
 812                               :element-type '(unsigned-byte 8)))))
 813         (setf input-size size)
 814         (setf input-type type)))
 815
 816     (when output-p
 817       (multiple-value-bind (routine type size)
 818           (pick-output-routine target-type (fd-stream-buffering fd-stream))
 819         (unless routine
 820           (error "could not find any output routine for ~S buffered ~S"
 821                  (fd-stream-buffering fd-stream)
 822                  target-type))
 823         (setf (fd-stream-obuf-sap fd-stream) (next-available-buffer))
 824         (setf (fd-stream-obuf-length fd-stream) bytes-per-buffer)
 825         (setf (fd-stream-obuf-tail fd-stream) 0)
 826         (if (subtypep type 'character)
 827           (setf (fd-stream-out fd-stream) routine
 828                 (fd-stream-bout fd-stream) #'ill-bout)
 829           (setf (fd-stream-out fd-stream)
 830                 (or (if (eql size 1)
 831                       (pick-output-routine 'base-char
 832                                            (fd-stream-buffering fd-stream)))
 833                     #'ill-out)
 834                 (fd-stream-bout fd-stream) routine))
 835         (setf (fd-stream-sout fd-stream)
 836               (if (eql size 1) #'fd-sout #'ill-out))
 837         (setf (fd-stream-char-pos fd-stream) 0)
 838         (setf output-size size)
 839         (setf output-type type)))
 840
 841     (when (and input-size output-size
 842                (not (eq input-size output-size)))
 843       (error "Element sizes for input (~S:~S) and output (~S:~S) differ?"
 844              input-type input-size
 845              output-type output-size))
 846     (setf (fd-stream-element-size fd-stream)
 847           (or input-size output-size))
 848
 849     (setf (fd-stream-element-type fd-stream)
 850           (cond ((equal input-type output-type)
 851                  input-type)
 852                 ((null output-type)
 853                  input-type)
 854                 ((null input-type)
 855                  output-type)
 856                 ((subtypep input-type output-type)
 857                  input-type)
 858                 ((subtypep output-type input-type)
 859                  output-type)
 860                 (t
 861                  (error "Input type (~S) and output type (~S) are unrelated?"
 862                         input-type
 863                         output-type))))))
 864
 865 ;;; Handle miscellaneous operations on FD-STREAM.
 866 (defun fd-stream-misc-routine (fd-stream operation &optional arg1 arg2)
 867   (declare (ignore arg2))
 868   (case operation
 869     (:listen
 870      (or (not (eql (fd-stream-ibuf-head fd-stream)
 871                    (fd-stream-ibuf-tail fd-stream)))
 872          (fd-stream-listen fd-stream)
 873          (setf (fd-stream-listen fd-stream)
 874                (eql (sb!alien:with-alien ((read-fds (sb!alien:struct
 875                                                      sb!unix:fd-set)))
 876                       (sb!unix:fd-zero read-fds)
 877                       (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 878                       (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 879                                                 (sb!alien:addr read-fds)
 880                                                 nil nil 0 0))
 881                     1))))
 882     (:unread
 883      (setf (fd-stream-unread fd-stream) arg1)
 884      (setf (fd-stream-listen fd-stream) t))
 885     (:close
 886      (cond (arg1
 887             ;; We got us an abort on our hands.
 888             (when (fd-stream-handler fd-stream)
 889                   (sb!sys:remove-fd-handler (fd-stream-handler fd-stream))
 890                   (setf (fd-stream-handler fd-stream) nil))
 891             (when (and (fd-stream-file fd-stream)
 892                        (fd-stream-obuf-sap fd-stream))
 893               ;; We can't do anything unless we know what file were
 894               ;; dealing with, and we don't want to do anything
 895               ;; strange unless we were writing to the file.
 896               (if (fd-stream-original fd-stream)
 897                   ;; We have a handle on the original, just revert.
 898                   (multiple-value-bind (okay err)
 899                       (sb!unix:unix-rename (fd-stream-original fd-stream)
 900                                            (fd-stream-file fd-stream))
 901                     (unless okay
 902                       (simple-stream-perror
 903                        "couldn't restore ~S to its original contents"
 904                        fd-stream
 905                        err)))
 906                   ;; We can't restore the original, so nuke that puppy.
 907                   (multiple-value-bind (okay err)
 908                       (sb!unix:unix-unlink (fd-stream-file fd-stream))
 909                     (unless okay
 910                       (error 'simple-file-error
 911                              :pathname (fd-stream-file fd-stream)
 912                              :format-control
 913                              "~@<couldn't remove ~S: ~2I~_~A~:>"
 914                              :format-arguments (list (fd-stream-file fd-stream)
 915                                                      (strerror err))))))))
 916            (t
 917             (fd-stream-misc-routine fd-stream :finish-output)
 918             (when (and (fd-stream-original fd-stream)
 919                        (fd-stream-delete-original fd-stream))
 920               (multiple-value-bind (okay err)
 921                   (sb!unix:unix-unlink (fd-stream-original fd-stream))
 922                 (unless okay
 923                   (error 'simple-file-error
 924                          :pathname (fd-stream-original fd-stream)
 925                          :format-control
 926                          "~@<couldn't delete ~S during close of ~S: ~
 927                           ~2I~_~A~:>"
 928                          :format-arguments
 929                          (list (fd-stream-original fd-stream)
 930                                fd-stream
 931                                (strerror err))))))))
 932      (when (fboundp 'cancel-finalization)
 933        (cancel-finalization fd-stream))
 934      (sb!unix:unix-close (fd-stream-fd fd-stream))
 935      (when (fd-stream-obuf-sap fd-stream)
 936        (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 937        (setf (fd-stream-obuf-sap fd-stream) nil))
 938      (when (fd-stream-ibuf-sap fd-stream)
 939        (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 940        (setf (fd-stream-ibuf-sap fd-stream) nil))
 941      (sb!impl::set-closed-flame fd-stream))
 942     (:clear-input
 943      (setf (fd-stream-unread fd-stream) nil)
 944      (setf (fd-stream-ibuf-head fd-stream) 0)
 945      (setf (fd-stream-ibuf-tail fd-stream) 0)
 946      (catch 'eof-input-catcher
 947        (loop
 948         (let ((count (sb!alien:with-alien ((read-fds (sb!alien:struct
 949                                                       sb!unix:fd-set)))
 950                        (sb!unix:fd-zero read-fds)
 951                        (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 952                        (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 953                                                  (sb!alien:addr read-fds)
 954                                                  nil
 955                                                  nil
 956                                                  0
 957                                                  0))))
 958           (cond ((eql count 1)
 959                  (frob-input fd-stream)
 960                  (setf (fd-stream-ibuf-head fd-stream) 0)
 961                  (setf (fd-stream-ibuf-tail fd-stream) 0))
 962                 (t
 963                  (return t)))))))
 964     (:force-output
 965      (flush-output-buffer fd-stream))
 966     (:finish-output
 967      (flush-output-buffer fd-stream)
 968      (do ()
 969          ((null (fd-stream-output-later fd-stream)))
 970        (sb!sys:serve-all-events)))
 971     (:element-type
 972      (fd-stream-element-type fd-stream))
 973     (:interactive-p
 974      (= 1 (the (member 0 1)
 975             (sb!unix:unix-isatty (fd-stream-fd fd-stream)))))
 976     (:line-length
 977      80)
 978     (:charpos
 979      (fd-stream-char-pos fd-stream))
 980     (:file-length
 981      (unless (fd-stream-file fd-stream)
 982        ;; This is a TYPE-ERROR because ANSI's species FILE-LENGTH
 983        ;; "should signal an error of type TYPE-ERROR if stream is not
 984        ;; a stream associated with a file". Too bad there's no very
 985        ;; appropriate value for the EXPECTED-TYPE slot..
 986        (error 'simple-type-error
 987               :datum fd-stream
 988               :expected-type 'file-stream
 989               :format-control "~S is not a stream associated with a file."
 990               :format-arguments (list fd-stream)))
 991      (multiple-value-bind (okay dev ino mode nlink uid gid rdev size
 992                            atime mtime ctime blksize blocks)
 993          (sb!unix:unix-fstat (fd-stream-fd fd-stream))
 994        (declare (ignore ino nlink uid gid rdev
 995                         atime mtime ctime blksize blocks))
 996        (unless okay
 997          (simple-stream-perror "failed Unix fstat(2) on ~S" fd-stream dev))
 998        (if (zerop mode)
 999            nil
1000            (truncate size (fd-stream-element-size fd-stream)))))
1001     (:file-position
1002      (fd-stream-file-position fd-stream arg1))))
1003
1004 (defun fd-stream-file-position (stream &optional newpos)
1005   (declare (type file-stream stream)
1006            (type (or (alien sb!unix:off-t) (member nil :start :end)) newpos))
1007   (if (null newpos)
1008       (sb!sys:without-interrupts
1009         ;; First, find the position of the UNIX file descriptor in the file.
1010         (multiple-value-bind (posn errno)
1011             (sb!unix:unix-lseek (fd-stream-fd stream) 0 sb!unix:l_incr)
1012           (declare (type (or (alien sb!unix:off-t) null) posn))
1013           (cond ((integerp posn)
1014                  ;; Adjust for buffered output: If there is any output
1015                  ;; buffered, the *real* file position will be larger
1016                  ;; than reported by lseek() because lseek() obviously
1017                  ;; cannot take into account output we have not sent
1018                  ;; yet.
1019                  (dolist (later (fd-stream-output-later stream))
1020                    (incf posn (- (caddr later)
1021                                  (cadr later))))
1022                  (incf posn (fd-stream-obuf-tail stream))
1023                  ;; Adjust for unread input: If there is any input
1024                  ;; read from UNIX but not supplied to the user of the
1025                  ;; stream, the *real* file position will smaller than
1026                  ;; reported, because we want to look like the unread
1027                  ;; stuff is still available.
1028                  (decf posn (- (fd-stream-ibuf-tail stream)
1029                                (fd-stream-ibuf-head stream)))
1030                  (when (fd-stream-unread stream)
1031                    (decf posn))
1032                  ;; Divide bytes by element size.
1033                  (truncate posn (fd-stream-element-size stream)))
1034                 ((eq errno sb!unix:espipe)
1035                  nil)
1036                 (t
1037                  (sb!sys:with-interrupts
1038                    (simple-stream-perror "failure in Unix lseek() on ~S"
1039                                          stream
1040                                          errno))))))
1041       (let ((offset 0) origin)
1042         (declare (type (alien sb!unix:off-t) offset))
1043         ;; Make sure we don't have any output pending, because if we
1044         ;; move the file pointer before writing this stuff, it will be
1045         ;; written in the wrong location.
1046         (flush-output-buffer stream)
1047         (do ()
1048             ((null (fd-stream-output-later stream)))
1049           (sb!sys:serve-all-events))
1050         ;; Clear out any pending input to force the next read to go to
1051         ;; the disk.
1052         (setf (fd-stream-unread stream) nil)
1053         (setf (fd-stream-ibuf-head stream) 0)
1054         (setf (fd-stream-ibuf-tail stream) 0)
1055         ;; Trash cached value for listen, so that we check next time.
1056         (setf (fd-stream-listen stream) nil)
1057         ;; Now move it.
1058         (cond ((eq newpos :start)
1059                (setf offset 0 origin sb!unix:l_set))
1060               ((eq newpos :end)
1061                (setf offset 0 origin sb!unix:l_xtnd))
1062               ((typep newpos '(alien sb!unix:off-t))
1063                (setf offset (* newpos (fd-stream-element-size stream))
1064                      origin sb!unix:l_set))
1065               (t
1066                (error "invalid position given to FILE-POSITION: ~S" newpos)))
1067         (multiple-value-bind (posn errno)
1068             (sb!unix:unix-lseek (fd-stream-fd stream) offset origin)
1069           (cond ((typep posn '(alien sb!unix:off-t))
1070                  t)
1071                 ((eq errno sb!unix:espipe)
1072                  nil)
1073                 (t
1074                  (simple-stream-perror "error in Unix lseek() on ~S"
1075                                        stream
1076                                        errno)))))))
1077 \f
1078 ;;;; creation routines (MAKE-FD-STREAM and OPEN)
1079
1080 ;;; Create a stream for the given Unix file descriptor.
1081 ;;;
1082 ;;; If INPUT is non-NIL, allow input operations. If OUTPUT is non-nil,
1083 ;;; allow output operations. If neither INPUT nor OUTPUT is specified,
1084 ;;; default to allowing input.
1085 ;;;
1086 ;;; ELEMENT-TYPE indicates the element type to use (as for OPEN).
1087 ;;;
1088 ;;; BUFFERING indicates the kind of buffering to use.
1089 ;;;
1090 ;;; TIMEOUT (if true) is the number of seconds to wait for input. If
1091 ;;; NIL (the default), then wait forever. When we time out, we signal
1092 ;;; IO-TIMEOUT.
1093 ;;;
1094 ;;; FILE is the name of the file (will be returned by PATHNAME).
1095 ;;;
1096 ;;; NAME is used to identify the stream when printed.
1097 (defun make-fd-stream (fd
1098                        &key
1099                        (input nil input-p)
1100                        (output nil output-p)
1101                        (element-type 'base-char)
1102                        (buffering :full)
1103                        timeout
1104                        file
1105                        original
1106                        delete-original
1107                        pathname
1108                        input-buffer-p
1109                        (name (if file
1110                                  (format nil "file ~S" file)
1111                                  (format nil "descriptor ~W" fd)))
1112                        auto-close)
1113   (declare (type index fd) (type (or index null) timeout)
1114            (type (member :none :line :full) buffering))
1115   (cond ((not (or input-p output-p))
1116          (setf input t))
1117         ((not (or input output))
1118          (error "File descriptor must be opened either for input or output.")))
1119   (let ((stream (%make-fd-stream :fd fd
1120                                  :name name
1121                                  :file file
1122                                  :original original
1123                                  :delete-original delete-original
1124                                  :pathname pathname
1125                                  :buffering buffering
1126                                  :timeout timeout)))
1127     (set-fd-stream-routines stream element-type input output input-buffer-p)
1128     (when (and auto-close (fboundp 'finalize))
1129       (finalize stream
1130                 (lambda ()
1131                   (sb!unix:unix-close fd)
1132                   #!+sb-show
1133                   (format *terminal-io* "** closed file descriptor ~W **~%"
1134                           fd))))
1135     stream))
1136
1137 ;;; Pick a name to use for the backup file for the :IF-EXISTS
1138 ;;; :RENAME-AND-DELETE and :RENAME options.
1139 (defun pick-backup-name (name)
1140   (declare (type simple-base-string name))
1141   (concatenate 'simple-base-string name ".bak"))
1142
1143 ;;; Ensure that the given arg is one of the given list of valid
1144 ;;; things. Allow the user to fix any problems.
1145 (defun ensure-one-of (item list what)
1146   (unless (member item list)
1147     (error 'simple-type-error
1148            :datum item
1149            :expected-type `(member ,@list)
1150            :format-control "~@<~S is ~_invalid for ~S; ~_need one of~{ ~S~}~:>"
1151            :format-arguments (list item what list))))
1152
1153 ;;; Rename NAMESTRING to ORIGINAL. First, check whether we have write
1154 ;;; access, since we don't want to trash unwritable files even if we
1155 ;;; technically can. We return true if we succeed in renaming.
1156 (defun rename-the-old-one (namestring original)
1157   (unless (sb!unix:unix-access namestring sb!unix:w_ok)
1158     (error "~@<The file ~2I~_~S ~I~_is not writable.~:>" namestring))
1159   (multiple-value-bind (okay err) (sb!unix:unix-rename namestring original)
1160     (if okay
1161         t
1162         (error 'simple-file-error
1163                :pathname namestring
1164                :format-control
1165                "~@<couldn't rename ~2I~_~S ~I~_to ~2I~_~S: ~4I~_~A~:>"
1166                :format-arguments (list namestring original (strerror err))))))
1167
1168 (defun open (filename
1169              &key
1170              (direction :input)
1171              (element-type 'base-char)
1172              (if-exists nil if-exists-given)
1173              (if-does-not-exist nil if-does-not-exist-given)
1174              (external-format :default)
1175              &aux ; Squelch assignment warning.
1176              (direction direction)
1177              (if-does-not-exist if-does-not-exist)
1178              (if-exists if-exists))
1179   #!+sb-doc
1180   "Return a stream which reads from or writes to FILENAME.
1181   Defined keywords:
1182    :DIRECTION - one of :INPUT, :OUTPUT, :IO, or :PROBE
1183    :ELEMENT-TYPE - the type of object to read or write, default BASE-CHAR
1184    :IF-EXISTS - one of :ERROR, :NEW-VERSION, :RENAME, :RENAME-AND-DELETE,
1185                        :OVERWRITE, :APPEND, :SUPERSEDE or NIL
1186    :IF-DOES-NOT-EXIST - one of :ERROR, :CREATE or NIL
1187   See the manual for details."
1188
1189   (declare (ignore external-format)) ; FIXME: CHECK-TYPE?  WARN-if-not?
1190
1191   ;; Calculate useful stuff.
1192   (multiple-value-bind (input output mask)
1193       (case direction
1194         (:input  (values   t nil sb!unix:o_rdonly))
1195         (:output (values nil   t sb!unix:o_wronly))
1196         (:io     (values   t   t sb!unix:o_rdwr))
1197         (:probe  (values   t nil sb!unix:o_rdonly)))
1198     (declare (type index mask))
1199     (let* ((pathname (merge-pathnames filename))
1200            (namestring
1201             (cond ((unix-namestring pathname input))
1202                   ((and input (eq if-does-not-exist :create))
1203                    (unix-namestring pathname nil))
1204                   ((and (eq direction :io) (not if-does-not-exist-given))
1205                    (unix-namestring pathname nil)))))
1206       ;; Process if-exists argument if we are doing any output.
1207       (cond (output
1208              (unless if-exists-given
1209                (setf if-exists
1210                      (if (eq (pathname-version pathname) :newest)
1211                          :new-version
1212                          :error)))
1213              (ensure-one-of if-exists
1214                             '(:error :new-version :rename
1215                                      :rename-and-delete :overwrite
1216                                      :append :supersede nil)
1217                             :if-exists)
1218              (case if-exists
1219                ((:new-version :error nil)
1220                 (setf mask (logior mask sb!unix:o_excl)))
1221                ((:rename :rename-and-delete)
1222                 (setf mask (logior mask sb!unix:o_creat)))
1223                ((:supersede)
1224                 (setf mask (logior mask sb!unix:o_trunc)))
1225                (:append
1226                 (setf mask (logior mask sb!unix:o_append)))))
1227             (t
1228              (setf if-exists :ignore-this-arg)))
1229
1230       (unless if-does-not-exist-given
1231         (setf if-does-not-exist
1232               (cond ((eq direction :input) :error)
1233                     ((and output
1234                           (member if-exists '(:overwrite :append)))
1235                      :error)
1236                     ((eq direction :probe)
1237                      nil)
1238                     (t
1239                      :create))))
1240       (ensure-one-of if-does-not-exist
1241                      '(:error :create nil)
1242                      :if-does-not-exist)
1243       (if (eq if-does-not-exist :create)
1244         (setf mask (logior mask sb!unix:o_creat)))
1245
1246       (let ((original (if (member if-exists
1247                                   '(:rename :rename-and-delete))
1248                           (pick-backup-name namestring)))
1249             (delete-original (eq if-exists :rename-and-delete))
1250             (mode #o666))
1251         (when original
1252           ;; We are doing a :RENAME or :RENAME-AND-DELETE. Determine
1253           ;; whether the file already exists, make sure the original
1254           ;; file is not a directory, and keep the mode.
1255           (let ((exists
1256                  (and namestring
1257                       (multiple-value-bind (okay err/dev inode orig-mode)
1258                           (sb!unix:unix-stat namestring)
1259                         (declare (ignore inode)
1260                                  (type (or index null) orig-mode))
1261                         (cond
1262                          (okay
1263                           (when (and output (= (logand orig-mode #o170000)
1264                                                #o40000))
1265                             (error 'simple-file-error
1266                                    :pathname namestring
1267                                    :format-control
1268                                    "can't open ~S for output: is a directory"
1269                                    :format-arguments (list namestring)))
1270                           (setf mode (logand orig-mode #o777))
1271                           t)
1272                          ((eql err/dev sb!unix:enoent)
1273                           nil)
1274                          (t
1275                           (simple-file-perror "can't find ~S"
1276                                               namestring
1277                                               err/dev)))))))
1278             (unless (and exists
1279                          (rename-the-old-one namestring original))
1280               (setf original nil)
1281               (setf delete-original nil)
1282               ;; In order to use :SUPERSEDE instead, we have to make
1283               ;; sure SB!UNIX:O_CREAT corresponds to
1284               ;; IF-DOES-NOT-EXIST. SB!UNIX:O_CREAT was set before
1285               ;; because of IF-EXISTS being :RENAME.
1286               (unless (eq if-does-not-exist :create)
1287                 (setf mask
1288                       (logior (logandc2 mask sb!unix:o_creat)
1289                               sb!unix:o_trunc)))
1290               (setf if-exists :supersede))))
1291
1292         ;; Now we can try the actual Unix open(2).
1293         (multiple-value-bind (fd errno)
1294             (if namestring
1295                 (sb!unix:unix-open namestring mask mode)
1296                 (values nil sb!unix:enoent))
1297           (labels ((open-error (format-control &rest format-arguments)
1298                      (error 'simple-file-error
1299                             :pathname pathname
1300                             :format-control format-control
1301                             :format-arguments format-arguments))
1302                    (vanilla-open-error ()
1303                      (simple-file-perror "error opening ~S" pathname errno)))
1304             (cond ((numberp fd)
1305                    (case direction
1306                      ((:input :output :io)
1307                       (make-fd-stream fd
1308                                       :input input
1309                                       :output output
1310                                       :element-type element-type
1311                                       :file namestring
1312                                       :original original
1313                                       :delete-original delete-original
1314                                       :pathname pathname
1315                                       :input-buffer-p t
1316                                       :auto-close t))
1317                      (:probe
1318                       (let ((stream
1319                              (%make-fd-stream :name namestring
1320                                               :fd fd
1321                                               :pathname pathname
1322                                               :element-type element-type)))
1323                         (close stream)
1324                         stream))))
1325                   ((eql errno sb!unix:enoent)
1326                    (case if-does-not-exist
1327                      (:error (vanilla-open-error))
1328                      (:create
1329                       (open-error "~@<The path ~2I~_~S ~I~_does not exist.~:>"
1330                                   pathname))
1331                      (t nil)))
1332                   ((and (eql errno sb!unix:eexist) (null if-exists))
1333                    nil)
1334                   (t
1335                    (vanilla-open-error)))))))))
1336 \f
1337 ;;;; initialization
1338
1339 ;;; the stream connected to the controlling terminal, or NIL if there is none
1340 (defvar *tty*)
1341
1342 ;;; the stream connected to the standard input (file descriptor 0)
1343 (defvar *stdin*)
1344
1345 ;;; the stream connected to the standard output (file descriptor 1)
1346 (defvar *stdout*)
1347
1348 ;;; the stream connected to the standard error output (file descriptor 2)
1349 (defvar *stderr*)
1350
1351 ;;; This is called when the cold load is first started up, and may also
1352 ;;; be called in an attempt to recover from nested errors.
1353 (defun stream-cold-init-or-reset ()
1354   (stream-reinit)
1355   (setf *terminal-io* (make-synonym-stream '*tty*))
1356   (setf *standard-output* (make-synonym-stream '*stdout*))
1357   (setf *standard-input* (make-synonym-stream '*stdin*))
1358   (setf *error-output* (make-synonym-stream '*stderr*))
1359   (setf *query-io* (make-synonym-stream '*terminal-io*))
1360   (setf *debug-io* *query-io*)
1361   (setf *trace-output* *standard-output*)
1362   (values))
1363
1364 ;;; This is called whenever a saved core is restarted.
1365 (defun stream-reinit ()
1366   (setf *available-buffers* nil)
1367   (setf *stdin*
1368         (make-fd-stream 0 :name "standard input" :input t :buffering :line))
1369   (setf *stdout*
1370         (make-fd-stream 1 :name "standard output" :output t :buffering :line))
1371   (setf *stderr*
1372         (make-fd-stream 2 :name "standard error" :output t :buffering :line))
1373   (let ((tty (sb!unix:unix-open "/dev/tty" sb!unix:o_rdwr #o666)))
1374     (if tty
1375         (setf *tty*
1376               (make-fd-stream tty
1377                               :name "the terminal"
1378                               :input t
1379                               :output t
1380                               :buffering :line
1381                               :auto-close t))
1382         (setf *tty* (make-two-way-stream *stdin* *stdout*))))
1383   (values))
1384 \f
1385 ;;;; miscellany
1386
1387 ;;; the Unix way to beep
1388 (defun beep (stream)
1389   (write-char (code-char bell-char-code) stream)
1390   (finish-output stream))
1391
1392 ;;; This is kind of like FILE-POSITION, but is an internal hack used
1393 ;;; by the filesys stuff to get and set the file name.
1394 ;;;
1395 ;;; FIXME: misleading name, screwy interface
1396 (defun file-name (stream &optional new-name)
1397   (when (typep stream 'file-stream)
1398       (cond (new-name
1399              (setf (fd-stream-pathname stream) new-name)
1400              (setf (fd-stream-file stream)
1401                    (unix-namestring new-name nil))
1402              t)
1403             (t
1404              (fd-stream-pathname stream)))))
1405 \f
1406 ;;;; international character support (which is trivial for our simple
1407 ;;;; character sets)
1408
1409 ;;;; (Those who do Lisp only in English might not remember that ANSI
1410 ;;;; requires these functions to be exported from package
1411 ;;;; COMMON-LISP.)
1412
1413 (defun file-string-length (stream object)
1414   (declare (type (or string character) object) (type file-stream stream))
1415   #!+sb-doc
1416   "Return the delta in STREAM's FILE-POSITION that would be caused by writing
1417    OBJECT to STREAM. Non-trivial only in implementations that support
1418    international character sets."
1419   (declare (ignore stream))
1420   (etypecase object
1421     (character 1)
1422     (string (length object))))
1423
1424 (defun stream-external-format (stream)
1425   (declare (type file-stream stream) (ignore stream))
1426   #!+sb-doc
1427   "Return :DEFAULT."
1428   :default)