src/code/filesys.lisp

   1 ;;;; file system interface functions -- fairly Unix-specific
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; Unix pathname host support
  15
  16 ;;; Unix namestrings have the following format:
  17 ;;;
  18 ;;; namestring := [ directory ] [ file [ type [ version ]]]
  19 ;;; directory := [ "/" | search-list ] { file "/" }*
  20 ;;; search-list := [^:/]*:
  21 ;;; file := [^/]*
  22 ;;; type := "." [^/.]*
  23 ;;; version := "." ([0-9]+ | "*")
  24 ;;;
  25 ;;; FIXME: Search lists are no longer supported.
  26 ;;;
  27 ;;; Note: this grammar is ambiguous. The string foo.bar.5 can be
  28 ;;; parsed as either just the file specified or as specifying the
  29 ;;; file, type, and version. Therefore, we use the following rules
  30 ;;; when confronted with an ambiguous file.type.version string:
  31 ;;;
  32 ;;; - If the first character is a dot, it's part of the file. It is not
  33 ;;; considered a dot in the following rules.
  34 ;;;
  35 ;;; - If there is only one dot, it separates the file and the type.
  36 ;;;
  37 ;;; - If there are multiple dots and the stuff following the last dot
  38 ;;; is a valid version, then that is the version and the stuff between
  39 ;;; the second to last dot and the last dot is the type.
  40 ;;;
  41 ;;; Wildcard characters:
  42 ;;;
  43 ;;; If the directory, file, type components contain any of the
  44 ;;; following characters, it is considered part of a wildcard pattern
  45 ;;; and has the following meaning.
  46 ;;;
  47 ;;; ? - matches any character
  48 ;;; * - matches any zero or more characters.
  49 ;;; [abc] - matches any of a, b, or c.
  50 ;;; {str1,str2,...,strn} - matches any of str1, str2, ..., or strn.
  51 ;;;
  52 ;;; Any of these special characters can be preceded by a backslash to
  53 ;;; cause it to be treated as a regular character.
  54 (defun remove-backslashes (namestr start end)
  55   #!+sb-doc
  56   "Remove any occurrences of #\\ from the string because we've already
  57    checked for whatever they may have protected."
  58   (declare (type simple-base-string namestr)
  59            (type index start end))
  60   (let* ((result (make-string (- end start)))
  61          (dst 0)
  62          (quoted nil))
  63     (do ((src start (1+ src)))
  64         ((= src end))
  65       (cond (quoted
  66              (setf (schar result dst) (schar namestr src))
  67              (setf quoted nil)
  68              (incf dst))
  69             (t
  70              (let ((char (schar namestr src)))
  71                (cond ((char= char #\\)
  72                       (setq quoted t))
  73                      (t
  74                       (setf (schar result dst) char)
  75                       (incf dst)))))))
  76     (when quoted
  77       (error 'namestring-parse-error
  78              :complaint "backslash in a bad place"
  79              :namestring namestr
  80              :offset (1- end)))
  81     (shrink-vector result dst)))
  82
  83 (defvar *ignore-wildcards* nil)
  84
  85 (/show0 "filesys.lisp 86")
  86
  87 (defun maybe-make-pattern (namestr start end)
  88   (declare (type simple-base-string namestr)
  89            (type index start end))
  90   (if *ignore-wildcards*
  91       (subseq namestr start end)
  92       (collect ((pattern))
  93         (let ((quoted nil)
  94               (any-quotes nil)
  95               (last-regular-char nil)
  96               (index start))
  97           (flet ((flush-pending-regulars ()
  98                    (when last-regular-char
  99                      (pattern (if any-quotes
 100                                   (remove-backslashes namestr
 101                                                       last-regular-char
 102                                                       index)
 103                                   (subseq namestr last-regular-char index)))
 104                      (setf any-quotes nil)
 105                      (setf last-regular-char nil))))
 106             (loop
 107               (when (>= index end)
 108                 (return))
 109               (let ((char (schar namestr index)))
 110                 (cond (quoted
 111                        (incf index)
 112                        (setf quoted nil))
 113                       ((char= char #\\)
 114                        (setf quoted t)
 115                        (setf any-quotes t)
 116                        (unless last-regular-char
 117                          (setf last-regular-char index))
 118                        (incf index))
 119                       ((char= char #\?)
 120                        (flush-pending-regulars)
 121                        (pattern :single-char-wild)
 122                        (incf index))
 123                       ((char= char #\*)
 124                        (flush-pending-regulars)
 125                        (pattern :multi-char-wild)
 126                        (incf index))
 127                       ((char= char #\[)
 128                        (flush-pending-regulars)
 129                        (let ((close-bracket
 130                               (position #\] namestr :start index :end end)))
 131                          (unless close-bracket
 132                            (error 'namestring-parse-error
 133                                   :complaint "#\\[ with no corresponding #\\]"
 134                                   :namestring namestr
 135                                   :offset index))
 136                          (pattern (list :character-set
 137                                         (subseq namestr
 138                                                 (1+ index)
 139                                                 close-bracket)))
 140                          (setf index (1+ close-bracket))))
 141                       (t
 142                        (unless last-regular-char
 143                          (setf last-regular-char index))
 144                        (incf index)))))
 145             (flush-pending-regulars)))
 146         (cond ((null (pattern))
 147                "")
 148               ((null (cdr (pattern)))
 149                (let ((piece (first (pattern))))
 150                  (typecase piece
 151                    ((member :multi-char-wild) :wild)
 152                    (simple-string piece)
 153                    (t
 154                     (make-pattern (pattern))))))
 155               (t
 156                (make-pattern (pattern)))))))
 157
 158 (/show0 "filesys.lisp 160")
 159
 160 (defun extract-name-type-and-version (namestr start end)
 161   (declare (type simple-base-string namestr)
 162            (type index start end))
 163   (let* ((last-dot (position #\. namestr :start (1+ start) :end end
 164                              :from-end t))
 165          (second-to-last-dot (and last-dot
 166                                   (position #\. namestr :start (1+ start)
 167                                             :end last-dot :from-end t)))
 168          (version :newest))
 169     ;; If there is a second-to-last dot, check to see whether there is
 170     ;; a valid version after the last dot.
 171     (when second-to-last-dot
 172       (cond ((and (= (+ last-dot 2) end)
 173                   (char= (schar namestr (1+ last-dot)) #\*))
 174              (setf version :wild))
 175             ((and (< (1+ last-dot) end)
 176                   (do ((index (1+ last-dot) (1+ index)))
 177                       ((= index end) t)
 178                     (unless (char<= #\0 (schar namestr index) #\9)
 179                       (return nil))))
 180              (setf version
 181                    (parse-integer namestr :start (1+ last-dot) :end end)))
 182             (t
 183              (setf second-to-last-dot nil))))
 184     (cond (second-to-last-dot
 185            (values (maybe-make-pattern namestr start second-to-last-dot)
 186                    (maybe-make-pattern namestr
 187                                        (1+ second-to-last-dot)
 188                                        last-dot)
 189                    version))
 190           (last-dot
 191            (values (maybe-make-pattern namestr start last-dot)
 192                    (maybe-make-pattern namestr (1+ last-dot) end)
 193                    version))
 194           (t
 195            (values (maybe-make-pattern namestr start end)
 196                    nil
 197                    version)))))
 198
 199 (/show0 "filesys.lisp 200")
 200
 201 ;;; Take a string and return a list of cons cells that mark the char
 202 ;;; separated subseq. The first value is true if absolute directories
 203 ;;; location.
 204 (defun split-at-slashes (namestr start end)
 205   (declare (type simple-base-string namestr)
 206            (type index start end))
 207   (let ((absolute (and (/= start end)
 208                        (char= (schar namestr start) #\/))))
 209     (when absolute
 210       (incf start))
 211     ;; Next, split the remainder into slash-separated chunks.
 212     (collect ((pieces))
 213       (loop
 214         (let ((slash (position #\/ namestr :start start :end end)))
 215           (pieces (cons start (or slash end)))
 216           (unless slash
 217             (return))
 218           (setf start (1+ slash))))
 219       (values absolute (pieces)))))
 220
 221 (defun maybe-extract-search-list (namestr start end)
 222   (declare (type simple-base-string namestr)
 223            (type index start end))
 224   (let ((quoted nil))
 225     (do ((index start (1+ index)))
 226         ((= index end)
 227          (values nil start))
 228       (if quoted
 229           (setf quoted nil)
 230           (case (schar namestr index)
 231             (#\\
 232              (setf quoted t))
 233             (#\:
 234              (return (values (remove-backslashes namestr start index)
 235                              (1+ index)))))))))
 236
 237 (defun parse-unix-namestring (namestr start end)
 238   (declare (type simple-base-string namestr)
 239            (type index start end))
 240   (multiple-value-bind (absolute pieces) (split-at-slashes namestr start end)
 241     (let ((search-list (if absolute
 242                            nil
 243                            (let ((first (car pieces)))
 244                              (multiple-value-bind (search-list new-start)
 245                                  (maybe-extract-search-list namestr
 246                                                             (car first)
 247                                                             (cdr first))
 248                                (when search-list
 249                                  (setf absolute t)
 250                                  (setf (car first) new-start))
 251                                search-list)))))
 252       (multiple-value-bind (name type version)
 253           (let* ((tail (car (last pieces)))
 254                  (tail-start (car tail))
 255                  (tail-end (cdr tail)))
 256             (unless (= tail-start tail-end)
 257               (setf pieces (butlast pieces))
 258               (extract-name-type-and-version namestr tail-start tail-end)))
 259         ;; PVE: make sure there are no illegal characters in
 260         ;; the name, illegal being (code-char 0) and #\/
 261         #!+high-security
 262         (when (and (stringp name)
 263                    (find-if #'(lambda (x) (or (char= x (code-char 0))
 264                                               (char= x #\/)))
 265                             name))
 266           (error 'parse-error))
 267
 268         ;; Now we have everything we want. So return it.
 269         (values nil ; no host for unix namestrings.
 270                 nil ; no devices for unix namestrings.
 271                 (collect ((dirs))
 272                   (when search-list
 273                     (dirs (intern-search-list search-list)))
 274                   (dolist (piece pieces)
 275                     (let ((piece-start (car piece))
 276                           (piece-end (cdr piece)))
 277                       (unless (= piece-start piece-end)
 278                         (cond ((string= namestr ".." :start1 piece-start
 279                                         :end1 piece-end)
 280                                (dirs :up))
 281                               ((string= namestr "**" :start1 piece-start
 282                                         :end1 piece-end)
 283                                (dirs :wild-inferiors))
 284                               (t
 285                                (dirs (maybe-make-pattern namestr
 286                                                          piece-start
 287                                                          piece-end)))))))
 288                   (cond (absolute
 289                          (cons :absolute (dirs)))
 290                         ((dirs)
 291                          (cons :relative (dirs)))
 292                         (t
 293                          nil)))
 294                 name
 295                 type
 296                 version)))))
 297
 298 (/show0 "filesys.lisp 300")
 299
 300 (defun unparse-unix-host (pathname)
 301   (declare (type pathname pathname)
 302            (ignore pathname))
 303   "Unix")
 304
 305 (defun unparse-unix-piece (thing)
 306   (etypecase thing
 307     ((member :wild) "*")
 308     (simple-string
 309      (let* ((srclen (length thing))
 310             (dstlen srclen))
 311        (dotimes (i srclen)
 312          (case (schar thing i)
 313            ((#\* #\? #\[)
 314             (incf dstlen))))
 315        (let ((result (make-string dstlen))
 316              (dst 0))
 317          (dotimes (src srclen)
 318            (let ((char (schar thing src)))
 319              (case char
 320                ((#\* #\? #\[)
 321                 (setf (schar result dst) #\\)
 322                 (incf dst)))
 323              (setf (schar result dst) char)
 324              (incf dst)))
 325          result)))
 326     (pattern
 327      (collect ((strings))
 328        (dolist (piece (pattern-pieces thing))
 329          (etypecase piece
 330            (simple-string
 331             (strings piece))
 332            (symbol
 333             (ecase piece
 334               (:multi-char-wild
 335                (strings "*"))
 336               (:single-char-wild
 337                (strings "?"))))
 338            (cons
 339             (case (car piece)
 340               (:character-set
 341                (strings "[")
 342                (strings (cdr piece))
 343                (strings "]"))
 344               (t
 345                (error "invalid pattern piece: ~S" piece))))))
 346        (apply #'concatenate
 347               'simple-string
 348               (strings))))))
 349
 350 (defun unparse-unix-directory-list (directory)
 351   (declare (type list directory))
 352   (collect ((pieces))
 353     (when directory
 354       (ecase (pop directory)
 355         (:absolute
 356          (cond ((search-list-p (car directory))
 357                 (pieces (search-list-name (pop directory)))
 358                 (pieces ":"))
 359                (t
 360                 (pieces "/"))))
 361         (:relative
 362          ;; nothing special
 363          ))
 364       (dolist (dir directory)
 365         (typecase dir
 366           ((member :up)
 367            (pieces "../"))
 368           ((member :back)
 369            (error ":BACK cannot be represented in namestrings."))
 370           ((member :wild-inferiors)
 371            (pieces "**/"))
 372           ((or simple-string pattern)
 373            (pieces (unparse-unix-piece dir))
 374            (pieces "/"))
 375           (t
 376            (error "invalid directory component: ~S" dir)))))
 377     (apply #'concatenate 'simple-string (pieces))))
 378
 379 (defun unparse-unix-directory (pathname)
 380   (declare (type pathname pathname))
 381   (unparse-unix-directory-list (%pathname-directory pathname)))
 382
 383 (defun unparse-unix-file (pathname)
 384   (declare (type pathname pathname))
 385   (collect ((strings))
 386     (let* ((name (%pathname-name pathname))
 387            (type (%pathname-type pathname))
 388            (type-supplied (not (or (null type) (eq type :unspecific)))))
 389       ;; Note: by ANSI 19.3.1.1.5, we ignore the version slot when
 390       ;; translating logical pathnames to a filesystem without
 391       ;; versions (like Unix).
 392       (when name
 393         (strings (unparse-unix-piece name)))
 394       (when type-supplied
 395         (unless name
 396           (error "cannot specify the type without a file: ~S" pathname))
 397         (strings ".")
 398         (strings (unparse-unix-piece type))))
 399     (apply #'concatenate 'simple-string (strings))))
 400
 401 (/show0 "filesys.lisp 406")
 402
 403 (defun unparse-unix-namestring (pathname)
 404   (declare (type pathname pathname))
 405   (concatenate 'simple-string
 406                (unparse-unix-directory pathname)
 407                (unparse-unix-file pathname)))
 408
 409 (defun unparse-unix-enough (pathname defaults)
 410   (declare (type pathname pathname defaults))
 411   (flet ((lose ()
 412            (error "~S cannot be represented relative to ~S."
 413                   pathname defaults)))
 414     (collect ((strings))
 415       (let* ((pathname-directory (%pathname-directory pathname))
 416              (defaults-directory (%pathname-directory defaults))
 417              (prefix-len (length defaults-directory))
 418              (result-dir
 419               (cond ((and (> prefix-len 1)
 420                           (>= (length pathname-directory) prefix-len)
 421                           (compare-component (subseq pathname-directory
 422                                                      0 prefix-len)
 423                                              defaults-directory))
 424                      ;; Pathname starts with a prefix of default. So
 425                      ;; just use a relative directory from then on out.
 426                      (cons :relative (nthcdr prefix-len pathname-directory)))
 427                     ((eq (car pathname-directory) :absolute)
 428                      ;; We are an absolute pathname, so we can just use it.
 429                      pathname-directory)
 430                     (t
 431                      ;; We are a relative directory. So we lose.
 432                      (lose)))))
 433         (strings (unparse-unix-directory-list result-dir)))
 434       (let* ((pathname-version (%pathname-version pathname))
 435              (version-needed (and pathname-version
 436                                   (not (eq pathname-version :newest))))
 437              (pathname-type (%pathname-type pathname))
 438              (type-needed (or version-needed
 439                               (and pathname-type
 440                                    (not (eq pathname-type :unspecific)))))
 441              (pathname-name (%pathname-name pathname))
 442              (name-needed (or type-needed
 443                               (and pathname-name
 444                                    (not (compare-component pathname-name
 445                                                            (%pathname-name
 446                                                             defaults)))))))
 447         (when name-needed
 448           (unless pathname-name (lose))
 449           (strings (unparse-unix-piece pathname-name)))
 450         (when type-needed
 451           (when (or (null pathname-type) (eq pathname-type :unspecific))
 452             (lose))
 453           (strings ".")
 454           (strings (unparse-unix-piece pathname-type)))
 455         (when version-needed
 456           (typecase pathname-version
 457             ((member :wild)
 458              (strings ".*"))
 459             (integer
 460              (strings (format nil ".~D" pathname-version)))
 461             (t
 462              (lose)))))
 463       (apply #'concatenate 'simple-string (strings)))))
 464
 465 (/show0 "filesys.lisp 471")
 466
 467 (def!struct (unix-host
 468              (:make-load-form-fun make-unix-host-load-form)
 469              (:include host
 470                        (parse #'parse-unix-namestring)
 471                        (unparse #'unparse-unix-namestring)
 472                        (unparse-host #'unparse-unix-host)
 473                        (unparse-directory #'unparse-unix-directory)
 474                        (unparse-file #'unparse-unix-file)
 475                        (unparse-enough #'unparse-unix-enough)
 476                        (customary-case :lower))))
 477
 478 (/show0 "filesys.lisp 486")
 479
 480 (defvar *unix-host* (make-unix-host))
 481
 482 (/show0 "filesys.lisp 488")
 483
 484 (defun make-unix-host-load-form (host)
 485   (declare (ignore host))
 486   '*unix-host*)
 487 \f
 488 ;;;; wildcard matching stuff
 489
 490 (/show0 "filesys.lisp 498")
 491
 492 ;;; FIXME: could maybe be EVAL-WHEN (COMPILE EVAL)
 493
 494 (defmacro enumerate-matches ((var pathname &optional result
 495                                   &key (verify-existence t)
 496                                   (follow-links t))
 497                              &body body)
 498   (let ((body-name (gensym "ENUMERATE-MATCHES-BODY-FUN-")))
 499     `(block nil
 500        (flet ((,body-name (,var)
 501                 ,@body))
 502          (declare (dynamic-extent ,body-name))
 503          (%enumerate-matches (pathname ,pathname)
 504                              ,verify-existence
 505                              ,follow-links
 506                              #',body-name)
 507          ,result))))
 508
 509 (/show0 "filesys.lisp 500")
 510
 511 (defun %enumerate-matches (pathname verify-existence follow-links function)
 512   (/show0 "entering %ENUMERATE-MATCHES")
 513   (when (pathname-type pathname)
 514     (unless (pathname-name pathname)
 515       (error "cannot supply a type without a name:~%  ~S" pathname)))
 516   (when (and (integerp (pathname-version pathname))
 517              (member (pathname-type pathname) '(nil :unspecific)))
 518     (error "cannot supply a version without a type:~%  ~S" pathname))
 519   (let ((directory (pathname-directory pathname)))
 520     (/show0 "computed DIRECTORY")
 521     (if directory
 522         (ecase (car directory)
 523           (:absolute
 524            (/show0 "absolute directory")
 525            (%enumerate-directories "/" (cdr directory) pathname
 526                                    verify-existence follow-links
 527                                    nil function))
 528           (:relative
 529            (/show0 "relative directory")
 530            (%enumerate-directories "" (cdr directory) pathname
 531                                    verify-existence follow-links
 532                                    nil function)))
 533         (%enumerate-files "" pathname verify-existence function))))
 534
 535 (defun %enumerate-directories (head tail pathname verify-existence
 536                                follow-links nodes function)
 537   (declare (simple-string head))
 538   (macrolet ((unix-xstat (name)
 539                `(if follow-links
 540                     (sb!unix:unix-stat ,name)
 541                     (sb!unix:unix-lstat ,name)))
 542              (with-directory-node-noted ((head) &body body)
 543                `(multiple-value-bind (res dev ino mode)
 544                     (unix-xstat ,head)
 545                   (when (and res (eql (logand mode sb!unix:s-ifmt)
 546                                       sb!unix:s-ifdir))
 547                     (let ((nodes (cons (cons dev ino) nodes)))
 548                       ,@body))))
 549              (do-directory-entries ((name directory) &body body)
 550                `(let ((dir (sb!unix:open-dir ,directory)))
 551              (when dir
 552                (unwind-protect
 553                    (loop
 554                           (let ((,name (sb!unix:read-dir dir)))
 555                             (cond ((null ,name)
 556                               (return))
 557                                   ((string= ,name "."))
 558                                   ((string= ,name ".."))
 559                                   (t
 560                                    ,@body))))
 561                       (sb!unix:close-dir dir))))))
 562     (if tail
 563         (let ((piece (car tail)))
 564           (etypecase piece
 565             (simple-string
 566              (let ((head (concatenate 'string head piece)))
 567                (with-directory-node-noted (head)
 568                  (%enumerate-directories (concatenate 'string head "/")
 569                                          (cdr tail) pathname
 570                                          verify-existence follow-links
 571                                          nodes function))))
 572             ((member :wild-inferiors)
 573              (%enumerate-directories head (rest tail) pathname
 574                                      verify-existence follow-links
 575                                      nodes function)
 576              (do-directory-entries (name head)
 577                (let ((subdir (concatenate 'string head name)))
 578                  (multiple-value-bind (res dev ino mode)
 579                      (unix-xstat subdir)
 580                    (declare (type (or fixnum null) mode))
 581                    (when (and res (eql (logand mode sb!unix:s-ifmt)
 582                                        sb!unix:s-ifdir))
 583                      (unless (dolist (dir nodes nil)
 584                                (when (and (eql (car dir) dev)
 585                                           (eql (cdr dir) ino))
 586                                  (return t)))
 587                        (let ((nodes (cons (cons dev ino) nodes))
 588                              (subdir (concatenate 'string subdir "/")))
 589                          (%enumerate-directories subdir tail pathname
 590                                                  verify-existence follow-links
 591                                                  nodes function))))))))
 592             ((or pattern (member :wild))
 593              (do-directory-entries (name head)
 594                (when (or (eq piece :wild) (pattern-matches piece name))
 595                  (let ((subdir (concatenate 'string head name)))
 596                    (multiple-value-bind (res dev ino mode)
 597                        (unix-xstat subdir)
 598                      (declare (type (or fixnum null) mode))
 599                      (when (and res
 600                                 (eql (logand mode sb!unix:s-ifmt)
 601                                      sb!unix:s-ifdir))
 602                        (let ((nodes (cons (cons dev ino) nodes))
 603                              (subdir (concatenate 'string subdir "/")))
 604                          (%enumerate-directories subdir (rest tail) pathname
 605                                                  verify-existence follow-links
 606                                                  nodes function))))))))
 607           ((member :up)
 608              (let ((head (concatenate 'string head "..")))
 609                (with-directory-node-noted (head)
 610                  (%enumerate-directories (concatenate 'string head "/")
 611                                          (rest tail) pathname
 612                                          verify-existence follow-links
 613                                          nodes function))))))
 614         (%enumerate-files head pathname verify-existence function))))
 615
 616 (defun %enumerate-files (directory pathname verify-existence function)
 617   (declare (simple-string directory))
 618   (/show0 "entering %ENUMERATE-FILES")
 619   (let ((name (%pathname-name pathname))
 620         (type (%pathname-type pathname))
 621         (version (%pathname-version pathname)))
 622     (/show0 "computed NAME, TYPE, and VERSION")
 623     (cond ((member name '(nil :unspecific))
 624            (/show0 "UNSPECIFIC, more or less")
 625            (when (or (not verify-existence)
 626                      (sb!unix:unix-file-kind directory))
 627              (funcall function directory)))
 628           ((or (pattern-p name)
 629                (pattern-p type)
 630                (eq name :wild)
 631                (eq type :wild))
 632            (/show0 "WILD, more or less")
 633            (let ((dir (sb!unix:open-dir directory)))
 634              (when dir
 635                (unwind-protect
 636                    (loop
 637                      (/show0 "at head of LOOP")
 638                      (let ((file (sb!unix:read-dir dir)))
 639                        (if file
 640                            (unless (or (string= file ".")
 641                                        (string= file ".."))
 642                              (multiple-value-bind
 643                                  (file-name file-type file-version)
 644                                  (let ((*ignore-wildcards* t))
 645                                    (extract-name-type-and-version
 646                                     file 0 (length file)))
 647                                (when (and (components-match file-name name)
 648                                           (components-match file-type type)
 649                                           (components-match file-version
 650                                                             version))
 651                                  (funcall function
 652                                           (concatenate 'string
 653                                                        directory
 654                                                        file)))))
 655                            (return))))
 656                  (sb!unix:close-dir dir)))))
 657           (t
 658            (/show0 "default case")
 659            (let ((file (concatenate 'string directory name)))
 660              (/show0 "computed basic FILE=..")
 661              (/primitive-print file)
 662              (unless (or (null type) (eq type :unspecific))
 663                (/show0 "tweaking FILE for more-or-less-:UNSPECIFIC case")
 664                (setf file (concatenate 'string file "." type)))
 665              (unless (member version '(nil :newest :wild))
 666                (/show0 "tweaking FILE for more-or-less-:WILD case")
 667                (setf file (concatenate 'string file "."
 668                                        (quick-integer-to-string version))))
 669              (/show0 "finished possibly tweaking FILE=..")
 670              (/primitive-print file)
 671              (when (or (not verify-existence)
 672                        (sb!unix:unix-file-kind file t))
 673                (/show0 "calling FUNCTION on FILE")
 674                (funcall function file)))))))
 675
 676 (/show0 "filesys.lisp 603")
 677
 678 ;;; FIXME: Why do we need this?
 679 (defun quick-integer-to-string (n)
 680   (declare (type integer n))
 681   (cond ((not (fixnump n))
 682          (write-to-string n :base 10 :radix nil))
 683         ((zerop n) "0")
 684         ((eql n 1) "1")
 685         ((minusp n)
 686          (concatenate 'simple-string "-"
 687                       (the simple-string (quick-integer-to-string (- n)))))
 688         (t
 689          (do* ((len (1+ (truncate (integer-length n) 3)))
 690                (res (make-string len))
 691                (i (1- len) (1- i))
 692                (q n)
 693                (r 0))
 694               ((zerop q)
 695                (incf i)
 696                (replace res res :start2 i :end2 len)
 697                (shrink-vector res (- len i)))
 698            (declare (simple-string res)
 699                     (fixnum len i r q))
 700            (multiple-value-setq (q r) (truncate q 10))
 701            (setf (schar res i) (schar "0123456789" r))))))
 702 \f
 703 ;;;; UNIX-NAMESTRING
 704
 705 (defun unix-namestring (pathname &optional (for-input t) executable-only)
 706   #!+sb-doc
 707   "Convert PATHNAME into a string that can be used with UNIX system calls.
 708    Search-lists and wild-cards are expanded."
 709   ;; toy@rtp.ericsson.se: Let unix-namestring also handle logical
 710   ;; pathnames too.
 711   ;; FIXME: What does this ^ mean? A bug? A remark on a change already made?
 712   (let ((path (let ((lpn (pathname pathname)))
 713                 (if (typep lpn 'logical-pathname)
 714                     (namestring (translate-logical-pathname lpn))
 715                     pathname))))
 716     (enumerate-search-list
 717       (pathname path)
 718       (collect ((names))
 719         (enumerate-matches (name pathname nil :verify-existence for-input)
 720                            (when (or (not executable-only)
 721                                      (and (eq (sb!unix:unix-file-kind name)
 722                                               :file)
 723                                           (sb!unix:unix-access name
 724                                                                sb!unix:x_ok)))
 725                              (names name)))
 726         (let ((names (names)))
 727           (when names
 728             (when (cdr names)
 729               (error 'simple-file-error
 730                      :format-control "~S is ambiguous:~{~%  ~A~}"
 731                      :format-arguments (list pathname names)))
 732             (return (car names))))))))
 733 \f
 734 ;;;; TRUENAME and PROBE-FILE
 735
 736 ;;; Another silly file function trivially different from another function.
 737 (defun truename (pathname)
 738   #!+sb-doc
 739   "Return the pathname for the actual file described by the pathname
 740   An error of type file-error is signalled if no such file exists,
 741   or the pathname is wild."
 742   (if (wild-pathname-p pathname)
 743       (error 'simple-file-error
 744              :format-control "bad place for a wild pathname"
 745              :pathname pathname)
 746       (let ((result (probe-file pathname)))
 747         (unless result
 748           (error 'simple-file-error
 749                  :pathname pathname
 750                  :format-control "The file ~S does not exist."
 751                  :format-arguments (list (namestring pathname))))
 752         result)))
 753
 754 ;;; If PATHNAME exists, return its truename, otherwise NIL.
 755 (defun probe-file (pathname)
 756   #!+sb-doc
 757   "Return a pathname which is the truename of the file if it exists, NIL
 758   otherwise. An error of type FILE-ERROR is signaled if pathname is wild."
 759   (if (wild-pathname-p pathname)
 760       (error 'simple-file-error
 761              :pathname pathname
 762              :format-control "bad place for a wild pathname")
 763       (let ((namestring (unix-namestring pathname t)))
 764         (when (and namestring (sb!unix:unix-file-kind namestring))
 765           (let ((truename (sb!unix:unix-resolve-links
 766                            (sb!unix:unix-maybe-prepend-current-directory
 767                             namestring))))
 768             (when truename
 769               (let ((*ignore-wildcards* t))
 770                 (pathname (sb!unix:unix-simplify-pathname truename)))))))))
 771 \f
 772 ;;;; miscellaneous other operations
 773
 774 (/show0 "filesys.lisp 700")
 775
 776 (defun rename-file (file new-name)
 777   #!+sb-doc
 778   "Rename File to have the specified New-Name. If file is a stream open to a
 779   file, then the associated file is renamed."
 780   (let* ((original (truename file))
 781          (original-namestring (unix-namestring original t))
 782          (new-name (merge-pathnames new-name original))
 783          (new-namestring (unix-namestring new-name nil)))
 784     (unless new-namestring
 785       (error 'simple-file-error
 786              :pathname new-name
 787              :format-control "~S can't be created."
 788              :format-arguments (list new-name)))
 789     (multiple-value-bind (res error)
 790         (sb!unix:unix-rename original-namestring new-namestring)
 791       (unless res
 792         (error 'simple-file-error
 793                :pathname new-name
 794                :format-control "failed to rename ~A to ~A: ~A"
 795                :format-arguments (list original new-name
 796                                        (sb!unix:get-unix-error-msg error))))
 797       (when (streamp file)
 798         (file-name file new-namestring))
 799       (values new-name original (truename new-name)))))
 800
 801 (defun delete-file (file)
 802   #!+sb-doc
 803   "Delete the specified file."
 804   (let ((namestring (unix-namestring file t)))
 805     (when (streamp file)
 806       (close file :abort t))
 807     (unless namestring
 808       (error 'simple-file-error
 809              :pathname file
 810              :format-control "~S doesn't exist."
 811              :format-arguments (list file)))
 812
 813     (multiple-value-bind (res err) (sb!unix:unix-unlink namestring)
 814       (unless res
 815         (error 'simple-file-error
 816                :pathname namestring
 817                :format-control "could not delete ~A: ~A"
 818                :format-arguments (list namestring
 819                                        (sb!unix:get-unix-error-msg err))))))
 820   t)
 821 \f
 822 ;;; Return Home:, which is set up for us at initialization time.
 823 (defun user-homedir-pathname (&optional host)
 824   #!+sb-doc
 825   "Returns the home directory of the logged in user as a pathname.
 826   This is obtained from the logical name \"home:\"."
 827   (declare (ignore host))
 828   ;; Note: CMU CL did #P"home:" here instead of using a call to
 829   ;; PATHNAME. Delaying construction of the pathname until we're
 830   ;; running in a target Lisp lets us avoid figuring out how to dump
 831   ;; cross-compilation host Lisp PATHNAME objects into a target Lisp
 832   ;; object file. It also might have a small positive effect on
 833   ;; efficiency, in that we don't allocate a PATHNAME we don't need,
 834   ;; but it it could also have a larger negative effect. Hopefully
 835   ;; it'll be OK. -- WHN 19990714
 836   (pathname "home:"))
 837
 838 (defun file-write-date (file)
 839   #!+sb-doc
 840   "Return file's creation date, or NIL if it doesn't exist.
 841  An error of type file-error is signaled if file is a wild pathname"
 842   (if (wild-pathname-p file)
 843       ;; FIXME: This idiom appears many times in this file. Perhaps it
 844       ;; should turn into (CANNOT-BE-WILD-PATHNAME FILE). (C-B-W-P
 845       ;; should be a macro, not a function, so that the error message
 846       ;; is reported as coming from e.g. FILE-WRITE-DATE instead of
 847       ;; from CANNOT-BE-WILD-PATHNAME itself.)
 848       (error 'simple-file-error
 849              :pathname file
 850              :format-control "bad place for a wild pathname")
 851       (let ((name (unix-namestring file t)))
 852         (when name
 853           (multiple-value-bind
 854               (res dev ino mode nlink uid gid rdev size atime mtime)
 855               (sb!unix:unix-stat name)
 856             (declare (ignore dev ino mode nlink uid gid rdev size atime))
 857             (when res
 858               (+ unix-to-universal-time mtime)))))))
 859
 860 (defun file-author (file)
 861   #!+sb-doc
 862   "Returns the file author as a string, or nil if the author cannot be
 863  determined. Signals an error of type file-error if file doesn't exist,
 864  or file is a wild pathname."
 865   (if (wild-pathname-p file)
 866       (error 'simple-file-error
 867              :pathname file
 868              "bad place for a wild pathname")
 869       (let ((name (unix-namestring (pathname file) t)))
 870         (unless name
 871           (error 'simple-file-error
 872                  :pathname file
 873                  :format-control "~S doesn't exist."
 874                  :format-arguments (list file)))
 875         (multiple-value-bind (winp dev ino mode nlink uid)
 876             (sb!unix:unix-stat name)
 877           (declare (ignore dev ino mode nlink))
 878           (if winp (lookup-login-name uid))))))
 879 \f
 880 ;;;; DIRECTORY
 881
 882 (/show0 "filesys.lisp 800")
 883
 884 (defun directory (pathname &key (all t) (check-for-subdirs t)
 885                            (follow-links t))
 886   #!+sb-doc
 887   "Returns a list of pathnames, one for each file that matches the given
 888    pathname. Supplying :ALL as NIL causes this to ignore Unix dot files. This
 889    never includes Unix dot and dot-dot in the result. If :FOLLOW-LINKS is NIL,
 890    then symbolic links in the result are not expanded. This is not the
 891    default because TRUENAME does follow links, and the result pathnames are
 892    defined to be the TRUENAME of the pathname (the truename of a link may well
 893    be in another directory.)"
 894   (let ((results nil))
 895     (enumerate-search-list
 896         (pathname (merge-pathnames pathname
 897                                    (make-pathname :name :wild
 898                                                   :type :wild
 899                                                   :version :wild)))
 900       (enumerate-matches (name pathname)
 901         (when (or all
 902                   (let ((slash (position #\/ name :from-end t)))
 903                     (or (null slash)
 904                         (= (1+ slash) (length name))
 905                         (char/= (schar name (1+ slash)) #\.))))
 906           (push name results))))
 907     (let ((*ignore-wildcards* t))
 908       (mapcar (lambda (name)
 909                 (let ((name (if (and check-for-subdirs
 910                                      (eq (sb!unix:unix-file-kind name)
 911                                          :directory))
 912                                 (concatenate 'string name "/")
 913                                 name)))
 914                   (if follow-links (truename name) (pathname name))))
 915               (sort (delete-duplicates results :test #'string=) #'string<)))))
 916 \f
 917 ;;;; translating Unix uid's
 918 ;;;;
 919 ;;;; FIXME: should probably move into unix.lisp
 920
 921 (defvar *uid-hash-table* (make-hash-table)
 922   #!+sb-doc
 923   "hash table for keeping track of uid's and login names")
 924
 925 (/show0 "filesys.lisp 844")
 926
 927 ;;; LOOKUP-LOGIN-NAME translates a user id into a login name. Previous
 928 ;;; lookups are cached in a hash table since groveling the passwd(s)
 929 ;;; files is somewhat expensive. The table may hold NIL for id's that
 930 ;;; cannot be looked up since this keeps the files from having to be
 931 ;;; searched in their entirety each time this id is translated.
 932 (defun lookup-login-name (uid)
 933   (multiple-value-bind (login-name foundp) (gethash uid *uid-hash-table*)
 934     (if foundp
 935         login-name
 936         (setf (gethash uid *uid-hash-table*)
 937               (get-group-or-user-name :user uid)))))
 938
 939 ;;; GET-GROUP-OR-USER-NAME first tries "/etc/passwd" ("/etc/group")
 940 ;;; since it is a much smaller file, contains all the local id's, and
 941 ;;; most uses probably involve id's on machines one would login into.
 942 ;;; Then if necessary, we look in "/etc/passwds" ("/etc/groups") which
 943 ;;; is really long and has to be fetched over the net.
 944 ;;;
 945 ;;; FIXME: Now that we no longer have lookup-group-name, we no longer need
 946 ;;; the GROUP-OR-USER argument.
 947 (defun get-group-or-user-name (group-or-user id)
 948   #!+sb-doc
 949   "Returns the simple-string user or group name of the user whose uid or gid
 950    is id, or NIL if no such user or group exists. Group-or-user is either
 951    :group or :user."
 952   (let ((id-string (let ((*print-base* 10)) (prin1-to-string id))))
 953     (declare (simple-string id-string))
 954     (multiple-value-bind (file1 file2)
 955         (ecase group-or-user
 956           (:group (values "/etc/group" "/etc/groups"))
 957           (:user (values "/etc/passwd" "/etc/passwd")))
 958       (or (get-group-or-user-name-aux id-string file1)
 959           (get-group-or-user-name-aux id-string file2)))))
 960
 961 ;;; FIXME: Isn't there now a POSIX routine to parse the passwd file?
 962 ;;; getpwent? getpwuid?
 963 (defun get-group-or-user-name-aux (id-string passwd-file)
 964   (with-open-file (stream passwd-file)
 965     (loop
 966       (let ((entry (read-line stream nil)))
 967         (unless entry (return nil))
 968         (let ((name-end (position #\: (the simple-string entry)
 969                                   :test #'char=)))
 970           (when name-end
 971             (let ((id-start (position #\: (the simple-string entry)
 972                                       :start (1+ name-end) :test #'char=)))
 973               (when id-start
 974                 (incf id-start)
 975                 (let ((id-end (position #\: (the simple-string entry)
 976                                         :start id-start :test #'char=)))
 977                   (when (and id-end
 978                              (string= id-string entry
 979                                       :start2 id-start :end2 id-end))
 980                     (return (subseq entry 0 name-end))))))))))))
 981 \f
 982 (/show0 "filesys.lisp 899")
 983
 984 ;;; predicate to order pathnames by; goes by name
 985 (defun pathname-order (x y)
 986   (let ((xn (%pathname-name x))
 987         (yn (%pathname-name y)))
 988     (if (and xn yn)
 989         (let ((res (string-lessp xn yn)))
 990           (cond ((not res) nil)
 991                 ((= res (length (the simple-string xn))) t)
 992                 ((= res (length (the simple-string yn))) nil)
 993                 (t t)))
 994         xn)))
 995 \f
 996 (defun default-directory ()
 997   #!+sb-doc
 998   "Returns the pathname for the default directory. This is the place where
 999   a file will be written if no directory is specified. This may be changed
1000   with setf."
1001   (multiple-value-bind (gr dir-or-error) (sb!unix:unix-current-directory)
1002     (if gr
1003         (let ((*ignore-wildcards* t))
1004           (pathname (concatenate 'simple-string dir-or-error "/")))
1005         (error dir-or-error))))
1006
1007 (defun %set-default-directory (new-val)
1008   (let ((namestring (unix-namestring new-val t)))
1009     (unless namestring
1010       (error "~S doesn't exist." new-val))
1011     (multiple-value-bind (gr error) (sb!unix:unix-chdir namestring)
1012       (if gr
1013           (setf (search-list "default:") (default-directory))
1014           (error (sb!unix:get-unix-error-msg error))))
1015     new-val))
1016
1017 (/show0 "filesys.lisp 934")
1018
1019 (/show0 "entering what used to be !FILESYS-COLD-INIT")
1020 (defvar *default-pathname-defaults*
1021   (%make-pathname *unix-host* nil nil nil nil :newest))
1022 (setf (search-list "default:") (default-directory))
1023 (/show0 "leaving what used to be !FILESYS-COLD-INIT")
1024 \f
1025 (defun ensure-directories-exist (pathspec &key verbose (mode #o777))
1026   #!+sb-doc
1027   "Tests whether the directories containing the specified file
1028   actually exist, and attempts to create them if they do not.
1029   Portable programs should avoid using the :MODE argument."
1030   (let* ((pathname (pathname pathspec))
1031          (pathname (if (typep pathname 'logical-pathname)
1032                        (translate-logical-pathname pathname)
1033                        pathname))
1034          (created-p nil))
1035     (when (wild-pathname-p pathname)
1036       (error 'simple-file-error
1037              :format-control "bad place for a wild pathname"
1038              :pathname pathspec))
1039     (enumerate-search-list (pathname pathname)
1040        (let ((dir (pathname-directory pathname)))
1041          (loop for i from 1 upto (length dir)
1042                do (let ((newpath (make-pathname
1043                                   :host (pathname-host pathname)
1044                                   :device (pathname-device pathname)
1045                                   :directory (subseq dir 0 i))))
1046                     (unless (probe-file newpath)
1047                       (let ((namestring (namestring newpath)))
1048                         (when verbose
1049                           (format *standard-output*
1050                                   "~&creating directory: ~A~%"
1051                                   namestring))
1052                         (sb!unix:unix-mkdir namestring mode)
1053                         (unless (probe-file namestring)
1054                           (error 'simple-file-error
1055                                  :pathname pathspec
1056                                  :format-control "can't create directory ~A"
1057                                  :format-arguments (list namestring)))
1058                         (setf created-p t)))))
1059          ;; Only the first path in a search-list is considered.
1060          (return (values pathname created-p))))))
1061
1062 (/show0 "filesys.lisp 1000")