src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defvar *ignore-wildcards* nil)
  84
  85 (/show0 "filesys.lisp 86")
  86
  87 (defun maybe-make-pattern (namestr start end)
  88   (declare (type simple-string namestr)
  89            (type index start end))
  90   (if *ignore-wildcards*
  91       (subseq namestr start end)
  92       (collect ((pattern))
  93         (let ((quoted nil)
  94               (any-quotes nil)
  95               (last-regular-char nil)
  96               (index start))
  97           (flet ((flush-pending-regulars ()
  98                    (when last-regular-char
  99                      (pattern (if any-quotes
 100                                   (remove-backslashes namestr
 101                                                       last-regular-char
 102                                                       index)
 103                                   (subseq namestr last-regular-char index)))
 104                      (setf any-quotes nil)
 105                      (setf last-regular-char nil))))
 106             (loop
 107               (when (>= index end)
 108                 (return))
 109               (let ((char (schar namestr index)))
 110                 (cond (quoted
 111                        (incf index)
 112                        (setf quoted nil))
 113                       ((char= char #\\)
 114                        (setf quoted t)
 115                        (setf any-quotes t)
 116                        (unless last-regular-char
 117                          (setf last-regular-char index))
 118                        (incf index))
 119                       ((char= char #\?)
 120                        (flush-pending-regulars)
 121                        (pattern :single-char-wild)
 122                        (incf index))
 123                       ((char= char #\*)
 124                        (flush-pending-regulars)
 125                        (pattern :multi-char-wild)
 126                        (incf index))
 127                       ((char= char #\[)
 128                        (flush-pending-regulars)
 129                        (let ((close-bracket
 130                               (position #\] namestr :start index :end end)))
 131                          (unless close-bracket
 132                            (error 'namestring-parse-error
 133                                   :complaint "#\\[ with no corresponding #\\]"
 134                                   :namestring namestr
 135                                   :offset index))
 136                          (pattern (cons :character-set
 137                                         (subseq namestr
 138                                                 (1+ index)
 139                                                 close-bracket)))
 140                          (setf index (1+ close-bracket))))
 141                       (t
 142                        (unless last-regular-char
 143                          (setf last-regular-char index))
 144                        (incf index)))))
 145             (flush-pending-regulars)))
 146         (cond ((null (pattern))
 147                "")
 148               ((null (cdr (pattern)))
 149                (let ((piece (first (pattern))))
 150                  (typecase piece
 151                    ((member :multi-char-wild) :wild)
 152                    (simple-string piece)
 153                    (t
 154                     (make-pattern (pattern))))))
 155               (t
 156                (make-pattern (pattern)))))))
 157
 158 (/show0 "filesys.lisp 160")
 159
 160 (defun extract-name-type-and-version (namestr start end)
 161   (declare (type simple-string namestr)
 162            (type index start end))
 163   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 164                              :from-end t)))
 165     (cond
 166       (last-dot
 167        (values (maybe-make-pattern namestr start last-dot)
 168                (maybe-make-pattern namestr (1+ last-dot) end)
 169                :newest))
 170       (t
 171        (values (maybe-make-pattern namestr start end)
 172                nil
 173                :newest)))))
 174
 175 (/show0 "filesys.lisp 200")
 176
 177 \f
 178 ;;;; wildcard matching stuff
 179
 180 ;;; Return a list of all the Lispy filenames (not including e.g. the
 181 ;;; Unix magic "." and "..") in the directory named by DIRECTORY-NAME.
 182 (defun directory-lispy-filenames (directory-name)
 183   (with-alien ((adlf (* c-string)
 184                      (alien-funcall (extern-alien
 185                                      "alloc_directory_lispy_filenames"
 186                                      (function (* c-string) c-string))
 187                                     directory-name)))
 188     (if (null-alien adlf)
 189         (error 'simple-file-error
 190                :pathname directory-name
 191                :format-control "~@<couldn't read directory ~S: ~2I~_~A~:>"
 192                :format-arguments (list directory-name (strerror)))
 193         (unwind-protect
 194             (c-strings->string-list adlf)
 195           (alien-funcall (extern-alien "free_directory_lispy_filenames"
 196                                        (function void (* c-string)))
 197                          adlf)))))
 198
 199 (/show0 "filesys.lisp 498")
 200
 201 (defmacro !enumerate-matches ((var pathname &optional result
 202                                    &key (verify-existence t)
 203                                    (follow-links t))
 204                               &body body)
 205   `(block nil
 206      (%enumerate-matches (pathname ,pathname)
 207                          ,verify-existence
 208                          ,follow-links
 209                          (lambda (,var) ,@body))
 210      ,result))
 211
 212 (/show0 "filesys.lisp 500")
 213
 214 ;;; Call FUNCTION on matches.
 215 ;;;
 216 ;;; KLUDGE: this assumes that an absolute pathname is indicated to the
 217 ;;; operating system by having a directory separator as the first
 218 ;;; character in the directory part.  This is true for Win32 pathnames
 219 ;;; and for Unix pathnames, but it isn't true for LispM pathnames (and
 220 ;;; their bastard offspring, logical pathnames.  Also it assumes that
 221 ;;; Unix pathnames have an empty or :unspecific device, and that
 222 ;;; windows drive letters are the only kinds of non-empty/:UNSPECIFIC
 223 ;;; devices.
 224 (defun %enumerate-matches (pathname verify-existence follow-links function)
 225   (/noshow0 "entering %ENUMERATE-MATCHES")
 226   (when (pathname-type pathname)
 227     (unless (pathname-name pathname)
 228       (error "cannot supply a type without a name:~%  ~S" pathname)))
 229   (when (and (integerp (pathname-version pathname))
 230              (member (pathname-type pathname) '(nil :unspecific)))
 231     (error "cannot supply a version without a type:~%  ~S" pathname))
 232   (let ((host (pathname-host pathname))
 233         (device (pathname-device pathname))
 234         (directory (pathname-directory pathname)))
 235     (/noshow0 "computed HOST and DIRECTORY")
 236     (let* ((dirstring (if directory
 237                           (ecase (first directory)
 238                             (:absolute (host-unparse-directory-separator host))
 239                             (:relative ""))
 240                           ""))
 241            (devstring (if (and device (not (eq device :unspecific)))
 242                           (concatenate 'simple-string (string device) (string #\:))
 243                           ""))
 244            (headstring (concatenate 'simple-string devstring dirstring)))
 245       (if directory
 246           (%enumerate-directories headstring (rest directory) pathname
 247                                   verify-existence follow-links nil function)
 248           (%enumerate-files headstring pathname verify-existence function)))))
 249
 250 ;;; Call FUNCTION on directories.
 251 (defun %enumerate-directories (head tail pathname verify-existence
 252                                follow-links nodes function
 253                                &aux (host (pathname-host pathname)))
 254   (declare (simple-string head))
 255   #!+win32
 256   (setf follow-links nil)
 257   (macrolet ((unix-xstat (name)
 258                `(if follow-links
 259                     (sb!unix:unix-stat ,name)
 260                     (sb!unix:unix-lstat ,name)))
 261              (with-directory-node-noted ((head) &body body)
 262                `(multiple-value-bind (res dev ino mode)
 263                     (unix-xstat ,head)
 264                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 265                                       sb!unix:s-ifdir))
 266                     (let ((nodes (cons (cons dev ino) nodes)))
 267                       ,@body))))
 268              (with-directory-node-removed ((head) &body body)
 269                `(multiple-value-bind (res dev ino mode)
 270                     (unix-xstat ,head)
 271                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 272                                       sb!unix:s-ifdir))
 273                     (let ((nodes (remove (cons dev ino) nodes :test #'equal)))
 274                       ,@body)))))
 275     (if tail
 276         (let ((piece (car tail)))
 277           (etypecase piece
 278             (simple-string
 279              (let ((head (concatenate 'string head piece)))
 280                (with-directory-node-noted (head)
 281                  (%enumerate-directories
 282                   (concatenate 'string head
 283                                (host-unparse-directory-separator host))
 284                   (cdr tail) pathname
 285                   verify-existence follow-links
 286                   nodes function))))
 287             ((member :wild-inferiors)
 288              ;; now with extra error case handling from CLHS
 289              ;; 19.2.2.4.3 -- CSR, 2004-01-24
 290              (when (member (cadr tail) '(:up :back))
 291                (error 'simple-file-error
 292                       :pathname pathname
 293                       :format-control "~@<invalid use of ~S after :WILD-INFERIORS~@:>."
 294                       :format-arguments (list (cadr tail))))
 295              (%enumerate-directories head (rest tail) pathname
 296                                      verify-existence follow-links
 297                                      nodes function)
 298              (dolist (name (directory-lispy-filenames head))
 299                (let ((subdir (concatenate 'string head name)))
 300                  (multiple-value-bind (res dev ino mode)
 301                      (unix-xstat subdir)
 302                    (declare (type (or fixnum null) mode))
 303                    (when (and res (eql (logand mode sb!unix:s-ifmt)
 304                                        sb!unix:s-ifdir))
 305                      (unless (dolist (dir nodes nil)
 306                                (when (and (eql (car dir) dev)
 307                                           #!+win32 ;; KLUDGE
 308                                           (not (zerop ino))
 309                                           (eql (cdr dir) ino))
 310                                  (return t)))
 311                        (let ((nodes (cons (cons dev ino) nodes))
 312                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 313                          (%enumerate-directories subdir tail pathname
 314                                                  verify-existence follow-links
 315                                                  nodes function))))))))
 316             ((or pattern (member :wild))
 317              (dolist (name (directory-lispy-filenames head))
 318                (when (or (eq piece :wild) (pattern-matches piece name))
 319                  (let ((subdir (concatenate 'string head name)))
 320                    (multiple-value-bind (res dev ino mode)
 321                        (unix-xstat subdir)
 322                      (declare (type (or fixnum null) mode))
 323                      (when (and res
 324                                 (eql (logand mode sb!unix:s-ifmt)
 325                                      sb!unix:s-ifdir))
 326                        (let ((nodes (cons (cons dev ino) nodes))
 327                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 328                          (%enumerate-directories subdir (rest tail) pathname
 329                                                  verify-existence follow-links
 330                                                  nodes function))))))))
 331           ((member :up)
 332            (when (string= head (host-unparse-directory-separator host))
 333              (error 'simple-file-error
 334                     :pathname pathname
 335                     :format-control "~@<invalid use of :UP after :ABSOLUTE.~@:>"))
 336            (with-directory-node-removed (head)
 337              (let ((head (concatenate 'string head "..")))
 338                (with-directory-node-noted (head)
 339                  (%enumerate-directories (concatenate 'string head (host-unparse-directory-separator host))
 340                                          (rest tail) pathname
 341                                          verify-existence follow-links
 342                                          nodes function)))))
 343           ((member :back)
 344            ;; :WILD-INFERIORS is handled above, so the only case here
 345            ;; should be (:ABSOLUTE :BACK)
 346            (aver (string= head (host-unparse-directory-separator host)))
 347            (error 'simple-file-error
 348                   :pathname pathname
 349                   :format-control "~@<invalid use of :BACK after :ABSOLUTE.~@:>"))))
 350         (%enumerate-files head pathname verify-existence function))))
 351
 352 ;;; Call FUNCTION on files.
 353 (defun %enumerate-files (directory pathname verify-existence function)
 354   (declare (simple-string directory))
 355   (/noshow0 "entering %ENUMERATE-FILES")
 356   (let ((name (%pathname-name pathname))
 357         (type (%pathname-type pathname))
 358         (version (%pathname-version pathname)))
 359     (/noshow0 "computed NAME, TYPE, and VERSION")
 360     (cond ((member name '(nil :unspecific))
 361            (/noshow0 "UNSPECIFIC, more or less")
 362            (let ((directory (coerce directory 'string)))
 363              (when (or (not verify-existence)
 364                        (sb!unix:unix-file-kind directory))
 365                (funcall function directory))))
 366           ((or (pattern-p name)
 367                (pattern-p type)
 368                (eq name :wild)
 369                (eq type :wild))
 370            (/noshow0 "WILD, more or less")
 371            ;; I IGNORE-ERRORS here just because the original CMU CL
 372            ;; code did. I think the intent is that it's not an error
 373            ;; to request matches to a wild pattern when no matches
 374            ;; exist, but I haven't tried to figure out whether
 375            ;; everything is kosher. (E.g. what if we try to match a
 376            ;; wildcard but we don't have permission to read one of the
 377            ;; relevant directories?) -- WHN 2001-04-17
 378            (dolist (complete-filename (ignore-errors
 379                                         (directory-lispy-filenames directory)))
 380              (multiple-value-bind
 381                  (file-name file-type file-version)
 382                  (let ((*ignore-wildcards* t))
 383                    (extract-name-type-and-version
 384                     complete-filename 0 (length complete-filename)))
 385                (when (and (components-match file-name name)
 386                           (components-match file-type type)
 387                           (components-match file-version version))
 388                  (funcall function
 389                           (concatenate 'string
 390                                        directory
 391                                        complete-filename))))))
 392           (t
 393            (/noshow0 "default case")
 394            (let ((file (concatenate 'string directory name)))
 395              (/noshow "computed basic FILE")
 396              (unless (or (null type) (eq type :unspecific))
 397                (/noshow0 "tweaking FILE for more-or-less-:UNSPECIFIC case")
 398                (setf file (concatenate 'string file "." type)))
 399              (unless (member version '(nil :newest :wild :unspecific))
 400                (/noshow0 "tweaking FILE for more-or-less-:WILD case")
 401                (setf file (concatenate 'string file "."
 402                                        (quick-integer-to-string version))))
 403              (/noshow0 "finished possibly tweaking FILE")
 404              (when (or (not verify-existence)
 405                        (sb!unix:unix-file-kind file t))
 406                (/noshow0 "calling FUNCTION on FILE")
 407                (funcall function file)))))))
 408
 409 (/noshow0 "filesys.lisp 603")
 410
 411 ;;; FIXME: Why do we need this?
 412 (defun quick-integer-to-string (n)
 413   (declare (type integer n))
 414   (cond ((not (fixnump n))
 415          (write-to-string n :base 10 :radix nil))
 416         ((zerop n) "0")
 417         ((eql n 1) "1")
 418         ((minusp n)
 419          (concatenate 'simple-base-string "-"
 420                       (the simple-base-string (quick-integer-to-string (- n)))))
 421         (t
 422          (do* ((len (1+ (truncate (integer-length n) 3)))
 423                (res (make-string len :element-type 'base-char))
 424                (i (1- len) (1- i))
 425                (q n)
 426                (r 0))
 427               ((zerop q)
 428                (incf i)
 429                (replace res res :start2 i :end2 len)
 430                (%shrink-vector res (- len i)))
 431            (declare (simple-string res)
 432                     (fixnum len i r q))
 433            (multiple-value-setq (q r) (truncate q 10))
 434            (setf (schar res i) (schar "0123456789" r))))))
 435 \f
 436 ;;;; UNIX-NAMESTRING
 437
 438 (defun empty-relative-pathname-spec-p (x)
 439   (or (equal x "")
 440       (and (pathnamep x)
 441            (or (equal (pathname-directory x) '(:relative))
 442                ;; KLUDGE: I'm not sure this second check should really
 443                ;; have to be here. But on sbcl-0.6.12.7,
 444                ;; (PATHNAME-DIRECTORY (PATHNAME "")) is NIL, and
 445                ;; (PATHNAME "") seems to act like an empty relative
 446                ;; pathname, so in order to work with that, I test
 447                ;; for NIL here. -- WHN 2001-05-18
 448                (null (pathname-directory x)))
 449            (null (pathname-name x))
 450            (null (pathname-type x)))
 451       ;; (The ANSI definition of "pathname specifier" has
 452       ;; other cases, but none of them seem to admit the possibility
 453       ;; of being empty and relative.)
 454       ))
 455
 456 ;;; Convert PATHNAME into a string that can be used with UNIX system
 457 ;;; calls, or return NIL if no match is found. Wild-cards are expanded.
 458 ;;;
 459 ;;; FIXME: apart from the error checking (for wildness and for
 460 ;;; existence) and conversion to physical pathanme, this is redundant
 461 ;;; with UNPARSE-NATIVE-UNIX-NAMESTRING; one should probably be
 462 ;;; written in terms of the other.
 463 ;;;
 464 ;;; FIXME: actually this (I think) works not just for Unix.
 465 (defun unix-namestring (pathname-spec &optional (for-input t))
 466   (let* ((namestring (physicalize-pathname (merge-pathnames pathname-spec)))
 467          (matches nil)) ; an accumulator for actual matches
 468     (when (wild-pathname-p namestring)
 469       (error 'simple-file-error
 470              :pathname namestring
 471              :format-control "bad place for a wild pathname"))
 472     (!enumerate-matches (match namestring nil :verify-existence for-input)
 473                         (push match matches))
 474     (case (length matches)
 475       (0 nil)
 476       (1 (first matches))
 477       (t (bug "!ENUMERATE-MATCHES returned more than one match on a non-wild pathname")))))
 478 \f
 479 ;;;; TRUENAME and PROBE-FILE
 480
 481 ;;; This is only trivially different from PROBE-FILE, which is silly
 482 ;;; but ANSI.
 483 (defun truename (pathname)
 484   #!+sb-doc
 485   "Return the pathname for the actual file described by PATHNAME.
 486 An error of type FILE-ERROR is signalled if no such file exists, or the
 487 pathname is wild.
 488
 489 Under Unix, the TRUENAME of a broken symlink is considered to be the name of
 490 the broken symlink itself."
 491   (let ((result (probe-file pathname)))
 492     (unless result
 493       (error 'simple-file-error
 494              :pathname pathname
 495              :format-control "The file ~S does not exist."
 496              :format-arguments (list (namestring pathname))))
 497     result))
 498
 499 (defun probe-file (pathname)
 500   #!+sb-doc
 501   "Return a pathname which is the truename of the file if it exists, or NIL
 502 otherwise. An error of type FILE-ERROR is signaled if pathname is wild."
 503   (let* ((defaulted-pathname (merge-pathnames
 504                               pathname
 505                               (sane-default-pathname-defaults)))
 506          (namestring (unix-namestring defaulted-pathname t)))
 507     (when (and namestring (sb!unix:unix-file-kind namestring t))
 508       (let ((trueishname (sb!unix:unix-resolve-links namestring)))
 509         (when trueishname
 510           (let* ((*ignore-wildcards* t)
 511                  (name (simplify-namestring
 512                         trueishname
 513                         (pathname-host defaulted-pathname))))
 514             (if (eq (sb!unix:unix-file-kind name) :directory)
 515                 ;; FIXME: this might work, but it's ugly.
 516                 (pathname (concatenate 'string name "/"))
 517                 (pathname name))))))))
 518 \f
 519 ;;;; miscellaneous other operations
 520
 521 (/show0 "filesys.lisp 700")
 522
 523 (defun rename-file (file new-name)
 524   #!+sb-doc
 525   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 526   file, then the associated file is renamed."
 527   (let* ((original (truename file))
 528          (original-namestring (unix-namestring original t))
 529          (new-name (merge-pathnames new-name original))
 530          (new-namestring (unix-namestring new-name nil)))
 531     (unless new-namestring
 532       (error 'simple-file-error
 533              :pathname new-name
 534              :format-control "~S can't be created."
 535              :format-arguments (list new-name)))
 536     (multiple-value-bind (res error)
 537         (sb!unix:unix-rename original-namestring new-namestring)
 538       (unless res
 539         (error 'simple-file-error
 540                :pathname new-name
 541                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 542                                 ~I~_~A~:>"
 543                :format-arguments (list original new-name (strerror error))))
 544       (when (streamp file)
 545         (file-name file new-name))
 546       (values new-name original (truename new-name)))))
 547
 548 (defun delete-file (file)
 549   #!+sb-doc
 550   "Delete the specified FILE."
 551   (let ((namestring (unix-namestring file t)))
 552     (when (streamp file)
 553       (close file :abort t))
 554     (unless namestring
 555       (error 'simple-file-error
 556              :pathname file
 557              :format-control "~S doesn't exist."
 558              :format-arguments (list file)))
 559     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 560       (unless res
 561         (simple-file-perror "couldn't delete ~A" namestring err))))
 562   t)
 563 \f
 564 (defun ensure-trailing-slash (string)
 565   (let ((last-char (char string (1- (length string)))))
 566          (if (or (eql last-char #\/)
 567                  #!+win32
 568                  (eql last-char #\\))
 569              string
 570              (concatenate 'string string "/"))))
 571
 572 (defun sbcl-homedir-pathname ()
 573   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 574     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 575     (when sbcl-home
 576       (parse-native-namestring
 577        (ensure-trailing-slash sbcl-home)))))
 578
 579 ;;; (This is an ANSI Common Lisp function.)
 580 (defun user-homedir-pathname (&optional host)
 581   #!+sb-doc
 582   "Return the home directory of the user as a pathname. If the HOME
 583 environment variable has been specified, the directory it designates
 584 is returned; otherwise obtains the home directory from the operating
 585 system."
 586   (declare (ignore host))
 587   (let ((env-home (posix-getenv "HOME")))
 588     (parse-native-namestring
 589      (ensure-trailing-slash
 590       (if (and env-home
 591                (not (equal env-home "")))
 592           env-home
 593           #!-win32
 594           (sb!unix:uid-homedir (sb!unix:unix-getuid))
 595           #!+win32
 596           ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 597           (return-from user-homedir-pathname
 598             (sb!win32::get-folder-pathname sb!win32::csidl_profile)))))))
 599
 600 (defun file-write-date (file)
 601   #!+sb-doc
 602   "Return file's creation date, or NIL if it doesn't exist.
 603  An error of type file-error is signaled if file is a wild pathname"
 604   (let ((name (unix-namestring file t)))
 605     (when name
 606       (multiple-value-bind
 607             (res dev ino mode nlink uid gid rdev size atime mtime)
 608           (sb!unix:unix-stat name)
 609         (declare (ignore dev ino mode nlink uid gid rdev size atime))
 610         (when res
 611           (+ unix-to-universal-time mtime))))))
 612
 613 (defun file-author (file)
 614   #!+sb-doc
 615   "Return the file author as a string, or NIL if the author cannot be
 616  determined. Signal an error of type FILE-ERROR if FILE doesn't exist,
 617  or FILE is a wild pathname."
 618   (let ((name (unix-namestring (pathname file) t)))
 619     (unless name
 620       (error 'simple-file-error
 621              :pathname file
 622              :format-control "~S doesn't exist."
 623              :format-arguments (list file)))
 624     (multiple-value-bind (winp dev ino mode nlink uid)
 625         (sb!unix:unix-stat name)
 626       (declare (ignore dev ino mode nlink))
 627       (and winp (sb!unix:uid-username uid)))))
 628 \f
 629 ;;;; DIRECTORY
 630
 631 (/show0 "filesys.lisp 800")
 632
 633 ;;; NOTE: There is a fair amount of hair below that is probably not
 634 ;;; strictly necessary.
 635 ;;;
 636 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 637 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 638 ;;; did not translate the logical pathname at all, but instead treated
 639 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 640 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 641 ;;; which is fine as far as it goes, but not very interesting, and
 642 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 643 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 644 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 645 ;;; exists, of course).
 646 ;;;
 647 ;;; So, the interpretation that I am pushing is for all pathnames
 648 ;;; matching the input pathname to be queried.  This means that we
 649 ;;; need to compute the intersection of the input pathname and the
 650 ;;; logical host FROM translations, and then translate the resulting
 651 ;;; pathname using the host to the TO translation; this treatment is
 652 ;;; recursively invoked until we get a physical pathname, whereupon
 653 ;;; our physical DIRECTORY implementation takes over.
 654
 655 ;;; FIXME: this is an incomplete implementation.  It only works when
 656 ;;; both are logical pathnames (which is OK, because that's the only
 657 ;;; case when we call it), but there are other pitfalls as well: see
 658 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 659 ;;; pattern handling.
 660 (defun pathname-intersections (one two)
 661   (aver (logical-pathname-p one))
 662   (aver (logical-pathname-p two))
 663   (labels
 664       ((intersect-version (one two)
 665          (aver (typep one '(or null (member :newest :wild :unspecific)
 666                             integer)))
 667          (aver (typep two '(or null (member :newest :wild :unspecific)
 668                             integer)))
 669          (cond
 670            ((eq one :wild) two)
 671            ((eq two :wild) one)
 672            ((or (null one) (eq one :unspecific)) two)
 673            ((or (null two) (eq two :unspecific)) one)
 674            ((eql one two) one)
 675            (t nil)))
 676        (intersect-name/type (one two)
 677          (aver (typep one '(or null (member :wild :unspecific) string)))
 678          (aver (typep two '(or null (member :wild :unspecific) string)))
 679          (cond
 680            ((eq one :wild) two)
 681            ((eq two :wild) one)
 682            ((or (null one) (eq one :unspecific)) two)
 683            ((or (null two) (eq two :unspecific)) one)
 684            ((string= one two) one)
 685            (t nil)))
 686        (intersect-directory (one two)
 687          (aver (typep one '(or null (member :wild :unspecific) list)))
 688          (aver (typep two '(or null (member :wild :unspecific) list)))
 689          (cond
 690            ((eq one :wild) two)
 691            ((eq two :wild) one)
 692            ((or (null one) (eq one :unspecific)) two)
 693            ((or (null two) (eq two :unspecific)) one)
 694            (t (aver (eq (car one) (car two)))
 695               (mapcar
 696                (lambda (x) (cons (car one) x))
 697                (intersect-directory-helper (cdr one) (cdr two)))))))
 698     (let ((version (intersect-version
 699                     (pathname-version one) (pathname-version two)))
 700           (name (intersect-name/type
 701                  (pathname-name one) (pathname-name two)))
 702           (type (intersect-name/type
 703                  (pathname-type one) (pathname-type two)))
 704           (host (pathname-host one)))
 705       (mapcar (lambda (d)
 706                 (make-pathname :host host :name name :type type
 707                                :version version :directory d))
 708               (intersect-directory
 709                (pathname-directory one) (pathname-directory two))))))
 710
 711 ;;; FIXME: written as its own function because I (CSR) don't
 712 ;;; understand it, so helping both debuggability and modularity.  In
 713 ;;; case anyone is motivated to rewrite it, it returns a list of
 714 ;;; sublists representing the intersection of the two input directory
 715 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 716 ;;;
 717 ;;; FIXME: Does not work with :UP or :BACK
 718 ;;; FIXME: Does not work with patterns
 719 ;;;
 720 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 721 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 722 ;;; turns out to be worth it.
 723 (defun intersect-directory-helper (one two)
 724   (flet ((simple-intersection (cone ctwo)
 725            (cond
 726              ((eq cone :wild) ctwo)
 727              ((eq ctwo :wild) cone)
 728              (t (aver (typep cone 'string))
 729                 (aver (typep ctwo 'string))
 730                 (if (string= cone ctwo) cone nil)))))
 731     (macrolet
 732         ((loop-possible-wild-inferiors-matches
 733              (lower-bound bounding-sequence order)
 734            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 735              `(let ((,l (length ,bounding-sequence)))
 736                (loop for ,index from ,lower-bound to ,l
 737                 append (mapcar (lambda (,g2)
 738                                  (append
 739                                   (butlast ,bounding-sequence (- ,l ,index))
 740                                   ,g2))
 741                         (mapcar
 742                          (lambda (,g3)
 743                            (append
 744                             (if (eq (car (nthcdr ,index ,bounding-sequence))
 745                                     :wild-inferiors)
 746                                 '(:wild-inferiors)
 747                                 nil) ,g3))
 748                          (intersect-directory-helper
 749                           ,@(if order
 750                                 `((nthcdr ,index one) (cdr two))
 751                                 `((cdr one) (nthcdr ,index two)))))))))))
 752       (cond
 753         ((and (eq (car one) :wild-inferiors)
 754               (eq (car two) :wild-inferiors))
 755          (delete-duplicates
 756           (append (mapcar (lambda (x) (cons :wild-inferiors x))
 757                           (intersect-directory-helper (cdr one) (cdr two)))
 758                   (loop-possible-wild-inferiors-matches 2 one t)
 759                   (loop-possible-wild-inferiors-matches 2 two nil))
 760           :test 'equal))
 761         ((eq (car one) :wild-inferiors)
 762          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
 763                             :test 'equal))
 764         ((eq (car two) :wild-inferiors)
 765          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
 766                             :test 'equal))
 767         ((and (null one) (null two)) (list nil))
 768         ((null one) nil)
 769         ((null two) nil)
 770         (t (and (simple-intersection (car one) (car two))
 771                 (mapcar (lambda (x) (cons (simple-intersection
 772                                            (car one) (car two)) x))
 773                         (intersect-directory-helper (cdr one) (cdr two)))))))))
 774
 775 (defun directory (pathname &key)
 776   #!+sb-doc
 777   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 778    given pathname. Note that the interaction between this ANSI-specified
 779    TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
 780    means this function can sometimes return files which don't have the same
 781    directory as PATHNAME."
 782   (let (;; We create one entry in this hash table for each truename,
 783         ;; as an asymptotically efficient way of removing duplicates
 784         ;; (which can arise when e.g. multiple symlinks map to the
 785         ;; same truename).
 786         (truenames (make-hash-table :test #'equal))
 787         ;; FIXME: Possibly this MERGE-PATHNAMES call should only
 788         ;; happen once we get a physical pathname.
 789         (merged-pathname (merge-pathnames pathname)))
 790     (labels ((do-physical-directory (pathname)
 791                (aver (not (logical-pathname-p pathname)))
 792                (!enumerate-matches (match pathname)
 793                  (let* ((*ignore-wildcards* t)
 794                         ;; FIXME: Why not TRUENAME?  As reported by
 795                         ;; Milan Zamazal sbcl-devel 2003-10-05, using
 796                         ;; TRUENAME causes a race condition whereby
 797                         ;; removal of a file during the directory
 798                         ;; operation causes an error.  It's not clear
 799                         ;; what the right thing to do is, though.  --
 800                         ;; CSR, 2003-10-13
 801                         (truename (probe-file match)))
 802                    (when truename
 803                      (setf (gethash (namestring truename) truenames)
 804                            truename)))))
 805              (do-directory (pathname)
 806                (if (logical-pathname-p pathname)
 807                    (let ((host (intern-logical-host (pathname-host pathname))))
 808                      (dolist (x (logical-host-canon-transls host))
 809                        (destructuring-bind (from to) x
 810                          (let ((intersections
 811                                 (pathname-intersections pathname from)))
 812                            (dolist (p intersections)
 813                              (do-directory (translate-pathname p from to)))))))
 814                    (do-physical-directory pathname))))
 815       (do-directory merged-pathname))
 816     (mapcar #'cdr
 817             ;; Sorting isn't required by the ANSI spec, but sorting
 818             ;; into some canonical order seems good just on the
 819             ;; grounds that the implementation should have repeatable
 820             ;; behavior when possible.
 821             (sort (loop for name being each hash-key in truenames
 822                      using (hash-value truename)
 823                      collect (cons name truename))
 824                   #'string<
 825                   :key #'car))))
 826 \f
 827 (/show0 "filesys.lisp 899")
 828
 829 ;;; predicate to order pathnames by; goes by name
 830 (defun pathname-order (x y)
 831   (let ((xn (%pathname-name x))
 832         (yn (%pathname-name y)))
 833     (if (and xn yn)
 834         (let ((res (string-lessp xn yn)))
 835           (cond ((not res) nil)
 836                 ((= res (length (the simple-string xn))) t)
 837                 ((= res (length (the simple-string yn))) nil)
 838                 (t t)))
 839         xn)))
 840 \f
 841 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
 842   #!+sb-doc
 843   "Test whether the directories containing the specified file
 844   actually exist, and attempt to create them if they do not.
 845   The MODE argument is a CMUCL/SBCL-specific extension to control
 846   the Unix permission bits."
 847   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
 848         (created-p nil))
 849     (when (wild-pathname-p pathname)
 850       (error 'simple-file-error
 851              :format-control "bad place for a wild pathname"
 852              :pathname pathspec))
 853     (let ((dir (pathname-directory pathname)))
 854       (loop for i from 1 upto (length dir)
 855             do (let ((newpath (make-pathname
 856                                :host (pathname-host pathname)
 857                                :device (pathname-device pathname)
 858                                :directory (subseq dir 0 i))))
 859                  (unless (probe-file newpath)
 860                    (let ((namestring (coerce (namestring newpath) 'string)))
 861                      (when verbose
 862                        (format *standard-output*
 863                                "~&creating directory: ~A~%"
 864                                namestring))
 865                      (sb!unix:unix-mkdir namestring mode)
 866                      (unless (probe-file namestring)
 867                        (restart-case (error 'simple-file-error
 868                                             :pathname pathspec
 869                                             :format-control "can't create directory ~A"
 870                                             :format-arguments (list namestring))
 871                          (retry ()
 872                            :report "Retry directory creation."
 873                            (ensure-directories-exist pathspec :verbose verbose :mode mode))
 874                          (continue ()
 875                            :report "Continue as if directory creation was successful."
 876                            nil)))
 877                      (setf created-p t)))))
 878       (values pathspec created-p))))
 879
 880 (/show0 "filesys.lisp 1000")