src/code/fd-stream.lisp

   1 ;;;; streams for UNIX file descriptors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; BUFFER
  15 ;;;;
  16 ;;;; Streams hold BUFFER objects, which contain a SAP, size of the
  17 ;;;; memory area the SAP stands for (LENGTH bytes), and HEAD and TAIL
  18 ;;;; indexes which delimit the "valid", or "active" area of the
  19 ;;;; memory. HEAD is inclusive, TAIL is exclusive.
  20 ;;;;
  21 ;;;; Buffers get allocated lazily, and are recycled by returning them
  22 ;;;; to the *AVAILABLE-BUFFERS* list. Every buffer has it's own
  23 ;;;; finalizer, to take care of releasing the SAP memory when a stream
  24 ;;;; is not properly closed.
  25 ;;;;
  26 ;;;; The code aims to provide a limited form of thread and interrupt
  27 ;;;; safety: parallel writes and reads may lose output or input, cause
  28 ;;;; interleaved IO, etc -- but they should not corrupt memory. The
  29 ;;;; key to doing this is to read buffer state once, and update the
  30 ;;;; state based on the read state:
  31 ;;;;
  32 ;;;; (let ((tail (buffer-tail buffer)))
  33 ;;;;   ...
  34 ;;;;   (setf (buffer-tail buffer) (+ tail n)))
  35 ;;;;
  36 ;;;; NOT
  37 ;;;;
  38 ;;;; (let ((tail (buffer-tail buffer)))
  39 ;;;;   ...
  40 ;;;;  (incf (buffer-tail buffer) n))
  41 ;;;;
  42
  43 (declaim (inline buffer-sap buffer-length buffer-head buffer-tail
  44                  (setf buffer-head) (setf buffer-tail)))
  45 (defstruct (buffer (:constructor %make-buffer (sap length)))
  46   (sap (missing-arg) :type system-area-pointer :read-only t)
  47   (length (missing-arg) :type index :read-only t)
  48   (head 0 :type index)
  49   (tail 0 :type index))
  50
  51 (defvar *available-buffers* ()
  52   #!+sb-doc
  53   "List of available buffers.")
  54
  55 (defvar *available-buffers-spinlock* (sb!thread::make-spinlock
  56                                       :name "lock for *AVAILABLE-BUFFERS*")
  57   #!+sb-doc
  58   "Mutex for access to *AVAILABLE-BUFFERS*.")
  59
  60 (defmacro with-available-buffers-lock ((&optional) &body body)
  61   ;; CALL-WITH-SYSTEM-SPINLOCK because
  62   ;;
  63   ;; 1. streams are low-level enough to be async signal safe, and in
  64   ;;    particular a C-c that brings up the debugger while holding the
  65   ;;    mutex would lose badly
  66   ;;
  67   ;; 2. this can potentially be a fairly busy (but also probably
  68   ;;    uncontended) lock, so we don't want to pay the syscall per
  69   ;;    release -- hence a spinlock.
  70   ;;
  71   ;; ...again, once we have smarted locks the spinlock here can become
  72   ;; a mutex.
  73   `(sb!thread::with-system-spinlock (*available-buffers-spinlock*)
  74      ,@body))
  75
  76 (defconstant +bytes-per-buffer+ (* 4 1024)
  77   #!+sb-doc
  78   "Default number of bytes per buffer.")
  79
  80 (defun alloc-buffer (&optional (size +bytes-per-buffer+))
  81   ;; Don't want to allocate & unwind before the finalizer is in place.
  82   (without-interrupts
  83     (let* ((sap (allocate-system-memory size))
  84            (buffer (%make-buffer sap size)))
  85       (when (zerop (sap-int sap))
  86         (error "Could not allocate ~D bytes for buffer." size))
  87       (finalize buffer (lambda ()
  88                          (deallocate-system-memory sap size))
  89                 :dont-save t)
  90       buffer)))
  91
  92 (defun get-buffer ()
  93   ;; Don't go for the lock if there is nothing to be had -- sure,
  94   ;; another thread might just release one before we get it, but that
  95   ;; is not worth the cost of locking. Also release the lock before
  96   ;; allocation, since it's going to take a while.
  97   (if *available-buffers*
  98       (or (with-available-buffers-lock ()
  99             (pop *available-buffers*))
 100           (alloc-buffer))
 101       (alloc-buffer)))
 102
 103 (declaim (inline reset-buffer))
 104 (defun reset-buffer (buffer)
 105   (setf (buffer-head buffer) 0
 106         (buffer-tail buffer) 0)
 107   buffer)
 108
 109 (defun release-buffer (buffer)
 110   (reset-buffer buffer)
 111   (with-available-buffers-lock ()
 112     (push buffer *available-buffers*)))
 113
 114 ;;; This is a separate buffer management function, as it wants to be
 115 ;;; clever about locking -- grabbing the lock just once.
 116 (defun release-fd-stream-buffers (fd-stream)
 117   (let ((ibuf (fd-stream-ibuf fd-stream))
 118         (obuf (fd-stream-obuf fd-stream))
 119         (queue (loop for item in (fd-stream-output-queue fd-stream)
 120                        when (buffer-p item)
 121                        collect (reset-buffer item))))
 122     (when ibuf
 123       (push (reset-buffer ibuf) queue))
 124     (when obuf
 125       (push (reset-buffer obuf) queue))
 126     ;; ...so, anything found?
 127     (when queue
 128       ;; detach from stream
 129       (setf (fd-stream-ibuf fd-stream) nil
 130             (fd-stream-obuf fd-stream) nil
 131             (fd-stream-output-queue fd-stream) nil)
 132       ;; splice to *available-buffers*
 133       (with-available-buffers-lock ()
 134         (setf *available-buffers* (nconc queue *available-buffers*))))))
 135 \f
 136 ;;;; the FD-STREAM structure
 137
 138 (defstruct (fd-stream
 139             (:constructor %make-fd-stream)
 140             (:conc-name fd-stream-)
 141             (:predicate fd-stream-p)
 142             (:include ansi-stream
 143                       (misc #'fd-stream-misc-routine))
 144             (:copier nil))
 145
 146   ;; the name of this stream
 147   (name nil)
 148   ;; the file this stream is for
 149   (file nil)
 150   ;; the backup file namestring for the old file, for :IF-EXISTS
 151   ;; :RENAME or :RENAME-AND-DELETE.
 152   (original nil :type (or simple-string null))
 153   (delete-original nil)       ; for :if-exists :rename-and-delete
 154   ;;; the number of bytes per element
 155   (element-size 1 :type index)
 156   ;; the type of element being transfered
 157   (element-type 'base-char)
 158   ;; the Unix file descriptor
 159   (fd -1 :type fixnum)
 160   ;; controls when the output buffer is flushed
 161   (buffering :full :type (member :full :line :none))
 162   ;; controls whether the input buffer must be cleared before output
 163   ;; (must be done for files, not for sockets, pipes and other data
 164   ;; sources where input and output aren't related).  non-NIL means
 165   ;; don't clear input buffer.
 166   (dual-channel-p nil)
 167   ;; character position if known -- this may run into bignums, but
 168   ;; we probably should flip it into null then for efficiency's sake...
 169   (char-pos nil :type (or unsigned-byte null))
 170   ;; T if input is waiting on FD. :EOF if we hit EOF.
 171   (listen nil :type (member nil t :eof))
 172
 173   ;; the input buffer
 174   (instead (make-array 0 :element-type 'character :adjustable t :fill-pointer t) :type (array character (*)))
 175   (ibuf nil :type (or buffer null))
 176   (eof-forced-p nil :type (member t nil))
 177
 178   ;; the output buffer
 179   (obuf nil :type (or buffer null))
 180
 181   ;; output flushed, but not written due to non-blocking io?
 182   (output-queue nil)
 183   (handler nil)
 184   ;; timeout specified for this stream as seconds or NIL if none
 185   (timeout nil :type (or single-float null))
 186   ;; pathname of the file this stream is opened to (returned by PATHNAME)
 187   (pathname nil :type (or pathname null))
 188   (external-format :default)
 189   ;; fixed width, or function to call with a character
 190   (char-size 1 :type (or fixnum function))
 191   (output-bytes #'ill-out :type function)
 192   ;; a boolean indicating whether the stream is bivalent.  For
 193   ;; internal use only.
 194   (bivalent-p nil :type boolean))
 195 (def!method print-object ((fd-stream fd-stream) stream)
 196   (declare (type stream stream))
 197   (print-unreadable-object (fd-stream stream :type t :identity t)
 198     (format stream "for ~S" (fd-stream-name fd-stream))))
 199 \f
 200 ;;;; CORE OUTPUT FUNCTIONS
 201
 202 ;;; Buffer the section of THING delimited by START and END by copying
 203 ;;; to output buffer(s) of stream.
 204 (defun buffer-output (stream thing start end)
 205   (declare (index start end))
 206   (when (< end start)
 207     (error ":END before :START!"))
 208   (when (> end start)
 209     ;; Copy bytes from THING to buffers.
 210     (flet ((copy-to-buffer (buffer tail count)
 211              (declare (buffer buffer) (index tail count))
 212              (aver (plusp count))
 213              (let ((sap (buffer-sap buffer)))
 214                (etypecase thing
 215                  (system-area-pointer
 216                   (system-area-ub8-copy thing start sap tail count))
 217                  ((simple-unboxed-array (*))
 218                   (copy-ub8-to-system-area thing start sap tail count))))
 219              ;; Not INCF! If another thread has moved tail from under
 220              ;; us, we don't want to accidentally increment tail
 221              ;; beyond buffer-length.
 222              (setf (buffer-tail buffer) (+ count tail))
 223              (incf start count)))
 224       (tagbody
 225          ;; First copy is special: the buffer may already contain
 226          ;; something, or be even full.
 227          (let* ((obuf (fd-stream-obuf stream))
 228                 (tail (buffer-tail obuf))
 229                 (space (- (buffer-length obuf) tail)))
 230            (when (plusp space)
 231              (copy-to-buffer obuf tail (min space (- end start)))
 232              (go :more-output-p)))
 233        :flush-and-fill
 234          ;; Later copies should always have an empty buffer, since
 235          ;; they are freshly flushed, but if another thread is
 236          ;; stomping on the same buffer that might not be the case.
 237          (let* ((obuf (flush-output-buffer stream))
 238                 (tail (buffer-tail obuf))
 239                 (space (- (buffer-length obuf) tail)))
 240            (copy-to-buffer obuf tail (min space (- end start))))
 241        :more-output-p
 242          (when (> end start)
 243            (go :flush-and-fill))))))
 244
 245 ;;; Flush the current output buffer of the stream, ensuring that the
 246 ;;; new buffer is empty. Returns (for convenience) the new output
 247 ;;; buffer -- which may or may not be EQ to the old one. If the is no
 248 ;;; queued output we try to write the buffer immediately -- otherwise
 249 ;;; we queue it for later.
 250 (defun flush-output-buffer (stream)
 251   (let ((obuf (fd-stream-obuf stream)))
 252     (when obuf
 253       (let ((head (buffer-head obuf))
 254             (tail (buffer-tail obuf)))
 255         (cond ((eql head tail)
 256                ;; Buffer is already empty -- just ensure that is is
 257                ;; set to zero as well.
 258                (reset-buffer obuf))
 259               ((fd-stream-output-queue stream)
 260                ;; There is already stuff on the queue -- go directly
 261                ;; there.
 262                (aver (< head tail))
 263                (%queue-and-replace-output-buffer stream))
 264               (t
 265                ;; Try a non-blocking write, queue whatever is left over.
 266                (aver (< head tail))
 267                (synchronize-stream-output stream)
 268                (let ((length (- tail head)))
 269                  (multiple-value-bind (count errno)
 270                      (sb!unix:unix-write (fd-stream-fd stream) (buffer-sap obuf)
 271                                          head length)
 272                    (cond ((eql count length)
 273                           ;; Complete write -- we can use the same buffer.
 274                           (reset-buffer obuf))
 275                          (count
 276                           ;; Partial write -- update buffer status and queue.
 277                           ;; Do not use INCF! Another thread might have moved
 278                           ;; head...
 279                           (setf (buffer-head obuf) (+ count head))
 280                           (%queue-and-replace-output-buffer stream))
 281                          #!-win32
 282                          ((eql errno sb!unix:ewouldblock)
 283                           ;; Blocking, queue.
 284                           (%queue-and-replace-output-buffer stream))
 285                          (t
 286                           (simple-stream-perror "Couldn't write to ~s"
 287                                                 stream errno)))))))))))
 288
 289 ;;; Helper for FLUSH-OUTPUT-BUFFER -- returns the new buffer.
 290 (defun %queue-and-replace-output-buffer (stream)
 291   (let ((queue (fd-stream-output-queue stream))
 292         (later (list (or (fd-stream-obuf stream) (bug "Missing obuf."))))
 293         (new (get-buffer)))
 294     ;; Important: before putting the buffer on queue, give the stream
 295     ;; a new one. If we get an interrupt and unwind losing the buffer
 296     ;; is relatively OK, but having the same buffer in two places
 297     ;; would be bad.
 298     (setf (fd-stream-obuf stream) new)
 299     (cond (queue
 300            (nconc queue later))
 301           (t
 302            (setf (fd-stream-output-queue stream) later)))
 303     (unless (fd-stream-handler stream)
 304       (setf (fd-stream-handler stream)
 305             (add-fd-handler (fd-stream-fd stream)
 306                             :output
 307                             (lambda (fd)
 308                               (declare (ignore fd))
 309                               (write-output-from-queue stream)))))
 310     new))
 311
 312 ;;; This is called by the FD-HANDLER for the stream when output is
 313 ;;; possible.
 314 (defun write-output-from-queue (stream)
 315   (synchronize-stream-output stream)
 316   (let (not-first-p)
 317     (tagbody
 318      :pop-buffer
 319        (let* ((buffer (pop (fd-stream-output-queue stream)))
 320               (head (buffer-head buffer))
 321               (length (- (buffer-tail buffer) head)))
 322          (declare (index head length))
 323          (aver (>= length 0))
 324          (multiple-value-bind (count errno)
 325              (sb!unix:unix-write (fd-stream-fd stream) (buffer-sap buffer)
 326                                  head length)
 327            (cond ((eql count length)
 328                   ;; Complete write, see if we can do another right
 329                   ;; away, or remove the handler if we're done.
 330                   (release-buffer buffer)
 331                   (cond ((fd-stream-output-queue stream)
 332                          (setf not-first-p t)
 333                          (go :pop-buffer))
 334                         (t
 335                          (let ((handler (fd-stream-handler stream)))
 336                            (aver handler)
 337                            (setf (fd-stream-handler stream) nil)
 338                            (remove-fd-handler handler)))))
 339                  (count
 340                   ;; Partial write. Update buffer status and requeue.
 341                   (aver (< count length))
 342                   ;; Do not use INCF! Another thread might have moved head.
 343                   (setf (buffer-head buffer) (+ head count))
 344                   (push buffer (fd-stream-output-queue stream)))
 345                  (not-first-p
 346                   ;; We tried to do multiple writes, and finally our
 347                   ;; luck ran out. Requeue.
 348                   (push buffer (fd-stream-output-queue stream)))
 349                  (t
 350                   ;; Could not write on the first try at all!
 351                   #!+win32
 352                   (simple-stream-perror "Couldn't write to ~S." stream errno)
 353                   #!-win32
 354                   (if (= errno sb!unix:ewouldblock)
 355                       (bug "Unexpected blocking in WRITE-OUTPUT-FROM-QUEUE.")
 356                       (simple-stream-perror "Couldn't write to ~S"
 357                                             stream errno))))))))
 358   nil)
 359
 360 ;;; Try to write THING directly to STREAM without buffering, if
 361 ;;; possible. If direct write doesn't happen, buffer.
 362 (defun write-or-buffer-output (stream thing start end)
 363   (declare (index start end))
 364   (cond ((fd-stream-output-queue stream)
 365          (buffer-output stream thing start end))
 366         ((< end start)
 367          (error ":END before :START!"))
 368         ((> end start)
 369          (let ((length (- end start)))
 370            (synchronize-stream-output stream)
 371            (multiple-value-bind (count errno)
 372                (sb!unix:unix-write (fd-stream-fd stream) thing start length)
 373              (cond ((eql count length)
 374                     ;; Complete write -- done!
 375                     )
 376                    (count
 377                     (aver (< count length))
 378                     ;; Partial write -- buffer the rest.
 379                     (buffer-output stream thing (+ start count) end))
 380                    (t
 381                     ;; Could not write -- buffer or error.
 382                     #!+win32
 383                     (simple-stream-perror "couldn't write to ~s" stream errno)
 384                     #!-win32
 385                     (if (= errno sb!unix:ewouldblock)
 386                         (buffer-output stream thing start end)
 387                         (simple-stream-perror "couldn't write to ~s" stream errno)))))))))
 388
 389 ;;; Deprecated -- can go away after 1.1 or so. Deprecated because
 390 ;;; this is not something we want to export. Nikodemus thinks the
 391 ;;; right thing is to support a low-level non-stream like IO layer,
 392 ;;; akin to java.nio.
 393 (defun output-raw-bytes (stream thing &optional start end)
 394   (write-or-buffer-output stream thing (or start 0) (or end (length thing))))
 395
 396 (define-compiler-macro output-raw-bytes (stream thing &optional start end)
 397   (deprecation-warning 'output-raw-bytes)
 398   (let ((x (gensym "THING")))
 399     `(let ((,x ,thing))
 400        (write-or-buffer-output ,stream ,x (or ,start 0) (or ,end (length ,x))))))
 401 \f
 402 ;;;; output routines and related noise
 403
 404 (defvar *output-routines* ()
 405   #!+sb-doc
 406   "List of all available output routines. Each element is a list of the
 407   element-type output, the kind of buffering, the function name, and the number
 408   of bytes per element.")
 409
 410 ;;; common idioms for reporting low-level stream and file problems
 411 (defun simple-stream-perror (note-format stream errno)
 412   (error 'simple-stream-error
 413          :stream stream
 414          :format-control "~@<~?: ~2I~_~A~:>"
 415          :format-arguments (list note-format (list stream) (strerror errno))))
 416 (defun simple-file-perror (note-format pathname errno)
 417   (error 'simple-file-error
 418          :pathname pathname
 419          :format-control "~@<~?: ~2I~_~A~:>"
 420          :format-arguments
 421          (list note-format (list pathname) (strerror errno))))
 422
 423 (defun stream-decoding-error (stream octets)
 424   (error 'stream-decoding-error
 425          :external-format (stream-external-format stream)
 426          :stream stream
 427          ;; FIXME: dunno how to get at OCTETS currently, or even if
 428          ;; that's the right thing to report.
 429          :octets octets))
 430 (defun stream-encoding-error (stream code)
 431   (error 'stream-encoding-error
 432          :external-format (stream-external-format stream)
 433          :stream stream
 434          :code code))
 435
 436 (defun c-string-encoding-error (external-format code)
 437   (error 'c-string-encoding-error
 438          :external-format external-format
 439          :code code))
 440
 441 (defun c-string-decoding-error (external-format octets)
 442   (error 'c-string-decoding-error
 443          :external-format external-format
 444          :octets octets))
 445
 446 ;;; Returning true goes into end of file handling, false will enter another
 447 ;;; round of input buffer filling followed by re-entering character decode.
 448 (defun stream-decoding-error-and-handle (stream octet-count)
 449   (restart-case
 450       (stream-decoding-error stream
 451                              (let* ((buffer (fd-stream-ibuf stream))
 452                                     (sap (buffer-sap buffer))
 453                                     (head (buffer-head buffer)))
 454                                (loop for i from 0 below octet-count
 455                                      collect (sap-ref-8 sap (+ head i)))))
 456     (attempt-resync ()
 457       :report (lambda (stream)
 458                 (format stream
 459                         "~@<Attempt to resync the stream at a ~
 460                         character boundary and continue.~@:>"))
 461       (fd-stream-resync stream)
 462       nil)
 463     (force-end-of-file ()
 464       :report (lambda (stream)
 465                 (format stream "~@<Force an end of file.~@:>"))
 466       (setf (fd-stream-eof-forced-p stream) t))
 467     (input-replacement (string)
 468       :report (lambda (stream)
 469                 (format stream "~@<Use string as replacement input, ~
 470                                attempt to resync at a character ~
 471                                boundary and continue.~@:>"))
 472       :interactive (lambda ()
 473                      (format *query-io* "~@<Enter a string: ~@:>")
 474                      (finish-output *query-io*)
 475                      (list (read *query-io*)))
 476       (let ((string (reverse (string string)))
 477             (instead (fd-stream-instead stream)))
 478         (dotimes (i (length string))
 479           (vector-push-extend (char string i) instead))
 480         (fd-stream-resync stream)
 481         (when (> (length string) 0)
 482           (setf (fd-stream-listen stream) t)))
 483       nil)))
 484
 485 (defun stream-encoding-error-and-handle (stream code)
 486   (restart-case
 487       (stream-encoding-error stream code)
 488     (output-nothing ()
 489       :report (lambda (stream)
 490                 (format stream "~@<Skip output of this character.~@:>"))
 491       (throw 'output-nothing nil))
 492     (output-replacement (string)
 493       :report (lambda (stream)
 494                 (format stream "~@<Output replacement string.~@:>"))
 495       :interactive (lambda ()
 496                      (format *query-io* "~@<Enter a string: ~@:>")
 497                      (finish-output *query-io*)
 498                      (list (read *query-io*)))
 499       (let ((string (string string)))
 500         (fd-sout stream (string string) 0 (length string)))
 501       (throw 'output-nothing nil))))
 502
 503 (defun external-format-encoding-error (stream code)
 504   (if (streamp stream)
 505       (stream-encoding-error-and-handle stream code)
 506       (c-string-encoding-error stream code)))
 507
 508 (defun synchronize-stream-output (stream)
 509   ;; If we're reading and writing on the same file, flush buffered
 510   ;; input and rewind file position accordingly.
 511   (unless (fd-stream-dual-channel-p stream)
 512     (let ((adjust (nth-value 1 (flush-input-buffer stream))))
 513       (unless (eql 0 adjust)
 514         (sb!unix:unix-lseek (fd-stream-fd stream) (- adjust) sb!unix:l_incr)))))
 515
 516 (defun fd-stream-output-finished-p (stream)
 517   (let ((obuf (fd-stream-obuf stream)))
 518     (or (not obuf)
 519         (and (zerop (buffer-tail obuf))
 520              (not (fd-stream-output-queue stream))))))
 521
 522 (defmacro output-wrapper/variable-width ((stream size buffering restart)
 523                                          &body body)
 524   (let ((stream-var (gensym "STREAM")))
 525     `(let* ((,stream-var ,stream)
 526             (obuf (fd-stream-obuf ,stream-var))
 527             (tail (buffer-tail obuf))
 528             (size ,size))
 529       ,(unless (eq (car buffering) :none)
 530          `(when (<= (buffer-length obuf) (+ tail size))
 531             (setf obuf (flush-output-buffer ,stream-var)
 532                   tail (buffer-tail obuf))))
 533       ,(unless (eq (car buffering) :none)
 534          ;; FIXME: Why this here? Doesn't seem necessary.
 535          `(synchronize-stream-output ,stream-var))
 536       ,(if restart
 537            `(catch 'output-nothing
 538               ,@body
 539               (setf (buffer-tail obuf) (+ tail size)))
 540            `(progn
 541              ,@body
 542              (setf (buffer-tail obuf) (+ tail size))))
 543       ,(ecase (car buffering)
 544          (:none
 545           `(flush-output-buffer ,stream-var))
 546          (:line
 547           `(when (eql byte #\Newline)
 548              (flush-output-buffer ,stream-var)))
 549          (:full))
 550     (values))))
 551
 552 (defmacro output-wrapper ((stream size buffering restart) &body body)
 553   (let ((stream-var (gensym "STREAM")))
 554     `(let* ((,stream-var ,stream)
 555             (obuf (fd-stream-obuf ,stream-var))
 556             (tail (buffer-tail obuf)))
 557       ,(unless (eq (car buffering) :none)
 558          `(when (<= (buffer-length obuf) (+ tail ,size))
 559             (setf obuf (flush-output-buffer ,stream-var)
 560                   tail (buffer-tail obuf))))
 561       ;; FIXME: Why this here? Doesn't seem necessary.
 562       ,(unless (eq (car buffering) :none)
 563          `(synchronize-stream-output ,stream-var))
 564       ,(if restart
 565            `(catch 'output-nothing
 566               ,@body
 567               (setf (buffer-tail obuf) (+ tail ,size)))
 568            `(progn
 569              ,@body
 570              (setf (buffer-tail obuf) (+ tail ,size))))
 571       ,(ecase (car buffering)
 572          (:none
 573           `(flush-output-buffer ,stream-var))
 574          (:line
 575           `(when (eql byte #\Newline)
 576              (flush-output-buffer ,stream-var)))
 577          (:full))
 578     (values))))
 579
 580 (defmacro def-output-routines/variable-width
 581     ((name-fmt size restart external-format &rest bufferings)
 582      &body body)
 583   (declare (optimize (speed 1)))
 584   (cons 'progn
 585         (mapcar
 586             (lambda (buffering)
 587               (let ((function
 588                      (intern (format nil name-fmt (string (car buffering))))))
 589                 `(progn
 590                    (defun ,function (stream byte)
 591                      (declare (ignorable byte))
 592                      (output-wrapper/variable-width (stream ,size ,buffering ,restart)
 593                        ,@body))
 594                    (setf *output-routines*
 595                          (nconc *output-routines*
 596                                 ',(mapcar
 597                                    (lambda (type)
 598                                      (list type
 599                                            (car buffering)
 600                                            function
 601                                            1
 602                                            external-format))
 603                                    (cdr buffering)))))))
 604             bufferings)))
 605
 606 ;;; Define output routines that output numbers SIZE bytes long for the
 607 ;;; given bufferings. Use BODY to do the actual output.
 608 (defmacro def-output-routines ((name-fmt size restart &rest bufferings)
 609                                &body body)
 610   (declare (optimize (speed 1)))
 611   (cons 'progn
 612         (mapcar
 613             (lambda (buffering)
 614               (let ((function
 615                      (intern (format nil name-fmt (string (car buffering))))))
 616                 `(progn
 617                    (defun ,function (stream byte)
 618                      (output-wrapper (stream ,size ,buffering ,restart)
 619                        ,@body))
 620                    (setf *output-routines*
 621                          (nconc *output-routines*
 622                                 ',(mapcar
 623                                    (lambda (type)
 624                                      (list type
 625                                            (car buffering)
 626                                            function
 627                                            size
 628                                            nil))
 629                                    (cdr buffering)))))))
 630             bufferings)))
 631
 632 ;;; FIXME: is this used anywhere any more?
 633 (def-output-routines ("OUTPUT-CHAR-~A-BUFFERED"
 634                       1
 635                       t
 636                       (:none character)
 637                       (:line character)
 638                       (:full character))
 639   (if (eql byte #\Newline)
 640       (setf (fd-stream-char-pos stream) 0)
 641       (incf (fd-stream-char-pos stream)))
 642   (setf (sap-ref-8 (buffer-sap obuf) tail)
 643         (char-code byte)))
 644
 645 (def-output-routines ("OUTPUT-UNSIGNED-BYTE-~A-BUFFERED"
 646                       1
 647                       nil
 648                       (:none (unsigned-byte 8))
 649                       (:full (unsigned-byte 8)))
 650   (setf (sap-ref-8 (buffer-sap obuf) tail)
 651         byte))
 652
 653 (def-output-routines ("OUTPUT-SIGNED-BYTE-~A-BUFFERED"
 654                       1
 655                       nil
 656                       (:none (signed-byte 8))
 657                       (:full (signed-byte 8)))
 658   (setf (signed-sap-ref-8 (buffer-sap obuf) tail)
 659         byte))
 660
 661 (def-output-routines ("OUTPUT-UNSIGNED-SHORT-~A-BUFFERED"
 662                       2
 663                       nil
 664                       (:none (unsigned-byte 16))
 665                       (:full (unsigned-byte 16)))
 666   (setf (sap-ref-16 (buffer-sap obuf) tail)
 667         byte))
 668
 669 (def-output-routines ("OUTPUT-SIGNED-SHORT-~A-BUFFERED"
 670                       2
 671                       nil
 672                       (:none (signed-byte 16))
 673                       (:full (signed-byte 16)))
 674   (setf (signed-sap-ref-16 (buffer-sap obuf) tail)
 675         byte))
 676
 677 (def-output-routines ("OUTPUT-UNSIGNED-LONG-~A-BUFFERED"
 678                       4
 679                       nil
 680                       (:none (unsigned-byte 32))
 681                       (:full (unsigned-byte 32)))
 682   (setf (sap-ref-32 (buffer-sap obuf) tail)
 683         byte))
 684
 685 (def-output-routines ("OUTPUT-SIGNED-LONG-~A-BUFFERED"
 686                       4
 687                       nil
 688                       (:none (signed-byte 32))
 689                       (:full (signed-byte 32)))
 690   (setf (signed-sap-ref-32 (buffer-sap obuf) tail)
 691         byte))
 692
 693 #+#.(cl:if (cl:= sb!vm:n-word-bits 64) '(and) '(or))
 694 (progn
 695   (def-output-routines ("OUTPUT-UNSIGNED-LONG-LONG-~A-BUFFERED"
 696                         8
 697                         nil
 698                         (:none (unsigned-byte 64))
 699                         (:full (unsigned-byte 64)))
 700     (setf (sap-ref-64 (buffer-sap obuf) tail)
 701           byte))
 702   (def-output-routines ("OUTPUT-SIGNED-LONG-LONG-~A-BUFFERED"
 703                         8
 704                         nil
 705                         (:none (signed-byte 64))
 706                         (:full (signed-byte 64)))
 707     (setf (signed-sap-ref-64 (buffer-sap obuf) tail)
 708           byte)))
 709
 710 ;;; the routine to use to output a string. If the stream is
 711 ;;; unbuffered, slam the string down the file descriptor, otherwise
 712 ;;; use OUTPUT-RAW-BYTES to buffer the string. Update charpos by
 713 ;;; checking to see where the last newline was.
 714 (defun fd-sout (stream thing start end)
 715   (declare (type fd-stream stream) (type string thing))
 716   (let ((start (or start 0))
 717         (end (or end (length (the vector thing)))))
 718     (declare (fixnum start end))
 719     (let ((last-newline
 720            (string-dispatch (simple-base-string
 721                              #!+sb-unicode
 722                              (simple-array character (*))
 723                              string)
 724                thing
 725              (position #\newline thing :from-end t
 726                        :start start :end end))))
 727       (if (and (typep thing 'base-string)
 728                (eq (fd-stream-external-format-keyword stream) :latin-1))
 729           (ecase (fd-stream-buffering stream)
 730             (:full
 731              (buffer-output stream thing start end))
 732             (:line
 733              (buffer-output stream thing start end)
 734              (when last-newline
 735                (flush-output-buffer stream)))
 736             (:none
 737              (write-or-buffer-output stream thing start end)))
 738           (ecase (fd-stream-buffering stream)
 739             (:full (funcall (fd-stream-output-bytes stream)
 740                             stream thing nil start end))
 741             (:line (funcall (fd-stream-output-bytes stream)
 742                             stream thing last-newline start end))
 743             (:none (funcall (fd-stream-output-bytes stream)
 744                             stream thing t start end))))
 745       (if last-newline
 746           (setf (fd-stream-char-pos stream) (- end last-newline 1))
 747           (incf (fd-stream-char-pos stream) (- end start))))))
 748
 749 (defstruct (external-format
 750              (:constructor %make-external-format)
 751              (:conc-name ef-)
 752              (:predicate external-format-p)
 753              (:copier %copy-external-format))
 754   ;; All the names that can refer to this external format.  The first
 755   ;; one is the canonical name.
 756   (names (missing-arg) :type list :read-only t)
 757   (default-replacement-character (missing-arg) :type character)
 758   (read-n-chars-fun (missing-arg) :type function)
 759   (read-char-fun (missing-arg) :type function)
 760   (write-n-bytes-fun (missing-arg) :type function)
 761   (write-char-none-buffered-fun (missing-arg) :type function)
 762   (write-char-line-buffered-fun (missing-arg) :type function)
 763   (write-char-full-buffered-fun (missing-arg) :type function)
 764   ;; Can be nil for fixed-width formats.
 765   (resync-fun nil :type (or function null))
 766   (bytes-for-char-fun (missing-arg) :type function)
 767   (read-c-string-fun (missing-arg) :type function)
 768   (write-c-string-fun (missing-arg) :type function)
 769   ;; We indirect through symbols in these functions so that a
 770   ;; developer working on the octets code can easily redefine things
 771   ;; and use the new function definition without redefining the
 772   ;; external format as well.  The slots above don't do any
 773   ;; indirection because a developer working with those slots would be
 774   ;; redefining the external format anyway.
 775   (octets-to-string-fun (missing-arg) :type function)
 776   (string-to-octets-fun (missing-arg) :type function))
 777
 778 (defun wrap-external-format-functions (external-format fun)
 779   (let ((result (%copy-external-format external-format)))
 780     (macrolet ((frob (accessor)
 781                  `(setf (,accessor result) (funcall fun (,accessor result)))))
 782       (frob ef-read-n-chars-fun)
 783       (frob ef-read-char-fun)
 784       (frob ef-write-n-bytes-fun)
 785       (frob ef-write-char-none-buffered-fun)
 786       (frob ef-write-char-line-buffered-fun)
 787       (frob ef-write-char-full-buffered-fun)
 788       (frob ef-resync-fun)
 789       (frob ef-bytes-for-char-fun)
 790       (frob ef-read-c-string-fun)
 791       (frob ef-write-c-string-fun)
 792       (frob ef-octets-to-string-fun)
 793       (frob ef-string-to-octets-fun))
 794     result))
 795
 796 (defvar *external-formats* (make-hash-table)
 797   #!+sb-doc
 798   "Hashtable of all available external formats. The table maps from
 799   external-format names to EXTERNAL-FORMAT structures.")
 800
 801 (defun get-external-format (external-format)
 802   (flet ((keyword-external-format (keyword)
 803            (declare (type keyword keyword))
 804            (gethash keyword *external-formats*))
 805          (replacement-handlerify (entry replacement)
 806            (when entry
 807              (wrap-external-format-functions
 808               entry
 809               (lambda (fun)
 810                 (and fun
 811                      (lambda (&rest rest)
 812                        (declare (dynamic-extent rest))
 813                        (handler-bind
 814                            ((stream-decoding-error
 815                              (lambda (c)
 816                                (declare (ignore c))
 817                                (invoke-restart 'input-replacement replacement)))
 818                             (stream-encoding-error
 819                              (lambda (c)
 820                                (declare (ignore c))
 821                                (invoke-restart 'output-replacement replacement)))
 822                             (octets-encoding-error
 823                              (lambda (c) (use-value replacement c)))
 824                             (octet-decoding-error
 825                              (lambda (c) (use-value replacement c))))
 826                          (apply fun rest)))))))))
 827     (typecase external-format
 828       (keyword (keyword-external-format external-format))
 829       ((cons keyword)
 830        (let ((entry (keyword-external-format (car external-format)))
 831              (replacement (getf (cdr external-format) :replacement)))
 832          (if replacement
 833              (replacement-handlerify entry replacement)
 834              entry))))))
 835
 836 (defun get-external-format-or-lose (external-format)
 837   (or (get-external-format external-format)
 838       (error "Undefined external-format ~A" external-format)))
 839
 840 (defun external-format-keyword (external-format)
 841   (typecase external-format
 842     (keyword external-format)
 843     ((cons keyword) (car external-format))))
 844
 845 (defun fd-stream-external-format-keyword (stream)
 846   (external-format-keyword (fd-stream-external-format stream)))
 847
 848 (defun canonize-external-format (external-format entry)
 849   (typecase external-format
 850     (keyword (first (ef-names entry)))
 851     ((cons keyword) (cons (first (ef-names entry)) (rest external-format)))))
 852
 853 ;;; Find an output routine to use given the type and buffering. Return
 854 ;;; as multiple values the routine, the real type transfered, and the
 855 ;;; number of bytes per element.
 856 (defun pick-output-routine (type buffering &optional external-format)
 857   (when (subtypep type 'character)
 858     (let ((entry (get-external-format external-format)))
 859       (when entry
 860         (return-from pick-output-routine
 861           (values (ecase buffering
 862                     (:none (ef-write-char-none-buffered-fun entry))
 863                     (:line (ef-write-char-line-buffered-fun entry))
 864                     (:full (ef-write-char-full-buffered-fun entry)))
 865                   'character
 866                   1
 867                   (ef-write-n-bytes-fun entry)
 868                   (canonize-external-format external-format entry))))))
 869   (dolist (entry *output-routines*)
 870     (when (and (subtypep type (first entry))
 871                (eq buffering (second entry))
 872                (or (not (fifth entry))
 873                    (eq external-format (fifth entry))))
 874       (return-from pick-output-routine
 875         (values (symbol-function (third entry))
 876                 (first entry)
 877                 (fourth entry)))))
 878   ;; KLUDGE: dealing with the buffering here leads to excessive code
 879   ;; explosion.
 880   ;;
 881   ;; KLUDGE: also see comments in PICK-INPUT-ROUTINE
 882   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 883         if (subtypep type `(unsigned-byte ,i))
 884         do (return-from pick-output-routine
 885              (values
 886               (ecase buffering
 887                 (:none
 888                  (lambda (stream byte)
 889                    (output-wrapper (stream (/ i 8) (:none) nil)
 890                      (loop for j from 0 below (/ i 8)
 891                            do (setf (sap-ref-8 (buffer-sap obuf)
 892                                                (+ j tail))
 893                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 894                 (:full
 895                  (lambda (stream byte)
 896                    (output-wrapper (stream (/ i 8) (:full) nil)
 897                      (loop for j from 0 below (/ i 8)
 898                            do (setf (sap-ref-8 (buffer-sap obuf)
 899                                                (+ j tail))
 900                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 901               `(unsigned-byte ,i)
 902               (/ i 8))))
 903   (loop for i from 40 by 8 to 1024 ; ARB (KLUDGE)
 904         if (subtypep type `(signed-byte ,i))
 905         do (return-from pick-output-routine
 906              (values
 907               (ecase buffering
 908                 (:none
 909                  (lambda (stream byte)
 910                    (output-wrapper (stream (/ i 8) (:none) nil)
 911                      (loop for j from 0 below (/ i 8)
 912                            do (setf (sap-ref-8 (buffer-sap obuf)
 913                                                (+ j tail))
 914                                     (ldb (byte 8 (- i 8 (* j 8))) byte))))))
 915                 (:full
 916                  (lambda (stream byte)
 917                    (output-wrapper (stream (/ i 8) (:full) nil)
 918                      (loop for j from 0 below (/ i 8)
 919                            do (setf (sap-ref-8 (buffer-sap obuf)
 920                                                (+ j tail))
 921                                     (ldb (byte 8 (- i 8 (* j 8))) byte)))))))
 922               `(signed-byte ,i)
 923               (/ i 8)))))
 924 \f
 925 ;;;; input routines and related noise
 926
 927 ;;; a list of all available input routines. Each element is a list of
 928 ;;; the element-type input, the function name, and the number of bytes
 929 ;;; per element.
 930 (defvar *input-routines* ())
 931
 932 ;;; Return whether a primitive partial read operation on STREAM's FD
 933 ;;; would (probably) block.  Signal a `simple-stream-error' if the
 934 ;;; system call implementing this operation fails.
 935 ;;;
 936 ;;; It is "may" instead of "would" because "would" is not quite
 937 ;;; correct on win32.  However, none of the places that use it require
 938 ;;; further assurance than "may" versus "will definitely not".
 939 (defun sysread-may-block-p (stream)
 940   #!+win32
 941   ;; This answers T at EOF on win32, I think.
 942   (not (sb!win32:fd-listen (fd-stream-fd stream)))
 943   #!-win32
 944   (sb!unix:with-restarted-syscall (count errno)
 945     (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set)))
 946       (sb!unix:fd-zero read-fds)
 947       (sb!unix:fd-set (fd-stream-fd stream) read-fds)
 948       (sb!unix:unix-fast-select (1+ (fd-stream-fd stream))
 949                                 (sb!alien:addr read-fds)
 950                                 nil nil 0 0))
 951     (case count
 952       ((1) nil)
 953       ((0) t)
 954       (otherwise
 955        (simple-stream-perror "couldn't check whether ~S is readable"
 956                              stream
 957                              errno)))))
 958
 959 ;;; If the read would block wait (using SERVE-EVENT) till input is available,
 960 ;;; then fill the input buffer, and return the number of bytes read. Throws
 961 ;;; to EOF-INPUT-CATCHER if the eof was reached.
 962 (defun refill-input-buffer (stream)
 963   (dx-let ((fd (fd-stream-fd stream))
 964            (errno 0)
 965            (count 0))
 966     (tagbody
 967        ;; Check for blocking input before touching the stream, as if
 968        ;; we happen to wait we are liable to be interrupted, and the
 969        ;; interrupt handler may use the same stream.
 970        (if (sysread-may-block-p stream)
 971            (go :wait-for-input)
 972            (go :main))
 973        ;; These (:CLOSED-FLAME and :READ-ERROR) tags are here so what
 974        ;; we can signal errors outside the WITHOUT-INTERRUPTS.
 975      :closed-flame
 976        (closed-flame stream)
 977      :read-error
 978        (simple-stream-perror "couldn't read from ~S" stream errno)
 979      :wait-for-input
 980        ;; This tag is here so we can unwind outside the WITHOUT-INTERRUPTS
 981        ;; to wait for input if read tells us EWOULDBLOCK.
 982        (unless (wait-until-fd-usable fd :input (fd-stream-timeout stream))
 983          (signal-timeout 'io-timeout :stream stream :direction :read
 984                          :seconds (fd-stream-timeout stream)))
 985      :main
 986        ;; Since the read should not block, we'll disable the
 987        ;; interrupts here, so that we don't accidentally unwind and
 988        ;; leave the stream in an inconsistent state.
 989
 990        ;; Execute the nlx outside without-interrupts to ensure the
 991        ;; resulting thunk is stack-allocatable.
 992        ((lambda (return-reason)
 993           (ecase return-reason
 994             ((nil))             ; fast path normal cases
 995             ((:wait-for-input) (go :wait-for-input))
 996             ((:closed-flame)   (go :closed-flame))
 997             ((:read-error)     (go :read-error))))
 998         (without-interrupts
 999           ;; Check the buffer: if it is null, then someone has closed
1000           ;; the stream from underneath us. This is not ment to fix
1001           ;; multithreaded races, but to deal with interrupt handlers
1002           ;; closing the stream.
1003           (block nil
1004             (prog1 nil
1005               (let* ((ibuf (or (fd-stream-ibuf stream) (return :closed-flame)))
1006                      (sap (buffer-sap ibuf))
1007                      (length (buffer-length ibuf))
1008                      (head (buffer-head ibuf))
1009                      (tail (buffer-tail ibuf)))
1010                 (declare (index length head tail)
1011                          (inline sb!unix:unix-read))
1012                 (unless (zerop head)
1013                   (cond ((eql head tail)
1014                          ;; Buffer is empty, but not at yet reset -- make it so.
1015                          (setf head 0
1016                                tail 0)
1017                          (reset-buffer ibuf))
1018                         (t
1019                          ;; Buffer has things in it, but they are not at the
1020                          ;; head -- move them there.
1021                          (let ((n (- tail head)))
1022                            (system-area-ub8-copy sap head sap 0 n)
1023                            (setf head 0
1024                                  (buffer-head ibuf) head
1025                                  tail n
1026                                  (buffer-tail ibuf) tail)))))
1027                 (setf (fd-stream-listen stream) nil)
1028                 (setf (values count errno)
1029                       (sb!unix:unix-read fd (sap+ sap tail) (- length tail)))
1030                 (cond ((null count)
1031                        #!+win32
1032                        (return :read-error)
1033                        #!-win32
1034                        (if (eql errno sb!unix:ewouldblock)
1035                            (return :wait-for-input)
1036                            (return :read-error)))
1037                       ((zerop count)
1038                        (setf (fd-stream-listen stream) :eof)
1039                        (/show0 "THROWing EOF-INPUT-CATCHER")
1040                        (throw 'eof-input-catcher nil))
1041                       (t
1042                        ;; Success! (Do not use INCF, for sake of other threads.)
1043                        (setf (buffer-tail ibuf) (+ count tail))))))))))
1044     count))
1045
1046 ;;; Make sure there are at least BYTES number of bytes in the input
1047 ;;; buffer. Keep calling REFILL-INPUT-BUFFER until that condition is met.
1048 (defmacro input-at-least (stream bytes)
1049   (let ((stream-var (gensym "STREAM"))
1050         (bytes-var (gensym "BYTES"))
1051         (buffer-var (gensym "IBUF")))
1052     `(let* ((,stream-var ,stream)
1053             (,bytes-var ,bytes)
1054             (,buffer-var (fd-stream-ibuf ,stream-var)))
1055        (loop
1056          (when (>= (- (buffer-tail ,buffer-var)
1057                       (buffer-head ,buffer-var))
1058                    ,bytes-var)
1059            (return))
1060          (refill-input-buffer ,stream-var)))))
1061
1062 (defmacro input-wrapper/variable-width ((stream bytes eof-error eof-value)
1063                                         &body read-forms)
1064   (let ((stream-var (gensym "STREAM"))
1065         (retry-var (gensym "RETRY"))
1066         (element-var (gensym "ELT")))
1067     `(let* ((,stream-var ,stream)
1068             (ibuf (fd-stream-ibuf ,stream-var))
1069             (size nil))
1070        (block use-instead
1071          (when (fd-stream-eof-forced-p ,stream-var)
1072            (setf (fd-stream-eof-forced-p ,stream-var) nil)
1073            (return-from use-instead
1074              (eof-or-lose ,stream-var ,eof-error ,eof-value)))
1075          (let ((,element-var nil)
1076                (decode-break-reason nil))
1077            (do ((,retry-var t))
1078                ((not ,retry-var))
1079              (if (> (length (fd-stream-instead ,stream-var)) 0)
1080                  (let* ((instead (fd-stream-instead ,stream-var))
1081                         (result (vector-pop instead))
1082                         (pointer (fill-pointer instead)))
1083                    (when (= pointer 0)
1084                      (setf (fd-stream-listen ,stream-var) nil))
1085                    (return-from use-instead result))
1086                  (unless
1087                      (catch 'eof-input-catcher
1088                        (setf decode-break-reason
1089                              (block decode-break-reason
1090                                (input-at-least ,stream-var 1)
1091                                (let* ((byte (sap-ref-8 (buffer-sap ibuf)
1092                                                        (buffer-head ibuf))))
1093                                  (declare (ignorable byte))
1094                                  (setq size ,bytes)
1095                                  (input-at-least ,stream-var size)
1096                                  (setq ,element-var (locally ,@read-forms))
1097                                  (setq ,retry-var nil))
1098                                nil))
1099                        (when decode-break-reason
1100                          (when (stream-decoding-error-and-handle
1101                                 stream decode-break-reason)
1102                            (setq ,retry-var nil)
1103                            (throw 'eof-input-catcher nil)))
1104                        t)
1105                    (let ((octet-count (- (buffer-tail ibuf)
1106                                          (buffer-head ibuf))))
1107                      (when (or (zerop octet-count)
1108                                (and (not ,element-var)
1109                                     (not decode-break-reason)
1110                                     (stream-decoding-error-and-handle
1111                                      stream octet-count)))
1112                        (setq ,retry-var nil))))))
1113            (cond (,element-var
1114                   (incf (buffer-head ibuf) size)
1115                   ,element-var)
1116                  (t
1117                   (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
1118
1119 ;;; a macro to wrap around all input routines to handle EOF-ERROR noise
1120 (defmacro input-wrapper ((stream bytes eof-error eof-value) &body read-forms)
1121   (let ((stream-var (gensym "STREAM"))
1122         (element-var (gensym "ELT")))
1123     `(let* ((,stream-var ,stream)
1124             (ibuf (fd-stream-ibuf ,stream-var)))
1125        (if (> (length (fd-stream-instead ,stream-var)) 0)
1126            (bug "INSTEAD not empty in INPUT-WRAPPER for ~S" ,stream-var)
1127            (let ((,element-var
1128                   (catch 'eof-input-catcher
1129                     (input-at-least ,stream-var ,bytes)
1130                     (locally ,@read-forms))))
1131              (cond (,element-var
1132                     (incf (buffer-head (fd-stream-ibuf ,stream-var)) ,bytes)
1133                     ,element-var)
1134                    (t
1135                     (eof-or-lose ,stream-var ,eof-error ,eof-value))))))))
1136
1137 (defmacro def-input-routine/variable-width (name
1138                                             (type external-format size sap head)
1139                                             &rest body)
1140   `(progn
1141      (defun ,name (stream eof-error eof-value)
1142        (input-wrapper/variable-width (stream ,size eof-error eof-value)
1143          (let ((,sap (buffer-sap ibuf))
1144                (,head (buffer-head ibuf)))
1145            ,@body)))
1146      (setf *input-routines*
1147            (nconc *input-routines*
1148                   (list (list ',type ',name 1 ',external-format))))))
1149
1150 (defmacro def-input-routine (name
1151                              (type size sap head)
1152                              &rest body)
1153   `(progn
1154      (defun ,name (stream eof-error eof-value)
1155        (input-wrapper (stream ,size eof-error eof-value)
1156          (let ((,sap (buffer-sap ibuf))
1157                (,head (buffer-head ibuf)))
1158            ,@body)))
1159      (setf *input-routines*
1160            (nconc *input-routines*
1161                   (list (list ',type ',name ',size nil))))))
1162
1163 ;;; STREAM-IN routine for reading a string char
1164 (def-input-routine input-character
1165                    (character 1 sap head)
1166   (code-char (sap-ref-8 sap head)))
1167
1168 ;;; STREAM-IN routine for reading an unsigned 8 bit number
1169 (def-input-routine input-unsigned-8bit-byte
1170                    ((unsigned-byte 8) 1 sap head)
1171   (sap-ref-8 sap head))
1172
1173 ;;; STREAM-IN routine for reading a signed 8 bit number
1174 (def-input-routine input-signed-8bit-number
1175                    ((signed-byte 8) 1 sap head)
1176   (signed-sap-ref-8 sap head))
1177
1178 ;;; STREAM-IN routine for reading an unsigned 16 bit number
1179 (def-input-routine input-unsigned-16bit-byte
1180                    ((unsigned-byte 16) 2 sap head)
1181   (sap-ref-16 sap head))
1182
1183 ;;; STREAM-IN routine for reading a signed 16 bit number
1184 (def-input-routine input-signed-16bit-byte
1185                    ((signed-byte 16) 2 sap head)
1186   (signed-sap-ref-16 sap head))
1187
1188 ;;; STREAM-IN routine for reading a unsigned 32 bit number
1189 (def-input-routine input-unsigned-32bit-byte
1190                    ((unsigned-byte 32) 4 sap head)
1191   (sap-ref-32 sap head))
1192
1193 ;;; STREAM-IN routine for reading a signed 32 bit number
1194 (def-input-routine input-signed-32bit-byte
1195                    ((signed-byte 32) 4 sap head)
1196   (signed-sap-ref-32 sap head))
1197
1198 #+#.(cl:if (cl:= sb!vm:n-word-bits 64) '(and) '(or))
1199 (progn
1200   (def-input-routine input-unsigned-64bit-byte
1201       ((unsigned-byte 64) 8 sap head)
1202     (sap-ref-64 sap head))
1203   (def-input-routine input-signed-64bit-byte
1204       ((signed-byte 64) 8 sap head)
1205     (signed-sap-ref-64 sap head)))
1206
1207 ;;; Find an input routine to use given the type. Return as multiple
1208 ;;; values the routine, the real type transfered, and the number of
1209 ;;; bytes per element (and for character types string input routine).
1210 (defun pick-input-routine (type &optional external-format)
1211   (when (subtypep type 'character)
1212     (let ((entry (get-external-format external-format)))
1213       (when entry
1214         (return-from pick-input-routine
1215           (values (ef-read-char-fun entry)
1216                   'character
1217                   1
1218                   (ef-read-n-chars-fun entry)
1219                   (canonize-external-format external-format entry))))))
1220   (dolist (entry *input-routines*)
1221     (when (and (subtypep type (first entry))
1222                (or (not (fourth entry))
1223                    (eq external-format (fourth entry))))
1224       (return-from pick-input-routine
1225         (values (symbol-function (second entry))
1226                 (first entry)
1227                 (third entry)))))
1228   ;; FIXME: let's do it the hard way, then (but ignore things like
1229   ;; endianness, efficiency, and the necessary coupling between these
1230   ;; and the output routines).  -- CSR, 2004-02-09
1231   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
1232         if (subtypep type `(unsigned-byte ,i))
1233         do (return-from pick-input-routine
1234              (values
1235               (lambda (stream eof-error eof-value)
1236                 (input-wrapper (stream (/ i 8) eof-error eof-value)
1237                   (let ((sap (buffer-sap ibuf))
1238                         (head (buffer-head ibuf)))
1239                     (loop for j from 0 below (/ i 8)
1240                           with result = 0
1241                           do (setf result
1242                                    (+ (* 256 result)
1243                                       (sap-ref-8 sap (+ head j))))
1244                           finally (return result)))))
1245               `(unsigned-byte ,i)
1246               (/ i 8))))
1247   (loop for i from 40 by 8 to 1024 ; ARB (well, KLUDGE really)
1248         if (subtypep type `(signed-byte ,i))
1249         do (return-from pick-input-routine
1250              (values
1251               (lambda (stream eof-error eof-value)
1252                 (input-wrapper (stream (/ i 8) eof-error eof-value)
1253                   (let ((sap (buffer-sap ibuf))
1254                         (head (buffer-head ibuf)))
1255                     (loop for j from 0 below (/ i 8)
1256                           with result = 0
1257                           do (setf result
1258                                    (+ (* 256 result)
1259                                       (sap-ref-8 sap (+ head j))))
1260                           finally (return (if (logbitp (1- i) result)
1261                                               (dpb result (byte i 0) -1)
1262                                               result))))))
1263               `(signed-byte ,i)
1264               (/ i 8)))))
1265
1266 ;;; the N-BIN method for FD-STREAMs
1267 ;;;
1268 ;;; Note that this blocks in UNIX-READ. It is generally used where
1269 ;;; there is a definite amount of reading to be done, so blocking
1270 ;;; isn't too problematical.
1271 (defun fd-stream-read-n-bytes (stream buffer start requested eof-error-p
1272                                &aux (total-copied 0))
1273   (declare (type fd-stream stream))
1274   (declare (type index start requested total-copied))
1275   (aver (= (length (fd-stream-instead stream)) 0))
1276   (do ()
1277       (nil)
1278     (let* ((remaining-request (- requested total-copied))
1279            (ibuf (fd-stream-ibuf stream))
1280            (head (buffer-head ibuf))
1281            (tail (buffer-tail ibuf))
1282            (available (- tail head))
1283            (n-this-copy (min remaining-request available))
1284            (this-start (+ start total-copied))
1285            (this-end (+ this-start n-this-copy))
1286            (sap (buffer-sap ibuf)))
1287       (declare (type index remaining-request head tail available))
1288       (declare (type index n-this-copy))
1289       ;; Copy data from stream buffer into user's buffer.
1290       (%byte-blt sap head buffer this-start this-end)
1291       (incf (buffer-head ibuf) n-this-copy)
1292       (incf total-copied n-this-copy)
1293       ;; Maybe we need to refill the stream buffer.
1294       (cond (;; If there were enough data in the stream buffer, we're done.
1295              (eql total-copied requested)
1296              (return total-copied))
1297             (;; If EOF, we're done in another way.
1298              (null (catch 'eof-input-catcher (refill-input-buffer stream)))
1299              (if eof-error-p
1300                  (error 'end-of-file :stream stream)
1301                  (return total-copied)))
1302             ;; Otherwise we refilled the stream buffer, so fall
1303             ;; through into another pass of the loop.
1304             ))))
1305
1306 (defun fd-stream-resync (stream)
1307   (let ((entry (get-external-format (fd-stream-external-format stream))))
1308     (when entry
1309       (funcall (ef-resync-fun entry) stream))))
1310
1311 (defun get-fd-stream-character-sizer (stream)
1312   (let ((entry (get-external-format (fd-stream-external-format stream))))
1313     (when entry
1314       (ef-bytes-for-char-fun entry))))
1315
1316 (defun fd-stream-character-size (stream char)
1317   (let ((sizer (get-fd-stream-character-sizer stream)))
1318     (when sizer (funcall sizer char))))
1319
1320 (defun fd-stream-string-size (stream string)
1321   (let ((sizer (get-fd-stream-character-sizer stream)))
1322     (when sizer
1323       (loop for char across string summing (funcall sizer char)))))
1324
1325 (defun find-external-format (external-format)
1326   (when external-format
1327     (get-external-format external-format)))
1328
1329 (defun variable-width-external-format-p (ef-entry)
1330   (and ef-entry (not (null (ef-resync-fun ef-entry)))))
1331
1332 (defun bytes-for-char-fun (ef-entry)
1333   (if ef-entry (ef-bytes-for-char-fun ef-entry) (constantly 1)))
1334
1335 (defmacro define-unibyte-mapping-external-format
1336     (canonical-name (&rest other-names) &body exceptions)
1337   (let ((->code-name (symbolicate canonical-name '->code-mapper))
1338         (code->-name (symbolicate 'code-> canonical-name '-mapper))
1339         (get-bytes-name (symbolicate 'get- canonical-name '-bytes))
1340         (string->-name (symbolicate 'string-> canonical-name))
1341         (define-string*-name (symbolicate 'define- canonical-name '->string*))
1342         (string*-name (symbolicate canonical-name '->string*))
1343         (define-string-name (symbolicate 'define- canonical-name '->string))
1344         (string-name (symbolicate canonical-name '->string))
1345         (->string-aref-name (symbolicate canonical-name '->string-aref)))
1346     `(progn
1347        (define-unibyte-mapper ,->code-name ,code->-name
1348          ,@exceptions)
1349        (declaim (inline ,get-bytes-name))
1350        (defun ,get-bytes-name (string pos)
1351          (declare (optimize speed (safety 0))
1352                   (type simple-string string)
1353                   (type array-range pos))
1354          (get-latin-bytes #',code->-name ,canonical-name string pos))
1355        (defun ,string->-name (string sstart send null-padding)
1356          (declare (optimize speed (safety 0))
1357                   (type simple-string string)
1358                   (type array-range sstart send))
1359          (values (string->latin% string sstart send #',get-bytes-name null-padding)))
1360        (defmacro ,define-string*-name (accessor type)
1361          (declare (ignore type))
1362          (let ((name (make-od-name ',string*-name accessor)))
1363            `(progn
1364               (defun ,name (string sstart send array astart aend)
1365                 (,(make-od-name 'latin->string* accessor)
1366                   string sstart send array astart aend #',',->code-name)))))
1367        (instantiate-octets-definition ,define-string*-name)
1368        (defmacro ,define-string-name (accessor type)
1369          (declare (ignore type))
1370          (let ((name (make-od-name ',string-name accessor)))
1371            `(progn
1372               (defun ,name (array astart aend)
1373                 (,(make-od-name 'latin->string accessor)
1374                   array astart aend #',',->code-name)))))
1375        (instantiate-octets-definition ,define-string-name)
1376        (define-unibyte-external-format ,canonical-name ,other-names
1377          (let ((octet (,code->-name bits)))
1378            (if octet
1379                (setf (sap-ref-8 sap tail) octet)
1380                (external-format-encoding-error stream bits)))
1381          (let ((code (,->code-name byte)))
1382            (if code
1383                (code-char code)
1384                (return-from decode-break-reason 1)))
1385          ,->string-aref-name
1386          ,string->-name))))
1387
1388 (defmacro define-unibyte-external-format
1389     (canonical-name (&rest other-names)
1390      out-form in-form octets-to-string-symbol string-to-octets-symbol)
1391   `(define-external-format/variable-width (,canonical-name ,@other-names)
1392      t #\? 1
1393      ,out-form
1394      1
1395      ,in-form
1396      ,octets-to-string-symbol
1397      ,string-to-octets-symbol))
1398
1399 (defmacro define-external-format/variable-width
1400     (external-format output-restart replacement-character
1401      out-size-expr out-expr in-size-expr in-expr
1402      octets-to-string-sym string-to-octets-sym)
1403   (let* ((name (first external-format))
1404          (out-function (symbolicate "OUTPUT-BYTES/" name))
1405          (format (format nil "OUTPUT-CHAR-~A-~~A-BUFFERED" (string name)))
1406          (in-function (symbolicate "FD-STREAM-READ-N-CHARACTERS/" name))
1407          (in-char-function (symbolicate "INPUT-CHAR/" name))
1408          (resync-function (symbolicate "RESYNC/" name))
1409          (size-function (symbolicate "BYTES-FOR-CHAR/" name))
1410          (read-c-string-function (symbolicate "READ-FROM-C-STRING/" name))
1411          (output-c-string-function (symbolicate "OUTPUT-TO-C-STRING/" name))
1412          (n-buffer (gensym "BUFFER")))
1413     `(progn
1414       (defun ,size-function (byte)
1415         (declare (ignorable byte))
1416         ,out-size-expr)
1417       (defun ,out-function (stream string flush-p start end)
1418         (let ((start (or start 0))
1419               (end (or end (length string))))
1420           (declare (type index start end))
1421           (synchronize-stream-output stream)
1422           (unless (<= 0 start end (length string))
1423             (sequence-bounding-indices-bad-error string start end))
1424           (do ()
1425               ((= end start))
1426             (let ((obuf (fd-stream-obuf stream)))
1427               (string-dispatch (simple-base-string
1428                                 #!+sb-unicode (simple-array character (*))
1429                                 string)
1430                   string
1431                 (let ((len (buffer-length obuf))
1432                       (sap (buffer-sap obuf))
1433                       ;; FIXME: Rename
1434                       (tail (buffer-tail obuf)))
1435                   (declare (type index tail)
1436                            ;; STRING bounds have already been checked.
1437                            (optimize (safety 0)))
1438                   (,@(if output-restart
1439                          `(catch 'output-nothing)
1440                          `(progn))
1441                      (do* ()
1442                           ((or (= start end) (< (- len tail) 4)))
1443                        (let* ((byte (aref string start))
1444                               (bits (char-code byte))
1445                               (size ,out-size-expr))
1446                          ,out-expr
1447                          (incf tail size)
1448                          (setf (buffer-tail obuf) tail)
1449                          (incf start)))
1450                      (go flush))
1451                   ;; Exited via CATCH: skip the current character.
1452                   (incf start))))
1453            flush
1454             (when (< start end)
1455               (flush-output-buffer stream)))
1456           (when flush-p
1457             (flush-output-buffer stream))))
1458       (def-output-routines/variable-width (,format
1459                                            ,out-size-expr
1460                                            ,output-restart
1461                                            ,external-format
1462                                            (:none character)
1463                                            (:line character)
1464                                            (:full character))
1465           (if (eql byte #\Newline)
1466               (setf (fd-stream-char-pos stream) 0)
1467               (incf (fd-stream-char-pos stream)))
1468         (let ((bits (char-code byte))
1469               (sap (buffer-sap obuf))
1470               (tail (buffer-tail obuf)))
1471           ,out-expr))
1472       (defun ,in-function (stream buffer start requested eof-error-p
1473                            &aux (total-copied 0))
1474         (declare (type fd-stream stream)
1475                  (type index start requested total-copied)
1476                  (type
1477                   (simple-array character (#.+ansi-stream-in-buffer-length+))
1478                   buffer))
1479         (when (fd-stream-eof-forced-p stream)
1480           (setf (fd-stream-eof-forced-p stream) nil)
1481           (return-from ,in-function 0))
1482         (do ((instead (fd-stream-instead stream)))
1483             ((= (fill-pointer instead) 0)
1484              (setf (fd-stream-listen stream) nil))
1485           (setf (aref buffer (+ start total-copied)) (vector-pop instead))
1486           (incf total-copied)
1487           (when (= requested total-copied)
1488             (when (= (fill-pointer instead) 0)
1489               (setf (fd-stream-listen stream) nil))
1490             (return-from ,in-function total-copied)))
1491         (do ()
1492             (nil)
1493           (let* ((ibuf (fd-stream-ibuf stream))
1494                  (head (buffer-head ibuf))
1495                  (tail (buffer-tail ibuf))
1496                  (sap (buffer-sap ibuf))
1497                  (decode-break-reason nil))
1498             (declare (type index head tail))
1499             ;; Copy data from stream buffer into user's buffer.
1500             (do ((size nil nil))
1501                 ((or (= tail head) (= requested total-copied)))
1502               (setf decode-break-reason
1503                     (block decode-break-reason
1504                       (let ((byte (sap-ref-8 sap head)))
1505                         (declare (ignorable byte))
1506                         (setq size ,in-size-expr)
1507                         (when (> size (- tail head))
1508                           (return))
1509                         (setf (aref buffer (+ start total-copied)) ,in-expr)
1510                         (incf total-copied)
1511                         (incf head size))
1512                       nil))
1513               (setf (buffer-head ibuf) head)
1514               (when decode-break-reason
1515                 ;; If we've already read some characters on when the invalid
1516                 ;; code sequence is detected, we return immediately. The
1517                 ;; handling of the error is deferred until the next call
1518                 ;; (where this check will be false). This allows establishing
1519                 ;; high-level handlers for decode errors (for example
1520                 ;; automatically resyncing in Lisp comments).
1521                 (when (plusp total-copied)
1522                   (return-from ,in-function total-copied))
1523                 (when (stream-decoding-error-and-handle
1524                        stream decode-break-reason)
1525                   (if eof-error-p
1526                       (error 'end-of-file :stream stream)
1527                       (return-from ,in-function total-copied)))
1528                 ;; we might have been given stuff to use instead, so
1529                 ;; we have to return (and trust our caller to know
1530                 ;; what to do about TOTAL-COPIED being 0).
1531                 (return-from ,in-function total-copied)))
1532             (setf (buffer-head ibuf) head)
1533             ;; Maybe we need to refill the stream buffer.
1534             (cond ( ;; If there were enough data in the stream buffer, we're done.
1535                    (= total-copied requested)
1536                    (return total-copied))
1537                   ( ;; If EOF, we're done in another way.
1538                    (or (eq decode-break-reason 'eof)
1539                        (null (catch 'eof-input-catcher
1540                                (refill-input-buffer stream))))
1541                    (if eof-error-p
1542                        (error 'end-of-file :stream stream)
1543                        (return total-copied)))
1544                   ;; Otherwise we refilled the stream buffer, so fall
1545                   ;; through into another pass of the loop.
1546                   ))))
1547       (def-input-routine/variable-width ,in-char-function (character
1548                                                            ,external-format
1549                                                            ,in-size-expr
1550                                                            sap head)
1551         (let ((byte (sap-ref-8 sap head)))
1552           (declare (ignorable byte))
1553           ,in-expr))
1554       (defun ,resync-function (stream)
1555         (let ((ibuf (fd-stream-ibuf stream)))
1556           (catch 'eof-input-catcher
1557             (loop
1558                (incf (buffer-head ibuf))
1559                (input-at-least stream 1)
1560                (unless (block decode-break-reason
1561                          (let* ((sap (buffer-sap ibuf))
1562                                 (head (buffer-head ibuf))
1563                                 (byte (sap-ref-8 sap head))
1564                                 (size ,in-size-expr))
1565                            (declare (ignorable byte))
1566                            (input-at-least stream size)
1567                            (setf head (buffer-head ibuf))
1568                            ,in-expr)
1569                          nil)
1570                  (return))))))
1571       (defun ,read-c-string-function (sap element-type)
1572         (declare (type system-area-pointer sap))
1573         (locally
1574             (declare (optimize (speed 3) (safety 0)))
1575           (let* ((stream ,name)
1576                  (size 0) (head 0) (byte 0) (char nil)
1577                  (decode-break-reason nil)
1578                  (length (dotimes (count (1- ARRAY-DIMENSION-LIMIT) count)
1579                            (setf decode-break-reason
1580                                  (block decode-break-reason
1581                                    (setf byte (sap-ref-8 sap head)
1582                                          size ,in-size-expr
1583                                          char ,in-expr)
1584                                    (incf head size)
1585                                    nil))
1586                            (when decode-break-reason
1587                              (c-string-decoding-error ,name decode-break-reason))
1588                            (when (zerop (char-code char))
1589                              (return count))))
1590                  (string (make-string length :element-type element-type)))
1591             (declare (ignorable stream)
1592                      (type index head length) ;; size
1593                      (type (unsigned-byte 8) byte)
1594                      (type (or null character) char)
1595                      (type string string))
1596             (setf head 0)
1597             (dotimes (index length string)
1598               (setf decode-break-reason
1599                     (block decode-break-reason
1600                       (setf byte (sap-ref-8 sap head)
1601                             size ,in-size-expr
1602                             char ,in-expr)
1603                       (incf head size)
1604                       nil))
1605               (when decode-break-reason
1606                 (c-string-decoding-error ,name decode-break-reason))
1607               (setf (aref string index) char)))))
1608
1609       (defun ,output-c-string-function (string)
1610         (declare (type simple-string string))
1611         (locally
1612             (declare (optimize (speed 3) (safety 0)))
1613           (let* ((length (length string))
1614                  (char-length (make-array (1+ length) :element-type 'index))
1615                  (buffer-length
1616                   (+ (loop for i of-type index below length
1617                         for byte of-type character = (aref string i)
1618                         for bits = (char-code byte)
1619                         sum (setf (aref char-length i)
1620                                   (the index ,out-size-expr)))
1621                      (let* ((byte (code-char 0))
1622                             (bits (char-code byte)))
1623                        (declare (ignorable byte bits))
1624                        (setf (aref char-length length)
1625                              (the index ,out-size-expr)))))
1626                  (tail 0)
1627                  (,n-buffer (make-array buffer-length
1628                                         :element-type '(unsigned-byte 8)))
1629                  stream)
1630             (declare (type index length buffer-length tail)
1631                      (type null stream)
1632                      (ignorable stream))
1633             (with-pinned-objects (,n-buffer)
1634               (let ((sap (vector-sap ,n-buffer)))
1635                 (declare (system-area-pointer sap))
1636                 (loop for i of-type index below length
1637                       for byte of-type character = (aref string i)
1638                       for bits = (char-code byte)
1639                       for size of-type index = (aref char-length i)
1640                       do (prog1
1641                              ,out-expr
1642                            (incf tail size)))
1643                 (let* ((bits 0)
1644                        (byte (code-char bits))
1645                        (size (aref char-length length)))
1646                   (declare (ignorable bits byte size))
1647                   ,out-expr)))
1648             ,n-buffer)))
1649
1650       (let ((entry (%make-external-format
1651                     :names ',external-format
1652                     :default-replacement-character ,replacement-character
1653                     :read-n-chars-fun #',in-function
1654                     :read-char-fun #',in-char-function
1655                     :write-n-bytes-fun #',out-function
1656                     ,@(mapcan #'(lambda (buffering)
1657                                   (list (intern (format nil "WRITE-CHAR-~A-BUFFERED-FUN" buffering) :keyword)
1658                                         `#',(intern (format nil format (string buffering)))))
1659                               '(:none :line :full))
1660                     :resync-fun #',resync-function
1661                     :bytes-for-char-fun #',size-function
1662                     :read-c-string-fun #',read-c-string-function
1663                     :write-c-string-fun #',output-c-string-function
1664                     :octets-to-string-fun (lambda (&rest rest)
1665                                             (declare (dynamic-extent rest))
1666                                             (apply ',octets-to-string-sym rest))
1667                     :string-to-octets-fun (lambda (&rest rest)
1668                                             (declare (dynamic-extent rest))
1669                                             (apply ',string-to-octets-sym rest)))))
1670         (dolist (ef ',external-format)
1671           (setf (gethash ef *external-formats*) entry))))))
1672 \f
1673 ;;;; utility functions (misc routines, etc)
1674
1675 ;;; Fill in the various routine slots for the given type. INPUT-P and
1676 ;;; OUTPUT-P indicate what slots to fill. The buffering slot must be
1677 ;;; set prior to calling this routine.
1678 (defun set-fd-stream-routines (fd-stream element-type external-format
1679                                input-p output-p buffer-p)
1680   (let* ((target-type (case element-type
1681                         (unsigned-byte '(unsigned-byte 8))
1682                         (signed-byte '(signed-byte 8))
1683                         (:default 'character)
1684                         (t element-type)))
1685          (character-stream-p (subtypep target-type 'character))
1686          (bivalent-stream-p (eq element-type :default))
1687          normalized-external-format
1688          (bin-routine #'ill-bin)
1689          (bin-type nil)
1690          (bin-size nil)
1691          (cin-routine #'ill-in)
1692          (cin-type nil)
1693          (cin-size nil)
1694          (input-type nil)           ;calculated from bin-type/cin-type
1695          (input-size nil)           ;calculated from bin-size/cin-size
1696          (read-n-characters #'ill-in)
1697          (bout-routine #'ill-bout)
1698          (bout-type nil)
1699          (bout-size nil)
1700          (cout-routine #'ill-out)
1701          (cout-type nil)
1702          (cout-size nil)
1703          (output-type nil)
1704          (output-size nil)
1705          (output-bytes #'ill-bout))
1706
1707     ;; Ensure that we have buffers in the desired direction(s) only,
1708     ;; getting new ones and dropping/resetting old ones as necessary.
1709     (let ((obuf (fd-stream-obuf fd-stream)))
1710       (if output-p
1711           (if obuf
1712               (reset-buffer obuf)
1713               (setf (fd-stream-obuf fd-stream) (get-buffer)))
1714           (when obuf
1715             (setf (fd-stream-obuf fd-stream) nil)
1716             (release-buffer obuf))))
1717
1718     (let ((ibuf (fd-stream-ibuf fd-stream)))
1719       (if input-p
1720           (if ibuf
1721               (reset-buffer ibuf)
1722               (setf (fd-stream-ibuf fd-stream) (get-buffer)))
1723           (when ibuf
1724             (setf (fd-stream-ibuf fd-stream) nil)
1725             (release-buffer ibuf))))
1726
1727     ;; FIXME: Why only for output? Why unconditionally?
1728     (when output-p
1729       (setf (fd-stream-char-pos fd-stream) 0))
1730
1731     (when (and character-stream-p
1732                (eq external-format :default))
1733       (/show0 "/getting default external format")
1734       (setf external-format (default-external-format)))
1735
1736     (when input-p
1737       (when (or (not character-stream-p) bivalent-stream-p)
1738         (multiple-value-setq (bin-routine bin-type bin-size read-n-characters
1739                                           normalized-external-format)
1740           (pick-input-routine (if bivalent-stream-p '(unsigned-byte 8)
1741                                   target-type)
1742                               external-format))
1743         (unless bin-routine
1744           (error "could not find any input routine for ~S" target-type)))
1745       (when character-stream-p
1746         (multiple-value-setq (cin-routine cin-type cin-size read-n-characters
1747                                           normalized-external-format)
1748           (pick-input-routine target-type external-format))
1749         (unless cin-routine
1750           (error "could not find any input routine for ~S" target-type)))
1751       (setf (fd-stream-in fd-stream) cin-routine
1752             (fd-stream-bin fd-stream) bin-routine)
1753       ;; character type gets preferential treatment
1754       (setf input-size (or cin-size bin-size))
1755       (setf input-type (or cin-type bin-type))
1756       (when normalized-external-format
1757         (setf (fd-stream-external-format fd-stream)
1758               normalized-external-format))
1759       (when (= (or cin-size 1) (or bin-size 1) 1)
1760         (setf (fd-stream-n-bin fd-stream) ;XXX
1761               (if (and character-stream-p (not bivalent-stream-p))
1762                   read-n-characters
1763                   #'fd-stream-read-n-bytes))
1764         ;; Sometimes turn on fast-read-char/fast-read-byte.  Switch on
1765         ;; for character and (unsigned-byte 8) streams.  In these
1766         ;; cases, fast-read-* will read from the
1767         ;; ansi-stream-(c)in-buffer, saving function calls.
1768         ;; Otherwise, the various data-reading functions in the stream
1769         ;; structure will be called.
1770         (when (and buffer-p
1771                    (not bivalent-stream-p)
1772                    ;; temporary disable on :io streams
1773                    (not output-p))
1774           (cond (character-stream-p
1775                  (setf (ansi-stream-cin-buffer fd-stream)
1776                        (make-array +ansi-stream-in-buffer-length+
1777                                    :element-type 'character)))
1778                 ((equal target-type '(unsigned-byte 8))
1779                  (setf (ansi-stream-in-buffer fd-stream)
1780                        (make-array +ansi-stream-in-buffer-length+
1781                                    :element-type '(unsigned-byte 8))))))))
1782
1783     (when output-p
1784       (when (or (not character-stream-p) bivalent-stream-p)
1785         (multiple-value-setq (bout-routine bout-type bout-size output-bytes
1786                                            normalized-external-format)
1787           (pick-output-routine (if bivalent-stream-p
1788                                    '(unsigned-byte 8)
1789                                    target-type)
1790                                (fd-stream-buffering fd-stream)
1791                                external-format))
1792         (unless bout-routine
1793           (error "could not find any output routine for ~S buffered ~S"
1794                  (fd-stream-buffering fd-stream)
1795                  target-type)))
1796       (when character-stream-p
1797         (multiple-value-setq (cout-routine cout-type cout-size output-bytes
1798                                            normalized-external-format)
1799           (pick-output-routine target-type
1800                                (fd-stream-buffering fd-stream)
1801                                external-format))
1802         (unless cout-routine
1803           (error "could not find any output routine for ~S buffered ~S"
1804                  (fd-stream-buffering fd-stream)
1805                  target-type)))
1806       (when normalized-external-format
1807         (setf (fd-stream-external-format fd-stream)
1808               normalized-external-format))
1809       (when character-stream-p
1810         (setf (fd-stream-output-bytes fd-stream) output-bytes))
1811       (setf (fd-stream-out fd-stream) cout-routine
1812             (fd-stream-bout fd-stream) bout-routine
1813             (fd-stream-sout fd-stream) (if (eql cout-size 1)
1814                                            #'fd-sout #'ill-out))
1815       (setf output-size (or cout-size bout-size))
1816       (setf output-type (or cout-type bout-type)))
1817
1818     (when (and input-size output-size
1819                (not (eq input-size output-size)))
1820       (error "Element sizes for input (~S:~S) and output (~S:~S) differ?"
1821              input-type input-size
1822              output-type output-size))
1823     (setf (fd-stream-element-size fd-stream)
1824           (or input-size output-size))
1825
1826     (setf (fd-stream-element-type fd-stream)
1827           (cond ((equal input-type output-type)
1828                  input-type)
1829                 ((null output-type)
1830                  input-type)
1831                 ((null input-type)
1832                  output-type)
1833                 ((subtypep input-type output-type)
1834                  input-type)
1835                 ((subtypep output-type input-type)
1836                  output-type)
1837                 (t
1838                  (error "Input type (~S) and output type (~S) are unrelated?"
1839                         input-type
1840                         output-type))))))
1841
1842 ;;; Handles the resource-release aspects of stream closing, and marks
1843 ;;; it as closed.
1844 (defun release-fd-stream-resources (fd-stream)
1845   (handler-case
1846       (without-interrupts
1847         ;; Drop handlers first.
1848         (when (fd-stream-handler fd-stream)
1849           (remove-fd-handler (fd-stream-handler fd-stream))
1850           (setf (fd-stream-handler fd-stream) nil))
1851         ;; Disable interrupts so that a asynch unwind will not leave
1852         ;; us with a dangling finalizer (that would close the same
1853         ;; --possibly reassigned-- FD again), or a stream with a closed
1854         ;; FD that appears open.
1855         (sb!unix:unix-close (fd-stream-fd fd-stream))
1856         (set-closed-flame fd-stream)
1857         (when (fboundp 'cancel-finalization)
1858           (cancel-finalization fd-stream)))
1859     ;; On error unwind from WITHOUT-INTERRUPTS.
1860     (serious-condition (e)
1861       (error e)))
1862   ;; Release all buffers. If this is undone, or interrupted,
1863   ;; we're still safe: buffers have finalizers of their own.
1864   (release-fd-stream-buffers fd-stream))
1865
1866 ;;; Flushes the current input buffer and any supplied replacements,
1867 ;;; and returns the input buffer, and the amount of of flushed input
1868 ;;; in bytes.
1869 (defun flush-input-buffer (stream)
1870   (let ((unread (length (fd-stream-instead stream))))
1871     (setf (fill-pointer (fd-stream-instead stream)) 0)
1872     (let ((ibuf (fd-stream-ibuf stream)))
1873       (if ibuf
1874           (let ((head (buffer-head ibuf))
1875                 (tail (buffer-tail ibuf)))
1876             (values (reset-buffer ibuf) (- (+ unread tail) head)))
1877           (values nil unread)))))
1878
1879 (defun fd-stream-clear-input (stream)
1880   (flush-input-buffer stream)
1881   #!+win32
1882   (progn
1883     (sb!win32:fd-clear-input (fd-stream-fd stream))
1884     (setf (fd-stream-listen stream) nil))
1885   #!-win32
1886   (catch 'eof-input-catcher
1887     (loop until (sysread-may-block-p stream)
1888           do
1889           (refill-input-buffer stream)
1890           (reset-buffer (fd-stream-ibuf stream)))
1891     t))
1892
1893 ;;; Handle miscellaneous operations on FD-STREAM.
1894 (defun fd-stream-misc-routine (fd-stream operation &optional arg1 arg2)
1895   (declare (ignore arg2))
1896   (case operation
1897     (:listen
1898      (labels ((do-listen ()
1899                 (let ((ibuf (fd-stream-ibuf fd-stream)))
1900                   (or (not (eql (buffer-head ibuf) (buffer-tail ibuf)))
1901                       (fd-stream-listen fd-stream)
1902                       #!+win32
1903                       (sb!win32:fd-listen (fd-stream-fd fd-stream))
1904                       #!-win32
1905                       ;; If the read can block, LISTEN will certainly return NIL.
1906                       (if (sysread-may-block-p fd-stream)
1907                           nil
1908                           ;; Otherwise select(2) and CL:LISTEN have slightly
1909                           ;; different semantics.  The former returns that an FD
1910                           ;; is readable when a read operation wouldn't block.
1911                           ;; That includes EOF.  However, LISTEN must return NIL
1912                           ;; at EOF.
1913                           (progn (catch 'eof-input-catcher
1914                                    ;; r-b/f too calls select, but it shouldn't
1915                                    ;; block as long as read can return once w/o
1916                                    ;; blocking
1917                                    (refill-input-buffer fd-stream))
1918                                  ;; At this point either IBUF-HEAD != IBUF-TAIL
1919                                  ;; and FD-STREAM-LISTEN is NIL, in which case
1920                                  ;; we should return T, or IBUF-HEAD ==
1921                                  ;; IBUF-TAIL and FD-STREAM-LISTEN is :EOF, in
1922                                  ;; which case we should return :EOF for this
1923                                  ;; call and all future LISTEN call on this stream.
1924                                  ;; Call ourselves again to determine which case
1925                                  ;; applies.
1926                                  (do-listen)))))))
1927        (do-listen)))
1928     (:unread
1929      (decf (buffer-head (fd-stream-ibuf fd-stream))
1930            (fd-stream-character-size fd-stream arg1)))
1931     (:close
1932      ;; Drop input buffers
1933      (setf (ansi-stream-in-index fd-stream) +ansi-stream-in-buffer-length+
1934            (ansi-stream-cin-buffer fd-stream) nil
1935            (ansi-stream-in-buffer fd-stream) nil)
1936      (cond (arg1
1937             ;; We got us an abort on our hands.
1938             (let ((outputp (fd-stream-obuf fd-stream))
1939                   (file (fd-stream-file fd-stream))
1940                   (orig (fd-stream-original fd-stream)))
1941               ;; This takes care of the important stuff -- everything
1942               ;; rest is cleaning up the file-system, which we cannot
1943               ;; do on some platforms as long as the file is open.
1944               (release-fd-stream-resources fd-stream)
1945               ;; We can't do anything unless we know what file were
1946               ;; dealing with, and we don't want to do anything
1947               ;; strange unless we were writing to the file.
1948               (when (and outputp file)
1949                 (if orig
1950                     ;; If the original is EQ to file we are appending to
1951                     ;; and can just close the file without renaming.
1952                     (unless (eq orig file)
1953                       ;; We have a handle on the original, just revert.
1954                       (multiple-value-bind (okay err)
1955                           (sb!unix:unix-rename orig file)
1956                         ;; FIXME: Why is this a SIMPLE-STREAM-ERROR, and the
1957                         ;; others are SIMPLE-FILE-ERRORS? Surely they should
1958                         ;; all be the same?
1959                         (unless okay
1960                           (error 'simple-stream-error
1961                                  :format-control
1962                                  "~@<Couldn't restore ~S to its original contents ~
1963                                   from ~S while closing ~S: ~2I~_~A~:>"
1964                                  :format-arguments
1965                                  (list file orig fd-stream (strerror err))
1966                                  :stream fd-stream))))
1967                     ;; We can't restore the original, and aren't
1968                     ;; appending, so nuke that puppy.
1969                     ;;
1970                     ;; FIXME: This is currently the fate of superseded
1971                     ;; files, and according to the CLOSE spec this is
1972                     ;; wrong. However, there seems to be no clean way to
1973                     ;; do that that doesn't involve either copying the
1974                     ;; data (bad if the :abort resulted from a full
1975                     ;; disk), or renaming the old file temporarily
1976                     ;; (probably bad because stream opening becomes more
1977                     ;; racy).
1978                     (multiple-value-bind (okay err)
1979                         (sb!unix:unix-unlink file)
1980                       (unless okay
1981                         (error 'simple-file-error
1982                                :pathname file
1983                                :format-control
1984                                "~@<Couldn't remove ~S while closing ~S: ~2I~_~A~:>"
1985                                :format-arguments
1986                                (list file fd-stream (strerror err)))))))))
1987            (t
1988             (finish-fd-stream-output fd-stream)
1989             (let ((orig (fd-stream-original fd-stream)))
1990               (when (and orig (fd-stream-delete-original fd-stream))
1991                 (multiple-value-bind (okay err) (sb!unix:unix-unlink orig)
1992                   (unless okay
1993                     (error 'simple-file-error
1994                            :pathname orig
1995                            :format-control
1996                            "~@<couldn't delete ~S while closing ~S: ~2I~_~A~:>"
1997                            :format-arguments
1998                            (list orig fd-stream (strerror err)))))))
1999             ;; In case of no-abort close, don't *really* close the
2000             ;; stream until the last moment -- the cleaning up of the
2001             ;; original can be done first.
2002             (release-fd-stream-resources fd-stream))))
2003     (:clear-input
2004      (fd-stream-clear-input fd-stream))
2005     (:force-output
2006      (flush-output-buffer fd-stream))
2007     (:finish-output
2008      (finish-fd-stream-output fd-stream))
2009     (:element-type
2010      (fd-stream-element-type fd-stream))
2011     (:external-format
2012      (fd-stream-external-format fd-stream))
2013     (:interactive-p
2014      (= 1 (the (member 0 1)
2015             (sb!unix:unix-isatty (fd-stream-fd fd-stream)))))
2016     (:line-length
2017      80)
2018     (:charpos
2019      (fd-stream-char-pos fd-stream))
2020     (:file-length
2021      (unless (fd-stream-file fd-stream)
2022        ;; This is a TYPE-ERROR because ANSI's species FILE-LENGTH
2023        ;; "should signal an error of type TYPE-ERROR if stream is not
2024        ;; a stream associated with a file". Too bad there's no very
2025        ;; appropriate value for the EXPECTED-TYPE slot..
2026        (error 'simple-type-error
2027               :datum fd-stream
2028               :expected-type 'fd-stream
2029               :format-control "~S is not a stream associated with a file."
2030               :format-arguments (list fd-stream)))
2031      (multiple-value-bind (okay dev ino mode nlink uid gid rdev size
2032                                 atime mtime ctime blksize blocks)
2033          (sb!unix:unix-fstat (fd-stream-fd fd-stream))
2034        (declare (ignore ino nlink uid gid rdev
2035                         atime mtime ctime blksize blocks))
2036        (unless okay
2037          (simple-stream-perror "failed Unix fstat(2) on ~S" fd-stream dev))
2038        (if (zerop mode)
2039            nil
2040            (truncate size (fd-stream-element-size fd-stream)))))
2041     (:file-string-length
2042      (etypecase arg1
2043        (character (fd-stream-character-size fd-stream arg1))
2044        (string (fd-stream-string-size fd-stream arg1))))
2045     (:file-position
2046      (if arg1
2047          (fd-stream-set-file-position fd-stream arg1)
2048          (fd-stream-get-file-position fd-stream)))))
2049
2050 ;; FIXME: Think about this.
2051 ;;
2052 ;; (defun finish-fd-stream-output (fd-stream)
2053 ;;   (let ((timeout (fd-stream-timeout fd-stream)))
2054 ;;     (loop while (fd-stream-output-queue fd-stream)
2055 ;;        ;; FIXME: SIGINT while waiting for a timeout will
2056 ;;        ;; cause a timeout here.
2057 ;;        do (when (and (not (serve-event timeout)) timeout)
2058 ;;             (signal-timeout 'io-timeout
2059 ;;                             :stream fd-stream
2060 ;;                             :direction :write
2061 ;;                             :seconds timeout)))))
2062
2063 (defun finish-fd-stream-output (stream)
2064   (flush-output-buffer stream)
2065   (do ()
2066       ((null (fd-stream-output-queue stream)))
2067     (serve-all-events)))
2068
2069 (defun fd-stream-get-file-position (stream)
2070   (declare (fd-stream stream))
2071   (without-interrupts
2072     (let ((posn (sb!unix:unix-lseek (fd-stream-fd stream) 0 sb!unix:l_incr)))
2073       (declare (type (or (alien sb!unix:off-t) null) posn))
2074       ;; We used to return NIL for errno==ESPIPE, and signal an error
2075       ;; in other failure cases. However, CLHS says to return NIL if
2076       ;; the position cannot be determined -- so that's what we do.
2077       (when (integerp posn)
2078         ;; Adjust for buffered output: If there is any output
2079         ;; buffered, the *real* file position will be larger
2080         ;; than reported by lseek() because lseek() obviously
2081         ;; cannot take into account output we have not sent
2082         ;; yet.
2083         (dolist (buffer (fd-stream-output-queue stream))
2084           (incf posn (- (buffer-tail buffer) (buffer-head buffer))))
2085         (let ((obuf (fd-stream-obuf stream)))
2086           (when obuf
2087             (incf posn (buffer-tail obuf))))
2088         ;; Adjust for unread input: If there is any input
2089         ;; read from UNIX but not supplied to the user of the
2090         ;; stream, the *real* file position will smaller than
2091         ;; reported, because we want to look like the unread
2092         ;; stuff is still available.
2093         (let ((ibuf (fd-stream-ibuf stream)))
2094           (when ibuf
2095             (decf posn (- (buffer-tail ibuf) (buffer-head ibuf)))))
2096         ;; Divide bytes by element size.
2097         (truncate posn (fd-stream-element-size stream))))))
2098
2099 (defun fd-stream-set-file-position (stream position-spec)
2100   (declare (fd-stream stream))
2101   (check-type position-spec
2102               (or (alien sb!unix:off-t) (member nil :start :end))
2103               "valid file position designator")
2104   (tagbody
2105    :again
2106      ;; Make sure we don't have any output pending, because if we
2107      ;; move the file pointer before writing this stuff, it will be
2108      ;; written in the wrong location.
2109      (finish-fd-stream-output stream)
2110      ;; Disable interrupts so that interrupt handlers doing output
2111      ;; won't screw us.
2112      (without-interrupts
2113        (unless (fd-stream-output-finished-p stream)
2114          ;; We got interrupted and more output came our way during
2115          ;; the interrupt. Wrapping the FINISH-FD-STREAM-OUTPUT in
2116          ;; WITHOUT-INTERRUPTS gets nasty as it can signal errors,
2117          ;; so we prefer to do things like this...
2118          (go :again))
2119        ;; Clear out any pending input to force the next read to go to
2120        ;; the disk.
2121        (flush-input-buffer stream)
2122        ;; Trash cached value for listen, so that we check next time.
2123        (setf (fd-stream-listen stream) nil)
2124          ;; Now move it.
2125          (multiple-value-bind (offset origin)
2126              (case position-spec
2127                (:start
2128                 (values 0 sb!unix:l_set))
2129                (:end
2130                 (values 0 sb!unix:l_xtnd))
2131                (t
2132                 (values (* position-spec (fd-stream-element-size stream))
2133                         sb!unix:l_set)))
2134            (declare (type (alien sb!unix:off-t) offset))
2135            (let ((posn (sb!unix:unix-lseek (fd-stream-fd stream)
2136                                            offset origin)))
2137              ;; CLHS says to return true if the file-position was set
2138              ;; succesfully, and NIL otherwise. We are to signal an error
2139              ;; only if the given position was out of bounds, and that is
2140              ;; dealt with above. In times past we used to return NIL for
2141              ;; errno==ESPIPE, and signal an error in other cases.
2142              ;;
2143              ;; FIXME: We are still liable to signal an error if flushing
2144              ;; output fails.
2145              (return-from fd-stream-set-file-position
2146                (typep posn '(alien sb!unix:off-t))))))))
2147
2148 \f
2149 ;;;; creation routines (MAKE-FD-STREAM and OPEN)
2150
2151 ;;; Create a stream for the given Unix file descriptor.
2152 ;;;
2153 ;;; If INPUT is non-NIL, allow input operations. If OUTPUT is non-nil,
2154 ;;; allow output operations. If neither INPUT nor OUTPUT is specified,
2155 ;;; default to allowing input.
2156 ;;;
2157 ;;; ELEMENT-TYPE indicates the element type to use (as for OPEN).
2158 ;;;
2159 ;;; BUFFERING indicates the kind of buffering to use.
2160 ;;;
2161 ;;; TIMEOUT (if true) is the number of seconds to wait for input. If
2162 ;;; NIL (the default), then wait forever. When we time out, we signal
2163 ;;; IO-TIMEOUT.
2164 ;;;
2165 ;;; FILE is the name of the file (will be returned by PATHNAME).
2166 ;;;
2167 ;;; NAME is used to identify the stream when printed.
2168 (defun make-fd-stream (fd
2169                        &key
2170                        (input nil input-p)
2171                        (output nil output-p)
2172                        (element-type 'base-char)
2173                        (buffering :full)
2174                        (external-format :default)
2175                        timeout
2176                        file
2177                        original
2178                        delete-original
2179                        pathname
2180                        input-buffer-p
2181                        dual-channel-p
2182                        (name (if file
2183                                  (format nil "file ~A" file)
2184                                  (format nil "descriptor ~W" fd)))
2185                        auto-close)
2186   (declare (type index fd) (type (or real null) timeout)
2187            (type (member :none :line :full) buffering))
2188   (cond ((not (or input-p output-p))
2189          (setf input t))
2190         ((not (or input output))
2191          (error "File descriptor must be opened either for input or output.")))
2192   (let ((stream (%make-fd-stream :fd fd
2193                                  :name name
2194                                  :file file
2195                                  :original original
2196                                  :delete-original delete-original
2197                                  :pathname pathname
2198                                  :buffering buffering
2199                                  :dual-channel-p dual-channel-p
2200                                  :external-format external-format
2201                                  :bivalent-p (eq element-type :default)
2202                                  :char-size (external-format-char-size external-format)
2203                                  :timeout
2204                                  (if timeout
2205                                      (coerce timeout 'single-float)
2206                                      nil))))
2207     (set-fd-stream-routines stream element-type external-format
2208                             input output input-buffer-p)
2209     (when (and auto-close (fboundp 'finalize))
2210       (finalize stream
2211                 (lambda ()
2212                   (sb!unix:unix-close fd)
2213                   #!+sb-show
2214                   (format *terminal-io* "** closed file descriptor ~W **~%"
2215                           fd))
2216                 :dont-save t))
2217     stream))
2218
2219 ;;; Pick a name to use for the backup file for the :IF-EXISTS
2220 ;;; :RENAME-AND-DELETE and :RENAME options.
2221 (defun pick-backup-name (name)
2222   (declare (type simple-string name))
2223   (concatenate 'simple-string name ".bak"))
2224
2225 ;;; Ensure that the given arg is one of the given list of valid
2226 ;;; things. Allow the user to fix any problems.
2227 (defun ensure-one-of (item list what)
2228   (unless (member item list)
2229     (error 'simple-type-error
2230            :datum item
2231            :expected-type `(member ,@list)
2232            :format-control "~@<~S is ~_invalid for ~S; ~_need one of~{ ~S~}~:>"
2233            :format-arguments (list item what list))))
2234
2235 ;;; Rename NAMESTRING to ORIGINAL. First, check whether we have write
2236 ;;; access, since we don't want to trash unwritable files even if we
2237 ;;; technically can. We return true if we succeed in renaming.
2238 (defun rename-the-old-one (namestring original)
2239   (unless (sb!unix:unix-access namestring sb!unix:w_ok)
2240     (error "~@<The file ~2I~_~S ~I~_is not writable.~:>" namestring))
2241   (multiple-value-bind (okay err) (sb!unix:unix-rename namestring original)
2242     (if okay
2243         t
2244         (error 'simple-file-error
2245                :pathname namestring
2246                :format-control
2247                "~@<couldn't rename ~2I~_~S ~I~_to ~2I~_~S: ~4I~_~A~:>"
2248                :format-arguments (list namestring original (strerror err))))))
2249
2250 (defun open (filename
2251              &key
2252              (direction :input)
2253              (element-type 'base-char)
2254              (if-exists nil if-exists-given)
2255              (if-does-not-exist nil if-does-not-exist-given)
2256              (external-format :default)
2257              &aux ; Squelch assignment warning.
2258              (direction direction)
2259              (if-does-not-exist if-does-not-exist)
2260              (if-exists if-exists))
2261   #!+sb-doc
2262   "Return a stream which reads from or writes to FILENAME.
2263   Defined keywords:
2264    :DIRECTION - one of :INPUT, :OUTPUT, :IO, or :PROBE
2265    :ELEMENT-TYPE - the type of object to read or write, default BASE-CHAR
2266    :IF-EXISTS - one of :ERROR, :NEW-VERSION, :RENAME, :RENAME-AND-DELETE,
2267                        :OVERWRITE, :APPEND, :SUPERSEDE or NIL
2268    :IF-DOES-NOT-EXIST - one of :ERROR, :CREATE or NIL
2269   See the manual for details."
2270
2271   ;; Calculate useful stuff.
2272   (multiple-value-bind (input output mask)
2273       (ecase direction
2274         (:input  (values   t nil sb!unix:o_rdonly))
2275         (:output (values nil   t sb!unix:o_wronly))
2276         (:io     (values   t   t sb!unix:o_rdwr))
2277         (:probe  (values   t nil sb!unix:o_rdonly)))
2278     (declare (type index mask))
2279     (let* (;; PATHNAME is the pathname we associate with the stream.
2280            (pathname (merge-pathnames filename))
2281            (physical (physicalize-pathname pathname))
2282            (truename (probe-file physical))
2283            ;; NAMESTRING is the native namestring we open the file with.
2284            (namestring (cond (truename
2285                               (native-namestring truename :as-file t))
2286                              ((or (not input)
2287                                   (and input (eq if-does-not-exist :create))
2288                                   (and (eq direction :io) (not if-does-not-exist-given)))
2289                               (native-namestring physical :as-file t)))))
2290       ;; Process if-exists argument if we are doing any output.
2291       (cond (output
2292              (unless if-exists-given
2293                (setf if-exists
2294                      (if (eq (pathname-version pathname) :newest)
2295                          :new-version
2296                          :error)))
2297              (ensure-one-of if-exists
2298                             '(:error :new-version :rename
2299                                      :rename-and-delete :overwrite
2300                                      :append :supersede nil)
2301                             :if-exists)
2302              (case if-exists
2303                ((:new-version :error nil)
2304                 (setf mask (logior mask sb!unix:o_excl)))
2305                ((:rename :rename-and-delete)
2306                 (setf mask (logior mask sb!unix:o_creat)))
2307                ((:supersede)
2308                 (setf mask (logior mask sb!unix:o_trunc)))
2309                (:append
2310                 (setf mask (logior mask sb!unix:o_append)))))
2311             (t
2312              (setf if-exists :ignore-this-arg)))
2313
2314       (unless if-does-not-exist-given
2315         (setf if-does-not-exist
2316               (cond ((eq direction :input) :error)
2317                     ((and output
2318                           (member if-exists '(:overwrite :append)))
2319                      :error)
2320                     ((eq direction :probe)
2321                      nil)
2322                     (t
2323                      :create))))
2324       (ensure-one-of if-does-not-exist
2325                      '(:error :create nil)
2326                      :if-does-not-exist)
2327       (if (eq if-does-not-exist :create)
2328         (setf mask (logior mask sb!unix:o_creat)))
2329
2330       (let ((original (case if-exists
2331                         ((:rename :rename-and-delete)
2332                          (pick-backup-name namestring))
2333                         ((:append :overwrite)
2334                          ;; KLUDGE: Provent CLOSE from deleting
2335                          ;; appending streams when called with :ABORT T
2336                          namestring)))
2337             (delete-original (eq if-exists :rename-and-delete))
2338             (mode #o666))
2339         (when (and original (not (eq original namestring)))
2340           ;; We are doing a :RENAME or :RENAME-AND-DELETE. Determine
2341           ;; whether the file already exists, make sure the original
2342           ;; file is not a directory, and keep the mode.
2343           (let ((exists
2344                  (and namestring
2345                       (multiple-value-bind (okay err/dev inode orig-mode)
2346                           (sb!unix:unix-stat namestring)
2347                         (declare (ignore inode)
2348                                  (type (or index null) orig-mode))
2349                         (cond
2350                          (okay
2351                           (when (and output (= (logand orig-mode #o170000)
2352                                                #o40000))
2353                             (error 'simple-file-error
2354                                    :pathname pathname
2355                                    :format-control
2356                                    "can't open ~S for output: is a directory"
2357                                    :format-arguments (list namestring)))
2358                           (setf mode (logand orig-mode #o777))
2359                           t)
2360                          ((eql err/dev sb!unix:enoent)
2361                           nil)
2362                          (t
2363                           (simple-file-perror "can't find ~S"
2364                                               namestring
2365                                               err/dev)))))))
2366             (unless (and exists
2367                          (rename-the-old-one namestring original))
2368               (setf original nil)
2369               (setf delete-original nil)
2370               ;; In order to use :SUPERSEDE instead, we have to make
2371               ;; sure SB!UNIX:O_CREAT corresponds to
2372               ;; IF-DOES-NOT-EXIST. SB!UNIX:O_CREAT was set before
2373               ;; because of IF-EXISTS being :RENAME.
2374               (unless (eq if-does-not-exist :create)
2375                 (setf mask
2376                       (logior (logandc2 mask sb!unix:o_creat)
2377                               sb!unix:o_trunc)))
2378               (setf if-exists :supersede))))
2379
2380         ;; Now we can try the actual Unix open(2).
2381         (multiple-value-bind (fd errno)
2382             (if namestring
2383                 (sb!unix:unix-open namestring mask mode)
2384                 (values nil sb!unix:enoent))
2385           (labels ((open-error (format-control &rest format-arguments)
2386                      (error 'simple-file-error
2387                             :pathname pathname
2388                             :format-control format-control
2389                             :format-arguments format-arguments))
2390                    (vanilla-open-error ()
2391                      (simple-file-perror "error opening ~S" pathname errno)))
2392             (cond ((numberp fd)
2393                    (case direction
2394                      ((:input :output :io)
2395                       (make-fd-stream fd
2396                                       :input input
2397                                       :output output
2398                                       :element-type element-type
2399                                       :external-format external-format
2400                                       :file namestring
2401                                       :original original
2402                                       :delete-original delete-original
2403                                       :pathname pathname
2404                                       :dual-channel-p nil
2405                                       :input-buffer-p t
2406                                       :auto-close t))
2407                      (:probe
2408                       (let ((stream
2409                              (%make-fd-stream :name namestring
2410                                               :fd fd
2411                                               :pathname pathname
2412                                               :element-type element-type)))
2413                         (close stream)
2414                         stream))))
2415                   ((eql errno sb!unix:enoent)
2416                    (case if-does-not-exist
2417                      (:error (vanilla-open-error))
2418                      (:create
2419                       (open-error "~@<The path ~2I~_~S ~I~_does not exist.~:>"
2420                                   pathname))
2421                      (t nil)))
2422                   ((and (eql errno sb!unix:eexist) (null if-exists))
2423                    nil)
2424                   (t
2425                    (vanilla-open-error)))))))))
2426 \f
2427 ;;;; initialization
2428
2429 ;;; the stream connected to the controlling terminal, or NIL if there is none
2430 (defvar *tty*)
2431
2432 ;;; the stream connected to the standard input (file descriptor 0)
2433 (defvar *stdin*)
2434
2435 ;;; the stream connected to the standard output (file descriptor 1)
2436 (defvar *stdout*)
2437
2438 ;;; the stream connected to the standard error output (file descriptor 2)
2439 (defvar *stderr*)
2440
2441 ;;; This is called when the cold load is first started up, and may also
2442 ;;; be called in an attempt to recover from nested errors.
2443 (defun stream-cold-init-or-reset ()
2444   (stream-reinit)
2445   (setf *terminal-io* (make-synonym-stream '*tty*))
2446   (setf *standard-output* (make-synonym-stream '*stdout*))
2447   (setf *standard-input* (make-synonym-stream '*stdin*))
2448   (setf *error-output* (make-synonym-stream '*stderr*))
2449   (setf *query-io* (make-synonym-stream '*terminal-io*))
2450   (setf *debug-io* *query-io*)
2451   (setf *trace-output* *standard-output*)
2452   (values))
2453
2454 (defun stream-deinit ()
2455   ;; Unbind to make sure we're not accidently dealing with it
2456   ;; before we're ready (or after we think it's been deinitialized).
2457   (with-available-buffers-lock ()
2458     (without-package-locks
2459         (makunbound '*available-buffers*))))
2460
2461 (defun stdstream-external-format (outputp)
2462   (declare (ignorable outputp))
2463   (let* ((keyword #!+win32 (if outputp (sb!win32::console-output-codepage) (sb!win32::console-input-codepage))
2464                   #!-win32 (default-external-format))
2465          (ef (get-external-format keyword))
2466          (replacement (ef-default-replacement-character ef)))
2467     `(,keyword :replacement ,replacement)))
2468
2469 ;;; This is called whenever a saved core is restarted.
2470 (defun stream-reinit (&optional init-buffers-p)
2471   (when init-buffers-p
2472     (with-available-buffers-lock ()
2473       (aver (not (boundp '*available-buffers*)))
2474       (setf *available-buffers* nil)))
2475   (with-output-to-string (*error-output*)
2476     (setf *stdin*
2477           (make-fd-stream 0 :name "standard input" :input t :buffering :line
2478                             :external-format (stdstream-external-format nil)))
2479     (setf *stdout*
2480           (make-fd-stream 1 :name "standard output" :output t :buffering :line
2481                             :external-format (stdstream-external-format t)))
2482     (setf *stderr*
2483           (make-fd-stream 2 :name "standard error" :output t :buffering :line
2484                             :external-format (stdstream-external-format t)))
2485     (let* ((ttyname #.(coerce "/dev/tty" 'simple-base-string))
2486            (tty (sb!unix:unix-open ttyname sb!unix:o_rdwr #o666)))
2487       (if tty
2488           (setf *tty*
2489                 (make-fd-stream tty :name "the terminal"
2490                                 :input t :output t :buffering :line
2491                                 :external-format (stdstream-external-format t)
2492                                 :auto-close t))
2493           (setf *tty* (make-two-way-stream *stdin* *stdout*))))
2494     (princ (get-output-stream-string *error-output*) *stderr*))
2495   (values))
2496 \f
2497 ;;;; miscellany
2498
2499 ;;; the Unix way to beep
2500 (defun beep (stream)
2501   (write-char (code-char bell-char-code) stream)
2502   (finish-output stream))
2503
2504 ;;; This is kind of like FILE-POSITION, but is an internal hack used
2505 ;;; by the filesys stuff to get and set the file name.
2506 ;;;
2507 ;;; FIXME: misleading name, screwy interface
2508 (defun file-name (stream &optional new-name)
2509   (when (typep stream 'fd-stream)
2510       (cond (new-name
2511              (setf (fd-stream-pathname stream) new-name)
2512              (setf (fd-stream-file stream)
2513                    (native-namestring (physicalize-pathname new-name)
2514                                       :as-file t))
2515              t)
2516             (t
2517              (fd-stream-pathname stream)))))