src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defvar *ignore-wildcards* nil)
  84
  85 (/show0 "filesys.lisp 86")
  86
  87 (defun maybe-make-pattern (namestr start end)
  88   (declare (type simple-string namestr)
  89            (type index start end))
  90   (if *ignore-wildcards*
  91       (subseq namestr start end)
  92       (collect ((pattern))
  93         (let ((quoted nil)
  94               (any-quotes nil)
  95               (last-regular-char nil)
  96               (index start))
  97           (flet ((flush-pending-regulars ()
  98                    (when last-regular-char
  99                      (pattern (if any-quotes
 100                                   (remove-backslashes namestr
 101                                                       last-regular-char
 102                                                       index)
 103                                   (subseq namestr last-regular-char index)))
 104                      (setf any-quotes nil)
 105                      (setf last-regular-char nil))))
 106             (loop
 107               (when (>= index end)
 108                 (return))
 109               (let ((char (schar namestr index)))
 110                 (cond (quoted
 111                        (incf index)
 112                        (setf quoted nil))
 113                       ((char= char #\\)
 114                        (setf quoted t)
 115                        (setf any-quotes t)
 116                        (unless last-regular-char
 117                          (setf last-regular-char index))
 118                        (incf index))
 119                       ((char= char #\?)
 120                        (flush-pending-regulars)
 121                        (pattern :single-char-wild)
 122                        (incf index))
 123                       ((char= char #\*)
 124                        (flush-pending-regulars)
 125                        (pattern :multi-char-wild)
 126                        (incf index))
 127                       ((char= char #\[)
 128                        (flush-pending-regulars)
 129                        (let ((close-bracket
 130                               (position #\] namestr :start index :end end)))
 131                          (unless close-bracket
 132                            (error 'namestring-parse-error
 133                                   :complaint "#\\[ with no corresponding #\\]"
 134                                   :namestring namestr
 135                                   :offset index))
 136                          (pattern (cons :character-set
 137                                         (subseq namestr
 138                                                 (1+ index)
 139                                                 close-bracket)))
 140                          (setf index (1+ close-bracket))))
 141                       (t
 142                        (unless last-regular-char
 143                          (setf last-regular-char index))
 144                        (incf index)))))
 145             (flush-pending-regulars)))
 146         (cond ((null (pattern))
 147                "")
 148               ((null (cdr (pattern)))
 149                (let ((piece (first (pattern))))
 150                  (typecase piece
 151                    ((member :multi-char-wild) :wild)
 152                    (simple-string piece)
 153                    (t
 154                     (make-pattern (pattern))))))
 155               (t
 156                (make-pattern (pattern)))))))
 157
 158 (/show0 "filesys.lisp 160")
 159
 160 (defun extract-name-type-and-version (namestr start end)
 161   (declare (type simple-string namestr)
 162            (type index start end))
 163   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 164                              :from-end t)))
 165     (cond
 166       (last-dot
 167        (values (maybe-make-pattern namestr start last-dot)
 168                (maybe-make-pattern namestr (1+ last-dot) end)
 169                :newest))
 170       (t
 171        (values (maybe-make-pattern namestr start end)
 172                nil
 173                :newest)))))
 174
 175 (/show0 "filesys.lisp 200")
 176
 177 \f
 178 ;;;; wildcard matching stuff
 179
 180 ;;; Return a list of all the Lispy filenames (not including e.g. the
 181 ;;; Unix magic "." and "..") in the directory named by DIRECTORY-NAME.
 182 (defun directory-lispy-filenames (directory-name)
 183   (with-alien ((adlf (* c-string)
 184                      (alien-funcall (extern-alien
 185                                      "alloc_directory_lispy_filenames"
 186                                      (function (* c-string) c-string))
 187                                     directory-name)))
 188     (if (null-alien adlf)
 189         (error 'simple-file-error
 190                :pathname directory-name
 191                :format-control "~@<couldn't read directory ~S: ~2I~_~A~:>"
 192                :format-arguments (list directory-name (strerror)))
 193         (unwind-protect
 194             (c-strings->string-list adlf)
 195           (alien-funcall (extern-alien "free_directory_lispy_filenames"
 196                                        (function void (* c-string)))
 197                          adlf)))))
 198
 199 (/show0 "filesys.lisp 498")
 200
 201 (defmacro !enumerate-matches ((var pathname &optional result
 202                                    &key (verify-existence t)
 203                                    (follow-links t))
 204                               &body body)
 205   `(block nil
 206      (%enumerate-matches (pathname ,pathname)
 207                          ,verify-existence
 208                          ,follow-links
 209                          (lambda (,var) ,@body))
 210      ,result))
 211
 212 (/show0 "filesys.lisp 500")
 213
 214 ;;; Call FUNCTION on matches.
 215 ;;;
 216 ;;; KLUDGE: this assumes that an absolute pathname is indicated to the
 217 ;;; operating system by having a directory separator as the first
 218 ;;; character in the directory part.  This is true for Win32 pathnames
 219 ;;; and for Unix pathnames, but it isn't true for LispM pathnames (and
 220 ;;; their bastard offspring, logical pathnames.  Also it assumes that
 221 ;;; Unix pathnames have an empty or :unspecific device, and that
 222 ;;; windows drive letters are the only kinds of non-empty/:UNSPECIFIC
 223 ;;; devices.
 224 (defun %enumerate-matches (pathname verify-existence follow-links function)
 225   (/noshow0 "entering %ENUMERATE-MATCHES")
 226   (when (pathname-type pathname)
 227     (unless (pathname-name pathname)
 228       (error "cannot supply a type without a name:~%  ~S" pathname)))
 229   (when (and (integerp (pathname-version pathname))
 230              (member (pathname-type pathname) '(nil :unspecific)))
 231     (error "cannot supply a version without a type:~%  ~S" pathname))
 232   (let ((host (pathname-host pathname))
 233         (device (pathname-device pathname))
 234         (directory (pathname-directory pathname)))
 235     (/noshow0 "computed HOST and DIRECTORY")
 236     (let* ((dirstring (if directory
 237                           (ecase (first directory)
 238                             (:absolute (host-unparse-directory-separator host))
 239                             (:relative ""))
 240                           ""))
 241            (devstring (if (and device (not (eq device :unspecific)))
 242                           (concatenate 'simple-string (string device) (string #\:))
 243                           ""))
 244            (headstring (concatenate 'simple-string devstring dirstring)))
 245       (if directory
 246           (%enumerate-directories headstring (rest directory) pathname
 247                                   verify-existence follow-links nil function)
 248           (%enumerate-files headstring pathname verify-existence function)))))
 249
 250 ;;; Call FUNCTION on directories.
 251 (defun %enumerate-directories (head tail pathname verify-existence
 252                                follow-links nodes function
 253                                &aux (host (pathname-host pathname)))
 254   (declare (simple-string head))
 255   #!+win32
 256   (setf follow-links nil)
 257   (macrolet ((unix-xstat (name)
 258                `(if follow-links
 259                     (sb!unix:unix-stat ,name)
 260                     (sb!unix:unix-lstat ,name)))
 261              (with-directory-node-noted ((head) &body body)
 262                `(multiple-value-bind (res dev ino mode)
 263                     (unix-xstat ,head)
 264                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 265                                       sb!unix:s-ifdir))
 266                     (let ((nodes (cons (cons dev ino) nodes)))
 267                       ,@body))))
 268              (with-directory-node-removed ((head) &body body)
 269                `(multiple-value-bind (res dev ino mode)
 270                     (unix-xstat ,head)
 271                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 272                                       sb!unix:s-ifdir))
 273                     (let ((nodes (remove (cons dev ino) nodes :test #'equal)))
 274                       ,@body)))))
 275     (if tail
 276         (let ((piece (car tail)))
 277           (etypecase piece
 278             (simple-string
 279              (let ((head (concatenate 'string head piece)))
 280                (with-directory-node-noted (head)
 281                  (%enumerate-directories
 282                   (concatenate 'string head
 283                                (host-unparse-directory-separator host))
 284                   (cdr tail) pathname
 285                   verify-existence follow-links
 286                   nodes function))))
 287             ((member :wild-inferiors)
 288              ;; now with extra error case handling from CLHS
 289              ;; 19.2.2.4.3 -- CSR, 2004-01-24
 290              (when (member (cadr tail) '(:up :back))
 291                (error 'simple-file-error
 292                       :pathname pathname
 293                       :format-control "~@<invalid use of ~S after :WILD-INFERIORS~@:>."
 294                       :format-arguments (list (cadr tail))))
 295              (%enumerate-directories head (rest tail) pathname
 296                                      verify-existence follow-links
 297                                      nodes function)
 298              (dolist (name (directory-lispy-filenames head))
 299                (let ((subdir (concatenate 'string head name)))
 300                  (multiple-value-bind (res dev ino mode)
 301                      (unix-xstat subdir)
 302                    (declare (type (or fixnum null) mode))
 303                    (when (and res (eql (logand mode sb!unix:s-ifmt)
 304                                        sb!unix:s-ifdir))
 305                      (unless (dolist (dir nodes nil)
 306                                (when (and (eql (car dir) dev)
 307                                           #!+win32 ;; KLUDGE
 308                                           (not (zerop ino))
 309                                           (eql (cdr dir) ino))
 310                                  (return t)))
 311                        (let ((nodes (cons (cons dev ino) nodes))
 312                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 313                          (%enumerate-directories subdir tail pathname
 314                                                  verify-existence follow-links
 315                                                  nodes function))))))))
 316             ((or pattern (member :wild))
 317              (dolist (name (directory-lispy-filenames head))
 318                (when (or (eq piece :wild) (pattern-matches piece name))
 319                  (let ((subdir (concatenate 'string head name)))
 320                    (multiple-value-bind (res dev ino mode)
 321                        (unix-xstat subdir)
 322                      (declare (type (or fixnum null) mode))
 323                      (when (and res
 324                                 (eql (logand mode sb!unix:s-ifmt)
 325                                      sb!unix:s-ifdir))
 326                        (let ((nodes (cons (cons dev ino) nodes))
 327                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 328                          (%enumerate-directories subdir (rest tail) pathname
 329                                                  verify-existence follow-links
 330                                                  nodes function))))))))
 331           ((member :up)
 332            (when (string= head (host-unparse-directory-separator host))
 333              (error 'simple-file-error
 334                     :pathname pathname
 335                     :format-control "~@<invalid use of :UP after :ABSOLUTE.~@:>"))
 336            (with-directory-node-removed (head)
 337              (let ((head (concatenate 'string head "..")))
 338                (with-directory-node-noted (head)
 339                  (%enumerate-directories (concatenate 'string head (host-unparse-directory-separator host))
 340                                          (rest tail) pathname
 341                                          verify-existence follow-links
 342                                          nodes function)))))
 343           ((member :back)
 344            ;; :WILD-INFERIORS is handled above, so the only case here
 345            ;; should be (:ABSOLUTE :BACK)
 346            (aver (string= head (host-unparse-directory-separator host)))
 347            (error 'simple-file-error
 348                   :pathname pathname
 349                   :format-control "~@<invalid use of :BACK after :ABSOLUTE.~@:>"))))
 350         (%enumerate-files head pathname verify-existence function))))
 351
 352 ;;; Call FUNCTION on files.
 353 (defun %enumerate-files (directory pathname verify-existence function)
 354   (declare (simple-string directory))
 355   (/noshow0 "entering %ENUMERATE-FILES")
 356   (let ((name (%pathname-name pathname))
 357         (type (%pathname-type pathname))
 358         (version (%pathname-version pathname)))
 359     (/noshow0 "computed NAME, TYPE, and VERSION")
 360     (cond ((member name '(nil :unspecific))
 361            (/noshow0 "UNSPECIFIC, more or less")
 362            (let ((directory (coerce directory 'string)))
 363              (when (or (not verify-existence)
 364                        (sb!unix:unix-file-kind directory))
 365                (funcall function directory))))
 366           ((or (pattern-p name)
 367                (pattern-p type)
 368                (eq name :wild)
 369                (eq type :wild))
 370            (/noshow0 "WILD, more or less")
 371            ;; I IGNORE-ERRORS here just because the original CMU CL
 372            ;; code did. I think the intent is that it's not an error
 373            ;; to request matches to a wild pattern when no matches
 374            ;; exist, but I haven't tried to figure out whether
 375            ;; everything is kosher. (E.g. what if we try to match a
 376            ;; wildcard but we don't have permission to read one of the
 377            ;; relevant directories?) -- WHN 2001-04-17
 378            (dolist (complete-filename (ignore-errors
 379                                         (directory-lispy-filenames directory)))
 380              (multiple-value-bind
 381                  (file-name file-type file-version)
 382                  (let ((*ignore-wildcards* t))
 383                    (extract-name-type-and-version
 384                     complete-filename 0 (length complete-filename)))
 385                (when (and (components-match file-name name)
 386                           (components-match file-type type)
 387                           (components-match file-version version))
 388                  (funcall function
 389                           (concatenate 'string
 390                                        directory
 391                                        complete-filename))))))
 392           (t
 393            (/noshow0 "default case")
 394            (let ((file (concatenate 'string directory name)))
 395              (/noshow "computed basic FILE")
 396              (unless (or (null type) (eq type :unspecific))
 397                (/noshow0 "tweaking FILE for more-or-less-:UNSPECIFIC case")
 398                (setf file (concatenate 'string file "." type)))
 399              (unless (member version '(nil :newest :wild :unspecific))
 400                (/noshow0 "tweaking FILE for more-or-less-:WILD case")
 401                (setf file (concatenate 'string file "."
 402                                        (quick-integer-to-string version))))
 403              (/noshow0 "finished possibly tweaking FILE")
 404              (when (or (not verify-existence)
 405                        (sb!unix:unix-file-kind file t))
 406                (/noshow0 "calling FUNCTION on FILE")
 407                (funcall function file)))))))
 408
 409 (/noshow0 "filesys.lisp 603")
 410
 411 ;;; FIXME: Why do we need this?
 412 (defun quick-integer-to-string (n)
 413   (declare (type integer n))
 414   (cond ((not (fixnump n))
 415          (write-to-string n :base 10 :radix nil))
 416         ((zerop n) "0")
 417         ((eql n 1) "1")
 418         ((minusp n)
 419          (concatenate 'simple-base-string "-"
 420                       (the simple-base-string (quick-integer-to-string (- n)))))
 421         (t
 422          (do* ((len (1+ (truncate (integer-length n) 3)))
 423                (res (make-string len :element-type 'base-char))
 424                (i (1- len) (1- i))
 425                (q n)
 426                (r 0))
 427               ((zerop q)
 428                (incf i)
 429                (replace res res :start2 i :end2 len)
 430                (%shrink-vector res (- len i)))
 431            (declare (simple-string res)
 432                     (fixnum len i r q))
 433            (multiple-value-setq (q r) (truncate q 10))
 434            (setf (schar res i) (schar "0123456789" r))))))
 435 \f
 436 ;;;; UNIX-NAMESTRING
 437
 438 (defun empty-relative-pathname-spec-p (x)
 439   (or (equal x "")
 440       (and (pathnamep x)
 441            (or (equal (pathname-directory x) '(:relative))
 442                ;; KLUDGE: I'm not sure this second check should really
 443                ;; have to be here. But on sbcl-0.6.12.7,
 444                ;; (PATHNAME-DIRECTORY (PATHNAME "")) is NIL, and
 445                ;; (PATHNAME "") seems to act like an empty relative
 446                ;; pathname, so in order to work with that, I test
 447                ;; for NIL here. -- WHN 2001-05-18
 448                (null (pathname-directory x)))
 449            (null (pathname-name x))
 450            (null (pathname-type x)))
 451       ;; (The ANSI definition of "pathname specifier" has
 452       ;; other cases, but none of them seem to admit the possibility
 453       ;; of being empty and relative.)
 454       ))
 455
 456 ;;; Convert PATHNAME into a string that can be used with UNIX system
 457 ;;; calls, or return NIL if no match is found. Wild-cards are expanded.
 458 ;;;
 459 ;;; FIXME: apart from the error checking (for wildness and for
 460 ;;; existence) and conversion to physical pathanme, this is redundant
 461 ;;; with UNPARSE-NATIVE-UNIX-NAMESTRING; one should probably be
 462 ;;; written in terms of the other.
 463 ;;;
 464 ;;; FIXME: actually this (I think) works not just for Unix.
 465 (defun unix-namestring (pathname-spec &optional (for-input t))
 466   (let* ((namestring (physicalize-pathname (merge-pathnames pathname-spec)))
 467          (matches nil)) ; an accumulator for actual matches
 468     (when (wild-pathname-p namestring)
 469       (error 'simple-file-error
 470              :pathname namestring
 471              :format-control "bad place for a wild pathname"))
 472     (!enumerate-matches (match namestring nil :verify-existence for-input)
 473                         (push match matches))
 474     (case (length matches)
 475       (0 nil)
 476       (1 (first matches))
 477       (t (bug "!ENUMERATE-MATCHES returned more than one match on a non-wild pathname")))))
 478 \f
 479 ;;;; TRUENAME, PROBE-FILE, FILE-AUTHOR, FILE-WRITE-DATE.
 480
 481 ;;; Rewritten in 12/2007 by RMK, replacing 13+ year old CMU code that
 482 ;;; made a mess of things in order to support search lists (which SBCL
 483 ;;; has never had).  These are now all relatively straightforward
 484 ;;; wrappers around stat(2) and realpath(2), with the same basic logic
 485 ;;; in all cases.  The wrinkles to be aware of:
 486 ;;;
 487 ;;; * SBCL defines the truename of an existing, dangling or
 488 ;;;   self-referring symlink to be the symlink itself.
 489 ;;; * The old version of PROBE-FILE merged the pathspec against
 490 ;;;   *DEFAULT-PATHNAME-DEFAULTS* twice, and so lost when *D-P-D*
 491 ;;;   was a relative pathname.  Even if the case where *D-P-D* is a
 492 ;;;   relative pathname is problematic, there's no particular reason
 493 ;;;   to get that wrong, so let's try not to.
 494 ;;; * Note that while stat(2) is probably atomic, getting the truename
 495 ;;;   for a filename involves poking all over the place, and so is
 496 ;;;   subject to race conditions if other programs mutate the file
 497 ;;;   system while we're resolving symlinks.  So it's not implausible for
 498 ;;;   realpath(3) to fail even if stat(2) succeeded.  There's nothing
 499 ;;;   obvious we can do about this, however.
 500 ;;; * Windows' apparent analogue of realpath(3) is called
 501 ;;;   GetFullPathName, and it's a bit less useful than realpath(3).
 502 ;;;   In particular, while realpath(3) errors in case the file doesn't
 503 ;;;   exist, GetFullPathName seems to return a filename in all cases.
 504 ;;;   As realpath(3) is not atomic anyway, we only ever call it when
 505 ;;;   we think a file exists, so just be careful when rewriting this
 506 ;;;   routine.
 507 (defun query-file-system (pathspec query-for &optional (errorp t))
 508   (let ((pathname (translate-logical-pathname
 509                    (merge-pathnames
 510                     (pathname pathspec)
 511                     (sane-default-pathname-defaults)))))
 512     (when (wild-pathname-p pathname)
 513       (error 'simple-file-error
 514              :pathname pathname
 515              :format-control "~@<can't find the ~A of wild pathname ~A~
 516                               (physicalized from ~A).~:>"
 517              :format-arguments (list query-for pathname pathspec)))
 518     (flet ((fail (note-format pathname errno)
 519              (if errorp
 520                  (simple-file-perror note-format pathname errno)
 521                  (return-from query-file-system nil))))
 522       (let ((filename (native-namestring pathname :as-file t)))
 523         (multiple-value-bind (existsp errno ino mode nlink uid gid rdev size
 524                                       atime mtime)
 525             (sb!unix:unix-stat filename)
 526           (declare (ignore ino nlink gid rdev size atime))
 527           (if existsp
 528               (case query-for
 529                 (:truename (nth-value
 530                             0
 531                             (parse-native-namestring
 532                              ;; Note: in case the file is stat'able, POSIX
 533                              ;; realpath(3) gets us a canonical absolute
 534                              ;; filename, even if the post-merge PATHNAME
 535                              ;; is not absolute...
 536                              (multiple-value-bind (realpath errno)
 537                                  (sb!unix:unix-realpath filename)
 538                                (if realpath
 539                                    realpath
 540                                    (fail "couldn't resolve ~A" filename errno)))
 541                              (pathname-host pathname)
 542                              (sane-default-pathname-defaults)
 543                              ;; ... but without any trailing slash.
 544                              :as-directory (eql (logand  mode sb!unix:s-ifmt)
 545                                                 sb!unix:s-ifdir))))
 546                 (:author (sb!unix:uid-username uid))
 547                 (:write-date (+ unix-to-universal-time mtime)))
 548               (progn
 549                 ;; SBCL has for many years had a policy that a pathname
 550                 ;; that names an existing, dangling or self-referential
 551                 ;; symlink denotes the symlink itself.  stat(2) fails
 552                 ;; and sets errno to ENOENT or ELOOP respectively, but
 553                 ;; we must distinguish cases where the symlink exists
 554                 ;; from ones where there's a loop in the apparent
 555                 ;; containing directory.
 556                 #!-win32
 557                 (multiple-value-bind (linkp ignore ino mode nlink uid gid rdev
 558                                             size atime mtime)
 559                     (sb!unix:unix-lstat filename)
 560                   (declare (ignore ignore ino mode nlink gid rdev size atime))
 561                   (when (and (or (= errno sb!unix:enoent)
 562                                  (= errno sb!unix:eloop))
 563                              linkp)
 564                     (return-from query-file-system
 565                       (case query-for
 566                         (:truename
 567                          ;; So here's a trick: since lstat succeded,
 568                          ;; FILENAME exists, so its directory exists and
 569                          ;; only the non-directory part is loopy.  So
 570                          ;; let's resolve FILENAME's directory part with
 571                          ;; realpath(3), in order to get a canonical
 572                          ;; absolute name for the directory, and then
 573                          ;; return a pathname having PATHNAME's name,
 574                          ;; type, and version, but the rest from the
 575                          ;; truename of the directory.  Since we turned
 576                          ;; PATHNAME into FILENAME "as a file", FILENAME
 577                          ;; does not end in a slash, and so we get the
 578                          ;; directory part of FILENAME by reparsing
 579                          ;; FILENAME and masking off its name, type, and
 580                          ;; version bits.  But note not to call ourselves
 581                          ;; recursively, because we don't want to
 582                          ;; re-merge against *DEFAULT-PATHNAME-DEFAULTS*,
 583                          ;; since PATHNAME may be a relative pathname.
 584                          (merge-pathnames
 585                           (nth-value
 586                            0
 587                            (parse-native-namestring
 588                             (multiple-value-bind (realpath errno)
 589                                 (sb!unix:unix-realpath
 590                                  (native-namestring
 591                                   (make-pathname
 592                                    :name :unspecific
 593                                    :type :unspecific
 594                                    :version :unspecific
 595                                    :defaults (parse-native-namestring
 596                                               filename
 597                                               (pathname-host pathname)
 598                                               (sane-default-pathname-defaults)))))
 599                               (if realpath
 600                                   realpath
 601                                   (fail "couldn't resolve ~A" filename errno)))
 602                             (pathname-host pathname)
 603                             (sane-default-pathname-defaults)
 604                             :as-directory t))
 605                           pathname))
 606                         (:author (sb!unix:uid-username uid))
 607                         (:write-date (+ unix-to-universal-time mtime))))))
 608                 ;; If we're still here, the file doesn't exist; error.
 609                 (fail
 610                  (format nil "failed to find the ~A of ~~A" query-for)
 611                  pathspec errno))))))))
 612
 613
 614 (defun probe-file (pathspec)
 615   #!+sb-doc
 616   "Return the truename of PATHSPEC if the truename can be found,
 617 or NIL otherwise.  See TRUENAME for more information."
 618   (query-file-system pathspec :truename nil))
 619
 620 (defun truename (pathspec)
 621   #!+sb-doc
 622   "If PATHSPEC is a pathname that names an existing file, return
 623 a pathname that denotes a canonicalized name for the file.  If
 624 pathspec is a stream associated with a file, return a pathname
 625 that denotes a canonicalized name for the file associated with
 626 the stream.
 627
 628 An error of type FILE-ERROR is signalled if no such file exists
 629 or if the file system is such that a canonicalized file name
 630 cannot be determined or if the pathname is wild.
 631
 632 Under Unix, the TRUENAME of a symlink that links to itself or to
 633 a file that doesn't exist is considered to be the name of the
 634 broken symlink itself."
 635   ;; Note that eventually this routine might be different for streams
 636   ;; than for other pathname designators.
 637   (if (streamp pathspec)
 638       (query-file-system pathspec :truename)
 639       (query-file-system pathspec :truename)))
 640
 641 (defun file-author (pathspec)
 642   #!+sb-doc
 643   "Return the author of the file specified by PATHSPEC. Signal an
 644 error of type FILE-ERROR if no such file exists, or if PATHSPEC
 645 is a wild pathname."
 646   (query-file-system pathspec :author))
 647
 648 (defun file-write-date (pathspec)
 649   #!+sb-doc
 650   "Return the write date of the file specified by PATHSPEC.
 651 An error of type FILE-ERROR is signaled if no such file exists,
 652 or if PATHSPEC is a wild pathname."
 653   (query-file-system pathspec :write-date))
 654 \f
 655 ;;;; miscellaneous other operations
 656
 657 (/show0 "filesys.lisp 700")
 658
 659 (defun rename-file (file new-name)
 660   #!+sb-doc
 661   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 662   file, then the associated file is renamed."
 663   (let* ((original (truename file))
 664          (original-namestring (unix-namestring original t))
 665          (new-name (merge-pathnames new-name original))
 666          (new-namestring (unix-namestring new-name nil)))
 667     (unless new-namestring
 668       (error 'simple-file-error
 669              :pathname new-name
 670              :format-control "~S can't be created."
 671              :format-arguments (list new-name)))
 672     (multiple-value-bind (res error)
 673         (sb!unix:unix-rename original-namestring new-namestring)
 674       (unless res
 675         (error 'simple-file-error
 676                :pathname new-name
 677                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 678                                 ~I~_~A~:>"
 679                :format-arguments (list original new-name (strerror error))))
 680       (when (streamp file)
 681         (file-name file new-name))
 682       (values new-name original (truename new-name)))))
 683
 684 (defun delete-file (file)
 685   #!+sb-doc
 686   "Delete the specified FILE."
 687   (let ((namestring (unix-namestring file t)))
 688     (when (streamp file)
 689       (close file :abort t))
 690     (unless namestring
 691       (error 'simple-file-error
 692              :pathname file
 693              :format-control "~S doesn't exist."
 694              :format-arguments (list file)))
 695     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 696       (unless res
 697         (simple-file-perror "couldn't delete ~A" namestring err))))
 698   t)
 699 \f
 700 (defun sbcl-homedir-pathname ()
 701   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 702     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 703     (when (and sbcl-home (not (string= sbcl-home "")))
 704       (parse-native-namestring sbcl-home
 705                                #!-win32 sb!impl::*unix-host*
 706                                #!+win32 sb!impl::*win32-host*
 707                                *default-pathname-defaults*
 708                                :as-directory t))))
 709
 710 ;;; (This is an ANSI Common Lisp function.)
 711 (defun user-homedir-pathname (&optional host)
 712   #!+sb-doc
 713   "Return the home directory of the user as a pathname. If the HOME
 714 environment variable has been specified, the directory it designates
 715 is returned; otherwise obtains the home directory from the operating
 716 system."
 717   (declare (ignore host))
 718   (let ((env-home (posix-getenv "HOME")))
 719     (values
 720      (parse-native-namestring
 721       (if (and env-home (not (string= env-home "")))
 722           env-home
 723           #!-win32
 724           (sb!unix:uid-homedir (sb!unix:unix-getuid))
 725           #!+win32
 726           ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 727           ;; What?! -- RMK, 2007-12-31
 728           (return-from user-homedir-pathname
 729             (sb!win32::get-folder-pathname sb!win32::csidl_profile)))
 730       #!-win32 sb!impl::*unix-host*
 731       #!+win32 sb!impl::*win32-host*
 732       *default-pathname-defaults*
 733       :as-directory t))))
 734
 735 \f
 736 ;;;; DIRECTORY
 737
 738 (/show0 "filesys.lisp 800")
 739
 740 ;;; NOTE: There is a fair amount of hair below that is probably not
 741 ;;; strictly necessary.
 742 ;;;
 743 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 744 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 745 ;;; did not translate the logical pathname at all, but instead treated
 746 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 747 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 748 ;;; which is fine as far as it goes, but not very interesting, and
 749 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 750 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 751 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 752 ;;; exists, of course).
 753 ;;;
 754 ;;; So, the interpretation that I am pushing is for all pathnames
 755 ;;; matching the input pathname to be queried.  This means that we
 756 ;;; need to compute the intersection of the input pathname and the
 757 ;;; logical host FROM translations, and then translate the resulting
 758 ;;; pathname using the host to the TO translation; this treatment is
 759 ;;; recursively invoked until we get a physical pathname, whereupon
 760 ;;; our physical DIRECTORY implementation takes over.
 761
 762 ;;; FIXME: this is an incomplete implementation.  It only works when
 763 ;;; both are logical pathnames (which is OK, because that's the only
 764 ;;; case when we call it), but there are other pitfalls as well: see
 765 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 766 ;;; pattern handling.
 767
 768 ;;; The above was written by CSR, I (RMK) believe.  The argument that
 769 ;;; motivates the interpretation is faulty, however: PATHNAME-MATCH-P
 770 ;;; returns true for (PATHNAME-MATCH-P #P"/tmp/*/" #P"/tmp/../"), but
 771 ;;; the latter pathname is not in the result of DIRECTORY on the
 772 ;;; former.  Indeed, if DIRECTORY were constrained to return the
 773 ;;; truename for every pathname for which PATHNAME-MATCH-P returned
 774 ;;; true and which denoted a filename that named an existing file,
 775 ;;; (DIRECTORY #P"/tmp/**/") would be required to list every file on a
 776 ;;; Unix system, since any file can be named as though it were "below"
 777 ;;; /tmp, given the dotdot entries.  So I think the strongest
 778 ;;; "consistency" we can define between PATHNAME-MATCH-P and DIRECTORY
 779 ;;; is that PATHNAME-MATCH-P returns true of everything DIRECTORY
 780 ;;; returns, but not vice versa.
 781
 782 ;;; In any case, even if the motivation were sound, DIRECTORY on a
 783 ;;; wild logical pathname has no portable semantics.  I see nothing in
 784 ;;; ANSI that requires implementations to support wild physical
 785 ;;; pathnames, and so there need not be any translation of a wild
 786 ;;; logical pathname to a phyiscal pathname.  So a program that calls
 787 ;;; DIRECTORY on a wild logical pathname is doing something
 788 ;;; non-portable at best.  And if the only sensible semantics for
 789 ;;; DIRECTORY on a wild logical pathname is something like the
 790 ;;; following, it would be just as well if it signaled an error, since
 791 ;;; a program can't possibly rely on the result of an intersection of
 792 ;;; user-defined translations with a file system probe.  (Potentially
 793 ;;; useful kinds of "pathname" that might not support wildcards could
 794 ;;; include pathname hosts that model unqueryable namespaces like HTTP
 795 ;;; URIs, or that model namespaces that it's not convenient to
 796 ;;; investigate, such as the namespace of TCP ports that some network
 797 ;;; host listens on.  I happen to think it a bad idea to try to
 798 ;;; shoehorn such namespaces into a pathnames system, but people
 799 ;;; sometimes claim to want pathnames for these things.)  -- RMK
 800 ;;; 2007-12-31.
 801
 802 (defun pathname-intersections (one two)
 803   (aver (logical-pathname-p one))
 804   (aver (logical-pathname-p two))
 805   (labels
 806       ((intersect-version (one two)
 807          (aver (typep one '(or null (member :newest :wild :unspecific)
 808                             integer)))
 809          (aver (typep two '(or null (member :newest :wild :unspecific)
 810                             integer)))
 811          (cond
 812            ((eq one :wild) two)
 813            ((eq two :wild) one)
 814            ((or (null one) (eq one :unspecific)) two)
 815            ((or (null two) (eq two :unspecific)) one)
 816            ((eql one two) one)
 817            (t nil)))
 818        (intersect-name/type (one two)
 819          (aver (typep one '(or null (member :wild :unspecific) string)))
 820          (aver (typep two '(or null (member :wild :unspecific) string)))
 821          (cond
 822            ((eq one :wild) two)
 823            ((eq two :wild) one)
 824            ((or (null one) (eq one :unspecific)) two)
 825            ((or (null two) (eq two :unspecific)) one)
 826            ((string= one two) one)
 827            (t nil)))
 828        (intersect-directory (one two)
 829          (aver (typep one '(or null (member :wild :unspecific) list)))
 830          (aver (typep two '(or null (member :wild :unspecific) list)))
 831          (cond
 832            ((eq one :wild) two)
 833            ((eq two :wild) one)
 834            ((or (null one) (eq one :unspecific)) two)
 835            ((or (null two) (eq two :unspecific)) one)
 836            (t (aver (eq (car one) (car two)))
 837               (mapcar
 838                (lambda (x) (cons (car one) x))
 839                (intersect-directory-helper (cdr one) (cdr two)))))))
 840     (let ((version (intersect-version
 841                     (pathname-version one) (pathname-version two)))
 842           (name (intersect-name/type
 843                  (pathname-name one) (pathname-name two)))
 844           (type (intersect-name/type
 845                  (pathname-type one) (pathname-type two)))
 846           (host (pathname-host one)))
 847       (mapcar (lambda (d)
 848                 (make-pathname :host host :name name :type type
 849                                :version version :directory d))
 850               (intersect-directory
 851                (pathname-directory one) (pathname-directory two))))))
 852
 853 ;;; FIXME: written as its own function because I (CSR) don't
 854 ;;; understand it, so helping both debuggability and modularity.  In
 855 ;;; case anyone is motivated to rewrite it, it returns a list of
 856 ;;; sublists representing the intersection of the two input directory
 857 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 858 ;;;
 859 ;;; FIXME: Does not work with :UP or :BACK
 860 ;;; FIXME: Does not work with patterns
 861 ;;;
 862 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 863 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 864 ;;; turns out to be worth it.
 865 (defun intersect-directory-helper (one two)
 866   (flet ((simple-intersection (cone ctwo)
 867            (cond
 868              ((eq cone :wild) ctwo)
 869              ((eq ctwo :wild) cone)
 870              (t (aver (typep cone 'string))
 871                 (aver (typep ctwo 'string))
 872                 (if (string= cone ctwo) cone nil)))))
 873     (macrolet
 874         ((loop-possible-wild-inferiors-matches
 875              (lower-bound bounding-sequence order)
 876            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 877              `(let ((,l (length ,bounding-sequence)))
 878                (loop for ,index from ,lower-bound to ,l
 879                 append (mapcar (lambda (,g2)
 880                                  (append
 881                                   (butlast ,bounding-sequence (- ,l ,index))
 882                                   ,g2))
 883                         (mapcar
 884                          (lambda (,g3)
 885                            (append
 886                             (if (eq (car (nthcdr ,index ,bounding-sequence))
 887                                     :wild-inferiors)
 888                                 '(:wild-inferiors)
 889                                 nil) ,g3))
 890                          (intersect-directory-helper
 891                           ,@(if order
 892                                 `((nthcdr ,index one) (cdr two))
 893                                 `((cdr one) (nthcdr ,index two)))))))))))
 894       (cond
 895         ((and (eq (car one) :wild-inferiors)
 896               (eq (car two) :wild-inferiors))
 897          (delete-duplicates
 898           (append (mapcar (lambda (x) (cons :wild-inferiors x))
 899                           (intersect-directory-helper (cdr one) (cdr two)))
 900                   (loop-possible-wild-inferiors-matches 2 one t)
 901                   (loop-possible-wild-inferiors-matches 2 two nil))
 902           :test 'equal))
 903         ((eq (car one) :wild-inferiors)
 904          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
 905                             :test 'equal))
 906         ((eq (car two) :wild-inferiors)
 907          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
 908                             :test 'equal))
 909         ((and (null one) (null two)) (list nil))
 910         ((null one) nil)
 911         ((null two) nil)
 912         (t (and (simple-intersection (car one) (car two))
 913                 (mapcar (lambda (x) (cons (simple-intersection
 914                                            (car one) (car two)) x))
 915                         (intersect-directory-helper (cdr one) (cdr two)))))))))
 916
 917 (defun directory (pathname &key)
 918   #!+sb-doc
 919   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 920    given pathname. Note that the interaction between this ANSI-specified
 921    TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
 922    means this function can sometimes return files which don't have the same
 923    directory as PATHNAME."
 924   (let (;; We create one entry in this hash table for each truename,
 925         ;; as an asymptotically efficient way of removing duplicates
 926         ;; (which can arise when e.g. multiple symlinks map to the
 927         ;; same truename).
 928         (truenames (make-hash-table :test #'equal))
 929         ;; FIXME: Possibly this MERGE-PATHNAMES call should only
 930         ;; happen once we get a physical pathname.
 931         (merged-pathname (merge-pathnames pathname)))
 932     (labels ((do-physical-directory (pathname)
 933                (aver (not (logical-pathname-p pathname)))
 934                (!enumerate-matches (match pathname)
 935                  (let* ((*ignore-wildcards* t)
 936                         ;; FIXME: Why not TRUENAME?  As reported by
 937                         ;; Milan Zamazal sbcl-devel 2003-10-05, using
 938                         ;; TRUENAME causes a race condition whereby
 939                         ;; removal of a file during the directory
 940                         ;; operation causes an error.  It's not clear
 941                         ;; what the right thing to do is, though.  --
 942                         ;; CSR, 2003-10-13
 943                         (truename (probe-file match)))
 944                    (when truename
 945                      (setf (gethash (namestring truename) truenames)
 946                            truename)))))
 947              (do-directory (pathname)
 948                (if (logical-pathname-p pathname)
 949                    (let ((host (intern-logical-host (pathname-host pathname))))
 950                      (dolist (x (logical-host-canon-transls host))
 951                        (destructuring-bind (from to) x
 952                          (let ((intersections
 953                                 (pathname-intersections pathname from)))
 954                            (dolist (p intersections)
 955                              (do-directory (translate-pathname p from to)))))))
 956                    (do-physical-directory pathname))))
 957       (do-directory merged-pathname))
 958     (mapcar #'cdr
 959             ;; Sorting isn't required by the ANSI spec, but sorting
 960             ;; into some canonical order seems good just on the
 961             ;; grounds that the implementation should have repeatable
 962             ;; behavior when possible.
 963             (sort (loop for name being each hash-key in truenames
 964                      using (hash-value truename)
 965                      collect (cons name truename))
 966                   #'string<
 967                   :key #'car))))
 968 \f
 969 (/show0 "filesys.lisp 899")
 970
 971 ;;; predicate to order pathnames by; goes by name
 972 ;; FIXME: Does anything use this?  It's not exported, and I don't find
 973 ;; the name anywhere else.
 974 (defun pathname-order (x y)
 975   (let ((xn (%pathname-name x))
 976         (yn (%pathname-name y)))
 977     (if (and xn yn)
 978         (let ((res (string-lessp xn yn)))
 979           (cond ((not res) nil)
 980                 ((= res (length (the simple-string xn))) t)
 981                 ((= res (length (the simple-string yn))) nil)
 982                 (t t)))
 983         xn)))
 984 \f
 985 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
 986   #!+sb-doc
 987   "Test whether the directories containing the specified file
 988   actually exist, and attempt to create them if they do not.
 989   The MODE argument is a CMUCL/SBCL-specific extension to control
 990   the Unix permission bits."
 991   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
 992         (created-p nil))
 993     (when (wild-pathname-p pathname)
 994       (error 'simple-file-error
 995              :format-control "bad place for a wild pathname"
 996              :pathname pathspec))
 997     (let ((dir (pathname-directory pathname)))
 998       (loop for i from 1 upto (length dir)
 999             do (let ((newpath (make-pathname
1000                                :host (pathname-host pathname)
1001                                :device (pathname-device pathname)
1002                                :directory (subseq dir 0 i))))
1003                  (unless (probe-file newpath)
1004                    (let ((namestring (coerce (native-namestring newpath)
1005                                              'string)))
1006                      (when verbose
1007                        (format *standard-output*
1008                                "~&creating directory: ~A~%"
1009                                namestring))
1010                      (sb!unix:unix-mkdir namestring mode)
1011                      (unless (probe-file newpath)
1012                        (restart-case (error
1013                                       'simple-file-error
1014                                       :pathname pathspec
1015                                       :format-control
1016                                       "can't create directory ~A"
1017                                       :format-arguments (list namestring))
1018                          (retry ()
1019                            :report "Retry directory creation."
1020                            (ensure-directories-exist
1021                             pathspec
1022                             :verbose verbose :mode mode))
1023                          (continue ()
1024                            :report
1025                            "Continue as if directory creation was successful."
1026                            nil)))
1027                      (setf created-p t)))))
1028       (values pathspec created-p))))
1029
1030 (/show0 "filesys.lisp 1000")