src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defvar *ignore-wildcards* nil)
  84
  85 (/show0 "filesys.lisp 86")
  86
  87 (defun maybe-make-pattern (namestr start end)
  88   (declare (type simple-string namestr)
  89            (type index start end))
  90   (if *ignore-wildcards*
  91       (subseq namestr start end)
  92       (collect ((pattern))
  93         (let ((quoted nil)
  94               (any-quotes nil)
  95               (last-regular-char nil)
  96               (index start))
  97           (flet ((flush-pending-regulars ()
  98                    (when last-regular-char
  99                      (pattern (if any-quotes
 100                                   (remove-backslashes namestr
 101                                                       last-regular-char
 102                                                       index)
 103                                   (subseq namestr last-regular-char index)))
 104                      (setf any-quotes nil)
 105                      (setf last-regular-char nil))))
 106             (loop
 107               (when (>= index end)
 108                 (return))
 109               (let ((char (schar namestr index)))
 110                 (cond (quoted
 111                        (incf index)
 112                        (setf quoted nil))
 113                       ((char= char #\\)
 114                        (setf quoted t)
 115                        (setf any-quotes t)
 116                        (unless last-regular-char
 117                          (setf last-regular-char index))
 118                        (incf index))
 119                       ((char= char #\?)
 120                        (flush-pending-regulars)
 121                        (pattern :single-char-wild)
 122                        (incf index))
 123                       ((char= char #\*)
 124                        (flush-pending-regulars)
 125                        (pattern :multi-char-wild)
 126                        (incf index))
 127                       ((char= char #\[)
 128                        (flush-pending-regulars)
 129                        (let ((close-bracket
 130                               (position #\] namestr :start index :end end)))
 131                          (unless close-bracket
 132                            (error 'namestring-parse-error
 133                                   :complaint "#\\[ with no corresponding #\\]"
 134                                   :namestring namestr
 135                                   :offset index))
 136                          (pattern (cons :character-set
 137                                         (subseq namestr
 138                                                 (1+ index)
 139                                                 close-bracket)))
 140                          (setf index (1+ close-bracket))))
 141                       (t
 142                        (unless last-regular-char
 143                          (setf last-regular-char index))
 144                        (incf index)))))
 145             (flush-pending-regulars)))
 146         (cond ((null (pattern))
 147                "")
 148               ((null (cdr (pattern)))
 149                (let ((piece (first (pattern))))
 150                  (typecase piece
 151                    ((member :multi-char-wild) :wild)
 152                    (simple-string piece)
 153                    (t
 154                     (make-pattern (pattern))))))
 155               (t
 156                (make-pattern (pattern)))))))
 157
 158 (/show0 "filesys.lisp 160")
 159
 160 (defun extract-name-type-and-version (namestr start end)
 161   (declare (type simple-string namestr)
 162            (type index start end))
 163   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 164                              :from-end t)))
 165     (cond
 166       (last-dot
 167        (values (maybe-make-pattern namestr start last-dot)
 168                (maybe-make-pattern namestr (1+ last-dot) end)
 169                :newest))
 170       (t
 171        (values (maybe-make-pattern namestr start end)
 172                nil
 173                :newest)))))
 174
 175 (/show0 "filesys.lisp 200")
 176
 177 \f
 178 ;;;; wildcard matching stuff
 179
 180 ;;; Return a list of all the Lispy filenames (not including e.g. the
 181 ;;; Unix magic "." and "..") in the directory named by DIRECTORY-NAME.
 182 (defun directory-lispy-filenames (directory-name)
 183   (with-alien ((adlf (* c-string)
 184                      (alien-funcall (extern-alien
 185                                      "alloc_directory_lispy_filenames"
 186                                      (function (* c-string) c-string))
 187                                     directory-name)))
 188     (if (null-alien adlf)
 189         (error 'simple-file-error
 190                :pathname directory-name
 191                :format-control "~@<couldn't read directory ~S: ~2I~_~A~:>"
 192                :format-arguments (list directory-name (strerror)))
 193         (unwind-protect
 194             (c-strings->string-list adlf)
 195           (alien-funcall (extern-alien "free_directory_lispy_filenames"
 196                                        (function void (* c-string)))
 197                          adlf)))))
 198
 199 (/show0 "filesys.lisp 498")
 200
 201 (defmacro !enumerate-matches ((var pathname &optional result
 202                                    &key (verify-existence t)
 203                                    (follow-links t))
 204                               &body body)
 205   `(block nil
 206      (%enumerate-matches (pathname ,pathname)
 207                          ,verify-existence
 208                          ,follow-links
 209                          (lambda (,var) ,@body))
 210      ,result))
 211
 212 (/show0 "filesys.lisp 500")
 213
 214 ;;; Call FUNCTION on matches.
 215 ;;;
 216 ;;; KLUDGE: this assumes that an absolute pathname is indicated to the
 217 ;;; operating system by having a directory separator as the first
 218 ;;; character in the directory part.  This is true for Win32 pathnames
 219 ;;; and for Unix pathnames, but it isn't true for LispM pathnames (and
 220 ;;; their bastard offspring, logical pathnames.  Also it assumes that
 221 ;;; Unix pathnames have an empty or :unspecific device, and that
 222 ;;; windows drive letters are the only kinds of non-empty/:UNSPECIFIC
 223 ;;; devices.
 224 (defun %enumerate-matches (pathname verify-existence follow-links function)
 225   (/noshow0 "entering %ENUMERATE-MATCHES")
 226   (when (pathname-type pathname)
 227     (unless (pathname-name pathname)
 228       (error "cannot supply a type without a name:~%  ~S" pathname)))
 229   (when (and (integerp (pathname-version pathname))
 230              (member (pathname-type pathname) '(nil :unspecific)))
 231     (error "cannot supply a version without a type:~%  ~S" pathname))
 232   (let ((host (pathname-host pathname))
 233         (device (pathname-device pathname))
 234         (directory (pathname-directory pathname)))
 235     (/noshow0 "computed HOST and DIRECTORY")
 236     (let* ((dirstring (if directory
 237                           (ecase (first directory)
 238                             (:absolute (host-unparse-directory-separator host))
 239                             (:relative ""))
 240                           ""))
 241            (devstring (if (and device (not (eq device :unspecific)))
 242                           (concatenate 'simple-string (string device) (string #\:))
 243                           ""))
 244            (headstring (concatenate 'simple-string devstring dirstring)))
 245       (if directory
 246           (%enumerate-directories headstring (rest directory) pathname
 247                                   verify-existence follow-links nil function)
 248           (%enumerate-files headstring pathname verify-existence function)))))
 249
 250 ;;; Call FUNCTION on directories.
 251 (defun %enumerate-directories (head tail pathname verify-existence
 252                                follow-links nodes function
 253                                &aux (host (pathname-host pathname)))
 254   (declare (simple-string head))
 255   #!+win32
 256   (setf follow-links nil)
 257   (macrolet ((unix-xstat (name)
 258                `(if follow-links
 259                     (sb!unix:unix-stat ,name)
 260                     (sb!unix:unix-lstat ,name)))
 261              (with-directory-node-noted ((head) &body body)
 262                `(multiple-value-bind (res dev ino mode)
 263                     (unix-xstat ,head)
 264                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 265                                       sb!unix:s-ifdir))
 266                     (let ((nodes (cons (cons dev ino) nodes)))
 267                       ,@body))))
 268              (with-directory-node-removed ((head) &body body)
 269                `(multiple-value-bind (res dev ino mode)
 270                     (unix-xstat ,head)
 271                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 272                                       sb!unix:s-ifdir))
 273                     (let ((nodes (remove (cons dev ino) nodes :test #'equal)))
 274                       ,@body)))))
 275     (if tail
 276         (let ((piece (car tail)))
 277           (etypecase piece
 278             (simple-string
 279              (let ((head (concatenate 'string head piece)))
 280                (with-directory-node-noted (head)
 281                  (%enumerate-directories
 282                   (concatenate 'string head
 283                                (host-unparse-directory-separator host))
 284                   (cdr tail) pathname
 285                   verify-existence follow-links
 286                   nodes function))))
 287             ((member :wild-inferiors)
 288              ;; now with extra error case handling from CLHS
 289              ;; 19.2.2.4.3 -- CSR, 2004-01-24
 290              (when (member (cadr tail) '(:up :back))
 291                (error 'simple-file-error
 292                       :pathname pathname
 293                       :format-control "~@<invalid use of ~S after :WILD-INFERIORS~@:>."
 294                       :format-arguments (list (cadr tail))))
 295              (%enumerate-directories head (rest tail) pathname
 296                                      verify-existence follow-links
 297                                      nodes function)
 298              (dolist (name (directory-lispy-filenames head))
 299                (let ((subdir (concatenate 'string head name)))
 300                  (multiple-value-bind (res dev ino mode)
 301                      (unix-xstat subdir)
 302                    (declare (type (or fixnum null) mode))
 303                    (when (and res (eql (logand mode sb!unix:s-ifmt)
 304                                        sb!unix:s-ifdir))
 305                      (unless (dolist (dir nodes nil)
 306                                (when (and (eql (car dir) dev)
 307                                           #!+win32 ;; KLUDGE
 308                                           (not (zerop ino))
 309                                           (eql (cdr dir) ino))
 310                                  (return t)))
 311                        (let ((nodes (cons (cons dev ino) nodes))
 312                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 313                          (%enumerate-directories subdir tail pathname
 314                                                  verify-existence follow-links
 315                                                  nodes function))))))))
 316             ((or pattern (member :wild))
 317              (dolist (name (directory-lispy-filenames head))
 318                (when (or (eq piece :wild) (pattern-matches piece name))
 319                  (let ((subdir (concatenate 'string head name)))
 320                    (multiple-value-bind (res dev ino mode)
 321                        (unix-xstat subdir)
 322                      (declare (type (or fixnum null) mode))
 323                      (when (and res
 324                                 (eql (logand mode sb!unix:s-ifmt)
 325                                      sb!unix:s-ifdir))
 326                        (let ((nodes (cons (cons dev ino) nodes))
 327                              (subdir (concatenate 'string subdir (host-unparse-directory-separator host))))
 328                          (%enumerate-directories subdir (rest tail) pathname
 329                                                  verify-existence follow-links
 330                                                  nodes function))))))))
 331           ((member :up)
 332            (when (string= head (host-unparse-directory-separator host))
 333              (error 'simple-file-error
 334                     :pathname pathname
 335                     :format-control "~@<invalid use of :UP after :ABSOLUTE.~@:>"))
 336            (with-directory-node-removed (head)
 337              (let ((head (concatenate 'string head "..")))
 338                (with-directory-node-noted (head)
 339                  (%enumerate-directories (concatenate 'string head (host-unparse-directory-separator host))
 340                                          (rest tail) pathname
 341                                          verify-existence follow-links
 342                                          nodes function)))))
 343           ((member :back)
 344            ;; :WILD-INFERIORS is handled above, so the only case here
 345            ;; should be (:ABSOLUTE :BACK)
 346            (aver (string= head (host-unparse-directory-separator host)))
 347            (error 'simple-file-error
 348                   :pathname pathname
 349                   :format-control "~@<invalid use of :BACK after :ABSOLUTE.~@:>"))))
 350         (%enumerate-files head pathname verify-existence function))))
 351
 352 ;;; Call FUNCTION on files.
 353 (defun %enumerate-files (directory pathname verify-existence function)
 354   (declare (simple-string directory))
 355   (/noshow0 "entering %ENUMERATE-FILES")
 356   (let ((name (%pathname-name pathname))
 357         (type (%pathname-type pathname))
 358         (version (%pathname-version pathname)))
 359     (/noshow0 "computed NAME, TYPE, and VERSION")
 360     (cond ((member name '(nil :unspecific))
 361            (/noshow0 "UNSPECIFIC, more or less")
 362            (let ((directory (coerce directory 'string)))
 363              (when (or (not verify-existence)
 364                        (sb!unix:unix-file-kind directory))
 365                (funcall function directory))))
 366           ((or (pattern-p name)
 367                (pattern-p type)
 368                (eq name :wild)
 369                (eq type :wild))
 370            (/noshow0 "WILD, more or less")
 371            ;; I IGNORE-ERRORS here just because the original CMU CL
 372            ;; code did. I think the intent is that it's not an error
 373            ;; to request matches to a wild pattern when no matches
 374            ;; exist, but I haven't tried to figure out whether
 375            ;; everything is kosher. (E.g. what if we try to match a
 376            ;; wildcard but we don't have permission to read one of the
 377            ;; relevant directories?) -- WHN 2001-04-17
 378            (dolist (complete-filename (ignore-errors
 379                                         (directory-lispy-filenames directory)))
 380              (multiple-value-bind
 381                  (file-name file-type file-version)
 382                  (let ((*ignore-wildcards* t))
 383                    (extract-name-type-and-version
 384                     complete-filename 0 (length complete-filename)))
 385                (when (and (components-match file-name name)
 386                           (components-match file-type type)
 387                           (components-match file-version version))
 388                  (funcall function
 389                           (concatenate 'string
 390                                        directory
 391                                        complete-filename))))))
 392           (t
 393            (/noshow0 "default case")
 394            (let ((file (concatenate 'string directory name)))
 395              (/noshow "computed basic FILE")
 396              (unless (or (null type) (eq type :unspecific))
 397                (/noshow0 "tweaking FILE for more-or-less-:UNSPECIFIC case")
 398                (setf file (concatenate 'string file "." type)))
 399              (unless (member version '(nil :newest :wild :unspecific))
 400                (/noshow0 "tweaking FILE for more-or-less-:WILD case")
 401                (setf file (concatenate 'string file "."
 402                                        (quick-integer-to-string version))))
 403              (/noshow0 "finished possibly tweaking FILE")
 404              (when (or (not verify-existence)
 405                        (sb!unix:unix-file-kind file t))
 406                (/noshow0 "calling FUNCTION on FILE")
 407                (funcall function file)))))))
 408
 409 (/noshow0 "filesys.lisp 603")
 410
 411 ;;; FIXME: Why do we need this?
 412 (defun quick-integer-to-string (n)
 413   (declare (type integer n))
 414   (cond ((not (fixnump n))
 415          (write-to-string n :base 10 :radix nil))
 416         ((zerop n) "0")
 417         ((eql n 1) "1")
 418         ((minusp n)
 419          (concatenate 'simple-base-string "-"
 420                       (the simple-base-string (quick-integer-to-string (- n)))))
 421         (t
 422          (do* ((len (1+ (truncate (integer-length n) 3)))
 423                (res (make-string len :element-type 'base-char))
 424                (i (1- len) (1- i))
 425                (q n)
 426                (r 0))
 427               ((zerop q)
 428                (incf i)
 429                (replace res res :start2 i :end2 len)
 430                (%shrink-vector res (- len i)))
 431            (declare (simple-string res)
 432                     (fixnum len i r q))
 433            (multiple-value-setq (q r) (truncate q 10))
 434            (setf (schar res i) (schar "0123456789" r))))))
 435 \f
 436 ;;;; UNIX-NAMESTRING
 437
 438 (defun empty-relative-pathname-spec-p (x)
 439   (or (equal x "")
 440       (and (pathnamep x)
 441            (or (equal (pathname-directory x) '(:relative))
 442                ;; KLUDGE: I'm not sure this second check should really
 443                ;; have to be here. But on sbcl-0.6.12.7,
 444                ;; (PATHNAME-DIRECTORY (PATHNAME "")) is NIL, and
 445                ;; (PATHNAME "") seems to act like an empty relative
 446                ;; pathname, so in order to work with that, I test
 447                ;; for NIL here. -- WHN 2001-05-18
 448                (null (pathname-directory x)))
 449            (null (pathname-name x))
 450            (null (pathname-type x)))
 451       ;; (The ANSI definition of "pathname specifier" has
 452       ;; other cases, but none of them seem to admit the possibility
 453       ;; of being empty and relative.)
 454       ))
 455
 456 ;;; Convert PATHNAME into a string that can be used with UNIX system
 457 ;;; calls, or return NIL if no match is found. Wild-cards are expanded.
 458 ;;;
 459 ;;; FIXME: apart from the error checking (for wildness and for
 460 ;;; existence) and conversion to physical pathanme, this is redundant
 461 ;;; with UNPARSE-NATIVE-UNIX-NAMESTRING; one should probably be
 462 ;;; written in terms of the other.
 463 ;;;
 464 ;;; FIXME: actually this (I think) works not just for Unix.
 465 (defun unix-namestring (pathname-spec &optional (for-input t))
 466   (let* ((namestring (physicalize-pathname (merge-pathnames pathname-spec)))
 467          (matches nil)) ; an accumulator for actual matches
 468     (when (wild-pathname-p namestring)
 469       (error 'simple-file-error
 470              :pathname namestring
 471              :format-control "bad place for a wild pathname"))
 472     (!enumerate-matches (match namestring nil :verify-existence for-input)
 473                         (push match matches))
 474     (case (length matches)
 475       (0 nil)
 476       (1 (first matches))
 477       (t (bug "!ENUMERATE-MATCHES returned more than one match on a non-wild pathname")))))
 478 \f
 479 ;;;; TRUENAME and PROBE-FILE
 480
 481 ;;; This is only trivially different from PROBE-FILE, which is silly
 482 ;;; but ANSI.
 483 (defun truename (pathname)
 484   #!+sb-doc
 485   "Return the pathname for the actual file described by PATHNAME.
 486 An error of type FILE-ERROR is signalled if no such file exists, or the
 487 pathname is wild.
 488
 489 Under Unix, the TRUENAME of a broken symlink is considered to be the name of
 490 the broken symlink itself."
 491   (let ((result (probe-file pathname)))
 492     (unless result
 493       (error 'simple-file-error
 494              :pathname pathname
 495              :format-control "The file ~S does not exist."
 496              :format-arguments (list (namestring pathname))))
 497     result))
 498
 499 (defun probe-file (pathname)
 500   #!+sb-doc
 501   "Return a pathname which is the truename of the file if it exists, or NIL
 502 otherwise. An error of type FILE-ERROR is signaled if pathname is wild."
 503   (let* ((defaulted-pathname (merge-pathnames
 504                               pathname
 505                               (sane-default-pathname-defaults)))
 506          (namestring (unix-namestring defaulted-pathname t)))
 507     (when (and namestring (sb!unix:unix-file-kind namestring t))
 508       (let ((trueishname (sb!unix:unix-resolve-links namestring)))
 509         (when trueishname
 510           (let* ((*ignore-wildcards* t)
 511                  (name (simplify-namestring
 512                         trueishname
 513                         (pathname-host defaulted-pathname))))
 514             (if (eq (sb!unix:unix-file-kind name) :directory)
 515                 ;; FIXME: this might work, but it's ugly.
 516                 (pathname (concatenate 'string name "/"))
 517                 (pathname name))))))))
 518 \f
 519 ;;;; miscellaneous other operations
 520
 521 (/show0 "filesys.lisp 700")
 522
 523 (defun rename-file (file new-name)
 524   #!+sb-doc
 525   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 526   file, then the associated file is renamed."
 527   (let* ((original (truename file))
 528          (original-namestring (unix-namestring original t))
 529          (new-name (merge-pathnames new-name original))
 530          (new-namestring (unix-namestring new-name nil)))
 531     (unless new-namestring
 532       (error 'simple-file-error
 533              :pathname new-name
 534              :format-control "~S can't be created."
 535              :format-arguments (list new-name)))
 536     (multiple-value-bind (res error)
 537         (sb!unix:unix-rename original-namestring new-namestring)
 538       (unless res
 539         (error 'simple-file-error
 540                :pathname new-name
 541                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 542                                 ~I~_~A~:>"
 543                :format-arguments (list original new-name (strerror error))))
 544       (when (streamp file)
 545         (file-name file new-name))
 546       (values new-name original (truename new-name)))))
 547
 548 (defun delete-file (file)
 549   #!+sb-doc
 550   "Delete the specified FILE."
 551   (let ((namestring (unix-namestring file t)))
 552     (when (streamp file)
 553       (close file :abort t))
 554     (unless namestring
 555       (error 'simple-file-error
 556              :pathname file
 557              :format-control "~S doesn't exist."
 558              :format-arguments (list file)))
 559     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 560       (unless res
 561         (simple-file-perror "couldn't delete ~A" namestring err))))
 562   t)
 563 \f
 564 (defun ensure-trailing-slash (string)
 565   (let ((last-char (char string (1- (length string)))))
 566          (if (or (eql last-char #\/)
 567                  #!+win32
 568                  (eql last-char #\\))
 569              string
 570              (concatenate 'string string "/"))))
 571
 572 (defun sbcl-homedir-pathname ()
 573   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 574     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 575     (when sbcl-home
 576       (parse-native-namestring
 577        (ensure-trailing-slash sbcl-home)))))
 578
 579 ;;; (This is an ANSI Common Lisp function.)
 580 (defun user-homedir-pathname (&optional host)
 581   #!+sb-doc
 582   "Return the home directory of the user as a pathname. If the HOME
 583 environment variable has been specified, the directory it designates
 584 is returned; otherwise obtains the home directory from the operating
 585 system."
 586   (declare (ignore host))
 587   (parse-native-namestring
 588    (ensure-trailing-slash
 589     (if (posix-getenv "HOME")
 590         (posix-getenv "HOME")
 591         #!-win32
 592         (sb!unix:uid-homedir (sb!unix:unix-getuid))
 593         #!+win32
 594         ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 595         (return-from user-homedir-pathname
 596           (sb!win32::get-folder-pathname sb!win32::csidl_profile))))))
 597
 598 (defun file-write-date (file)
 599   #!+sb-doc
 600   "Return file's creation date, or NIL if it doesn't exist.
 601  An error of type file-error is signaled if file is a wild pathname"
 602   (let ((name (unix-namestring file t)))
 603     (when name
 604       (multiple-value-bind
 605             (res dev ino mode nlink uid gid rdev size atime mtime)
 606           (sb!unix:unix-stat name)
 607         (declare (ignore dev ino mode nlink uid gid rdev size atime))
 608         (when res
 609           (+ unix-to-universal-time mtime))))))
 610
 611 (defun file-author (file)
 612   #!+sb-doc
 613   "Return the file author as a string, or NIL if the author cannot be
 614  determined. Signal an error of type FILE-ERROR if FILE doesn't exist,
 615  or FILE is a wild pathname."
 616   (let ((name (unix-namestring (pathname file) t)))
 617     (unless name
 618       (error 'simple-file-error
 619              :pathname file
 620              :format-control "~S doesn't exist."
 621              :format-arguments (list file)))
 622     (multiple-value-bind (winp dev ino mode nlink uid)
 623         (sb!unix:unix-stat name)
 624       (declare (ignore dev ino mode nlink))
 625       (and winp (sb!unix:uid-username uid)))))
 626 \f
 627 ;;;; DIRECTORY
 628
 629 (/show0 "filesys.lisp 800")
 630
 631 ;;; NOTE: There is a fair amount of hair below that is probably not
 632 ;;; strictly necessary.
 633 ;;;
 634 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 635 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 636 ;;; did not translate the logical pathname at all, but instead treated
 637 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 638 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 639 ;;; which is fine as far as it goes, but not very interesting, and
 640 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 641 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 642 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 643 ;;; exists, of course).
 644 ;;;
 645 ;;; So, the interpretation that I am pushing is for all pathnames
 646 ;;; matching the input pathname to be queried.  This means that we
 647 ;;; need to compute the intersection of the input pathname and the
 648 ;;; logical host FROM translations, and then translate the resulting
 649 ;;; pathname using the host to the TO translation; this treatment is
 650 ;;; recursively invoked until we get a physical pathname, whereupon
 651 ;;; our physical DIRECTORY implementation takes over.
 652
 653 ;;; FIXME: this is an incomplete implementation.  It only works when
 654 ;;; both are logical pathnames (which is OK, because that's the only
 655 ;;; case when we call it), but there are other pitfalls as well: see
 656 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 657 ;;; pattern handling.
 658 (defun pathname-intersections (one two)
 659   (aver (logical-pathname-p one))
 660   (aver (logical-pathname-p two))
 661   (labels
 662       ((intersect-version (one two)
 663          (aver (typep one '(or null (member :newest :wild :unspecific)
 664                             integer)))
 665          (aver (typep two '(or null (member :newest :wild :unspecific)
 666                             integer)))
 667          (cond
 668            ((eq one :wild) two)
 669            ((eq two :wild) one)
 670            ((or (null one) (eq one :unspecific)) two)
 671            ((or (null two) (eq two :unspecific)) one)
 672            ((eql one two) one)
 673            (t nil)))
 674        (intersect-name/type (one two)
 675          (aver (typep one '(or null (member :wild :unspecific) string)))
 676          (aver (typep two '(or null (member :wild :unspecific) string)))
 677          (cond
 678            ((eq one :wild) two)
 679            ((eq two :wild) one)
 680            ((or (null one) (eq one :unspecific)) two)
 681            ((or (null two) (eq two :unspecific)) one)
 682            ((string= one two) one)
 683            (t nil)))
 684        (intersect-directory (one two)
 685          (aver (typep one '(or null (member :wild :unspecific) list)))
 686          (aver (typep two '(or null (member :wild :unspecific) list)))
 687          (cond
 688            ((eq one :wild) two)
 689            ((eq two :wild) one)
 690            ((or (null one) (eq one :unspecific)) two)
 691            ((or (null two) (eq two :unspecific)) one)
 692            (t (aver (eq (car one) (car two)))
 693               (mapcar
 694                (lambda (x) (cons (car one) x))
 695                (intersect-directory-helper (cdr one) (cdr two)))))))
 696     (let ((version (intersect-version
 697                     (pathname-version one) (pathname-version two)))
 698           (name (intersect-name/type
 699                  (pathname-name one) (pathname-name two)))
 700           (type (intersect-name/type
 701                  (pathname-type one) (pathname-type two)))
 702           (host (pathname-host one)))
 703       (mapcar (lambda (d)
 704                 (make-pathname :host host :name name :type type
 705                                :version version :directory d))
 706               (intersect-directory
 707                (pathname-directory one) (pathname-directory two))))))
 708
 709 ;;; FIXME: written as its own function because I (CSR) don't
 710 ;;; understand it, so helping both debuggability and modularity.  In
 711 ;;; case anyone is motivated to rewrite it, it returns a list of
 712 ;;; sublists representing the intersection of the two input directory
 713 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 714 ;;;
 715 ;;; FIXME: Does not work with :UP or :BACK
 716 ;;; FIXME: Does not work with patterns
 717 ;;;
 718 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 719 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 720 ;;; turns out to be worth it.
 721 (defun intersect-directory-helper (one two)
 722   (flet ((simple-intersection (cone ctwo)
 723            (cond
 724              ((eq cone :wild) ctwo)
 725              ((eq ctwo :wild) cone)
 726              (t (aver (typep cone 'string))
 727                 (aver (typep ctwo 'string))
 728                 (if (string= cone ctwo) cone nil)))))
 729     (macrolet
 730         ((loop-possible-wild-inferiors-matches
 731              (lower-bound bounding-sequence order)
 732            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 733              `(let ((,l (length ,bounding-sequence)))
 734                (loop for ,index from ,lower-bound to ,l
 735                 append (mapcar (lambda (,g2)
 736                                  (append
 737                                   (butlast ,bounding-sequence (- ,l ,index))
 738                                   ,g2))
 739                         (mapcar
 740                          (lambda (,g3)
 741                            (append
 742                             (if (eq (car (nthcdr ,index ,bounding-sequence))
 743                                     :wild-inferiors)
 744                                 '(:wild-inferiors)
 745                                 nil) ,g3))
 746                          (intersect-directory-helper
 747                           ,@(if order
 748                                 `((nthcdr ,index one) (cdr two))
 749                                 `((cdr one) (nthcdr ,index two)))))))))))
 750       (cond
 751         ((and (eq (car one) :wild-inferiors)
 752               (eq (car two) :wild-inferiors))
 753          (delete-duplicates
 754           (append (mapcar (lambda (x) (cons :wild-inferiors x))
 755                           (intersect-directory-helper (cdr one) (cdr two)))
 756                   (loop-possible-wild-inferiors-matches 2 one t)
 757                   (loop-possible-wild-inferiors-matches 2 two nil))
 758           :test 'equal))
 759         ((eq (car one) :wild-inferiors)
 760          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
 761                             :test 'equal))
 762         ((eq (car two) :wild-inferiors)
 763          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
 764                             :test 'equal))
 765         ((and (null one) (null two)) (list nil))
 766         ((null one) nil)
 767         ((null two) nil)
 768         (t (and (simple-intersection (car one) (car two))
 769                 (mapcar (lambda (x) (cons (simple-intersection
 770                                            (car one) (car two)) x))
 771                         (intersect-directory-helper (cdr one) (cdr two)))))))))
 772
 773 (defun directory (pathname &key)
 774   #!+sb-doc
 775   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 776    given pathname. Note that the interaction between this ANSI-specified
 777    TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
 778    means this function can sometimes return files which don't have the same
 779    directory as PATHNAME."
 780   (let (;; We create one entry in this hash table for each truename,
 781         ;; as an asymptotically efficient way of removing duplicates
 782         ;; (which can arise when e.g. multiple symlinks map to the
 783         ;; same truename).
 784         (truenames (make-hash-table :test #'equal))
 785         ;; FIXME: Possibly this MERGE-PATHNAMES call should only
 786         ;; happen once we get a physical pathname.
 787         (merged-pathname (merge-pathnames pathname)))
 788     (labels ((do-physical-directory (pathname)
 789                (aver (not (logical-pathname-p pathname)))
 790                (!enumerate-matches (match pathname)
 791                  (let* ((*ignore-wildcards* t)
 792                         ;; FIXME: Why not TRUENAME?  As reported by
 793                         ;; Milan Zamazal sbcl-devel 2003-10-05, using
 794                         ;; TRUENAME causes a race condition whereby
 795                         ;; removal of a file during the directory
 796                         ;; operation causes an error.  It's not clear
 797                         ;; what the right thing to do is, though.  --
 798                         ;; CSR, 2003-10-13
 799                         (truename (probe-file match)))
 800                    (when truename
 801                      (setf (gethash (namestring truename) truenames)
 802                            truename)))))
 803              (do-directory (pathname)
 804                (if (logical-pathname-p pathname)
 805                    (let ((host (intern-logical-host (pathname-host pathname))))
 806                      (dolist (x (logical-host-canon-transls host))
 807                        (destructuring-bind (from to) x
 808                          (let ((intersections
 809                                 (pathname-intersections pathname from)))
 810                            (dolist (p intersections)
 811                              (do-directory (translate-pathname p from to)))))))
 812                    (do-physical-directory pathname))))
 813       (do-directory merged-pathname))
 814     (mapcar #'cdr
 815             ;; Sorting isn't required by the ANSI spec, but sorting
 816             ;; into some canonical order seems good just on the
 817             ;; grounds that the implementation should have repeatable
 818             ;; behavior when possible.
 819             (sort (loop for name being each hash-key in truenames
 820                      using (hash-value truename)
 821                      collect (cons name truename))
 822                   #'string<
 823                   :key #'car))))
 824 \f
 825 (/show0 "filesys.lisp 899")
 826
 827 ;;; predicate to order pathnames by; goes by name
 828 (defun pathname-order (x y)
 829   (let ((xn (%pathname-name x))
 830         (yn (%pathname-name y)))
 831     (if (and xn yn)
 832         (let ((res (string-lessp xn yn)))
 833           (cond ((not res) nil)
 834                 ((= res (length (the simple-string xn))) t)
 835                 ((= res (length (the simple-string yn))) nil)
 836                 (t t)))
 837         xn)))
 838 \f
 839 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
 840   #!+sb-doc
 841   "Test whether the directories containing the specified file
 842   actually exist, and attempt to create them if they do not.
 843   The MODE argument is a CMUCL/SBCL-specific extension to control
 844   the Unix permission bits."
 845   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
 846         (created-p nil))
 847     (when (wild-pathname-p pathname)
 848       (error 'simple-file-error
 849              :format-control "bad place for a wild pathname"
 850              :pathname pathspec))
 851     (let ((dir (pathname-directory pathname)))
 852       (loop for i from 1 upto (length dir)
 853             do (let ((newpath (make-pathname
 854                                :host (pathname-host pathname)
 855                                :device (pathname-device pathname)
 856                                :directory (subseq dir 0 i))))
 857                  (unless (probe-file newpath)
 858                    (let ((namestring (coerce (namestring newpath) 'string)))
 859                      (when verbose
 860                        (format *standard-output*
 861                                "~&creating directory: ~A~%"
 862                                namestring))
 863                      (sb!unix:unix-mkdir namestring mode)
 864                      (unless (probe-file namestring)
 865                        (restart-case (error 'simple-file-error
 866                                             :pathname pathspec
 867                                             :format-control "can't create directory ~A"
 868                                             :format-arguments (list namestring))
 869                          (retry ()
 870                            :report "Retry directory creation."
 871                            (ensure-directories-exist pathspec :verbose verbose :mode mode))
 872                          (continue ()
 873                            :report "Continue as if directory creation was successful."
 874                            nil)))
 875                      (setf created-p t)))))
 876       (values pathspec created-p))))
 877
 878 (/show0 "filesys.lisp 1000")