src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Define NAME as a fasl operation, with op-code FOP-CODE. PUSHP
   6 ;;; describes what the body does to the fop stack:
   7 ;;;   T
   8 ;;;     The body might pop the fop stack. The result of the body is
   9 ;;;     pushed on the fop stack.
  10 ;;;   NIL
  11 ;;;     The body might pop the fop stack. The result of the body is
  12 ;;;     discarded.
  13 ;;; STACKP describes whether or not the body interacts with the fop stack.
  14 (defmacro define-fop ((name fop-code &key (pushp t) (stackp t)) &rest forms)
  15   `(progn
  16      (defun ,name ()
  17        ,(if stackp
  18             `(with-fop-stack ,pushp ,@forms)
  19             `(progn ,@forms)))
  20      (%define-fop ',name ,fop-code)))
  21
  22 (defun %define-fop (name code)
  23   (let ((oname (svref *fop-names* code)))
  24     (when (and oname (not (eq oname name)))
  25       (error "multiple names for fop code ~D: ~S and ~S" code name oname)))
  26   ;; KLUDGE: It's mnemonically suboptimal to use 'FOP-CODE as the name of the
  27   ;; tag which associates names with codes when it's also used as one of
  28   ;; the names. Perhaps the fops named FOP-CODE and FOP-SMALL-CODE could
  29   ;; be renamed to something more mnemonic? -- WHN 19990902
  30   (let ((ocode (get name 'fop-code)))
  31     (when (and ocode (/= ocode code))
  32       (error "multiple codes for fop name ~S: ~D and ~D" name code ocode)))
  33   (setf (svref *fop-names* code) name
  34         (get name 'fop-code) code
  35         (svref *fop-funs* code) (symbol-function name))
  36   (values))
  37
  38 ;;; Define a pair of fops which are identical except that one reads
  39 ;;; a four-byte argument while the other reads a one-byte argument. The
  40 ;;; argument can be accessed by using the CLONE-ARG macro.
  41 ;;;
  42 ;;; KLUDGE: It would be nice if the definition here encapsulated which
  43 ;;; value ranges went with which fop variant, and chose the correct
  44 ;;; fop code to use. Currently, since such logic isn't encapsulated,
  45 ;;; we see callers doing stuff like
  46 ;;;     (cond ((and (< num-consts #x100) (< total-length #x10000))
  47 ;;;            (dump-fop 'sb!impl::fop-small-code file)
  48 ;;;            (dump-byte num-consts file)
  49 ;;;            (dump-integer-as-n-bytes total-length 2 file))
  50 ;;;           (t
  51 ;;;            (dump-fop 'sb!impl::fop-code file)
  52 ;;;            (dump-unsigned-32 num-consts file)
  53 ;;;            (dump-unsigned-32 total-length file))))
  54 ;;; in several places. It would be cleaner if this could be replaced with
  55 ;;; something like
  56 ;;;     (dump-fop file fop-code num-consts total-length)
  57 ;;; Some of this logic is already in DUMP-FOP*, but that still requires the
  58 ;;; caller to know that it's a 1-byte-arg/4-byte-arg cloned fop pair, and to
  59 ;;; know both the 1-byte-arg and the 4-byte-arg fop names. -- WHN 19990902
  60 (defmacro define-cloned-fops ((name code &key (pushp t) (stackp t))
  61                               (small-name small-code) &rest forms)
  62   (aver (member pushp '(nil t)))
  63   (aver (member stackp '(nil t)))
  64   `(progn
  65      (macrolet ((clone-arg () '(read-arg 4)))
  66        (define-fop (,name ,code :pushp ,pushp :stackp ,stackp) ,@forms))
  67      (macrolet ((clone-arg () '(read-arg 1)))
  68        (define-fop (,small-name ,small-code :pushp ,pushp :stackp stackp) ,@forms))))
  69
  70 ;;; a helper function for reading string values from FASL files: sort
  71 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  72 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  73 ;;; for each element read
  74 (declaim (ftype (function (stream simple-string &optional index) (values)) read-string-as-bytes))
  75 (defun read-string-as-bytes (stream string &optional (length (length string)))
  76   (dotimes (i length)
  77     (setf (aref string i)
  78           (code-char (read-byte stream))))
  79   ;; FIXME: The classic CMU CL code to do this was
  80   ;;   (READ-N-BYTES FILE STRING START END).
  81   ;; It was changed for SBCL because we needed a portable version for
  82   ;; bootstrapping. Benchmark the non-portable version and see whether it's
  83   ;; significantly better than the portable version here. If it is, then use
  84   ;; add as an alternate definition, protected with #-SB-XC-HOST.
  85   (values))
  86 \f
  87 ;;;; miscellaneous fops
  88
  89 ;;; FIXME: POP-STACK should be called something more mnemonic. (POP-FOP-STACK?
  90 ;;; But that would conflict with PUSH-FOP-TABLE. Something, anyway..)
  91
  92 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
  93 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
  94 ;;; progress of FASL loading.
  95 #!+sb-show
  96 (defvar *show-fop-nop4-p* nil)
  97
  98 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
  99 ;;; occurs disproportionately often in fasl files for other reasons,
 100 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 101 ;;; into fasl files for debugging purposes. There's no shortage of
 102 ;;; unused fop codes, so we add this second NOP, which reads 4
 103 ;;; arbitrary bytes and discards them.
 104 (define-fop (fop-nop4 137 :stackp nil)
 105   (let ((arg (read-arg 4)))
 106     (declare (ignorable arg))
 107     #!+sb-show
 108     (when *show-fop-nop4-p*
 109       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 110
 111 (define-fop (fop-nop 0 :stackp nil))
 112 (define-fop (fop-pop 1 :pushp nil) (push-fop-table (pop-stack)))
 113 (define-fop (fop-push 2) (svref *current-fop-table* (read-arg 4)))
 114 (define-fop (fop-byte-push 3) (svref *current-fop-table* (read-arg 1)))
 115
 116 (define-fop (fop-empty-list 4) ())
 117 (define-fop (fop-truth 5) t)
 118 ;;; CMU CL had FOP-POP-FOR-EFFECT as fop 65, but it was never used and seemed
 119 ;;; to have no possible use.
 120 (define-fop (fop-misc-trap 66)
 121   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 122   (error "FOP-MISC-TRAP can't be defined without %PRIMITIVE.")
 123   #-sb-xc-host
 124   (%primitive sb!c:make-other-immediate-type 0 sb!vm:unbound-marker-widetag))
 125
 126 ;;; CMU CL had FOP-CHARACTER as fop 68, but it's not needed in current
 127 ;;; SBCL as we have no extended characters, only 1-byte characters.
 128 ;;; (Ditto for CMU CL, actually: FOP-CHARACTER was speculative generality.)
 129 (define-fop (fop-short-character 69)
 130   (code-char (read-arg 1)))
 131
 132 (define-cloned-fops (fop-struct 48) (fop-small-struct 49)
 133   (let* ((size (clone-arg))
 134          (res (%make-instance size)))
 135     (declare (type index size))
 136     (do ((n (1- size) (1- n)))
 137         ((minusp n))
 138       (declare (type index-or-minus-1 n))
 139       (setf (%instance-ref res n) (pop-stack)))
 140     res))
 141
 142 (define-fop (fop-layout 45)
 143   (let ((length (pop-stack))
 144         (depthoid (pop-stack))
 145         (inherits (pop-stack))
 146         (name (pop-stack)))
 147     (find-and-init-or-check-layout name length inherits depthoid)))
 148
 149 (define-fop (fop-end-group 64 :stackp nil)
 150   (/show0 "THROWing FASL-GROUP-END")
 151   (throw 'fasl-group-end t))
 152
 153 ;;; In the normal loader, we just ignore these. GENESIS overwrites
 154 ;;; FOP-MAYBE-COLD-LOAD with something that knows whether to revert to
 155 ;;; cold-loading or not.
 156 (define-fop (fop-normal-load 81 :stackp nil))
 157 (define-fop (fop-maybe-cold-load 82 :stackp nil))
 158
 159 (define-fop (fop-verify-table-size 62 :stackp nil)
 160   (let ((expected-index (read-arg 4)))
 161     (unless (= *current-fop-table-index* expected-index)
 162       (bug "fasl table of improper size"))))
 163 (define-fop (fop-verify-empty-stack 63 :stackp nil)
 164   (unless (zerop (length *fop-stack*))
 165     (bug "fasl stack not empty when it should be")))
 166 \f
 167 ;;;; fops for loading symbols
 168
 169 (defvar *load-symbol-buffer* (make-string 100))
 170 (declaim (simple-string *load-symbol-buffer*))
 171 (defvar *load-symbol-buffer-size* 100)
 172 (declaim (type index *load-symbol-buffer-size*))
 173 ;;; FIXME:
 174 ;;;   (1) *LOAD-SYMBOL-BUFFER-SIZE* is redundant, should just be
 175 ;;;       (LENGTH *LOAD-SYMBOL-BUFFER*).
 176 ;;;   (2) *LOAD-SYMBOL-BUFFER* should not have a global value, but should
 177 ;;;       be bound on entry to FASL loading, and it should be renamed to
 178 ;;;       *FASL-SYMBOL-BUFFER*.
 179
 180 (macrolet (;; FIXME: Should all this code really be duplicated inside
 181            ;; each fop? Perhaps it would be better for this shared
 182            ;; code to live in FLET FROB1 and FLET FROB4 (for the
 183            ;; two different sizes of counts).
 184            (frob (name code name-size package)
 185              (let ((n-package (gensym))
 186                    (n-size (gensym))
 187                    (n-buffer (gensym)))
 188                `(define-fop (,name ,code)
 189                   (prepare-for-fast-read-byte *fasl-input-stream*
 190                     (let ((,n-package ,package)
 191                           (,n-size (fast-read-u-integer ,name-size)))
 192                       (when (> ,n-size *load-symbol-buffer-size*)
 193                         (setq *load-symbol-buffer*
 194                               (make-string (setq *load-symbol-buffer-size*
 195                                                  (* ,n-size 2)))))
 196                       (done-with-fast-read-byte)
 197                       (let ((,n-buffer *load-symbol-buffer*))
 198                         (read-string-as-bytes *fasl-input-stream*
 199                                               ,n-buffer
 200                                               ,n-size)
 201                         (push-fop-table (intern* ,n-buffer
 202                                                  ,n-size
 203                                                  ,n-package)))))))))
 204
 205   ;; Note: CMU CL had FOP-SYMBOL-SAVE and FOP-SMALL-SYMBOL-SAVE, but
 206   ;; since they made the behavior of the fasloader depend on the
 207   ;; *PACKAGE* variable, not only were they a pain to support (because
 208   ;; they required various hacks to handle *PACKAGE*-manipulation
 209   ;; forms) they were basically broken by design, because ANSI gives
 210   ;; the user so much flexibility in manipulating *PACKAGE* at
 211   ;; load-time that no reasonable hacks could possibly make things
 212   ;; work right. The ones used in CMU CL certainly didn't, as shown by
 213   ;; e.g.
 214   ;;   (IN-PACKAGE :CL-USER)
 215   ;;     (DEFVAR CL::*FOO* 'FOO-VALUE)
 216   ;;     (EVAL-WHEN (:COMPILE-TOPLEVEL :LOAD-TOPLEVEL :EXECUTE)
 217   ;;       (SETF *PACKAGE* (FIND-PACKAGE :CL)))
 218   ;; which in CMU CL 2.4.9 defines a variable CL-USER::*FOO* instead of
 219   ;; defining CL::*FOO*. Therefore, we don't use those fops in SBCL.
 220   ;;(frob fop-symbol-save               6 4 *package*)
 221   ;;(frob fop-small-symbol-save   7 1 *package*)
 222
 223   (frob fop-lisp-symbol-save          75 4 *cl-package*)
 224   (frob fop-lisp-small-symbol-save    76 1 *cl-package*)
 225   (frob fop-keyword-symbol-save       77 4 *keyword-package*)
 226   (frob fop-keyword-small-symbol-save 78 1 *keyword-package*)
 227
 228   ;; FIXME: Because we don't have FOP-SYMBOL-SAVE any more, an enormous number
 229   ;; of symbols will fall through to this case, probably resulting in bloated
 230   ;; fasl files. A new
 231   ;; FOP-SYMBOL-IN-LAST-PACKAGE-SAVE/FOP-SMALL-SYMBOL-IN-LAST-PACKAGE-SAVE
 232   ;; cloned fop pair could undo some of this bloat.
 233   (frob fop-symbol-in-package-save 8 4
 234     (svref *current-fop-table* (fast-read-u-integer 4)))
 235   (frob fop-small-symbol-in-package-save 9 1
 236     (svref *current-fop-table* (fast-read-u-integer 4)))
 237   (frob fop-symbol-in-byte-package-save 10 4
 238     (svref *current-fop-table* (fast-read-u-integer 1)))
 239   (frob fop-small-symbol-in-byte-package-save 11 1
 240     (svref *current-fop-table* (fast-read-u-integer 1))))
 241
 242 (define-cloned-fops (fop-uninterned-symbol-save 12)
 243                     (fop-uninterned-small-symbol-save 13)
 244   (let* ((arg (clone-arg))
 245          (res (make-string arg)))
 246     (read-string-as-bytes *fasl-input-stream* res)
 247     (push-fop-table (make-symbol res))))
 248
 249 (define-fop (fop-package 14)
 250   (find-undeleted-package-or-lose (pop-stack)))
 251 \f
 252 ;;;; fops for loading numbers
 253
 254 ;;; Load a signed integer LENGTH bytes long from *FASL-INPUT-STREAM*.
 255 (defun load-s-integer (length)
 256   (declare (fixnum length))
 257   ;; #+cmu (declare (optimize (inhibit-warnings 2)))
 258   (do* ((index length (1- index))
 259         (byte 0 (read-byte *fasl-input-stream*))
 260         (result 0 (+ result (ash byte bits)))
 261         (bits 0 (+ bits 8)))
 262        ((= index 0)
 263         (if (logbitp 7 byte)    ; look at sign bit
 264             (- result (ash 1 bits))
 265             result))
 266     (declare (fixnum index byte bits))))
 267
 268 (define-cloned-fops (fop-integer 33) (fop-small-integer 34)
 269   (load-s-integer (clone-arg)))
 270
 271 (define-fop (fop-word-integer 35)
 272   (prepare-for-fast-read-byte *fasl-input-stream*
 273     (prog1
 274      (fast-read-s-integer 4)
 275      (done-with-fast-read-byte))))
 276
 277 (define-fop (fop-byte-integer 36)
 278   (prepare-for-fast-read-byte *fasl-input-stream*
 279     (prog1
 280      (fast-read-s-integer 1)
 281      (done-with-fast-read-byte))))
 282
 283 (define-fop (fop-ratio 70)
 284   (let ((den (pop-stack)))
 285     (%make-ratio (pop-stack) den)))
 286
 287 (define-fop (fop-complex 71)
 288   (let ((im (pop-stack)))
 289     (%make-complex (pop-stack) im)))
 290
 291 (macrolet ((fast-read-single-float ()
 292              '(make-single-float (fast-read-s-integer 4)))
 293            (fast-read-double-float ()
 294              '(let ((lo (fast-read-u-integer 4)))
 295                (make-double-float (fast-read-s-integer 4) lo))))
 296   (macrolet ((define-complex-fop (name fop-code type)
 297                (let ((reader (symbolicate "FAST-READ-" type)))
 298                  `(define-fop (,name ,fop-code)
 299                       (prepare-for-fast-read-byte *fasl-input-stream*
 300                         (prog1
 301                             (complex (,reader) (,reader))
 302                           (done-with-fast-read-byte))))))
 303              (define-float-fop (name fop-code type)
 304                (let ((reader (symbolicate "FAST-READ-" type)))
 305                  `(define-fop (,name ,fop-code)
 306                       (prepare-for-fast-read-byte *fasl-input-stream*
 307                         (prog1
 308                             (,reader)
 309                           (done-with-fast-read-byte)))))))
 310     (define-complex-fop fop-complex-single-float 72 single-float)
 311     (define-complex-fop fop-complex-double-float 73 double-float)
 312     #!+long-float
 313     (define-complex-fop fop-complex-long-float 67 long-float)
 314     (define-float-fop fop-single-float 46 single-float)
 315     (define-float-fop fop-double-float 47 double-float)
 316     #!+long-float
 317     (define-float-fop fop-long-float 52 long-float)))
 318
 319 \f
 320 ;;;; loading lists
 321
 322 (define-fop (fop-list 15)
 323   (do ((res () (cons (pop-stack) res))
 324        (n (read-arg 1) (1- n)))
 325       ((zerop n) res)
 326     (declare (type index n))))
 327
 328 (define-fop (fop-list* 16)
 329   (do ((res (pop-stack) (cons (pop-stack) res))
 330        (n (read-arg 1) (1- n)))
 331       ((zerop n) res)
 332     (declare (type index n))))
 333
 334 (macrolet ((frob (name op fun n)
 335              `(define-fop (,name ,op)
 336                 (call-with-popped-args ,fun ,n))))
 337
 338   (frob fop-list-1 17 list 1)
 339   (frob fop-list-2 18 list 2)
 340   (frob fop-list-3 19 list 3)
 341   (frob fop-list-4 20 list 4)
 342   (frob fop-list-5 21 list 5)
 343   (frob fop-list-6 22 list 6)
 344   (frob fop-list-7 23 list 7)
 345   (frob fop-list-8 24 list 8)
 346
 347   (frob fop-list*-1 25 list* 2)
 348   (frob fop-list*-2 26 list* 3)
 349   (frob fop-list*-3 27 list* 4)
 350   (frob fop-list*-4 28 list* 5)
 351   (frob fop-list*-5 29 list* 6)
 352   (frob fop-list*-6 30 list* 7)
 353   (frob fop-list*-7 31 list* 8)
 354   (frob fop-list*-8 32 list* 9))
 355 \f
 356 ;;;; fops for loading arrays
 357
 358 (define-cloned-fops (fop-string 37) (fop-small-string 38)
 359   (let* ((arg (clone-arg))
 360          (res (make-string arg)))
 361     (read-string-as-bytes *fasl-input-stream* res)
 362     res))
 363
 364 (define-cloned-fops (fop-vector 39) (fop-small-vector 40)
 365   (let* ((size (clone-arg))
 366          (res (make-array size)))
 367     (declare (fixnum size))
 368     (do ((n (1- size) (1- n)))
 369         ((minusp n))
 370       (setf (svref res n) (pop-stack)))
 371     res))
 372
 373 (define-fop (fop-array 83)
 374   (let* ((rank (read-arg 4))
 375          (vec (pop-stack))
 376          (length (length vec))
 377          (res (make-array-header sb!vm:simple-array-widetag rank)))
 378     (declare (simple-array vec)
 379              (type (unsigned-byte 24) rank))
 380     (set-array-header res vec length nil 0
 381                       (do ((i rank (1- i))
 382                            (dimensions () (cons (pop-stack) dimensions)))
 383                           ((zerop i) dimensions)
 384                         (declare (type index i)))
 385                       nil)
 386     res))
 387
 388 (define-fop (fop-single-float-vector 84)
 389   (let* ((length (read-arg 4))
 390          (result (make-array length :element-type 'single-float)))
 391     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes))
 392     result))
 393
 394 (define-fop (fop-double-float-vector 85)
 395   (let* ((length (read-arg 4))
 396          (result (make-array length :element-type 'double-float)))
 397     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 398     result))
 399
 400 (define-fop (fop-complex-single-float-vector 86)
 401   (let* ((length (read-arg 4))
 402          (result (make-array length :element-type '(complex single-float))))
 403     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 404     result))
 405
 406 (define-fop (fop-complex-double-float-vector 87)
 407   (let* ((length (read-arg 4))
 408          (result (make-array length :element-type '(complex double-float))))
 409     (read-n-bytes *fasl-input-stream*
 410                   result
 411                   0
 412                   (* length sb!vm:n-word-bytes 2 2))
 413     result))
 414
 415 ;;; CMU CL comment:
 416 ;;;   *** NOT *** the FOP-INT-VECTOR as currently documented in rtguts.
 417 ;;;   Size must be a directly supported I-vector element size, with no
 418 ;;;   extra bits. This must be packed according to the local
 419 ;;;   byte-ordering, allowing us to directly read the bits.
 420 (define-fop (fop-int-vector 43)
 421   (prepare-for-fast-read-byte *fasl-input-stream*
 422     (let* ((len (fast-read-u-integer 4))
 423            (size (fast-read-byte))
 424            (res (case size
 425                   (0 (make-array len :element-type 'nil))
 426                   (1 (make-array len :element-type 'bit))
 427                   (2 (make-array len :element-type '(unsigned-byte 2)))
 428                   (4 (make-array len :element-type '(unsigned-byte 4)))
 429                   (7 (prog1 (make-array len :element-type '(unsigned-byte 7))
 430                        (setf size 8)))
 431                   (8 (make-array len :element-type '(unsigned-byte 8)))
 432                   (15 (prog1 (make-array len :element-type '(unsigned-byte 15))
 433                         (setf size 16)))
 434                   (16 (make-array len :element-type '(unsigned-byte 16)))
 435                   (31 (prog1 (make-array len :element-type '(unsigned-byte 31))
 436                         (setf size 32)))
 437                   (32 (make-array len :element-type '(unsigned-byte 32)))
 438                   (t (bug "losing i-vector element size: ~S" size)))))
 439       (declare (type index len))
 440       (done-with-fast-read-byte)
 441       (read-n-bytes *fasl-input-stream*
 442                     res
 443                     0
 444                     (ceiling (the index (* size len))
 445                              sb!vm:n-byte-bits))
 446       res)))
 447
 448 ;;; This is the same as FOP-INT-VECTOR, except this is for signed
 449 ;;; SIMPLE-ARRAYs.
 450 (define-fop (fop-signed-int-vector 50)
 451   (prepare-for-fast-read-byte *fasl-input-stream*
 452     (let* ((len (fast-read-u-integer 4))
 453            (size (fast-read-byte))
 454            (res (case size
 455                   (8 (make-array len :element-type '(signed-byte 8)))
 456                   (16 (make-array len :element-type '(signed-byte 16)))
 457                   (29 (make-array len :element-type '(unsigned-byte 29)))
 458                   (30 (make-array len :element-type '(signed-byte 30)))
 459                   (32 (make-array len :element-type '(signed-byte 32)))
 460                   (t (bug "losing si-vector element size: ~S" size)))))
 461       (declare (type index len))
 462       (done-with-fast-read-byte)
 463       (read-n-bytes *fasl-input-stream*
 464                     res
 465                     0
 466                     (ceiling (the index (* (if (or (= size 30) (= size 29))
 467                                                32 ; Adjust for (signed-byte 30)
 468                                                size) len)) sb!vm:n-byte-bits))
 469       res)))
 470
 471 (define-fop (fop-eval 53)
 472   (let ((result (eval (pop-stack))))
 473     ;; FIXME: CMU CL had this code here:
 474     ;;   (when *load-print*
 475     ;;     (load-fresh-line)
 476     ;;     (prin1 result)
 477     ;;     (terpri))
 478     ;; Unfortunately, this dependence on the *LOAD-PRINT* global
 479     ;; variable is non-ANSI, so for now we've just punted printing in
 480     ;; fasl loading.
 481     result))
 482
 483 (define-fop (fop-eval-for-effect 54 :pushp nil)
 484   (let ((result (eval (pop-stack))))
 485     ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 486     (declare (ignore result))
 487     #+nil (when *load-print*
 488             (load-fresh-line)
 489             (prin1 result)
 490             (terpri))))
 491
 492 (define-fop (fop-funcall 55)
 493   (let ((arg (read-arg 1)))
 494     (if (zerop arg)
 495         (funcall (pop-stack))
 496         (do ((args () (cons (pop-stack) args))
 497              (n arg (1- n)))
 498             ((zerop n) (apply (pop-stack) args))
 499           (declare (type index n))))))
 500
 501 (define-fop (fop-funcall-for-effect 56 :pushp nil)
 502   (let ((arg (read-arg 1)))
 503     (if (zerop arg)
 504         (funcall (pop-stack))
 505         (do ((args () (cons (pop-stack) args))
 506              (n arg (1- n)))
 507             ((zerop n) (apply (pop-stack) args))
 508           (declare (type index n))))))
 509 \f
 510 ;;;; fops for fixing up circularities
 511
 512 (define-fop (fop-rplaca 200 :pushp nil)
 513   (let ((obj (svref *current-fop-table* (read-arg 4)))
 514         (idx (read-arg 4))
 515         (val (pop-stack)))
 516     (setf (car (nthcdr idx obj)) val)))
 517
 518 (define-fop (fop-rplacd 201 :pushp nil)
 519   (let ((obj (svref *current-fop-table* (read-arg 4)))
 520         (idx (read-arg 4))
 521         (val (pop-stack)))
 522     (setf (cdr (nthcdr idx obj)) val)))
 523
 524 (define-fop (fop-svset 202 :pushp nil)
 525   (let* ((obi (read-arg 4))
 526          (obj (svref *current-fop-table* obi))
 527          (idx (read-arg 4))
 528          (val (pop-stack)))
 529     (if (typep obj 'instance)
 530         (setf (%instance-ref obj idx) val)
 531         (setf (svref obj idx) val))))
 532
 533 (define-fop (fop-structset 204 :pushp nil)
 534   (setf (%instance-ref (svref *current-fop-table* (read-arg 4))
 535                        (read-arg 4))
 536         (pop-stack)))
 537
 538 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 539 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 540 (define-fop (fop-nthcdr 203)
 541   (nthcdr (read-arg 4) (pop-stack)))
 542 \f
 543 ;;;; fops for loading functions
 544
 545 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 546 ;;; conventionally placed at the beginning of each fasl file to test
 547 ;;; for compatibility between the fasl file and the CMU CL which
 548 ;;; loaded it. In SBCL, this functionality has been replaced by
 549 ;;; putting the implementation and version in required fields in the
 550 ;;; fasl file header.)
 551
 552 (define-fop (fop-code 58 :stackp nil)
 553   (load-code (read-arg 4) (read-arg 4)))
 554
 555 (define-fop (fop-small-code 59 :stackp nil)
 556   (load-code (read-arg 1) (read-arg 2)))
 557
 558 (define-fop (fop-fdefinition 60)
 559   (fdefinition-object (pop-stack) t))
 560
 561 (define-fop (fop-sanctify-for-execution 61)
 562   (let ((component (pop-stack)))
 563     (sb!vm:sanctify-for-execution component)
 564     component))
 565
 566 (define-fop (fop-fset 74 :pushp nil)
 567   ;; Ordinary, not-for-cold-load code shouldn't need to mess with this
 568   ;; at all, since it's only used as part of the conspiracy between
 569   ;; the cross-compiler and GENESIS to statically link FDEFINITIONs
 570   ;; for cold init.
 571   (warn "~@<FOP-FSET seen in ordinary load (not cold load) -- quite strange! ~
 572 If you didn't do something strange to cause this, please report it as a ~
 573 bug.~:@>")
 574   ;; Unlike CMU CL, we don't treat this as a no-op in ordinary code.
 575   ;; If the user (or, more likely, developer) is trying to reload
 576   ;; compiled-for-cold-load code into a warm SBCL, we'll do a warm
 577   ;; assignment. (This is partly for abstract tidiness, since the warm
 578   ;; assignment is the closest analogy to what happens at cold load,
 579   ;; and partly because otherwise our compiled-for-cold-load code will
 580   ;; fail, since in SBCL things like compiled-for-cold-load %DEFUN
 581   ;; depend more strongly than in CMU CL on FOP-FSET actually doing
 582   ;; something.)
 583   (let ((fn (pop-stack))
 584         (name (pop-stack)))
 585     (setf (fdefinition name) fn)))
 586
 587 ;;; Modify a slot in a CONSTANTS object.
 588 (define-cloned-fops (fop-alter-code 140 :pushp nil) (fop-byte-alter-code 141)
 589   (let ((value (pop-stack))
 590         (code (pop-stack)))
 591     (setf (code-header-ref code (clone-arg)) value)
 592     (values)))
 593
 594 (define-fop (fop-fun-entry 142)
 595   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 596   (error "FOP-FUN-ENTRY can't be defined without %PRIMITIVE.")
 597   #-sb-xc-host
 598   (let ((type (pop-stack))
 599         (arglist (pop-stack))
 600         (name (pop-stack))
 601         (code-object (pop-stack))
 602         (offset (read-arg 4)))
 603     (declare (type index offset))
 604     (unless (zerop (logand offset sb!vm:lowtag-mask))
 605       (bug "unaligned function object, offset = #X~X" offset))
 606     (let ((fun (%primitive sb!c:compute-fun code-object offset)))
 607       (setf (%simple-fun-self fun) fun)
 608       (setf (%simple-fun-next fun) (%code-entry-points code-object))
 609       (setf (%code-entry-points code-object) fun)
 610       (setf (%simple-fun-name fun) name)
 611       (setf (%simple-fun-arglist fun) arglist)
 612       (setf (%simple-fun-type fun) type)
 613       ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 614       #+nil (when *load-print*
 615               (load-fresh-line)
 616               (format t "~S defined~%" fun))
 617       fun)))
 618 \f
 619 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 620 ;;;; was sufficiently stale that the functions it called were no
 621 ;;;; longer defined, so I (William Harold Newman) deleted it.
 622 ;;;;
 623 ;;;; In case someone in the future is trying to make sense of FOP layout,
 624 ;;;; it might be worth recording that the Dylan FOPs were
 625 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 626 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 627 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 628 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 629 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 630 \f
 631 ;;;; assemblerish fops
 632
 633 (define-fop (fop-foreign-fixup 147)
 634   (let* ((kind (pop-stack))
 635          (code-object (pop-stack))
 636          (len (read-arg 1))
 637          (sym (make-string len)))
 638     (read-n-bytes *fasl-input-stream* sym 0 len)
 639     (sb!vm:fixup-code-object code-object
 640                              (read-arg 4)
 641                              (foreign-symbol-address-as-integer sym)
 642                              kind)
 643     code-object))
 644
 645 (define-fop (fop-assembler-code 144)
 646   (error "cannot load assembler code except at cold load"))
 647
 648 (define-fop (fop-assembler-routine 145)
 649   (error "cannot load assembler code except at cold load"))
 650
 651 (define-fop (fop-assembler-fixup 148)
 652   (let ((routine (pop-stack))
 653         (kind (pop-stack))
 654         (code-object (pop-stack)))
 655     (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 656       (unless found
 657         (error "undefined assembler routine: ~S" routine))
 658       (sb!vm:fixup-code-object code-object (read-arg 4) value kind))
 659     code-object))
 660
 661 (define-fop (fop-code-object-fixup 149)
 662   (let ((kind (pop-stack))
 663         (code-object (pop-stack)))
 664     ;; Note: We don't have to worry about GC moving the code-object after
 665     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 666     ;; we can only use code-object fixups when code-objects don't move.
 667     (sb!vm:fixup-code-object code-object (read-arg 4)
 668                              (get-lisp-obj-address code-object) kind)
 669     code-object))