src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Define NAME as a fasl operation, with op-code FOP-CODE. PUSHP
   6 ;;; describes what the body does to the fop stack:
   7 ;;;   T
   8 ;;;     The body might pop the fop stack. The result of the body is
   9 ;;;     pushed on the fop stack.
  10 ;;;   NIL
  11 ;;;     The body might pop the fop stack. The result of the body is
  12 ;;;     discarded.
  13 ;;; STACKP describes whether or not the body interacts with the fop stack.
  14 (defmacro define-fop ((name fop-code &key (pushp t) (stackp t)) &rest forms)
  15   `(progn
  16      (defun ,name ()
  17        ,(if stackp
  18             `(with-fop-stack ,pushp ,@forms)
  19             `(progn ,@forms)))
  20      (%define-fop ',name ,fop-code)))
  21
  22 (defun %define-fop (name code)
  23   (let ((oname (svref *fop-names* code)))
  24     (when (and oname (not (eq oname name)))
  25       (error "multiple names for fop code ~D: ~S and ~S" code name oname)))
  26   ;; KLUDGE: It's mnemonically suboptimal to use 'FOP-CODE as the name of the
  27   ;; tag which associates names with codes when it's also used as one of
  28   ;; the names. Perhaps the fops named FOP-CODE and FOP-SMALL-CODE could
  29   ;; be renamed to something more mnemonic? -- WHN 19990902
  30   (let ((ocode (get name 'fop-code)))
  31     (when (and ocode (/= ocode code))
  32       (error "multiple codes for fop name ~S: ~D and ~D" name code ocode)))
  33   (setf (svref *fop-names* code) name
  34         (get name 'fop-code) code
  35         (svref *fop-funs* code) (symbol-function name))
  36   (values))
  37
  38 ;;; Define a pair of fops which are identical except that one reads
  39 ;;; a four-byte argument while the other reads a one-byte argument. The
  40 ;;; argument can be accessed by using the CLONE-ARG macro.
  41 ;;;
  42 ;;; KLUDGE: It would be nice if the definition here encapsulated which
  43 ;;; value ranges went with which fop variant, and chose the correct
  44 ;;; fop code to use. Currently, since such logic isn't encapsulated,
  45 ;;; we see callers doing stuff like
  46 ;;;     (cond ((and (< num-consts #x100) (< total-length #x10000))
  47 ;;;            (dump-fop 'sb!impl::fop-small-code file)
  48 ;;;            (dump-byte num-consts file)
  49 ;;;            (dump-integer-as-n-bytes total-length 2 file))
  50 ;;;           (t
  51 ;;;            (dump-fop 'sb!impl::fop-code file)
  52 ;;;            (dump-word num-consts file)
  53 ;;;            (dump-word total-length file))))
  54 ;;; in several places. It would be cleaner if this could be replaced with
  55 ;;; something like
  56 ;;;     (dump-fop file fop-code num-consts total-length)
  57 ;;; Some of this logic is already in DUMP-FOP*, but that still requires the
  58 ;;; caller to know that it's a 1-byte-arg/4-byte-arg cloned fop pair, and to
  59 ;;; know both the 1-byte-arg and the 4-byte-arg fop names. -- WHN 19990902
  60 (defmacro define-cloned-fops ((name code &key (pushp t) (stackp t))
  61                               (small-name small-code) &rest forms)
  62   (aver (member pushp '(nil t)))
  63   (aver (member stackp '(nil t)))
  64   `(progn
  65      (macrolet ((clone-arg () '(read-word-arg)))
  66        (define-fop (,name ,code :pushp ,pushp :stackp ,stackp) ,@forms))
  67      (macrolet ((clone-arg () '(read-byte-arg)))
  68        (define-fop (,small-name ,small-code :pushp ,pushp :stackp stackp) ,@forms))))
  69
  70 ;;; a helper function for reading string values from FASL files: sort
  71 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  72 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  73 ;;; for each element read
  74 (declaim (ftype (function (stream simple-string &optional index) (values))
  75                 read-string-as-bytes #!+sb-unicode read-string-as-words))
  76 (defun read-string-as-bytes (stream string &optional (length (length string)))
  77   (dotimes (i length)
  78     (setf (aref string i)
  79           (sb!xc:code-char (read-byte stream))))
  80   ;; FIXME: The classic CMU CL code to do this was
  81   ;;   (READ-N-BYTES FILE STRING START END).
  82   ;; It was changed for SBCL because we needed a portable version for
  83   ;; bootstrapping. Benchmark the non-portable version and see whether it's
  84   ;; significantly better than the portable version here. If it is, then use
  85   ;; it as an alternate definition, protected with #-SB-XC-HOST.
  86   (values))
  87 #!+sb-unicode
  88 (defun read-string-as-words (stream string &optional (length (length string)))
  89   #+sb-xc-host (bug "READ-STRING-AS-WORDS called")
  90   (dotimes (i length)
  91     (setf (aref string i)
  92           (sb!xc:code-char (logior
  93                             (read-byte stream)
  94                             (ash (read-byte stream) 8)
  95                             (ash (read-byte stream) 16)
  96                             (ash (read-byte stream) 24)))))
  97   (values))
  98 \f
  99 ;;;; miscellaneous fops
 100
 101 ;;; FIXME: POP-STACK should be called something more mnemonic. (POP-FOP-STACK?
 102 ;;; But that would conflict with PUSH-FOP-TABLE. Something, anyway..)
 103
 104 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
 105 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
 106 ;;; progress of FASL loading.
 107 #!+sb-show
 108 (defvar *show-fop-nop4-p* nil)
 109
 110 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
 111 ;;; occurs disproportionately often in fasl files for other reasons,
 112 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 113 ;;; into fasl files for debugging purposes. There's no shortage of
 114 ;;; unused fop codes, so we add this second NOP, which reads 4
 115 ;;; arbitrary bytes and discards them.
 116 (define-fop (fop-nop4 137 :stackp nil)
 117   (let ((arg (read-arg 4)))
 118     (declare (ignorable arg))
 119     #!+sb-show
 120     (when *show-fop-nop4-p*
 121       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 122
 123 (define-fop (fop-nop 0 :stackp nil))
 124 (define-fop (fop-pop 1 :pushp nil) (push-fop-table (pop-stack)))
 125 (define-fop (fop-push 2) (svref *current-fop-table* (read-word-arg)))
 126 (define-fop (fop-byte-push 3) (svref *current-fop-table* (read-byte-arg)))
 127
 128 (define-fop (fop-empty-list 4) ())
 129 (define-fop (fop-truth 5) t)
 130 ;;; CMU CL had FOP-POP-FOR-EFFECT as fop 65, but it was never used and seemed
 131 ;;; to have no possible use.
 132 (define-fop (fop-misc-trap 66)
 133   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 134   (error "FOP-MISC-TRAP can't be defined without %PRIMITIVE.")
 135   #-sb-xc-host
 136   (%primitive sb!c:make-other-immediate-type 0 sb!vm:unbound-marker-widetag))
 137
 138 (define-cloned-fops (fop-character 68) (fop-short-character 69)
 139   (code-char (clone-arg)))
 140
 141 (define-cloned-fops (fop-struct 48) (fop-small-struct 49)
 142   (let* ((size (clone-arg))
 143          (res (%make-instance size)))
 144     (declare (type index size))
 145     (do ((n (1- size) (1- n)))
 146         ((minusp n))
 147       (declare (type index-or-minus-1 n))
 148       (setf (%instance-ref res n) (pop-stack)))
 149     res))
 150
 151 (define-fop (fop-layout 45)
 152   (let ((length (pop-stack))
 153         (depthoid (pop-stack))
 154         (inherits (pop-stack))
 155         (name (pop-stack)))
 156     (find-and-init-or-check-layout name length inherits depthoid)))
 157
 158 (define-fop (fop-end-group 64 :stackp nil)
 159   (/show0 "THROWing FASL-GROUP-END")
 160   (throw 'fasl-group-end t))
 161
 162 ;;; In the normal loader, we just ignore these. GENESIS overwrites
 163 ;;; FOP-MAYBE-COLD-LOAD with something that knows whether to revert to
 164 ;;; cold-loading or not.
 165 (define-fop (fop-normal-load 81 :stackp nil))
 166 (define-fop (fop-maybe-cold-load 82 :stackp nil))
 167
 168 (define-fop (fop-verify-table-size 62 :stackp nil)
 169   (let ((expected-index (read-word-arg)))
 170     (unless (= *current-fop-table-index* expected-index)
 171       (bug "fasl table of improper size"))))
 172 (define-fop (fop-verify-empty-stack 63 :stackp nil)
 173   (unless (zerop (length *fop-stack*))
 174     (bug "fasl stack not empty when it should be")))
 175 \f
 176 ;;;; fops for loading symbols
 177
 178 (macrolet (;; FIXME: Should all this code really be duplicated inside
 179            ;; each fop? Perhaps it would be better for this shared
 180            ;; code to live in FLET FROB1 and FLET FROB4 (for the
 181            ;; two different sizes of counts).
 182            (frob (name code name-size package)
 183              (let ((n-package (gensym))
 184                    (n-size (gensym))
 185                    (n-buffer (gensym)))
 186                `(define-fop (,name ,code)
 187                   (prepare-for-fast-read-byte *fasl-input-stream*
 188                     (let ((,n-package ,package)
 189                           (,n-size (fast-read-u-integer ,name-size)))
 190                       (when (> ,n-size (length *fasl-symbol-buffer*))
 191                         (setq *fasl-symbol-buffer*
 192                               (make-string (* ,n-size 2))))
 193                       (done-with-fast-read-byte)
 194                       (let ((,n-buffer *fasl-symbol-buffer*))
 195                         #+sb-xc-host
 196                         (read-string-as-bytes *fasl-input-stream*
 197                                               ,n-buffer
 198                                               ,n-size)
 199                         #-sb-xc-host
 200                         (#!+sb-unicode read-string-as-words
 201                          #!-sb-unicode read-string-as-bytes
 202                          *fasl-input-stream*
 203                          ,n-buffer
 204                          ,n-size)
 205                         (push-fop-table (without-package-locks
 206                                          (intern* ,n-buffer
 207                                                   ,n-size
 208                                                   ,n-package))))))))))
 209
 210   ;; Note: CMU CL had FOP-SYMBOL-SAVE and FOP-SMALL-SYMBOL-SAVE, but
 211   ;; since they made the behavior of the fasloader depend on the
 212   ;; *PACKAGE* variable, not only were they a pain to support (because
 213   ;; they required various hacks to handle *PACKAGE*-manipulation
 214   ;; forms) they were basically broken by design, because ANSI gives
 215   ;; the user so much flexibility in manipulating *PACKAGE* at
 216   ;; load-time that no reasonable hacks could possibly make things
 217   ;; work right. The ones used in CMU CL certainly didn't, as shown by
 218   ;; e.g.
 219   ;;   (IN-PACKAGE :CL-USER)
 220   ;;     (DEFVAR CL::*FOO* 'FOO-VALUE)
 221   ;;     (EVAL-WHEN (:COMPILE-TOPLEVEL :LOAD-TOPLEVEL :EXECUTE)
 222   ;;       (SETF *PACKAGE* (FIND-PACKAGE :CL)))
 223   ;; which in CMU CL 2.4.9 defines a variable CL-USER::*FOO* instead of
 224   ;; defining CL::*FOO*. Therefore, we don't use those fops in SBCL.
 225   ;;(frob fop-symbol-save               6 4 *package*)
 226   ;;(frob fop-small-symbol-save   7 1 *package*)
 227
 228   (frob fop-lisp-symbol-save          75 #.sb!vm:n-word-bytes *cl-package*)
 229   (frob fop-lisp-small-symbol-save    76 1 *cl-package*)
 230   (frob fop-keyword-symbol-save       77 #.sb!vm:n-word-bytes *keyword-package*)
 231   (frob fop-keyword-small-symbol-save 78 1 *keyword-package*)
 232
 233   ;; FIXME: Because we don't have FOP-SYMBOL-SAVE any more, an enormous number
 234   ;; of symbols will fall through to this case, probably resulting in bloated
 235   ;; fasl files. A new
 236   ;; FOP-SYMBOL-IN-LAST-PACKAGE-SAVE/FOP-SMALL-SYMBOL-IN-LAST-PACKAGE-SAVE
 237   ;; cloned fop pair could undo some of this bloat.
 238   (frob fop-symbol-in-package-save 8 #.sb!vm:n-word-bytes
 239     (svref *current-fop-table* (fast-read-u-integer #.sb!vm:n-word-bytes)))
 240   (frob fop-small-symbol-in-package-save 9 1
 241     (svref *current-fop-table* (fast-read-u-integer #.sb!vm:n-word-bytes)))
 242   (frob fop-symbol-in-byte-package-save 10 #.sb!vm:n-word-bytes
 243     (svref *current-fop-table* (fast-read-u-integer 1)))
 244   (frob fop-small-symbol-in-byte-package-save 11 1
 245     (svref *current-fop-table* (fast-read-u-integer 1))))
 246
 247 (define-cloned-fops (fop-uninterned-symbol-save 12)
 248                     (fop-uninterned-small-symbol-save 13)
 249   (let* ((arg (clone-arg))
 250          (res (make-string arg)))
 251     #!-sb-unicode
 252     (read-string-as-bytes *fasl-input-stream* res)
 253     #!+sb-unicode
 254     (read-string-as-words *fasl-input-stream* res)
 255     (push-fop-table (make-symbol res))))
 256
 257 (define-fop (fop-package 14)
 258   (find-undeleted-package-or-lose (pop-stack)))
 259 \f
 260 ;;;; fops for loading numbers
 261
 262 ;;; Load a signed integer LENGTH bytes long from *FASL-INPUT-STREAM*.
 263 (defun load-s-integer (length)
 264   (declare (fixnum length))
 265   ;; #+cmu (declare (optimize (inhibit-warnings 2)))
 266   (do* ((index length (1- index))
 267         (byte 0 (read-byte *fasl-input-stream*))
 268         (result 0 (+ result (ash byte bits)))
 269         (bits 0 (+ bits 8)))
 270        ((= index 0)
 271         (if (logbitp 7 byte)    ; look at sign bit
 272             (- result (ash 1 bits))
 273             result))
 274     (declare (fixnum index byte bits))))
 275
 276 (define-cloned-fops (fop-integer 33) (fop-small-integer 34)
 277   (load-s-integer (clone-arg)))
 278
 279 (define-fop (fop-word-integer 35)
 280   (prepare-for-fast-read-byte *fasl-input-stream*
 281     (prog1
 282      (fast-read-s-integer #.sb!vm:n-word-bytes)
 283      (done-with-fast-read-byte))))
 284
 285 (define-fop (fop-byte-integer 36)
 286   (prepare-for-fast-read-byte *fasl-input-stream*
 287     (prog1
 288      (fast-read-s-integer 1)
 289      (done-with-fast-read-byte))))
 290
 291 (define-fop (fop-ratio 70)
 292   (let ((den (pop-stack)))
 293     (%make-ratio (pop-stack) den)))
 294
 295 (define-fop (fop-complex 71)
 296   (let ((im (pop-stack)))
 297     (%make-complex (pop-stack) im)))
 298
 299 (macrolet ((fast-read-single-float ()
 300              '(make-single-float (fast-read-s-integer 4)))
 301            (fast-read-double-float ()
 302              '(let ((lo (fast-read-u-integer 4)))
 303                (make-double-float (fast-read-s-integer 4) lo))))
 304   (macrolet ((define-complex-fop (name fop-code type)
 305                (let ((reader (symbolicate "FAST-READ-" type)))
 306                  `(define-fop (,name ,fop-code)
 307                       (prepare-for-fast-read-byte *fasl-input-stream*
 308                         (prog1
 309                             (complex (,reader) (,reader))
 310                           (done-with-fast-read-byte))))))
 311              (define-float-fop (name fop-code type)
 312                (let ((reader (symbolicate "FAST-READ-" type)))
 313                  `(define-fop (,name ,fop-code)
 314                       (prepare-for-fast-read-byte *fasl-input-stream*
 315                         (prog1
 316                             (,reader)
 317                           (done-with-fast-read-byte)))))))
 318     (define-complex-fop fop-complex-single-float 72 single-float)
 319     (define-complex-fop fop-complex-double-float 73 double-float)
 320     #!+long-float
 321     (define-complex-fop fop-complex-long-float 67 long-float)
 322     (define-float-fop fop-single-float 46 single-float)
 323     (define-float-fop fop-double-float 47 double-float)
 324     #!+long-float
 325     (define-float-fop fop-long-float 52 long-float)))
 326
 327 \f
 328 ;;;; loading lists
 329
 330 (define-fop (fop-list 15)
 331   (do ((res () (cons (pop-stack) res))
 332        (n (read-byte-arg) (1- n)))
 333       ((zerop n) res)
 334     (declare (type index n))))
 335
 336 (define-fop (fop-list* 16)
 337   (do ((res (pop-stack) (cons (pop-stack) res))
 338        (n (read-byte-arg) (1- n)))
 339       ((zerop n) res)
 340     (declare (type index n))))
 341
 342 (macrolet ((frob (name op fun n)
 343              `(define-fop (,name ,op)
 344                 (call-with-popped-args ,fun ,n))))
 345
 346   (frob fop-list-1 17 list 1)
 347   (frob fop-list-2 18 list 2)
 348   (frob fop-list-3 19 list 3)
 349   (frob fop-list-4 20 list 4)
 350   (frob fop-list-5 21 list 5)
 351   (frob fop-list-6 22 list 6)
 352   (frob fop-list-7 23 list 7)
 353   (frob fop-list-8 24 list 8)
 354
 355   (frob fop-list*-1 25 list* 2)
 356   (frob fop-list*-2 26 list* 3)
 357   (frob fop-list*-3 27 list* 4)
 358   (frob fop-list*-4 28 list* 5)
 359   (frob fop-list*-5 29 list* 6)
 360   (frob fop-list*-6 30 list* 7)
 361   (frob fop-list*-7 31 list* 8)
 362   (frob fop-list*-8 32 list* 9))
 363 \f
 364 ;;;; fops for loading arrays
 365
 366 (define-cloned-fops (fop-base-string 37) (fop-small-base-string 38)
 367   (let* ((arg (clone-arg))
 368          (res (make-string arg :element-type 'base-char)))
 369     (read-string-as-bytes *fasl-input-stream* res)
 370     res))
 371
 372 #!+sb-unicode
 373 (progn
 374   #+sb-xc-host
 375   (define-cloned-fops (fop-character-string 161) (fop-small-character-string 162)
 376     (bug "CHARACTER-STRING FOP encountered"))
 377
 378   #-sb-xc-host
 379   (define-cloned-fops (fop-character-string 161) (fop-small-character-string 162)
 380     (let* ((arg (clone-arg))
 381            (res (make-string arg)))
 382       (read-string-as-words *fasl-input-stream* res)
 383       res)))
 384
 385 (define-cloned-fops (fop-vector 39) (fop-small-vector 40)
 386   (let* ((size (clone-arg))
 387          (res (make-array size)))
 388     (declare (fixnum size))
 389     (do ((n (1- size) (1- n)))
 390         ((minusp n))
 391       (setf (svref res n) (pop-stack)))
 392     res))
 393
 394 (define-fop (fop-array 83)
 395   (let* ((rank (read-word-arg))
 396          (vec (pop-stack))
 397          (length (length vec))
 398          (res (make-array-header sb!vm:simple-array-widetag rank)))
 399     (declare (simple-array vec)
 400              (type (unsigned-byte #.(- sb!vm:n-word-bits sb!vm:n-widetag-bits)) rank))
 401     (set-array-header res vec length nil 0
 402                       (do ((i rank (1- i))
 403                            (dimensions () (cons (pop-stack) dimensions)))
 404                           ((zerop i) dimensions)
 405                         (declare (type index i)))
 406                       nil)
 407     res))
 408
 409 (define-fop (fop-single-float-vector 84)
 410   (let* ((length (read-word-arg))
 411          (result (make-array length :element-type 'single-float)))
 412     (read-n-bytes *fasl-input-stream* result 0 (* length 4))
 413     result))
 414
 415 (define-fop (fop-double-float-vector 85)
 416   (let* ((length (read-word-arg))
 417          (result (make-array length :element-type 'double-float)))
 418     (read-n-bytes *fasl-input-stream* result 0 (* length 8))
 419     result))
 420
 421 (define-fop (fop-complex-single-float-vector 86)
 422   (let* ((length (read-word-arg))
 423          (result (make-array length :element-type '(complex single-float))))
 424     (read-n-bytes *fasl-input-stream* result 0 (* length 8))
 425     result))
 426
 427 (define-fop (fop-complex-double-float-vector 87)
 428   (let* ((length (read-word-arg))
 429          (result (make-array length :element-type '(complex double-float))))
 430     (read-n-bytes *fasl-input-stream* result 0 (* length 16))
 431     result))
 432
 433 ;;; CMU CL comment:
 434 ;;;   *** NOT *** the FOP-INT-VECTOR as currently documented in rtguts.
 435 ;;;   Size must be a directly supported I-vector element size, with no
 436 ;;;   extra bits. This must be packed according to the local
 437 ;;;   byte-ordering, allowing us to directly read the bits.
 438 (define-fop (fop-int-vector 43)
 439   (prepare-for-fast-read-byte *fasl-input-stream*
 440     (let* ((len (fast-read-u-integer #.sb!vm:n-word-bytes))
 441            (size (fast-read-byte))
 442            (res (case size
 443                   (0 (make-array len :element-type 'nil))
 444                   (1 (make-array len :element-type 'bit))
 445                   (2 (make-array len :element-type '(unsigned-byte 2)))
 446                   (4 (make-array len :element-type '(unsigned-byte 4)))
 447                   (7 (prog1 (make-array len :element-type '(unsigned-byte 7))
 448                        (setf size 8)))
 449                   (8 (make-array len :element-type '(unsigned-byte 8)))
 450                   (15 (prog1 (make-array len :element-type '(unsigned-byte 15))
 451                         (setf size 16)))
 452                   (16 (make-array len :element-type '(unsigned-byte 16)))
 453                   (31 (prog1 (make-array len :element-type '(unsigned-byte 31))
 454                         (setf size 32)))
 455                   (32 (make-array len :element-type '(unsigned-byte 32)))
 456                   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 457                   (63 (prog1 (make-array len :element-type '(unsigned-byte 63))
 458                         (setf size 64)))
 459                   (64 (make-array len :element-type '(unsigned-byte 64)))
 460                   (t (bug "losing i-vector element size: ~S" size)))))
 461       (declare (type index len))
 462       (done-with-fast-read-byte)
 463       (read-n-bytes *fasl-input-stream*
 464                     res
 465                     0
 466                     (ceiling (the index (* size len)) sb!vm:n-byte-bits))
 467       res)))
 468
 469 ;;; This is the same as FOP-INT-VECTOR, except this is for signed
 470 ;;; SIMPLE-ARRAYs.
 471 (define-fop (fop-signed-int-vector 50)
 472   (prepare-for-fast-read-byte *fasl-input-stream*
 473     (let* ((len (fast-read-u-integer #.sb!vm:n-word-bytes))
 474            (size (fast-read-byte))
 475            (res (case size
 476                   (8 (make-array len :element-type '(signed-byte 8)))
 477                   (16 (make-array len :element-type '(signed-byte 16)))
 478                   #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 479                   (29 (prog1 (make-array len :element-type '(unsigned-byte 29))
 480                         (setf size 32)))
 481                   #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 482                   (30 (prog1 (make-array len :element-type '(signed-byte 30))
 483                         (setf size 32)))
 484                   (32 (make-array len :element-type '(signed-byte 32)))
 485                   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 486                   (60 (prog1 (make-array len :element-type '(unsigned-byte 60))
 487                         (setf size 64)))
 488                   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 489                   (61 (prog1 (make-array len :element-type '(signed-byte 61))
 490                         (setf size 64)))
 491                   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 492                   (64 (make-array len :element-type '(signed-byte 64)))
 493                   (t (bug "losing si-vector element size: ~S" size)))))
 494       (declare (type index len))
 495       (done-with-fast-read-byte)
 496       (read-n-bytes *fasl-input-stream*
 497                     res
 498                     0
 499                     (ceiling (the index (* size len)) sb!vm:n-byte-bits))
 500       res)))
 501
 502 (define-fop (fop-eval 53)
 503   (let ((result (eval (pop-stack))))
 504     ;; FIXME: CMU CL had this code here:
 505     ;;   (when *load-print*
 506     ;;     (load-fresh-line)
 507     ;;     (prin1 result)
 508     ;;     (terpri))
 509     ;; Unfortunately, this dependence on the *LOAD-PRINT* global
 510     ;; variable is non-ANSI, so for now we've just punted printing in
 511     ;; fasl loading.
 512     result))
 513
 514 (define-fop (fop-eval-for-effect 54 :pushp nil)
 515   (let ((result (eval (pop-stack))))
 516     ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 517     (declare (ignore result))
 518     #+nil (when *load-print*
 519             (load-fresh-line)
 520             (prin1 result)
 521             (terpri))))
 522
 523 (define-fop (fop-funcall 55)
 524   (let ((arg (read-byte-arg)))
 525     (if (zerop arg)
 526         (funcall (pop-stack))
 527         (do ((args () (cons (pop-stack) args))
 528              (n arg (1- n)))
 529             ((zerop n) (apply (pop-stack) args))
 530           (declare (type index n))))))
 531
 532 (define-fop (fop-funcall-for-effect 56 :pushp nil)
 533   (let ((arg (read-byte-arg)))
 534     (if (zerop arg)
 535         (funcall (pop-stack))
 536         (do ((args () (cons (pop-stack) args))
 537              (n arg (1- n)))
 538             ((zerop n) (apply (pop-stack) args))
 539           (declare (type index n))))))
 540 \f
 541 ;;;; fops for fixing up circularities
 542
 543 (define-fop (fop-rplaca 200 :pushp nil)
 544   (let ((obj (svref *current-fop-table* (read-word-arg)))
 545         (idx (read-word-arg))
 546         (val (pop-stack)))
 547     (setf (car (nthcdr idx obj)) val)))
 548
 549 (define-fop (fop-rplacd 201 :pushp nil)
 550   (let ((obj (svref *current-fop-table* (read-word-arg)))
 551         (idx (read-word-arg))
 552         (val (pop-stack)))
 553     (setf (cdr (nthcdr idx obj)) val)))
 554
 555 (define-fop (fop-svset 202 :pushp nil)
 556   (let* ((obi (read-word-arg))
 557          (obj (svref *current-fop-table* obi))
 558          (idx (read-word-arg))
 559          (val (pop-stack)))
 560     (if (typep obj 'instance)
 561         (setf (%instance-ref obj idx) val)
 562         (setf (svref obj idx) val))))
 563
 564 (define-fop (fop-structset 204 :pushp nil)
 565   (setf (%instance-ref (svref *current-fop-table* (read-word-arg))
 566                        (read-word-arg))
 567         (pop-stack)))
 568
 569 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 570 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 571 (define-fop (fop-nthcdr 203)
 572   (nthcdr (read-word-arg) (pop-stack)))
 573 \f
 574 ;;;; fops for loading functions
 575
 576 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 577 ;;; conventionally placed at the beginning of each fasl file to test
 578 ;;; for compatibility between the fasl file and the CMU CL which
 579 ;;; loaded it. In SBCL, this functionality has been replaced by
 580 ;;; putting the implementation and version in required fields in the
 581 ;;; fasl file header.)
 582
 583 (define-fop (fop-code 58 :stackp nil)
 584   (load-code (read-word-arg) (read-word-arg)))
 585
 586 (define-fop (fop-small-code 59 :stackp nil)
 587   (load-code (read-byte-arg) (read-halfword-arg)))
 588
 589 (define-fop (fop-fdefinition 60)
 590   (fdefinition-object (pop-stack) t))
 591
 592 (define-fop (fop-sanctify-for-execution 61)
 593   (let ((component (pop-stack)))
 594     (sb!vm:sanctify-for-execution component)
 595     component))
 596
 597 (define-fop (fop-fset 74 :pushp nil)
 598   ;; Ordinary, not-for-cold-load code shouldn't need to mess with this
 599   ;; at all, since it's only used as part of the conspiracy between
 600   ;; the cross-compiler and GENESIS to statically link FDEFINITIONs
 601   ;; for cold init.
 602   (warn "~@<FOP-FSET seen in ordinary load (not cold load) -- quite strange! ~
 603 If you didn't do something strange to cause this, please report it as a ~
 604 bug.~:@>")
 605   ;; Unlike CMU CL, we don't treat this as a no-op in ordinary code.
 606   ;; If the user (or, more likely, developer) is trying to reload
 607   ;; compiled-for-cold-load code into a warm SBCL, we'll do a warm
 608   ;; assignment. (This is partly for abstract tidiness, since the warm
 609   ;; assignment is the closest analogy to what happens at cold load,
 610   ;; and partly because otherwise our compiled-for-cold-load code will
 611   ;; fail, since in SBCL things like compiled-for-cold-load %DEFUN
 612   ;; depend more strongly than in CMU CL on FOP-FSET actually doing
 613   ;; something.)
 614   (let ((fn (pop-stack))
 615         (name (pop-stack)))
 616     (setf (fdefinition name) fn)))
 617
 618 ;;; Modify a slot in a CONSTANTS object.
 619 (define-cloned-fops (fop-alter-code 140 :pushp nil) (fop-byte-alter-code 141)
 620   (let ((value (pop-stack))
 621         (code (pop-stack)))
 622     (setf (code-header-ref code (clone-arg)) value)
 623     (values)))
 624
 625 (define-fop (fop-fun-entry 142)
 626   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 627   (error "FOP-FUN-ENTRY can't be defined without %PRIMITIVE.")
 628   #-sb-xc-host
 629   (let ((type (pop-stack))
 630         (arglist (pop-stack))
 631         (name (pop-stack))
 632         (code-object (pop-stack))
 633         (offset (read-word-arg)))
 634     (declare (type index offset))
 635     (unless (zerop (logand offset sb!vm:lowtag-mask))
 636       (bug "unaligned function object, offset = #X~X" offset))
 637     (let ((fun (%primitive sb!c:compute-fun code-object offset)))
 638       (setf (%simple-fun-self fun) fun)
 639       (setf (%simple-fun-next fun) (%code-entry-points code-object))
 640       (setf (%code-entry-points code-object) fun)
 641       (setf (%simple-fun-name fun) name)
 642       (setf (%simple-fun-arglist fun) arglist)
 643       (setf (%simple-fun-type fun) type)
 644       ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 645       #+nil (when *load-print*
 646               (load-fresh-line)
 647               (format t "~S defined~%" fun))
 648       fun)))
 649 \f
 650 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 651 ;;;; was sufficiently stale that the functions it called were no
 652 ;;;; longer defined, so I (William Harold Newman) deleted it.
 653 ;;;;
 654 ;;;; In case someone in the future is trying to make sense of FOP layout,
 655 ;;;; it might be worth recording that the Dylan FOPs were
 656 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 657 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 658 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 659 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 660 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 661 \f
 662 ;;;; assemblerish fops
 663
 664 (define-fop (fop-assembler-code 144)
 665   (error "cannot load assembler code except at cold load"))
 666
 667 (define-fop (fop-assembler-routine 145)
 668   (error "cannot load assembler code except at cold load"))
 669
 670 (define-fop (fop-foreign-fixup 147)
 671   (let* ((kind (pop-stack))
 672          (code-object (pop-stack))
 673          (len (read-byte-arg))
 674          (sym (make-string len :element-type 'base-char)))
 675     (read-n-bytes *fasl-input-stream* sym 0 len)
 676     (sb!vm:fixup-code-object code-object
 677                              (read-word-arg)
 678                              (foreign-symbol-address-as-integer sym)
 679                              kind)
 680     code-object))
 681
 682 (define-fop (fop-assembler-fixup 148)
 683   (let ((routine (pop-stack))
 684         (kind (pop-stack))
 685         (code-object (pop-stack)))
 686     (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 687       (unless found
 688         (error "undefined assembler routine: ~S" routine))
 689       (sb!vm:fixup-code-object code-object (read-word-arg) value kind))
 690     code-object))
 691
 692 (define-fop (fop-code-object-fixup 149)
 693   (let ((kind (pop-stack))
 694         (code-object (pop-stack)))
 695     ;; Note: We don't have to worry about GC moving the code-object after
 696     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 697     ;; we can only use code-object fixups when code-objects don't move.
 698     (sb!vm:fixup-code-object code-object (read-word-arg)
 699                              (get-lisp-obj-address code-object) kind)
 700     code-object))
 701
 702 #!+linkage-table
 703 (define-fop (fop-foreign-dataref-fixup 150)
 704   (let* ((kind (pop-stack))
 705          (code-object (pop-stack))
 706          (len (read-byte-arg))
 707          (sym (make-string len :element-type 'base-char)))
 708     (read-n-bytes *fasl-input-stream* sym 0 len)
 709     (sb!vm:fixup-code-object code-object
 710                              (read-word-arg)
 711                              (foreign-symbol-address-as-integer sym t)
 712                              kind)
 713     code-object))