src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Define NAME as a fasl operation, with op-code FOP-CODE. PUSHP
   6 ;;; describes what the body does to the fop stack:
   7 ;;;   T
   8 ;;;     The body might pop the fop stack. The result of the body is
   9 ;;;     pushed on the fop stack.
  10 ;;;   NIL
  11 ;;;     The body might pop the fop stack. The result of the body is
  12 ;;;     discarded.
  13 ;;; STACKP describes whether or not the body interacts with the fop stack.
  14 (defmacro define-fop ((name fop-code &key (pushp t) (stackp t)) &rest forms)
  15   `(progn
  16      (defun ,name ()
  17        ,(if stackp
  18             `(with-fop-stack ,pushp ,@forms)
  19             `(progn ,@forms)))
  20      (%define-fop ',name ,fop-code)))
  21
  22 (defun %define-fop (name code)
  23   (let ((oname (svref *fop-names* code)))
  24     (when (and oname (not (eq oname name)))
  25       (error "multiple names for fop code ~D: ~S and ~S" code name oname)))
  26   ;; KLUDGE: It's mnemonically suboptimal to use 'FOP-CODE as the name of the
  27   ;; tag which associates names with codes when it's also used as one of
  28   ;; the names. Perhaps the fops named FOP-CODE and FOP-SMALL-CODE could
  29   ;; be renamed to something more mnemonic? -- WHN 19990902
  30   (let ((ocode (get name 'fop-code)))
  31     (when (and ocode (/= ocode code))
  32       (error "multiple codes for fop name ~S: ~D and ~D" name code ocode)))
  33   (setf (svref *fop-names* code) name
  34         (get name 'fop-code) code
  35         (svref *fop-funs* code) (symbol-function name))
  36   (values))
  37
  38 ;;; Define a pair of fops which are identical except that one reads
  39 ;;; a four-byte argument while the other reads a one-byte argument. The
  40 ;;; argument can be accessed by using the Clone-Arg macro.
  41 ;;;
  42 ;;; KLUDGE: It would be nice if the definition here encapsulated which
  43 ;;; value ranges went with which fop variant, and chose the correct
  44 ;;; fop code to use. Currently, since such logic isn't encapsulated,
  45 ;;; we see callers doing stuff like
  46 ;;;     (cond ((and (< num-consts #x100) (< total-length #x10000))
  47 ;;;            (dump-fop 'sb!impl::fop-small-code file)
  48 ;;;            (dump-byte num-consts file)
  49 ;;;            (dump-integer-as-n-bytes total-length 2 file))
  50 ;;;           (t
  51 ;;;            (dump-fop 'sb!impl::fop-code file)
  52 ;;;            (dump-unsigned-32 num-consts file)
  53 ;;;            (dump-unsigned-32 total-length file))))
  54 ;;; in several places. It would be cleaner if this could be replaced with
  55 ;;; something like
  56 ;;;     (dump-fop file fop-code num-consts total-length)
  57 ;;; Some of this logic is already in DUMP-FOP*, but that still requires the
  58 ;;; caller to know that it's a 1-byte-arg/4-byte-arg cloned fop pair, and to
  59 ;;; know both the 1-byte-arg and the 4-byte-arg fop names. -- WHN 19990902
  60 (defmacro define-cloned-fops ((name code &key (pushp t) (stackp t))
  61                               (small-name small-code) &rest forms)
  62   (aver (member pushp '(nil t)))
  63   (aver (member stackp '(nil t)))
  64   `(progn
  65      (macrolet ((clone-arg () '(read-arg 4)))
  66        (define-fop (,name ,code :pushp ,pushp :stackp ,stackp) ,@forms))
  67      (macrolet ((clone-arg () '(read-arg 1)))
  68        (define-fop (,small-name ,small-code :pushp ,pushp :stackp stackp) ,@forms))))
  69
  70 ;;; a helper function for reading string values from FASL files: sort
  71 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  72 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  73 ;;; for each element read
  74 (declaim (ftype (function (stream simple-string &optional index) (values)) read-string-as-bytes))
  75 (defun read-string-as-bytes (stream string &optional (length (length string)))
  76   (dotimes (i length)
  77     (setf (aref string i)
  78           (code-char (read-byte stream))))
  79   ;; FIXME: The classic CMU CL code to do this was
  80   ;;   (READ-N-BYTES FILE STRING START END).
  81   ;; It was changed for SBCL because we needed a portable version for
  82   ;; bootstrapping. Benchmark the non-portable version and see whether it's
  83   ;; significantly better than the portable version here. If it is, then use
  84   ;; add as an alternate definition, protected with #-SB-XC-HOST.
  85   (values))
  86 \f
  87 ;;;; miscellaneous fops
  88
  89 ;;; FIXME: POP-STACK should be called something more mnemonic. (POP-FOP-STACK?
  90 ;;; But that would conflict with PUSH-FOP-TABLE. Something, anyway..)
  91
  92 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
  93 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
  94 ;;; progress of FASL loading.
  95 #!+sb-show
  96 (defvar *show-fop-nop4-p* nil)
  97
  98 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
  99 ;;; occurs disproportionately often in fasl files for other reasons,
 100 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 101 ;;; into fasl files for debugging purposes. There's no shortage of
 102 ;;; unused fop codes, so we add this second NOP, which reads 4
 103 ;;; arbitrary bytes and discards them.
 104 (define-fop (fop-nop4 137 :stackp nil)
 105   (let ((arg (read-arg 4)))
 106     (declare (ignorable arg))
 107     #!+sb-show
 108     (when *show-fop-nop4-p*
 109       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 110
 111 (define-fop (fop-nop 0 :stackp nil))
 112 (define-fop (fop-pop 1 :pushp nil) (push-fop-table (pop-stack)))
 113 (define-fop (fop-push 2) (svref *current-fop-table* (read-arg 4)))
 114 (define-fop (fop-byte-push 3) (svref *current-fop-table* (read-arg 1)))
 115
 116 (define-fop (fop-empty-list 4) ())
 117 (define-fop (fop-truth 5) t)
 118 ;;; CMU CL had FOP-POP-FOR-EFFECT as fop 65, but it was never used and seemed
 119 ;;; to have no possible use.
 120 (define-fop (fop-misc-trap 66)
 121   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 122   (error "FOP-MISC-TRAP can't be defined without %PRIMITIVE.")
 123   #-sb-xc-host
 124   (%primitive sb!c:make-other-immediate-type 0 sb!vm:unbound-marker-widetag))
 125
 126 ;;; CMU CL had FOP-CHARACTER as fop 68, but it's not needed in current
 127 ;;; SBCL as we have no extended characters, only 1-byte characters.
 128 ;;; (Ditto for CMU CL, actually: FOP-CHARACTER was speculative generality.)
 129 (define-fop (fop-short-character 69)
 130   (code-char (read-arg 1)))
 131
 132 (define-cloned-fops (fop-struct 48) (fop-small-struct 49)
 133   (let* ((size (clone-arg))
 134          (res (%make-instance size)))
 135     (declare (type index size))
 136     (do ((n (1- size) (1- n)))
 137         ((minusp n))
 138       (declare (type index-or-minus-1 n))
 139       (setf (%instance-ref res n) (pop-stack)))
 140     res))
 141
 142 (define-fop (fop-layout 45)
 143   (let ((length (pop-stack))
 144         (depthoid (pop-stack))
 145         (inherits (pop-stack))
 146         (name (pop-stack)))
 147     (find-and-init-or-check-layout name length inherits depthoid)))
 148
 149 (define-fop (fop-end-group 64 :stackp nil)
 150   (/show0 "THROWing FASL-GROUP-END")
 151   (throw 'fasl-group-end t))
 152
 153 ;;; In the normal loader, we just ignore these. GENESIS overwrites
 154 ;;; FOP-MAYBE-COLD-LOAD with something that knows whether to revert to
 155 ;;; cold-loading or not.
 156 (define-fop (fop-normal-load 81 :stackp nil))
 157 (define-fop (fop-maybe-cold-load 82 :stackp nil))
 158
 159 (define-fop (fop-verify-table-size 62 :stackp nil)
 160   (let ((expected-index (read-arg 4)))
 161     (unless (= *current-fop-table-index* expected-index)
 162       (bug "fasl table of improper size"))))
 163 (define-fop (fop-verify-empty-stack 63 :stackp nil)
 164   (unless (= *fop-stack-pointer* *fop-stack-pointer-on-entry*)
 165     (bug "fasl stack not empty when it should be")))
 166 \f
 167 ;;;; fops for loading symbols
 168
 169 (defvar *load-symbol-buffer* (make-string 100))
 170 (declaim (simple-string *load-symbol-buffer*))
 171 (defvar *load-symbol-buffer-size* 100)
 172 (declaim (type index *load-symbol-buffer-size*))
 173 ;;; FIXME:
 174 ;;;   (1) *LOAD-SYMBOL-BUFFER-SIZE* is redundant, should just be
 175 ;;;       (LENGTH *LOAD-SYMBOL-BUFFER*).
 176 ;;;   (2) *LOAD-SYMBOL-BUFFER* should not have a global value, but should
 177 ;;;       be bound on entry to FASL loading, and it should be renamed to
 178 ;;;       *FASL-SYMBOL-BUFFER*.
 179
 180 (macrolet (;; FIXME: Should all this code really be duplicated inside
 181            ;; each fop? Perhaps it would be better for this shared
 182            ;; code to live in FLET FROB1 and FLET FROB4 (for the
 183            ;; two different sizes of counts).
 184            (frob (name code name-size package)
 185              (let ((n-package (gensym))
 186                    (n-size (gensym))
 187                    (n-buffer (gensym)))
 188                `(define-fop (,name ,code)
 189                   (prepare-for-fast-read-byte *fasl-input-stream*
 190                     (let ((,n-package ,package)
 191                           (,n-size (fast-read-u-integer ,name-size)))
 192                       (when (> ,n-size *load-symbol-buffer-size*)
 193                         (setq *load-symbol-buffer*
 194                               (make-string (setq *load-symbol-buffer-size*
 195                                                  (* ,n-size 2)))))
 196                       (done-with-fast-read-byte)
 197                       (let ((,n-buffer *load-symbol-buffer*))
 198                         (read-string-as-bytes *fasl-input-stream*
 199                                               ,n-buffer
 200                                               ,n-size)
 201                         (push-fop-table (intern* ,n-buffer
 202                                                  ,n-size
 203                                                  ,n-package)))))))))
 204
 205   ;; Note: CMU CL had FOP-SYMBOL-SAVE and FOP-SMALL-SYMBOL-SAVE, but
 206   ;; since they made the behavior of the fasloader depend on the
 207   ;; *PACKAGE* variable, not only were they a pain to support (because
 208   ;; they required various hacks to handle *PACKAGE*-manipulation
 209   ;; forms) they were basically broken by design, because ANSI gives
 210   ;; the user so much flexibility in manipulating *PACKAGE* at
 211   ;; load-time that no reasonable hacks could possibly make things
 212   ;; work right. The ones used in CMU CL certainly didn't, as shown by
 213   ;; e.g.
 214   ;;   (IN-PACKAGE :CL-USER)
 215   ;;     (DEFVAR CL::*FOO* 'FOO-VALUE)
 216   ;;     (EVAL-WHEN (:COMPILE-TOPLEVEL :LOAD-TOPLEVEL :EXECUTE)
 217   ;;       (SETF *PACKAGE* (FIND-PACKAGE :CL)))
 218   ;; which in CMU CL 2.4.9 defines a variable CL-USER::*FOO* instead of
 219   ;; defining CL::*FOO*. Therefore, we don't use those fops in SBCL.
 220   ;;(frob fop-symbol-save               6 4 *package*)
 221   ;;(frob fop-small-symbol-save   7 1 *package*)
 222
 223   (frob fop-lisp-symbol-save          75 4 *cl-package*)
 224   (frob fop-lisp-small-symbol-save    76 1 *cl-package*)
 225   (frob fop-keyword-symbol-save       77 4 *keyword-package*)
 226   (frob fop-keyword-small-symbol-save 78 1 *keyword-package*)
 227
 228   ;; FIXME: Because we don't have FOP-SYMBOL-SAVE any more, an enormous number
 229   ;; of symbols will fall through to this case, probably resulting in bloated
 230   ;; fasl files. A new
 231   ;; FOP-SYMBOL-IN-LAST-PACKAGE-SAVE/FOP-SMALL-SYMBOL-IN-LAST-PACKAGE-SAVE
 232   ;; cloned fop pair could undo some of this bloat.
 233   (frob fop-symbol-in-package-save 8 4
 234     (svref *current-fop-table* (fast-read-u-integer 4)))
 235   (frob fop-small-symbol-in-package-save 9 1
 236     (svref *current-fop-table* (fast-read-u-integer 4)))
 237   (frob fop-symbol-in-byte-package-save 10 4
 238     (svref *current-fop-table* (fast-read-u-integer 1)))
 239   (frob fop-small-symbol-in-byte-package-save 11 1
 240     (svref *current-fop-table* (fast-read-u-integer 1))))
 241
 242 (define-cloned-fops (fop-uninterned-symbol-save 12)
 243                     (fop-uninterned-small-symbol-save 13)
 244   (let* ((arg (clone-arg))
 245          (res (make-string arg)))
 246     (read-string-as-bytes *fasl-input-stream* res)
 247     (push-fop-table (make-symbol res))))
 248
 249 (define-fop (fop-package 14)
 250   (find-undeleted-package-or-lose (pop-stack)))
 251 \f
 252 ;;;; fops for loading numbers
 253
 254 ;;; Load a signed integer LENGTH bytes long from *FASL-INPUT-STREAM*.
 255 (defun load-s-integer (length)
 256   (declare (fixnum length))
 257   ;; #+cmu (declare (optimize (inhibit-warnings 2)))
 258   (do* ((index length (1- index))
 259         (byte 0 (read-byte *fasl-input-stream*))
 260         (result 0 (+ result (ash byte bits)))
 261         (bits 0 (+ bits 8)))
 262        ((= index 0)
 263         (if (logbitp 7 byte)    ; look at sign bit
 264             (- result (ash 1 bits))
 265             result))
 266     (declare (fixnum index byte bits))))
 267
 268 (define-cloned-fops (fop-integer 33) (fop-small-integer 34)
 269   (load-s-integer (clone-arg)))
 270
 271 (define-fop (fop-word-integer 35)
 272   (prepare-for-fast-read-byte *fasl-input-stream*
 273     (prog1
 274      (fast-read-s-integer 4)
 275      (done-with-fast-read-byte))))
 276
 277 (define-fop (fop-byte-integer 36)
 278   (prepare-for-fast-read-byte *fasl-input-stream*
 279     (prog1
 280      (fast-read-s-integer 1)
 281      (done-with-fast-read-byte))))
 282
 283 (define-fop (fop-ratio 70)
 284   (let ((den (pop-stack)))
 285     (%make-ratio (pop-stack) den)))
 286
 287 (define-fop (fop-complex 71)
 288   (let ((im (pop-stack)))
 289     (%make-complex (pop-stack) im)))
 290
 291 (macrolet ((fast-read-single-float ()
 292              '(make-single-float (fast-read-s-integer 4)))
 293            (fast-read-double-float ()
 294              '(let ((lo (fast-read-u-integer 4)))
 295                (make-double-float (fast-read-s-integer 4) lo)))
 296            #!+long-float
 297            (fast-read-long-float ()
 298              '(let ((lo (fast-read-u-integer 4))
 299                     #!+sparc (mid (fast-read-u-integer 4))
 300                     (hi (fast-read-u-integer 4)) ; XXX
 301                     (exp (fast-read-s-integer #!+x86 2 #!+sparc 4)))
 302                (make-long-float exp hi #!+sparc mid lo))))
 303   (macrolet ((define-complex-fop (name fop-code type)
 304                (let ((reader (symbolicate "FAST-READ-" type)))
 305                  `(define-fop (,name ,fop-code)
 306                       (prepare-for-fast-read-byte *fasl-input-stream*
 307                         (prog1
 308                             (complex (,reader) (,reader))
 309                           (done-with-fast-read-byte))))))
 310              (define-float-fop (name fop-code type)
 311                (let ((reader (symbolicate "FAST-READ-" type)))
 312                  `(define-fop (,name ,fop-code)
 313                       (prepare-for-fast-read-byte *fasl-input-stream*
 314                         (prog1
 315                             (,reader)
 316                           (done-with-fast-read-byte)))))))
 317     (define-complex-fop fop-complex-single-float 72 single-float)
 318     (define-complex-fop fop-complex-double-float 73 double-float)
 319     #!+long-float
 320     (define-complex-fop fop-complex-long-float 67 long-float)
 321     (define-float-fop fop-single-float 46 single-float)
 322     (define-float-fop fop-double-float 47 double-float)
 323     #!+long-float
 324     (define-float-fop fop-long-float 52 long-float)))
 325
 326 \f
 327 ;;;; loading lists
 328
 329 (define-fop (fop-list 15)
 330   (do ((res () (cons (pop-stack) res))
 331        (n (read-arg 1) (1- n)))
 332       ((zerop n) res)
 333     (declare (type index n))))
 334
 335 (define-fop (fop-list* 16)
 336   (do ((res (pop-stack) (cons (pop-stack) res))
 337        (n (read-arg 1) (1- n)))
 338       ((zerop n) res)
 339     (declare (type index n))))
 340
 341 (macrolet ((frob (name op fun n)
 342              `(define-fop (,name ,op)
 343                 (call-with-popped-things ,fun ,n))))
 344
 345   (frob fop-list-1 17 list 1)
 346   (frob fop-list-2 18 list 2)
 347   (frob fop-list-3 19 list 3)
 348   (frob fop-list-4 20 list 4)
 349   (frob fop-list-5 21 list 5)
 350   (frob fop-list-6 22 list 6)
 351   (frob fop-list-7 23 list 7)
 352   (frob fop-list-8 24 list 8)
 353
 354   (frob fop-list*-1 25 list* 2)
 355   (frob fop-list*-2 26 list* 3)
 356   (frob fop-list*-3 27 list* 4)
 357   (frob fop-list*-4 28 list* 5)
 358   (frob fop-list*-5 29 list* 6)
 359   (frob fop-list*-6 30 list* 7)
 360   (frob fop-list*-7 31 list* 8)
 361   (frob fop-list*-8 32 list* 9))
 362 \f
 363 ;;;; fops for loading arrays
 364
 365 (define-cloned-fops (fop-string 37) (fop-small-string 38)
 366   (let* ((arg (clone-arg))
 367          (res (make-string arg)))
 368     (read-string-as-bytes *fasl-input-stream* res)
 369     res))
 370
 371 (define-cloned-fops (fop-vector 39) (fop-small-vector 40)
 372   (let* ((size (clone-arg))
 373          (res (make-array size)))
 374     (declare (fixnum size))
 375     (do ((n (1- size) (1- n)))
 376         ((minusp n))
 377       (setf (svref res n) (pop-stack)))
 378     res))
 379
 380 (define-fop (fop-array 83)
 381   (let* ((rank (read-arg 4))
 382          (vec (pop-stack))
 383          (length (length vec))
 384          (res (make-array-header sb!vm:simple-array-widetag rank)))
 385     (declare (simple-array vec)
 386              (type (unsigned-byte 24) rank))
 387     (set-array-header res vec length length 0
 388                       (do ((i rank (1- i))
 389                            (dimensions () (cons (pop-stack) dimensions)))
 390                           ((zerop i) dimensions)
 391                         (declare (type index i)))
 392                       nil)
 393     res))
 394
 395 (define-fop (fop-single-float-vector 84)
 396   (let* ((length (read-arg 4))
 397          (result (make-array length :element-type 'single-float)))
 398     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes))
 399     result))
 400
 401 (define-fop (fop-double-float-vector 85)
 402   (let* ((length (read-arg 4))
 403          (result (make-array length :element-type 'double-float)))
 404     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 405     result))
 406
 407 #!+long-float
 408 (define-fop (fop-long-float-vector 88)
 409   (let* ((length (read-arg 4))
 410          (result (make-array length :element-type 'long-float)))
 411     (read-n-bytes *fasl-input-stream*
 412                   result
 413                   0
 414                   (* length sb!vm:n-word-bytes #!+x86 3 #!+sparc 4))
 415     result))
 416
 417 (define-fop (fop-complex-single-float-vector 86)
 418   (let* ((length (read-arg 4))
 419          (result (make-array length :element-type '(complex single-float))))
 420     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 421     result))
 422
 423 (define-fop (fop-complex-double-float-vector 87)
 424   (let* ((length (read-arg 4))
 425          (result (make-array length :element-type '(complex double-float))))
 426     (read-n-bytes *fasl-input-stream*
 427                   result
 428                   0
 429                   (* length sb!vm:n-word-bytes 2 2))
 430     result))
 431
 432 #!+long-float
 433 (define-fop (fop-complex-long-float-vector 89)
 434   (let* ((length (read-arg 4))
 435          (result (make-array length :element-type '(complex long-float))))
 436     (read-n-bytes *fasl-input-stream* result 0
 437                   (* length sb!vm:n-word-bytes #!+x86 3 #!+sparc 4 2))
 438     result))
 439
 440 ;;; CMU CL comment:
 441 ;;;   *** NOT *** the FOP-INT-VECTOR as currently documented in rtguts.
 442 ;;;   Size must be a directly supported I-vector element size, with no
 443 ;;;   extra bits. This must be packed according to the local
 444 ;;;   byte-ordering, allowing us to directly read the bits.
 445 (define-fop (fop-int-vector 43)
 446   (prepare-for-fast-read-byte *fasl-input-stream*
 447     (let* ((len (fast-read-u-integer 4))
 448            (size (fast-read-byte))
 449            (res (case size
 450                   (0 (make-array len :element-type 'nil))
 451                   (1 (make-array len :element-type 'bit))
 452                   (2 (make-array len :element-type '(unsigned-byte 2)))
 453                   (4 (make-array len :element-type '(unsigned-byte 4)))
 454                   (7 (prog1 (make-array len :element-type '(unsigned-byte 7))
 455                        (setf size 8)))
 456                   (8 (make-array len :element-type '(unsigned-byte 8)))
 457                   (15 (prog1 (make-array len :element-type '(unsigned-byte 15))
 458                         (setf size 16)))
 459                   (16 (make-array len :element-type '(unsigned-byte 16)))
 460                   (31 (prog1 (make-array len :element-type '(unsigned-byte 31))
 461                         (setf size 32)))
 462                   (32 (make-array len :element-type '(unsigned-byte 32)))
 463                   (t (bug "losing i-vector element size: ~S" size)))))
 464       (declare (type index len))
 465       (done-with-fast-read-byte)
 466       (read-n-bytes *fasl-input-stream*
 467                     res
 468                     0
 469                     (ceiling (the index (* size len))
 470                              sb!vm:n-byte-bits))
 471       res)))
 472
 473 ;;; This is the same as FOP-INT-VECTOR, except this is for signed
 474 ;;; SIMPLE-ARRAYs.
 475 (define-fop (fop-signed-int-vector 50)
 476   (prepare-for-fast-read-byte *fasl-input-stream*
 477     (let* ((len (fast-read-u-integer 4))
 478            (size (fast-read-byte))
 479            (res (case size
 480                   (8 (make-array len :element-type '(signed-byte 8)))
 481                   (16 (make-array len :element-type '(signed-byte 16)))
 482                   (29 (make-array len :element-type '(unsigned-byte 29)))
 483                   (30 (make-array len :element-type '(signed-byte 30)))
 484                   (32 (make-array len :element-type '(signed-byte 32)))
 485                   (t (bug "losing si-vector element size: ~S" size)))))
 486       (declare (type index len))
 487       (done-with-fast-read-byte)
 488       (read-n-bytes *fasl-input-stream*
 489                     res
 490                     0
 491                     (ceiling (the index (* (if (or (= size 30) (= size 29))
 492                                                32 ; Adjust for (signed-byte 30)
 493                                                size) len)) sb!vm:n-byte-bits))
 494       res)))
 495
 496 (define-fop (fop-eval 53)
 497   (let ((result (eval (pop-stack))))
 498     ;; FIXME: CMU CL had this code here:
 499     ;;   (when *load-print*
 500     ;;     (load-fresh-line)
 501     ;;     (prin1 result)
 502     ;;     (terpri))
 503     ;; Unfortunately, this dependence on the *LOAD-PRINT* global
 504     ;; variable is non-ANSI, so for now we've just punted printing in
 505     ;; fasl loading.
 506     result))
 507
 508 (define-fop (fop-eval-for-effect 54 :pushp nil)
 509   (let ((result (eval (pop-stack))))
 510     ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 511     (declare (ignore result))
 512     #+nil (when *load-print*
 513             (load-fresh-line)
 514             (prin1 result)
 515             (terpri))))
 516
 517 (define-fop (fop-funcall 55)
 518   (let ((arg (read-arg 1)))
 519     (if (zerop arg)
 520         (funcall (pop-stack))
 521         (do ((args () (cons (pop-stack) args))
 522              (n arg (1- n)))
 523             ((zerop n) (apply (pop-stack) args))
 524           (declare (type index n))))))
 525
 526 (define-fop (fop-funcall-for-effect 56 :pushp nil)
 527   (let ((arg (read-arg 1)))
 528     (if (zerop arg)
 529         (funcall (pop-stack))
 530         (do ((args () (cons (pop-stack) args))
 531              (n arg (1- n)))
 532             ((zerop n) (apply (pop-stack) args))
 533           (declare (type index n))))))
 534 \f
 535 ;;;; fops for fixing up circularities
 536
 537 (define-fop (fop-rplaca 200 :pushp nil)
 538   (let ((obj (svref *current-fop-table* (read-arg 4)))
 539         (idx (read-arg 4))
 540         (val (pop-stack)))
 541     (setf (car (nthcdr idx obj)) val)))
 542
 543 (define-fop (fop-rplacd 201 :pushp nil)
 544   (let ((obj (svref *current-fop-table* (read-arg 4)))
 545         (idx (read-arg 4))
 546         (val (pop-stack)))
 547     (setf (cdr (nthcdr idx obj)) val)))
 548
 549 (define-fop (fop-svset 202 :pushp nil)
 550   (let* ((obi (read-arg 4))
 551          (obj (svref *current-fop-table* obi))
 552          (idx (read-arg 4))
 553          (val (pop-stack)))
 554     (if (typep obj 'instance)
 555         (setf (%instance-ref obj idx) val)
 556         (setf (svref obj idx) val))))
 557
 558 (define-fop (fop-structset 204 :pushp nil)
 559   (setf (%instance-ref (svref *current-fop-table* (read-arg 4))
 560                        (read-arg 4))
 561         (pop-stack)))
 562
 563 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 564 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 565 (define-fop (fop-nthcdr 203)
 566   (nthcdr (read-arg 4) (pop-stack)))
 567 \f
 568 ;;;; fops for loading functions
 569
 570 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 571 ;;; conventionally placed at the beginning of each fasl file to test
 572 ;;; for compatibility between the fasl file and the CMU CL which
 573 ;;; loaded it. In SBCL, this functionality has been replaced by
 574 ;;; putting the implementation and version in required fields in the
 575 ;;; fasl file header.)
 576
 577 (define-fop (fop-code 58 :stackp nil)
 578   (load-code (read-arg 4) (read-arg 4)))
 579
 580 (define-fop (fop-small-code 59 :stackp nil)
 581   (load-code (read-arg 1) (read-arg 2)))
 582
 583 (define-fop (fop-fdefinition 60)
 584   (fdefinition-object (pop-stack) t))
 585
 586 (define-fop (fop-sanctify-for-execution 61)
 587   (let ((component (pop-stack)))
 588     (sb!vm:sanctify-for-execution component)
 589     component))
 590
 591 (define-fop (fop-fset 74 :pushp nil)
 592   ;; Ordinary, not-for-cold-load code shouldn't need to mess with this
 593   ;; at all, since it's only used as part of the conspiracy between
 594   ;; the cross-compiler and GENESIS to statically link FDEFINITIONs
 595   ;; for cold init.
 596   (warn "~@<FOP-FSET seen in ordinary load (not cold load) -- quite strange! ~
 597 If you didn't do something strange to cause this, please report it as a ~
 598 bug.~:@>")
 599   ;; Unlike CMU CL, we don't treat this as a no-op in ordinary code.
 600   ;; If the user (or, more likely, developer) is trying to reload
 601   ;; compiled-for-cold-load code into a warm SBCL, we'll do a warm
 602   ;; assignment. (This is partly for abstract tidiness, since the warm
 603   ;; assignment is the closest analogy to what happens at cold load,
 604   ;; and partly because otherwise our compiled-for-cold-load code will
 605   ;; fail, since in SBCL things like compiled-for-cold-load %DEFUN
 606   ;; depend more strongly than in CMU CL on FOP-FSET actually doing
 607   ;; something.)
 608   (let ((fn (pop-stack))
 609         (name (pop-stack)))
 610     (setf (fdefinition name) fn)))
 611
 612 ;;; Modify a slot in a CONSTANTS object.
 613 (define-cloned-fops (fop-alter-code 140 :pushp nil) (fop-byte-alter-code 141)
 614   (let ((value (pop-stack))
 615         (code (pop-stack)))
 616     (setf (code-header-ref code (clone-arg)) value)
 617     (values)))
 618
 619 (define-fop (fop-fun-entry 142)
 620   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 621   (error "FOP-FUN-ENTRY can't be defined without %PRIMITIVE.")
 622   #-sb-xc-host
 623   (let ((type (pop-stack))
 624         (arglist (pop-stack))
 625         (name (pop-stack))
 626         (code-object (pop-stack))
 627         (offset (read-arg 4)))
 628     (declare (type index offset))
 629     (unless (zerop (logand offset sb!vm:lowtag-mask))
 630       (bug "unaligned function object, offset = #X~X" offset))
 631     (let ((fun (%primitive sb!c:compute-fun code-object offset)))
 632       (setf (%simple-fun-self fun) fun)
 633       (setf (%simple-fun-next fun) (%code-entry-points code-object))
 634       (setf (%code-entry-points code-object) fun)
 635       (setf (%simple-fun-name fun) name)
 636       (setf (%simple-fun-arglist fun) arglist)
 637       (setf (%simple-fun-type fun) type)
 638       ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 639       #+nil (when *load-print*
 640               (load-fresh-line)
 641               (format t "~S defined~%" fun))
 642       fun)))
 643 \f
 644 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 645 ;;;; was sufficiently stale that the functions it called were no
 646 ;;;; longer defined, so I (William Harold Newman) deleted it.
 647 ;;;;
 648 ;;;; In case someone in the future is trying to make sense of FOP layout,
 649 ;;;; it might be worth recording that the Dylan FOPs were
 650 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 651 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 652 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 653 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 654 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 655 \f
 656 ;;;; assemblerish fops
 657
 658 (define-fop (fop-foreign-fixup 147)
 659   (let* ((kind (pop-stack))
 660          (code-object (pop-stack))
 661          (len (read-arg 1))
 662          (sym (make-string len)))
 663     (read-n-bytes *fasl-input-stream* sym 0 len)
 664     (sb!vm:fixup-code-object code-object
 665                              (read-arg 4)
 666                              (foreign-symbol-address-as-integer sym)
 667                              kind)
 668     code-object))
 669
 670 (define-fop (fop-assembler-code 144)
 671   (error "cannot load assembler code except at cold load"))
 672
 673 (define-fop (fop-assembler-routine 145)
 674   (error "cannot load assembler code except at cold load"))
 675
 676 (define-fop (fop-assembler-fixup 148)
 677   (let ((routine (pop-stack))
 678         (kind (pop-stack))
 679         (code-object (pop-stack)))
 680     (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 681       (unless found
 682         (error "undefined assembler routine: ~S" routine))
 683       (sb!vm:fixup-code-object code-object (read-arg 4) value kind))
 684     code-object))
 685
 686 (define-fop (fop-code-object-fixup 149)
 687   (let ((kind (pop-stack))
 688         (code-object (pop-stack)))
 689     ;; Note: We don't have to worry about GC moving the code-object after
 690     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 691     ;; we can only use code-object fixups when code-objects don't move.
 692     (sb!vm:fixup-code-object code-object (read-arg 4)
 693                              (get-lisp-obj-address code-object) kind)
 694     code-object))