src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defun maybe-make-pattern (namestr start end)
  84   (declare (type simple-string namestr)
  85            (type index start end))
  86   (collect ((pattern))
  87     (let ((quoted nil)
  88           (any-quotes nil)
  89           (last-regular-char nil)
  90           (index start))
  91       (flet ((flush-pending-regulars ()
  92                (when last-regular-char
  93                  (pattern (if any-quotes
  94                               (remove-backslashes namestr
  95                                                   last-regular-char
  96                                                   index)
  97                               (subseq namestr last-regular-char index)))
  98                  (setf any-quotes nil)
  99                  (setf last-regular-char nil))))
 100         (loop
 101           (when (>= index end)
 102             (return))
 103           (let ((char (schar namestr index)))
 104             (cond (quoted
 105                    (incf index)
 106                    (setf quoted nil))
 107                   ((char= char #\\)
 108                    (setf quoted t)
 109                    (setf any-quotes t)
 110                    (unless last-regular-char
 111                      (setf last-regular-char index))
 112                    (incf index))
 113                   ((char= char #\?)
 114                    (flush-pending-regulars)
 115                    (pattern :single-char-wild)
 116                    (incf index))
 117                   ((char= char #\*)
 118                    (flush-pending-regulars)
 119                    (pattern :multi-char-wild)
 120                    (incf index))
 121                   ((char= char #\[)
 122                    (flush-pending-regulars)
 123                    (let ((close-bracket
 124                           (position #\] namestr :start index :end end)))
 125                      (unless close-bracket
 126                        (error 'namestring-parse-error
 127                               :complaint "#\\[ with no corresponding #\\]"
 128                               :namestring namestr
 129                               :offset index))
 130                      (pattern (cons :character-set
 131                                     (subseq namestr
 132                                             (1+ index)
 133                                             close-bracket)))
 134                      (setf index (1+ close-bracket))))
 135                   (t
 136                    (unless last-regular-char
 137                      (setf last-regular-char index))
 138                    (incf index)))))
 139         (flush-pending-regulars)))
 140     (cond ((null (pattern))
 141            "")
 142           ((null (cdr (pattern)))
 143            (let ((piece (first (pattern))))
 144              (typecase piece
 145                ((member :multi-char-wild) :wild)
 146                (simple-string piece)
 147                (t
 148                 (make-pattern (pattern))))))
 149           (t
 150            (make-pattern (pattern))))))
 151
 152 (defun unparse-physical-piece (thing)
 153   (etypecase thing
 154     ((member :wild) "*")
 155     (simple-string
 156      (let* ((srclen (length thing))
 157             (dstlen srclen))
 158        (dotimes (i srclen)
 159          (case (schar thing i)
 160            ((#\* #\? #\[)
 161             (incf dstlen))))
 162        (let ((result (make-string dstlen))
 163              (dst 0))
 164          (dotimes (src srclen)
 165            (let ((char (schar thing src)))
 166              (case char
 167                ((#\* #\? #\[)
 168                 (setf (schar result dst) #\\)
 169                 (incf dst)))
 170              (setf (schar result dst) char)
 171              (incf dst)))
 172          result)))
 173     (pattern
 174      (with-output-to-string (s)
 175        (dolist (piece (pattern-pieces thing))
 176          (etypecase piece
 177            (simple-string
 178             (write-string piece s))
 179            (symbol
 180             (ecase piece
 181               (:multi-char-wild
 182                (write-string "*" s))
 183               (:single-char-wild
 184                (write-string "?" s))))
 185            (cons
 186             (case (car piece)
 187               (:character-set
 188                (write-string "[" s)
 189                (write-string (cdr piece) s)
 190                (write-string "]" s))
 191               (t
 192                (error "invalid pattern piece: ~S" piece))))))))))
 193
 194 (defun make-matcher (piece)
 195   (cond ((eq piece :wild)
 196          (constantly t))
 197         ((typep piece 'pattern)
 198          (lambda (other)
 199            (when (stringp other)
 200              (pattern-matches piece other))))
 201         (t
 202          (lambda (other)
 203            (equal piece other)))))
 204
 205 (/show0 "filesys.lisp 160")
 206
 207 (defun extract-name-type-and-version (namestr start end)
 208   (declare (type simple-string namestr)
 209            (type index start end))
 210   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 211                              :from-end t)))
 212     (cond
 213       (last-dot
 214        (values (maybe-make-pattern namestr start last-dot)
 215                (maybe-make-pattern namestr (1+ last-dot) end)
 216                :newest))
 217       (t
 218        (values (maybe-make-pattern namestr start end)
 219                nil
 220                :newest)))))
 221
 222 (/show0 "filesys.lisp 200")
 223
 224 \f
 225 ;;;; Grabbing the kind of file when we have a namestring.
 226 (defun native-file-kind (namestring)
 227   (multiple-value-bind (existsp errno ino mode)
 228       #!-win32
 229       (sb!unix:unix-lstat namestring)
 230       #!+win32
 231       (sb!unix:unix-stat namestring)
 232     (declare (ignore errno ino))
 233     (when existsp
 234       (let ((ifmt (logand mode sb!unix:s-ifmt)))
 235        (case ifmt
 236          (#.sb!unix:s-ifreg :file)
 237          (#.sb!unix:s-ifdir :directory)
 238          #!-win32
 239          (#.sb!unix:s-iflnk :symlink)
 240          (t :special))))))
 241 \f
 242 ;;;; TRUENAME, PROBE-FILE, FILE-AUTHOR, FILE-WRITE-DATE.
 243
 244 ;;; Rewritten in 12/2007 by RMK, replacing 13+ year old CMU code that
 245 ;;; made a mess of things in order to support search lists (which SBCL
 246 ;;; has never had).  These are now all relatively straightforward
 247 ;;; wrappers around stat(2) and realpath(2), with the same basic logic
 248 ;;; in all cases.  The wrinkles to be aware of:
 249 ;;;
 250 ;;; * SBCL defines the truename of an existing, dangling or
 251 ;;;   self-referring symlink to be the symlink itself.
 252 ;;; * The old version of PROBE-FILE merged the pathspec against
 253 ;;;   *DEFAULT-PATHNAME-DEFAULTS* twice, and so lost when *D-P-D*
 254 ;;;   was a relative pathname.  Even if the case where *D-P-D* is a
 255 ;;;   relative pathname is problematic, there's no particular reason
 256 ;;;   to get that wrong, so let's try not to.
 257 ;;; * Note that while stat(2) is probably atomic, getting the truename
 258 ;;;   for a filename involves poking all over the place, and so is
 259 ;;;   subject to race conditions if other programs mutate the file
 260 ;;;   system while we're resolving symlinks.  So it's not implausible for
 261 ;;;   realpath(3) to fail even if stat(2) succeeded.  There's nothing
 262 ;;;   obvious we can do about this, however.
 263 ;;; * Windows' apparent analogue of realpath(3) is called
 264 ;;;   GetFullPathName, and it's a bit less useful than realpath(3).
 265 ;;;   In particular, while realpath(3) errors in case the file doesn't
 266 ;;;   exist, GetFullPathName seems to return a filename in all cases.
 267 ;;;   As realpath(3) is not atomic anyway, we only ever call it when
 268 ;;;   we think a file exists, so just be careful when rewriting this
 269 ;;;   routine.
 270 ;;;
 271 ;;; Given a pathname designator, some quality to query for, return one
 272 ;;; of a pathname, a universal time, or a string (a file-author), or
 273 ;;; NIL.  QUERY-FOR may be one of :TRUENAME, :EXISTENCE, :WRITE-DATE,
 274 ;;; :AUTHOR.  If ERRORP is false, return NIL in case the file system
 275 ;;; returns an error code; otherwise, signal an error.  Accepts
 276 ;;; logical pathnames, too (but never returns LPNs).  For internal
 277 ;;; use.
 278 (defun query-file-system (pathspec query-for &optional (errorp t))
 279   (let ((pathname (translate-logical-pathname
 280                    (merge-pathnames
 281                     (pathname pathspec)
 282                     (sane-default-pathname-defaults)))))
 283     (when (wild-pathname-p pathname)
 284       (error 'simple-file-error
 285              :pathname pathname
 286              :format-control "~@<can't find the ~A of wild pathname ~A~
 287                               (physicalized from ~A).~:>"
 288              :format-arguments (list query-for pathname pathspec)))
 289     (flet ((fail (note-format pathname errno)
 290              (if errorp
 291                  (simple-file-perror note-format pathname errno)
 292                  (return-from query-file-system nil))))
 293       (let ((filename (native-namestring pathname :as-file t)))
 294         (multiple-value-bind (existsp errno ino mode nlink uid gid rdev size
 295                                       atime mtime)
 296             (sb!unix:unix-stat filename)
 297           (declare (ignore ino nlink gid rdev size atime
 298                            #!+win32 uid))
 299           (if existsp
 300               (case query-for
 301                 (:existence (nth-value
 302                              0
 303                              (parse-native-namestring
 304                               filename
 305                               (pathname-host pathname)
 306                               (sane-default-pathname-defaults)
 307                               :as-directory (eql (logand mode sb!unix:s-ifmt)
 308                                                  sb!unix:s-ifdir))))
 309                 (:truename (nth-value
 310                             0
 311                             (parse-native-namestring
 312                              ;; Note: in case the file is stat'able, POSIX
 313                              ;; realpath(3) gets us a canonical absolute
 314                              ;; filename, even if the post-merge PATHNAME
 315                              ;; is not absolute...
 316                              (multiple-value-bind (realpath errno)
 317                                  (sb!unix:unix-realpath filename)
 318                                (if realpath
 319                                    realpath
 320                                    (fail "couldn't resolve ~A" filename errno)))
 321                              (pathname-host pathname)
 322                              (sane-default-pathname-defaults)
 323                              ;; ... but without any trailing slash.
 324                              :as-directory (eql (logand  mode sb!unix:s-ifmt)
 325                                                 sb!unix:s-ifdir))))
 326                 (:author
 327                  #!-win32
 328                  (sb!unix:uid-username uid))
 329                 (:write-date (+ unix-to-universal-time mtime)))
 330               (progn
 331                 ;; SBCL has for many years had a policy that a pathname
 332                 ;; that names an existing, dangling or self-referential
 333                 ;; symlink denotes the symlink itself.  stat(2) fails
 334                 ;; and sets errno to ENOENT or ELOOP respectively, but
 335                 ;; we must distinguish cases where the symlink exists
 336                 ;; from ones where there's a loop in the apparent
 337                 ;; containing directory.
 338                 #!-win32
 339                 (multiple-value-bind (linkp ignore ino mode nlink uid gid rdev
 340                                             size atime mtime)
 341                     (sb!unix:unix-lstat filename)
 342                   (declare (ignore ignore ino mode nlink gid rdev size atime))
 343                   (when (and (or (= errno sb!unix:enoent)
 344                                  (= errno sb!unix:eloop))
 345                              linkp)
 346                     (return-from query-file-system
 347                       (case query-for
 348                         (:existence
 349                          ;; We do this reparse so as to return a
 350                          ;; normalized pathname.
 351                          (parse-native-namestring
 352                           filename (pathname-host pathname)))
 353                         (:truename
 354                          ;; So here's a trick: since lstat succeded,
 355                          ;; FILENAME exists, so its directory exists and
 356                          ;; only the non-directory part is loopy.  So
 357                          ;; let's resolve FILENAME's directory part with
 358                          ;; realpath(3), in order to get a canonical
 359                          ;; absolute name for the directory, and then
 360                          ;; return a pathname having PATHNAME's name,
 361                          ;; type, and version, but the rest from the
 362                          ;; truename of the directory.  Since we turned
 363                          ;; PATHNAME into FILENAME "as a file", FILENAME
 364                          ;; does not end in a slash, and so we get the
 365                          ;; directory part of FILENAME by reparsing
 366                          ;; FILENAME and masking off its name, type, and
 367                          ;; version bits.  But note not to call ourselves
 368                          ;; recursively, because we don't want to
 369                          ;; re-merge against *DEFAULT-PATHNAME-DEFAULTS*,
 370                          ;; since PATHNAME may be a relative pathname.
 371                          (merge-pathnames
 372                           (nth-value
 373                            0
 374                            (parse-native-namestring
 375                             (multiple-value-bind (realpath errno)
 376                                 (sb!unix:unix-realpath
 377                                  (native-namestring
 378                                   (make-pathname
 379                                    :name :unspecific
 380                                    :type :unspecific
 381                                    :version :unspecific
 382                                    :defaults (parse-native-namestring
 383                                               filename
 384                                               (pathname-host pathname)
 385                                               (sane-default-pathname-defaults)))))
 386                               (if realpath
 387                                   realpath
 388                                   (fail "couldn't resolve ~A" filename errno)))
 389                             (pathname-host pathname)
 390                             (sane-default-pathname-defaults)
 391                             :as-directory t))
 392                           pathname))
 393                         (:author (sb!unix:uid-username uid))
 394                         (:write-date (+ unix-to-universal-time mtime))))))
 395                 ;; If we're still here, the file doesn't exist; error.
 396                 (fail
 397                  (format nil "failed to find the ~A of ~~A" query-for)
 398                  pathspec errno))))))))
 399
 400
 401 (defun probe-file (pathspec)
 402   #!+sb-doc
 403   "Return the truename of PATHSPEC if the truename can be found,
 404 or NIL otherwise.  See TRUENAME for more information."
 405   (query-file-system pathspec :truename nil))
 406
 407 (defun truename (pathspec)
 408   #!+sb-doc
 409   "If PATHSPEC is a pathname that names an existing file, return
 410 a pathname that denotes a canonicalized name for the file.  If
 411 pathspec is a stream associated with a file, return a pathname
 412 that denotes a canonicalized name for the file associated with
 413 the stream.
 414
 415 An error of type FILE-ERROR is signalled if no such file exists
 416 or if the file system is such that a canonicalized file name
 417 cannot be determined or if the pathname is wild.
 418
 419 Under Unix, the TRUENAME of a symlink that links to itself or to
 420 a file that doesn't exist is considered to be the name of the
 421 broken symlink itself."
 422   ;; Note that eventually this routine might be different for streams
 423   ;; than for other pathname designators.
 424   (if (streamp pathspec)
 425       (query-file-system pathspec :truename)
 426       (query-file-system pathspec :truename)))
 427
 428 (defun file-author (pathspec)
 429   #!+sb-doc
 430   "Return the author of the file specified by PATHSPEC. Signal an
 431 error of type FILE-ERROR if no such file exists, or if PATHSPEC
 432 is a wild pathname."
 433   (query-file-system pathspec :author))
 434
 435 (defun file-write-date (pathspec)
 436   #!+sb-doc
 437   "Return the write date of the file specified by PATHSPEC.
 438 An error of type FILE-ERROR is signaled if no such file exists,
 439 or if PATHSPEC is a wild pathname."
 440   (query-file-system pathspec :write-date))
 441 \f
 442 ;;;; miscellaneous other operations
 443
 444 (/show0 "filesys.lisp 700")
 445
 446 (defun rename-file (file new-name)
 447   #!+sb-doc
 448   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 449   file, then the associated file is renamed."
 450   (let* ((original (truename file))
 451          (original-namestring (native-namestring original :as-file t))
 452          (new-name (merge-pathnames new-name original))
 453          (new-namestring (native-namestring (physicalize-pathname new-name)
 454                                             :as-file t)))
 455     (unless new-namestring
 456       (error 'simple-file-error
 457              :pathname new-name
 458              :format-control "~S can't be created."
 459              :format-arguments (list new-name)))
 460     (multiple-value-bind (res error)
 461         (sb!unix:unix-rename original-namestring new-namestring)
 462       (unless res
 463         (error 'simple-file-error
 464                :pathname new-name
 465                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 466                                 ~I~_~A~:>"
 467                :format-arguments (list original new-name (strerror error))))
 468       (when (streamp file)
 469         (file-name file new-name))
 470       (values new-name original (truename new-name)))))
 471
 472 (defun delete-file (file)
 473   #!+sb-doc
 474   "Delete the specified FILE.
 475
 476 If FILE is a stream, on Windows the stream is closed immediately. On Unix
 477 plaforms the stream remains open, allowing IO to continue: the OS resources
 478 associated with the deleted file remain available till the stream is closed as
 479 per standard Unix unlink() behaviour."
 480   (let* ((pathname (translate-logical-pathname file))
 481          (namestring (native-namestring pathname :as-file t)))
 482     (truename file) ; for error-checking side-effect
 483     #!+win32
 484     (when (streamp file)
 485       (close file))
 486     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 487       (unless res
 488         (simple-file-perror "couldn't delete ~A" namestring err))))
 489   t)
 490
 491 (defun delete-directory (pathspec &key recursive)
 492   "Deletes the directory designated by PATHSPEC (a pathname designator).
 493 Returns the truename of the directory deleted.
 494
 495 If RECURSIVE is false \(the default), signals an error unless the directory is
 496 empty. If RECURSIVE is true, first deletes all files and subdirectories. If
 497 RECURSIVE is true and the directory contains symbolic links, the links are
 498 deleted, not the files and directories they point to.
 499
 500 Signals an error if PATHSPEC designates a file instead of a directory, or if
 501 the directory could not be deleted for any reason.
 502
 503 \(DELETE-DIRECTORY \"/tmp/foo\") and \(DELETE-DIRECTORY \"/tmp/foo/\") both
 504 delete the \"foo\" subdirectory of \"/tmp\", or signal an error if it does not
 505 exist or is a file.
 506
 507 Experimental: interface subject to change."
 508   (declare (type pathname-designator pathspec))
 509   (with-pathname (pathname pathspec)
 510     (let ((truename (truename (translate-logical-pathname pathname))))
 511       (labels ((recurse (dir)
 512                  (map-directory #'recurse dir
 513                                 :files nil
 514                                 :directories t
 515                                 :classify-symlinks nil)
 516                  (map-directory #'delete-file dir
 517                                 :files t
 518                                 :directories nil
 519                                 :classify-symlinks nil)
 520                  (delete-dir dir))
 521                (delete-dir (dir)
 522                  (let* ((namestring (native-namestring dir :as-file t))
 523                         (res (alien-funcall (extern-alien #!-win32 "rmdir"
 524                                                           #!+win32 "_rmdir"
 525                                                           (function int c-string))
 526                                             namestring)))
 527                    (if (minusp res)
 528                        (simple-file-perror "Could not delete directory ~A:~%  ~A"
 529                                            namestring (get-errno))
 530                        dir))))
 531         (if recursive
 532             (recurse truename)
 533             (delete-dir truename))))))
 534 \f
 535 (defun sbcl-homedir-pathname ()
 536   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 537     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 538     (when (and sbcl-home (not (string= sbcl-home "")))
 539       (parse-native-namestring sbcl-home
 540                                #!-win32 sb!impl::*unix-host*
 541                                #!+win32 sb!impl::*win32-host*
 542                                *default-pathname-defaults*
 543                                :as-directory t))))
 544
 545 (defun user-homedir-namestring (&optional username)
 546   (if username
 547       (sb!unix:user-homedir username)
 548       (let ((env-home (posix-getenv "HOME")))
 549         (if (and env-home (not (string= env-home "")))
 550             env-home
 551             #!-win32
 552             (sb!unix:uid-homedir (sb!unix:unix-getuid))))))
 553
 554 ;;; (This is an ANSI Common Lisp function.)
 555 (defun user-homedir-pathname (&optional host)
 556   #!+sb-doc
 557   "Return the home directory of the user as a pathname. If the HOME
 558 environment variable has been specified, the directory it designates
 559 is returned; otherwise obtains the home directory from the operating
 560 system. HOST argument is ignored by SBCL."
 561   (declare (ignore host))
 562   (values
 563    (parse-native-namestring
 564     (or (user-homedir-namestring)
 565         #!+win32
 566         (sb!win32::get-folder-namestring sb!win32::csidl_profile))
 567     #!-win32 sb!impl::*unix-host*
 568     #!+win32 sb!impl::*win32-host*
 569     *default-pathname-defaults*
 570     :as-directory t)))
 571
 572 \f
 573 ;;;; DIRECTORY
 574
 575 (defun directory (pathspec &key (resolve-symlinks t))
 576   #!+sb-doc
 577   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 578 given pathname. Note that the interaction between this ANSI-specified
 579 TRUENAMEing and the semantics of the Unix filesystem (symbolic links..) means
 580 this function can sometimes return files which don't have the same directory
 581 as PATHNAME. If :RESOLVE-SYMLINKS is NIL, don't resolve symbolic links in
 582 matching filenames."
 583   (let (;; We create one entry in this hash table for each truename,
 584         ;; as an asymptotically efficient way of removing duplicates
 585         ;; (which can arise when e.g. multiple symlinks map to the
 586         ;; same truename).
 587         (truenames (make-hash-table :test #'equal)))
 588     (labels ((record (pathname)
 589                (let ((truename (if resolve-symlinks
 590                                    ;; FIXME: Why not not TRUENAME?  As reported by
 591                                    ;; Milan Zamazal sbcl-devel 2003-10-05, using
 592                                    ;; TRUENAME causes a race condition whereby
 593                                    ;; removal of a file during the directory
 594                                    ;; operation causes an error.  It's not clear
 595                                    ;; what the right thing to do is, though.  --
 596                                    ;; CSR, 2003-10-13
 597                                    (query-file-system pathname :truename nil)
 598                                    (query-file-system pathname :existence nil))))
 599                  (when truename
 600                    (setf (gethash (namestring truename) truenames)
 601                          truename))))
 602              (do-physical-pathnames (pathname)
 603                (aver (not (logical-pathname-p pathname)))
 604                (let* (;; KLUDGE: Since we don't canonize pathnames on construction,
 605                       ;; we really have to do it here to get #p"foo/." mean the same
 606                       ;; as #p"foo/./".
 607                       (pathname (canonicalize-pathname pathname))
 608                       (name (pathname-name pathname))
 609                       (type (pathname-type pathname))
 610                       (match-name (make-matcher name))
 611                       (match-type (make-matcher type)))
 612                  (map-matching-directories
 613                   (if (or name type)
 614                       (lambda (directory)
 615                         (map-matching-entries #'record
 616                                               directory
 617                                               match-name
 618                                               match-type))
 619                       #'record)
 620                   pathname)))
 621              (do-pathnames (pathname)
 622                (if (logical-pathname-p pathname)
 623                    (let ((host (intern-logical-host (pathname-host pathname))))
 624                      (dolist (x (logical-host-canon-transls host))
 625                        (destructuring-bind (from to) x
 626                          (let ((intersections
 627                                 (pathname-intersections pathname from)))
 628                            (dolist (p intersections)
 629                              (do-pathnames (translate-pathname p from to)))))))
 630                    (do-physical-pathnames pathname))))
 631       (declare (truly-dynamic-extent #'record))
 632       (do-pathnames (merge-pathnames pathspec)))
 633     (mapcar #'cdr
 634             ;; Sorting isn't required by the ANSI spec, but sorting into some
 635             ;; canonical order seems good just on the grounds that the
 636             ;; implementation should have repeatable behavior when possible.
 637             (sort (loop for namestring being each hash-key in truenames
 638                         using (hash-value truename)
 639                         collect (cons namestring truename))
 640                   #'string<
 641                   :key #'car))))
 642
 643 (defun canonicalize-pathname (pathname)
 644   ;; We're really only interested in :UNSPECIFIC -> NIL, :BACK and :UP,
 645   ;; and dealing with #p"foo/.." and #p"foo/."
 646   (labels ((simplify (piece)
 647              (unless (eq :unspecific piece)
 648                piece))
 649            (canonicalize-directory (directory)
 650              (let (pieces)
 651                (dolist (piece directory)
 652                  (if (and pieces (member piece '(:back :up)))
 653                      ;; FIXME: We should really canonicalize when we construct
 654                      ;; pathnames. This is just wrong.
 655                      (case (car pieces)
 656                        ((:absolute :wild-inferiors)
 657                         (error 'simple-file-error
 658                                :format-control "Invalid use of ~S after ~S."
 659                                :format-arguments (list piece (car pieces))
 660                                :pathname pathname))
 661                        ((:relative :up :back)
 662                         (push piece pieces))
 663                        (t
 664                         (pop pieces)))
 665                      (push piece pieces)))
 666                (nreverse pieces))))
 667     (let ((name (simplify (pathname-name pathname)))
 668           (type (simplify (pathname-type pathname)))
 669           (dir (canonicalize-directory (pathname-directory pathname))))
 670       (cond ((equal "." name)
 671              (cond ((not type)
 672                     (make-pathname :name nil :defaults pathname))
 673                    ((equal "" type)
 674                     (make-pathname :name nil
 675                                    :type nil
 676                                    :directory (butlast dir)
 677                                    :defaults pathname))))
 678             (t
 679              (make-pathname :name name :type type
 680                             :directory dir
 681                             :defaults pathname))))))
 682
 683 ;;; Given a native namestring, provides a WITH-HASH-TABLE-ITERATOR style
 684 ;;; interface to mapping over namestrings of entries in the corresponding
 685 ;;; directory.
 686 (defmacro with-native-directory-iterator ((iterator namestring &key errorp) &body body)
 687   (with-unique-names (one-iter)
 688     `(dx-flet
 689          ((iterate (,one-iter)
 690             (declare (type function ,one-iter))
 691             (macrolet ((,iterator ()
 692                          `(funcall ,',one-iter)))
 693               ,@body)))
 694        (call-with-native-directory-iterator #'iterate ,namestring ,errorp))))
 695
 696 (defun call-with-native-directory-iterator (function namestring errorp)
 697   (declare (type (or null string) namestring)
 698            (function function))
 699   (let (dp)
 700     (when namestring
 701       (dx-flet
 702           ((one-iter ()
 703              (tagbody
 704               :next
 705                 (let ((ent (sb!unix:unix-readdir dp nil)))
 706                   (when ent
 707                     (let ((name (sb!unix:unix-dirent-name ent)))
 708                       (when name
 709                         (cond ((equal "." name)
 710                                (go :next))
 711                               ((equal ".." name)
 712                                (go :next))
 713                               (t
 714                                (return-from one-iter name))))))))))
 715         (unwind-protect
 716              (progn
 717                (setf dp (sb!unix:unix-opendir namestring errorp))
 718                (when dp
 719                  (funcall function #'one-iter)))
 720           (when dp
 721             (sb!unix:unix-closedir dp nil)))))))
 722
 723 ;;; This is our core directory access interface that we use to implement
 724 ;;; DIRECTORY.
 725 (defun map-directory (function directory &key (files t) (directories t)
 726                       (classify-symlinks) (errorp t))
 727   #!+sb-doc
 728   "Map over entries in DIRECTORY. Keyword arguments specify which entries to
 729 map over, and how:
 730
 731  :FILES
 732     If true, call FUNCTION with the pathname of each file in DIRECTORY.
 733     Defaults to T.
 734
 735  :DIRECTORIES
 736    If true, call FUNCTION with a pathname for each subdirectory of DIRECTORY.
 737    If :AS-FILES, the pathname used is a pathname designating the subdirectory
 738    as a file in DIRECTORY. Otherwise the pathname used is a directory
 739    pathname. Defaults to T.
 740
 741  :CLASSIFY-SYMLINKS
 742    If T, the decision to call FUNCTION with the pathname of a symbolic link
 743    depends on the resolution of the link: if it points to a directory, it is
 744    considered a directory entry, otherwise a file entry. If false, all
 745    symbolic links are considered file entries. Defaults to T. In both cases
 746    the pathname used for the symbolic link is not fully resolved, but names it
 747    as an immediate child of DIRECTORY.
 748
 749  :ERRORP
 750    If true, signal an error if DIRECTORY does not exist, cannot be read, etc.
 751    Defaults to T.
 752
 753 Experimental: interface subject to change."
 754   (declare (pathname-designator directory))
 755   (let* ((fun (%coerce-callable-to-fun function))
 756          (as-files (eq :as-files directories))
 757          (physical (physicalize-pathname directory))
 758          ;; Not QUERY-FILE-SYSTEM :EXISTENCE, since it doesn't work on Windows
 759          ;; network shares.
 760          (realname (sb!unix:unix-realpath (native-namestring physical :as-file t)))
 761          (canonical (if realname
 762                         (parse-native-namestring realname
 763                                                  (pathname-host physical)
 764                                                  (sane-default-pathname-defaults)
 765                                                  :as-directory t)
 766                         (return-from map-directory nil)))
 767          (dirname (native-namestring canonical)))
 768     (flet ((map-it (name dirp)
 769              (funcall fun
 770                       (merge-pathnames (parse-native-namestring
 771                                         name nil physical
 772                                         :as-directory (and dirp (not as-files)))
 773                                        physical))))
 774       (with-native-directory-iterator (next dirname :errorp errorp)
 775        (loop for name = (next)
 776              while name
 777              do (let* ((full (concatenate 'string dirname name))
 778                        (kind (native-file-kind full)))
 779                   (when kind
 780                     (case kind
 781                       (:directory
 782                        (when directories
 783                          (map-it name t)))
 784                       (:symlink
 785                        (if classify-symlinks
 786                            (let* ((tmpname (merge-pathnames
 787                                             (parse-native-namestring
 788                                              name nil physical :as-directory nil)
 789                                             physical))
 790                                   (truename (query-file-system tmpname :truename nil)))
 791                              (if (or (not truename)
 792                                      (or (pathname-name truename) (pathname-type truename)))
 793                                  (when files
 794                                    (funcall fun tmpname))
 795                                  (when directories
 796                                    (map-it name t))))
 797                            (when files
 798                              (map-it name nil))))
 799                       (t
 800                        ;; Anything else parses as a file.
 801                        (when files
 802                          (map-it name nil)))))))))))
 803
 804 ;;; Part of DIRECTORY: implements matching the directory spec. Calls FUNCTION
 805 ;;; with all DIRECTORIES that match the directory portion of PATHSPEC.
 806 (defun map-matching-directories (function pathspec)
 807   (let* ((dir (pathname-directory pathspec))
 808          (length (length dir))
 809          (wild (position-if (lambda (elt)
 810                               (or (eq :wild elt) (typep elt 'pattern)))
 811                             dir))
 812          (wild-inferiors (position :wild-inferiors dir))
 813          (end (cond ((and wild wild-inferiors)
 814                      (min wild wild-inferiors))
 815                     (t
 816                      (or wild wild-inferiors length))))
 817          (rest (subseq dir end))
 818          (starting-point (make-pathname :directory (subseq dir 0 end)
 819                                         :device (pathname-device pathspec)
 820                                         :host (pathname-host pathspec)
 821                                         :name nil
 822                                         :type nil
 823                                         :version nil)))
 824     (cond (wild-inferiors
 825            (map-wild-inferiors function rest starting-point))
 826           (wild
 827            (map-wild function rest starting-point))
 828           (t
 829            ;; Nothing wild -- the directory matches itself.
 830            (funcall function starting-point))))
 831   nil)
 832
 833 (defun last-directory-piece (pathname)
 834   (car (last (pathname-directory pathname))))
 835
 836 ;;; Part of DIRECTORY: implements iterating over a :WILD or pattern component
 837 ;;; in the directory spec.
 838 (defun map-wild (function more directory)
 839   (let ((this (pop more))
 840         (next (car more)))
 841     (flet ((cont (subdirectory)
 842              (cond ((not more)
 843                     ;; end of the line
 844                     (funcall function subdirectory))
 845                    ((or (eq :wild next) (typep next 'pattern))
 846                     (map-wild function more subdirectory))
 847                    ((eq :wild-inferiors next)
 848                     (map-wild-inferiors function more subdirectory))
 849                    (t
 850                     (let ((this (pathname-directory subdirectory)))
 851                       (map-matching-directories
 852                        function
 853                        (make-pathname :directory (append this more)
 854                                       :defaults subdirectory)))))))
 855       (map-directory
 856        (if (eq :wild this)
 857            #'cont
 858            (lambda (sub)
 859              (when (pattern-matches this (last-directory-piece sub))
 860                (funcall #'cont sub))))
 861        directory
 862        :files nil
 863        :directories t
 864        :errorp nil))))
 865
 866 ;;; Part of DIRECTORY: implements iterating over a :WILD-INFERIORS component
 867 ;;; in the directory spec.
 868 (defun map-wild-inferiors (function more directory)
 869   (loop while (member (car more) '(:wild :wild-inferiors))
 870         do (pop more))
 871   (let ((next (car more))
 872         (rest (cdr more)))
 873     (unless more
 874       (funcall function directory))
 875     (map-directory
 876      (cond ((not more)
 877             (lambda (pathname)
 878               (funcall function pathname)
 879               (map-wild-inferiors function more pathname)))
 880            (t
 881             (lambda (pathname)
 882               (let ((this (pathname-directory pathname)))
 883                 (when (equal next (car (last this)))
 884                   (map-matching-directories
 885                    function
 886                    (make-pathname :directory (append this rest)
 887                                   :defaults pathname)))
 888                 (map-wild-inferiors function more pathname)))))
 889      directory
 890      :files nil
 891      :directories t
 892      :errorp nil)))
 893
 894 ;;; Part of DIRECTORY: implements iterating over entries in a directory, and
 895 ;;; matching them.
 896 (defun map-matching-entries (function directory match-name match-type)
 897   (map-directory
 898    (lambda (file)
 899      (when (and (funcall match-name (pathname-name file))
 900                 (funcall match-type (pathname-type file)))
 901        (funcall function file)))
 902    directory
 903    :files t
 904    :directories :as-files
 905    :errorp nil))
 906
 907 ;;; NOTE: There is a fair amount of hair below that is probably not
 908 ;;; strictly necessary.
 909 ;;;
 910 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 911 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 912 ;;; did not translate the logical pathname at all, but instead treated
 913 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 914 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 915 ;;; which is fine as far as it goes, but not very interesting, and
 916 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 917 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 918 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 919 ;;; exists, of course).
 920 ;;;
 921 ;;; So, the interpretation that I am pushing is for all pathnames
 922 ;;; matching the input pathname to be queried.  This means that we
 923 ;;; need to compute the intersection of the input pathname and the
 924 ;;; logical host FROM translations, and then translate the resulting
 925 ;;; pathname using the host to the TO translation; this treatment is
 926 ;;; recursively invoked until we get a physical pathname, whereupon
 927 ;;; our physical DIRECTORY implementation takes over.
 928
 929 ;;; FIXME: this is an incomplete implementation.  It only works when
 930 ;;; both are logical pathnames (which is OK, because that's the only
 931 ;;; case when we call it), but there are other pitfalls as well: see
 932 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 933 ;;; pattern handling.
 934
 935 ;;; The above was written by CSR, I (RMK) believe.  The argument that
 936 ;;; motivates the interpretation is faulty, however: PATHNAME-MATCH-P
 937 ;;; returns true for (PATHNAME-MATCH-P #P"/tmp/*/" #P"/tmp/../"), but
 938 ;;; the latter pathname is not in the result of DIRECTORY on the
 939 ;;; former.  Indeed, if DIRECTORY were constrained to return the
 940 ;;; truename for every pathname for which PATHNAME-MATCH-P returned
 941 ;;; true and which denoted a filename that named an existing file,
 942 ;;; (DIRECTORY #P"/tmp/**/") would be required to list every file on a
 943 ;;; Unix system, since any file can be named as though it were "below"
 944 ;;; /tmp, given the dotdot entries.  So I think the strongest
 945 ;;; "consistency" we can define between PATHNAME-MATCH-P and DIRECTORY
 946 ;;; is that PATHNAME-MATCH-P returns true of everything DIRECTORY
 947 ;;; returns, but not vice versa.
 948
 949 ;;; In any case, even if the motivation were sound, DIRECTORY on a
 950 ;;; wild logical pathname has no portable semantics.  I see nothing in
 951 ;;; ANSI that requires implementations to support wild physical
 952 ;;; pathnames, and so there need not be any translation of a wild
 953 ;;; logical pathname to a phyiscal pathname.  So a program that calls
 954 ;;; DIRECTORY on a wild logical pathname is doing something
 955 ;;; non-portable at best.  And if the only sensible semantics for
 956 ;;; DIRECTORY on a wild logical pathname is something like the
 957 ;;; following, it would be just as well if it signaled an error, since
 958 ;;; a program can't possibly rely on the result of an intersection of
 959 ;;; user-defined translations with a file system probe.  (Potentially
 960 ;;; useful kinds of "pathname" that might not support wildcards could
 961 ;;; include pathname hosts that model unqueryable namespaces like HTTP
 962 ;;; URIs, or that model namespaces that it's not convenient to
 963 ;;; investigate, such as the namespace of TCP ports that some network
 964 ;;; host listens on.  I happen to think it a bad idea to try to
 965 ;;; shoehorn such namespaces into a pathnames system, but people
 966 ;;; sometimes claim to want pathnames for these things.)  -- RMK
 967 ;;; 2007-12-31.
 968
 969 (defun pathname-intersections (one two)
 970   (aver (logical-pathname-p one))
 971   (aver (logical-pathname-p two))
 972   (labels
 973       ((intersect-version (one two)
 974          (aver (typep one '(or null (member :newest :wild :unspecific)
 975                             integer)))
 976          (aver (typep two '(or null (member :newest :wild :unspecific)
 977                             integer)))
 978          (cond
 979            ((eq one :wild) two)
 980            ((eq two :wild) one)
 981            ((or (null one) (eq one :unspecific)) two)
 982            ((or (null two) (eq two :unspecific)) one)
 983            ((eql one two) one)
 984            (t nil)))
 985        (intersect-name/type (one two)
 986          (aver (typep one '(or null (member :wild :unspecific) string)))
 987          (aver (typep two '(or null (member :wild :unspecific) string)))
 988          (cond
 989            ((eq one :wild) two)
 990            ((eq two :wild) one)
 991            ((or (null one) (eq one :unspecific)) two)
 992            ((or (null two) (eq two :unspecific)) one)
 993            ((string= one two) one)
 994            (t nil)))
 995        (intersect-directory (one two)
 996          (aver (typep one '(or null (member :wild :unspecific) list)))
 997          (aver (typep two '(or null (member :wild :unspecific) list)))
 998          (cond
 999            ((eq one :wild) two)
1000            ((eq two :wild) one)
1001            ((or (null one) (eq one :unspecific)) two)
1002            ((or (null two) (eq two :unspecific)) one)
1003            (t (aver (eq (car one) (car two)))
1004               (mapcar
1005                (lambda (x) (cons (car one) x))
1006                (intersect-directory-helper (cdr one) (cdr two)))))))
1007     (let ((version (intersect-version
1008                     (pathname-version one) (pathname-version two)))
1009           (name (intersect-name/type
1010                  (pathname-name one) (pathname-name two)))
1011           (type (intersect-name/type
1012                  (pathname-type one) (pathname-type two)))
1013           (host (pathname-host one)))
1014       (mapcar (lambda (d)
1015                 (make-pathname :host host :name name :type type
1016                                :version version :directory d))
1017               (intersect-directory
1018                (pathname-directory one) (pathname-directory two))))))
1019
1020 ;;; FIXME: written as its own function because I (CSR) don't
1021 ;;; understand it, so helping both debuggability and modularity.  In
1022 ;;; case anyone is motivated to rewrite it, it returns a list of
1023 ;;; sublists representing the intersection of the two input directory
1024 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
1025 ;;;
1026 ;;; FIXME: Does not work with :UP or :BACK
1027 ;;; FIXME: Does not work with patterns
1028 ;;;
1029 ;;; FIXME: PFD suggests replacing this implementation with a DFA
1030 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
1031 ;;; turns out to be worth it.
1032 (defun intersect-directory-helper (one two)
1033   (flet ((simple-intersection (cone ctwo)
1034            (cond
1035              ((eq cone :wild) ctwo)
1036              ((eq ctwo :wild) cone)
1037              (t (aver (typep cone 'string))
1038                 (aver (typep ctwo 'string))
1039                 (if (string= cone ctwo) cone nil)))))
1040     (macrolet
1041         ((loop-possible-wild-inferiors-matches
1042              (lower-bound bounding-sequence order)
1043            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
1044              `(let ((,l (length ,bounding-sequence)))
1045                (loop for ,index from ,lower-bound to ,l
1046                 append (mapcar (lambda (,g2)
1047                                  (append
1048                                   (butlast ,bounding-sequence (- ,l ,index))
1049                                   ,g2))
1050                         (mapcar
1051                          (lambda (,g3)
1052                            (append
1053                             (if (eq (car (nthcdr ,index ,bounding-sequence))
1054                                     :wild-inferiors)
1055                                 '(:wild-inferiors)
1056                                 nil) ,g3))
1057                          (intersect-directory-helper
1058                           ,@(if order
1059                                 `((nthcdr ,index one) (cdr two))
1060                                 `((cdr one) (nthcdr ,index two)))))))))))
1061       (cond
1062         ((and (eq (car one) :wild-inferiors)
1063               (eq (car two) :wild-inferiors))
1064          (delete-duplicates
1065           (append (mapcar (lambda (x) (cons :wild-inferiors x))
1066                           (intersect-directory-helper (cdr one) (cdr two)))
1067                   (loop-possible-wild-inferiors-matches 2 one t)
1068                   (loop-possible-wild-inferiors-matches 2 two nil))
1069           :test 'equal))
1070         ((eq (car one) :wild-inferiors)
1071          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
1072                             :test 'equal))
1073         ((eq (car two) :wild-inferiors)
1074          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
1075                             :test 'equal))
1076         ((and (null one) (null two)) (list nil))
1077         ((null one) nil)
1078         ((null two) nil)
1079         (t (and (simple-intersection (car one) (car two))
1080                 (mapcar (lambda (x) (cons (simple-intersection
1081                                            (car one) (car two)) x))
1082                         (intersect-directory-helper (cdr one) (cdr two)))))))))
1083 \f
1084 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
1085   #!+sb-doc
1086   "Test whether the directories containing the specified file
1087   actually exist, and attempt to create them if they do not.
1088   The MODE argument is a CMUCL/SBCL-specific extension to control
1089   the Unix permission bits."
1090   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
1091         (created-p nil))
1092     (when (wild-pathname-p pathname)
1093       (error 'simple-file-error
1094              :format-control "bad place for a wild pathname"
1095              :pathname pathspec))
1096     (let ((dir (pathname-directory pathname)))
1097       (loop for i from 1 upto (length dir)
1098             do (let ((newpath (make-pathname
1099                                :host (pathname-host pathname)
1100                                :device (pathname-device pathname)
1101                                :directory (subseq dir 0 i))))
1102                  (unless (probe-file newpath)
1103                    (let ((namestring (coerce (native-namestring newpath)
1104                                              'string)))
1105                      (when verbose
1106                        (format *standard-output*
1107                                "~&creating directory: ~A~%"
1108                                namestring))
1109                      (sb!unix:unix-mkdir namestring mode)
1110                      (unless (probe-file newpath)
1111                        (restart-case (error
1112                                       'simple-file-error
1113                                       :pathname pathspec
1114                                       :format-control
1115                                       "can't create directory ~A"
1116                                       :format-arguments (list namestring))
1117                          (retry ()
1118                            :report "Retry directory creation."
1119                            (ensure-directories-exist
1120                             pathspec
1121                             :verbose verbose :mode mode))
1122                          (continue ()
1123                            :report
1124                            "Continue as if directory creation was successful."
1125                            nil)))
1126                      (setf created-p t)))))
1127       (values pathspec created-p))))
1128
1129 (/show0 "filesys.lisp 1000")