src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Sometimes we want to skip over any FOPs with side-effects (like
   6 ;;; function calls) while executing other FOPs. *SKIP-UNTIL* will
   7 ;;; either contain the position where the skipping will stop, or
   8 ;;; NIL if we're executing normally.
   9 (defvar *skip-until* nil)
  10
  11 ;;; Define NAME as a fasl operation, with op-code FOP-CODE. PUSHP
  12 ;;; describes what the body does to the fop stack:
  13 ;;;   T
  14 ;;;     The body might pop the fop stack. The result of the body is
  15 ;;;     pushed on the fop stack.
  16 ;;;   NIL
  17 ;;;     The body might pop the fop stack. The result of the body is
  18 ;;;     discarded.
  19 ;;; STACKP describes whether or not the body interacts with the fop stack.
  20 (defmacro define-fop ((name fop-code &key (pushp t) (stackp t)) &body forms)
  21   `(progn
  22      (defun ,name ()
  23        ,(if stackp
  24             `(with-fop-stack ,pushp ,@forms)
  25             `(progn ,@forms)))
  26      (%define-fop ',name ,fop-code)))
  27
  28 (defun %define-fop (name code)
  29   (let ((oname (svref *fop-names* code)))
  30     (when (and oname (not (eq oname name)))
  31       (error "multiple names for fop code ~D: ~S and ~S" code name oname)))
  32   ;; KLUDGE: It's mnemonically suboptimal to use 'FOP-CODE as the name of the
  33   ;; tag which associates names with codes when it's also used as one of
  34   ;; the names. Perhaps the fops named FOP-CODE and FOP-SMALL-CODE could
  35   ;; be renamed to something more mnemonic? -- WHN 19990902
  36   (let ((ocode (get name 'fop-code)))
  37     (when (and ocode (/= ocode code))
  38       (error "multiple codes for fop name ~S: ~D and ~D" name code ocode)))
  39   (setf (svref *fop-names* code) name
  40         (get name 'fop-code) code
  41         (svref *fop-funs* code) (symbol-function name))
  42   (values))
  43
  44 ;;; Define a pair of fops which are identical except that one reads
  45 ;;; a four-byte argument while the other reads a one-byte argument. The
  46 ;;; argument can be accessed by using the CLONE-ARG macro.
  47 ;;;
  48 ;;; KLUDGE: It would be nice if the definition here encapsulated which
  49 ;;; value ranges went with which fop variant, and chose the correct
  50 ;;; fop code to use. Currently, since such logic isn't encapsulated,
  51 ;;; we see callers doing stuff like
  52 ;;;     (cond ((and (< num-consts #x100) (< total-length #x10000))
  53 ;;;            (dump-fop 'sb!impl::fop-small-code file)
  54 ;;;            (dump-byte num-consts file)
  55 ;;;            (dump-integer-as-n-bytes total-length 2 file))
  56 ;;;           (t
  57 ;;;            (dump-fop 'sb!impl::fop-code file)
  58 ;;;            (dump-word num-consts file)
  59 ;;;            (dump-word total-length file))))
  60 ;;; in several places. It would be cleaner if this could be replaced with
  61 ;;; something like
  62 ;;;     (dump-fop file fop-code num-consts total-length)
  63 ;;; Some of this logic is already in DUMP-FOP*, but that still requires the
  64 ;;; caller to know that it's a 1-byte-arg/4-byte-arg cloned fop pair, and to
  65 ;;; know both the 1-byte-arg and the 4-byte-arg fop names. -- WHN 19990902
  66 (defmacro define-cloned-fops ((name code &key (pushp t) (stackp t))
  67                               (small-name small-code) &rest forms)
  68   (aver (member pushp '(nil t)))
  69   (aver (member stackp '(nil t)))
  70   `(progn
  71      (macrolet ((clone-arg () '(read-word-arg)))
  72        (define-fop (,name ,code :pushp ,pushp :stackp ,stackp) ,@forms))
  73      (macrolet ((clone-arg () '(read-byte-arg)))
  74        (define-fop (,small-name ,small-code :pushp ,pushp :stackp ,stackp) ,@forms))))
  75
  76 ;;; a helper function for reading string values from FASL files: sort
  77 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  78 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  79 ;;; for each element read
  80 (defun read-string-as-bytes (stream string &optional (length (length string)))
  81   (declare (type (simple-array character (*)) string)
  82            (type index length)
  83            (optimize speed))
  84   (with-fast-read-byte ((unsigned-byte 8) stream)
  85     (dotimes (i length)
  86       (setf (aref string i)
  87             (sb!xc:code-char (fast-read-byte)))))
  88   string)
  89 (defun read-base-string-as-bytes (stream string &optional (length (length string)))
  90   (declare (type (simple-array base-char (*)) string)
  91            (type index length)
  92            (optimize speed))
  93   (with-fast-read-byte ((unsigned-byte 8) stream)
  94     (dotimes (i length)
  95       (setf (aref string i)
  96             (sb!xc:code-char (fast-read-byte)))))
  97   string)
  98 #!+sb-unicode
  99 (defun read-string-as-unsigned-byte-32
 100     (stream string &optional (length (length string)))
 101   (declare (type (simple-array character (*)) string)
 102            (type index length)
 103            (optimize speed))
 104   #+sb-xc-host (bug "READ-STRING-AS-UNSIGNED-BYTE-32 called")
 105   (with-fast-read-byte ((unsigned-byte 8) stream)
 106     (dotimes (i length)
 107       (setf (aref string i)
 108             (sb!xc:code-char (fast-read-u-integer 4)))))
 109   string)
 110 \f
 111 ;;;; miscellaneous fops
 112
 113 ;;; FIXME: POP-STACK should be called something more mnemonic. (POP-FOP-STACK?
 114 ;;; But that would conflict with PUSH-FOP-TABLE. Something, anyway..)
 115
 116 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
 117 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
 118 ;;; progress of FASL loading.
 119 #!+sb-show
 120 (defvar *show-fop-nop4-p* nil)
 121
 122 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
 123 ;;; occurs disproportionately often in fasl files for other reasons,
 124 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 125 ;;; into fasl files for debugging purposes. There's no shortage of
 126 ;;; unused fop codes, so we add this second NOP, which reads 4
 127 ;;; arbitrary bytes and discards them.
 128 (define-fop (fop-nop4 137 :stackp nil)
 129   (let ((arg (read-arg 4)))
 130     (declare (ignorable arg))
 131     #!+sb-show
 132     (when *show-fop-nop4-p*
 133       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 134
 135 (define-fop (fop-nop 0 :stackp nil))
 136 (define-fop (fop-pop 1 :pushp nil) (push-fop-table (pop-stack)))
 137 (define-fop (fop-push 2) (ref-fop-table (read-word-arg)))
 138 (define-fop (fop-byte-push 3) (ref-fop-table (read-byte-arg)))
 139
 140 (define-fop (fop-empty-list 4) ())
 141 (define-fop (fop-truth 5) t)
 142 ;;; CMU CL had FOP-POP-FOR-EFFECT as fop 65, but it was never used and seemed
 143 ;;; to have no possible use.
 144 (define-fop (fop-misc-trap 66)
 145   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 146   (error "FOP-MISC-TRAP can't be defined without %PRIMITIVE.")
 147   #-sb-xc-host
 148   (%primitive sb!c:make-unbound-marker))
 149
 150 (define-cloned-fops (fop-character 68) (fop-short-character 69)
 151   (code-char (clone-arg)))
 152
 153 (define-cloned-fops (fop-struct 48) (fop-small-struct 49)
 154   (let* ((size (clone-arg))
 155          (res (%make-instance size)))
 156     (declare (type index size))
 157     (let* ((layout (pop-stack))
 158            (nuntagged (layout-n-untagged-slots layout))
 159            (ntagged (- size nuntagged)))
 160       (setf (%instance-ref res 0) layout)
 161       (dotimes (n (1- ntagged))
 162         (declare (type index n))
 163         (setf (%instance-ref res (1+ n)) (pop-stack)))
 164       (dotimes (n nuntagged)
 165         (declare (type index n))
 166         (setf (%raw-instance-ref/word res (- nuntagged n 1)) (pop-stack))))
 167     res))
 168
 169 (define-fop (fop-layout 45)
 170   (let ((nuntagged (pop-stack))
 171         (length (pop-stack))
 172         (depthoid (pop-stack))
 173         (inherits (pop-stack))
 174         (name (pop-stack)))
 175     (find-and-init-or-check-layout name length inherits depthoid nuntagged)))
 176
 177 (define-fop (fop-end-group 64 :stackp nil)
 178   (/show0 "THROWing FASL-GROUP-END")
 179   (throw 'fasl-group-end t))
 180
 181 ;;; We used to have FOP-NORMAL-LOAD as 81 and FOP-MAYBE-COLD-LOAD as
 182 ;;; 82 until GENESIS learned how to work with host symbols and
 183 ;;; packages directly instead of piggybacking on the host code.
 184
 185 (define-fop (fop-verify-table-size 62 :stackp nil)
 186   (let ((expected-index (read-word-arg)))
 187     (unless (= (get-fop-table-index) expected-index)
 188       (bug "fasl table of improper size"))))
 189 (define-fop (fop-verify-empty-stack 63 :stackp nil)
 190   (unless (fop-stack-empty-p)
 191     (bug "fasl stack not empty when it should be")))
 192 \f
 193 ;;;; fops for loading symbols
 194
 195 (defun aux-fop-intern (smallp package)
 196   (declare (optimize speed))
 197   (let* ((size (if smallp
 198                    (read-byte-arg)
 199                    (read-word-arg)))
 200          (buffer (make-string size)))
 201     #+sb-xc-host
 202     (read-string-as-bytes *fasl-input-stream* buffer size)
 203     #-sb-xc-host
 204     (progn
 205       #!+sb-unicode
 206       (read-string-as-unsigned-byte-32 *fasl-input-stream* buffer size)
 207       #!-sb-unicode
 208       (read-string-as-bytes *fasl-input-stream* buffer size))
 209     (push-fop-table (without-package-locks
 210                       (intern* buffer
 211                                size
 212                                package
 213                                :no-copy t)))))
 214
 215 (macrolet ((def (name code smallp package-form)
 216              `(define-fop (,name ,code)
 217                 (aux-fop-intern ,smallp ,package-form))))
 218
 219   (def fop-lisp-symbol-save          75 nil *cl-package*)
 220   (def fop-lisp-small-symbol-save    76 t   *cl-package*)
 221   (def fop-keyword-symbol-save       77 nil *keyword-package*)
 222   (def fop-keyword-small-symbol-save 78 t   *keyword-package*)
 223
 224   ;; FIXME: Because we don't have FOP-SYMBOL-SAVE any more, an
 225   ;; enormous number of symbols will fall through to this case,
 226   ;; probably resulting in bloated fasl files. A new
 227   ;; FOP-SYMBOL-IN-LAST-PACKAGE-SAVE/FOP-SMALL-SYMBOL-IN-LAST-PACKAGE-SAVE
 228   ;; cloned fop pair could undo some of this bloat.
 229   (def fop-symbol-in-package-save             8 nil
 230     (ref-fop-table (read-word-arg)))
 231   (def fop-small-symbol-in-package-save       9 t
 232     (ref-fop-table (read-word-arg)))
 233   (def fop-symbol-in-byte-package-save       10 nil
 234     (ref-fop-table (read-byte-arg)))
 235   (def fop-small-symbol-in-byte-package-save 11 t
 236     (ref-fop-table (read-byte-arg))))
 237
 238 (define-cloned-fops (fop-uninterned-symbol-save 12)
 239                     (fop-uninterned-small-symbol-save 13)
 240   (let* ((arg (clone-arg))
 241          (res (make-string arg)))
 242     #!-sb-unicode
 243     (read-string-as-bytes *fasl-input-stream* res)
 244     #!+sb-unicode
 245     (read-string-as-unsigned-byte-32 *fasl-input-stream* res)
 246     (push-fop-table (make-symbol res))))
 247
 248 (define-fop (fop-package 14)
 249   (find-undeleted-package-or-lose (pop-stack)))
 250
 251 (define-cloned-fops (fop-named-package-save 156 :stackp nil)
 252                     (fop-small-named-package-save 157)
 253   (let* ((arg (clone-arg))
 254          (package-name (make-string arg)))
 255     #+sb-xc-host
 256     (read-string-as-bytes *fasl-input-stream* package-name)
 257     #-sb-xc-host
 258     (progn
 259       #!-sb-unicode
 260       (read-string-as-bytes *fasl-input-stream* package-name)
 261       #!+sb-unicode
 262       (read-string-as-unsigned-byte-32 *fasl-input-stream* package-name))
 263     (push-fop-table (find-undeleted-package-or-lose package-name))))
 264 \f
 265 ;;;; fops for loading numbers
 266
 267 ;;; Load a signed integer LENGTH bytes long from *FASL-INPUT-STREAM*.
 268 (defun load-s-integer (length)
 269   (declare (fixnum length)
 270            (optimize speed))
 271   (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 272     (do* ((index length (1- index))
 273           (byte 0 (fast-read-byte))
 274           (result 0 (+ result (ash byte bits)))
 275           (bits 0 (+ bits 8)))
 276          ((= index 0)
 277           (if (logbitp 7 byte)          ; look at sign bit
 278               (- result (ash 1 bits))
 279               result))
 280       (declare (fixnum index byte bits)))))
 281
 282 (define-cloned-fops (fop-integer 33) (fop-small-integer 34)
 283   (load-s-integer (clone-arg)))
 284
 285 (define-fop (fop-word-integer 35)
 286   (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 287     (fast-read-s-integer #.sb!vm:n-word-bytes)))
 288
 289 (define-fop (fop-byte-integer 36)
 290   (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 291     (fast-read-s-integer 1)))
 292
 293 (define-fop (fop-ratio 70)
 294   (let ((den (pop-stack)))
 295     (%make-ratio (pop-stack) den)))
 296
 297 (define-fop (fop-complex 71)
 298   (let ((im (pop-stack)))
 299     (%make-complex (pop-stack) im)))
 300
 301 (macrolet ((fast-read-single-float ()
 302              '(make-single-float (fast-read-s-integer 4)))
 303            (fast-read-double-float ()
 304              '(let ((lo (fast-read-u-integer 4)))
 305                (make-double-float (fast-read-s-integer 4) lo))))
 306   (macrolet ((define-complex-fop (name fop-code type)
 307                (let ((reader (symbolicate "FAST-READ-" type)))
 308                  `(define-fop (,name ,fop-code)
 309                       (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 310                         (complex (,reader) (,reader))))))
 311              (define-float-fop (name fop-code type)
 312                (let ((reader (symbolicate "FAST-READ-" type)))
 313                  `(define-fop (,name ,fop-code)
 314                     (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 315                       (,reader))))))
 316     (define-complex-fop fop-complex-single-float 72 single-float)
 317     (define-complex-fop fop-complex-double-float 73 double-float)
 318     #!+long-float
 319     (define-complex-fop fop-complex-long-float 67 long-float)
 320     (define-float-fop fop-single-float 46 single-float)
 321     (define-float-fop fop-double-float 47 double-float)
 322     #!+long-float
 323     (define-float-fop fop-long-float 52 long-float)))
 324
 325 #!+sb-simd-pack
 326 (define-fop (fop-simd-pack 88)
 327   (with-fast-read-byte ((unsigned-byte 8) *fasl-input-stream*)
 328     (%make-simd-pack (fast-read-s-integer 8)
 329                      (fast-read-u-integer 8)
 330                      (fast-read-u-integer 8))))
 331 \f
 332 ;;;; loading lists
 333
 334 (define-fop (fop-list 15)
 335   (do ((res () (cons (pop-stack) res))
 336        (n (read-byte-arg) (1- n)))
 337       ((zerop n) res)
 338     (declare (type index n))))
 339
 340 (define-fop (fop-list* 16)
 341   (do ((res (pop-stack) (cons (pop-stack) res))
 342        (n (read-byte-arg) (1- n)))
 343       ((zerop n) res)
 344     (declare (type index n))))
 345
 346 (macrolet ((frob (name op fun n)
 347              `(define-fop (,name ,op)
 348                 (call-with-popped-args ,fun ,n))))
 349
 350   (frob fop-list-1 17 list 1)
 351   (frob fop-list-2 18 list 2)
 352   (frob fop-list-3 19 list 3)
 353   (frob fop-list-4 20 list 4)
 354   (frob fop-list-5 21 list 5)
 355   (frob fop-list-6 22 list 6)
 356   (frob fop-list-7 23 list 7)
 357   (frob fop-list-8 24 list 8)
 358
 359   (frob fop-list*-1 25 list* 2)
 360   (frob fop-list*-2 26 list* 3)
 361   (frob fop-list*-3 27 list* 4)
 362   (frob fop-list*-4 28 list* 5)
 363   (frob fop-list*-5 29 list* 6)
 364   (frob fop-list*-6 30 list* 7)
 365   (frob fop-list*-7 31 list* 8)
 366   (frob fop-list*-8 32 list* 9))
 367 \f
 368 ;;;; fops for loading arrays
 369
 370 (define-cloned-fops (fop-base-string 37) (fop-small-base-string 38)
 371   (let* ((arg (clone-arg))
 372          (res (make-string arg :element-type 'base-char)))
 373     (read-base-string-as-bytes *fasl-input-stream* res)
 374     res))
 375
 376 #!+sb-unicode
 377 (progn
 378   #+sb-xc-host
 379   (define-cloned-fops (fop-character-string 161) (fop-small-character-string 162)
 380     (bug "CHARACTER-STRING FOP encountered"))
 381
 382   #-sb-xc-host
 383   (define-cloned-fops (fop-character-string 161) (fop-small-character-string 162)
 384     (let* ((arg (clone-arg))
 385            (res (make-string arg)))
 386       (read-string-as-unsigned-byte-32 *fasl-input-stream* res)
 387       res)))
 388
 389 (define-cloned-fops (fop-vector 39) (fop-small-vector 40)
 390   (let* ((size (clone-arg))
 391          (res (make-array size)))
 392     (declare (fixnum size))
 393     (do ((n (1- size) (1- n)))
 394         ((minusp n))
 395       (setf (svref res n) (pop-stack)))
 396     res))
 397
 398 (define-fop (fop-array 83)
 399   (let* ((rank (read-word-arg))
 400          (vec (pop-stack))
 401          (length (length vec))
 402          (res (make-array-header sb!vm:simple-array-widetag rank)))
 403     (declare (simple-array vec)
 404              (type (unsigned-byte #.(- sb!vm:n-word-bits sb!vm:n-widetag-bits)) rank))
 405     (set-array-header res vec length nil 0
 406                       (do ((i rank (1- i))
 407                            (dimensions () (cons (pop-stack) dimensions)))
 408                           ((zerop i) dimensions)
 409                         (declare (type index i)))
 410                       nil
 411                       t)
 412     res))
 413
 414 (defglobal **saetp-bits-per-length**
 415     (let ((array (make-array 255 :element-type '(unsigned-byte 8)
 416                                  :initial-element 255)))
 417       (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 418             do
 419             (setf (aref array (sb!vm:saetp-typecode saetp))
 420                   (sb!vm:saetp-n-bits saetp)))
 421       array)
 422     "255 means bad entry.")
 423 (declaim (type (simple-array (unsigned-byte 8) (255))
 424                **saetp-bits-per-length**))
 425
 426 (define-fop (fop-spec-vector 43)
 427   (let* ((length (read-word-arg))
 428          (widetag (read-byte-arg))
 429          (bits-per-length (aref **saetp-bits-per-length** widetag))
 430          (bytes  (progn
 431                    (aver (< bits-per-length 255))
 432                    (ceiling (* length bits-per-length) sb!vm:n-byte-bits)))
 433          (vector (allocate-vector widetag length (* bytes sb!vm:n-word-bytes))))
 434     (declare (type index length))
 435     (read-n-bytes *fasl-input-stream* vector 0 bytes)
 436     vector))
 437
 438 (define-fop (fop-eval 53)
 439   (if *skip-until*
 440       (pop-stack)
 441       (let ((result (eval (pop-stack))))
 442         ;; FIXME: CMU CL had this code here:
 443         ;;   (when *load-print*
 444         ;;     (load-fresh-line)
 445         ;;     (prin1 result)
 446         ;;     (terpri))
 447         ;; Unfortunately, this dependence on the *LOAD-PRINT* global
 448         ;; variable is non-ANSI, so for now we've just punted printing in
 449         ;; fasl loading.
 450         result)))
 451
 452 (define-fop (fop-eval-for-effect 54 :pushp nil)
 453   (if *skip-until*
 454       (pop-stack)
 455       (let ((result (eval (pop-stack))))
 456         ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 457         (declare (ignore result))
 458         #+nil (when *load-print*
 459                 (load-fresh-line)
 460                 (prin1 result)
 461                 (terpri)))))
 462
 463 (define-fop (fop-funcall 55)
 464   (let ((arg (read-byte-arg)))
 465     (if *skip-until*
 466         (dotimes (i (1+ arg))
 467           (pop-stack))
 468         (if (zerop arg)
 469             (funcall (pop-stack))
 470             (do ((args () (cons (pop-stack) args))
 471                  (n arg (1- n)))
 472                 ((zerop n) (apply (pop-stack) args))
 473               (declare (type index n)))))))
 474
 475 (define-fop (fop-funcall-for-effect 56 :pushp nil)
 476   (let ((arg (read-byte-arg)))
 477     (if *skip-until*
 478         (dotimes (i (1+ arg))
 479           (pop-stack))
 480         (if (zerop arg)
 481             (funcall (pop-stack))
 482             (do ((args () (cons (pop-stack) args))
 483                  (n arg (1- n)))
 484                 ((zerop n) (apply (pop-stack) args))
 485               (declare (type index n)))))))
 486 \f
 487 ;;;; fops for fixing up circularities
 488
 489 (define-fop (fop-rplaca 200 :pushp nil)
 490   (let ((obj (ref-fop-table (read-word-arg)))
 491         (idx (read-word-arg))
 492         (val (pop-stack)))
 493     (setf (car (nthcdr idx obj)) val)))
 494
 495 (define-fop (fop-rplacd 201 :pushp nil)
 496   (let ((obj (ref-fop-table (read-word-arg)))
 497         (idx (read-word-arg))
 498         (val (pop-stack)))
 499     (setf (cdr (nthcdr idx obj)) val)))
 500
 501 (define-fop (fop-svset 202 :pushp nil)
 502   (let* ((obi (read-word-arg))
 503          (obj (ref-fop-table obi))
 504          (idx (read-word-arg))
 505          (val (pop-stack)))
 506     (if (%instancep obj)
 507         (setf (%instance-ref obj idx) val)
 508         (setf (svref obj idx) val))))
 509
 510 (define-fop (fop-structset 204 :pushp nil)
 511   (setf (%instance-ref (ref-fop-table (read-word-arg))
 512                        (read-word-arg))
 513         (pop-stack)))
 514
 515 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 516 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 517 (define-fop (fop-nthcdr 203)
 518   (nthcdr (read-word-arg) (pop-stack)))
 519 \f
 520 ;;;; fops for loading functions
 521
 522 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 523 ;;; conventionally placed at the beginning of each fasl file to test
 524 ;;; for compatibility between the fasl file and the CMU CL which
 525 ;;; loaded it. In SBCL, this functionality has been replaced by
 526 ;;; putting the implementation and version in required fields in the
 527 ;;; fasl file header.)
 528
 529 (define-fop (fop-code 58 :stackp nil)
 530   (load-code (read-word-arg) (read-word-arg)))
 531
 532 (define-fop (fop-small-code 59 :stackp nil)
 533   (load-code (read-byte-arg) (read-halfword-arg)))
 534
 535 (define-fop (fop-fdefinition 60)
 536   (fdefinition-object (pop-stack) t))
 537
 538 (define-fop (fop-known-fun 65)
 539   (%coerce-name-to-fun (pop-stack)))
 540
 541 (define-fop (fop-sanctify-for-execution 61)
 542   (let ((component (pop-stack)))
 543     (sb!vm:sanctify-for-execution component)
 544     component))
 545
 546 (define-fop (fop-fset 74 :pushp nil)
 547   ;; Ordinary, not-for-cold-load code shouldn't need to mess with this
 548   ;; at all, since it's only used as part of the conspiracy between
 549   ;; the cross-compiler and GENESIS to statically link FDEFINITIONs
 550   ;; for cold init.
 551   (warn "~@<FOP-FSET seen in ordinary load (not cold load) -- quite strange! ~
 552 If you didn't do something strange to cause this, please report it as a ~
 553 bug.~:@>")
 554   ;; Unlike CMU CL, we don't treat this as a no-op in ordinary code.
 555   ;; If the user (or, more likely, developer) is trying to reload
 556   ;; compiled-for-cold-load code into a warm SBCL, we'll do a warm
 557   ;; assignment. (This is partly for abstract tidiness, since the warm
 558   ;; assignment is the closest analogy to what happens at cold load,
 559   ;; and partly because otherwise our compiled-for-cold-load code will
 560   ;; fail, since in SBCL things like compiled-for-cold-load %DEFUN
 561   ;; depend more strongly than in CMU CL on FOP-FSET actually doing
 562   ;; something.)
 563   (let ((fn (pop-stack))
 564         (name (pop-stack)))
 565     (setf (fdefinition name) fn)))
 566
 567 (define-fop (fop-note-debug-source 174 :pushp nil)
 568   (warn "~@<FOP-NOTE-DEBUG-SOURCE seen in ordinary load (not cold load) -- ~
 569 very strange!  If you didn't do something to cause this, please report it as ~
 570 a bug.~@:>")
 571   ;; as with COLD-FSET above, we are going to be lenient with coming
 572   ;; across this fop in a warm SBCL.
 573   (let ((debug-source (pop-stack)))
 574     (setf (sb!c::debug-source-compiled debug-source) (get-universal-time)
 575           (sb!c::debug-source-created debug-source)
 576           (file-write-date (sb!c::debug-source-namestring debug-source)))))
 577
 578 ;;; Modify a slot in a CONSTANTS object.
 579 (define-cloned-fops (fop-alter-code 140 :pushp nil) (fop-byte-alter-code 141)
 580   (let ((value (pop-stack))
 581         (code (pop-stack)))
 582     (setf (code-header-ref code (clone-arg)) value)
 583     (values)))
 584
 585 (define-fop (fop-fun-entry 142)
 586   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 587   (error "FOP-FUN-ENTRY can't be defined without %PRIMITIVE.")
 588   #-sb-xc-host
 589   (let ((info (pop-stack))
 590         (type (pop-stack))
 591         (arglist (pop-stack))
 592         (name (pop-stack))
 593         (code-object (pop-stack))
 594         (offset (read-word-arg)))
 595     (declare (type index offset))
 596     (unless (zerop (logand offset sb!vm:lowtag-mask))
 597       (bug "unaligned function object, offset = #X~X" offset))
 598     (let ((fun (%primitive sb!c:compute-fun code-object offset)))
 599       (setf (%simple-fun-self fun) fun)
 600       (setf (%simple-fun-next fun) (%code-entry-points code-object))
 601       (setf (%code-entry-points code-object) fun)
 602       (setf (%simple-fun-name fun) name)
 603       (setf (%simple-fun-arglist fun) arglist)
 604       (setf (%simple-fun-type fun) type)
 605       (setf (%simple-fun-info fun) info)
 606       ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 607       #+nil (when *load-print*
 608               (load-fresh-line)
 609               (format t "~S defined~%" fun))
 610       fun)))
 611 \f
 612 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 613 ;;;; was sufficiently stale that the functions it called were no
 614 ;;;; longer defined, so I (William Harold Newman) deleted it.
 615 ;;;;
 616 ;;;; In case someone in the future is trying to make sense of FOP layout,
 617 ;;;; it might be worth recording that the Dylan FOPs were
 618 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 619 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 620 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 621 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 622 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 623 \f
 624 ;;;; assemblerish fops
 625
 626 (define-fop (fop-assembler-code 144)
 627   (error "cannot load assembler code except at cold load"))
 628
 629 (define-fop (fop-assembler-routine 145)
 630   (error "cannot load assembler code except at cold load"))
 631
 632 (define-fop (fop-foreign-fixup 147)
 633   (let* ((kind (pop-stack))
 634          (code-object (pop-stack))
 635          (len (read-byte-arg))
 636          (sym (make-string len :element-type 'base-char)))
 637     (read-n-bytes *fasl-input-stream* sym 0 len)
 638     (sb!vm:fixup-code-object code-object
 639                              (read-word-arg)
 640                              (foreign-symbol-address sym)
 641                              kind)
 642     code-object))
 643
 644 (define-fop (fop-assembler-fixup 148)
 645   (let ((routine (pop-stack))
 646         (kind (pop-stack))
 647         (code-object (pop-stack)))
 648     (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 649       (unless found
 650         (error "undefined assembler routine: ~S" routine))
 651       (sb!vm:fixup-code-object code-object (read-word-arg) value kind))
 652     code-object))
 653
 654 (define-fop (fop-code-object-fixup 149)
 655   (let ((kind (pop-stack))
 656         (code-object (pop-stack)))
 657     ;; Note: We don't have to worry about GC moving the code-object after
 658     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 659     ;; we can only use code-object fixups when code-objects don't move.
 660     (sb!vm:fixup-code-object code-object (read-word-arg)
 661                              (get-lisp-obj-address code-object) kind)
 662     code-object))
 663
 664 #!+linkage-table
 665 (define-fop (fop-foreign-dataref-fixup 150)
 666   (let* ((kind (pop-stack))
 667          (code-object (pop-stack))
 668          (len (read-byte-arg))
 669          (sym (make-string len :element-type 'base-char)))
 670     (read-n-bytes *fasl-input-stream* sym 0 len)
 671     (sb!vm:fixup-code-object code-object
 672                              (read-word-arg)
 673                              (foreign-symbol-address sym t)
 674                              kind)
 675     code-object))
 676
 677 ;;; FOPs needed for implementing an IF operator in a FASL
 678
 679 ;;; Skip until a FOP-MAYBE-STOP-SKIPPING with the same POSITION is
 680 ;;; executed. While skipping, we execute most FOPs normally, except
 681 ;;; for ones that a) funcall/eval b) start skipping. This needs to
 682 ;;; be done to ensure that the fop table gets populated correctly
 683 ;;; regardless of the execution path.
 684 (define-fop (fop-skip 151 :pushp nil)
 685   (let ((position (pop-stack)))
 686     (unless *skip-until*
 687       (setf *skip-until* position)))
 688   (values))
 689
 690 ;;; As before, but only start skipping if the top of the FOP stack is NIL.
 691 (define-fop (fop-skip-if-false 152 :pushp nil)
 692   (let ((condition (pop-stack))
 693         (position (pop-stack)))
 694     (unless (or condition
 695                 *skip-until*)
 696       (setf *skip-until* position)))
 697   (values))
 698
 699 ;;; If skipping, pop the top of the stack and discard it. Needed for
 700 ;;; ensuring that the stack stays balanced when skipping.
 701 (define-fop (fop-drop-if-skipping 153 :pushp nil)
 702   (when *skip-until*
 703     (pop-stack))
 704   (values))
 705
 706 ;;; If skipping, push a dummy value on the stack. Needed for
 707 ;;; ensuring that the stack stays balanced when skipping.
 708 (define-fop (fop-push-nil-if-skipping 154 :pushp nil)
 709   (when *skip-until*
 710     (push-stack nil))
 711   (values))
 712
 713 ;;; Stop skipping if the top of the stack matches *SKIP-UNTIL*
 714 (define-fop (fop-maybe-stop-skipping 155 :pushp nil)
 715   (let ((label (pop-stack)))
 716     (when (eql *skip-until* label)
 717       (setf *skip-until* nil)))
 718   (values))