src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defun maybe-make-pattern (namestr start end)
  84   (declare (type simple-string namestr)
  85            (type index start end))
  86   (collect ((pattern))
  87     (let ((quoted nil)
  88           (any-quotes nil)
  89           (last-regular-char nil)
  90           (index start))
  91       (flet ((flush-pending-regulars ()
  92                (when last-regular-char
  93                  (pattern (if any-quotes
  94                               (remove-backslashes namestr
  95                                                   last-regular-char
  96                                                   index)
  97                               (subseq namestr last-regular-char index)))
  98                  (setf any-quotes nil)
  99                  (setf last-regular-char nil))))
 100         (loop
 101           (when (>= index end)
 102             (return))
 103           (let ((char (schar namestr index)))
 104             (cond (quoted
 105                    (incf index)
 106                    (setf quoted nil))
 107                   ((char= char #\\)
 108                    (setf quoted t)
 109                    (setf any-quotes t)
 110                    (unless last-regular-char
 111                      (setf last-regular-char index))
 112                    (incf index))
 113                   ((char= char #\?)
 114                    (flush-pending-regulars)
 115                    (pattern :single-char-wild)
 116                    (incf index))
 117                   ((char= char #\*)
 118                    (flush-pending-regulars)
 119                    (pattern :multi-char-wild)
 120                    (incf index))
 121                   ((char= char #\[)
 122                    (flush-pending-regulars)
 123                    (let ((close-bracket
 124                           (position #\] namestr :start index :end end)))
 125                      (unless close-bracket
 126                        (error 'namestring-parse-error
 127                               :complaint "#\\[ with no corresponding #\\]"
 128                               :namestring namestr
 129                               :offset index))
 130                      (pattern (cons :character-set
 131                                     (subseq namestr
 132                                             (1+ index)
 133                                             close-bracket)))
 134                      (setf index (1+ close-bracket))))
 135                   (t
 136                    (unless last-regular-char
 137                      (setf last-regular-char index))
 138                    (incf index)))))
 139         (flush-pending-regulars)))
 140     (cond ((null (pattern))
 141            "")
 142           ((null (cdr (pattern)))
 143            (let ((piece (first (pattern))))
 144              (typecase piece
 145                ((member :multi-char-wild) :wild)
 146                (simple-string piece)
 147                (t
 148                 (make-pattern (pattern))))))
 149           (t
 150            (make-pattern (pattern))))))
 151
 152 (defun unparse-physical-piece (thing)
 153   (etypecase thing
 154     ((member :wild) "*")
 155     (simple-string
 156      (let* ((srclen (length thing))
 157             (dstlen srclen))
 158        (dotimes (i srclen)
 159          (case (schar thing i)
 160            ((#\* #\? #\[)
 161             (incf dstlen))))
 162        (let ((result (make-string dstlen))
 163              (dst 0))
 164          (dotimes (src srclen)
 165            (let ((char (schar thing src)))
 166              (case char
 167                ((#\* #\? #\[)
 168                 (setf (schar result dst) #\\)
 169                 (incf dst)))
 170              (setf (schar result dst) char)
 171              (incf dst)))
 172          result)))
 173     (pattern
 174      (with-output-to-string (s)
 175        (dolist (piece (pattern-pieces thing))
 176          (etypecase piece
 177            (simple-string
 178             (write-string piece s))
 179            (symbol
 180             (ecase piece
 181               (:multi-char-wild
 182                (write-string "*" s))
 183               (:single-char-wild
 184                (write-string "?" s))))
 185            (cons
 186             (case (car piece)
 187               (:character-set
 188                (write-string "[" s)
 189                (write-string (cdr piece) s)
 190                (write-string "]" s))
 191               (t
 192                (error "invalid pattern piece: ~S" piece))))))))))
 193
 194 (defun make-matcher (piece)
 195   (cond ((eq piece :wild)
 196          (constantly t))
 197         ((typep piece 'pattern)
 198          (lambda (other)
 199            (when (stringp other)
 200              (pattern-matches piece other))))
 201         (t
 202          (lambda (other)
 203            (equal piece other)))))
 204
 205 (/show0 "filesys.lisp 160")
 206
 207 (defun extract-name-type-and-version (namestr start end)
 208   (declare (type simple-string namestr)
 209            (type index start end))
 210   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 211                              :from-end t)))
 212     (cond
 213       (last-dot
 214        (values (maybe-make-pattern namestr start last-dot)
 215                (maybe-make-pattern namestr (1+ last-dot) end)
 216                :newest))
 217       (t
 218        (values (maybe-make-pattern namestr start end)
 219                nil
 220                :newest)))))
 221
 222 (/show0 "filesys.lisp 200")
 223
 224 \f
 225 ;;;; Grabbing the kind of file when we have a namestring.
 226 (defun native-file-kind (namestring)
 227   (multiple-value-bind (existsp errno ino mode)
 228       #!-win32
 229       (sb!unix:unix-lstat namestring)
 230       #!+win32
 231       (sb!unix:unix-stat namestring)
 232     (declare (ignore errno ino))
 233     (when existsp
 234       (let ((ifmt (logand mode sb!unix:s-ifmt)))
 235        (case ifmt
 236          (#.sb!unix:s-ifreg :file)
 237          (#.sb!unix:s-ifdir :directory)
 238          #!-win32
 239          (#.sb!unix:s-iflnk :symlink)
 240          (t :special))))))
 241 \f
 242 ;;;; TRUENAME, PROBE-FILE, FILE-AUTHOR, FILE-WRITE-DATE.
 243
 244 ;;; Rewritten in 12/2007 by RMK, replacing 13+ year old CMU code that
 245 ;;; made a mess of things in order to support search lists (which SBCL
 246 ;;; has never had).  These are now all relatively straightforward
 247 ;;; wrappers around stat(2) and realpath(2), with the same basic logic
 248 ;;; in all cases.  The wrinkles to be aware of:
 249 ;;;
 250 ;;; * SBCL defines the truename of an existing, dangling or
 251 ;;;   self-referring symlink to be the symlink itself.
 252 ;;; * The old version of PROBE-FILE merged the pathspec against
 253 ;;;   *DEFAULT-PATHNAME-DEFAULTS* twice, and so lost when *D-P-D*
 254 ;;;   was a relative pathname.  Even if the case where *D-P-D* is a
 255 ;;;   relative pathname is problematic, there's no particular reason
 256 ;;;   to get that wrong, so let's try not to.
 257 ;;; * Note that while stat(2) is probably atomic, getting the truename
 258 ;;;   for a filename involves poking all over the place, and so is
 259 ;;;   subject to race conditions if other programs mutate the file
 260 ;;;   system while we're resolving symlinks.  So it's not implausible for
 261 ;;;   realpath(3) to fail even if stat(2) succeeded.  There's nothing
 262 ;;;   obvious we can do about this, however.
 263 ;;; * Windows' apparent analogue of realpath(3) is called
 264 ;;;   GetFullPathName, and it's a bit less useful than realpath(3).
 265 ;;;   In particular, while realpath(3) errors in case the file doesn't
 266 ;;;   exist, GetFullPathName seems to return a filename in all cases.
 267 ;;;   As realpath(3) is not atomic anyway, we only ever call it when
 268 ;;;   we think a file exists, so just be careful when rewriting this
 269 ;;;   routine.
 270 ;;;
 271 ;;; Given a pathname designator, some quality to query for, return one
 272 ;;; of a pathname, a universal time, or a string (a file-author), or
 273 ;;; NIL.  QUERY-FOR may be one of :TRUENAME, :EXISTENCE, :WRITE-DATE,
 274 ;;; :AUTHOR.  If ERRORP is false, return NIL in case the file system
 275 ;;; returns an error code; otherwise, signal an error.  Accepts
 276 ;;; logical pathnames, too (but never returns LPNs).  For internal
 277 ;;; use.
 278 (defun query-file-system (pathspec query-for &optional (errorp t))
 279   (let ((pathname (translate-logical-pathname
 280                    (merge-pathnames
 281                     (pathname pathspec)
 282                     (sane-default-pathname-defaults)))))
 283     (when (wild-pathname-p pathname)
 284       (error 'simple-file-error
 285              :pathname pathname
 286              :format-control "~@<can't find the ~A of wild pathname ~A~
 287                               (physicalized from ~A).~:>"
 288              :format-arguments (list query-for pathname pathspec)))
 289     (flet ((fail (note-format pathname errno)
 290              (if errorp
 291                  (simple-file-perror note-format pathname errno)
 292                  (return-from query-file-system nil))))
 293       (let ((filename (native-namestring pathname :as-file t)))
 294         (multiple-value-bind (existsp errno ino mode nlink uid gid rdev size
 295                                       atime mtime)
 296             (sb!unix:unix-stat filename)
 297           (declare (ignore ino nlink gid rdev size atime
 298                            #!+win32 uid))
 299           (if existsp
 300               (case query-for
 301                 (:existence (nth-value
 302                              0
 303                              (parse-native-namestring
 304                               filename
 305                               (pathname-host pathname)
 306                               (sane-default-pathname-defaults)
 307                               :as-directory (eql (logand mode sb!unix:s-ifmt)
 308                                                  sb!unix:s-ifdir))))
 309                 (:truename (nth-value
 310                             0
 311                             (parse-native-namestring
 312                              ;; Note: in case the file is stat'able, POSIX
 313                              ;; realpath(3) gets us a canonical absolute
 314                              ;; filename, even if the post-merge PATHNAME
 315                              ;; is not absolute...
 316                              (multiple-value-bind (realpath errno)
 317                                  (sb!unix:unix-realpath filename)
 318                                (if realpath
 319                                    realpath
 320                                    (fail "couldn't resolve ~A" filename errno)))
 321                              (pathname-host pathname)
 322                              (sane-default-pathname-defaults)
 323                              ;; ... but without any trailing slash.
 324                              :as-directory (eql (logand  mode sb!unix:s-ifmt)
 325                                                 sb!unix:s-ifdir))))
 326                 (:author
 327                  #!-win32
 328                  (sb!unix:uid-username uid))
 329                 (:write-date (+ unix-to-universal-time mtime)))
 330               (progn
 331                 ;; SBCL has for many years had a policy that a pathname
 332                 ;; that names an existing, dangling or self-referential
 333                 ;; symlink denotes the symlink itself.  stat(2) fails
 334                 ;; and sets errno to ENOENT or ELOOP respectively, but
 335                 ;; we must distinguish cases where the symlink exists
 336                 ;; from ones where there's a loop in the apparent
 337                 ;; containing directory.
 338                 #!-win32
 339                 (multiple-value-bind (linkp ignore ino mode nlink uid gid rdev
 340                                             size atime mtime)
 341                     (sb!unix:unix-lstat filename)
 342                   (declare (ignore ignore ino mode nlink gid rdev size atime))
 343                   (when (and (or (= errno sb!unix:enoent)
 344                                  (= errno sb!unix:eloop))
 345                              linkp)
 346                     (return-from query-file-system
 347                       (case query-for
 348                         (:existence
 349                          ;; We do this reparse so as to return a
 350                          ;; normalized pathname.
 351                          (parse-native-namestring
 352                           filename (pathname-host pathname)))
 353                         (:truename
 354                          ;; So here's a trick: since lstat succeded,
 355                          ;; FILENAME exists, so its directory exists and
 356                          ;; only the non-directory part is loopy.  So
 357                          ;; let's resolve FILENAME's directory part with
 358                          ;; realpath(3), in order to get a canonical
 359                          ;; absolute name for the directory, and then
 360                          ;; return a pathname having PATHNAME's name,
 361                          ;; type, and version, but the rest from the
 362                          ;; truename of the directory.  Since we turned
 363                          ;; PATHNAME into FILENAME "as a file", FILENAME
 364                          ;; does not end in a slash, and so we get the
 365                          ;; directory part of FILENAME by reparsing
 366                          ;; FILENAME and masking off its name, type, and
 367                          ;; version bits.  But note not to call ourselves
 368                          ;; recursively, because we don't want to
 369                          ;; re-merge against *DEFAULT-PATHNAME-DEFAULTS*,
 370                          ;; since PATHNAME may be a relative pathname.
 371                          (merge-pathnames
 372                           (nth-value
 373                            0
 374                            (parse-native-namestring
 375                             (multiple-value-bind (realpath errno)
 376                                 (sb!unix:unix-realpath
 377                                  (native-namestring
 378                                   (make-pathname
 379                                    :name :unspecific
 380                                    :type :unspecific
 381                                    :version :unspecific
 382                                    :defaults (parse-native-namestring
 383                                               filename
 384                                               (pathname-host pathname)
 385                                               (sane-default-pathname-defaults)))))
 386                               (if realpath
 387                                   realpath
 388                                   (fail "couldn't resolve ~A" filename errno)))
 389                             (pathname-host pathname)
 390                             (sane-default-pathname-defaults)
 391                             :as-directory t))
 392                           pathname))
 393                         (:author (sb!unix:uid-username uid))
 394                         (:write-date (+ unix-to-universal-time mtime))))))
 395                 ;; If we're still here, the file doesn't exist; error.
 396                 (fail
 397                  (format nil "failed to find the ~A of ~~A" query-for)
 398                  pathspec errno))))))))
 399
 400
 401 (defun probe-file (pathspec)
 402   #!+sb-doc
 403   "Return the truename of PATHSPEC if the truename can be found,
 404 or NIL otherwise.  See TRUENAME for more information."
 405   (query-file-system pathspec :truename nil))
 406
 407 (defun truename (pathspec)
 408   #!+sb-doc
 409   "If PATHSPEC is a pathname that names an existing file, return
 410 a pathname that denotes a canonicalized name for the file.  If
 411 pathspec is a stream associated with a file, return a pathname
 412 that denotes a canonicalized name for the file associated with
 413 the stream.
 414
 415 An error of type FILE-ERROR is signalled if no such file exists
 416 or if the file system is such that a canonicalized file name
 417 cannot be determined or if the pathname is wild.
 418
 419 Under Unix, the TRUENAME of a symlink that links to itself or to
 420 a file that doesn't exist is considered to be the name of the
 421 broken symlink itself."
 422   ;; Note that eventually this routine might be different for streams
 423   ;; than for other pathname designators.
 424   (if (streamp pathspec)
 425       (query-file-system pathspec :truename)
 426       (query-file-system pathspec :truename)))
 427
 428 (defun file-author (pathspec)
 429   #!+sb-doc
 430   "Return the author of the file specified by PATHSPEC. Signal an
 431 error of type FILE-ERROR if no such file exists, or if PATHSPEC
 432 is a wild pathname."
 433   (query-file-system pathspec :author))
 434
 435 (defun file-write-date (pathspec)
 436   #!+sb-doc
 437   "Return the write date of the file specified by PATHSPEC.
 438 An error of type FILE-ERROR is signaled if no such file exists,
 439 or if PATHSPEC is a wild pathname."
 440   (query-file-system pathspec :write-date))
 441 \f
 442 ;;;; miscellaneous other operations
 443
 444 (/show0 "filesys.lisp 700")
 445
 446 (defun rename-file (file new-name)
 447   #!+sb-doc
 448   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 449   file, then the associated file is renamed."
 450   (let* ((original (truename file))
 451          (original-namestring (native-namestring original :as-file t))
 452          (new-name (merge-pathnames new-name original))
 453          (new-namestring (native-namestring (physicalize-pathname new-name)
 454                                             :as-file t)))
 455     (unless new-namestring
 456       (error 'simple-file-error
 457              :pathname new-name
 458              :format-control "~S can't be created."
 459              :format-arguments (list new-name)))
 460     (multiple-value-bind (res error)
 461         (sb!unix:unix-rename original-namestring new-namestring)
 462       (unless res
 463         (error 'simple-file-error
 464                :pathname new-name
 465                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 466                                 ~I~_~A~:>"
 467                :format-arguments (list original new-name (strerror error))))
 468       (when (streamp file)
 469         (file-name file new-name))
 470       (values new-name original (truename new-name)))))
 471
 472 (defun delete-file (file)
 473   #!+sb-doc
 474   "Delete the specified FILE.
 475
 476 If FILE is a stream, on Windows the stream is closed immediately. On Unix
 477 plaforms the stream remains open, allowing IO to continue: the OS resources
 478 associated with the deleted file remain available till the stream is closed as
 479 per standard Unix unlink() behaviour."
 480   (let* ((pathname (pathname file))
 481          (namestring (native-namestring pathname :as-file t)))
 482     (truename file) ; for error-checking side-effect
 483     #!+win32
 484     (when (streamp file)
 485       (close file))
 486     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 487       (unless res
 488         (simple-file-perror "couldn't delete ~A" namestring err))))
 489   t)
 490 \f
 491 (defun sbcl-homedir-pathname ()
 492   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 493     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 494     (when (and sbcl-home (not (string= sbcl-home "")))
 495       (parse-native-namestring sbcl-home
 496                                #!-win32 sb!impl::*unix-host*
 497                                #!+win32 sb!impl::*win32-host*
 498                                *default-pathname-defaults*
 499                                :as-directory t))))
 500
 501 ;;; (This is an ANSI Common Lisp function.)
 502 (defun user-homedir-pathname (&optional host)
 503   #!+sb-doc
 504   "Return the home directory of the user as a pathname. If the HOME
 505 environment variable has been specified, the directory it designates
 506 is returned; otherwise obtains the home directory from the operating
 507 system."
 508   (declare (ignore host))
 509   (let ((env-home (posix-getenv "HOME")))
 510     (values
 511      (parse-native-namestring
 512       (if (and env-home (not (string= env-home "")))
 513           env-home
 514           #!-win32
 515           (sb!unix:uid-homedir (sb!unix:unix-getuid))
 516           #!+win32
 517           ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 518           ;; What?! -- RMK, 2007-12-31
 519           (return-from user-homedir-pathname
 520             (sb!win32::get-folder-pathname sb!win32::csidl_profile)))
 521       #!-win32 sb!impl::*unix-host*
 522       #!+win32 sb!impl::*win32-host*
 523       *default-pathname-defaults*
 524       :as-directory t))))
 525
 526 \f
 527 ;;;; DIRECTORY
 528
 529 (defun directory (pathspec &key (resolve-symlinks t))
 530   #!+sb-doc
 531   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 532 given pathname. Note that the interaction between this ANSI-specified
 533 TRUENAMEing and the semantics of the Unix filesystem (symbolic links..) means
 534 this function can sometimes return files which don't have the same directory
 535 as PATHNAME. If :RESOLVE-SYMLINKS is NIL, don't resolve symbolic links in
 536 matching filenames."
 537   (let (;; We create one entry in this hash table for each truename,
 538         ;; as an asymptotically efficient way of removing duplicates
 539         ;; (which can arise when e.g. multiple symlinks map to the
 540         ;; same truename).
 541         (truenames (make-hash-table :test #'equal)))
 542     (labels ((record (pathname)
 543                (let ((truename (if resolve-symlinks
 544                                    ;; FIXME: Why not not TRUENAME?  As reported by
 545                                    ;; Milan Zamazal sbcl-devel 2003-10-05, using
 546                                    ;; TRUENAME causes a race condition whereby
 547                                    ;; removal of a file during the directory
 548                                    ;; operation causes an error.  It's not clear
 549                                    ;; what the right thing to do is, though.  --
 550                                    ;; CSR, 2003-10-13
 551                                    (query-file-system pathname :truename nil)
 552                                    (query-file-system pathname :existence nil))))
 553                  (when truename
 554                    (setf (gethash (namestring truename) truenames)
 555                          truename))))
 556              (do-physical-pathnames (pathname)
 557                (aver (not (logical-pathname-p pathname)))
 558                (let* (;; KLUDGE: Since we don't canonize pathnames on construction,
 559                       ;; we really have to do it here to get #p"foo/." mean the same
 560                       ;; as #p"foo/./".
 561                       (pathname (canonicalize-pathname pathname))
 562                       (name (pathname-name pathname))
 563                       (type (pathname-type pathname))
 564                       (match-name (make-matcher name))
 565                       (match-type (make-matcher type)))
 566                  (map-matching-directories
 567                   (if (or name type)
 568                       (lambda (directory)
 569                         (map-matching-entries #'record
 570                                               directory
 571                                               match-name
 572                                               match-type))
 573                       #'record)
 574                   pathname)))
 575              (do-pathnames (pathname)
 576                (if (logical-pathname-p pathname)
 577                    (let ((host (intern-logical-host (pathname-host pathname))))
 578                      (dolist (x (logical-host-canon-transls host))
 579                        (destructuring-bind (from to) x
 580                          (let ((intersections
 581                                 (pathname-intersections pathname from)))
 582                            (dolist (p intersections)
 583                              (do-pathnames (translate-pathname p from to)))))))
 584                    (do-physical-pathnames pathname))))
 585       (declare (truly-dynamic-extent #'record))
 586       (do-pathnames (merge-pathnames pathspec)))
 587     (mapcar #'cdr
 588             ;; Sorting isn't required by the ANSI spec, but sorting into some
 589             ;; canonical order seems good just on the grounds that the
 590             ;; implementation should have repeatable behavior when possible.
 591             (sort (loop for namestring being each hash-key in truenames
 592                         using (hash-value truename)
 593                         collect (cons namestring truename))
 594                   #'string<
 595                   :key #'car))))
 596
 597 (defun canonicalize-pathname (pathname)
 598   ;; We're really only interested in :UNSPECIFIC -> NIL, :BACK and :UP,
 599   ;; and dealing with #p"foo/.." and #p"foo/."
 600   (labels ((simplify (piece)
 601              (unless (eq :unspecific piece)
 602                piece))
 603            (canonicalize-directory (directory)
 604              (let (pieces)
 605                (dolist (piece directory)
 606                  (if (and pieces (member piece '(:back :up)))
 607                      ;; FIXME: We should really canonicalize when we construct
 608                      ;; pathnames. This is just wrong.
 609                      (case (car pieces)
 610                        ((:absolute :wild-inferiors)
 611                         (error 'simple-file-error
 612                                :format-control "Invalid use of ~S after ~S."
 613                                :format-arguments (list piece (car pieces))
 614                                :pathname pathname))
 615                        ((:relative :up :back)
 616                         (push piece pieces))
 617                        (t
 618                         (pop pieces)))
 619                      (push piece pieces)))
 620                (nreverse pieces))))
 621     (let ((name (simplify (pathname-name pathname)))
 622           (type (simplify (pathname-type pathname)))
 623           (dir (canonicalize-directory (pathname-directory pathname))))
 624       (cond ((equal "." name)
 625              (cond ((not type)
 626                     (make-pathname :name nil :defaults pathname))
 627                    ((equal "" type)
 628                     (make-pathname :name nil
 629                                    :type nil
 630                                    :directory (butlast dir)
 631                                    :defaults pathname))))
 632             (t
 633              (make-pathname :name name :type type
 634                             :directory dir
 635                             :defaults pathname))))))
 636
 637 ;;; Given a native namestring, provides a WITH-HASH-TABLE-ITERATOR style
 638 ;;; interface to mapping over namestrings of entries in the corresponding
 639 ;;; directory.
 640 (defmacro with-native-directory-iterator ((iterator namestring &key errorp) &body body)
 641   (with-unique-names (one-iter)
 642     `(dx-flet
 643          ((iterate (,one-iter)
 644             (declare (type function ,one-iter))
 645             (macrolet ((,iterator ()
 646                          `(funcall ,',one-iter)))
 647               ,@body)))
 648        (call-with-native-directory-iterator #'iterate ,namestring ,errorp))))
 649
 650 (defun call-with-native-directory-iterator (function namestring errorp)
 651   (declare (type (or null string) namestring)
 652            (function function))
 653   (let (dp)
 654     (when namestring
 655       (dx-flet
 656           ((one-iter ()
 657              (tagbody
 658               :next
 659                 (let ((ent (sb!unix:unix-readdir dp nil)))
 660                   (when ent
 661                     (let ((name (sb!unix:unix-dirent-name ent)))
 662                       (when name
 663                         (cond ((equal "." name)
 664                                (go :next))
 665                               ((equal ".." name)
 666                                (go :next))
 667                               (t
 668                                (return-from one-iter name))))))))))
 669         (unwind-protect
 670              (progn
 671                (setf dp (sb!unix:unix-opendir namestring errorp))
 672                (when dp
 673                  (funcall function #'one-iter)))
 674           (when dp
 675             (sb!unix:unix-closedir dp nil)))))))
 676
 677 ;;; This is our core directory access interface that we use to implement
 678 ;;; DIRECTORY.
 679 (defun map-directory (function directory &key (files t) (directories t) (errorp t))
 680   #!+sb-doc
 681   "Map over entries in DIRECTORY. Keyword arguments specify which entries to
 682 map over, and how:
 683
 684  :FILES
 685     If true, call FUNCTION with the pathname of each file in DIRECTORY.
 686     Defaults to T.
 687
 688  :DIRECTORIES
 689    If true, call FUNCTION with a pathname for each subdirectory of DIRECTORY.
 690    If :AS-FILES, the pathname used is a pathname designating the subdirectory
 691    as a file in DIRECTORY. Otherwise the pathname used is a directory
 692    pathname. Defaults to T.
 693
 694  :ERRORP
 695    If true, signal an error if DIRECTORY does not exist, cannot be read, etc.
 696    Defaults to T.
 697
 698 On platforms supporting symbolic links the decision to call FUNCTION with its
 699 pathname depends on the resolution of the link: if it points to a directory,
 700 it is considered a directory entry. Whether it is considered a file or a
 701 directory, the provided pathname is not fully resolved, but rather names the
 702 symbolic link as an immediate child of DIRECTORY.
 703
 704 Experimental: interface subject to change."
 705   (declare (pathname-designator directory))
 706   (let* ((fun (%coerce-callable-to-fun function))
 707          (as-files (eq :as-files directories))
 708          (physical (physicalize-pathname directory))
 709          ;; Not QUERY-FILE-SYSTEM :EXISTENCE, since it doesn't work on Windows
 710          ;; network shares.
 711          (realname (sb!unix:unix-realpath (native-namestring physical :as-file t)))
 712          (canonical (if realname
 713                         (parse-native-namestring realname
 714                                                  (pathname-host physical)
 715                                                  (sane-default-pathname-defaults)
 716                                                  :as-directory t)
 717                         (return-from map-directory nil)))
 718          (dirname (native-namestring canonical)))
 719     (flet ((map-it (name dirp)
 720              (funcall fun
 721                       (merge-pathnames (parse-native-namestring
 722                                         name nil physical
 723                                         :as-directory (and dirp (not as-files)))
 724                                        physical))))
 725       (with-native-directory-iterator (next dirname :errorp errorp)
 726        (loop for name = (next)
 727              while name
 728              do (let* ((full (concatenate 'string dirname name))
 729                        (kind (native-file-kind full)))
 730                   (when kind
 731                     (case kind
 732                       (:directory
 733                        (when directories
 734                          (map-it name t)))
 735                       (:symlink
 736                        (let* ((tmpname (merge-pathnames
 737                                         (parse-native-namestring
 738                                          name nil physical :as-directory nil)
 739                                         physical))
 740                               (truename (query-file-system tmpname :truename nil)))
 741                          (if (or (not truename)
 742                                  (or (pathname-name truename) (pathname-type truename)))
 743                              (when files
 744                                (funcall fun tmpname))
 745                              (when directories
 746                                (map-it name t)))))
 747                       (t
 748                        ;; Anything else parses as a file.
 749                        (when files
 750                          (map-it name nil)))))))))))
 751
 752 ;;; Part of DIRECTORY: implements matching the directory spec. Calls FUNCTION
 753 ;;; with all DIRECTORIES that match the directory portion of PATHSPEC.
 754 (defun map-matching-directories (function pathspec)
 755   (let* ((dir (pathname-directory pathspec))
 756          (length (length dir))
 757          (wild (position-if (lambda (elt)
 758                               (or (eq :wild elt) (typep elt 'pattern)))
 759                             dir))
 760          (wild-inferiors (position :wild-inferiors dir))
 761          (end (cond ((and wild wild-inferiors)
 762                      (min wild wild-inferiors))
 763                     (t
 764                      (or wild wild-inferiors length))))
 765          (rest (subseq dir end))
 766          (starting-point (make-pathname :directory (subseq dir 0 end)
 767                                         :device (pathname-device pathspec)
 768                                         :host (pathname-host pathspec)
 769                                         :name nil
 770                                         :type nil
 771                                         :version nil)))
 772     (cond (wild-inferiors
 773            (map-wild-inferiors function rest starting-point))
 774           (wild
 775            (map-wild function rest starting-point))
 776           (t
 777            ;; Nothing wild -- the directory matches itself.
 778            (funcall function starting-point))))
 779   nil)
 780
 781 (defun last-directory-piece (pathname)
 782   (car (last (pathname-directory pathname))))
 783
 784 ;;; Part of DIRECTORY: implements iterating over a :WILD or pattern component
 785 ;;; in the directory spec.
 786 (defun map-wild (function more directory)
 787   (let ((this (pop more))
 788         (next (car more)))
 789     (flet ((cont (subdirectory)
 790              (cond ((not more)
 791                     ;; end of the line
 792                     (funcall function subdirectory))
 793                    ((or (eq :wild next) (typep next 'pattern))
 794                     (map-wild function more subdirectory))
 795                    ((eq :wild-inferiors next)
 796                     (map-wild-inferiors function more subdirectory))
 797                    (t
 798                     (let ((this (pathname-directory subdirectory)))
 799                       (map-matching-directories
 800                        function
 801                        (make-pathname :directory (append this more)
 802                                       :defaults subdirectory)))))))
 803       (map-directory
 804        (if (eq :wild this)
 805            #'cont
 806            (lambda (sub)
 807              (when (pattern-matches this (last-directory-piece sub))
 808                (funcall #'cont sub))))
 809        directory
 810        :files nil
 811        :directories t
 812        :errorp nil))))
 813
 814 ;;; Part of DIRECTORY: implements iterating over a :WILD-INFERIORS component
 815 ;;; in the directory spec.
 816 (defun map-wild-inferiors (function more directory)
 817   (loop while (member (car more) '(:wild :wild-inferiors))
 818         do (pop more))
 819   (let ((next (car more))
 820         (rest (cdr more)))
 821     (unless more
 822       (funcall function directory))
 823     (map-directory
 824      (cond ((not more)
 825             (lambda (pathname)
 826               (funcall function pathname)
 827               (map-wild-inferiors function more pathname)))
 828            (t
 829             (lambda (pathname)
 830               (let ((this (pathname-directory pathname)))
 831                 (when (equal next (car (last this)))
 832                   (map-matching-directories
 833                    function
 834                    (make-pathname :directory (append this rest)
 835                                   :defaults pathname)))
 836                 (map-wild-inferiors function more pathname)))))
 837      directory
 838      :files nil
 839      :directories t
 840      :errorp nil)))
 841
 842 ;;; Part of DIRECTORY: implements iterating over entries in a directory, and
 843 ;;; matching them.
 844 (defun map-matching-entries (function directory match-name match-type)
 845   (map-directory
 846    (lambda (file)
 847      (when (and (funcall match-name (pathname-name file))
 848                 (funcall match-type (pathname-type file)))
 849        (funcall function file)))
 850    directory
 851    :files t
 852    :directories :as-files
 853    :errorp nil))
 854
 855 ;;; NOTE: There is a fair amount of hair below that is probably not
 856 ;;; strictly necessary.
 857 ;;;
 858 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 859 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 860 ;;; did not translate the logical pathname at all, but instead treated
 861 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 862 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 863 ;;; which is fine as far as it goes, but not very interesting, and
 864 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 865 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 866 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 867 ;;; exists, of course).
 868 ;;;
 869 ;;; So, the interpretation that I am pushing is for all pathnames
 870 ;;; matching the input pathname to be queried.  This means that we
 871 ;;; need to compute the intersection of the input pathname and the
 872 ;;; logical host FROM translations, and then translate the resulting
 873 ;;; pathname using the host to the TO translation; this treatment is
 874 ;;; recursively invoked until we get a physical pathname, whereupon
 875 ;;; our physical DIRECTORY implementation takes over.
 876
 877 ;;; FIXME: this is an incomplete implementation.  It only works when
 878 ;;; both are logical pathnames (which is OK, because that's the only
 879 ;;; case when we call it), but there are other pitfalls as well: see
 880 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 881 ;;; pattern handling.
 882
 883 ;;; The above was written by CSR, I (RMK) believe.  The argument that
 884 ;;; motivates the interpretation is faulty, however: PATHNAME-MATCH-P
 885 ;;; returns true for (PATHNAME-MATCH-P #P"/tmp/*/" #P"/tmp/../"), but
 886 ;;; the latter pathname is not in the result of DIRECTORY on the
 887 ;;; former.  Indeed, if DIRECTORY were constrained to return the
 888 ;;; truename for every pathname for which PATHNAME-MATCH-P returned
 889 ;;; true and which denoted a filename that named an existing file,
 890 ;;; (DIRECTORY #P"/tmp/**/") would be required to list every file on a
 891 ;;; Unix system, since any file can be named as though it were "below"
 892 ;;; /tmp, given the dotdot entries.  So I think the strongest
 893 ;;; "consistency" we can define between PATHNAME-MATCH-P and DIRECTORY
 894 ;;; is that PATHNAME-MATCH-P returns true of everything DIRECTORY
 895 ;;; returns, but not vice versa.
 896
 897 ;;; In any case, even if the motivation were sound, DIRECTORY on a
 898 ;;; wild logical pathname has no portable semantics.  I see nothing in
 899 ;;; ANSI that requires implementations to support wild physical
 900 ;;; pathnames, and so there need not be any translation of a wild
 901 ;;; logical pathname to a phyiscal pathname.  So a program that calls
 902 ;;; DIRECTORY on a wild logical pathname is doing something
 903 ;;; non-portable at best.  And if the only sensible semantics for
 904 ;;; DIRECTORY on a wild logical pathname is something like the
 905 ;;; following, it would be just as well if it signaled an error, since
 906 ;;; a program can't possibly rely on the result of an intersection of
 907 ;;; user-defined translations with a file system probe.  (Potentially
 908 ;;; useful kinds of "pathname" that might not support wildcards could
 909 ;;; include pathname hosts that model unqueryable namespaces like HTTP
 910 ;;; URIs, or that model namespaces that it's not convenient to
 911 ;;; investigate, such as the namespace of TCP ports that some network
 912 ;;; host listens on.  I happen to think it a bad idea to try to
 913 ;;; shoehorn such namespaces into a pathnames system, but people
 914 ;;; sometimes claim to want pathnames for these things.)  -- RMK
 915 ;;; 2007-12-31.
 916
 917 (defun pathname-intersections (one two)
 918   (aver (logical-pathname-p one))
 919   (aver (logical-pathname-p two))
 920   (labels
 921       ((intersect-version (one two)
 922          (aver (typep one '(or null (member :newest :wild :unspecific)
 923                             integer)))
 924          (aver (typep two '(or null (member :newest :wild :unspecific)
 925                             integer)))
 926          (cond
 927            ((eq one :wild) two)
 928            ((eq two :wild) one)
 929            ((or (null one) (eq one :unspecific)) two)
 930            ((or (null two) (eq two :unspecific)) one)
 931            ((eql one two) one)
 932            (t nil)))
 933        (intersect-name/type (one two)
 934          (aver (typep one '(or null (member :wild :unspecific) string)))
 935          (aver (typep two '(or null (member :wild :unspecific) string)))
 936          (cond
 937            ((eq one :wild) two)
 938            ((eq two :wild) one)
 939            ((or (null one) (eq one :unspecific)) two)
 940            ((or (null two) (eq two :unspecific)) one)
 941            ((string= one two) one)
 942            (t nil)))
 943        (intersect-directory (one two)
 944          (aver (typep one '(or null (member :wild :unspecific) list)))
 945          (aver (typep two '(or null (member :wild :unspecific) list)))
 946          (cond
 947            ((eq one :wild) two)
 948            ((eq two :wild) one)
 949            ((or (null one) (eq one :unspecific)) two)
 950            ((or (null two) (eq two :unspecific)) one)
 951            (t (aver (eq (car one) (car two)))
 952               (mapcar
 953                (lambda (x) (cons (car one) x))
 954                (intersect-directory-helper (cdr one) (cdr two)))))))
 955     (let ((version (intersect-version
 956                     (pathname-version one) (pathname-version two)))
 957           (name (intersect-name/type
 958                  (pathname-name one) (pathname-name two)))
 959           (type (intersect-name/type
 960                  (pathname-type one) (pathname-type two)))
 961           (host (pathname-host one)))
 962       (mapcar (lambda (d)
 963                 (make-pathname :host host :name name :type type
 964                                :version version :directory d))
 965               (intersect-directory
 966                (pathname-directory one) (pathname-directory two))))))
 967
 968 ;;; FIXME: written as its own function because I (CSR) don't
 969 ;;; understand it, so helping both debuggability and modularity.  In
 970 ;;; case anyone is motivated to rewrite it, it returns a list of
 971 ;;; sublists representing the intersection of the two input directory
 972 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 973 ;;;
 974 ;;; FIXME: Does not work with :UP or :BACK
 975 ;;; FIXME: Does not work with patterns
 976 ;;;
 977 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 978 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 979 ;;; turns out to be worth it.
 980 (defun intersect-directory-helper (one two)
 981   (flet ((simple-intersection (cone ctwo)
 982            (cond
 983              ((eq cone :wild) ctwo)
 984              ((eq ctwo :wild) cone)
 985              (t (aver (typep cone 'string))
 986                 (aver (typep ctwo 'string))
 987                 (if (string= cone ctwo) cone nil)))))
 988     (macrolet
 989         ((loop-possible-wild-inferiors-matches
 990              (lower-bound bounding-sequence order)
 991            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 992              `(let ((,l (length ,bounding-sequence)))
 993                (loop for ,index from ,lower-bound to ,l
 994                 append (mapcar (lambda (,g2)
 995                                  (append
 996                                   (butlast ,bounding-sequence (- ,l ,index))
 997                                   ,g2))
 998                         (mapcar
 999                          (lambda (,g3)
1000                            (append
1001                             (if (eq (car (nthcdr ,index ,bounding-sequence))
1002                                     :wild-inferiors)
1003                                 '(:wild-inferiors)
1004                                 nil) ,g3))
1005                          (intersect-directory-helper
1006                           ,@(if order
1007                                 `((nthcdr ,index one) (cdr two))
1008                                 `((cdr one) (nthcdr ,index two)))))))))))
1009       (cond
1010         ((and (eq (car one) :wild-inferiors)
1011               (eq (car two) :wild-inferiors))
1012          (delete-duplicates
1013           (append (mapcar (lambda (x) (cons :wild-inferiors x))
1014                           (intersect-directory-helper (cdr one) (cdr two)))
1015                   (loop-possible-wild-inferiors-matches 2 one t)
1016                   (loop-possible-wild-inferiors-matches 2 two nil))
1017           :test 'equal))
1018         ((eq (car one) :wild-inferiors)
1019          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
1020                             :test 'equal))
1021         ((eq (car two) :wild-inferiors)
1022          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
1023                             :test 'equal))
1024         ((and (null one) (null two)) (list nil))
1025         ((null one) nil)
1026         ((null two) nil)
1027         (t (and (simple-intersection (car one) (car two))
1028                 (mapcar (lambda (x) (cons (simple-intersection
1029                                            (car one) (car two)) x))
1030                         (intersect-directory-helper (cdr one) (cdr two)))))))))
1031 \f
1032 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
1033   #!+sb-doc
1034   "Test whether the directories containing the specified file
1035   actually exist, and attempt to create them if they do not.
1036   The MODE argument is a CMUCL/SBCL-specific extension to control
1037   the Unix permission bits."
1038   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
1039         (created-p nil))
1040     (when (wild-pathname-p pathname)
1041       (error 'simple-file-error
1042              :format-control "bad place for a wild pathname"
1043              :pathname pathspec))
1044     (let ((dir (pathname-directory pathname)))
1045       (loop for i from 1 upto (length dir)
1046             do (let ((newpath (make-pathname
1047                                :host (pathname-host pathname)
1048                                :device (pathname-device pathname)
1049                                :directory (subseq dir 0 i))))
1050                  (unless (probe-file newpath)
1051                    (let ((namestring (coerce (native-namestring newpath)
1052                                              'string)))
1053                      (when verbose
1054                        (format *standard-output*
1055                                "~&creating directory: ~A~%"
1056                                namestring))
1057                      (sb!unix:unix-mkdir namestring mode)
1058                      (unless (probe-file newpath)
1059                        (restart-case (error
1060                                       'simple-file-error
1061                                       :pathname pathspec
1062                                       :format-control
1063                                       "can't create directory ~A"
1064                                       :format-arguments (list namestring))
1065                          (retry ()
1066                            :report "Retry directory creation."
1067                            (ensure-directories-exist
1068                             pathspec
1069                             :verbose verbose :mode mode))
1070                          (continue ()
1071                            :report
1072                            "Continue as if directory creation was successful."
1073                            nil)))
1074                      (setf created-p t)))))
1075       (values pathspec created-p))))
1076
1077 (/show0 "filesys.lisp 1000")