src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-centric, but with
   2 ;;;; differences between Unix and Win32 papered over.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; Unix pathname host support
  16
  17 ;;; FIXME: the below shouldn't really be here, but in documentation
  18 ;;; (chapter 19 makes a lot of requirements for documenting
  19 ;;; implementation-dependent decisions), but anyway it's probably not
  20 ;;; what we currently do.
  21 ;;;
  22 ;;; Unix namestrings have the following format:
  23 ;;;
  24 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  25 ;;; directory := [ "/" ] { file "/" }*
  26 ;;; file := [^/]*
  27 ;;; type := "." [^/.]*
  28 ;;; version := "." ([0-9]+ | "*")
  29 ;;;
  30 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  31 ;;; parsed as either just the file specified or as specifying the
  32 ;;; file, type, and version. Therefore, we use the following rules
  33 ;;; when confronted with an ambiguous file.type.version string:
  34 ;;;
  35 ;;; - If the first character is a dot, it's part of the file. It is not
  36 ;;; considered a dot in the following rules.
  37 ;;;
  38 ;;; - Otherwise, the last dot separates the file and the type.
  39 ;;;
  40 ;;; Wildcard characters:
  41 ;;;
  42 ;;; If the directory, file, type components contain any of the
  43 ;;; following characters, it is considered part of a wildcard pattern
  44 ;;; and has the following meaning.
  45 ;;;
  46 ;;; ? - matches any one character
  47 ;;; * - matches any zero or more characters.
  48 ;;; [abc] - matches any of a, b, or c.
  49 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  50 ;;;   (FIXME: no it doesn't)
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start) :element-type 'character))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (%shrink-vector result dst)))
  82
  83 (defun maybe-make-pattern (namestr start end)
  84   (declare (type simple-string namestr)
  85            (type index start end))
  86   (collect ((pattern))
  87     (let ((quoted nil)
  88           (any-quotes nil)
  89           (last-regular-char nil)
  90           (index start))
  91       (flet ((flush-pending-regulars ()
  92                (when last-regular-char
  93                  (pattern (if any-quotes
  94                               (remove-backslashes namestr
  95                                                   last-regular-char
  96                                                   index)
  97                               (subseq namestr last-regular-char index)))
  98                  (setf any-quotes nil)
  99                  (setf last-regular-char nil))))
 100         (loop
 101           (when (>= index end)
 102             (return))
 103           (let ((char (schar namestr index)))
 104             (cond (quoted
 105                    (incf index)
 106                    (setf quoted nil))
 107                   ((char= char #\\)
 108                    (setf quoted t)
 109                    (setf any-quotes t)
 110                    (unless last-regular-char
 111                      (setf last-regular-char index))
 112                    (incf index))
 113                   ((char= char #\?)
 114                    (flush-pending-regulars)
 115                    (pattern :single-char-wild)
 116                    (incf index))
 117                   ((char= char #\*)
 118                    (flush-pending-regulars)
 119                    (pattern :multi-char-wild)
 120                    (incf index))
 121                   ((char= char #\[)
 122                    (flush-pending-regulars)
 123                    (let ((close-bracket
 124                           (position #\] namestr :start index :end end)))
 125                      (unless close-bracket
 126                        (error 'namestring-parse-error
 127                               :complaint "#\\[ with no corresponding #\\]"
 128                               :namestring namestr
 129                               :offset index))
 130                      (pattern (cons :character-set
 131                                     (subseq namestr
 132                                             (1+ index)
 133                                             close-bracket)))
 134                      (setf index (1+ close-bracket))))
 135                   (t
 136                    (unless last-regular-char
 137                      (setf last-regular-char index))
 138                    (incf index)))))
 139         (flush-pending-regulars)))
 140     (cond ((null (pattern))
 141            "")
 142           ((null (cdr (pattern)))
 143            (let ((piece (first (pattern))))
 144              (typecase piece
 145                ((member :multi-char-wild) :wild)
 146                (simple-string piece)
 147                (t
 148                 (make-pattern (pattern))))))
 149           (t
 150            (make-pattern (pattern))))))
 151
 152 (defun unparse-physical-piece (thing)
 153   (etypecase thing
 154     ((member :wild) "*")
 155     (simple-string
 156      (let* ((srclen (length thing))
 157             (dstlen srclen))
 158        (dotimes (i srclen)
 159          (case (schar thing i)
 160            ((#\* #\? #\[)
 161             (incf dstlen))))
 162        (let ((result (make-string dstlen))
 163              (dst 0))
 164          (dotimes (src srclen)
 165            (let ((char (schar thing src)))
 166              (case char
 167                ((#\* #\? #\[)
 168                 (setf (schar result dst) #\\)
 169                 (incf dst)))
 170              (setf (schar result dst) char)
 171              (incf dst)))
 172          result)))
 173     (pattern
 174      (with-output-to-string (s)
 175        (dolist (piece (pattern-pieces thing))
 176          (etypecase piece
 177            (simple-string
 178             (write-string piece s))
 179            (symbol
 180             (ecase piece
 181               (:multi-char-wild
 182                (write-string "*" s))
 183               (:single-char-wild
 184                (write-string "?" s))))
 185            (cons
 186             (case (car piece)
 187               (:character-set
 188                (write-string "[" s)
 189                (write-string (cdr piece) s)
 190                (write-string "]" s))
 191               (t
 192                (error "invalid pattern piece: ~S" piece))))))))))
 193
 194 (defun make-matcher (piece)
 195   (cond ((eq piece :wild)
 196          (constantly t))
 197         ((typep piece 'pattern)
 198          (lambda (other)
 199            (when (stringp other)
 200              (pattern-matches piece other))))
 201         (t
 202          (lambda (other)
 203            (equal piece other)))))
 204
 205 (/show0 "filesys.lisp 160")
 206
 207 (defun extract-name-type-and-version (namestr start end)
 208   (declare (type simple-string namestr)
 209            (type index start end))
 210   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 211                              :from-end t)))
 212     (cond
 213       (last-dot
 214        (values (maybe-make-pattern namestr start last-dot)
 215                (maybe-make-pattern namestr (1+ last-dot) end)
 216                :newest))
 217       (t
 218        (values (maybe-make-pattern namestr start end)
 219                nil
 220                :newest)))))
 221
 222 (/show0 "filesys.lisp 200")
 223
 224 \f
 225 ;;;; Grabbing the kind of file when we have a namestring.
 226 (defun native-file-kind (namestring)
 227   (multiple-value-bind (existsp errno ino mode)
 228       #!-win32
 229       (sb!unix:unix-lstat namestring)
 230       #!+win32
 231       (sb!unix:unix-stat namestring)
 232     (declare (ignore errno ino))
 233     (when existsp
 234       (let ((ifmt (logand mode sb!unix:s-ifmt)))
 235        (case ifmt
 236          (#.sb!unix:s-ifreg :file)
 237          (#.sb!unix:s-ifdir :directory)
 238          #!-win32
 239          (#.sb!unix:s-iflnk :symlink)
 240          (t :special))))))
 241 \f
 242 ;;;; TRUENAME, PROBE-FILE, FILE-AUTHOR, FILE-WRITE-DATE.
 243
 244 ;;; Rewritten in 12/2007 by RMK, replacing 13+ year old CMU code that
 245 ;;; made a mess of things in order to support search lists (which SBCL
 246 ;;; has never had).  These are now all relatively straightforward
 247 ;;; wrappers around stat(2) and realpath(2), with the same basic logic
 248 ;;; in all cases.  The wrinkles to be aware of:
 249 ;;;
 250 ;;; * SBCL defines the truename of an existing, dangling or
 251 ;;;   self-referring symlink to be the symlink itself.
 252 ;;; * The old version of PROBE-FILE merged the pathspec against
 253 ;;;   *DEFAULT-PATHNAME-DEFAULTS* twice, and so lost when *D-P-D*
 254 ;;;   was a relative pathname.  Even if the case where *D-P-D* is a
 255 ;;;   relative pathname is problematic, there's no particular reason
 256 ;;;   to get that wrong, so let's try not to.
 257 ;;; * Note that while stat(2) is probably atomic, getting the truename
 258 ;;;   for a filename involves poking all over the place, and so is
 259 ;;;   subject to race conditions if other programs mutate the file
 260 ;;;   system while we're resolving symlinks.  So it's not implausible for
 261 ;;;   realpath(3) to fail even if stat(2) succeeded.  There's nothing
 262 ;;;   obvious we can do about this, however.
 263 ;;; * Windows' apparent analogue of realpath(3) is called
 264 ;;;   GetFullPathName, and it's a bit less useful than realpath(3).
 265 ;;;   In particular, while realpath(3) errors in case the file doesn't
 266 ;;;   exist, GetFullPathName seems to return a filename in all cases.
 267 ;;;   As realpath(3) is not atomic anyway, we only ever call it when
 268 ;;;   we think a file exists, so just be careful when rewriting this
 269 ;;;   routine.
 270 ;;;
 271 ;;; Given a pathname designator, some quality to query for, return one
 272 ;;; of a pathname, a universal time, or a string (a file-author), or
 273 ;;; NIL.  QUERY-FOR may be one of :TRUENAME, :EXISTENCE, :WRITE-DATE,
 274 ;;; :AUTHOR.  If ERRORP is false, return NIL in case the file system
 275 ;;; returns an error code; otherwise, signal an error.  Accepts
 276 ;;; logical pathnames, too (but never returns LPNs).  For internal
 277 ;;; use.
 278 (defun query-file-system (pathspec query-for &optional (errorp t))
 279   (let ((pathname (translate-logical-pathname
 280                    (merge-pathnames
 281                     (pathname pathspec)
 282                     (sane-default-pathname-defaults)))))
 283     (when (wild-pathname-p pathname)
 284       (error 'simple-file-error
 285              :pathname pathname
 286              :format-control "~@<can't find the ~A of wild pathname ~A~
 287                               (physicalized from ~A).~:>"
 288              :format-arguments (list query-for pathname pathspec)))
 289     (flet ((fail (note-format pathname errno)
 290              (if errorp
 291                  (simple-file-perror note-format pathname errno)
 292                  (return-from query-file-system nil))))
 293       (let ((filename (native-namestring pathname :as-file t)))
 294         (multiple-value-bind (existsp errno ino mode nlink uid gid rdev size
 295                                       atime mtime)
 296             (sb!unix:unix-stat filename)
 297           (declare (ignore ino nlink gid rdev size atime
 298                            #!+win32 uid))
 299           (if existsp
 300               (case query-for
 301                 (:existence (nth-value
 302                              0
 303                              (parse-native-namestring
 304                               filename
 305                               (pathname-host pathname)
 306                               (sane-default-pathname-defaults)
 307                               :as-directory (eql (logand mode sb!unix:s-ifmt)
 308                                                  sb!unix:s-ifdir))))
 309                 (:truename (nth-value
 310                             0
 311                             (parse-native-namestring
 312                              ;; Note: in case the file is stat'able, POSIX
 313                              ;; realpath(3) gets us a canonical absolute
 314                              ;; filename, even if the post-merge PATHNAME
 315                              ;; is not absolute...
 316                              (multiple-value-bind (realpath errno)
 317                                  (sb!unix:unix-realpath filename)
 318                                (if realpath
 319                                    realpath
 320                                    (fail "couldn't resolve ~A" filename errno)))
 321                              (pathname-host pathname)
 322                              (sane-default-pathname-defaults)
 323                              ;; ... but without any trailing slash.
 324                              :as-directory (eql (logand  mode sb!unix:s-ifmt)
 325                                                 sb!unix:s-ifdir))))
 326                 (:author
 327                  #!-win32
 328                  (sb!unix:uid-username uid))
 329                 (:write-date (+ unix-to-universal-time mtime)))
 330               (progn
 331                 ;; SBCL has for many years had a policy that a pathname
 332                 ;; that names an existing, dangling or self-referential
 333                 ;; symlink denotes the symlink itself.  stat(2) fails
 334                 ;; and sets errno to ENOENT or ELOOP respectively, but
 335                 ;; we must distinguish cases where the symlink exists
 336                 ;; from ones where there's a loop in the apparent
 337                 ;; containing directory.
 338                 #!-win32
 339                 (multiple-value-bind (linkp ignore ino mode nlink uid gid rdev
 340                                             size atime mtime)
 341                     (sb!unix:unix-lstat filename)
 342                   (declare (ignore ignore ino mode nlink gid rdev size atime))
 343                   (when (and (or (= errno sb!unix:enoent)
 344                                  (= errno sb!unix:eloop))
 345                              linkp)
 346                     (return-from query-file-system
 347                       (case query-for
 348                         (:existence
 349                          ;; We do this reparse so as to return a
 350                          ;; normalized pathname.
 351                          (parse-native-namestring
 352                           filename (pathname-host pathname)))
 353                         (:truename
 354                          ;; So here's a trick: since lstat succeded,
 355                          ;; FILENAME exists, so its directory exists and
 356                          ;; only the non-directory part is loopy.  So
 357                          ;; let's resolve FILENAME's directory part with
 358                          ;; realpath(3), in order to get a canonical
 359                          ;; absolute name for the directory, and then
 360                          ;; return a pathname having PATHNAME's name,
 361                          ;; type, and version, but the rest from the
 362                          ;; truename of the directory.  Since we turned
 363                          ;; PATHNAME into FILENAME "as a file", FILENAME
 364                          ;; does not end in a slash, and so we get the
 365                          ;; directory part of FILENAME by reparsing
 366                          ;; FILENAME and masking off its name, type, and
 367                          ;; version bits.  But note not to call ourselves
 368                          ;; recursively, because we don't want to
 369                          ;; re-merge against *DEFAULT-PATHNAME-DEFAULTS*,
 370                          ;; since PATHNAME may be a relative pathname.
 371                          (merge-pathnames
 372                           (nth-value
 373                            0
 374                            (parse-native-namestring
 375                             (multiple-value-bind (realpath errno)
 376                                 (sb!unix:unix-realpath
 377                                  (native-namestring
 378                                   (make-pathname
 379                                    :name :unspecific
 380                                    :type :unspecific
 381                                    :version :unspecific
 382                                    :defaults (parse-native-namestring
 383                                               filename
 384                                               (pathname-host pathname)
 385                                               (sane-default-pathname-defaults)))))
 386                               (if realpath
 387                                   realpath
 388                                   (fail "couldn't resolve ~A" filename errno)))
 389                             (pathname-host pathname)
 390                             (sane-default-pathname-defaults)
 391                             :as-directory t))
 392                           pathname))
 393                         (:author (sb!unix:uid-username uid))
 394                         (:write-date (+ unix-to-universal-time mtime))))))
 395                 ;; If we're still here, the file doesn't exist; error.
 396                 (fail
 397                  (format nil "failed to find the ~A of ~~A" query-for)
 398                  pathspec errno))))))))
 399
 400
 401 (defun probe-file (pathspec)
 402   #!+sb-doc
 403   "Return the truename of PATHSPEC if the truename can be found,
 404 or NIL otherwise.  See TRUENAME for more information."
 405   (query-file-system pathspec :truename nil))
 406
 407 (defun truename (pathspec)
 408   #!+sb-doc
 409   "If PATHSPEC is a pathname that names an existing file, return
 410 a pathname that denotes a canonicalized name for the file.  If
 411 pathspec is a stream associated with a file, return a pathname
 412 that denotes a canonicalized name for the file associated with
 413 the stream.
 414
 415 An error of type FILE-ERROR is signalled if no such file exists
 416 or if the file system is such that a canonicalized file name
 417 cannot be determined or if the pathname is wild.
 418
 419 Under Unix, the TRUENAME of a symlink that links to itself or to
 420 a file that doesn't exist is considered to be the name of the
 421 broken symlink itself."
 422   ;; Note that eventually this routine might be different for streams
 423   ;; than for other pathname designators.
 424   (if (streamp pathspec)
 425       (query-file-system pathspec :truename)
 426       (query-file-system pathspec :truename)))
 427
 428 (defun file-author (pathspec)
 429   #!+sb-doc
 430   "Return the author of the file specified by PATHSPEC. Signal an
 431 error of type FILE-ERROR if no such file exists, or if PATHSPEC
 432 is a wild pathname."
 433   (query-file-system pathspec :author))
 434
 435 (defun file-write-date (pathspec)
 436   #!+sb-doc
 437   "Return the write date of the file specified by PATHSPEC.
 438 An error of type FILE-ERROR is signaled if no such file exists,
 439 or if PATHSPEC is a wild pathname."
 440   (query-file-system pathspec :write-date))
 441 \f
 442 ;;;; miscellaneous other operations
 443
 444 (/show0 "filesys.lisp 700")
 445
 446 (defun rename-file (file new-name)
 447   #!+sb-doc
 448   "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
 449   file, then the associated file is renamed."
 450   (let* ((original (truename file))
 451          (original-namestring (native-namestring original :as-file t))
 452          (new-name (merge-pathnames new-name original))
 453          (new-namestring (native-namestring (physicalize-pathname new-name)
 454                                             :as-file t)))
 455     (unless new-namestring
 456       (error 'simple-file-error
 457              :pathname new-name
 458              :format-control "~S can't be created."
 459              :format-arguments (list new-name)))
 460     (multiple-value-bind (res error)
 461         (sb!unix:unix-rename original-namestring new-namestring)
 462       (unless res
 463         (error 'simple-file-error
 464                :pathname new-name
 465                :format-control "~@<couldn't rename ~2I~_~A ~I~_to ~2I~_~A: ~
 466                                 ~I~_~A~:>"
 467                :format-arguments (list original new-name (strerror error))))
 468       (when (streamp file)
 469         (file-name file new-name))
 470       (values new-name original (truename new-name)))))
 471
 472 (defun delete-file (file)
 473   #!+sb-doc
 474   "Delete the specified FILE."
 475   (let* ((truename (probe-file file))
 476          (namestring (when truename
 477                        (native-namestring truename :as-file t))))
 478     (when (streamp file)
 479       (close file :abort t))
 480     (unless namestring
 481       (error 'simple-file-error
 482              :pathname file
 483              :format-control "~S doesn't exist."
 484              :format-arguments (list file)))
 485     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 486       (unless res
 487         (simple-file-perror "couldn't delete ~A" namestring err))))
 488   t)
 489 \f
 490 (defun sbcl-homedir-pathname ()
 491   (let ((sbcl-home (posix-getenv "SBCL_HOME")))
 492     ;; SBCL_HOME isn't set for :EXECUTABLE T embedded cores
 493     (when (and sbcl-home (not (string= sbcl-home "")))
 494       (parse-native-namestring sbcl-home
 495                                #!-win32 sb!impl::*unix-host*
 496                                #!+win32 sb!impl::*win32-host*
 497                                *default-pathname-defaults*
 498                                :as-directory t))))
 499
 500 ;;; (This is an ANSI Common Lisp function.)
 501 (defun user-homedir-pathname (&optional host)
 502   #!+sb-doc
 503   "Return the home directory of the user as a pathname. If the HOME
 504 environment variable has been specified, the directory it designates
 505 is returned; otherwise obtains the home directory from the operating
 506 system."
 507   (declare (ignore host))
 508   (let ((env-home (posix-getenv "HOME")))
 509     (values
 510      (parse-native-namestring
 511       (if (and env-home (not (string= env-home "")))
 512           env-home
 513           #!-win32
 514           (sb!unix:uid-homedir (sb!unix:unix-getuid))
 515           #!+win32
 516           ;; Needs to bypass PARSE-NATIVE-NAMESTRING & ENSURE-TRAILING-SLASH
 517           ;; What?! -- RMK, 2007-12-31
 518           (return-from user-homedir-pathname
 519             (sb!win32::get-folder-pathname sb!win32::csidl_profile)))
 520       #!-win32 sb!impl::*unix-host*
 521       #!+win32 sb!impl::*win32-host*
 522       *default-pathname-defaults*
 523       :as-directory t))))
 524
 525 \f
 526 ;;;; DIRECTORY
 527
 528 (defun directory (pathspec &key (resolve-symlinks t))
 529   #!+sb-doc
 530   "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
 531 given pathname. Note that the interaction between this ANSI-specified
 532 TRUENAMEing and the semantics of the Unix filesystem (symbolic links..) means
 533 this function can sometimes return files which don't have the same directory
 534 as PATHNAME. If :RESOLVE-SYMLINKS is NIL, don't resolve symbolic links in
 535 matching filenames."
 536   (let (;; We create one entry in this hash table for each truename,
 537         ;; as an asymptotically efficient way of removing duplicates
 538         ;; (which can arise when e.g. multiple symlinks map to the
 539         ;; same truename).
 540         (truenames (make-hash-table :test #'equal)))
 541     (labels ((record (pathname)
 542                (let ((truename (if resolve-symlinks
 543                                    ;; FIXME: Why not not TRUENAME?  As reported by
 544                                    ;; Milan Zamazal sbcl-devel 2003-10-05, using
 545                                    ;; TRUENAME causes a race condition whereby
 546                                    ;; removal of a file during the directory
 547                                    ;; operation causes an error.  It's not clear
 548                                    ;; what the right thing to do is, though.  --
 549                                    ;; CSR, 2003-10-13
 550                                    (query-file-system pathname :truename nil)
 551                                    (query-file-system pathname :existence nil))))
 552                  (when truename
 553                    (setf (gethash (namestring truename) truenames)
 554                          truename))))
 555              (do-physical-pathnames (pathname)
 556                (aver (not (logical-pathname-p pathname)))
 557                (let* (;; KLUDGE: Since we don't canonize pathnames on construction,
 558                       ;; we really have to do it here to get #p"foo/." mean the same
 559                       ;; as #p"foo/./".
 560                       (pathname (canonicalize-pathname pathname))
 561                       (name (pathname-name pathname))
 562                       (type (pathname-type pathname))
 563                       ;; KLUDGE: We want #p"/foo" to match #p"/foo/,
 564                       ;; so cobble up a directory name component from
 565                       ;; name and type -- just take care with "*.*"!
 566                       (dirname (if (and (eq :wild name) (eq :wild type))
 567                                    "*"
 568                                    (with-output-to-string (s)
 569                                      (when name
 570                                        (write-string (unparse-physical-piece name) s))
 571                                      (when type
 572                                        (write-string "." s)
 573                                        (write-string (unparse-physical-piece type) s)))))
 574                       (dir (maybe-make-pattern dirname 0 (length dirname)))
 575                       (match-name (make-matcher name))
 576                       (match-type (make-matcher type))
 577                       (match-dir (make-matcher dir)))
 578                  (map-matching-directories
 579                   (if (or name type)
 580                       (lambda (directory)
 581                         (map-matching-files #'record
 582                                             directory
 583                                             match-name
 584                                             match-type
 585                                             match-dir))
 586                       #'record)
 587                   pathname)))
 588              (do-pathnames (pathname)
 589                (if (logical-pathname-p pathname)
 590                    (let ((host (intern-logical-host (pathname-host pathname))))
 591                      (dolist (x (logical-host-canon-transls host))
 592                        (destructuring-bind (from to) x
 593                          (let ((intersections
 594                                 (pathname-intersections pathname from)))
 595                            (dolist (p intersections)
 596                              (do-pathnames (translate-pathname p from to)))))))
 597                    (do-physical-pathnames pathname))))
 598       (declare (truly-dynamic-extent #'record))
 599       (do-pathnames (merge-pathnames pathspec)))
 600     (mapcar #'cdr
 601             ;; Sorting isn't required by the ANSI spec, but sorting into some
 602             ;; canonical order seems good just on the grounds that the
 603             ;; implementation should have repeatable behavior when possible.
 604             (sort (loop for namestring being each hash-key in truenames
 605                         using (hash-value truename)
 606                         collect (cons namestring truename))
 607                   #'string<
 608                   :key #'car))))
 609
 610 (defun canonicalize-pathname (pathname)
 611   ;; We're really only interested in :UNSPECIFIC -> NIL, :BACK and :UP,
 612   ;; and dealing with #p"foo/.." and #p"foo/."
 613   (labels ((simplify (piece)
 614              (unless (eq :unspecific piece)
 615                piece))
 616            (canonicalize-directory (directory)
 617              (let (pieces)
 618                (dolist (piece directory)
 619                  (if (and pieces (member piece '(:back :up)))
 620                      ;; FIXME: We should really canonicalize when we construct
 621                      ;; pathnames. This is just wrong.
 622                      (case (car pieces)
 623                        ((:absolute :wild-inferiors)
 624                         (error 'simple-file-error
 625                                :format-control "Invalid use of ~S after ~S."
 626                                :format-arguments (list piece (car pieces))
 627                                :pathname pathname))
 628                        ((:relative :up :back)
 629                         (push piece pieces))
 630                        (t
 631                         (pop pieces)))
 632                      (push piece pieces)))
 633                (nreverse pieces))))
 634     (let ((name (simplify (pathname-name pathname)))
 635           (type (simplify (pathname-type pathname)))
 636           (dir (canonicalize-directory (pathname-directory pathname))))
 637       (cond ((equal "." name)
 638              (cond ((not type)
 639                     (make-pathname :name nil :defaults pathname))
 640                    ((equal "" type)
 641                     (make-pathname :name nil
 642                                    :type nil
 643                                    :directory (butlast dir)
 644                                    :defaults pathname))))
 645             (t
 646              (make-pathname :name name :type type
 647                             :directory dir
 648                             :defaults pathname))))))
 649
 650 ;;; Given a native namestring, provides a WITH-HASH-TABLE-ITERATOR style
 651 ;;; interface to mapping over namestrings of entries in the corresponding
 652 ;;; directory.
 653 (defmacro with-native-directory-iterator ((iterator namestring &key errorp) &body body)
 654   (with-unique-names (one-iter)
 655     `(dx-flet
 656          ((iterate (,one-iter)
 657             (declare (type function ,one-iter))
 658             (macrolet ((,iterator ()
 659                          `(funcall ,',one-iter)))
 660               ,@body)))
 661        (call-with-native-directory-iterator #'iterate ,namestring ,errorp))))
 662
 663 (defun call-with-native-directory-iterator (function namestring errorp)
 664   (declare (type (or null string) namestring)
 665            (function function))
 666   (let (dp)
 667     (when namestring
 668       (dx-flet
 669           ((one-iter ()
 670              (tagbody
 671               :next
 672                 (let ((ent (sb!unix:unix-readdir dp nil)))
 673                   (when ent
 674                     (let ((name (sb!unix:unix-dirent-name ent)))
 675                       (when name
 676                         (cond ((equal "." name)
 677                                (go :next))
 678                               ((equal ".." name)
 679                                (go :next))
 680                               (t
 681                                (return-from one-iter name))))))))))
 682         (unwind-protect
 683              (progn
 684                (setf dp (sb!unix:unix-opendir namestring errorp))
 685                (when dp
 686                  (funcall function #'one-iter)))
 687           (when dp
 688             (sb!unix:unix-closedir dp nil)))))))
 689
 690 ;;; This is our core directory access interface that we use to implement
 691 ;;; DIRECTORY.
 692 (defun map-directory (function directory &key (files t) (directories t) (errorp t))
 693   #!+sb-doc
 694   "Call FUNCTION with the pathname for each entry in DIRECTORY as follows: if
 695 FILES is true (the default), FUNCTION is called for each file in the
 696 directory; if DIRECTORIES is true (the default), FUNCTION is called for each
 697 subdirectory. If ERRORP is true (the default) signal an error if DIRECTORY
 698 does not exist, cannot be read, etc.
 699
 700 On platforms supporting symbolic links the decision to call FUNCTION with its
 701 pathname depends on the resolution of the link: if it points to a directory,
 702 it is considered a directory entry. Whether it is considered a file or a
 703 directory, the provided pathname is not fully resolved, but rather names the
 704 symbolic link as an immediate child of DIRECTORY.
 705
 706 Experimental: interface subject to change."
 707   (declare (pathname-designator directory))
 708   (let* ((fun (%coerce-callable-to-fun function))
 709          (physical (physicalize-pathname directory))
 710          ;; Not QUERY-FILE-SYSTEM :EXISTENCE, since it doesn't work on Windows
 711          ;; network shares.
 712          (realname (sb!unix:unix-realpath (native-namestring physical :as-file t)))
 713          (canonical (if realname
 714                         (parse-native-namestring realname
 715                                                  (pathname-host physical)
 716                                                  (sane-default-pathname-defaults)
 717                                                  :as-directory t)
 718                         (return-from map-directory nil)))
 719          (dirname (native-namestring canonical)))
 720     (flet ((map-it (name dirp)
 721              (funcall fun
 722                       (merge-pathnames (parse-native-namestring
 723                                         name nil physical :as-directory dirp)
 724                                        physical))))
 725       (with-native-directory-iterator (next dirname :errorp errorp)
 726        (loop for name = (next)
 727              while name
 728              do (let* ((full (concatenate 'string dirname name))
 729                        (kind (native-file-kind full)))
 730                   (when kind
 731                     (case kind
 732                       (:directory
 733                        (when directories
 734                          (map-it name t)))
 735                       (:symlink
 736                        (let* ((tmpname (merge-pathnames
 737                                         (parse-native-namestring
 738                                          name nil physical :as-directory nil)
 739                                         physical))
 740                               (truename (query-file-system tmpname :truename nil)))
 741                          (if (or (not truename)
 742                                  (or (pathname-name truename) (pathname-type truename)))
 743                              (when files
 744                                (funcall fun tmpname))
 745                              (when directories
 746                                (map-it name t)))))
 747                       (t
 748                        ;; Anything else parses as a file.
 749                        (when files
 750                          (map-it name nil)))))))))))
 751
 752 ;;; Part of DIRECTORY: implements matching the directory spec. Calls FUNCTION
 753 ;;; with all DIRECTORIES that match the directory portion of PATHSPEC.
 754 (defun map-matching-directories (function pathspec)
 755   (let* ((dir (pathname-directory pathspec))
 756          (length (length dir))
 757          (wild (position-if (lambda (elt)
 758                               (or (eq :wild elt) (typep elt 'pattern)))
 759                             dir))
 760          (wild-inferiors (position :wild-inferiors dir))
 761          (end (cond ((and wild wild-inferiors)
 762                      (min wild wild-inferiors))
 763                     (t
 764                      (or wild wild-inferiors length))))
 765          (rest (subseq dir end))
 766          (starting-point (make-pathname :directory (subseq dir 0 end)
 767                                         :device (pathname-device pathspec)
 768                                         :host (pathname-host pathspec)
 769                                         :name nil
 770                                         :type nil
 771                                         :version nil)))
 772     (cond (wild-inferiors
 773            (map-wild-inferiors function rest starting-point))
 774           (wild
 775            (map-wild function rest starting-point))
 776           (t
 777            ;; Nothing wild -- the directory matches itself.
 778            (funcall function starting-point))))
 779   nil)
 780
 781 (defun last-directory-piece (pathname)
 782   (car (last (pathname-directory pathname))))
 783
 784 ;;; Part of DIRECTORY: implements iterating over a :WILD or pattern component
 785 ;;; in the directory spec.
 786 (defun map-wild (function more directory)
 787   (let ((this (pop more))
 788         (next (car more)))
 789     (flet ((cont (subdirectory)
 790              (cond ((not more)
 791                     ;; end of the line
 792                     (funcall function subdirectory))
 793                    ((or (eq :wild next) (typep next 'pattern))
 794                     (lambda (pathname)
 795                       (map-wild function more pathname)))
 796                    ((eq :wild-inferiors next)
 797                     (lambda (pathname)
 798                       (map-wild-inferiors function more pathname)))
 799                    (t
 800                     (lambda (pathname)
 801                       (let ((this (pathname-directory pathname)))
 802                         (when (equal next (car (last this)))
 803                           (map-matching-directories
 804                            function
 805                            (make-pathname :directory (append this more)
 806                                           :defaults pathname)))))))))
 807       (map-directory
 808        (if (eq :wild this)
 809            #'cont
 810            (lambda (sub)
 811              (when (pattern-matches this (last-directory-piece sub))
 812                (funcall #'cont sub))))
 813        directory
 814        :files nil
 815        :directories t
 816        :errorp nil))))
 817
 818 ;;; Part of DIRECTORY: implements iterating over a :WILD-INFERIORS component
 819 ;;; in the directory spec.
 820 (defun map-wild-inferiors (function more directory)
 821   (loop while (member (car more) '(:wild :wild-inferiors))
 822         do (pop more))
 823   (let ((next (car more))
 824         (rest (cdr more)))
 825     (unless more
 826       (funcall function directory))
 827     (map-directory
 828      (cond ((not more)
 829             (lambda (pathname)
 830               (funcall function pathname)
 831               (map-wild-inferiors function more pathname)))
 832            (t
 833             (lambda (pathname)
 834               (let ((this (pathname-directory pathname)))
 835                 (when (equal next (car (last this)))
 836                   (map-matching-directories
 837                    function
 838                    (make-pathname :directory (append this rest)
 839                                   :defaults pathname)))
 840                 (map-wild-inferiors function more pathname)))))
 841      directory
 842      :files nil
 843      :directories t
 844      :errorp nil)))
 845
 846 ;;; Part of DIRECTORY: implements iterating over files in a directory, and matching
 847 ;;; them.
 848 (defun map-matching-files (function directory match-name match-type match-dir)
 849   (map-directory
 850    (lambda (file)
 851      (let ((pname (pathname-name file))
 852            (ptype (pathname-type file)))
 853        (when (if (or pname ptype)
 854                  (and (funcall match-name pname) (funcall match-type ptype))
 855                  (funcall match-dir (last-directory-piece file)))
 856          (funcall function file))))
 857    directory
 858    :files t
 859    :directories t
 860    :errorp nil))
 861
 862 ;;; NOTE: There is a fair amount of hair below that is probably not
 863 ;;; strictly necessary.
 864 ;;;
 865 ;;; The issue is the following: what does (DIRECTORY "SYS:*;") mean?
 866 ;;; Until 2004-01, SBCL's behaviour was unquestionably wrong, as it
 867 ;;; did not translate the logical pathname at all, but instead treated
 868 ;;; it as a physical one.  Other Lisps seem to to treat this call as
 869 ;;; equivalent to (DIRECTORY (TRANSLATE-LOGICAL-PATHNAME "SYS:*;")),
 870 ;;; which is fine as far as it goes, but not very interesting, and
 871 ;;; arguably counterintuitive.  (PATHNAME-MATCH-P "SYS:SRC;" "SYS:*;")
 872 ;;; is true, so why should "SYS:SRC;" not show up in the call to
 873 ;;; DIRECTORY?  (assuming the physical pathname corresponding to it
 874 ;;; exists, of course).
 875 ;;;
 876 ;;; So, the interpretation that I am pushing is for all pathnames
 877 ;;; matching the input pathname to be queried.  This means that we
 878 ;;; need to compute the intersection of the input pathname and the
 879 ;;; logical host FROM translations, and then translate the resulting
 880 ;;; pathname using the host to the TO translation; this treatment is
 881 ;;; recursively invoked until we get a physical pathname, whereupon
 882 ;;; our physical DIRECTORY implementation takes over.
 883
 884 ;;; FIXME: this is an incomplete implementation.  It only works when
 885 ;;; both are logical pathnames (which is OK, because that's the only
 886 ;;; case when we call it), but there are other pitfalls as well: see
 887 ;;; the DIRECTORY-HELPER below for some, but others include a lack of
 888 ;;; pattern handling.
 889
 890 ;;; The above was written by CSR, I (RMK) believe.  The argument that
 891 ;;; motivates the interpretation is faulty, however: PATHNAME-MATCH-P
 892 ;;; returns true for (PATHNAME-MATCH-P #P"/tmp/*/" #P"/tmp/../"), but
 893 ;;; the latter pathname is not in the result of DIRECTORY on the
 894 ;;; former.  Indeed, if DIRECTORY were constrained to return the
 895 ;;; truename for every pathname for which PATHNAME-MATCH-P returned
 896 ;;; true and which denoted a filename that named an existing file,
 897 ;;; (DIRECTORY #P"/tmp/**/") would be required to list every file on a
 898 ;;; Unix system, since any file can be named as though it were "below"
 899 ;;; /tmp, given the dotdot entries.  So I think the strongest
 900 ;;; "consistency" we can define between PATHNAME-MATCH-P and DIRECTORY
 901 ;;; is that PATHNAME-MATCH-P returns true of everything DIRECTORY
 902 ;;; returns, but not vice versa.
 903
 904 ;;; In any case, even if the motivation were sound, DIRECTORY on a
 905 ;;; wild logical pathname has no portable semantics.  I see nothing in
 906 ;;; ANSI that requires implementations to support wild physical
 907 ;;; pathnames, and so there need not be any translation of a wild
 908 ;;; logical pathname to a phyiscal pathname.  So a program that calls
 909 ;;; DIRECTORY on a wild logical pathname is doing something
 910 ;;; non-portable at best.  And if the only sensible semantics for
 911 ;;; DIRECTORY on a wild logical pathname is something like the
 912 ;;; following, it would be just as well if it signaled an error, since
 913 ;;; a program can't possibly rely on the result of an intersection of
 914 ;;; user-defined translations with a file system probe.  (Potentially
 915 ;;; useful kinds of "pathname" that might not support wildcards could
 916 ;;; include pathname hosts that model unqueryable namespaces like HTTP
 917 ;;; URIs, or that model namespaces that it's not convenient to
 918 ;;; investigate, such as the namespace of TCP ports that some network
 919 ;;; host listens on.  I happen to think it a bad idea to try to
 920 ;;; shoehorn such namespaces into a pathnames system, but people
 921 ;;; sometimes claim to want pathnames for these things.)  -- RMK
 922 ;;; 2007-12-31.
 923
 924 (defun pathname-intersections (one two)
 925   (aver (logical-pathname-p one))
 926   (aver (logical-pathname-p two))
 927   (labels
 928       ((intersect-version (one two)
 929          (aver (typep one '(or null (member :newest :wild :unspecific)
 930                             integer)))
 931          (aver (typep two '(or null (member :newest :wild :unspecific)
 932                             integer)))
 933          (cond
 934            ((eq one :wild) two)
 935            ((eq two :wild) one)
 936            ((or (null one) (eq one :unspecific)) two)
 937            ((or (null two) (eq two :unspecific)) one)
 938            ((eql one two) one)
 939            (t nil)))
 940        (intersect-name/type (one two)
 941          (aver (typep one '(or null (member :wild :unspecific) string)))
 942          (aver (typep two '(or null (member :wild :unspecific) string)))
 943          (cond
 944            ((eq one :wild) two)
 945            ((eq two :wild) one)
 946            ((or (null one) (eq one :unspecific)) two)
 947            ((or (null two) (eq two :unspecific)) one)
 948            ((string= one two) one)
 949            (t nil)))
 950        (intersect-directory (one two)
 951          (aver (typep one '(or null (member :wild :unspecific) list)))
 952          (aver (typep two '(or null (member :wild :unspecific) list)))
 953          (cond
 954            ((eq one :wild) two)
 955            ((eq two :wild) one)
 956            ((or (null one) (eq one :unspecific)) two)
 957            ((or (null two) (eq two :unspecific)) one)
 958            (t (aver (eq (car one) (car two)))
 959               (mapcar
 960                (lambda (x) (cons (car one) x))
 961                (intersect-directory-helper (cdr one) (cdr two)))))))
 962     (let ((version (intersect-version
 963                     (pathname-version one) (pathname-version two)))
 964           (name (intersect-name/type
 965                  (pathname-name one) (pathname-name two)))
 966           (type (intersect-name/type
 967                  (pathname-type one) (pathname-type two)))
 968           (host (pathname-host one)))
 969       (mapcar (lambda (d)
 970                 (make-pathname :host host :name name :type type
 971                                :version version :directory d))
 972               (intersect-directory
 973                (pathname-directory one) (pathname-directory two))))))
 974
 975 ;;; FIXME: written as its own function because I (CSR) don't
 976 ;;; understand it, so helping both debuggability and modularity.  In
 977 ;;; case anyone is motivated to rewrite it, it returns a list of
 978 ;;; sublists representing the intersection of the two input directory
 979 ;;; paths (excluding the initial :ABSOLUTE or :RELATIVE).
 980 ;;;
 981 ;;; FIXME: Does not work with :UP or :BACK
 982 ;;; FIXME: Does not work with patterns
 983 ;;;
 984 ;;; FIXME: PFD suggests replacing this implementation with a DFA
 985 ;;; conversion of a NDFA.  Find out (a) what this means and (b) if it
 986 ;;; turns out to be worth it.
 987 (defun intersect-directory-helper (one two)
 988   (flet ((simple-intersection (cone ctwo)
 989            (cond
 990              ((eq cone :wild) ctwo)
 991              ((eq ctwo :wild) cone)
 992              (t (aver (typep cone 'string))
 993                 (aver (typep ctwo 'string))
 994                 (if (string= cone ctwo) cone nil)))))
 995     (macrolet
 996         ((loop-possible-wild-inferiors-matches
 997              (lower-bound bounding-sequence order)
 998            (let ((index (gensym)) (g2 (gensym)) (g3 (gensym)) (l (gensym)))
 999              `(let ((,l (length ,bounding-sequence)))
1000                (loop for ,index from ,lower-bound to ,l
1001                 append (mapcar (lambda (,g2)
1002                                  (append
1003                                   (butlast ,bounding-sequence (- ,l ,index))
1004                                   ,g2))
1005                         (mapcar
1006                          (lambda (,g3)
1007                            (append
1008                             (if (eq (car (nthcdr ,index ,bounding-sequence))
1009                                     :wild-inferiors)
1010                                 '(:wild-inferiors)
1011                                 nil) ,g3))
1012                          (intersect-directory-helper
1013                           ,@(if order
1014                                 `((nthcdr ,index one) (cdr two))
1015                                 `((cdr one) (nthcdr ,index two)))))))))))
1016       (cond
1017         ((and (eq (car one) :wild-inferiors)
1018               (eq (car two) :wild-inferiors))
1019          (delete-duplicates
1020           (append (mapcar (lambda (x) (cons :wild-inferiors x))
1021                           (intersect-directory-helper (cdr one) (cdr two)))
1022                   (loop-possible-wild-inferiors-matches 2 one t)
1023                   (loop-possible-wild-inferiors-matches 2 two nil))
1024           :test 'equal))
1025         ((eq (car one) :wild-inferiors)
1026          (delete-duplicates (loop-possible-wild-inferiors-matches 0 two nil)
1027                             :test 'equal))
1028         ((eq (car two) :wild-inferiors)
1029          (delete-duplicates (loop-possible-wild-inferiors-matches 0 one t)
1030                             :test 'equal))
1031         ((and (null one) (null two)) (list nil))
1032         ((null one) nil)
1033         ((null two) nil)
1034         (t (and (simple-intersection (car one) (car two))
1035                 (mapcar (lambda (x) (cons (simple-intersection
1036                                            (car one) (car two)) x))
1037                         (intersect-directory-helper (cdr one) (cdr two)))))))))
1038 \f
1039 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
1040   #!+sb-doc
1041   "Test whether the directories containing the specified file
1042   actually exist, and attempt to create them if they do not.
1043   The MODE argument is a CMUCL/SBCL-specific extension to control
1044   the Unix permission bits."
1045   (let ((pathname (physicalize-pathname (merge-pathnames (pathname pathspec))))
1046         (created-p nil))
1047     (when (wild-pathname-p pathname)
1048       (error 'simple-file-error
1049              :format-control "bad place for a wild pathname"
1050              :pathname pathspec))
1051     (let ((dir (pathname-directory pathname)))
1052       (loop for i from 1 upto (length dir)
1053             do (let ((newpath (make-pathname
1054                                :host (pathname-host pathname)
1055                                :device (pathname-device pathname)
1056                                :directory (subseq dir 0 i))))
1057                  (unless (probe-file newpath)
1058                    (let ((namestring (coerce (native-namestring newpath)
1059                                              'string)))
1060                      (when verbose
1061                        (format *standard-output*
1062                                "~&creating directory: ~A~%"
1063                                namestring))
1064                      (sb!unix:unix-mkdir namestring mode)
1065                      (unless (probe-file newpath)
1066                        (restart-case (error
1067                                       'simple-file-error
1068                                       :pathname pathspec
1069                                       :format-control
1070                                       "can't create directory ~A"
1071                                       :format-arguments (list namestring))
1072                          (retry ()
1073                            :report "Retry directory creation."
1074                            (ensure-directories-exist
1075                             pathspec
1076                             :verbose verbose :mode mode))
1077                          (continue ()
1078                            :report
1079                            "Continue as if directory creation was successful."
1080                            nil)))
1081                      (setf created-p t)))))
1082       (values pathspec created-p))))
1083
1084 (/show0 "filesys.lisp 1000")