src/code/fd-stream.lisp

   1 ;;;; streams for UNIX file descriptors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; buffer manipulation routines
  15
  16 ;;; FIXME: Is it really good to maintain this pool separate from the
  17 ;;; GC and the C malloc logic?
  18 (defvar *available-buffers* ()
  19   #!+sb-doc
  20   "List of available buffers. Each buffer is an sap pointing to
  21   bytes-per-buffer of memory.")
  22
  23 (defconstant bytes-per-buffer (* 4 1024)
  24   #!+sb-doc
  25   "Number of bytes per buffer.")
  26
  27 ;;; Return the next available buffer, creating one if necessary.
  28 #!-sb-fluid (declaim (inline next-available-buffer))
  29 (defun next-available-buffer ()
  30   (if *available-buffers*
  31       (pop *available-buffers*)
  32       (allocate-system-memory bytes-per-buffer)))
  33 \f
  34 ;;;; the FILE-STREAM structure
  35
  36 (defstruct (file-stream
  37             (:constructor %make-fd-stream)
  38             ;; KLUDGE: in an ideal world, maybe we'd rewrite
  39             ;; everything to use FILE-STREAM rather than simply
  40             ;; providing this hack for compatibility with the old
  41             ;; code.  However, CVS doesn't deal terribly well with
  42             ;; file renaming, so for now we use this
  43             ;; backward-compatibility feature.
  44             (:conc-name fd-stream-)
  45             (:predicate fd-stream-p)
  46             (:include ansi-stream
  47                       (misc #'fd-stream-misc-routine))
  48             (:copier nil))
  49
  50   ;; the name of this stream
  51   (name nil)
  52   ;; the file this stream is for
  53   (file nil)
  54   ;; the backup file namestring for the old file, for :IF-EXISTS
  55   ;; :RENAME or :RENAME-AND-DELETE.
  56   (original nil :type (or simple-string null))
  57   (delete-original nil)       ; for :if-exists :rename-and-delete
  58   ;;; the number of bytes per element
  59   (element-size 1 :type index)
  60   ;; the type of element being transfered
  61   (element-type 'base-char)
  62   ;; the Unix file descriptor
  63   (fd -1 :type fixnum)
  64   ;; controls when the output buffer is flushed
  65   (buffering :full :type (member :full :line :none))
  66   ;; character position (if known)
  67   (char-pos nil :type (or index null))
  68   ;; T if input is waiting on FD. :EOF if we hit EOF.
  69   (listen nil :type (member nil t :eof))
  70
  71   ;; the input buffer
  72   (unread nil)
  73   (ibuf-sap nil :type (or system-area-pointer null))
  74   (ibuf-length nil :type (or index null))
  75   (ibuf-head 0 :type index)
  76   (ibuf-tail 0 :type index)
  77
  78   ;; the output buffer
  79   (obuf-sap nil :type (or system-area-pointer null))
  80   (obuf-length nil :type (or index null))
  81   (obuf-tail 0 :type index)
  82
  83   ;; output flushed, but not written due to non-blocking io?
  84   (output-later nil)
  85   (handler nil)
  86   ;; timeout specified for this stream, or NIL if none
  87   (timeout nil :type (or index null))
  88   ;; pathname of the file this stream is opened to (returned by PATHNAME)
  89   (pathname nil :type (or pathname null)))
  90 (def!method print-object ((fd-stream file-stream) stream)
  91   (declare (type stream stream))
  92   (print-unreadable-object (fd-stream stream :type t :identity t)
  93     (format stream "for ~S" (fd-stream-name fd-stream))))
  94 \f
  95 ;;;; output routines and related noise
  96
  97 (defvar *output-routines* ()
  98   #!+sb-doc
  99   "List of all available output routines. Each element is a list of the
 100   element-type output, the kind of buffering, the function name, and the number
 101   of bytes per element.")
 102
 103 ;;; common idioms for reporting low-level stream and file problems
 104 (defun simple-stream-perror (note-format stream errno)
 105   (error 'simple-stream-error
 106          :stream stream
 107          :format-control "~@<~?: ~2I~_~A~:>"
 108          :format-arguments (list note-format (list stream) (strerror errno))))
 109 (defun simple-file-perror (note-format pathname errno)
 110   (error 'simple-file-error
 111          :pathname pathname
 112          :format-control "~@<~?: ~2I~_~A~:>"
 113          :format-arguments
 114          (list note-format (list pathname) (strerror errno))))
 115
 116 ;;; This is called by the server when we can write to the given file
 117 ;;; descriptor. Attempt to write the data again. If it worked, remove
 118 ;;; the data from the OUTPUT-LATER list. If it didn't work, something
 119 ;;; is wrong.
 120 (defun frob-output-later (stream)
 121   (let* ((stuff (pop (fd-stream-output-later stream)))
 122          (base (car stuff))
 123          (start (cadr stuff))
 124          (end (caddr stuff))
 125          (reuse-sap (cadddr stuff))
 126          (length (- end start)))
 127     (declare (type index start end length))
 128     (multiple-value-bind (count errno)
 129         (sb!unix:unix-write (fd-stream-fd stream)
 130                             base
 131                             start
 132                             length)
 133       (cond ((not count)
 134              (if (= errno sb!unix:ewouldblock)
 135                  (error "Write would have blocked, but SERVER told us to go.")
 136                  (simple-stream-perror "couldn't write to ~S" stream errno)))
 137             ((eql count length) ; Hot damn, it worked.
 138              (when reuse-sap
 139                (push base *available-buffers*)))
 140             ((not (null count)) ; sorta worked..
 141              (push (list base
 142                          (the index (+ start count))
 143                          end)
 144                    (fd-stream-output-later stream))))))
 145   (unless (fd-stream-output-later stream)
 146     (sb!sys:remove-fd-handler (fd-stream-handler stream))
 147     (setf (fd-stream-handler stream) nil)))
 148
 149 ;;; Arange to output the string when we can write on the file descriptor.
 150 (defun output-later (stream base start end reuse-sap)
 151   (cond ((null (fd-stream-output-later stream))
 152          (setf (fd-stream-output-later stream)
 153                (list (list base start end reuse-sap)))
 154          (setf (fd-stream-handler stream)
 155                (sb!sys:add-fd-handler (fd-stream-fd stream)
 156                                       :output
 157                                       (lambda (fd)
 158                                         (declare (ignore fd))
 159                                         (frob-output-later stream)))))
 160         (t
 161          (nconc (fd-stream-output-later stream)
 162                 (list (list base start end reuse-sap)))))
 163   (when reuse-sap
 164     (let ((new-buffer (next-available-buffer)))
 165       (setf (fd-stream-obuf-sap stream) new-buffer)
 166       (setf (fd-stream-obuf-length stream) bytes-per-buffer))))
 167
 168 ;;; Output the given noise. Check to see whether there are any pending
 169 ;;; writes. If so, just queue this one. Otherwise, try to write it. If
 170 ;;; this would block, queue it.
 171 (defun frob-output (stream base start end reuse-sap)
 172   (declare (type file-stream stream)
 173            (type (or system-area-pointer (simple-array * (*))) base)
 174            (type index start end))
 175   (if (not (null (fd-stream-output-later stream))) ; something buffered.
 176       (progn
 177         (output-later stream base start end reuse-sap)
 178         ;; ### check to see whether any of this noise can be output
 179         )
 180       (let ((length (- end start)))
 181         (multiple-value-bind (count errno)
 182             (sb!unix:unix-write (fd-stream-fd stream) base start length)
 183           (cond ((not count)
 184                  (if (= errno sb!unix:ewouldblock)
 185                      (output-later stream base start end reuse-sap)
 186                      (simple-stream-perror "couldn't write to ~S"
 187                                            stream
 188                                            errno)))
 189                 ((not (eql count length))
 190                  (output-later stream base (the index (+ start count))
 191                                end reuse-sap)))))))
 192
 193 ;;; Flush any data in the output buffer.
 194 (defun flush-output-buffer (stream)
 195   (let ((length (fd-stream-obuf-tail stream)))
 196     (unless (= length 0)
 197       (frob-output stream (fd-stream-obuf-sap stream) 0 length t)
 198       (setf (fd-stream-obuf-tail stream) 0))))
 199
 200 ;;; Define output routines that output numbers SIZE bytes long for the
 201 ;;; given bufferings. Use BODY to do the actual output.
 202 (defmacro def-output-routines ((name-fmt size &rest bufferings) &body body)
 203   (declare (optimize (speed 1)))
 204   (cons 'progn
 205         (mapcar
 206             (lambda (buffering)
 207               (let ((function
 208                      (intern (let ((*print-case* :upcase))
 209                                (format nil name-fmt (car buffering))))))
 210                 `(progn
 211                    (defun ,function (stream byte)
 212                      ,(unless (eq (car buffering) :none)
 213                         `(when (< (fd-stream-obuf-length stream)
 214                                   (+ (fd-stream-obuf-tail stream)
 215                                      ,size))
 216                            (flush-output-buffer stream)))
 217                      ,@body
 218                      (incf (fd-stream-obuf-tail stream) ,size)
 219                      ,(ecase (car buffering)
 220                         (:none
 221                          `(flush-output-buffer stream))
 222                         (:line
 223                          `(when (eq (char-code byte) (char-code #\Newline))
 224                             (flush-output-buffer stream)))
 225                         (:full
 226                          ))
 227                      (values))
 228                    (setf *output-routines*
 229                          (nconc *output-routines*
 230                                 ',(mapcar
 231                                    (lambda (type)
 232                                      (list type
 233                                            (car buffering)
 234                                            function
 235                                            size))
 236                                    (cdr buffering)))))))
 237             bufferings)))
 238
 239 (def-output-routines ("OUTPUT-CHAR-~A-BUFFERED"
 240                       1
 241                       (:none character)
 242                       (:line character)
 243                       (:full character))
 244   (if (and (base-char-p byte) (char= byte #\Newline))
 245       (setf (fd-stream-char-pos stream) 0)
 246       (incf (fd-stream-char-pos stream)))
 247   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 248         (char-code byte)))
 249
 250 (def-output-routines ("OUTPUT-UNSIGNED-BYTE-~A-BUFFERED"
 251                       1
 252                       (:none (unsigned-byte 8))
 253                       (:full (unsigned-byte 8)))
 254   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 255         byte))
 256
 257 (def-output-routines ("OUTPUT-SIGNED-BYTE-~A-BUFFERED"
 258                       1
 259                       (:none (signed-byte 8))
 260                       (:full (signed-byte 8)))
 261   (setf (signed-sap-ref-8 (fd-stream-obuf-sap stream)
 262                           (fd-stream-obuf-tail stream))
 263         byte))
 264
 265 (def-output-routines ("OUTPUT-UNSIGNED-SHORT-~A-BUFFERED"
 266                       2
 267                       (:none (unsigned-byte 16))
 268                       (:full (unsigned-byte 16)))
 269   (setf (sap-ref-16 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 270         byte))
 271
 272 (def-output-routines ("OUTPUT-SIGNED-SHORT-~A-BUFFERED"
 273                       2
 274                       (:none (signed-byte 16))
 275                       (:full (signed-byte 16)))
 276   (setf (signed-sap-ref-16 (fd-stream-obuf-sap stream)
 277                            (fd-stream-obuf-tail stream))
 278         byte))
 279
 280 (def-output-routines ("OUTPUT-UNSIGNED-LONG-~A-BUFFERED"
 281                       4
 282                       (:none (unsigned-byte 32))
 283                       (:full (unsigned-byte 32)))
 284   (setf (sap-ref-32 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 285         byte))
 286
 287 (def-output-routines ("OUTPUT-SIGNED-LONG-~A-BUFFERED"
 288                       4
 289                       (:none (signed-byte 32))
 290                       (:full (signed-byte 32)))
 291   (setf (signed-sap-ref-32 (fd-stream-obuf-sap stream)
 292                            (fd-stream-obuf-tail stream))
 293         byte))
 294
 295 ;;; Do the actual output. If there is space to buffer the string,
 296 ;;; buffer it. If the string would normally fit in the buffer, but
 297 ;;; doesn't because of other stuff in the buffer, flush the old noise
 298 ;;; out of the buffer and put the string in it. Otherwise we have a
 299 ;;; very long string, so just send it directly (after flushing the
 300 ;;; buffer, of course).
 301 (defun output-raw-bytes (fd-stream thing &optional start end)
 302   #!+sb-doc
 303   "Output THING to FD-STREAM. THING can be any kind of vector or a SAP. If
 304   THING is a SAP, END must be supplied (as length won't work)."
 305   (let ((start (or start 0))
 306         (end (or end (length (the (simple-array * (*)) thing)))))
 307     (declare (type index start end))
 308     (let* ((len (fd-stream-obuf-length fd-stream))
 309            (tail (fd-stream-obuf-tail fd-stream))
 310            (space (- len tail))
 311            (bytes (- end start))
 312            (newtail (+ tail bytes)))
 313       (cond ((minusp bytes) ; error case
 314              (error ":END before :START!"))
 315             ((zerop bytes)) ; easy case
 316             ((<= bytes space)
 317              (if (system-area-pointer-p thing)
 318                  (system-area-copy thing
 319                                    (* start sb!vm:n-byte-bits)
 320                                    (fd-stream-obuf-sap fd-stream)
 321                                    (* tail sb!vm:n-byte-bits)
 322                                    (* bytes sb!vm:n-byte-bits))
 323                  ;; FIXME: There should be some type checking somewhere to
 324                  ;; verify that THING here is a vector, not just <not a SAP>.
 325                  (copy-to-system-area thing
 326                                       (+ (* start sb!vm:n-byte-bits)
 327                                          (* sb!vm:vector-data-offset
 328                                             sb!vm:n-word-bits))
 329                                       (fd-stream-obuf-sap fd-stream)
 330                                       (* tail sb!vm:n-byte-bits)
 331                                       (* bytes sb!vm:n-byte-bits)))
 332              (setf (fd-stream-obuf-tail fd-stream) newtail))
 333             ((<= bytes len)
 334              (flush-output-buffer fd-stream)
 335              (if (system-area-pointer-p thing)
 336                  (system-area-copy thing
 337                                    (* start sb!vm:n-byte-bits)
 338                                    (fd-stream-obuf-sap fd-stream)
 339                                    0
 340                                    (* bytes sb!vm:n-byte-bits))
 341                  ;; FIXME: There should be some type checking somewhere to
 342                  ;; verify that THING here is a vector, not just <not a SAP>.
 343                  (copy-to-system-area thing
 344                                       (+ (* start sb!vm:n-byte-bits)
 345                                          (* sb!vm:vector-data-offset
 346                                             sb!vm:n-word-bits))
 347                                       (fd-stream-obuf-sap fd-stream)
 348                                       0
 349                                       (* bytes sb!vm:n-byte-bits)))
 350              (setf (fd-stream-obuf-tail fd-stream) bytes))
 351             (t
 352              (flush-output-buffer fd-stream)
 353              (frob-output fd-stream thing start end nil))))))
 354
 355 ;;; the routine to use to output a string. If the stream is
 356 ;;; unbuffered, slam the string down the file descriptor, otherwise
 357 ;;; use OUTPUT-RAW-BYTES to buffer the string. Update charpos by
 358 ;;; checking to see where the last newline was.
 359 ;;;
 360 ;;; Note: some bozos (the FASL dumper) call write-string with things
 361 ;;; other than strings. Therefore, we must make sure we have a string
 362 ;;; before calling POSITION on it.
 363 ;;; KLUDGE: It would be better to fix the bozos instead of trying to
 364 ;;; cover for them here. -- WHN 20000203
 365 (defun fd-sout (stream thing start end)
 366   (let ((start (or start 0))
 367         (end (or end (length (the vector thing)))))
 368     (declare (fixnum start end))
 369     (if (stringp thing)
 370         (let ((last-newline (and (find #\newline (the simple-string thing)
 371                                        :start start :end end)
 372                                  ;; FIXME why do we need both calls?
 373                                  ;; Is find faster forwards than
 374                                  ;; position is backwards?
 375                                  (position #\newline (the simple-string thing)
 376                                            :from-end t
 377                                            :start start
 378                                            :end end))))
 379           (ecase (fd-stream-buffering stream)
 380             (:full
 381              (output-raw-bytes stream thing start end))
 382             (:line
 383              (output-raw-bytes stream thing start end)
 384              (when last-newline
 385                (flush-output-buffer stream)))
 386             (:none
 387              (frob-output stream thing start end nil)))
 388           (if last-newline
 389               (setf (fd-stream-char-pos stream)
 390                     (- end last-newline 1))
 391               (incf (fd-stream-char-pos stream)
 392                     (- end start))))
 393         (ecase (fd-stream-buffering stream)
 394           ((:line :full)
 395            (output-raw-bytes stream thing start end))
 396           (:none
 397            (frob-output stream thing start end nil))))))
 398
 399 ;;; Find an output routine to use given the type and buffering. Return
 400 ;;; as multiple values the routine, the real type transfered, and the
 401 ;;; number of bytes per element.
 402 (defun pick-output-routine (type buffering)
 403   (dolist (entry *output-routines*)
 404     (when (and (subtypep type (car entry))
 405                (eq buffering (cadr entry)))
 406       (return (values (symbol-function (caddr entry))
 407                       (car entry)
 408                       (cadddr entry))))))
 409 \f
 410 ;;;; input routines and related noise
 411
 412 ;;; a list of all available input routines. Each element is a list of
 413 ;;; the element-type input, the function name, and the number of bytes
 414 ;;; per element.
 415 (defvar *input-routines* ())
 416
 417 ;;; Fill the input buffer, and return the first character. Throw to
 418 ;;; EOF-INPUT-CATCHER if the eof was reached. Drop into SYSTEM:SERVER
 419 ;;; if necessary.
 420 (defun frob-input (stream)
 421   (let ((fd (fd-stream-fd stream))
 422         (ibuf-sap (fd-stream-ibuf-sap stream))
 423         (buflen (fd-stream-ibuf-length stream))
 424         (head (fd-stream-ibuf-head stream))
 425         (tail (fd-stream-ibuf-tail stream)))
 426     (declare (type index head tail))
 427     (unless (zerop head)
 428       (cond ((eql head tail)
 429              (setf head 0)
 430              (setf tail 0)
 431              (setf (fd-stream-ibuf-head stream) 0)
 432              (setf (fd-stream-ibuf-tail stream) 0))
 433             (t
 434              (decf tail head)
 435              (system-area-copy ibuf-sap (* head sb!vm:n-byte-bits)
 436                                ibuf-sap 0 (* tail sb!vm:n-byte-bits))
 437              (setf head 0)
 438              (setf (fd-stream-ibuf-head stream) 0)
 439              (setf (fd-stream-ibuf-tail stream) tail))))
 440     (setf (fd-stream-listen stream) nil)
 441     (multiple-value-bind (count errno)
 442         ;; FIXME: Judging from compiler warnings, this WITH-ALIEN form expands
 443         ;; into something which uses the not-yet-defined type
 444         ;;   (SB!ALIEN-INTERNALS:ALIEN (* (SB!ALIEN:STRUCT SB!UNIX:FD-SET))).
 445         ;; This is probably inefficient and unsafe and generally bad, so
 446         ;; try to find some way to make that type known before
 447         ;; this is compiled.
 448         (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set)))
 449           (sb!unix:fd-zero read-fds)
 450           (sb!unix:fd-set fd read-fds)
 451           (sb!unix:unix-fast-select (1+ fd)
 452                                     (sb!alien:addr read-fds)
 453                                     nil
 454                                     nil
 455                                     0
 456                                     0))
 457       (case count
 458         (1)
 459         (0
 460          (unless #!-mp (sb!sys:wait-until-fd-usable
 461                        fd :input (fd-stream-timeout stream))
 462                  #!+mp (sb!mp:process-wait-until-fd-usable
 463                        fd :input (fd-stream-timeout stream))
 464            (error 'io-timeout :stream stream :direction :read)))
 465         (t
 466          (simple-stream-perror "couldn't check whether ~S is readable"
 467                                stream
 468                                errno))))
 469     (multiple-value-bind (count errno)
 470         (sb!unix:unix-read fd
 471                            (sb!sys:int-sap (+ (sb!sys:sap-int ibuf-sap) tail))
 472                            (- buflen tail))
 473       (cond ((null count)
 474              (if (eql errno sb!unix:ewouldblock)
 475                  (progn
 476                    (unless #!-mp (sb!sys:wait-until-fd-usable
 477                                  fd :input (fd-stream-timeout stream))
 478                            #!+mp (sb!mp:process-wait-until-fd-usable
 479                                  fd :input (fd-stream-timeout stream))
 480                      (error 'io-timeout :stream stream :direction :read))
 481                    (frob-input stream))
 482                  (simple-stream-perror "couldn't read from ~S" stream errno)))
 483             ((zerop count)
 484              (setf (fd-stream-listen stream) :eof)
 485              (/show0 "THROWing EOF-INPUT-CATCHER")
 486              (throw 'eof-input-catcher nil))
 487             (t
 488              (incf (fd-stream-ibuf-tail stream) count))))))
 489
 490 ;;; Make sure there are at least BYTES number of bytes in the input
 491 ;;; buffer. Keep calling FROB-INPUT until that condition is met.
 492 (defmacro input-at-least (stream bytes)
 493   (let ((stream-var (gensym))
 494         (bytes-var (gensym)))
 495     `(let ((,stream-var ,stream)
 496            (,bytes-var ,bytes))
 497        (loop
 498          (when (>= (- (fd-stream-ibuf-tail ,stream-var)
 499                       (fd-stream-ibuf-head ,stream-var))
 500                    ,bytes-var)
 501            (return))
 502          (frob-input ,stream-var)))))
 503
 504 ;;; a macro to wrap around all input routines to handle EOF-ERROR noise
 505 (defmacro input-wrapper ((stream bytes eof-error eof-value) &body read-forms)
 506   (let ((stream-var (gensym))
 507         (element-var (gensym)))
 508     `(let ((,stream-var ,stream))
 509        (if (fd-stream-unread ,stream-var)
 510            (prog1
 511                (fd-stream-unread ,stream-var)
 512              (setf (fd-stream-unread ,stream-var) nil)
 513              (setf (fd-stream-listen ,stream-var) nil))
 514            (let ((,element-var
 515                   (catch 'eof-input-catcher
 516                     (input-at-least ,stream-var ,bytes)
 517                     ,@read-forms)))
 518              (cond (,element-var
 519                     (incf (fd-stream-ibuf-head ,stream-var) ,bytes)
 520                     ,element-var)
 521                    (t
 522                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
 523
 524 (defmacro def-input-routine (name
 525                              (type size sap head)
 526                              &rest body)
 527   `(progn
 528      (defun ,name (stream eof-error eof-value)
 529        (input-wrapper (stream ,size eof-error eof-value)
 530          (let ((,sap (fd-stream-ibuf-sap stream))
 531                (,head (fd-stream-ibuf-head stream)))
 532            ,@body)))
 533      (setf *input-routines*
 534            (nconc *input-routines*
 535                   (list (list ',type ',name ',size))))))
 536
 537 ;;; STREAM-IN routine for reading a string char
 538 (def-input-routine input-character
 539                    (character 1 sap head)
 540   (code-char (sap-ref-8 sap head)))
 541
 542 ;;; STREAM-IN routine for reading an unsigned 8 bit number
 543 (def-input-routine input-unsigned-8bit-byte
 544                    ((unsigned-byte 8) 1 sap head)
 545   (sap-ref-8 sap head))
 546
 547 ;;; STREAM-IN routine for reading a signed 8 bit number
 548 (def-input-routine input-signed-8bit-number
 549                    ((signed-byte 8) 1 sap head)
 550   (signed-sap-ref-8 sap head))
 551
 552 ;;; STREAM-IN routine for reading an unsigned 16 bit number
 553 (def-input-routine input-unsigned-16bit-byte
 554                    ((unsigned-byte 16) 2 sap head)
 555   (sap-ref-16 sap head))
 556
 557 ;;; STREAM-IN routine for reading a signed 16 bit number
 558 (def-input-routine input-signed-16bit-byte
 559                    ((signed-byte 16) 2 sap head)
 560   (signed-sap-ref-16 sap head))
 561
 562 ;;; STREAM-IN routine for reading a unsigned 32 bit number
 563 (def-input-routine input-unsigned-32bit-byte
 564                    ((unsigned-byte 32) 4 sap head)
 565   (sap-ref-32 sap head))
 566
 567 ;;; STREAM-IN routine for reading a signed 32 bit number
 568 (def-input-routine input-signed-32bit-byte
 569                    ((signed-byte 32) 4 sap head)
 570   (signed-sap-ref-32 sap head))
 571
 572 ;;; Find an input routine to use given the type. Return as multiple
 573 ;;; values the routine, the real type transfered, and the number of
 574 ;;; bytes per element.
 575 (defun pick-input-routine (type)
 576   (dolist (entry *input-routines*)
 577     (when (subtypep type (car entry))
 578       (return (values (symbol-function (cadr entry))
 579                       (car entry)
 580                       (caddr entry))))))
 581
 582 ;;; Return a string constructed from SAP, START, and END.
 583 (defun string-from-sap (sap start end)
 584   (declare (type index start end))
 585   (let* ((length (- end start))
 586          (string (make-string length)))
 587     (copy-from-system-area sap (* start sb!vm:n-byte-bits)
 588                            string (* sb!vm:vector-data-offset
 589                                      sb!vm:n-word-bits)
 590                            (* length sb!vm:n-byte-bits))
 591     string))
 592
 593 ;;; the N-BIN method for FD-STREAMs
 594 ;;;
 595 ;;; Note that this blocks in UNIX-READ. It is generally used where
 596 ;;; there is a definite amount of reading to be done, so blocking
 597 ;;; isn't too problematical.
 598 (defun fd-stream-read-n-bytes (stream buffer start requested eof-error-p)
 599   (declare (type file-stream stream))
 600   (declare (type index start requested))
 601   (do ((total-copied 0))
 602       (nil)
 603     (declare (type index total-copied))
 604     (let* ((remaining-request (- requested total-copied))
 605            (head (fd-stream-ibuf-head stream))
 606            (tail (fd-stream-ibuf-tail stream))
 607            (available (- tail head))
 608            (n-this-copy (min remaining-request available))
 609            (this-start (+ start total-copied))
 610            (this-end (+ this-start n-this-copy))
 611            (sap (fd-stream-ibuf-sap stream)))
 612       (declare (type index remaining-request head tail available))
 613       (declare (type index n-this-copy))
 614       ;; Copy data from stream buffer into user's buffer.
 615       (%byte-blt sap head buffer this-start this-end)
 616       (incf (fd-stream-ibuf-head stream) n-this-copy)
 617       (incf total-copied n-this-copy)
 618       ;; Maybe we need to refill the stream buffer.
 619       (cond (;; If there were enough data in the stream buffer, we're done.
 620              (= total-copied requested)
 621              (return total-copied))
 622             (;; If EOF, we're done in another way.
 623              (zerop (refill-fd-stream-buffer stream))
 624              (if eof-error-p
 625                  (error 'end-of-file :stream stream)
 626                  (return total-copied)))
 627             ;; Otherwise we refilled the stream buffer, so fall
 628             ;; through into another pass of the loop.
 629             ))))
 630
 631 ;;; Try to refill the stream buffer. Return the number of bytes read.
 632 ;;; (For EOF, the return value will be zero, otherwise positive.)
 633 (defun refill-fd-stream-buffer (stream)
 634   ;; We don't have any logic to preserve leftover bytes in the buffer,
 635   ;; so we should only be called when the buffer is empty.
 636   (aver (= (fd-stream-ibuf-head stream) (fd-stream-ibuf-tail stream)))
 637   (multiple-value-bind (count err)
 638       (sb!unix:unix-read (fd-stream-fd stream)
 639                          (fd-stream-ibuf-sap stream)
 640                          (fd-stream-ibuf-length stream))
 641     (declare (type (or index null) count))
 642     (when (null count)
 643       (simple-stream-perror "couldn't read from ~S" stream err))
 644     (setf (fd-stream-listen stream) nil
 645           (fd-stream-ibuf-head stream) 0
 646           (fd-stream-ibuf-tail stream) count)
 647     count))
 648 \f
 649 ;;;; utility functions (misc routines, etc)
 650
 651 ;;; Fill in the various routine slots for the given type. INPUT-P and
 652 ;;; OUTPUT-P indicate what slots to fill. The buffering slot must be
 653 ;;; set prior to calling this routine.
 654 (defun set-fd-stream-routines (fd-stream type input-p output-p buffer-p)
 655   (let ((target-type (case type
 656                        ((:default unsigned-byte)
 657                         '(unsigned-byte 8))
 658                        (signed-byte
 659                         '(signed-byte 8))
 660                        (t
 661                         type)))
 662         (input-type nil)
 663         (output-type nil)
 664         (input-size nil)
 665         (output-size nil))
 666
 667     (when (fd-stream-obuf-sap fd-stream)
 668       (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 669       (setf (fd-stream-obuf-sap fd-stream) nil))
 670     (when (fd-stream-ibuf-sap fd-stream)
 671       (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 672       (setf (fd-stream-ibuf-sap fd-stream) nil))
 673
 674     (when input-p
 675       (multiple-value-bind (routine type size)
 676           (pick-input-routine target-type)
 677         (unless routine
 678           (error "could not find any input routine for ~S" target-type))
 679         (setf (fd-stream-ibuf-sap fd-stream) (next-available-buffer))
 680         (setf (fd-stream-ibuf-length fd-stream) bytes-per-buffer)
 681         (setf (fd-stream-ibuf-tail fd-stream) 0)
 682         (if (subtypep type 'character)
 683             (setf (fd-stream-in fd-stream) routine
 684                   (fd-stream-bin fd-stream) #'ill-bin)
 685             (setf (fd-stream-in fd-stream) #'ill-in
 686                   (fd-stream-bin fd-stream) routine))
 687         (when (eql size 1)
 688           (setf (fd-stream-n-bin fd-stream) #'fd-stream-read-n-bytes)
 689           (when buffer-p
 690             (setf (ansi-stream-in-buffer fd-stream)
 691                   (make-array +ansi-stream-in-buffer-length+
 692                               :element-type '(unsigned-byte 8)))))
 693         (setf input-size size)
 694         (setf input-type type)))
 695
 696     (when output-p
 697       (multiple-value-bind (routine type size)
 698           (pick-output-routine target-type (fd-stream-buffering fd-stream))
 699         (unless routine
 700           (error "could not find any output routine for ~S buffered ~S"
 701                  (fd-stream-buffering fd-stream)
 702                  target-type))
 703         (setf (fd-stream-obuf-sap fd-stream) (next-available-buffer))
 704         (setf (fd-stream-obuf-length fd-stream) bytes-per-buffer)
 705         (setf (fd-stream-obuf-tail fd-stream) 0)
 706         (if (subtypep type 'character)
 707           (setf (fd-stream-out fd-stream) routine
 708                 (fd-stream-bout fd-stream) #'ill-bout)
 709           (setf (fd-stream-out fd-stream)
 710                 (or (if (eql size 1)
 711                       (pick-output-routine 'base-char
 712                                            (fd-stream-buffering fd-stream)))
 713                     #'ill-out)
 714                 (fd-stream-bout fd-stream) routine))
 715         (setf (fd-stream-sout fd-stream)
 716               (if (eql size 1) #'fd-sout #'ill-out))
 717         (setf (fd-stream-char-pos fd-stream) 0)
 718         (setf output-size size)
 719         (setf output-type type)))
 720
 721     (when (and input-size output-size
 722                (not (eq input-size output-size)))
 723       (error "Element sizes for input (~S:~S) and output (~S:~S) differ?"
 724              input-type input-size
 725              output-type output-size))
 726     (setf (fd-stream-element-size fd-stream)
 727           (or input-size output-size))
 728
 729     (setf (fd-stream-element-type fd-stream)
 730           (cond ((equal input-type output-type)
 731                  input-type)
 732                 ((null output-type)
 733                  input-type)
 734                 ((null input-type)
 735                  output-type)
 736                 ((subtypep input-type output-type)
 737                  input-type)
 738                 ((subtypep output-type input-type)
 739                  output-type)
 740                 (t
 741                  (error "Input type (~S) and output type (~S) are unrelated?"
 742                         input-type
 743                         output-type))))))
 744
 745 ;;; Handle miscellaneous operations on FD-STREAM.
 746 (defun fd-stream-misc-routine (fd-stream operation &optional arg1 arg2)
 747   (declare (ignore arg2))
 748   (case operation
 749     (:listen
 750      (or (not (eql (fd-stream-ibuf-head fd-stream)
 751                    (fd-stream-ibuf-tail fd-stream)))
 752          (fd-stream-listen fd-stream)
 753          (setf (fd-stream-listen fd-stream)
 754                (eql (sb!alien:with-alien ((read-fds (sb!alien:struct
 755                                                      sb!unix:fd-set)))
 756                       (sb!unix:fd-zero read-fds)
 757                       (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 758                       (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 759                                                 (sb!alien:addr read-fds)
 760                                                 nil nil 0 0))
 761                     1))))
 762     (:unread
 763      (setf (fd-stream-unread fd-stream) arg1)
 764      (setf (fd-stream-listen fd-stream) t))
 765     (:close
 766      (cond (arg1
 767             ;; We got us an abort on our hands.
 768             (when (fd-stream-handler fd-stream)
 769                   (sb!sys:remove-fd-handler (fd-stream-handler fd-stream))
 770                   (setf (fd-stream-handler fd-stream) nil))
 771             (when (and (fd-stream-file fd-stream)
 772                        (fd-stream-obuf-sap fd-stream))
 773               ;; We can't do anything unless we know what file were
 774               ;; dealing with, and we don't want to do anything
 775               ;; strange unless we were writing to the file.
 776               (if (fd-stream-original fd-stream)
 777                   ;; We have a handle on the original, just revert.
 778                   (multiple-value-bind (okay err)
 779                       (sb!unix:unix-rename (fd-stream-original fd-stream)
 780                                            (fd-stream-file fd-stream))
 781                     (unless okay
 782                       (simple-stream-perror
 783                        "couldn't restore ~S to its original contents"
 784                        fd-stream
 785                        err)))
 786                   ;; We can't restore the original, so nuke that puppy.
 787                   (multiple-value-bind (okay err)
 788                       (sb!unix:unix-unlink (fd-stream-file fd-stream))
 789                     (unless okay
 790                       (error 'simple-file-error
 791                              :pathname (fd-stream-file fd-stream)
 792                              :format-control
 793                              "~@<couldn't remove ~S: ~2I~_~A~:>"
 794                              :format-arguments (list (fd-stream-file fd-stream)
 795                                                      (strerror err))))))))
 796            (t
 797             (fd-stream-misc-routine fd-stream :finish-output)
 798             (when (and (fd-stream-original fd-stream)
 799                        (fd-stream-delete-original fd-stream))
 800               (multiple-value-bind (okay err)
 801                   (sb!unix:unix-unlink (fd-stream-original fd-stream))
 802                 (unless okay
 803                   (error 'simple-file-error
 804                          :pathname (fd-stream-original fd-stream)
 805                          :format-control
 806                          "~@<couldn't delete ~S during close of ~S: ~
 807                           ~2I~_~A~:>"
 808                          :format-arguments
 809                          (list (fd-stream-original fd-stream)
 810                                fd-stream
 811                                (strerror err))))))))
 812      (when (fboundp 'cancel-finalization)
 813        (cancel-finalization fd-stream))
 814      (sb!unix:unix-close (fd-stream-fd fd-stream))
 815      (when (fd-stream-obuf-sap fd-stream)
 816        (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 817        (setf (fd-stream-obuf-sap fd-stream) nil))
 818      (when (fd-stream-ibuf-sap fd-stream)
 819        (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 820        (setf (fd-stream-ibuf-sap fd-stream) nil))
 821      (sb!impl::set-closed-flame fd-stream))
 822     (:clear-input
 823      (setf (fd-stream-unread fd-stream) nil)
 824      (setf (fd-stream-ibuf-head fd-stream) 0)
 825      (setf (fd-stream-ibuf-tail fd-stream) 0)
 826      (catch 'eof-input-catcher
 827        (loop
 828         (let ((count (sb!alien:with-alien ((read-fds (sb!alien:struct
 829                                                       sb!unix:fd-set)))
 830                        (sb!unix:fd-zero read-fds)
 831                        (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 832                        (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 833                                                  (sb!alien:addr read-fds)
 834                                                  nil
 835                                                  nil
 836                                                  0
 837                                                  0))))
 838           (cond ((eql count 1)
 839                  (frob-input fd-stream)
 840                  (setf (fd-stream-ibuf-head fd-stream) 0)
 841                  (setf (fd-stream-ibuf-tail fd-stream) 0))
 842                 (t
 843                  (return t)))))))
 844     (:force-output
 845      (flush-output-buffer fd-stream))
 846     (:finish-output
 847      (flush-output-buffer fd-stream)
 848      (do ()
 849          ((null (fd-stream-output-later fd-stream)))
 850        (sb!sys:serve-all-events)))
 851     (:element-type
 852      (fd-stream-element-type fd-stream))
 853     (:interactive-p
 854       ;; FIXME: sb!unix:unix-isatty is undefined.
 855      (sb!unix:unix-isatty (fd-stream-fd fd-stream)))
 856     (:line-length
 857      80)
 858     (:charpos
 859      (fd-stream-char-pos fd-stream))
 860     (:file-length
 861      (unless (fd-stream-file fd-stream)
 862        ;; This is a TYPE-ERROR because ANSI's species FILE-LENGTH
 863        ;; "should signal an error of type TYPE-ERROR if stream is not
 864        ;; a stream associated with a file". Too bad there's no very
 865        ;; appropriate value for the EXPECTED-TYPE slot..
 866        (error 'simple-type-error
 867               :datum fd-stream
 868               :expected-type 'file-stream
 869               :format-control "~S is not a stream associated with a file."
 870               :format-arguments (list fd-stream)))
 871      (multiple-value-bind (okay dev ino mode nlink uid gid rdev size
 872                            atime mtime ctime blksize blocks)
 873          (sb!unix:unix-fstat (fd-stream-fd fd-stream))
 874        (declare (ignore ino nlink uid gid rdev
 875                         atime mtime ctime blksize blocks))
 876        (unless okay
 877          (simple-stream-perror "failed Unix fstat(2) on ~S" fd-stream dev))
 878        (if (zerop mode)
 879            nil
 880            (truncate size (fd-stream-element-size fd-stream)))))
 881     (:file-position
 882      (fd-stream-file-position fd-stream arg1))))
 883
 884 (defun fd-stream-file-position (stream &optional newpos)
 885   (declare (type file-stream stream)
 886            (type (or index (member nil :start :end)) newpos))
 887   (if (null newpos)
 888       (sb!sys:without-interrupts
 889         ;; First, find the position of the UNIX file descriptor in the file.
 890         (multiple-value-bind (posn errno)
 891             (sb!unix:unix-lseek (fd-stream-fd stream) 0 sb!unix:l_incr)
 892           (declare (type (or index null) posn))
 893           (cond ((fixnump posn)
 894                  ;; Adjust for buffered output: If there is any output
 895                  ;; buffered, the *real* file position will be larger
 896                  ;; than reported by lseek() because lseek() obviously
 897                  ;; cannot take into account output we have not sent
 898                  ;; yet.
 899                  (dolist (later (fd-stream-output-later stream))
 900                    (incf posn (- (the index (caddr later))
 901                                  (the index (cadr later)))))
 902                  (incf posn (fd-stream-obuf-tail stream))
 903                  ;; Adjust for unread input: If there is any input
 904                  ;; read from UNIX but not supplied to the user of the
 905                  ;; stream, the *real* file position will smaller than
 906                  ;; reported, because we want to look like the unread
 907                  ;; stuff is still available.
 908                  (decf posn (- (fd-stream-ibuf-tail stream)
 909                                (fd-stream-ibuf-head stream)))
 910                  (when (fd-stream-unread stream)
 911                    (decf posn))
 912                  ;; Divide bytes by element size.
 913                  (truncate posn (fd-stream-element-size stream)))
 914                 ((eq errno sb!unix:espipe)
 915                  nil)
 916                 (t
 917                  (sb!sys:with-interrupts
 918                    (simple-stream-perror "failure in Unix lseek() on ~S"
 919                                          stream
 920                                          errno))))))
 921       (let ((offset 0) origin)
 922         (declare (type index offset))
 923         ;; Make sure we don't have any output pending, because if we
 924         ;; move the file pointer before writing this stuff, it will be
 925         ;; written in the wrong location.
 926         (flush-output-buffer stream)
 927         (do ()
 928             ((null (fd-stream-output-later stream)))
 929           (sb!sys:serve-all-events))
 930         ;; Clear out any pending input to force the next read to go to
 931         ;; the disk.
 932         (setf (fd-stream-unread stream) nil)
 933         (setf (fd-stream-ibuf-head stream) 0)
 934         (setf (fd-stream-ibuf-tail stream) 0)
 935         ;; Trash cached value for listen, so that we check next time.
 936         (setf (fd-stream-listen stream) nil)
 937         ;; Now move it.
 938         (cond ((eq newpos :start)
 939                (setf offset 0 origin sb!unix:l_set))
 940               ((eq newpos :end)
 941                (setf offset 0 origin sb!unix:l_xtnd))
 942               ((typep newpos 'index)
 943                (setf offset (* newpos (fd-stream-element-size stream))
 944                      origin sb!unix:l_set))
 945               (t
 946                (error "invalid position given to FILE-POSITION: ~S" newpos)))
 947         (multiple-value-bind (posn errno)
 948             (sb!unix:unix-lseek (fd-stream-fd stream) offset origin)
 949           (cond ((typep posn 'fixnum)
 950                  t)
 951                 ((eq errno sb!unix:espipe)
 952                  nil)
 953                 (t
 954                  (simple-stream-perror "error in Unix lseek() on ~S"
 955                                        stream
 956                                        errno)))))))
 957 \f
 958 ;;;; creation routines (MAKE-FD-STREAM and OPEN)
 959
 960 ;;; Create a stream for the given Unix file descriptor.
 961 ;;;
 962 ;;; If INPUT is non-NIL, allow input operations. If OUTPUT is non-nil,
 963 ;;; allow output operations. If neither INPUT nor OUTPUT is specified,
 964 ;;; default to allowing input.
 965 ;;;
 966 ;;; ELEMENT-TYPE indicates the element type to use (as for OPEN).
 967 ;;;
 968 ;;; BUFFERING indicates the kind of buffering to use.
 969 ;;;
 970 ;;; TIMEOUT (if true) is the number of seconds to wait for input. If
 971 ;;; NIL (the default), then wait forever. When we time out, we signal
 972 ;;; IO-TIMEOUT.
 973 ;;;
 974 ;;; FILE is the name of the file (will be returned by PATHNAME).
 975 ;;;
 976 ;;; NAME is used to identify the stream when printed.
 977 (defun make-fd-stream (fd
 978                        &key
 979                        (input nil input-p)
 980                        (output nil output-p)
 981                        (element-type 'base-char)
 982                        (buffering :full)
 983                        timeout
 984                        file
 985                        original
 986                        delete-original
 987                        pathname
 988                        input-buffer-p
 989                        (name (if file
 990                                  (format nil "file ~S" file)
 991                                  (format nil "descriptor ~W" fd)))
 992                        auto-close)
 993   (declare (type index fd) (type (or index null) timeout)
 994            (type (member :none :line :full) buffering))
 995   (cond ((not (or input-p output-p))
 996          (setf input t))
 997         ((not (or input output))
 998          (error "File descriptor must be opened either for input or output.")))
 999   (let ((stream (%make-fd-stream :fd fd
1000                                  :name name
1001                                  :file file
1002                                  :original original
1003                                  :delete-original delete-original
1004                                  :pathname pathname
1005                                  :buffering buffering
1006                                  :timeout timeout)))
1007     (set-fd-stream-routines stream element-type input output input-buffer-p)
1008     (when (and auto-close (fboundp 'finalize))
1009       (finalize stream
1010                 (lambda ()
1011                   (sb!unix:unix-close fd)
1012                   #!+sb-show
1013                   (format *terminal-io* "** closed file descriptor ~W **~%"
1014                           fd))))
1015     stream))
1016
1017 ;;; Pick a name to use for the backup file for the :IF-EXISTS
1018 ;;; :RENAME-AND-DELETE and :RENAME options.
1019 (defun pick-backup-name (name)
1020   (declare (type simple-string name))
1021   (concatenate 'simple-string name ".bak"))
1022
1023 ;;; Ensure that the given arg is one of the given list of valid
1024 ;;; things. Allow the user to fix any problems.
1025 (defun ensure-one-of (item list what)
1026   (unless (member item list)
1027     (error 'simple-type-error
1028            :datum item
1029            :expected-type `(member ,@list)
1030            :format-control "~@<~S is ~_invalid for ~S; ~_need one of~{ ~S~}~:>"
1031            :format-arguments (list item what list))))
1032
1033 ;;; Rename NAMESTRING to ORIGINAL. First, check whether we have write
1034 ;;; access, since we don't want to trash unwritable files even if we
1035 ;;; technically can. We return true if we succeed in renaming.
1036 (defun rename-the-old-one (namestring original)
1037   (unless (sb!unix:unix-access namestring sb!unix:w_ok)
1038     (error "~@<The file ~2I~_~S ~I~_is not writable.~:>" namestring))
1039   (multiple-value-bind (okay err) (sb!unix:unix-rename namestring original)
1040     (if okay
1041         t
1042         (error 'simple-file-error
1043                :pathname namestring
1044                :format-control
1045                "~@<couldn't rename ~2I~_~S ~I~_to ~2I~_~S: ~4I~_~A~:>"
1046                :format-arguments (list namestring original (strerror err))))))
1047
1048 (defun open (filename
1049              &key
1050              (direction :input)
1051              (element-type 'base-char)
1052              (if-exists nil if-exists-given)
1053              (if-does-not-exist nil if-does-not-exist-given)
1054              (external-format :default)
1055              &aux ; Squelch assignment warning.
1056              (direction direction)
1057              (if-does-not-exist if-does-not-exist)
1058              (if-exists if-exists))
1059   #!+sb-doc
1060   "Return a stream which reads from or writes to FILENAME.
1061   Defined keywords:
1062    :DIRECTION - one of :INPUT, :OUTPUT, :IO, or :PROBE
1063    :ELEMENT-TYPE - the type of object to read or write, default BASE-CHAR
1064    :IF-EXISTS - one of :ERROR, :NEW-VERSION, :RENAME, :RENAME-AND-DELETE,
1065                        :OVERWRITE, :APPEND, :SUPERSEDE or NIL
1066    :IF-DOES-NOT-EXIST - one of :ERROR, :CREATE or nil
1067   See the manual for details."
1068
1069   (unless (eq external-format :default)
1070     (error "Any external format other than :DEFAULT isn't recognized."))
1071
1072   ;; First, make sure that DIRECTION is valid.
1073   (ensure-one-of direction
1074                  '(:input :output :io :probe)
1075                  :direction)
1076
1077   ;; Calculate useful stuff.
1078   (multiple-value-bind (input output mask)
1079       (case direction
1080         (:input  (values   t nil sb!unix:o_rdonly))
1081         (:output (values nil   t sb!unix:o_wronly))
1082         (:io     (values   t   t sb!unix:o_rdwr))
1083         (:probe  (values   t nil sb!unix:o_rdonly)))
1084     (declare (type index mask))
1085     (let* ((pathname (merge-pathnames filename))
1086            (namestring
1087             (cond ((unix-namestring pathname input))
1088                   ((and input (eq if-does-not-exist :create))
1089                    (unix-namestring pathname nil)))))
1090       ;; Process if-exists argument if we are doing any output.
1091       (cond (output
1092              (unless if-exists-given
1093                (setf if-exists
1094                      (if (eq (pathname-version pathname) :newest)
1095                          :new-version
1096                          :error)))
1097              (ensure-one-of if-exists
1098                             '(:error :new-version :rename
1099                                      :rename-and-delete :overwrite
1100                                      :append :supersede nil)
1101                             :if-exists)
1102              (case if-exists
1103                ((:error nil)
1104                 (setf mask (logior mask sb!unix:o_excl)))
1105                ((:rename :rename-and-delete)
1106                 (setf mask (logior mask sb!unix:o_creat)))
1107                ((:new-version :supersede)
1108                 (setf mask (logior mask sb!unix:o_trunc)))
1109                (:append
1110                 (setf mask (logior mask sb!unix:o_append)))))
1111             (t
1112              (setf if-exists :ignore-this-arg)))
1113
1114       (unless if-does-not-exist-given
1115         (setf if-does-not-exist
1116               (cond ((eq direction :input) :error)
1117                     ((and output
1118                           (member if-exists '(:overwrite :append)))
1119                      :error)
1120                     ((eq direction :probe)
1121                      nil)
1122                     (t
1123                      :create))))
1124       (ensure-one-of if-does-not-exist
1125                      '(:error :create nil)
1126                      :if-does-not-exist)
1127       (if (eq if-does-not-exist :create)
1128         (setf mask (logior mask sb!unix:o_creat)))
1129
1130       (let ((original (if (member if-exists
1131                                   '(:rename :rename-and-delete))
1132                           (pick-backup-name namestring)))
1133             (delete-original (eq if-exists :rename-and-delete))
1134             (mode #o666))
1135         (when original
1136           ;; We are doing a :RENAME or :RENAME-AND-DELETE. Determine
1137           ;; whether the file already exists, make sure the original
1138           ;; file is not a directory, and keep the mode.
1139           (let ((exists
1140                  (and namestring
1141                       (multiple-value-bind (okay err/dev inode orig-mode)
1142                           (sb!unix:unix-stat namestring)
1143                         (declare (ignore inode)
1144                                  (type (or index null) orig-mode))
1145                         (cond
1146                          (okay
1147                           (when (and output (= (logand orig-mode #o170000)
1148                                                #o40000))
1149                             (error 'simple-file-error
1150                                    :pathname namestring
1151                                    :format-control
1152                                    "can't open ~S for output: is a directory"
1153                                    :format-arguments (list namestring)))
1154                           (setf mode (logand orig-mode #o777))
1155                           t)
1156                          ((eql err/dev sb!unix:enoent)
1157                           nil)
1158                          (t
1159                           (simple-file-perror "can't find ~S"
1160                                               namestring
1161                                               err/dev)))))))
1162             (unless (and exists
1163                          (rename-the-old-one namestring original))
1164               (setf original nil)
1165               (setf delete-original nil)
1166               ;; In order to use :SUPERSEDE instead, we have to make
1167               ;; sure SB!UNIX:O_CREAT corresponds to
1168               ;; IF-DOES-NOT-EXIST. SB!UNIX:O_CREAT was set before
1169               ;; because of IF-EXISTS being :RENAME.
1170               (unless (eq if-does-not-exist :create)
1171                 (setf mask
1172                       (logior (logandc2 mask sb!unix:o_creat)
1173                               sb!unix:o_trunc)))
1174               (setf if-exists :supersede))))
1175
1176         ;; Now we can try the actual Unix open(2).
1177         (multiple-value-bind (fd errno)
1178             (if namestring
1179                 (sb!unix:unix-open namestring mask mode)
1180                 (values nil sb!unix:enoent))
1181           (labels ((open-error (format-control &rest format-arguments)
1182                      (error 'simple-file-error
1183                             :pathname pathname
1184                             :format-control format-control
1185                             :format-arguments format-arguments))
1186                    (vanilla-open-error ()
1187                      (simple-file-perror "error opening ~S" pathname errno)))
1188             (cond ((numberp fd)
1189                    (case direction
1190                      ((:input :output :io)
1191                       (make-fd-stream fd
1192                                       :input input
1193                                       :output output
1194                                       :element-type element-type
1195                                       :file namestring
1196                                       :original original
1197                                       :delete-original delete-original
1198                                       :pathname pathname
1199                                       :input-buffer-p t
1200                                       :auto-close t))
1201                      (:probe
1202                       (let ((stream
1203                              (%make-fd-stream :name namestring
1204                                               :fd fd
1205                                               :pathname pathname
1206                                               :element-type element-type)))
1207                         (close stream)
1208                         stream))))
1209                   ((eql errno sb!unix:enoent)
1210                    (case if-does-not-exist
1211                      (:error (vanilla-open-error))
1212                      (:create
1213                       (open-error "~@<The path ~2I~_~S ~I~_does not exist.~:>"
1214                                   pathname))
1215                      (t nil)))
1216                   ((and (eql errno sb!unix:eexist) if-exists)
1217                    nil)
1218                   (t
1219                    (vanilla-open-error)))))))))
1220 \f
1221 ;;;; initialization
1222
1223 ;;; the stream connected to the controlling terminal, or NIL if there is none
1224 (defvar *tty*)
1225
1226 ;;; the stream connected to the standard input (file descriptor 0)
1227 (defvar *stdin*)
1228
1229 ;;; the stream connected to the standard output (file descriptor 1)
1230 (defvar *stdout*)
1231
1232 ;;; the stream connected to the standard error output (file descriptor 2)
1233 (defvar *stderr*)
1234
1235 ;;; This is called when the cold load is first started up, and may also
1236 ;;; be called in an attempt to recover from nested errors.
1237 (defun stream-cold-init-or-reset ()
1238   (stream-reinit)
1239   (setf *terminal-io* (make-synonym-stream '*tty*))
1240   (setf *standard-output* (make-synonym-stream '*stdout*))
1241   (setf *standard-input*
1242         (#!-high-security
1243          ;; FIXME: Why is *STANDARD-INPUT* a TWO-WAY-STREAM? ANSI says
1244          ;; it's an input stream.
1245          make-two-way-stream
1246          #!+high-security
1247          %make-two-way-stream (make-synonym-stream '*stdin*)
1248                              *standard-output*))
1249   (setf *error-output* (make-synonym-stream '*stderr*))
1250   (setf *query-io* (make-synonym-stream '*terminal-io*))
1251   (setf *debug-io* *query-io*)
1252   (setf *trace-output* *standard-output*)
1253   (values))
1254
1255 ;;; This is called whenever a saved core is restarted.
1256 (defun stream-reinit ()
1257   (setf *available-buffers* nil)
1258   (setf *stdin*
1259         (make-fd-stream 0 :name "standard input" :input t :buffering :line))
1260   (setf *stdout*
1261         (make-fd-stream 1 :name "standard output" :output t :buffering :line))
1262   (setf *stderr*
1263         (make-fd-stream 2 :name "standard error" :output t :buffering :line))
1264   (let ((tty (sb!unix:unix-open "/dev/tty" sb!unix:o_rdwr #o666)))
1265     (if tty
1266         (setf *tty*
1267               (make-fd-stream tty
1268                               :name "the terminal"
1269                               :input t
1270                               :output t
1271                               :buffering :line
1272                               :auto-close t))
1273         (setf *tty* (make-two-way-stream *stdin* *stdout*))))
1274   (values))
1275 \f
1276 ;;;; miscellany
1277
1278 ;;; the Unix way to beep
1279 (defun beep (stream)
1280   (write-char (code-char bell-char-code) stream)
1281   (finish-output stream))
1282
1283 ;;; This is kind of like FILE-POSITION, but is an internal hack used
1284 ;;; by the filesys stuff to get and set the file name.
1285 ;;;
1286 ;;; FIXME: misleading name, screwy interface
1287 (defun file-name (stream &optional new-name)
1288   (when (typep stream 'file-stream)
1289       (cond (new-name
1290              (setf (fd-stream-pathname stream) new-name)
1291              (setf (fd-stream-file stream)
1292                    (unix-namestring new-name nil))
1293              t)
1294             (t
1295              (fd-stream-pathname stream)))))
1296 \f
1297 ;;;; international character support (which is trivial for our simple
1298 ;;;; character sets)
1299
1300 ;;;; (Those who do Lisp only in English might not remember that ANSI
1301 ;;;; requires these functions to be exported from package
1302 ;;;; COMMON-LISP.)
1303
1304 (defun file-string-length (stream object)
1305   (declare (type (or string character) object) (type file-stream stream))
1306   #!+sb-doc
1307   "Return the delta in STREAM's FILE-POSITION that would be caused by writing
1308    OBJECT to STREAM. Non-trivial only in implementations that support
1309    international character sets."
1310   (declare (ignore stream))
1311   (etypecase object
1312     (character 1)
1313     (string (length object))))
1314
1315 (defun stream-external-format (stream)
1316   (declare (type file-stream stream) (ignore stream))
1317   #!+sb-doc
1318   "Return :DEFAULT."
1319   :default)