src/code/fd-stream.lisp

   1 ;;;; streams for UNIX file descriptors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; buffer manipulation routines
  15
  16 ;;; FIXME: Is it really good to maintain this pool separate from the
  17 ;;; GC and the C malloc logic?
  18 (defvar *available-buffers* ()
  19   #!+sb-doc
  20   "List of available buffers. Each buffer is an sap pointing to
  21   bytes-per-buffer of memory.")
  22
  23 (defconstant bytes-per-buffer (* 4 1024)
  24   #!+sb-doc
  25   "Number of bytes per buffer.")
  26
  27 ;;; Return the next available buffer, creating one if necessary.
  28 #!-sb-fluid (declaim (inline next-available-buffer))
  29 (defun next-available-buffer ()
  30   (if *available-buffers*
  31       (pop *available-buffers*)
  32       (allocate-system-memory bytes-per-buffer)))
  33 \f
  34 ;;;; the FILE-STREAM structure
  35
  36 (defstruct (file-stream
  37             (:constructor %make-fd-stream)
  38             ;; KLUDGE: in an ideal world, maybe we'd rewrite
  39             ;; everything to use FILE-STREAM rather than simply
  40             ;; providing this hack for compatibility with the old
  41             ;; code.  However, CVS doesn't deal terribly well with
  42             ;; file renaming, so for now we use this
  43             ;; backward-compatibility feature.
  44             (:conc-name fd-stream-)
  45             (:predicate fd-stream-p)
  46             (:include ansi-stream
  47                       (misc #'fd-stream-misc-routine))
  48             (:copier nil))
  49
  50   ;; the name of this stream
  51   (name nil)
  52   ;; the file this stream is for
  53   (file nil)
  54   ;; the backup file namestring for the old file, for :IF-EXISTS
  55   ;; :RENAME or :RENAME-AND-DELETE.
  56   (original nil :type (or simple-string null))
  57   (delete-original nil)       ; for :if-exists :rename-and-delete
  58   ;;; the number of bytes per element
  59   (element-size 1 :type index)
  60   ;; the type of element being transfered
  61   (element-type 'base-char)
  62   ;; the Unix file descriptor
  63   (fd -1 :type fixnum)
  64   ;; controls when the output buffer is flushed
  65   (buffering :full :type (member :full :line :none))
  66   ;; character position (if known)
  67   (char-pos nil :type (or index null))
  68   ;; T if input is waiting on FD. :EOF if we hit EOF.
  69   (listen nil :type (member nil t :eof))
  70
  71   ;; the input buffer
  72   (unread nil)
  73   (ibuf-sap nil :type (or system-area-pointer null))
  74   (ibuf-length nil :type (or index null))
  75   (ibuf-head 0 :type index)
  76   (ibuf-tail 0 :type index)
  77
  78   ;; the output buffer
  79   (obuf-sap nil :type (or system-area-pointer null))
  80   (obuf-length nil :type (or index null))
  81   (obuf-tail 0 :type index)
  82
  83   ;; output flushed, but not written due to non-blocking io?
  84   (output-later nil)
  85   (handler nil)
  86   ;; timeout specified for this stream, or NIL if none
  87   (timeout nil :type (or index null))
  88   ;; pathname of the file this stream is opened to (returned by PATHNAME)
  89   (pathname nil :type (or pathname null)))
  90 (def!method print-object ((fd-stream file-stream) stream)
  91   (declare (type stream stream))
  92   (print-unreadable-object (fd-stream stream :type t :identity t)
  93     (format stream "for ~S" (fd-stream-name fd-stream))))
  94 \f
  95 ;;;; output routines and related noise
  96
  97 (defvar *output-routines* ()
  98   #!+sb-doc
  99   "List of all available output routines. Each element is a list of the
 100   element-type output, the kind of buffering, the function name, and the number
 101   of bytes per element.")
 102
 103 ;;; common idioms for reporting low-level stream and file problems
 104 (defun simple-stream-perror (note-format stream errno)
 105   (error 'simple-stream-error
 106          :stream stream
 107          :format-control "~@<~?: ~2I~_~A~:>"
 108          :format-arguments (list note-format (list stream) (strerror errno))))
 109 (defun simple-file-perror (note-format pathname errno)
 110   (error 'simple-file-error
 111          :pathname pathname
 112          :format-control "~@<~?: ~2I~_~A~:>"
 113          :format-arguments
 114          (list note-format (list pathname) (strerror errno))))
 115
 116 ;;; This is called by the server when we can write to the given file
 117 ;;; descriptor. Attempt to write the data again. If it worked, remove
 118 ;;; the data from the OUTPUT-LATER list. If it didn't work, something
 119 ;;; is wrong.
 120 (defun frob-output-later (stream)
 121   (let* ((stuff (pop (fd-stream-output-later stream)))
 122          (base (car stuff))
 123          (start (cadr stuff))
 124          (end (caddr stuff))
 125          (reuse-sap (cadddr stuff))
 126          (length (- end start)))
 127     (declare (type index start end length))
 128     (multiple-value-bind (count errno)
 129         (sb!unix:unix-write (fd-stream-fd stream)
 130                             base
 131                             start
 132                             length)
 133       (cond ((not count)
 134              (if (= errno sb!unix:ewouldblock)
 135                  (error "Write would have blocked, but SERVER told us to go.")
 136                  (simple-stream-perror "couldn't write to ~S" stream errno)))
 137             ((eql count length) ; Hot damn, it worked.
 138              (when reuse-sap
 139                (push base *available-buffers*)))
 140             ((not (null count)) ; sorta worked..
 141              (push (list base
 142                          (the index (+ start count))
 143                          end)
 144                    (fd-stream-output-later stream))))))
 145   (unless (fd-stream-output-later stream)
 146     (sb!sys:remove-fd-handler (fd-stream-handler stream))
 147     (setf (fd-stream-handler stream) nil)))
 148
 149 ;;; Arange to output the string when we can write on the file descriptor.
 150 (defun output-later (stream base start end reuse-sap)
 151   (cond ((null (fd-stream-output-later stream))
 152          (setf (fd-stream-output-later stream)
 153                (list (list base start end reuse-sap)))
 154          (setf (fd-stream-handler stream)
 155                (sb!sys:add-fd-handler (fd-stream-fd stream)
 156                                       :output
 157                                       (lambda (fd)
 158                                         (declare (ignore fd))
 159                                         (frob-output-later stream)))))
 160         (t
 161          (nconc (fd-stream-output-later stream)
 162                 (list (list base start end reuse-sap)))))
 163   (when reuse-sap
 164     (let ((new-buffer (next-available-buffer)))
 165       (setf (fd-stream-obuf-sap stream) new-buffer)
 166       (setf (fd-stream-obuf-length stream) bytes-per-buffer))))
 167
 168 ;;; Output the given noise. Check to see whether there are any pending
 169 ;;; writes. If so, just queue this one. Otherwise, try to write it. If
 170 ;;; this would block, queue it.
 171 (defun frob-output (stream base start end reuse-sap)
 172   (declare (type file-stream stream)
 173            (type (or system-area-pointer (simple-array * (*))) base)
 174            (type index start end))
 175   (if (not (null (fd-stream-output-later stream))) ; something buffered.
 176       (progn
 177         (output-later stream base start end reuse-sap)
 178         ;; ### check to see whether any of this noise can be output
 179         )
 180       (let ((length (- end start)))
 181         (multiple-value-bind (count errno)
 182             (sb!unix:unix-write (fd-stream-fd stream) base start length)
 183           (cond ((not count)
 184                  (if (= errno sb!unix:ewouldblock)
 185                      (output-later stream base start end reuse-sap)
 186                      (simple-stream-perror "couldn't write to ~S"
 187                                            stream
 188                                            errno)))
 189                 ((not (eql count length))
 190                  (output-later stream base (the index (+ start count))
 191                                end reuse-sap)))))))
 192
 193 ;;; Flush any data in the output buffer.
 194 (defun flush-output-buffer (stream)
 195   (let ((length (fd-stream-obuf-tail stream)))
 196     (unless (= length 0)
 197       (frob-output stream (fd-stream-obuf-sap stream) 0 length t)
 198       (setf (fd-stream-obuf-tail stream) 0))))
 199
 200 ;;; Define output routines that output numbers SIZE bytes long for the
 201 ;;; given bufferings. Use BODY to do the actual output.
 202 (defmacro def-output-routines ((name-fmt size &rest bufferings) &body body)
 203   (declare (optimize (speed 1)))
 204   (cons 'progn
 205         (mapcar
 206             (lambda (buffering)
 207               (let ((function
 208                      (intern (let ((*print-case* :upcase))
 209                                (format nil name-fmt (car buffering))))))
 210                 `(progn
 211                    (defun ,function (stream byte)
 212                      ,(unless (eq (car buffering) :none)
 213                         `(when (< (fd-stream-obuf-length stream)
 214                                   (+ (fd-stream-obuf-tail stream)
 215                                      ,size))
 216                            (flush-output-buffer stream)))
 217                      ,@body
 218                      (incf (fd-stream-obuf-tail stream) ,size)
 219                      ,(ecase (car buffering)
 220                         (:none
 221                          `(flush-output-buffer stream))
 222                         (:line
 223                          `(when (eq (char-code byte) (char-code #\Newline))
 224                             (flush-output-buffer stream)))
 225                         (:full
 226                          ))
 227                      (values))
 228                    (setf *output-routines*
 229                          (nconc *output-routines*
 230                                 ',(mapcar
 231                                    (lambda (type)
 232                                      (list type
 233                                            (car buffering)
 234                                            function
 235                                            size))
 236                                    (cdr buffering)))))))
 237             bufferings)))
 238
 239 (def-output-routines ("OUTPUT-CHAR-~A-BUFFERED"
 240                       1
 241                       (:none character)
 242                       (:line character)
 243                       (:full character))
 244   (if (and (base-char-p byte) (char= byte #\Newline))
 245       (setf (fd-stream-char-pos stream) 0)
 246       (incf (fd-stream-char-pos stream)))
 247   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 248         (char-code byte)))
 249
 250 (def-output-routines ("OUTPUT-UNSIGNED-BYTE-~A-BUFFERED"
 251                       1
 252                       (:none (unsigned-byte 8))
 253                       (:full (unsigned-byte 8)))
 254   (setf (sap-ref-8 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 255         byte))
 256
 257 (def-output-routines ("OUTPUT-SIGNED-BYTE-~A-BUFFERED"
 258                       1
 259                       (:none (signed-byte 8))
 260                       (:full (signed-byte 8)))
 261   (setf (signed-sap-ref-8 (fd-stream-obuf-sap stream)
 262                           (fd-stream-obuf-tail stream))
 263         byte))
 264
 265 (def-output-routines ("OUTPUT-UNSIGNED-SHORT-~A-BUFFERED"
 266                       2
 267                       (:none (unsigned-byte 16))
 268                       (:full (unsigned-byte 16)))
 269   (setf (sap-ref-16 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 270         byte))
 271
 272 (def-output-routines ("OUTPUT-SIGNED-SHORT-~A-BUFFERED"
 273                       2
 274                       (:none (signed-byte 16))
 275                       (:full (signed-byte 16)))
 276   (setf (signed-sap-ref-16 (fd-stream-obuf-sap stream)
 277                            (fd-stream-obuf-tail stream))
 278         byte))
 279
 280 (def-output-routines ("OUTPUT-UNSIGNED-LONG-~A-BUFFERED"
 281                       4
 282                       (:none (unsigned-byte 32))
 283                       (:full (unsigned-byte 32)))
 284   (setf (sap-ref-32 (fd-stream-obuf-sap stream) (fd-stream-obuf-tail stream))
 285         byte))
 286
 287 (def-output-routines ("OUTPUT-SIGNED-LONG-~A-BUFFERED"
 288                       4
 289                       (:none (signed-byte 32))
 290                       (:full (signed-byte 32)))
 291   (setf (signed-sap-ref-32 (fd-stream-obuf-sap stream)
 292                            (fd-stream-obuf-tail stream))
 293         byte))
 294
 295 ;;; Do the actual output. If there is space to buffer the string,
 296 ;;; buffer it. If the string would normally fit in the buffer, but
 297 ;;; doesn't because of other stuff in the buffer, flush the old noise
 298 ;;; out of the buffer and put the string in it. Otherwise we have a
 299 ;;; very long string, so just send it directly (after flushing the
 300 ;;; buffer, of course).
 301 (defun output-raw-bytes (fd-stream thing &optional start end)
 302   #!+sb-doc
 303   "Output THING to FD-STREAM. THING can be any kind of vector or a SAP. If
 304   THING is a SAP, END must be supplied (as length won't work)."
 305   (let ((start (or start 0))
 306         (end (or end (length (the (simple-array * (*)) thing)))))
 307     (declare (type index start end))
 308     (let* ((len (fd-stream-obuf-length fd-stream))
 309            (tail (fd-stream-obuf-tail fd-stream))
 310            (space (- len tail))
 311            (bytes (- end start))
 312            (newtail (+ tail bytes)))
 313       (cond ((minusp bytes) ; error case
 314              (error ":END before :START!"))
 315             ((zerop bytes)) ; easy case
 316             ((<= bytes space)
 317              (if (system-area-pointer-p thing)
 318                  (system-area-copy thing
 319                                    (* start sb!vm:n-byte-bits)
 320                                    (fd-stream-obuf-sap fd-stream)
 321                                    (* tail sb!vm:n-byte-bits)
 322                                    (* bytes sb!vm:n-byte-bits))
 323                  ;; FIXME: There should be some type checking somewhere to
 324                  ;; verify that THING here is a vector, not just <not a SAP>.
 325                  (copy-to-system-area thing
 326                                       (+ (* start sb!vm:n-byte-bits)
 327                                          (* sb!vm:vector-data-offset
 328                                             sb!vm:n-word-bits))
 329                                       (fd-stream-obuf-sap fd-stream)
 330                                       (* tail sb!vm:n-byte-bits)
 331                                       (* bytes sb!vm:n-byte-bits)))
 332              (setf (fd-stream-obuf-tail fd-stream) newtail))
 333             ((<= bytes len)
 334              (flush-output-buffer fd-stream)
 335              (if (system-area-pointer-p thing)
 336                  (system-area-copy thing
 337                                    (* start sb!vm:n-byte-bits)
 338                                    (fd-stream-obuf-sap fd-stream)
 339                                    0
 340                                    (* bytes sb!vm:n-byte-bits))
 341                  ;; FIXME: There should be some type checking somewhere to
 342                  ;; verify that THING here is a vector, not just <not a SAP>.
 343                  (copy-to-system-area thing
 344                                       (+ (* start sb!vm:n-byte-bits)
 345                                          (* sb!vm:vector-data-offset
 346                                             sb!vm:n-word-bits))
 347                                       (fd-stream-obuf-sap fd-stream)
 348                                       0
 349                                       (* bytes sb!vm:n-byte-bits)))
 350              (setf (fd-stream-obuf-tail fd-stream) bytes))
 351             (t
 352              (flush-output-buffer fd-stream)
 353              (frob-output fd-stream thing start end nil))))))
 354
 355 ;;; the routine to use to output a string. If the stream is
 356 ;;; unbuffered, slam the string down the file descriptor, otherwise
 357 ;;; use OUTPUT-RAW-BYTES to buffer the string. Update charpos by
 358 ;;; checking to see where the last newline was.
 359 ;;;
 360 ;;; Note: some bozos (the FASL dumper) call write-string with things
 361 ;;; other than strings. Therefore, we must make sure we have a string
 362 ;;; before calling POSITION on it.
 363 ;;; KLUDGE: It would be better to fix the bozos instead of trying to
 364 ;;; cover for them here. -- WHN 20000203
 365 (defun fd-sout (stream thing start end)
 366   (let ((start (or start 0))
 367         (end (or end (length (the vector thing)))))
 368     (declare (fixnum start end))
 369     (if (stringp thing)
 370         (let ((last-newline (and (find #\newline (the simple-string thing)
 371                                        :start start :end end)
 372                                  ;; FIXME why do we need both calls?
 373                                  ;; Is find faster forwards than
 374                                  ;; position is backwards?
 375                                  (position #\newline (the simple-string thing)
 376                                            :from-end t
 377                                            :start start
 378                                            :end end))))
 379           (ecase (fd-stream-buffering stream)
 380             (:full
 381              (output-raw-bytes stream thing start end))
 382             (:line
 383              (output-raw-bytes stream thing start end)
 384              (when last-newline
 385                (flush-output-buffer stream)))
 386             (:none
 387              (frob-output stream thing start end nil)))
 388           (if last-newline
 389               (setf (fd-stream-char-pos stream)
 390                     (- end last-newline 1))
 391               (incf (fd-stream-char-pos stream)
 392                     (- end start))))
 393         (ecase (fd-stream-buffering stream)
 394           ((:line :full)
 395            (output-raw-bytes stream thing start end))
 396           (:none
 397            (frob-output stream thing start end nil))))))
 398
 399 ;;; Find an output routine to use given the type and buffering. Return
 400 ;;; as multiple values the routine, the real type transfered, and the
 401 ;;; number of bytes per element.
 402 (defun pick-output-routine (type buffering)
 403   (dolist (entry *output-routines*)
 404     (when (and (subtypep type (car entry))
 405                (eq buffering (cadr entry)))
 406       (return (values (symbol-function (caddr entry))
 407                       (car entry)
 408                       (cadddr entry))))))
 409 \f
 410 ;;;; input routines and related noise
 411
 412 ;;; a list of all available input routines. Each element is a list of
 413 ;;; the element-type input, the function name, and the number of bytes
 414 ;;; per element.
 415 (defvar *input-routines* ())
 416
 417 ;;; Fill the input buffer, and return the first character. Throw to
 418 ;;; EOF-INPUT-CATCHER if the eof was reached. Drop into SYSTEM:SERVER
 419 ;;; if necessary.
 420 (defun frob-input (stream)
 421   (let ((fd (fd-stream-fd stream))
 422         (ibuf-sap (fd-stream-ibuf-sap stream))
 423         (buflen (fd-stream-ibuf-length stream))
 424         (head (fd-stream-ibuf-head stream))
 425         (tail (fd-stream-ibuf-tail stream)))
 426     (declare (type index head tail))
 427     (unless (zerop head)
 428       (cond ((eql head tail)
 429              (setf head 0)
 430              (setf tail 0)
 431              (setf (fd-stream-ibuf-head stream) 0)
 432              (setf (fd-stream-ibuf-tail stream) 0))
 433             (t
 434              (decf tail head)
 435              (system-area-copy ibuf-sap (* head sb!vm:n-byte-bits)
 436                                ibuf-sap 0 (* tail sb!vm:n-byte-bits))
 437              (setf head 0)
 438              (setf (fd-stream-ibuf-head stream) 0)
 439              (setf (fd-stream-ibuf-tail stream) tail))))
 440     (setf (fd-stream-listen stream) nil)
 441     (multiple-value-bind (count errno)
 442         ;; FIXME: Judging from compiler warnings, this WITH-ALIEN form expands
 443         ;; into something which uses the not-yet-defined type
 444         ;;   (SB!ALIEN-INTERNALS:ALIEN (* (SB!ALIEN:STRUCT SB!UNIX:FD-SET))).
 445         ;; This is probably inefficient and unsafe and generally bad, so
 446         ;; try to find some way to make that type known before
 447         ;; this is compiled.
 448         (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set)))
 449           (sb!unix:fd-zero read-fds)
 450           (sb!unix:fd-set fd read-fds)
 451           (sb!unix:unix-fast-select (1+ fd)
 452                                     (sb!alien:addr read-fds)
 453                                     nil
 454                                     nil
 455                                     0
 456                                     0))
 457       (case count
 458         (1)
 459         (0
 460          (unless (sb!sys:wait-until-fd-usable
 461                   fd :input (fd-stream-timeout stream))
 462            (error 'io-timeout :stream stream :direction :read)))
 463         (t
 464          (simple-stream-perror "couldn't check whether ~S is readable"
 465                                stream
 466                                errno))))
 467     (multiple-value-bind (count errno)
 468         (sb!unix:unix-read fd
 469                            (sb!sys:int-sap (+ (sb!sys:sap-int ibuf-sap) tail))
 470                            (- buflen tail))
 471       (cond ((null count)
 472              (if (eql errno sb!unix:ewouldblock)
 473                  (progn
 474                    (unless (sb!sys:wait-until-fd-usable
 475                             fd :input (fd-stream-timeout stream))
 476                      (error 'io-timeout :stream stream :direction :read))
 477                    (frob-input stream))
 478                  (simple-stream-perror "couldn't read from ~S" stream errno)))
 479             ((zerop count)
 480              (setf (fd-stream-listen stream) :eof)
 481              (/show0 "THROWing EOF-INPUT-CATCHER")
 482              (throw 'eof-input-catcher nil))
 483             (t
 484              (incf (fd-stream-ibuf-tail stream) count))))))
 485
 486 ;;; Make sure there are at least BYTES number of bytes in the input
 487 ;;; buffer. Keep calling FROB-INPUT until that condition is met.
 488 (defmacro input-at-least (stream bytes)
 489   (let ((stream-var (gensym))
 490         (bytes-var (gensym)))
 491     `(let ((,stream-var ,stream)
 492            (,bytes-var ,bytes))
 493        (loop
 494          (when (>= (- (fd-stream-ibuf-tail ,stream-var)
 495                       (fd-stream-ibuf-head ,stream-var))
 496                    ,bytes-var)
 497            (return))
 498          (frob-input ,stream-var)))))
 499
 500 ;;; a macro to wrap around all input routines to handle EOF-ERROR noise
 501 (defmacro input-wrapper ((stream bytes eof-error eof-value) &body read-forms)
 502   (let ((stream-var (gensym))
 503         (element-var (gensym)))
 504     `(let ((,stream-var ,stream))
 505        (if (fd-stream-unread ,stream-var)
 506            (prog1
 507                (fd-stream-unread ,stream-var)
 508              (setf (fd-stream-unread ,stream-var) nil)
 509              (setf (fd-stream-listen ,stream-var) nil))
 510            (let ((,element-var
 511                   (catch 'eof-input-catcher
 512                     (input-at-least ,stream-var ,bytes)
 513                     ,@read-forms)))
 514              (cond (,element-var
 515                     (incf (fd-stream-ibuf-head ,stream-var) ,bytes)
 516                     ,element-var)
 517                    (t
 518                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
 519
 520 (defmacro def-input-routine (name
 521                              (type size sap head)
 522                              &rest body)
 523   `(progn
 524      (defun ,name (stream eof-error eof-value)
 525        (input-wrapper (stream ,size eof-error eof-value)
 526          (let ((,sap (fd-stream-ibuf-sap stream))
 527                (,head (fd-stream-ibuf-head stream)))
 528            ,@body)))
 529      (setf *input-routines*
 530            (nconc *input-routines*
 531                   (list (list ',type ',name ',size))))))
 532
 533 ;;; STREAM-IN routine for reading a string char
 534 (def-input-routine input-character
 535                    (character 1 sap head)
 536   (code-char (sap-ref-8 sap head)))
 537
 538 ;;; STREAM-IN routine for reading an unsigned 8 bit number
 539 (def-input-routine input-unsigned-8bit-byte
 540                    ((unsigned-byte 8) 1 sap head)
 541   (sap-ref-8 sap head))
 542
 543 ;;; STREAM-IN routine for reading a signed 8 bit number
 544 (def-input-routine input-signed-8bit-number
 545                    ((signed-byte 8) 1 sap head)
 546   (signed-sap-ref-8 sap head))
 547
 548 ;;; STREAM-IN routine for reading an unsigned 16 bit number
 549 (def-input-routine input-unsigned-16bit-byte
 550                    ((unsigned-byte 16) 2 sap head)
 551   (sap-ref-16 sap head))
 552
 553 ;;; STREAM-IN routine for reading a signed 16 bit number
 554 (def-input-routine input-signed-16bit-byte
 555                    ((signed-byte 16) 2 sap head)
 556   (signed-sap-ref-16 sap head))
 557
 558 ;;; STREAM-IN routine for reading a unsigned 32 bit number
 559 (def-input-routine input-unsigned-32bit-byte
 560                    ((unsigned-byte 32) 4 sap head)
 561   (sap-ref-32 sap head))
 562
 563 ;;; STREAM-IN routine for reading a signed 32 bit number
 564 (def-input-routine input-signed-32bit-byte
 565                    ((signed-byte 32) 4 sap head)
 566   (signed-sap-ref-32 sap head))
 567
 568 ;;; Find an input routine to use given the type. Return as multiple
 569 ;;; values the routine, the real type transfered, and the number of
 570 ;;; bytes per element.
 571 (defun pick-input-routine (type)
 572   (dolist (entry *input-routines*)
 573     (when (subtypep type (car entry))
 574       (return (values (symbol-function (cadr entry))
 575                       (car entry)
 576                       (caddr entry))))))
 577
 578 ;;; Return a string constructed from SAP, START, and END.
 579 (defun string-from-sap (sap start end)
 580   (declare (type index start end))
 581   (let* ((length (- end start))
 582          (string (make-string length)))
 583     (copy-from-system-area sap (* start sb!vm:n-byte-bits)
 584                            string (* sb!vm:vector-data-offset
 585                                      sb!vm:n-word-bits)
 586                            (* length sb!vm:n-byte-bits))
 587     string))
 588
 589 ;;; the N-BIN method for FD-STREAMs
 590 ;;;
 591 ;;; Note that this blocks in UNIX-READ. It is generally used where
 592 ;;; there is a definite amount of reading to be done, so blocking
 593 ;;; isn't too problematical.
 594 (defun fd-stream-read-n-bytes (stream buffer start requested eof-error-p)
 595   (declare (type file-stream stream))
 596   (declare (type index start requested))
 597   (do ((total-copied 0))
 598       (nil)
 599     (declare (type index total-copied))
 600     (let* ((remaining-request (- requested total-copied))
 601            (head (fd-stream-ibuf-head stream))
 602            (tail (fd-stream-ibuf-tail stream))
 603            (available (- tail head))
 604            (n-this-copy (min remaining-request available))
 605            (this-start (+ start total-copied))
 606            (this-end (+ this-start n-this-copy))
 607            (sap (fd-stream-ibuf-sap stream)))
 608       (declare (type index remaining-request head tail available))
 609       (declare (type index n-this-copy))
 610       ;; Copy data from stream buffer into user's buffer.
 611       (%byte-blt sap head buffer this-start this-end)
 612       (incf (fd-stream-ibuf-head stream) n-this-copy)
 613       (incf total-copied n-this-copy)
 614       ;; Maybe we need to refill the stream buffer.
 615       (cond (;; If there were enough data in the stream buffer, we're done.
 616              (= total-copied requested)
 617              (return total-copied))
 618             (;; If EOF, we're done in another way.
 619              (zerop (refill-fd-stream-buffer stream))
 620              (if eof-error-p
 621                  (error 'end-of-file :stream stream)
 622                  (return total-copied)))
 623             ;; Otherwise we refilled the stream buffer, so fall
 624             ;; through into another pass of the loop.
 625             ))))
 626
 627 ;;; Try to refill the stream buffer. Return the number of bytes read.
 628 ;;; (For EOF, the return value will be zero, otherwise positive.)
 629 (defun refill-fd-stream-buffer (stream)
 630   ;; We don't have any logic to preserve leftover bytes in the buffer,
 631   ;; so we should only be called when the buffer is empty.
 632   (aver (= (fd-stream-ibuf-head stream) (fd-stream-ibuf-tail stream)))
 633   (multiple-value-bind (count err)
 634       (sb!unix:unix-read (fd-stream-fd stream)
 635                          (fd-stream-ibuf-sap stream)
 636                          (fd-stream-ibuf-length stream))
 637     (declare (type (or index null) count))
 638     (when (null count)
 639       (simple-stream-perror "couldn't read from ~S" stream err))
 640     (setf (fd-stream-listen stream) nil
 641           (fd-stream-ibuf-head stream) 0
 642           (fd-stream-ibuf-tail stream) count)
 643     count))
 644 \f
 645 ;;;; utility functions (misc routines, etc)
 646
 647 ;;; Fill in the various routine slots for the given type. INPUT-P and
 648 ;;; OUTPUT-P indicate what slots to fill. The buffering slot must be
 649 ;;; set prior to calling this routine.
 650 (defun set-fd-stream-routines (fd-stream type input-p output-p buffer-p)
 651   (let ((target-type (case type
 652                        ((:default unsigned-byte)
 653                         '(unsigned-byte 8))
 654                        (signed-byte
 655                         '(signed-byte 8))
 656                        (t
 657                         type)))
 658         (input-type nil)
 659         (output-type nil)
 660         (input-size nil)
 661         (output-size nil))
 662
 663     (when (fd-stream-obuf-sap fd-stream)
 664       (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 665       (setf (fd-stream-obuf-sap fd-stream) nil))
 666     (when (fd-stream-ibuf-sap fd-stream)
 667       (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 668       (setf (fd-stream-ibuf-sap fd-stream) nil))
 669
 670     (when input-p
 671       (multiple-value-bind (routine type size)
 672           (pick-input-routine target-type)
 673         (unless routine
 674           (error "could not find any input routine for ~S" target-type))
 675         (setf (fd-stream-ibuf-sap fd-stream) (next-available-buffer))
 676         (setf (fd-stream-ibuf-length fd-stream) bytes-per-buffer)
 677         (setf (fd-stream-ibuf-tail fd-stream) 0)
 678         (if (subtypep type 'character)
 679             (setf (fd-stream-in fd-stream) routine
 680                   (fd-stream-bin fd-stream) #'ill-bin)
 681             (setf (fd-stream-in fd-stream) #'ill-in
 682                   (fd-stream-bin fd-stream) routine))
 683         (when (eql size 1)
 684           (setf (fd-stream-n-bin fd-stream) #'fd-stream-read-n-bytes)
 685           (when buffer-p
 686             (setf (ansi-stream-in-buffer fd-stream)
 687                   (make-array +ansi-stream-in-buffer-length+
 688                               :element-type '(unsigned-byte 8)))))
 689         (setf input-size size)
 690         (setf input-type type)))
 691
 692     (when output-p
 693       (multiple-value-bind (routine type size)
 694           (pick-output-routine target-type (fd-stream-buffering fd-stream))
 695         (unless routine
 696           (error "could not find any output routine for ~S buffered ~S"
 697                  (fd-stream-buffering fd-stream)
 698                  target-type))
 699         (setf (fd-stream-obuf-sap fd-stream) (next-available-buffer))
 700         (setf (fd-stream-obuf-length fd-stream) bytes-per-buffer)
 701         (setf (fd-stream-obuf-tail fd-stream) 0)
 702         (if (subtypep type 'character)
 703           (setf (fd-stream-out fd-stream) routine
 704                 (fd-stream-bout fd-stream) #'ill-bout)
 705           (setf (fd-stream-out fd-stream)
 706                 (or (if (eql size 1)
 707                       (pick-output-routine 'base-char
 708                                            (fd-stream-buffering fd-stream)))
 709                     #'ill-out)
 710                 (fd-stream-bout fd-stream) routine))
 711         (setf (fd-stream-sout fd-stream)
 712               (if (eql size 1) #'fd-sout #'ill-out))
 713         (setf (fd-stream-char-pos fd-stream) 0)
 714         (setf output-size size)
 715         (setf output-type type)))
 716
 717     (when (and input-size output-size
 718                (not (eq input-size output-size)))
 719       (error "Element sizes for input (~S:~S) and output (~S:~S) differ?"
 720              input-type input-size
 721              output-type output-size))
 722     (setf (fd-stream-element-size fd-stream)
 723           (or input-size output-size))
 724
 725     (setf (fd-stream-element-type fd-stream)
 726           (cond ((equal input-type output-type)
 727                  input-type)
 728                 ((null output-type)
 729                  input-type)
 730                 ((null input-type)
 731                  output-type)
 732                 ((subtypep input-type output-type)
 733                  input-type)
 734                 ((subtypep output-type input-type)
 735                  output-type)
 736                 (t
 737                  (error "Input type (~S) and output type (~S) are unrelated?"
 738                         input-type
 739                         output-type))))))
 740
 741 ;;; Handle miscellaneous operations on FD-STREAM.
 742 (defun fd-stream-misc-routine (fd-stream operation &optional arg1 arg2)
 743   (declare (ignore arg2))
 744   (case operation
 745     (:listen
 746      (or (not (eql (fd-stream-ibuf-head fd-stream)
 747                    (fd-stream-ibuf-tail fd-stream)))
 748          (fd-stream-listen fd-stream)
 749          (setf (fd-stream-listen fd-stream)
 750                (eql (sb!alien:with-alien ((read-fds (sb!alien:struct
 751                                                      sb!unix:fd-set)))
 752                       (sb!unix:fd-zero read-fds)
 753                       (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 754                       (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 755                                                 (sb!alien:addr read-fds)
 756                                                 nil nil 0 0))
 757                     1))))
 758     (:unread
 759      (setf (fd-stream-unread fd-stream) arg1)
 760      (setf (fd-stream-listen fd-stream) t))
 761     (:close
 762      (cond (arg1
 763             ;; We got us an abort on our hands.
 764             (when (fd-stream-handler fd-stream)
 765                   (sb!sys:remove-fd-handler (fd-stream-handler fd-stream))
 766                   (setf (fd-stream-handler fd-stream) nil))
 767             (when (and (fd-stream-file fd-stream)
 768                        (fd-stream-obuf-sap fd-stream))
 769               ;; We can't do anything unless we know what file were
 770               ;; dealing with, and we don't want to do anything
 771               ;; strange unless we were writing to the file.
 772               (if (fd-stream-original fd-stream)
 773                   ;; We have a handle on the original, just revert.
 774                   (multiple-value-bind (okay err)
 775                       (sb!unix:unix-rename (fd-stream-original fd-stream)
 776                                            (fd-stream-file fd-stream))
 777                     (unless okay
 778                       (simple-stream-perror
 779                        "couldn't restore ~S to its original contents"
 780                        fd-stream
 781                        err)))
 782                   ;; We can't restore the original, so nuke that puppy.
 783                   (multiple-value-bind (okay err)
 784                       (sb!unix:unix-unlink (fd-stream-file fd-stream))
 785                     (unless okay
 786                       (error 'simple-file-error
 787                              :pathname (fd-stream-file fd-stream)
 788                              :format-control
 789                              "~@<couldn't remove ~S: ~2I~_~A~:>"
 790                              :format-arguments (list (fd-stream-file fd-stream)
 791                                                      (strerror err))))))))
 792            (t
 793             (fd-stream-misc-routine fd-stream :finish-output)
 794             (when (and (fd-stream-original fd-stream)
 795                        (fd-stream-delete-original fd-stream))
 796               (multiple-value-bind (okay err)
 797                   (sb!unix:unix-unlink (fd-stream-original fd-stream))
 798                 (unless okay
 799                   (error 'simple-file-error
 800                          :pathname (fd-stream-original fd-stream)
 801                          :format-control
 802                          "~@<couldn't delete ~S during close of ~S: ~
 803                           ~2I~_~A~:>"
 804                          :format-arguments
 805                          (list (fd-stream-original fd-stream)
 806                                fd-stream
 807                                (strerror err))))))))
 808      (when (fboundp 'cancel-finalization)
 809        (cancel-finalization fd-stream))
 810      (sb!unix:unix-close (fd-stream-fd fd-stream))
 811      (when (fd-stream-obuf-sap fd-stream)
 812        (push (fd-stream-obuf-sap fd-stream) *available-buffers*)
 813        (setf (fd-stream-obuf-sap fd-stream) nil))
 814      (when (fd-stream-ibuf-sap fd-stream)
 815        (push (fd-stream-ibuf-sap fd-stream) *available-buffers*)
 816        (setf (fd-stream-ibuf-sap fd-stream) nil))
 817      (sb!impl::set-closed-flame fd-stream))
 818     (:clear-input
 819      (setf (fd-stream-unread fd-stream) nil)
 820      (setf (fd-stream-ibuf-head fd-stream) 0)
 821      (setf (fd-stream-ibuf-tail fd-stream) 0)
 822      (catch 'eof-input-catcher
 823        (loop
 824         (let ((count (sb!alien:with-alien ((read-fds (sb!alien:struct
 825                                                       sb!unix:fd-set)))
 826                        (sb!unix:fd-zero read-fds)
 827                        (sb!unix:fd-set (fd-stream-fd fd-stream) read-fds)
 828                        (sb!unix:unix-fast-select (1+ (fd-stream-fd fd-stream))
 829                                                  (sb!alien:addr read-fds)
 830                                                  nil
 831                                                  nil
 832                                                  0
 833                                                  0))))
 834           (cond ((eql count 1)
 835                  (frob-input fd-stream)
 836                  (setf (fd-stream-ibuf-head fd-stream) 0)
 837                  (setf (fd-stream-ibuf-tail fd-stream) 0))
 838                 (t
 839                  (return t)))))))
 840     (:force-output
 841      (flush-output-buffer fd-stream))
 842     (:finish-output
 843      (flush-output-buffer fd-stream)
 844      (do ()
 845          ((null (fd-stream-output-later fd-stream)))
 846        (sb!sys:serve-all-events)))
 847     (:element-type
 848      (fd-stream-element-type fd-stream))
 849     (:interactive-p
 850       ;; FIXME: sb!unix:unix-isatty is undefined.
 851      (sb!unix:unix-isatty (fd-stream-fd fd-stream)))
 852     (:line-length
 853      80)
 854     (:charpos
 855      (fd-stream-char-pos fd-stream))
 856     (:file-length
 857      (unless (fd-stream-file fd-stream)
 858        ;; This is a TYPE-ERROR because ANSI's species FILE-LENGTH
 859        ;; "should signal an error of type TYPE-ERROR if stream is not
 860        ;; a stream associated with a file". Too bad there's no very
 861        ;; appropriate value for the EXPECTED-TYPE slot..
 862        (error 'simple-type-error
 863               :datum fd-stream
 864               :expected-type 'file-stream
 865               :format-control "~S is not a stream associated with a file."
 866               :format-arguments (list fd-stream)))
 867      (multiple-value-bind (okay dev ino mode nlink uid gid rdev size
 868                            atime mtime ctime blksize blocks)
 869          (sb!unix:unix-fstat (fd-stream-fd fd-stream))
 870        (declare (ignore ino nlink uid gid rdev
 871                         atime mtime ctime blksize blocks))
 872        (unless okay
 873          (simple-stream-perror "failed Unix fstat(2) on ~S" fd-stream dev))
 874        (if (zerop mode)
 875            nil
 876            (truncate size (fd-stream-element-size fd-stream)))))
 877     (:file-position
 878      (fd-stream-file-position fd-stream arg1))))
 879
 880 (defun fd-stream-file-position (stream &optional newpos)
 881   (declare (type file-stream stream)
 882            (type (or index (member nil :start :end)) newpos))
 883   (if (null newpos)
 884       (sb!sys:without-interrupts
 885         ;; First, find the position of the UNIX file descriptor in the file.
 886         (multiple-value-bind (posn errno)
 887             (sb!unix:unix-lseek (fd-stream-fd stream) 0 sb!unix:l_incr)
 888           (declare (type (or index null) posn))
 889           (cond ((fixnump posn)
 890                  ;; Adjust for buffered output: If there is any output
 891                  ;; buffered, the *real* file position will be larger
 892                  ;; than reported by lseek() because lseek() obviously
 893                  ;; cannot take into account output we have not sent
 894                  ;; yet.
 895                  (dolist (later (fd-stream-output-later stream))
 896                    (incf posn (- (the index (caddr later))
 897                                  (the index (cadr later)))))
 898                  (incf posn (fd-stream-obuf-tail stream))
 899                  ;; Adjust for unread input: If there is any input
 900                  ;; read from UNIX but not supplied to the user of the
 901                  ;; stream, the *real* file position will smaller than
 902                  ;; reported, because we want to look like the unread
 903                  ;; stuff is still available.
 904                  (decf posn (- (fd-stream-ibuf-tail stream)
 905                                (fd-stream-ibuf-head stream)))
 906                  (when (fd-stream-unread stream)
 907                    (decf posn))
 908                  ;; Divide bytes by element size.
 909                  (truncate posn (fd-stream-element-size stream)))
 910                 ((eq errno sb!unix:espipe)
 911                  nil)
 912                 (t
 913                  (sb!sys:with-interrupts
 914                    (simple-stream-perror "failure in Unix lseek() on ~S"
 915                                          stream
 916                                          errno))))))
 917       (let ((offset 0) origin)
 918         (declare (type index offset))
 919         ;; Make sure we don't have any output pending, because if we
 920         ;; move the file pointer before writing this stuff, it will be
 921         ;; written in the wrong location.
 922         (flush-output-buffer stream)
 923         (do ()
 924             ((null (fd-stream-output-later stream)))
 925           (sb!sys:serve-all-events))
 926         ;; Clear out any pending input to force the next read to go to
 927         ;; the disk.
 928         (setf (fd-stream-unread stream) nil)
 929         (setf (fd-stream-ibuf-head stream) 0)
 930         (setf (fd-stream-ibuf-tail stream) 0)
 931         ;; Trash cached value for listen, so that we check next time.
 932         (setf (fd-stream-listen stream) nil)
 933         ;; Now move it.
 934         (cond ((eq newpos :start)
 935                (setf offset 0 origin sb!unix:l_set))
 936               ((eq newpos :end)
 937                (setf offset 0 origin sb!unix:l_xtnd))
 938               ((typep newpos 'index)
 939                (setf offset (* newpos (fd-stream-element-size stream))
 940                      origin sb!unix:l_set))
 941               (t
 942                (error "invalid position given to FILE-POSITION: ~S" newpos)))
 943         (multiple-value-bind (posn errno)
 944             (sb!unix:unix-lseek (fd-stream-fd stream) offset origin)
 945           (cond ((typep posn 'fixnum)
 946                  t)
 947                 ((eq errno sb!unix:espipe)
 948                  nil)
 949                 (t
 950                  (simple-stream-perror "error in Unix lseek() on ~S"
 951                                        stream
 952                                        errno)))))))
 953 \f
 954 ;;;; creation routines (MAKE-FD-STREAM and OPEN)
 955
 956 ;;; Create a stream for the given Unix file descriptor.
 957 ;;;
 958 ;;; If INPUT is non-NIL, allow input operations. If OUTPUT is non-nil,
 959 ;;; allow output operations. If neither INPUT nor OUTPUT is specified,
 960 ;;; default to allowing input.
 961 ;;;
 962 ;;; ELEMENT-TYPE indicates the element type to use (as for OPEN).
 963 ;;;
 964 ;;; BUFFERING indicates the kind of buffering to use.
 965 ;;;
 966 ;;; TIMEOUT (if true) is the number of seconds to wait for input. If
 967 ;;; NIL (the default), then wait forever. When we time out, we signal
 968 ;;; IO-TIMEOUT.
 969 ;;;
 970 ;;; FILE is the name of the file (will be returned by PATHNAME).
 971 ;;;
 972 ;;; NAME is used to identify the stream when printed.
 973 (defun make-fd-stream (fd
 974                        &key
 975                        (input nil input-p)
 976                        (output nil output-p)
 977                        (element-type 'base-char)
 978                        (buffering :full)
 979                        timeout
 980                        file
 981                        original
 982                        delete-original
 983                        pathname
 984                        input-buffer-p
 985                        (name (if file
 986                                  (format nil "file ~S" file)
 987                                  (format nil "descriptor ~W" fd)))
 988                        auto-close)
 989   (declare (type index fd) (type (or index null) timeout)
 990            (type (member :none :line :full) buffering))
 991   (cond ((not (or input-p output-p))
 992          (setf input t))
 993         ((not (or input output))
 994          (error "File descriptor must be opened either for input or output.")))
 995   (let ((stream (%make-fd-stream :fd fd
 996                                  :name name
 997                                  :file file
 998                                  :original original
 999                                  :delete-original delete-original
1000                                  :pathname pathname
1001                                  :buffering buffering
1002                                  :timeout timeout)))
1003     (set-fd-stream-routines stream element-type input output input-buffer-p)
1004     (when (and auto-close (fboundp 'finalize))
1005       (finalize stream
1006                 (lambda ()
1007                   (sb!unix:unix-close fd)
1008                   #!+sb-show
1009                   (format *terminal-io* "** closed file descriptor ~W **~%"
1010                           fd))))
1011     stream))
1012
1013 ;;; Pick a name to use for the backup file for the :IF-EXISTS
1014 ;;; :RENAME-AND-DELETE and :RENAME options.
1015 (defun pick-backup-name (name)
1016   (declare (type simple-base-string name))
1017   (concatenate 'simple-base-string name ".bak"))
1018
1019 ;;; Ensure that the given arg is one of the given list of valid
1020 ;;; things. Allow the user to fix any problems.
1021 (defun ensure-one-of (item list what)
1022   (unless (member item list)
1023     (error 'simple-type-error
1024            :datum item
1025            :expected-type `(member ,@list)
1026            :format-control "~@<~S is ~_invalid for ~S; ~_need one of~{ ~S~}~:>"
1027            :format-arguments (list item what list))))
1028
1029 ;;; Rename NAMESTRING to ORIGINAL. First, check whether we have write
1030 ;;; access, since we don't want to trash unwritable files even if we
1031 ;;; technically can. We return true if we succeed in renaming.
1032 (defun rename-the-old-one (namestring original)
1033   (unless (sb!unix:unix-access namestring sb!unix:w_ok)
1034     (error "~@<The file ~2I~_~S ~I~_is not writable.~:>" namestring))
1035   (multiple-value-bind (okay err) (sb!unix:unix-rename namestring original)
1036     (if okay
1037         t
1038         (error 'simple-file-error
1039                :pathname namestring
1040                :format-control
1041                "~@<couldn't rename ~2I~_~S ~I~_to ~2I~_~S: ~4I~_~A~:>"
1042                :format-arguments (list namestring original (strerror err))))))
1043
1044 (defun open (filename
1045              &key
1046              (direction :input)
1047              (element-type 'base-char)
1048              (if-exists nil if-exists-given)
1049              (if-does-not-exist nil if-does-not-exist-given)
1050              (external-format :default)
1051              &aux ; Squelch assignment warning.
1052              (direction direction)
1053              (if-does-not-exist if-does-not-exist)
1054              (if-exists if-exists))
1055   #!+sb-doc
1056   "Return a stream which reads from or writes to FILENAME.
1057   Defined keywords:
1058    :DIRECTION - one of :INPUT, :OUTPUT, :IO, or :PROBE
1059    :ELEMENT-TYPE - the type of object to read or write, default BASE-CHAR
1060    :IF-EXISTS - one of :ERROR, :NEW-VERSION, :RENAME, :RENAME-AND-DELETE,
1061                        :OVERWRITE, :APPEND, :SUPERSEDE or NIL
1062    :IF-DOES-NOT-EXIST - one of :ERROR, :CREATE or nil
1063   See the manual for details."
1064
1065   (unless (eq external-format :default)
1066     (error "Any external format other than :DEFAULT isn't recognized."))
1067
1068   ;; First, make sure that DIRECTION is valid.
1069   (ensure-one-of direction
1070                  '(:input :output :io :probe)
1071                  :direction)
1072
1073   ;; Calculate useful stuff.
1074   (multiple-value-bind (input output mask)
1075       (case direction
1076         (:input  (values   t nil sb!unix:o_rdonly))
1077         (:output (values nil   t sb!unix:o_wronly))
1078         (:io     (values   t   t sb!unix:o_rdwr))
1079         (:probe  (values   t nil sb!unix:o_rdonly)))
1080     (declare (type index mask))
1081     (let* ((pathname (merge-pathnames filename))
1082            (namestring
1083             (cond ((unix-namestring pathname input))
1084                   ((and input (eq if-does-not-exist :create))
1085                    (unix-namestring pathname nil)))))
1086       ;; Process if-exists argument if we are doing any output.
1087       (cond (output
1088              (unless if-exists-given
1089                (setf if-exists
1090                      (if (eq (pathname-version pathname) :newest)
1091                          :new-version
1092                          :error)))
1093              (ensure-one-of if-exists
1094                             '(:error :new-version :rename
1095                                      :rename-and-delete :overwrite
1096                                      :append :supersede nil)
1097                             :if-exists)
1098              (case if-exists
1099                ((:error nil)
1100                 (setf mask (logior mask sb!unix:o_excl)))
1101                ((:rename :rename-and-delete)
1102                 (setf mask (logior mask sb!unix:o_creat)))
1103                ((:new-version :supersede)
1104                 (setf mask (logior mask sb!unix:o_trunc)))
1105                (:append
1106                 (setf mask (logior mask sb!unix:o_append)))))
1107             (t
1108              (setf if-exists :ignore-this-arg)))
1109
1110       (unless if-does-not-exist-given
1111         (setf if-does-not-exist
1112               (cond ((eq direction :input) :error)
1113                     ((and output
1114                           (member if-exists '(:overwrite :append)))
1115                      :error)
1116                     ((eq direction :probe)
1117                      nil)
1118                     (t
1119                      :create))))
1120       (ensure-one-of if-does-not-exist
1121                      '(:error :create nil)
1122                      :if-does-not-exist)
1123       (if (eq if-does-not-exist :create)
1124         (setf mask (logior mask sb!unix:o_creat)))
1125
1126       (let ((original (if (member if-exists
1127                                   '(:rename :rename-and-delete))
1128                           (pick-backup-name namestring)))
1129             (delete-original (eq if-exists :rename-and-delete))
1130             (mode #o666))
1131         (when original
1132           ;; We are doing a :RENAME or :RENAME-AND-DELETE. Determine
1133           ;; whether the file already exists, make sure the original
1134           ;; file is not a directory, and keep the mode.
1135           (let ((exists
1136                  (and namestring
1137                       (multiple-value-bind (okay err/dev inode orig-mode)
1138                           (sb!unix:unix-stat namestring)
1139                         (declare (ignore inode)
1140                                  (type (or index null) orig-mode))
1141                         (cond
1142                          (okay
1143                           (when (and output (= (logand orig-mode #o170000)
1144                                                #o40000))
1145                             (error 'simple-file-error
1146                                    :pathname namestring
1147                                    :format-control
1148                                    "can't open ~S for output: is a directory"
1149                                    :format-arguments (list namestring)))
1150                           (setf mode (logand orig-mode #o777))
1151                           t)
1152                          ((eql err/dev sb!unix:enoent)
1153                           nil)
1154                          (t
1155                           (simple-file-perror "can't find ~S"
1156                                               namestring
1157                                               err/dev)))))))
1158             (unless (and exists
1159                          (rename-the-old-one namestring original))
1160               (setf original nil)
1161               (setf delete-original nil)
1162               ;; In order to use :SUPERSEDE instead, we have to make
1163               ;; sure SB!UNIX:O_CREAT corresponds to
1164               ;; IF-DOES-NOT-EXIST. SB!UNIX:O_CREAT was set before
1165               ;; because of IF-EXISTS being :RENAME.
1166               (unless (eq if-does-not-exist :create)
1167                 (setf mask
1168                       (logior (logandc2 mask sb!unix:o_creat)
1169                               sb!unix:o_trunc)))
1170               (setf if-exists :supersede))))
1171
1172         ;; Now we can try the actual Unix open(2).
1173         (multiple-value-bind (fd errno)
1174             (if namestring
1175                 (sb!unix:unix-open namestring mask mode)
1176                 (values nil sb!unix:enoent))
1177           (labels ((open-error (format-control &rest format-arguments)
1178                      (error 'simple-file-error
1179                             :pathname pathname
1180                             :format-control format-control
1181                             :format-arguments format-arguments))
1182                    (vanilla-open-error ()
1183                      (simple-file-perror "error opening ~S" pathname errno)))
1184             (cond ((numberp fd)
1185                    (case direction
1186                      ((:input :output :io)
1187                       (make-fd-stream fd
1188                                       :input input
1189                                       :output output
1190                                       :element-type element-type
1191                                       :file namestring
1192                                       :original original
1193                                       :delete-original delete-original
1194                                       :pathname pathname
1195                                       :input-buffer-p t
1196                                       :auto-close t))
1197                      (:probe
1198                       (let ((stream
1199                              (%make-fd-stream :name namestring
1200                                               :fd fd
1201                                               :pathname pathname
1202                                               :element-type element-type)))
1203                         (close stream)
1204                         stream))))
1205                   ((eql errno sb!unix:enoent)
1206                    (case if-does-not-exist
1207                      (:error (vanilla-open-error))
1208                      (:create
1209                       (open-error "~@<The path ~2I~_~S ~I~_does not exist.~:>"
1210                                   pathname))
1211                      (t nil)))
1212                   ((and (eql errno sb!unix:eexist) if-exists)
1213                    nil)
1214                   (t
1215                    (vanilla-open-error)))))))))
1216 \f
1217 ;;;; initialization
1218
1219 ;;; the stream connected to the controlling terminal, or NIL if there is none
1220 (defvar *tty*)
1221
1222 ;;; the stream connected to the standard input (file descriptor 0)
1223 (defvar *stdin*)
1224
1225 ;;; the stream connected to the standard output (file descriptor 1)
1226 (defvar *stdout*)
1227
1228 ;;; the stream connected to the standard error output (file descriptor 2)
1229 (defvar *stderr*)
1230
1231 ;;; This is called when the cold load is first started up, and may also
1232 ;;; be called in an attempt to recover from nested errors.
1233 (defun stream-cold-init-or-reset ()
1234   (stream-reinit)
1235   (setf *terminal-io* (make-synonym-stream '*tty*))
1236   (setf *standard-output* (make-synonym-stream '*stdout*))
1237   (setf *standard-input*
1238         (#!-high-security
1239          ;; FIXME: Why is *STANDARD-INPUT* a TWO-WAY-STREAM? ANSI says
1240          ;; it's an input stream.
1241          make-two-way-stream
1242          #!+high-security
1243          %make-two-way-stream (make-synonym-stream '*stdin*)
1244                              *standard-output*))
1245   (setf *error-output* (make-synonym-stream '*stderr*))
1246   (setf *query-io* (make-synonym-stream '*terminal-io*))
1247   (setf *debug-io* *query-io*)
1248   (setf *trace-output* *standard-output*)
1249   (values))
1250
1251 ;;; This is called whenever a saved core is restarted.
1252 (defun stream-reinit ()
1253   (setf *available-buffers* nil)
1254   (setf *stdin*
1255         (make-fd-stream 0 :name "standard input" :input t :buffering :line))
1256   (setf *stdout*
1257         (make-fd-stream 1 :name "standard output" :output t :buffering :line))
1258   (setf *stderr*
1259         (make-fd-stream 2 :name "standard error" :output t :buffering :line))
1260   (let ((tty (sb!unix:unix-open "/dev/tty" sb!unix:o_rdwr #o666)))
1261     (if tty
1262         (setf *tty*
1263               (make-fd-stream tty
1264                               :name "the terminal"
1265                               :input t
1266                               :output t
1267                               :buffering :line
1268                               :auto-close t))
1269         (setf *tty* (make-two-way-stream *stdin* *stdout*))))
1270   (values))
1271 \f
1272 ;;;; miscellany
1273
1274 ;;; the Unix way to beep
1275 (defun beep (stream)
1276   (write-char (code-char bell-char-code) stream)
1277   (finish-output stream))
1278
1279 ;;; This is kind of like FILE-POSITION, but is an internal hack used
1280 ;;; by the filesys stuff to get and set the file name.
1281 ;;;
1282 ;;; FIXME: misleading name, screwy interface
1283 (defun file-name (stream &optional new-name)
1284   (when (typep stream 'file-stream)
1285       (cond (new-name
1286              (setf (fd-stream-pathname stream) new-name)
1287              (setf (fd-stream-file stream)
1288                    (unix-namestring new-name nil))
1289              t)
1290             (t
1291              (fd-stream-pathname stream)))))
1292 \f
1293 ;;;; international character support (which is trivial for our simple
1294 ;;;; character sets)
1295
1296 ;;;; (Those who do Lisp only in English might not remember that ANSI
1297 ;;;; requires these functions to be exported from package
1298 ;;;; COMMON-LISP.)
1299
1300 (defun file-string-length (stream object)
1301   (declare (type (or string character) object) (type file-stream stream))
1302   #!+sb-doc
1303   "Return the delta in STREAM's FILE-POSITION that would be caused by writing
1304    OBJECT to STREAM. Non-trivial only in implementations that support
1305    international character sets."
1306   (declare (ignore stream))
1307   (etypecase object
1308     (character 1)
1309     (string (length object))))
1310
1311 (defun stream-external-format (stream)
1312   (declare (type file-stream stream) (ignore stream))
1313   #!+sb-doc
1314   "Return :DEFAULT."
1315   :default)