src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defun maybe-make-pattern (namestr start end)
  84   (declare (type simple-string namestr)
  85            (type index start end))
  86   (collect ((pattern))
  87     (let ((quoted nil)
  88           (any-quotes nil)
  89           (last-regular-char nil)
  90           (index start))
  91       (flet ((flush-pending-regulars ()
  92                (when last-regular-char
  93                  (pattern (if any-quotes
  94                               (remove-backslashes namestr
  95                                                   last-regular-char
  96                                                   index)
  97                               (subseq namestr last-regular-char index)))
  98                  (setf any-quotes nil)
  99                  (setf last-regular-char nil))))
 100         (loop
 101           (when (>= index end)
 102             (return))
 103           (let ((char (schar namestr index)))
 104             (cond (quoted
 105                    (incf index)
 106                    (setf quoted nil))
 107                   ((char= char #\\)
 108                    (setf quoted t)
 109                    (setf any-quotes t)
 110                    (unless last-regular-char
 111                      (setf last-regular-char index))
 112                    (incf index))
 113                   ((char= char #\?)
 114                    (flush-pending-regulars)
 115                    (pattern :single-char-wild)
 116                    (incf index))
 117                   ((char= char #\*)
 118                    (flush-pending-regulars)
 119                    (pattern :multi-char-wild)
 120                    (incf index))
 121                   ((char= char #\[)
 122                    (flush-pending-regulars)
 123                    (let ((close-bracket
 124                           (position #\] namestr :start index :end end)))
 125                      (unless close-bracket
 126                        (error 'namestring-parse-error
 127                               :complaint "#\\[ with no corresponding #\\]"
 128                               :namestring namestr
 129                               :offset index))
 130                      (pattern (cons :character-set
 131                                     (subseq namestr
 132                                             (1+ index)
 133                                             close-bracket)))
 134                      (setf index (1+ close-bracket))))
 135                   (t
 136                    (unless last-regular-char
 137                      (setf last-regular-char index))
 138                    (incf index)))))
 139         (flush-pending-regulars)))
 140     (cond ((null (pattern))
 141            "")
 142           ((null (cdr (pattern)))
 143            (let ((piece (first (pattern))))
 144              (typecase piece
 145                ((member :multi-char-wild) :wild)
 146                (simple-string piece)
 147                (t
 148                 (make-pattern (pattern))))))
 149           (t
 150            (make-pattern (pattern))))))
 151
 152 (defun unparse-physical-piece (thing)
 153   (etypecase thing
 154     ((member :wild) "*")
 155     (simple-string
 156      (let* ((srclen (length thing))
 157             (dstlen srclen))
 158        (dotimes (i srclen)
 159          (case (schar thing i)
 160            ((#\* #\? #\[)
 161             (incf dstlen))))
 162        (let ((result (make-string dstlen))
 163              (dst 0))
 164          (dotimes (src srclen)
 165            (let ((char (schar thing src)))
 166              (case char
 167                ((#\* #\? #\[)
 168                 (setf (schar result dst) #\\)
 169                 (incf dst)))
 170              (setf (schar result dst) char)
 171              (incf dst)))
 172          result)))
 173     (pattern
 174      (with-output-to-string (s)
 175        (dolist (piece (pattern-pieces thing))
 176          (etypecase piece
 177            (simple-string
 178             (write-string piece s))
 179            (symbol
 180             (ecase piece
 181               (:multi-char-wild
 182                (write-string "*" s))
 183               (:single-char-wild
 184                (write-string "?" s))))
 185            (cons
 186             (case (car piece)
 187               (:character-set
 188                (write-string "[" s)
 189                (write-string (cdr piece) s)
 190                (write-string "]" s))
 191               (t
 192                (error "invalid pattern piece: ~S" piece))))))))))
 193
 194 (defun make-matcher (piece)
 195   (cond ((eq piece :wild)
 196          (constantly t))
 197         ((typep piece 'pattern)
 198          (lambda (other)
 199            (when (stringp other)
 200              (pattern-matches piece other))))
 201         (t
 202          (lambda (other)
 203            (equal piece other)))))
 204
 205 (/show0 "filesys.lisp 160")
 206
 207 (defun extract-name-type-and-version (namestr start end)
 208   (declare (type simple-string namestr)
 209            (type index start end))
 210   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 211                              :from-end t)))
 212     (cond
 213       (last-dot
 214        (values (maybe-make-pattern namestr start last-dot)
 215                (maybe-make-pattern namestr (1+ last-dot) end)
 216                :newest))
 217       (t
 218        (values (maybe-make-pattern namestr start end)
 219                nil
 220                :newest)))))
 221
 222 (/show0 "filesys.lisp 200")
 223
 224 \f
 225 ;;;; Grabbing the kind of file when we have a namestring.
 226 (defun native-file-kind (namestring)
 227   (multiple-value-bind (existsp errno ino mode)
 228       #!-win32
 229       (sb!unix:unix-lstat namestring)
 230       #!+win32
 231       (sb!unix:unix-stat namestring)
 232     (declare (ignore errno ino))
 233     (when existsp
 234       (let ((ifmt (logand mode sb!unix:s-ifmt)))
 235        (case ifmt
 236          (#.sb!unix:s-ifreg :file)
 237          (#.sb!unix:s-ifdir :directory)
 238          #!-win32
 239          (#.sb!unix:s-iflnk :symlink)
 240          (t :special))))))
 241 \f
 242 ;;;; TRUENAME, PROBE-FILE, FILE-AUTHOR, FILE-WRITE-DATE.
 243
 244 ;;; Rewritten in 12/2007 by RMK, replacing 13+ year old CMU code that
 245 ;;; made a mess of things in order to support search lists (which SBCL
 246 ;;; has never had).  These are now all relatively straightforward
 247 ;;; wrappers around stat(2) and realpath(2), with the same basic logic
 248 ;;; in all cases.  The wrinkles to be aware of:
 249 ;;;
 250 ;;; * SBCL defines the truename of an existing, dangling or
 251 ;;;   self-referring symlink to be the symlink itself.
 252 ;;; * The old version of PROBE-FILE merged the pathspec against
 253 ;;;   *DEFAULT-PATHNAME-DEFAULTS* twice, and so lost when *D-P-D*
 254 ;;;   was a relative pathname.  Even if the case where *D-P-D* is a
 255 ;;;   relative pathname is problematic, there's no particular reason
 256 ;;;   to get that wrong, so let's try not to.
 257 ;;; * Note that while stat(2) is probably atomic, getting the truename
 258 ;;;   for a filename involves poking all over the place, and so is
 259 ;;;   subject to race conditions if other programs mutate the file
 260 ;;;   system while we're resolving symlinks.  So it's not implausible for
 261 ;;;   realpath(3) to fail even if stat(2) succeeded.  There's nothing
 262 ;;;   obvious we can do about this, however.
 263 ;;; * Windows' apparent analogue of realpath(3) is called
 264 ;;;   GetFullPathName, and it's a bit less useful than realpath(3).
 265 ;;;   In particular, while realpath(3) errors in case the file doesn't
 266 ;;;   exist, GetFullPathName seems to return a filename in all cases.
 267 ;;;   As realpath(3) is not atomic anyway, we only ever call it when
 268 ;;;   we think a file exists, so just be careful when rewriting this
 269 ;;;   routine.
 270 ;;;
 271 ;;; Given a pathname designator, some quality to query for, return one
 272 ;;; of a pathname, a universal time, or a string (a file-author), or
 273 ;;; NIL.  QUERY-FOR may be one of :TRUENAME, :EXISTENCE, :WRITE-DATE,
 274 ;;; :AUTHOR.  If ERRORP is false, return NIL in case the file system
 275 ;;; returns an error code; otherwise, signal an error.  Accepts
 276 ;;; logical pathnames, too (but never returns LPNs).  For internal
 277 ;;; use.
 278 (defun query-file-system (pathspec query-for &optional (errorp t))
 279   (let ((pathname (translate-logical-pathname
 280                    (merge-pathnames
 281                     (pathname pathspec)
 282                     (sane-default-pathname-defaults)))))
 283     (when (wild-pathname-p pathname)
 284       (error 'simple-file-error
 285              :pathname pathname
 286              :format-control "~@<can't find the ~A of wild pathname ~A~
 287                               (physicalized from ~A).~:>"
 288              :format-arguments (list query-for pathname pathspec)))
 289     (flet ((fail (note-format pathname errno)
 290              (if errorp
 291                  (simple-file-perror note-format pathname errno)
 292                  (return-from query-file-system nil))))
 293       (let ((filename (native-namestring pathname :as-file t)))
 294         (multiple-value-bind (existsp errno ino mode nlink uid gid rdev size
 295                                       atime mtime)
 296             (sb!unix:unix-stat filename)
 297           (declare (ignore ino nlink gid rdev size atime))
 298           (if existsp
 299               (case query-for
 300                 (:existence (nth-value
 301                              0
 302                              (parse-native-namestring
 303                               filename
 304                               (pathname-host pathname)
 305                               (sane-default-pathname-defaults)
 306                               :as-directory (eql (logand mode sb!unix:s-ifmt)
 307                                                  sb!unix:s-ifdir))))
 308                 (:truename (nth-value
 309                             0
 310                             (parse-native-namestring
 311                              ;; Note: in case the file is stat'able, POSIX
 312                              ;; realpath(3) gets us a canonical absolute
 313                              ;; filename, even if the post-merge PATHNAME
 314                              ;; is not absolute...
 315                              (multiple-value-bind (realpath errno)
 316                                  (sb!unix:unix-realpath filename)
 317                                (if realpath
 318                                    realpath
 319                                    (fail "couldn't resolve ~A" filename errno)))
 320                              (pathname-host pathname)
 321                              (sane-default-pathname-defaults)
 322                              ;; ... but without any trailing slash.
 323                              :as-directory (eql (logand  mode sb!unix:s-ifmt)
 324                                                 sb!unix:s-ifdir))))
 325                 (:author (sb!unix:uid-username uid))
 326                 (:write-date (+ unix-to-universal-time mtime)))
 327               (progn
 328                 ;; SBCL has for many years had a policy that a pathname
 329                 ;; that names an existing, dangling or self-referential
 330                 ;; symlink denotes the symlink itself.  stat(2) fails
 331                 ;; and sets errno to ENOENT or ELOOP respectively, but
 332                 ;; we must distinguish cases where the symlink exists
 333                 ;; from ones where there's a loop in the apparent
 334                 ;; containing directory.
 335                 #!-win32
 336                 (multiple-value-bind (linkp ignore ino mode nlink uid gid rdev
 337                                             size atime mtime)
 338                     (sb!unix:unix-lstat filename)
 339                   (declare (ignore ignore ino mode nlink gid rdev size atime))
 340                   (when (and (or (= errno sb!unix:enoent)
 341                                  (= errno sb!unix:eloop))
 342                              linkp)
 343                     (return-from query-file-system
 344                       (case query-for
 345                         (:existence
 346                          ;; We do this reparse so as to return a
 347                          ;; normalized pathname.
 348                          (parse-native-namestring
 349                           filename (pathname-host pathname)))
 350                         (:truename
 351                          ;; So here's a trick: since lstat succeded,
 352                          ;; FILENAME exists, so its directory exists and
 353                          ;; only the non-directory part is loopy.  So
 354                          ;; let's resolve FILENAME's directory part with
 355                          ;; realpath(3), in order to get a canonical
 356                          ;; absolute name for the directory, and then
 357                          ;; return a pathname having PATHNAME's name,
 358                          ;; type, and version, but the rest from the
 359                          ;; truename of the directory.  Since we turned
 360                          ;; PATHNAME into FILENAME "as a file", FILENAME
 361                          ;; does not end in a slash, and so we get the
 362                          ;; directory part of FILENAME by reparsing
 363                          ;; FILENAME and masking off its name, type, and
 364                          ;; version bits.  But note not to call ourselves
 365                          ;; recursively, because we don't want to
 366                          ;; re-merge against *DEFAULT-PATHNAME-DEFAULTS*,
 367                          ;; since PATHNAME may be a relative pathname.
 368                          (merge-pathnames
 369                           (nth-value
 370                            0
 371                            (parse-native-namestring
 372                             (multiple-value-bind (realpath errno)
 373                                 (sb!unix:unix-realpath
 374                                  (native-namestring
 375                                   (make-pathname
 376                                    :name :unspecific
 377                                    :type :unspecific
 378                                    :version :unspecific
 379                                    :defaults (parse-native-namestring
 380                                               filename
 381                                               (pathname-host pathname)
 382                                               (sane-default-pathname-defaults)))))
 383                               (if realpath
 384                                   realpath
 385                                   (fail "couldn't resolve ~A" filename errno)))
 386                             (pathname-host pathname)
 387                             (sane-default-pathname-defaults)
 388                             :as-directory t))
 389                           pathname))
 390                         (:author (sb!unix:uid-username uid))
 391                         (:write-date (+ unix-to-universal-time mtime))))))
 392                 ;; If we're still here, the file doesn't exist; error.
 393                 (fail
 394                  (format nil "failed to find the ~A of ~~A" query-for)
 395                  pathspec errno))))))))
 396
 397
 398 (defun probe-file (pathspec)
 399   #!+sb-doc
 400   "Return the truename of PATHSPEC if the truename can be found,
 401 or NIL otherwise.  See TRUENAME for more information."
 402   (query-file-system pathspec :truename nil))
 403
 404 (defun truename (pathspec)
 405   #!+sb-doc
 406   "If PATHSPEC is a pathname that names an existing file, return
 407 a pathname that denotes a canonicalized name for the file.  If
 408 pathspec is a stream associated with a file, return a pathname
 409 that denotes a canonicalized name for the file associated with
 410 the stream.
 411
 412 An error of type FILE-ERROR is signalled if no such file exists
 413 or if the file system is such that a canonicalized file name
 414 cannot be determined or if the pathname is wild.
 415
 416 Under Unix, the TRUENAME of a symlink that links to itself or to
 417 a file that doesn't exist is considered to be the name of the
 418 broken symlink itself."
 419   ;; Note that eventually this routine might be different for streams
 420   ;; than for other pathname designators.
 421   (if (streamp pathspec)
 422       (query-file-system pathspec :truename)
 423       (query-file-system pathspec :truename)))
 424
 425 (defun file-author (pathspec)
 426   #!+sb-doc
 427   "Return the author of the file specified by PATHSPEC. Signal an
 428 error of type FILE-ERROR if no such file exists, or if PATHSPEC
 429 is a wild pathname."
 430   (query-file-system pathspec :author))
 431
 432 (defun file-write-date (pathspec)
 433   #!+sb-doc
 434   "Return the write date of the file specified by PATHSPEC.
 435 An error of type FILE-ERROR is signaled if no such file exists,
 436 or if PATHSPEC is a wild pathname."
 437   (query-file-system pathspec :write-date))
 438 \f
 439 ;;;; miscellaneous other operations
 440
 441 (/show0 "filesys.lisp 700")
 442
 443 (defun rename-file (file new-name)
 444   #!+sb-doc
 445   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 446   file, then the associated file is renamed."
 447   (let* ((original (truename file))
 448          (original-namestring (native-namestring original :as-file t))
 449          (new-name (merge-pathnames new-name original))
 450          (new-namestring (native-namestring new-name :as-file t)))
 451     (unless new-namestring
 452       (error 'simple-file-error
 453              :pathname new-name
 454              :format-control "~S can't be created."
 455              :format-arguments (list new-name)))
 456     (multiple-value-bind (res error)
 457         (sb!unix:unix-rename original-namestring new-namestring)
 458       (unless res
 459         (error 'simple-file-error
 460                :pathname new-name
 461                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 462                                 ~I~_~A~:>"
 463                :format-arguments (list original new-name (strerror error))))
 464       (when (streamp file)
 465         (file-name file new-name))
 466       (values new-name original (truename new-name)))))
 467
 468 (defun delete-file (file)
 469   #!+sb-doc
 470   "Delete the specified FILE."
 471   (let* ((truename (probe-file file))
 472          (namestring (when truename
 473                        (native-namestring truename :as-file t))))
 474     (when (streamp file)
 475       (close file :abort t))
 476     (unless namestring
 477       (error 'simple-file-error
 478              :pathname file
 479              :format-control "~S doesn't exist."
 480              :format-arguments (list file)))
 481     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 482       (unless res
 483         (simple-file-perror "couldn't delete ~A" namestring err))))
 484   t)
 485 \f
 486 (defun sbcl-homedir-pathname ()
 487   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 488     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 489     (when (and sbcl-home (not (string= sbcl-home "")))
 490       (parse-native-namestring sbcl-home
 491                                #!-win32 sb!impl::*unix-host*
 492                                #!+win32 sb!impl::*win32-host*
 493                                *default-pathname-defaults*
 494                                :as-directory t))))
 495
 496 ;;; (This is an ANSI Common Lisp function.)
 497 (defun user-homedir-pathname (&optional host)
 498   #!+sb-doc
 499   "Return the home directory of the user as a pathname. If the HOME
 500 environment variable has been specified, the directory it designates
 501 is returned; otherwise obtains the home directory from the operating
 502 system."
 503   (declare (ignore host))
 504   (let ((env-home (posix-getenv "HOME")))
 505     (values
 506      (parse-native-namestring
 507       (if (and env-home (not (string= env-home "")))
 508           env-home
 509           #!-win32
 510           (sb!unix:uid-homedir (sb!unix:unix-getuid))
 511           #!+win32
 512           ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 513           ;; What?! -- RMK, 2007-12-31
 514           (return-from user-homedir-pathname
 515             (sb!win32::get-folder-pathname sb!win32::csidl_profile)))
 516       #!-win32 sb!impl::*unix-host*
 517       #!+win32 sb!impl::*win32-host*
 518       *default-pathname-defaults*
 519       :as-directory t))))
 520
 521 \f
 522 ;;;; DIRECTORY
 523
 524 (defun directory (pathspec &key (resolve-symlinks t))
 525   #!+sb-doc
 526   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 527 given pathname. Note that the interaction between this ANSI-specified
 528 TRUENAMEing and the semantics of the Unix filesystem (symbolic links..) means
 529 this function can sometimes return files which don't have the same directory
 530 as PATHNAME. If :RESOLVE-SYMLINKS is NIL, don't resolve symbolic links in
 531 matching filenames."
 532   (let (;; We create one entry in this hash table for each truename,
 533         ;; as an asymptotically efficient way of removing duplicates
 534         ;; (which can arise when e.g. multiple symlinks map to the
 535         ;; same truename).
 536         (truenames (make-hash-table :test #'equal)))
 537     (labels ((record (pathname)
 538                (let ((truename (if resolve-symlinks
 539                                    ;; FIXME: Why not not TRUENAME?  As reported by
 540                                    ;; Milan Zamazal sbcl-devel 2003-10-05, using
 541                                    ;; TRUENAME causes a race condition whereby
 542                                    ;; removal of a file during the directory
 543                                    ;; operation causes an error.  It's not clear
 544                                    ;; what the right thing to do is, though.  --
 545                                    ;; CSR, 2003-10-13
 546                                    (query-file-system pathname :truename nil)
 547                                    (query-file-system pathname :existence nil))))
 548                  (when truename
 549                    (setf (gethash (namestring truename) truenames)
 550                          truename))))
 551              (do-physical-pathnames (pathname)
 552                (aver (not (logical-pathname-p pathname)))
 553                (let* ((name (pathname-name pathname))
 554                       (type (pathname-type pathname))
 555                       ;; KLUDGE: We want #p"/foo" to match #p"/foo/,
 556                       ;; so cobble up a directory name component from
 557                       ;; name and type -- just take care with "*.*"!
 558                       (dirname (if (and (eq :wild name) (eq :wild type))
 559                                    "*"
 560                                    (with-output-to-string (s)
 561                                      (when name
 562                                        (write-string (unparse-physical-piece name) s))
 563                                      (when type
 564                                        (write-string "." s)
 565                                        (write-string (unparse-physical-piece type) s)))))
 566                       (dir (maybe-make-pattern dirname 0 (length dirname)))
 567                       (match-name (make-matcher name))
 568                       (match-type (make-matcher type))
 569                       (match-dir (make-matcher dir)))
 570                  (map-matching-directories
 571                   (if (or name type)
 572                       (lambda (directory)
 573                         (map-matching-files #'record
 574                                             directory
 575                                             match-name
 576                                             match-type
 577                                             match-dir))
 578                       #'record)
 579                   pathname)))
 580              (do-pathnames (pathname)
 581                (if (logical-pathname-p pathname)
 582                    (let ((host (intern-logical-host (pathname-host pathname))))
 583                      (dolist (x (logical-host-canon-transls host))
 584                        (destructuring-bind (from to) x
 585                          (let ((intersections
 586                                 (pathname-intersections pathname from)))
 587                            (dolist (p intersections)
 588                              (do-pathnames (translate-pathname p from to)))))))
 589                    (do-physical-pathnames pathname))))
 590       (declare (truly-dynamic-extent #'record))
 591       (do-pathnames (merge-pathnames pathspec)))
 592     (mapcar #'cdr
 593             ;; Sorting isn't required by the ANSI spec, but sorting into some
 594             ;; canonical order seems good just on the grounds that the
 595             ;; implementation should have repeatable behavior when possible.
 596             (sort (loop for namestring being each hash-key in truenames
 597                         using (hash-value truename)
 598                         collect (cons namestring truename))
 599                   #'string<
 600                   :key #'car))))
 601
 602 ;;; Given a native namestring, provides a WITH-HASH-TABLE-ITERATOR style
 603 ;;; interface to mapping over namestrings of entries in the corresponding
 604 ;;; directory.
 605 (defmacro with-native-directory-iterator ((iterator namestring &key errorp) &body body)
 606   (with-unique-names (one-iter)
 607     `(dx-flet
 608          ((iterate (,one-iter)
 609             (declare (type function ,one-iter))
 610             (macrolet ((,iterator ()
 611                          `(funcall ,',one-iter)))
 612               ,@body)))
 613        (call-with-native-directory-iterator #'iterate ,namestring ,errorp))))
 614
 615 (defun call-with-native-directory-iterator (function namestring errorp)
 616   (declare (type (or null string) namestring)
 617            (function function))
 618   (let (dp)
 619     (when namestring
 620       (dx-flet
 621           ((one-iter ()
 622              (tagbody
 623               :next
 624                 (let ((ent (sb!unix:unix-readdir dp nil)))
 625                   (when ent
 626                     (let ((name (sb!unix:unix-dirent-name ent)))
 627                       (when name
 628                         (cond ((equal "." name)
 629                                (go :next))
 630                               ((equal ".." name)
 631                                (go :next))
 632                               (t
 633                                (return-from one-iter name))))))))))
 634         (unwind-protect
 635              (progn
 636                (setf dp (sb!unix:unix-opendir namestring errorp))
 637                (when dp
 638                  (funcall function #'one-iter)))
 639           (when dp
 640             (sb!unix:unix-closedir dp nil)))))))
 641
 642 ;;; This is our core directory access interface that we use to implement
 643 ;;; DIRECTORY.
 644 (defun map-directory (function directory &key (files t) (directories t) (errorp t))
 645   #!+sb-doc
 646   "Call FUNCTION with the pathname for each entry in DIRECTORY as follows: if
 647 FILES is true (the default), FUNCTION is called for each file in the
 648 directory; if DIRECTORIES is true (the default), FUNCTION is called for each
 649 subdirectory. If ERRORP is true (the default) signal an error if DIRECTORY
 650 does not exist, cannot be read, etc.
 651
 652 On platforms supporting symbolic links the decision to call FUNCTION with its
 653 pathname depends on the resolution of the link: if it points to a directory,
 654 it is considered a directory entry. Whether it is considered a file or a
 655 directory, the provided pathname is not fully resolved, but rather names the
 656 symbolic link as an immediate child of DIRECTORY.
 657
 658 Experimental: interface subject to change."
 659   (let* ((fun (%coerce-callable-to-fun function))
 660          (realname (or (query-file-system directory :existence errorp)
 661                        (return-from map-directory nil)))
 662          (host (pathname-host realname))
 663          ;; We want the trailing separator: better to ask the
 664          ;; provide it rather than reason about its presence here.
 665          (dirname (native-namestring realname :as-file nil)))
 666     (with-native-directory-iterator (next dirname :errorp errorp)
 667       (loop for name = (next)
 668             while name
 669             do (let* ((full (concatenate 'string dirname name))
 670                       (kind (native-file-kind full)))
 671                  (when kind
 672                    (case kind
 673                      (:directory
 674                       (when directories
 675                         (funcall fun (parse-native-namestring
 676                                       full host realname :as-directory t))))
 677                      (:symlink
 678                       (let* ((tmpname (parse-native-namestring
 679                                        full host realname :as-directory nil))
 680                              (truename (query-file-system tmpname :truename nil)))
 681                         (if (or (not truename)
 682                                 (or (pathname-name truename) (pathname-type truename)))
 683                             (when files
 684                               (funcall fun tmpname))
 685                             (when directories
 686                               (funcall fun (parse-native-namestring
 687                                             full host realname :as-directory t))))))
 688                      (t
 689                       ;; Anything else parses as a file.
 690                       (when files
 691                         (funcall fun (parse-native-namestring
 692                                       full host realname :as-directory nil)))))))))))
 693
 694 ;;; Part of DIRECTORY: implements matching the directory spec. Calls FUNCTION
 695 ;;; with all DIRECTORIES that match the directory portion of PATHSPEC.
 696 (defun map-matching-directories (function pathspec)
 697   (let* ((dir (pathname-directory pathspec))
 698          (length (length dir))
 699          (wild (position-if (lambda (elt)
 700                               (or (eq :wild elt) (typep elt 'pattern)))
 701                             dir))
 702          (wild-inferiors (position :wild-inferiors dir))
 703          (end (cond ((and wild wild-inferiors)
 704                      (min wild wild-inferiors))
 705                     (t
 706                      (or wild wild-inferiors length))))
 707          (rest (subseq dir end))
 708          (starting-point (make-pathname :directory (subseq dir 0 end)
 709                                         :device (pathname-device pathspec)
 710                                         :host (pathname-host pathspec)
 711                                         :name nil
 712                                         :type nil
 713                                         :version nil)))
 714     (cond (wild-inferiors
 715            (map-wild-inferiors function rest starting-point))
 716           (wild
 717            (map-wild function rest starting-point))
 718           (t
 719            ;; Nothing wild -- the directory matches itself.
 720            (funcall function starting-point)))))
 721
 722 (defun last-directory-piece (pathname)
 723   (car (last (pathname-directory pathname))))
 724
 725 ;;; Part of DIRECTORY: implements iterating over a :WILD or pattern component
 726 ;;; in the directory spec.
 727 (defun map-wild (function more directory)
 728   (let ((this (pop more))
 729         (next (car more)))
 730     (flet ((cont (subdirectory)
 731              (cond ((not more)
 732                     ;; end of the line
 733                     (funcall function subdirectory))
 734                    ((or (eq :wild next) (typep next 'pattern))
 735                     (lambda (pathname)
 736                       (map-wild function more pathname)))
 737                    ((eq :wild-inferiors next)
 738                     (lambda (pathname)
 739                       (map-wild-inferiors function more pathname)))
 740                    (t
 741                     (lambda (pathname)
 742                       (let ((this (pathname-directory pathname)))
 743                         (when (equal next (car (last this)))
 744                           (map-matching-directories
 745                            function
 746                            (make-pathname :directory (append this more)
 747                                           :defaults pathname)))))))))
 748       (map-directory
 749        (if (eq :wild this)
 750            #'cont
 751            (lambda (sub)
 752              (awhen (pattern-matches this (last-directory-piece sub))
 753                (funcall #'cont it))))
 754        directory
 755        :files nil
 756        :directories t
 757        :errorp nil))))
 758
 759 ;;; Part of DIRECTORY: implements iterating over a :WILD-INFERIORS component
 760 ;;; in the directory spec.
 761 (defun map-wild-inferiors (function more directory)
 762   (loop while (member (car more) '(:wild :wild-inferiors))
 763         do (pop more))
 764   (let ((next (car more))
 765         (rest (cdr more)))
 766     (unless more
 767       (funcall function directory))
 768     (map-directory
 769      (cond ((not more)
 770             (lambda (pathname)
 771               (funcall function pathname)
 772               (map-wild-inferiors function more pathname)))
 773            (t
 774             (lambda (pathname)
 775               (let ((this (pathname-directory pathname)))
 776                 (when (equal next (car (last this)))
 777                   (map-matching-directories
 778                    function
 779                    (make-pathname :directory (append this rest)
 780                                   :defaults pathname)))
 781                 (map-wild-inferiors function more pathname)))))
 782      directory
 783      :files nil
 784      :directories t
 785      :errorp nil)))
 786
 787 ;;; Part of DIRECTORY: implements iterating over files in a directory, and matching
 788 ;;; them.
 789 (defun map-matching-files (function directory match-name match-type match-dir)
 790   (map-directory
 791    (lambda (file)
 792      (let ((pname (pathname-name file))
 793            (ptype (pathname-type file)))
 794        (when (if (or pname ptype)
 795                  (and (funcall match-name pname) (funcall match-type ptype))
 796                  (funcall match-dir (last-directory-piece file)))
 797          (funcall function file))))
 798    directory
 799    :files t
 800    :directories t
 801    :errorp nil))
 802
 803 ;;; NOTE: There is a fair amount of hair below that is probably not
 804 ;;; strictly necessary.
 805 ;;;
 806 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 807 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 808 ;;; did not translate the logical pathname at all, but instead treated
 809 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 810 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 811 ;;; which is fine as far as it goes, but not very interesting, and
 812 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 813 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 814 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 815 ;;; exists, of course).
 816 ;;;
 817 ;;; So, the interpretation that I am pushing is for all pathnames
 818 ;;; matching the input pathname to be queried.  This means that we
 819 ;;; need to compute the intersection of the input pathname and the
 820 ;;; logical host FROM translations, and then translate the resulting
 821 ;;; pathname using the host to the TO translation; this treatment is
 822 ;;; recursively invoked until we get a physical pathname, whereupon
 823 ;;; our physical DIRECTORY implementation takes over.
 824
 825 ;;; FIXME: this is an incomplete implementation.  It only works when
 826 ;;; both are logical pathnames (which is OK, because that's the only
 827 ;;; case when we call it), but there are other pitfalls as well: see
 828 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 829 ;;; pattern handling.
 830
 831 ;;; The above was written by CSR, I (RMK) believe.  The argument that
 832 ;;; motivates the interpretation is faulty, however: PATHNAME-MATCH-P
 833 ;;; returns true for (PATHNAME-MATCH-P #P"/tmp/*/" #P"/tmp/../"), but
 834 ;;; the latter pathname is not in the result of DIRECTORY on the
 835 ;;; former.  Indeed, if DIRECTORY were constrained to return the
 836 ;;; truename for every pathname for which PATHNAME-MATCH-P returned
 837 ;;; true and which denoted a filename that named an existing file,
 838 ;;; (DIRECTORY #P"/tmp/**/") would be required to list every file on a
 839 ;;; Unix system, since any file can be named as though it were "below"
 840 ;;; /tmp, given the dotdot entries.  So I think the strongest
 841 ;;; "consistency" we can define between PATHNAME-MATCH-P and DIRECTORY
 842 ;;; is that PATHNAME-MATCH-P returns true of everything DIRECTORY
 843 ;;; returns, but not vice versa.
 844
 845 ;;; In any case, even if the motivation were sound, DIRECTORY on a
 846 ;;; wild logical pathname has no portable semantics.  I see nothing in
 847 ;;; ANSI that requires implementations to support wild physical
 848 ;;; pathnames, and so there need not be any translation of a wild
 849 ;;; logical pathname to a phyiscal pathname.  So a program that calls
 850 ;;; DIRECTORY on a wild logical pathname is doing something
 851 ;;; non-portable at best.  And if the only sensible semantics for
 852 ;;; DIRECTORY on a wild logical pathname is something like the
 853 ;;; following, it would be just as well if it signaled an error, since
 854 ;;; a program can't possibly rely on the result of an intersection of
 855 ;;; user-defined translations with a file system probe.  (Potentially
 856 ;;; useful kinds of "pathname" that might not support wildcards could
 857 ;;; include pathname hosts that model unqueryable namespaces like HTTP
 858 ;;; URIs, or that model namespaces that it's not convenient to
 859 ;;; investigate, such as the namespace of TCP ports that some network
 860 ;;; host listens on.  I happen to think it a bad idea to try to
 861 ;;; shoehorn such namespaces into a pathnames system, but people
 862 ;;; sometimes claim to want pathnames for these things.)  -- RMK
 863 ;;; 2007-12-31.
 864
 865 (defun pathname-intersections (one two)
 866   (aver (logical-pathname-p one))
 867   (aver (logical-pathname-p two))
 868   (labels
 869       ((intersect-version (one two)
 870          (aver (typep one '(or null (member :newest :wild :unspecific)
 871                             integer)))
 872          (aver (typep two '(or null (member :newest :wild :unspecific)
 873                             integer)))
 874          (cond
 875            ((eq one :wild) two)
 876            ((eq two :wild) one)
 877            ((or (null one) (eq one :unspecific)) two)
 878            ((or (null two) (eq two :unspecific)) one)
 879            ((eql one two) one)
 880            (t nil)))
 881        (intersect-name/type (one two)
 882          (aver (typep one '(or null (member :wild :unspecific) string)))
 883          (aver (typep two '(or null (member :wild :unspecific) string)))
 884          (cond
 885            ((eq one :wild) two)
 886            ((eq two :wild) one)
 887            ((or (null one) (eq one :unspecific)) two)
 888            ((or (null two) (eq two :unspecific)) one)
 889            ((string= one two) one)
 890            (t nil)))
 891        (intersect-directory (one two)
 892          (aver (typep one '(or null (member :wild :unspecific) list)))
 893          (aver (typep two '(or null (member :wild :unspecific) list)))
 894          (cond
 895            ((eq one :wild) two)
 896            ((eq two :wild) one)
 897            ((or (null one) (eq one :unspecific)) two)
 898            ((or (null two) (eq two :unspecific)) one)
 899            (t (aver (eq (car one) (car two)))
 900               (mapcar
 901                (lambda (x) (cons (car one) x))
 902                (intersect-directory-helper (cdr one) (cdr two)))))))
 903     (let ((version (intersect-version
 904                     (pathname-version one) (pathname-version two)))
 905           (name (intersect-name/type
 906                  (pathname-name one) (pathname-name two)))
 907           (type (intersect-name/type
 908                  (pathname-type one) (pathname-type two)))
 909           (host (pathname-host one)))
 910       (mapcar (lambda (d)
 911                 (make-pathname :host host :name name :type type
 912                                :version version :directory d))
 913               (intersect-directory
 914                (pathname-directory one) (pathname-directory two))))))
 915
 916 ;;; FIXME: written as its own function because I (CSR) don't
 917 ;;; understand it, so helping both debuggability and modularity.  In
 918 ;;; case anyone is motivated to rewrite it, it returns a list of
 919 ;;; sublists representing the intersection of the two input directory
 920 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 921 ;;;
 922 ;;; FIXME: Does not work with :UP or :BACK
 923 ;;; FIXME: Does not work with patterns
 924 ;;;
 925 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 926 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 927 ;;; turns out to be worth it.
 928 (defun intersect-directory-helper (one two)
 929   (flet ((simple-intersection (cone ctwo)
 930            (cond
 931              ((eq cone :wild) ctwo)
 932              ((eq ctwo :wild) cone)
 933              (t (aver (typep cone 'string))
 934                 (aver (typep ctwo 'string))
 935                 (if (string= cone ctwo) cone nil)))))
 936     (macrolet
 937         ((loop-possible-wild-inferiors-matches
 938              (lower-bound bounding-sequence order)
 939            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 940              `(let ((,l (length ,bounding-sequence)))
 941                (loop for ,index from ,lower-bound to ,l
 942                 append (mapcar (lambda (,g2)
 943                                  (append
 944                                   (butlast ,bounding-sequence (- ,l ,index))
 945                                   ,g2))
 946                         (mapcar
 947                          (lambda (,g3)
 948                            (append
 949                             (if (eq (car (nthcdr ,index ,bounding-sequence))
 950                                     :wild-inferiors)
 951                                 '(:wild-inferiors)
 952                                 nil) ,g3))
 953                          (intersect-directory-helper
 954                           ,@(if order
 955                                 `((nthcdr ,index one) (cdr two))
 956                                 `((cdr one) (nthcdr ,index two)))))))))))
 957       (cond
 958         ((and (eq (car one) :wild-inferiors)
 959               (eq (car two) :wild-inferiors))
 960          (delete-duplicates
 961           (append (mapcar (lambda (x) (cons :wild-inferiors x))
 962                           (intersect-directory-helper (cdr one) (cdr two)))
 963                   (loop-possible-wild-inferiors-matches 2 one t)
 964                   (loop-possible-wild-inferiors-matches 2 two nil))
 965           :test 'equal))
 966         ((eq (car one) :wild-inferiors)
 967          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
 968                             :test 'equal))
 969         ((eq (car two) :wild-inferiors)
 970          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
 971                             :test 'equal))
 972         ((and (null one) (null two)) (list nil))
 973         ((null one) nil)
 974         ((null two) nil)
 975         (t (and (simple-intersection (car one) (car two))
 976                 (mapcar (lambda (x) (cons (simple-intersection
 977                                            (car one) (car two)) x))
 978                         (intersect-directory-helper (cdr one) (cdr two)))))))))
 979 \f
 980 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
 981   #!+sb-doc
 982   "Test whether the directories containing the specified file
 983   actually exist, and attempt to create them if they do not.
 984   The MODE argument is a CMUCL/SBCL-specific extension to control
 985   the Unix permission bits."
 986   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
 987         (created-p nil))
 988     (when (wild-pathname-p pathname)
 989       (error 'simple-file-error
 990              :format-control "bad place for a wild pathname"
 991              :pathname pathspec))
 992     (let ((dir (pathname-directory pathname)))
 993       (loop for i from 1 upto (length dir)
 994             do (let ((newpath (make-pathname
 995                                :host (pathname-host pathname)
 996                                :device (pathname-device pathname)
 997                                :directory (subseq dir 0 i))))
 998                  (unless (probe-file newpath)
 999                    (let ((namestring (coerce (native-namestring newpath)
1000                                              'string)))
1001                      (when verbose
1002                        (format *standard-output*
1003                                "~&creating directory: ~A~%"
1004                                namestring))
1005                      (sb!unix:unix-mkdir namestring mode)
1006                      (unless (probe-file newpath)
1007                        (restart-case (error
1008                                       'simple-file-error
1009                                       :pathname pathspec
1010                                       :format-control
1011                                       "can't create directory ~A"
1012                                       :format-arguments (list namestring))
1013                          (retry ()
1014                            :report "Retry directory creation."
1015                            (ensure-directories-exist
1016                             pathspec
1017                             :verbose verbose :mode mode))
1018                          (continue ()
1019                            :report
1020                            "Continue as if directory creation was successful."
1021                            nil)))
1022                      (setf created-p t)))))
1023       (values pathspec created-p))))
1024
1025 (/show0 "filesys.lisp 1000")