src/code/float.lisp

   1 ;;;; This file contains the definitions of float-specific number
   2 ;;;; support (other than irrational stuff, which is in irrat.) There is
   3 ;;;; code in here that assumes there are only two float formats: IEEE
   4 ;;;; single and double. (LONG-FLOAT support has been added, but bugs
   5 ;;;; may still remain due to old code which assumes this dichotomy.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!KERNEL")
  17 \f
  18 ;;;; utilities
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21
  22 ;;; These functions let us create floats from bits with the
  23 ;;; significand uniformly represented as an integer. This is less
  24 ;;; efficient for double floats, but is more convenient when making
  25 ;;; special values, etc.
  26 (defun single-from-bits (sign exp sig)
  27   (declare (type bit sign) (type (unsigned-byte 24) sig)
  28            (type (unsigned-byte 8) exp))
  29   (make-single-float
  30    (dpb exp sb!vm:single-float-exponent-byte
  31         (dpb sig sb!vm:single-float-significand-byte
  32              (if (zerop sign) 0 -1)))))
  33 (defun double-from-bits (sign exp sig)
  34   (declare (type bit sign) (type (unsigned-byte 53) sig)
  35            (type (unsigned-byte 11) exp))
  36   (make-double-float (dpb exp sb!vm:double-float-exponent-byte
  37                           (dpb (ash sig -32)
  38                                sb!vm:double-float-significand-byte
  39                                (if (zerop sign) 0 -1)))
  40                      (ldb (byte 32 0) sig)))
  41 #!+(and long-float x86)
  42 (defun long-from-bits (sign exp sig)
  43   (declare (type bit sign) (type (unsigned-byte 64) sig)
  44            (type (unsigned-byte 15) exp))
  45   (make-long-float (logior (ash sign 15) exp)
  46                    (ldb (byte 32 32) sig)
  47                    (ldb (byte 32 0) sig)))
  48
  49 ) ; EVAL-WHEN
  50 \f
  51 ;;;; float parameters
  52
  53 (defconstant least-positive-single-float (single-from-bits 0 0 1))
  54 (defconstant least-positive-short-float (single-from-bits 0 0 1))
  55 (defconstant least-negative-single-float (single-from-bits 1 0 1))
  56 (defconstant least-negative-short-float (single-from-bits 1 0 1))
  57 (defconstant least-positive-double-float (double-from-bits 0 0 1))
  58 #!-long-float
  59 (defconstant least-positive-long-float (double-from-bits 0 0 1))
  60 #!+(and long-float x86)
  61 (defconstant least-positive-long-float (long-from-bits 0 0 1))
  62 (defconstant least-negative-double-float (double-from-bits 1 0 1))
  63 #!-long-float
  64 (defconstant least-negative-long-float (double-from-bits 1 0 1))
  65 #!+(and long-float x86)
  66 (defconstant least-negative-long-float (long-from-bits 1 0 1))
  67
  68 (defconstant least-positive-normalized-single-float
  69   (single-from-bits 0 sb!vm:single-float-normal-exponent-min 0))
  70 (defconstant least-positive-normalized-short-float
  71   least-positive-normalized-single-float)
  72 (defconstant least-negative-normalized-single-float
  73   (single-from-bits 1 sb!vm:single-float-normal-exponent-min 0))
  74 (defconstant least-negative-normalized-short-float
  75   least-negative-normalized-single-float)
  76 (defconstant least-positive-normalized-double-float
  77   (double-from-bits 0 sb!vm:double-float-normal-exponent-min 0))
  78 #!-long-float
  79 (defconstant least-positive-normalized-long-float
  80   least-positive-normalized-double-float)
  81 #!+(and long-float x86)
  82 (defconstant least-positive-normalized-long-float
  83   (long-from-bits 0 sb!vm:long-float-normal-exponent-min
  84                   (ash sb!vm:long-float-hidden-bit 32)))
  85 (defconstant least-negative-normalized-double-float
  86   (double-from-bits 1 sb!vm:double-float-normal-exponent-min 0))
  87 #!-long-float
  88 (defconstant least-negative-normalized-long-float
  89   least-negative-normalized-double-float)
  90 #!+(and long-float x86)
  91 (defconstant least-negative-normalized-long-float
  92   (long-from-bits 1 sb!vm:long-float-normal-exponent-min
  93                   (ash sb!vm:long-float-hidden-bit 32)))
  94
  95 (defconstant most-positive-single-float
  96   (single-from-bits 0 sb!vm:single-float-normal-exponent-max
  97                     (ldb sb!vm:single-float-significand-byte -1)))
  98 (defconstant most-positive-short-float most-positive-single-float)
  99 (defconstant most-negative-single-float
 100   (single-from-bits 1 sb!vm:single-float-normal-exponent-max
 101                     (ldb sb!vm:single-float-significand-byte -1)))
 102 (defconstant most-negative-short-float most-negative-single-float)
 103 (defconstant most-positive-double-float
 104   (double-from-bits 0 sb!vm:double-float-normal-exponent-max
 105                     (ldb (byte sb!vm:double-float-digits 0) -1)))
 106 #!-long-float
 107 (defconstant most-positive-long-float most-positive-double-float)
 108 #!+(and long-float x86)
 109 (defconstant most-positive-long-float
 110   (long-from-bits 0 sb!vm:long-float-normal-exponent-max
 111                   (ldb (byte sb!vm:long-float-digits 0) -1)))
 112 (defconstant most-negative-double-float
 113   (double-from-bits 1 sb!vm:double-float-normal-exponent-max
 114                     (ldb (byte sb!vm:double-float-digits 0) -1)))
 115 #!-long-float
 116 (defconstant most-negative-long-float most-negative-double-float)
 117 #!+(and long-float x86)
 118 (defconstant most-negative-long-float
 119   (long-from-bits 1 sb!vm:long-float-normal-exponent-max
 120                   (ldb (byte sb!vm:long-float-digits 0) -1)))
 121
 122 ;;; We don't want to do these DEFCONSTANTs at cross-compilation time,
 123 ;;; because the cross-compilation host might not support floating
 124 ;;; point infinities. Putting them inside a LET removes
 125 ;;; toplevel-formness, so that any EVAL-WHEN trickiness in the
 126 ;;; DEFCONSTANT forms is suppressed.
 127 (let ()
 128 (defconstant single-float-positive-infinity
 129   (single-from-bits 0 (1+ sb!vm:single-float-normal-exponent-max) 0))
 130 (defconstant short-float-positive-infinity single-float-positive-infinity)
 131 (defconstant single-float-negative-infinity
 132   (single-from-bits 1 (1+ sb!vm:single-float-normal-exponent-max) 0))
 133 (defconstant short-float-negative-infinity single-float-negative-infinity)
 134 (defconstant double-float-positive-infinity
 135   (double-from-bits 0 (1+ sb!vm:double-float-normal-exponent-max) 0))
 136 #!+(not long-float)
 137 (defconstant long-float-positive-infinity double-float-positive-infinity)
 138 #!+(and long-float x86)
 139 (defconstant long-float-positive-infinity
 140   (long-from-bits 0 (1+ sb!vm:long-float-normal-exponent-max)
 141                   (ash sb!vm:long-float-hidden-bit 32)))
 142 (defconstant double-float-negative-infinity
 143   (double-from-bits 1 (1+ sb!vm:double-float-normal-exponent-max) 0))
 144 #!+(not long-float)
 145 (defconstant long-float-negative-infinity double-float-negative-infinity)
 146 #!+(and long-float x86)
 147 (defconstant long-float-negative-infinity
 148   (long-from-bits 1 (1+ sb!vm:long-float-normal-exponent-max)
 149                   (ash sb!vm:long-float-hidden-bit 32)))
 150 ) ; LET-to-suppress-possible-EVAL-WHENs
 151
 152 (defconstant single-float-epsilon
 153   (single-from-bits 0 (- sb!vm:single-float-bias
 154                          (1- sb!vm:single-float-digits)) 1))
 155 (defconstant short-float-epsilon single-float-epsilon)
 156 (defconstant single-float-negative-epsilon
 157   (single-from-bits 0 (- sb!vm:single-float-bias sb!vm:single-float-digits) 1))
 158 (defconstant short-float-negative-epsilon single-float-negative-epsilon)
 159 (defconstant double-float-epsilon
 160   (double-from-bits 0 (- sb!vm:double-float-bias
 161                          (1- sb!vm:double-float-digits)) 1))
 162 #!-long-float
 163 (defconstant long-float-epsilon double-float-epsilon)
 164 #!+(and long-float x86)
 165 (defconstant long-float-epsilon
 166   (long-from-bits 0 (- sb!vm:long-float-bias (1- sb!vm:long-float-digits))
 167                   (+ 1 (ash sb!vm:long-float-hidden-bit 32))))
 168 (defconstant double-float-negative-epsilon
 169   (double-from-bits 0 (- sb!vm:double-float-bias sb!vm:double-float-digits) 1))
 170 #!-long-float
 171 (defconstant long-float-negative-epsilon double-float-negative-epsilon)
 172 #!+(and long-float x86)
 173 (defconstant long-float-negative-epsilon
 174   (long-from-bits 0 (- sb!vm:long-float-bias sb!vm:long-float-digits)
 175                   (+ 1 (ash sb!vm:long-float-hidden-bit 32))))
 176 \f
 177 ;;;; float predicates and environment query
 178
 179 #!-sb-fluid
 180 (declaim (maybe-inline float-denormalized-p float-infinity-p float-nan-p
 181                        float-trapping-nan-p))
 182
 183 (defun float-denormalized-p (x)
 184   #!+sb-doc
 185   "Return true if the float X is denormalized."
 186   (number-dispatch ((x float))
 187     ((single-float)
 188      (and (zerop (ldb sb!vm:single-float-exponent-byte (single-float-bits x)))
 189           (not (zerop x))))
 190     ((double-float)
 191      (and (zerop (ldb sb!vm:double-float-exponent-byte
 192                       (double-float-high-bits x)))
 193           (not (zerop x))))
 194     #!+(and long-float x86)
 195     ((long-float)
 196      (and (zerop (ldb sb!vm:long-float-exponent-byte (long-float-exp-bits x)))
 197           (not (zerop x))))))
 198
 199 (defmacro !define-float-dispatching-function
 200     (name doc single double #!+(and long-float x86) long)
 201   `(defun ,name (x)
 202     ,doc
 203     (number-dispatch ((x float))
 204      ((single-float)
 205       (let ((bits (single-float-bits x)))
 206         (and (> (ldb sb!vm:single-float-exponent-byte bits)
 207                 sb!vm:single-float-normal-exponent-max)
 208              ,single)))
 209      ((double-float)
 210       (let ((hi (double-float-high-bits x))
 211             (lo (double-float-low-bits x)))
 212         (declare (ignorable lo))
 213         (and (> (ldb sb!vm:double-float-exponent-byte hi)
 214                 sb!vm:double-float-normal-exponent-max)
 215              ,double)))
 216      #!+(and long-float x86)
 217      ((long-float)
 218       (let ((exp (long-float-exp-bits x))
 219             (hi (long-float-high-bits x))
 220             (lo (long-float-low-bits x)))
 221         (declare (ignorable lo))
 222         (and (> (ldb sb!vm:long-float-exponent-byte exp)
 223                 sb!vm:long-float-normal-exponent-max)
 224              ,long))))))
 225
 226 (!define-float-dispatching-function float-infinity-p
 227   "Return true if the float X is an infinity (+ or -)."
 228   (zerop (ldb sb!vm:single-float-significand-byte bits))
 229   (and (zerop (ldb sb!vm:double-float-significand-byte hi))
 230        (zerop lo))
 231   #!+(and long-float x86)
 232   (and (zerop (ldb sb!vm:long-float-significand-byte hi))
 233        (zerop lo)))
 234
 235 (!define-float-dispatching-function float-nan-p
 236   "Return true if the float X is a NaN (Not a Number)."
 237   (not (zerop (ldb sb!vm:single-float-significand-byte bits)))
 238   (or (not (zerop (ldb sb!vm:double-float-significand-byte hi)))
 239       (not (zerop lo)))
 240   #!+(and long-float x86)
 241   (or (not (zerop (ldb sb!vm:long-float-significand-byte hi)))
 242       (not (zerop lo))))
 243
 244 (!define-float-dispatching-function float-trapping-nan-p
 245   "Return true if the float X is a trapping NaN (Not a Number)."
 246   (zerop (logand (ldb sb!vm:single-float-significand-byte bits)
 247                  sb!vm:single-float-trapping-nan-bit))
 248   (zerop (logand (ldb sb!vm:double-float-significand-byte hi)
 249                  sb!vm:double-float-trapping-nan-bit))
 250   #!+(and long-float x86)
 251   (zerop (logand (ldb sb!vm:long-float-significand-byte hi)
 252                  sb!vm:long-float-trapping-nan-bit)))
 253
 254 ;;; If denormalized, use a subfunction from INTEGER-DECODE-FLOAT to find the
 255 ;;; actual exponent (and hence how denormalized it is), otherwise we just
 256 ;;; return the number of digits or 0.
 257 #!-sb-fluid (declaim (maybe-inline float-precision))
 258 (defun float-precision (f)
 259   #!+sb-doc
 260   "Return a non-negative number of significant digits in its float argument.
 261   Will be less than FLOAT-DIGITS if denormalized or zero."
 262   (macrolet ((frob (digits bias decode)
 263                `(cond ((zerop f) 0)
 264                       ((float-denormalized-p f)
 265                        (multiple-value-bind (ignore exp) (,decode f)
 266                          (declare (ignore ignore))
 267                          (truly-the fixnum
 268                                     (+ ,digits (1- ,digits) ,bias exp))))
 269                       (t
 270                        ,digits))))
 271     (number-dispatch ((f float))
 272       ((single-float)
 273        (frob sb!vm:single-float-digits sb!vm:single-float-bias
 274          integer-decode-single-denorm))
 275       ((double-float)
 276        (frob sb!vm:double-float-digits sb!vm:double-float-bias
 277          integer-decode-double-denorm))
 278       #!+long-float
 279       ((long-float)
 280        (frob sb!vm:long-float-digits sb!vm:long-float-bias
 281          integer-decode-long-denorm)))))
 282
 283 (defun float-sign (float1 &optional (float2 (float 1 float1)))
 284   #!+sb-doc
 285   "Return a floating-point number that has the same sign as
 286    FLOAT1 and, if FLOAT2 is given, has the same absolute value
 287    as FLOAT2."
 288   (declare (float float1 float2))
 289   (* (if (etypecase float1
 290            (single-float (minusp (single-float-bits float1)))
 291            (double-float (minusp (double-float-high-bits float1)))
 292            #!+long-float
 293            (long-float (minusp (long-float-exp-bits float1))))
 294          (float -1 float1)
 295          (float 1 float1))
 296      (abs float2)))
 297
 298 (defun float-format-digits (format)
 299   (ecase format
 300     ((short-float single-float) sb!vm:single-float-digits)
 301     ((double-float #!-long-float long-float) sb!vm:double-float-digits)
 302     #!+long-float
 303     (long-float sb!vm:long-float-digits)))
 304
 305 #!-sb-fluid (declaim (inline float-digits float-radix))
 306
 307 (defun float-digits (f)
 308   (number-dispatch ((f float))
 309     ((single-float) sb!vm:single-float-digits)
 310     ((double-float) sb!vm:double-float-digits)
 311     #!+long-float
 312     ((long-float) sb!vm:long-float-digits)))
 313
 314 (defun float-radix (x)
 315   #!+sb-doc
 316   "Return (as an integer) the radix b of its floating-point argument."
 317   (declare (ignore x))
 318   2)
 319 \f
 320 ;;;; INTEGER-DECODE-FLOAT and DECODE-FLOAT
 321
 322 #!-sb-fluid
 323 (declaim (maybe-inline integer-decode-single-float
 324                        integer-decode-double-float))
 325
 326 ;;; Handle the denormalized case of INTEGER-DECODE-FLOAT for SINGLE-FLOAT.
 327 (defun integer-decode-single-denorm (x)
 328   (declare (type single-float x))
 329   (let* ((bits (single-float-bits (abs x)))
 330          (sig (ash (ldb sb!vm:single-float-significand-byte bits) 1))
 331          (extra-bias 0))
 332     (declare (type (unsigned-byte 24) sig)
 333              (type (integer 0 23) extra-bias))
 334     (loop
 335       (unless (zerop (logand sig sb!vm:single-float-hidden-bit))
 336         (return))
 337       (setq sig (ash sig 1))
 338       (incf extra-bias))
 339     (values sig
 340             (- (- sb!vm:single-float-bias)
 341                sb!vm:single-float-digits
 342                extra-bias)
 343             (if (minusp (float-sign x)) -1 1))))
 344
 345 ;;; Handle the single-float case of INTEGER-DECODE-FLOAT. If an infinity or
 346 ;;; NaN, error. If a denorm, call i-d-s-DENORM to handle it.
 347 (defun integer-decode-single-float (x)
 348   (declare (single-float x))
 349   (let* ((bits (single-float-bits (abs x)))
 350          (exp (ldb sb!vm:single-float-exponent-byte bits))
 351          (sig (ldb sb!vm:single-float-significand-byte bits))
 352          (sign (if (minusp (float-sign x)) -1 1))
 353          (biased (- exp sb!vm:single-float-bias sb!vm:single-float-digits)))
 354     (declare (fixnum biased))
 355     (unless (<= exp sb!vm:single-float-normal-exponent-max)
 356       (error "can't decode NaN or infinity: ~S" x))
 357     (cond ((and (zerop exp) (zerop sig))
 358            (values 0 biased sign))
 359           ((< exp sb!vm:single-float-normal-exponent-min)
 360            (integer-decode-single-denorm x))
 361           (t
 362            (values (logior sig sb!vm:single-float-hidden-bit) biased sign)))))
 363
 364 ;;; like INTEGER-DECODE-SINGLE-DENORM, only doubly so
 365 (defun integer-decode-double-denorm (x)
 366   (declare (type double-float x))
 367   (let* ((high-bits (double-float-high-bits (abs x)))
 368          (sig-high (ldb sb!vm:double-float-significand-byte high-bits))
 369          (low-bits (double-float-low-bits x))
 370          (sign (if (minusp (float-sign x)) -1 1))
 371          (biased (- (- sb!vm:double-float-bias) sb!vm:double-float-digits)))
 372     (if (zerop sig-high)
 373         (let ((sig low-bits)
 374               (extra-bias (- sb!vm:double-float-digits 33))
 375               (bit (ash 1 31)))
 376           (declare (type (unsigned-byte 32) sig) (fixnum extra-bias))
 377           (loop
 378             (unless (zerop (logand sig bit)) (return))
 379             (setq sig (ash sig 1))
 380             (incf extra-bias))
 381           (values (ash sig (- sb!vm:double-float-digits 32))
 382                   (truly-the fixnum (- biased extra-bias))
 383                   sign))
 384         (let ((sig (ash sig-high 1))
 385               (extra-bias 0))
 386           (declare (type (unsigned-byte 32) sig) (fixnum extra-bias))
 387           (loop
 388             (unless (zerop (logand sig sb!vm:double-float-hidden-bit))
 389               (return))
 390             (setq sig (ash sig 1))
 391             (incf extra-bias))
 392           (values (logior (ash sig 32) (ash low-bits (1- extra-bias)))
 393                   (truly-the fixnum (- biased extra-bias))
 394                   sign)))))
 395
 396 ;;; like INTEGER-DECODE-SINGLE-FLOAT, only doubly so
 397 (defun integer-decode-double-float (x)
 398   (declare (double-float x))
 399   (let* ((abs (abs x))
 400          (hi (double-float-high-bits abs))
 401          (lo (double-float-low-bits abs))
 402          (exp (ldb sb!vm:double-float-exponent-byte hi))
 403          (sig (ldb sb!vm:double-float-significand-byte hi))
 404          (sign (if (minusp (float-sign x)) -1 1))
 405          (biased (- exp sb!vm:double-float-bias sb!vm:double-float-digits)))
 406     (declare (fixnum biased))
 407     (unless (<= exp sb!vm:double-float-normal-exponent-max)
 408       (error "Can't decode NaN or infinity: ~S." x))
 409     (cond ((and (zerop exp) (zerop sig) (zerop lo))
 410            (values 0 biased sign))
 411           ((< exp sb!vm:double-float-normal-exponent-min)
 412            (integer-decode-double-denorm x))
 413           (t
 414            (values
 415             (logior (ash (logior (ldb sb!vm:double-float-significand-byte hi)
 416                                  sb!vm:double-float-hidden-bit)
 417                          32)
 418                     lo)
 419             biased sign)))))
 420
 421 #!+(and long-float x86)
 422 (defun integer-decode-long-denorm (x)
 423   (declare (type long-float x))
 424   (let* ((high-bits (long-float-high-bits (abs x)))
 425          (sig-high (ldb sb!vm:long-float-significand-byte high-bits))
 426          (low-bits (long-float-low-bits x))
 427          (sign (if (minusp (float-sign x)) -1 1))
 428          (biased (- (- sb!vm:long-float-bias) sb!vm:long-float-digits)))
 429     (if (zerop sig-high)
 430         (let ((sig low-bits)
 431               (extra-bias (- sb!vm:long-float-digits 33))
 432               (bit (ash 1 31)))
 433           (declare (type (unsigned-byte 32) sig) (fixnum extra-bias))
 434           (loop
 435             (unless (zerop (logand sig bit)) (return))
 436             (setq sig (ash sig 1))
 437             (incf extra-bias))
 438           (values (ash sig (- sb!vm:long-float-digits 32))
 439                   (truly-the fixnum (- biased extra-bias))
 440                   sign))
 441         (let ((sig (ash sig-high 1))
 442               (extra-bias 0))
 443           (declare (type (unsigned-byte 32) sig) (fixnum extra-bias))
 444           (loop
 445             (unless (zerop (logand sig sb!vm:long-float-hidden-bit))
 446               (return))
 447             (setq sig (ash sig 1))
 448             (incf extra-bias))
 449           (values (logior (ash sig 32) (ash low-bits (1- extra-bias)))
 450                   (truly-the fixnum (- biased extra-bias))
 451                   sign)))))
 452
 453 #!+(and long-float x86)
 454 (defun integer-decode-long-float (x)
 455   (declare (long-float x))
 456   (let* ((hi (long-float-high-bits x))
 457          (lo (long-float-low-bits x))
 458          (exp-bits (long-float-exp-bits x))
 459          (exp (ldb sb!vm:long-float-exponent-byte exp-bits))
 460          (sign (if (minusp exp-bits) -1 1))
 461          (biased (- exp sb!vm:long-float-bias sb!vm:long-float-digits)))
 462     (declare (fixnum biased))
 463     (unless (<= exp sb!vm:long-float-normal-exponent-max)
 464       (error "can't decode NaN or infinity: ~S" x))
 465     (cond ((and (zerop exp) (zerop hi) (zerop lo))
 466            (values 0 biased sign))
 467           ((< exp sb!vm:long-float-normal-exponent-min)
 468            (integer-decode-long-denorm x))
 469           (t
 470            (values (logior (ash hi 32) lo) biased sign)))))
 471
 472 ;;; Dispatch to the correct type-specific i-d-f function.
 473 (defun integer-decode-float (x)
 474   #!+sb-doc
 475   "Return three values:
 476    1) an integer representation of the significand.
 477    2) the exponent for the power of 2 that the significand must be multiplied
 478       by to get the actual value. This differs from the DECODE-FLOAT exponent
 479       by FLOAT-DIGITS, since the significand has been scaled to have all its
 480       digits before the radix point.
 481    3) -1 or 1 (i.e. the sign of the argument.)"
 482   (number-dispatch ((x float))
 483     ((single-float)
 484      (integer-decode-single-float x))
 485     ((double-float)
 486      (integer-decode-double-float x))
 487     #!+long-float
 488     ((long-float)
 489      (integer-decode-long-float x))))
 490
 491 #!-sb-fluid (declaim (maybe-inline decode-single-float decode-double-float))
 492
 493 ;;; Handle the denormalized case of DECODE-SINGLE-FLOAT. We call
 494 ;;; INTEGER-DECODE-SINGLE-DENORM and then make the result into a float.
 495 (defun decode-single-denorm (x)
 496   (declare (type single-float x))
 497   (multiple-value-bind (sig exp sign) (integer-decode-single-denorm x)
 498     (values (make-single-float
 499              (dpb sig sb!vm:single-float-significand-byte
 500                   (dpb sb!vm:single-float-bias
 501                        sb!vm:single-float-exponent-byte
 502                        0)))
 503             (truly-the fixnum (+ exp sb!vm:single-float-digits))
 504             (float sign x))))
 505
 506 ;;; Handle the single-float case of DECODE-FLOAT. If an infinity or NaN,
 507 ;;; error. If a denorm, call d-s-DENORM to handle it.
 508 (defun decode-single-float (x)
 509   (declare (single-float x))
 510   (let* ((bits (single-float-bits (abs x)))
 511          (exp (ldb sb!vm:single-float-exponent-byte bits))
 512          (sign (float-sign x))
 513          (biased (truly-the single-float-exponent
 514                             (- exp sb!vm:single-float-bias))))
 515     (unless (<= exp sb!vm:single-float-normal-exponent-max)
 516       (error "can't decode NaN or infinity: ~S" x))
 517     (cond ((zerop x)
 518            (values 0.0f0 biased sign))
 519           ((< exp sb!vm:single-float-normal-exponent-min)
 520            (decode-single-denorm x))
 521           (t
 522            (values (make-single-float
 523                     (dpb sb!vm:single-float-bias
 524                          sb!vm:single-float-exponent-byte
 525                          bits))
 526                    biased sign)))))
 527
 528 ;;; like DECODE-SINGLE-DENORM, only doubly so
 529 (defun decode-double-denorm (x)
 530   (declare (double-float x))
 531   (multiple-value-bind (sig exp sign) (integer-decode-double-denorm x)
 532     (values (make-double-float
 533              (dpb (logand (ash sig -32) (lognot sb!vm:double-float-hidden-bit))
 534                   sb!vm:double-float-significand-byte
 535                   (dpb sb!vm:double-float-bias
 536                        sb!vm:double-float-exponent-byte 0))
 537              (ldb (byte 32 0) sig))
 538             (truly-the fixnum (+ exp sb!vm:double-float-digits))
 539             (float sign x))))
 540
 541 ;;; like DECODE-SINGLE-FLOAT, only doubly so
 542 (defun decode-double-float (x)
 543   (declare (double-float x))
 544   (let* ((abs (abs x))
 545          (hi (double-float-high-bits abs))
 546          (lo (double-float-low-bits abs))
 547          (exp (ldb sb!vm:double-float-exponent-byte hi))
 548          (sign (float-sign x))
 549          (biased (truly-the double-float-exponent
 550                             (- exp sb!vm:double-float-bias))))
 551     (unless (<= exp sb!vm:double-float-normal-exponent-max)
 552       (error "can't decode NaN or infinity: ~S" x))
 553     (cond ((zerop x)
 554            (values 0.0d0 biased sign))
 555           ((< exp sb!vm:double-float-normal-exponent-min)
 556            (decode-double-denorm x))
 557           (t
 558            (values (make-double-float
 559                     (dpb sb!vm:double-float-bias
 560                          sb!vm:double-float-exponent-byte hi)
 561                     lo)
 562                    biased sign)))))
 563
 564 #!+(and long-float x86)
 565 (defun decode-long-denorm (x)
 566   (declare (long-float x))
 567   (multiple-value-bind (sig exp sign) (integer-decode-long-denorm x)
 568     (values (make-long-float sb!vm:long-float-bias (ash sig -32)
 569                              (ldb (byte 32 0) sig))
 570             (truly-the fixnum (+ exp sb!vm:long-float-digits))
 571             (float sign x))))
 572
 573 #!+(and long-float x86)
 574 (defun decode-long-float (x)
 575   (declare (long-float x))
 576   (let* ((hi (long-float-high-bits x))
 577          (lo (long-float-low-bits x))
 578          (exp-bits (long-float-exp-bits x))
 579          (exp (ldb sb!vm:long-float-exponent-byte exp-bits))
 580          (sign (if (minusp exp-bits) -1l0 1l0))
 581          (biased (truly-the long-float-exponent
 582                             (- exp sb!vm:long-float-bias))))
 583     (unless (<= exp sb!vm:long-float-normal-exponent-max)
 584       (error "can't decode NaN or infinity: ~S" x))
 585     (cond ((zerop x)
 586            (values 0.0l0 biased sign))
 587           ((< exp sb!vm:long-float-normal-exponent-min)
 588            (decode-long-denorm x))
 589           (t
 590            (values (make-long-float
 591                     (dpb sb!vm:long-float-bias sb!vm:long-float-exponent-byte
 592                          exp-bits)
 593                     hi
 594                     lo)
 595                    biased sign)))))
 596
 597 ;;; Dispatch to the appropriate type-specific function.
 598 (defun decode-float (f)
 599   #!+sb-doc
 600   "Return three values:
 601    1) a floating-point number representing the significand. This is always
 602       between 0.5 (inclusive) and 1.0 (exclusive).
 603    2) an integer representing the exponent.
 604    3) -1.0 or 1.0 (i.e. the sign of the argument.)"
 605   (number-dispatch ((f float))
 606     ((single-float)
 607      (decode-single-float f))
 608     ((double-float)
 609      (decode-double-float f))
 610     #!+long-float
 611     ((long-float)
 612      (decode-long-float f))))
 613 \f
 614 ;;;; SCALE-FLOAT
 615
 616 #!-sb-fluid (declaim (maybe-inline scale-single-float scale-double-float))
 617
 618 ;;; Handle float scaling where the X is denormalized or the result is
 619 ;;; denormalized or underflows to 0.
 620 (defun scale-float-maybe-underflow (x exp)
 621   (multiple-value-bind (sig old-exp) (integer-decode-float x)
 622     (let* ((digits (float-digits x))
 623            (new-exp (+ exp old-exp digits
 624                        (etypecase x
 625                          (single-float sb!vm:single-float-bias)
 626                          (double-float sb!vm:double-float-bias))))
 627            (sign (if (minusp (float-sign x)) 1 0)))
 628       (cond
 629        ((< new-exp
 630            (etypecase x
 631              (single-float sb!vm:single-float-normal-exponent-min)
 632              (double-float sb!vm:double-float-normal-exponent-min)))
 633         (when (sb!vm:current-float-trap :inexact)
 634           (error 'floating-point-inexact :operation 'scale-float
 635                  :operands (list x exp)))
 636         (when (sb!vm:current-float-trap :underflow)
 637           (error 'floating-point-underflow :operation 'scale-float
 638                  :operands (list x exp)))
 639         (let ((shift (1- new-exp)))
 640           (if (< shift (- (1- digits)))
 641               (float-sign x 0.0)
 642               (etypecase x
 643                 (single-float (single-from-bits sign 0 (ash sig shift)))
 644                 (double-float (double-from-bits sign 0 (ash sig shift)))))))
 645        (t
 646         (etypecase x
 647           (single-float (single-from-bits sign new-exp sig))
 648           (double-float (double-from-bits sign new-exp sig))))))))
 649
 650 ;;; Called when scaling a float overflows, or the original float was a
 651 ;;; NaN or infinity. If overflow errors are trapped, then error,
 652 ;;; otherwise return the appropriate infinity. If a NaN, signal or not
 653 ;;; as appropriate.
 654 (defun scale-float-maybe-overflow (x exp)
 655   (cond
 656    ((float-infinity-p x)
 657     ;; Infinity is infinity, no matter how small...
 658     x)
 659    ((float-nan-p x)
 660     (when (and (float-trapping-nan-p x)
 661                (sb!vm:current-float-trap :invalid))
 662       (error 'floating-point-invalid-operation :operation 'scale-float
 663              :operands (list x exp)))
 664     x)
 665    (t
 666     (when (sb!vm:current-float-trap :overflow)
 667       (error 'floating-point-overflow :operation 'scale-float
 668              :operands (list x exp)))
 669     (when (sb!vm:current-float-trap :inexact)
 670       (error 'floating-point-inexact :operation 'scale-float
 671              :operands (list x exp)))
 672     (* (float-sign x)
 673        (etypecase x
 674          (single-float single-float-positive-infinity)
 675          (double-float double-float-positive-infinity))))))
 676
 677 ;;; Scale a single or double float, calling the correct over/underflow
 678 ;;; functions.
 679 (defun scale-single-float (x exp)
 680   (declare (single-float x) (fixnum exp))
 681   (let* ((bits (single-float-bits x))
 682          (old-exp (ldb sb!vm:single-float-exponent-byte bits))
 683          (new-exp (+ old-exp exp)))
 684     (cond
 685      ((zerop x) x)
 686      ((or (< old-exp sb!vm:single-float-normal-exponent-min)
 687           (< new-exp sb!vm:single-float-normal-exponent-min))
 688       (scale-float-maybe-underflow x exp))
 689      ((or (> old-exp sb!vm:single-float-normal-exponent-max)
 690           (> new-exp sb!vm:single-float-normal-exponent-max))
 691       (scale-float-maybe-overflow x exp))
 692      (t
 693       (make-single-float (dpb new-exp
 694                               sb!vm:single-float-exponent-byte
 695                               bits))))))
 696 (defun scale-double-float (x exp)
 697   (declare (double-float x) (fixnum exp))
 698   (let* ((hi (double-float-high-bits x))
 699          (lo (double-float-low-bits x))
 700          (old-exp (ldb sb!vm:double-float-exponent-byte hi))
 701          (new-exp (+ old-exp exp)))
 702     (cond
 703      ((zerop x) x)
 704      ((or (< old-exp sb!vm:double-float-normal-exponent-min)
 705           (< new-exp sb!vm:double-float-normal-exponent-min))
 706       (scale-float-maybe-underflow x exp))
 707      ((or (> old-exp sb!vm:double-float-normal-exponent-max)
 708           (> new-exp sb!vm:double-float-normal-exponent-max))
 709       (scale-float-maybe-overflow x exp))
 710      (t
 711       (make-double-float (dpb new-exp sb!vm:double-float-exponent-byte hi)
 712                          lo)))))
 713
 714 #!+(and x86 long-float)
 715 (defun scale-long-float (x exp)
 716   (declare (long-float x) (fixnum exp))
 717   (scale-float x exp))
 718
 719 ;;; Dispatch to the correct type-specific scale-float function.
 720 (defun scale-float (f ex)
 721   #!+sb-doc
 722   "Return the value (* f (expt (float 2 f) ex)), but with no unnecessary loss
 723   of precision or overflow."
 724   (number-dispatch ((f float))
 725     ((single-float)
 726      (scale-single-float f ex))
 727     ((double-float)
 728      (scale-double-float f ex))
 729     #!+long-float
 730     ((long-float)
 731      (scale-long-float f ex))))
 732 \f
 733 ;;;; converting to/from floats
 734
 735 (defun float (number &optional (other () otherp))
 736   #!+sb-doc
 737   "Converts any REAL to a float. If OTHER is not provided, it returns a
 738   SINGLE-FLOAT if NUMBER is not already a FLOAT. If OTHER is provided, the
 739   result is the same float format as OTHER."
 740   (if otherp
 741       (number-dispatch ((number real) (other float))
 742         (((foreach rational single-float double-float #!+long-float long-float)
 743           (foreach single-float double-float #!+long-float long-float))
 744          (coerce number '(dispatch-type other))))
 745       (if (floatp number)
 746           number
 747           (coerce number 'single-float))))
 748
 749 (macrolet ((frob (name type)
 750              `(defun ,name (x)
 751                 (number-dispatch ((x real))
 752                   (((foreach single-float double-float #!+long-float long-float
 753                              fixnum))
 754                    (coerce x ',type))
 755                   ((bignum)
 756                    (bignum-to-float x ',type))
 757                   ((ratio)
 758                    (float-ratio x ',type))))))
 759   (frob %single-float single-float)
 760   (frob %double-float double-float)
 761   #!+long-float
 762   (frob %long-float long-float))
 763
 764 ;;; Convert a ratio to a float. We avoid any rounding error by doing an
 765 ;;; integer division. Accuracy is important to preserve read/print
 766 ;;; consistency, since this is ultimately how the reader reads a float. We
 767 ;;; scale the numerator by a power of two until the division results in the
 768 ;;; desired number of fraction bits, then do round-to-nearest.
 769 (defun float-ratio (x format)
 770   (let* ((signed-num (numerator x))
 771          (plusp (plusp signed-num))
 772          (num (if plusp signed-num (- signed-num)))
 773          (den (denominator x))
 774          (digits (float-format-digits format))
 775          (scale 0))
 776     (declare (fixnum digits scale))
 777     ;; Strip any trailing zeros from the denominator and move it into the scale
 778     ;; factor (to minimize the size of the operands.)
 779     (let ((den-twos (1- (integer-length (logxor den (1- den))))))
 780       (declare (fixnum den-twos))
 781       (decf scale den-twos)
 782       (setq den (ash den (- den-twos))))
 783     ;; Guess how much we need to scale by from the magnitudes of the numerator
 784     ;; and denominator. We want one extra bit for a guard bit.
 785     (let* ((num-len (integer-length num))
 786            (den-len (integer-length den))
 787            (delta (- den-len num-len))
 788            (shift (1+ (the fixnum (+ delta digits))))
 789            (shifted-num (ash num shift)))
 790       (declare (fixnum delta shift))
 791       (decf scale delta)
 792       (labels ((float-and-scale (bits)
 793                  (let* ((bits (ash bits -1))
 794                         (len (integer-length bits)))
 795                    (cond ((> len digits)
 796                           (aver (= len (the fixnum (1+ digits))))
 797                           (scale-float (floatit (ash bits -1)) (1+ scale)))
 798                          (t
 799                           (scale-float (floatit bits) scale)))))
 800                (floatit (bits)
 801                  (let ((sign (if plusp 0 1)))
 802                    (case format
 803                      (single-float
 804                       (single-from-bits sign sb!vm:single-float-bias bits))
 805                      (double-float
 806                       (double-from-bits sign sb!vm:double-float-bias bits))
 807                      #!+long-float
 808                      (long-float
 809                       (long-from-bits sign sb!vm:long-float-bias bits))))))
 810         (loop
 811           (multiple-value-bind (fraction-and-guard rem)
 812               (truncate shifted-num den)
 813             (let ((extra (- (integer-length fraction-and-guard) digits)))
 814               (declare (fixnum extra))
 815               (cond ((/= extra 1)
 816                      (aver (> extra 1)))
 817                     ((oddp fraction-and-guard)
 818                      (return
 819                       (if (zerop rem)
 820                           (float-and-scale
 821                            (if (zerop (logand fraction-and-guard 2))
 822                                fraction-and-guard
 823                                (1+ fraction-and-guard)))
 824                           (float-and-scale (1+ fraction-and-guard)))))
 825                     (t
 826                      (return (float-and-scale fraction-and-guard)))))
 827             (setq shifted-num (ash shifted-num -1))
 828             (incf scale)))))))
 829
 830 #|
 831 These might be useful if we ever have a machine without float/integer
 832 conversion hardware. For now, we'll use special ops that
 833 uninterruptibly frob the rounding modes & do ieee round-to-integer.
 834
 835 ;;; The compiler compiles a call to this when we are doing %UNARY-TRUNCATE
 836 ;;; and the result is known to be a fixnum. We can avoid some generic
 837 ;;; arithmetic in this case.
 838 (defun %unary-truncate-single-float/fixnum (x)
 839   (declare (single-float x) (values fixnum))
 840   (locally (declare (optimize (speed 3) (safety 0)))
 841     (let* ((bits (single-float-bits x))
 842            (exp (ldb sb!vm:single-float-exponent-byte bits))
 843            (frac (logior (ldb sb!vm:single-float-significand-byte bits)
 844                          sb!vm:single-float-hidden-bit))
 845            (shift (- exp sb!vm:single-float-digits sb!vm:single-float-bias)))
 846       (when (> exp sb!vm:single-float-normal-exponent-max)
 847         (error 'floating-point-invalid-operation :operator 'truncate
 848                :operands (list x)))
 849       (if (<= shift (- sb!vm:single-float-digits))
 850           0
 851           (let ((res (ash frac shift)))
 852             (declare (type (unsigned-byte 31) res))
 853             (if (minusp bits)
 854                 (- res)
 855                 res))))))
 856
 857 ;;; Double-float version of this operation (see above single op).
 858 (defun %unary-truncate-double-float/fixnum (x)
 859   (declare (double-float x) (values fixnum))
 860   (locally (declare (optimize (speed 3) (safety 0)))
 861     (let* ((hi-bits (double-float-high-bits x))
 862            (exp (ldb sb!vm:double-float-exponent-byte hi-bits))
 863            (frac (logior (ldb sb!vm:double-float-significand-byte hi-bits)
 864                          sb!vm:double-float-hidden-bit))
 865            (shift (- exp (- sb!vm:double-float-digits sb!vm:n-word-bits)
 866                      sb!vm:double-float-bias)))
 867       (when (> exp sb!vm:double-float-normal-exponent-max)
 868         (error 'floating-point-invalid-operation :operator 'truncate
 869                :operands (list x)))
 870       (if (<= shift (- sb!vm:n-word-bits sb!vm:double-float-digits))
 871           0
 872           (let* ((res-hi (ash frac shift))
 873                  (res (if (plusp shift)
 874                           (logior res-hi
 875                                   (the fixnum
 876                                        (ash (double-float-low-bits x)
 877                                             (- shift sb!vm:n-word-bits))))
 878                           res-hi)))
 879             (declare (type (unsigned-byte 31) res-hi res))
 880             (if (minusp hi-bits)
 881                 (- res)
 882                 res))))))
 883 |#
 884
 885 ;;; This function is called when we are doing a truncate without any funky
 886 ;;; divisor, i.e. converting a float or ratio to an integer. Note that we do
 887 ;;; *not* return the second value of truncate, so it must be computed by the
 888 ;;; caller if needed.
 889 ;;;
 890 ;;; In the float case, we pick off small arguments so that compiler can use
 891 ;;; special-case operations. We use an exclusive test, since (due to round-off
 892 ;;; error), (float most-positive-fixnum) may be greater than
 893 ;;; most-positive-fixnum.
 894 (defun %unary-truncate (number)
 895   (number-dispatch ((number real))
 896     ((integer) number)
 897     ((ratio) (values (truncate (numerator number) (denominator number))))
 898     (((foreach single-float double-float #!+long-float long-float))
 899      (if (< (float most-negative-fixnum number)
 900             number
 901             (float most-positive-fixnum number))
 902          (truly-the fixnum (%unary-truncate number))
 903          (multiple-value-bind (bits exp) (integer-decode-float number)
 904            (let ((res (ash bits exp)))
 905              (if (minusp number)
 906                  (- res)
 907                  res)))))))
 908
 909 ;;; Similar to %UNARY-TRUNCATE, but rounds to the nearest integer. If we
 910 ;;; can't use the round primitive, then we do our own round-to-nearest on the
 911 ;;; result of i-d-f. [Note that this rounding will really only happen with
 912 ;;; double floats, since the whole single-float fraction will fit in a fixnum,
 913 ;;; so all single-floats larger than most-positive-fixnum can be precisely
 914 ;;; represented by an integer.]
 915 (defun %unary-round (number)
 916   (number-dispatch ((number real))
 917     ((integer) number)
 918     ((ratio) (values (round (numerator number) (denominator number))))
 919     (((foreach single-float double-float #!+long-float long-float))
 920      (if (< (float most-negative-fixnum number)
 921             number
 922             (float most-positive-fixnum number))
 923          (truly-the fixnum (%unary-round number))
 924          (multiple-value-bind (bits exp) (integer-decode-float number)
 925            (let* ((shifted (ash bits exp))
 926                   (rounded (if (and (minusp exp)
 927                                     (oddp shifted)
 928                                     (eql (logand bits
 929                                                  (lognot (ash -1 (- exp))))
 930                                          (ash 1 (- -1 exp))))
 931                                (1+ shifted)
 932                                shifted)))
 933              (if (minusp number)
 934                  (- rounded)
 935                  rounded)))))))
 936
 937 (defun rational (x)
 938   #!+sb-doc
 939   "RATIONAL produces a rational number for any real numeric argument. This is
 940   more efficient than RATIONALIZE, but it assumes that floating-point is
 941   completely accurate, giving a result that isn't as pretty."
 942   (number-dispatch ((x real))
 943     (((foreach single-float double-float #!+long-float long-float))
 944      (multiple-value-bind (bits exp) (integer-decode-float x)
 945        (if (eql bits 0)
 946            0
 947            (let* ((int (if (minusp x) (- bits) bits))
 948                   (digits (float-digits x))
 949                   (ex (+ exp digits)))
 950              (if (minusp ex)
 951                  (integer-/-integer int (ash 1 (+ digits (- ex))))
 952                  (integer-/-integer (ash int ex) (ash 1 digits)))))))
 953     ((rational) x)))
 954
 955 (defun rationalize (x)
 956   #!+sb-doc
 957   "Converts any REAL to a RATIONAL. Floats are converted to a simple rational
 958   representation exploiting the assumption that floats are only accurate to
 959   their precision. RATIONALIZE (and also RATIONAL) preserve the invariant:
 960       (= x (float (rationalize x) x))"
 961   (number-dispatch ((x real))
 962     (((foreach single-float double-float #!+long-float long-float))
 963      ;; Thanks to Kim Fateman, who stole this function rationalize-float from
 964      ;; macsyma's rational. Macsyma'a rationalize was written by the legendary
 965      ;; Gosper (rwg). Guy Steele said about Gosper, "He has been called the
 966      ;; only living 17th century mathematician and is also the best pdp-10
 967      ;; hacker I know." So, if you can understand or debug this code you win
 968      ;; big.
 969      (cond ((minusp x) (- (rationalize (- x))))
 970            ((zerop x) 0)
 971            (t
 972             (let ((eps (etypecase x
 973                            (single-float single-float-epsilon)
 974                            (double-float double-float-epsilon)
 975                            #!+long-float
 976                            (long-float long-float-epsilon)))
 977                   (y ())
 978                   (a ()))
 979               (do ((xx x (setq y (/ (float 1.0 x) (- xx (float a x)))))
 980                    (num (setq a (truncate x))
 981                         (+ (* (setq a (truncate y)) num) onum))
 982                    (den 1 (+ (* a den) oden))
 983                    (onum 1 num)
 984                    (oden 0 den))
 985                   ((and (not (zerop den))
 986                         (not (> (abs (/ (- x (/ (float num x)
 987                                                 (float den x)))
 988                                         x))
 989                                 eps)))
 990                    (integer-/-integer num den))
 991                 (declare ((dispatch-type x) xx)))))))
 992     ((rational) x)))