src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Define NAME as a fasl operation, with op-code FOP-CODE. PUSHP
   6 ;;; describes what the body does to the fop stack:
   7 ;;;   T
   8 ;;;     The body might pop the fop stack. The result of the body is
   9 ;;;     pushed on the fop stack.
  10 ;;;   NIL
  11 ;;;     The body might pop the fop stack. The result of the body is
  12 ;;;     discarded.
  13 ;;; STACKP describes whether or not the body interacts with the fop stack.
  14 (defmacro define-fop ((name fop-code &key (pushp t) (stackp t)) &rest forms)
  15   `(progn
  16      (defun ,name ()
  17        ,(if stackp
  18             `(with-fop-stack ,pushp ,@forms)
  19             `(progn ,@forms)))
  20      (%define-fop ',name ,fop-code)))
  21
  22 (defun %define-fop (name code)
  23   (let ((oname (svref *fop-names* code)))
  24     (when (and oname (not (eq oname name)))
  25       (error "multiple names for fop code ~D: ~S and ~S" code name oname)))
  26   ;; KLUDGE: It's mnemonically suboptimal to use 'FOP-CODE as the name of the
  27   ;; tag which associates names with codes when it's also used as one of
  28   ;; the names. Perhaps the fops named FOP-CODE and FOP-SMALL-CODE could
  29   ;; be renamed to something more mnemonic? -- WHN 19990902
  30   (let ((ocode (get name 'fop-code)))
  31     (when (and ocode (/= ocode code))
  32       (error "multiple codes for fop name ~S: ~D and ~D" name code ocode)))
  33   (setf (svref *fop-names* code) name
  34         (get name 'fop-code) code
  35         (svref *fop-funs* code) (symbol-function name))
  36   (values))
  37
  38 ;;; Define a pair of fops which are identical except that one reads
  39 ;;; a four-byte argument while the other reads a one-byte argument. The
  40 ;;; argument can be accessed by using the Clone-Arg macro.
  41 ;;;
  42 ;;; KLUDGE: It would be nice if the definition here encapsulated which
  43 ;;; value ranges went with which fop variant, and chose the correct
  44 ;;; fop code to use. Currently, since such logic isn't encapsulated,
  45 ;;; we see callers doing stuff like
  46 ;;;     (cond ((and (< num-consts #x100) (< total-length #x10000))
  47 ;;;            (dump-fop 'sb!impl::fop-small-code file)
  48 ;;;            (dump-byte num-consts file)
  49 ;;;            (dump-integer-as-n-bytes total-length 2 file))
  50 ;;;           (t
  51 ;;;            (dump-fop 'sb!impl::fop-code file)
  52 ;;;            (dump-unsigned-32 num-consts file)
  53 ;;;            (dump-unsigned-32 total-length file))))
  54 ;;; in several places. It would be cleaner if this could be replaced with
  55 ;;; something like
  56 ;;;     (dump-fop file fop-code num-consts total-length)
  57 ;;; Some of this logic is already in DUMP-FOP*, but that still requires the
  58 ;;; caller to know that it's a 1-byte-arg/4-byte-arg cloned fop pair, and to
  59 ;;; know both the 1-byte-arg and the 4-byte-arg fop names. -- WHN 19990902
  60 (defmacro define-cloned-fops ((name code &key (pushp t) (stackp t))
  61                               (small-name small-code) &rest forms)
  62   (aver (member pushp '(nil t)))
  63   (aver (member stackp '(nil t)))
  64   `(progn
  65      (macrolet ((clone-arg () '(read-arg 4)))
  66        (define-fop (,name ,code :pushp ,pushp :stackp ,stackp) ,@forms))
  67      (macrolet ((clone-arg () '(read-arg 1)))
  68        (define-fop (,small-name ,small-code :pushp ,pushp :stackp stackp) ,@forms))))
  69
  70 ;;; a helper function for reading string values from FASL files: sort
  71 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  72 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  73 ;;; for each element read
  74 (declaim (ftype (function (stream simple-string &optional index) (values)) read-string-as-bytes))
  75 (defun read-string-as-bytes (stream string &optional (length (length string)))
  76   (dotimes (i length)
  77     (setf (aref string i)
  78           (code-char (read-byte stream))))
  79   ;; FIXME: The classic CMU CL code to do this was
  80   ;;   (READ-N-BYTES FILE STRING START END).
  81   ;; It was changed for SBCL because we needed a portable version for
  82   ;; bootstrapping. Benchmark the non-portable version and see whether it's
  83   ;; significantly better than the portable version here. If it is, then use
  84   ;; add as an alternate definition, protected with #-SB-XC-HOST.
  85   (values))
  86 \f
  87 ;;;; miscellaneous fops
  88
  89 ;;; FIXME: POP-STACK should be called something more mnemonic. (POP-FOP-STACK?
  90 ;;; But that would conflict with PUSH-FOP-TABLE. Something, anyway..)
  91
  92 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
  93 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
  94 ;;; progress of FASL loading.
  95 #!+sb-show
  96 (defvar *show-fop-nop4-p* nil)
  97
  98 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
  99 ;;; occurs disproportionately often in fasl files for other reasons,
 100 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 101 ;;; into fasl files for debugging purposes. There's no shortage of
 102 ;;; unused fop codes, so we add this second NOP, which reads 4
 103 ;;; arbitrary bytes and discards them.
 104 (define-fop (fop-nop4 137 :stackp nil)
 105   (let ((arg (read-arg 4)))
 106     (declare (ignorable arg))
 107     #!+sb-show
 108     (when *show-fop-nop4-p*
 109       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 110
 111 (define-fop (fop-nop 0 :stackp nil))
 112 (define-fop (fop-pop 1 :pushp nil) (push-fop-table (pop-stack)))
 113 (define-fop (fop-push 2) (svref *current-fop-table* (read-arg 4)))
 114 (define-fop (fop-byte-push 3) (svref *current-fop-table* (read-arg 1)))
 115
 116 (define-fop (fop-empty-list 4) ())
 117 (define-fop (fop-truth 5) t)
 118 ;;; CMU CL had FOP-POP-FOR-EFFECT as fop 65, but it was never used and seemed
 119 ;;; to have no possible use.
 120 (define-fop (fop-misc-trap 66)
 121   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 122   (error "FOP-MISC-TRAP can't be defined without %PRIMITIVE.")
 123   #-sb-xc-host
 124   (%primitive sb!c:make-other-immediate-type 0 sb!vm:unbound-marker-widetag))
 125
 126 (define-fop (fop-character 68)
 127   (code-char (read-arg 3)))
 128 ;;; CMU CL had FOP-CHARACTER as fop 68, but it's not needed in current
 129 ;;; SBCL as we have no extended characters, only 1-byte characters.
 130 ;;; (Ditto for CMU CL, actually: FOP-CHARACTER was speculative generality.)
 131 (define-fop (fop-short-character 69)
 132   (code-char (read-arg 1)))
 133
 134 (define-cloned-fops (fop-struct 48) (fop-small-struct 49)
 135   (let* ((size (clone-arg))
 136          (res (%make-instance size)))
 137     (declare (type index size))
 138     (do ((n (1- size) (1- n)))
 139         ((minusp n))
 140       (declare (type (integer -1 #.most-positive-fixnum) n))
 141       (setf (%instance-ref res n) (pop-stack)))
 142     res))
 143
 144 (define-fop (fop-layout 45)
 145   (let ((length (pop-stack))
 146         (depthoid (pop-stack))
 147         (inherits (pop-stack))
 148         (name (pop-stack)))
 149     (find-and-init-or-check-layout name length inherits depthoid)))
 150
 151 (define-fop (fop-end-group 64 :stackp nil)
 152   (/show0 "THROWing FASL-GROUP-END")
 153   (throw 'fasl-group-end t))
 154
 155 ;;; In the normal loader, we just ignore these. GENESIS overwrites
 156 ;;; FOP-MAYBE-COLD-LOAD with something that knows whether to revert to
 157 ;;; cold-loading or not.
 158 (define-fop (fop-normal-load 81 :stackp nil))
 159 (define-fop (fop-maybe-cold-load 82 :stackp nil))
 160
 161 (define-fop (fop-verify-table-size 62 :stackp nil)
 162   (let ((expected-index (read-arg 4)))
 163     (unless (= *current-fop-table-index* expected-index)
 164       (error "internal error: fasl table of improper size"))))
 165 (define-fop (fop-verify-empty-stack 63 :stackp nil)
 166   (unless (= *fop-stack-pointer* *fop-stack-pointer-on-entry*)
 167     (error "internal error: fasl stack not empty when it should be")))
 168 \f
 169 ;;;; fops for loading symbols
 170
 171 (defvar *load-symbol-buffer* (make-string 100))
 172 (declaim (simple-string *load-symbol-buffer*))
 173 (defvar *load-symbol-buffer-size* 100)
 174 (declaim (type index *load-symbol-buffer-size*))
 175 ;;; FIXME:
 176 ;;;   (1) *LOAD-SYMBOL-BUFFER-SIZE* is redundant, should just be
 177 ;;;       (LENGTH *LOAD-SYMBOL-BUFFER*).
 178 ;;;   (2) *LOAD-SYMBOL-BUFFER* should not have a global value, but should
 179 ;;;       be bound on entry to FASL loading, and it should be renamed to
 180 ;;;       *FASL-SYMBOL-BUFFER*.
 181
 182 (macrolet (;; FIXME: Should all this code really be duplicated inside
 183            ;; each fop? Perhaps it would be better for this shared
 184            ;; code to live in FLET FROB1 and FLET FROB4 (for the
 185            ;; two different sizes of counts).
 186            (frob (name code name-size package)
 187              (let ((n-package (gensym))
 188                    (n-size (gensym))
 189                    (n-buffer (gensym)))
 190                `(define-fop (,name ,code)
 191                   (prepare-for-fast-read-byte *fasl-input-stream*
 192                     (let ((,n-package ,package)
 193                           (,n-size (fast-read-u-integer ,name-size)))
 194                       (when (> ,n-size *load-symbol-buffer-size*)
 195                         (setq *load-symbol-buffer*
 196                               (make-string (setq *load-symbol-buffer-size*
 197                                                  (* ,n-size 2)))))
 198                       (done-with-fast-read-byte)
 199                       (let ((,n-buffer *load-symbol-buffer*))
 200                         (read-string-as-bytes *fasl-input-stream*
 201                                               ,n-buffer
 202                                               ,n-size)
 203                         (push-fop-table (intern* ,n-buffer
 204                                                  ,n-size
 205                                                  ,n-package)))))))))
 206
 207   ;; Note: CMU CL had FOP-SYMBOL-SAVE and FOP-SMALL-SYMBOL-SAVE, but
 208   ;; since they made the behavior of the fasloader depend on the
 209   ;; *PACKAGE* variable, not only were they a pain to support (because
 210   ;; they required various hacks to handle *PACKAGE*-manipulation
 211   ;; forms) they were basically broken by design, because ANSI gives
 212   ;; the user so much flexibility in manipulating *PACKAGE* at
 213   ;; load-time that no reasonable hacks could possibly make things
 214   ;; work right. The ones used in CMU CL certainly didn't, as shown by
 215   ;; e.g.
 216   ;;   (IN-PACKAGE :CL-USER)
 217   ;;     (DEFVAR CL::*FOO* 'FOO-VALUE)
 218   ;;     (EVAL-WHEN (:COMPILE-TOPLEVEL :LOAD-TOPLEVEL :EXECUTE)
 219   ;;       (SETF *PACKAGE* (FIND-PACKAGE :CL)))
 220   ;; which in CMU CL 2.4.9 defines a variable CL-USER::*FOO* instead of
 221   ;; defining CL::*FOO*. Therefore, we don't use those fops in SBCL.
 222   ;;(frob fop-symbol-save               6 4 *package*)
 223   ;;(frob fop-small-symbol-save   7 1 *package*)
 224
 225   (frob fop-lisp-symbol-save          75 4 *cl-package*)
 226   (frob fop-lisp-small-symbol-save    76 1 *cl-package*)
 227   (frob fop-keyword-symbol-save       77 4 *keyword-package*)
 228   (frob fop-keyword-small-symbol-save 78 1 *keyword-package*)
 229
 230   ;; FIXME: Because we don't have FOP-SYMBOL-SAVE any more, an enormous number
 231   ;; of symbols will fall through to this case, probably resulting in bloated
 232   ;; fasl files. A new
 233   ;; FOP-SYMBOL-IN-LAST-PACKAGE-SAVE/FOP-SMALL-SYMBOL-IN-LAST-PACKAGE-SAVE
 234   ;; cloned fop pair could undo some of this bloat.
 235   (frob fop-symbol-in-package-save 8 4
 236     (svref *current-fop-table* (fast-read-u-integer 4)))
 237   (frob fop-small-symbol-in-package-save 9 1
 238     (svref *current-fop-table* (fast-read-u-integer 4)))
 239   (frob fop-symbol-in-byte-package-save 10 4
 240     (svref *current-fop-table* (fast-read-u-integer 1)))
 241   (frob fop-small-symbol-in-byte-package-save 11 1
 242     (svref *current-fop-table* (fast-read-u-integer 1))))
 243
 244 (define-cloned-fops (fop-uninterned-symbol-save 12)
 245                     (fop-uninterned-small-symbol-save 13)
 246   (let* ((arg (clone-arg))
 247          (res (make-string arg)))
 248     (read-string-as-bytes *fasl-input-stream* res)
 249     (push-fop-table (make-symbol res))))
 250
 251 (define-fop (fop-package 14)
 252   (find-undeleted-package-or-lose (pop-stack)))
 253 \f
 254 ;;;; fops for loading numbers
 255
 256 ;;; Load a signed integer LENGTH bytes long from *FASL-INPUT-STREAM*.
 257 (defun load-s-integer (length)
 258   (declare (fixnum length))
 259   ;; #+cmu (declare (optimize (inhibit-warnings 2)))
 260   (do* ((index length (1- index))
 261         (byte 0 (read-byte *fasl-input-stream*))
 262         (result 0 (+ result (ash byte bits)))
 263         (bits 0 (+ bits 8)))
 264        ((= index 0)
 265         (if (logbitp 7 byte)    ; look at sign bit
 266             (- result (ash 1 bits))
 267             result))
 268     (declare (fixnum index byte bits))))
 269
 270 (define-cloned-fops (fop-integer 33) (fop-small-integer 34)
 271   (load-s-integer (clone-arg)))
 272
 273 (define-fop (fop-word-integer 35)
 274   (prepare-for-fast-read-byte *fasl-input-stream*
 275     (prog1
 276      (fast-read-s-integer 4)
 277      (done-with-fast-read-byte))))
 278
 279 (define-fop (fop-byte-integer 36)
 280   (prepare-for-fast-read-byte *fasl-input-stream*
 281     (prog1
 282      (fast-read-s-integer 1)
 283      (done-with-fast-read-byte))))
 284
 285 (define-fop (fop-ratio 70)
 286   (let ((den (pop-stack)))
 287     (%make-ratio (pop-stack) den)))
 288
 289 (define-fop (fop-complex 71)
 290   (let ((im (pop-stack)))
 291     (%make-complex (pop-stack) im)))
 292
 293 (define-fop (fop-complex-single-float 72)
 294   (prepare-for-fast-read-byte *fasl-input-stream*
 295     (prog1
 296         (complex (make-single-float (fast-read-s-integer 4))
 297                  (make-single-float (fast-read-s-integer 4)))
 298       (done-with-fast-read-byte))))
 299
 300 (define-fop (fop-complex-double-float 73)
 301   (prepare-for-fast-read-byte *fasl-input-stream*
 302     (prog1
 303         (let* ((re-lo (fast-read-u-integer 4))
 304                (re-hi (fast-read-u-integer 4))
 305                (re (make-double-float re-hi re-lo))
 306                (im-lo (fast-read-u-integer 4))
 307                (im-hi (fast-read-u-integer 4))
 308                (im (make-double-float im-hi im-lo)))
 309           (complex re im))
 310       (done-with-fast-read-byte))))
 311
 312 #!+long-float
 313 (define-fop (fop-complex-long-float 67)
 314   (prepare-for-fast-read-byte *fasl-input-stream*
 315     (prog1
 316         (let* ((re-lo (fast-read-u-integer 4))
 317                #!+sparc (re-mid (fast-read-u-integer 4))
 318                (re-hi (fast-read-u-integer 4))
 319                (re-exp (fast-read-s-integer #!+x86 2 #!+sparc 4))
 320                (re (make-long-float re-exp re-hi #!+sparc re-mid re-lo))
 321                (im-lo (fast-read-u-integer 4))
 322                #!+sparc (im-mid (fast-read-u-integer 4))
 323                (im-hi (fast-read-u-integer 4))
 324                (im-exp (fast-read-s-integer #!+x86 2 #!+sparc 4))
 325                (im (make-long-float im-exp im-hi #!+sparc im-mid im-lo)))
 326           (complex re im))
 327       (done-with-fast-read-byte))))
 328
 329 (define-fop (fop-single-float 46)
 330   (prepare-for-fast-read-byte *fasl-input-stream*
 331     (prog1 (make-single-float (fast-read-s-integer 4))
 332       (done-with-fast-read-byte))))
 333
 334 (define-fop (fop-double-float 47)
 335   (prepare-for-fast-read-byte *fasl-input-stream*
 336     (prog1
 337         (let ((lo (fast-read-u-integer 4)))
 338           (make-double-float (fast-read-s-integer 4) lo))
 339       (done-with-fast-read-byte))))
 340
 341 #!+long-float
 342 (define-fop (fop-long-float 52)
 343   (prepare-for-fast-read-byte *fasl-input-stream*
 344     (prog1
 345         (let ((lo (fast-read-u-integer 4))
 346               #!+sparc (mid (fast-read-u-integer 4))
 347               (hi (fast-read-u-integer 4))
 348               (exp (fast-read-s-integer #!+x86 2 #!+sparc 4)))
 349           (make-long-float exp hi #!+sparc mid lo))
 350       (done-with-fast-read-byte))))
 351 \f
 352 ;;;; loading lists
 353
 354 (define-fop (fop-list 15)
 355   (do ((res () (cons (pop-stack) res))
 356        (n (read-arg 1) (1- n)))
 357       ((zerop n) res)
 358     (declare (type index n))))
 359
 360 (define-fop (fop-list* 16)
 361   (do ((res (pop-stack) (cons (pop-stack) res))
 362        (n (read-arg 1) (1- n)))
 363       ((zerop n) res)
 364     (declare (type index n))))
 365
 366 (macrolet ((frob (name op fun n)
 367              `(define-fop (,name ,op)
 368                 (call-with-popped-things ,fun ,n))))
 369
 370   (frob fop-list-1 17 list 1)
 371   (frob fop-list-2 18 list 2)
 372   (frob fop-list-3 19 list 3)
 373   (frob fop-list-4 20 list 4)
 374   (frob fop-list-5 21 list 5)
 375   (frob fop-list-6 22 list 6)
 376   (frob fop-list-7 23 list 7)
 377   (frob fop-list-8 24 list 8)
 378
 379   (frob fop-list*-1 25 list* 2)
 380   (frob fop-list*-2 26 list* 3)
 381   (frob fop-list*-3 27 list* 4)
 382   (frob fop-list*-4 28 list* 5)
 383   (frob fop-list*-5 29 list* 6)
 384   (frob fop-list*-6 30 list* 7)
 385   (frob fop-list*-7 31 list* 8)
 386   (frob fop-list*-8 32 list* 9))
 387 \f
 388 ;;;; fops for loading arrays
 389
 390 (define-cloned-fops (fop-string 37) (fop-small-string 38)
 391   (let* ((arg (clone-arg))
 392          (res (make-string arg)))
 393     (read-string-as-bytes *fasl-input-stream* res)
 394     res))
 395
 396 (define-cloned-fops (fop-vector 39) (fop-small-vector 40)
 397   (let* ((size (clone-arg))
 398          (res (make-array size)))
 399     (declare (fixnum size))
 400     (do ((n (1- size) (1- n)))
 401         ((minusp n))
 402       (setf (svref res n) (pop-stack)))
 403     res))
 404
 405 (define-fop (fop-array 83)
 406   (let* ((rank (read-arg 4))
 407          (vec (pop-stack))
 408          (length (length vec))
 409          (res (make-array-header sb!vm:simple-array-widetag rank)))
 410     (declare (simple-array vec)
 411              (type (unsigned-byte 24) rank))
 412     (set-array-header res vec length length 0
 413                       (do ((i rank (1- i))
 414                            (dimensions () (cons (pop-stack) dimensions)))
 415                           ((zerop i) dimensions)
 416                         (declare (type index i)))
 417                       nil)
 418     res))
 419
 420 (define-fop (fop-single-float-vector 84)
 421   (let* ((length (read-arg 4))
 422          (result (make-array length :element-type 'single-float)))
 423     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes))
 424     result))
 425
 426 (define-fop (fop-double-float-vector 85)
 427   (let* ((length (read-arg 4))
 428          (result (make-array length :element-type 'double-float)))
 429     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 430     result))
 431
 432 #!+long-float
 433 (define-fop (fop-long-float-vector 88)
 434   (let* ((length (read-arg 4))
 435          (result (make-array length :element-type 'long-float)))
 436     (read-n-bytes *fasl-input-stream*
 437                   result
 438                   0
 439                   (* length sb!vm:n-word-bytes #!+x86 3 #!+sparc 4))
 440     result))
 441
 442 (define-fop (fop-complex-single-float-vector 86)
 443   (let* ((length (read-arg 4))
 444          (result (make-array length :element-type '(complex single-float))))
 445     (read-n-bytes *fasl-input-stream* result 0 (* length sb!vm:n-word-bytes 2))
 446     result))
 447
 448 (define-fop (fop-complex-double-float-vector 87)
 449   (let* ((length (read-arg 4))
 450          (result (make-array length :element-type '(complex double-float))))
 451     (read-n-bytes *fasl-input-stream*
 452                   result
 453                   0
 454                   (* length sb!vm:n-word-bytes 2 2))
 455     result))
 456
 457 #!+long-float
 458 (define-fop (fop-complex-long-float-vector 89)
 459   (let* ((length (read-arg 4))
 460          (result (make-array length :element-type '(complex long-float))))
 461     (read-n-bytes *fasl-input-stream* result 0
 462                   (* length sb!vm:n-word-bytes #!+x86 3 #!+sparc 4 2))
 463     result))
 464
 465 ;;; CMU CL comment:
 466 ;;;   *** NOT *** the FOP-INT-VECTOR as currently documented in rtguts.
 467 ;;;   Size must be a directly supported I-vector element size, with no
 468 ;;;   extra bits. This must be packed according to the local
 469 ;;;   byte-ordering, allowing us to directly read the bits.
 470 (define-fop (fop-int-vector 43)
 471   (prepare-for-fast-read-byte *fasl-input-stream*
 472     (let* ((len (fast-read-u-integer 4))
 473            (size (fast-read-byte))
 474            (res (case size
 475                   (1 (make-array len :element-type 'bit))
 476                   (2 (make-array len :element-type '(unsigned-byte 2)))
 477                   (4 (make-array len :element-type '(unsigned-byte 4)))
 478                   (8 (make-array len :element-type '(unsigned-byte 8)))
 479                   (16 (make-array len :element-type '(unsigned-byte 16)))
 480                   (32 (make-array len :element-type '(unsigned-byte 32)))
 481                   (t (error "internal error: losing i-vector element size: ~S"
 482                             size)))))
 483       (declare (type index len))
 484       (done-with-fast-read-byte)
 485       (read-n-bytes *fasl-input-stream*
 486                     res
 487                     0
 488                     (ceiling (the index (* size len))
 489                              sb!vm:n-byte-bits))
 490       res)))
 491
 492 ;;; This is the same as FOP-INT-VECTOR, except this is for signed
 493 ;;; SIMPLE-ARRAYs.
 494 (define-fop (fop-signed-int-vector 50)
 495   (prepare-for-fast-read-byte *fasl-input-stream*
 496     (let* ((len (fast-read-u-integer 4))
 497            (size (fast-read-byte))
 498            (res (case size
 499                   (8 (make-array len :element-type '(signed-byte 8)))
 500                   (16 (make-array len :element-type '(signed-byte 16)))
 501                   (30 (make-array len :element-type '(signed-byte 30)))
 502                   (32 (make-array len :element-type '(signed-byte 32)))
 503                   (t (error "internal error: losing si-vector element size: ~S"
 504                             size)))))
 505       (declare (type index len))
 506       (done-with-fast-read-byte)
 507       (read-n-bytes *fasl-input-stream*
 508                     res
 509                     0
 510                     (ceiling (the index (* (if (= size 30)
 511                                                32 ; Adjust for (signed-byte 30)
 512                                                size) len)) sb!vm:n-byte-bits))
 513       res)))
 514
 515 (define-fop (fop-eval 53)
 516   (let ((result (eval (pop-stack))))
 517     ;; FIXME: CMU CL had this code here:
 518     ;;   (when *load-print*
 519     ;;     (load-fresh-line)
 520     ;;     (prin1 result)
 521     ;;     (terpri))
 522     ;; Unfortunately, this dependence on the *LOAD-PRINT* global
 523     ;; variable is non-ANSI, so for now we've just punted printing in
 524     ;; fasl loading.
 525     result))
 526
 527 (define-fop (fop-eval-for-effect 54 :pushp nil)
 528   (let ((result (eval (pop-stack))))
 529     ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 530     (declare (ignore result))
 531     #+nil (when *load-print*
 532             (load-fresh-line)
 533             (prin1 result)
 534             (terpri))))
 535
 536 (define-fop (fop-funcall 55)
 537   (let ((arg (read-arg 1)))
 538     (if (zerop arg)
 539         (funcall (pop-stack))
 540         (do ((args () (cons (pop-stack) args))
 541              (n arg (1- n)))
 542             ((zerop n) (apply (pop-stack) args))
 543           (declare (type index n))))))
 544
 545 (define-fop (fop-funcall-for-effect 56 :pushp nil)
 546   (let ((arg (read-arg 1)))
 547     (if (zerop arg)
 548         (funcall (pop-stack))
 549         (do ((args () (cons (pop-stack) args))
 550              (n arg (1- n)))
 551             ((zerop n) (apply (pop-stack) args))
 552           (declare (type index n))))))
 553 \f
 554 ;;;; fops for fixing up circularities
 555
 556 (define-fop (fop-rplaca 200 :pushp nil)
 557   (let ((obj (svref *current-fop-table* (read-arg 4)))
 558         (idx (read-arg 4))
 559         (val (pop-stack)))
 560     (setf (car (nthcdr idx obj)) val)))
 561
 562 (define-fop (fop-rplacd 201 :pushp nil)
 563   (let ((obj (svref *current-fop-table* (read-arg 4)))
 564         (idx (read-arg 4))
 565         (val (pop-stack)))
 566     (setf (cdr (nthcdr idx obj)) val)))
 567
 568 (define-fop (fop-svset 202 :pushp nil)
 569   (let* ((obi (read-arg 4))
 570          (obj (svref *current-fop-table* obi))
 571          (idx (read-arg 4))
 572          (val (pop-stack)))
 573     (if (typep obj 'instance)
 574         (setf (%instance-ref obj idx) val)
 575         (setf (svref obj idx) val))))
 576
 577 (define-fop (fop-structset 204 :pushp nil)
 578   (setf (%instance-ref (svref *current-fop-table* (read-arg 4))
 579                        (read-arg 4))
 580         (pop-stack)))
 581
 582 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 583 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 584 (define-fop (fop-nthcdr 203)
 585   (nthcdr (read-arg 4) (pop-stack)))
 586 \f
 587 ;;;; fops for loading functions
 588
 589 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 590 ;;; conventionally placed at the beginning of each fasl file to test
 591 ;;; for compatibility between the fasl file and the CMU CL which
 592 ;;; loaded it. In SBCL, this functionality has been replaced by
 593 ;;; putting the implementation and version in required fields in the
 594 ;;; fasl file header.)
 595
 596 (define-fop (fop-code 58 :stackp nil)
 597   (load-code (read-arg 4) (read-arg 4)))
 598
 599 (define-fop (fop-small-code 59 :stackp nil)
 600   (load-code (read-arg 1) (read-arg 2)))
 601
 602 (define-fop (fop-fdefinition 60)
 603   (fdefinition-object (pop-stack) t))
 604
 605 (define-fop (fop-sanctify-for-execution 61)
 606   (let ((component (pop-stack)))
 607     (sb!vm:sanctify-for-execution component)
 608     component))
 609
 610 (define-fop (fop-fset 74 :pushp nil)
 611   ;; Ordinary, not-for-cold-load code shouldn't need to mess with this
 612   ;; at all, since it's only used as part of the conspiracy between
 613   ;; the cross-compiler and GENESIS to statically link FDEFINITIONs
 614   ;; for cold init.
 615   (warn "~@<FOP-FSET seen in ordinary load (not cold load) -- quite strange! ~
 616 If you didn't do something strange to cause this, please report it as a ~
 617 bug.~:@>")
 618   ;; Unlike CMU CL, we don't treat this as a no-op in ordinary code.
 619   ;; If the user (or, more likely, developer) is trying to reload
 620   ;; compiled-for-cold-load code into a warm SBCL, we'll do a warm
 621   ;; assignment. (This is partly for abstract tidiness, since the warm
 622   ;; assignment is the closest analogy to what happens at cold load,
 623   ;; and partly because otherwise our compiled-for-cold-load code will
 624   ;; fail, since in SBCL things like compiled-for-cold-load %DEFUN
 625   ;; depend more strongly than in CMU CL on FOP-FSET actually doing
 626   ;; something.)
 627   (let ((fn (pop-stack))
 628         (name (pop-stack)))
 629     (setf (fdefinition name) fn)))
 630
 631 ;;; Modify a slot in a CONSTANTS object.
 632 (define-cloned-fops (fop-alter-code 140 :pushp nil) (fop-byte-alter-code 141)
 633   (let ((value (pop-stack))
 634         (code (pop-stack)))
 635     (setf (code-header-ref code (clone-arg)) value)
 636     (values)))
 637
 638 (define-fop (fop-fun-entry 142)
 639   #+sb-xc-host ; since xc host doesn't know how to compile %PRIMITIVE
 640   (error "FOP-FUN-ENTRY can't be defined without %PRIMITIVE.")
 641   #-sb-xc-host
 642   (let ((type (pop-stack))
 643         (arglist (pop-stack))
 644         (name (pop-stack))
 645         (code-object (pop-stack))
 646         (offset (read-arg 4)))
 647     (declare (type index offset))
 648     (unless (zerop (logand offset sb!vm:lowtag-mask))
 649       (error "internal error: unaligned function object, offset = #X~X"
 650              offset))
 651     (let ((fun (%primitive sb!c:compute-fun code-object offset)))
 652       (setf (%simple-fun-self fun) fun)
 653       (setf (%simple-fun-next fun) (%code-entry-points code-object))
 654       (setf (%code-entry-points code-object) fun)
 655       (setf (%simple-fun-name fun) name)
 656       (setf (%simple-fun-arglist fun) arglist)
 657       (setf (%simple-fun-type fun) type)
 658       ;; FIXME: See the comment about *LOAD-PRINT* in FOP-EVAL.
 659       #+nil (when *load-print*
 660               (load-fresh-line)
 661               (format t "~S defined~%" fun))
 662       fun)))
 663 \f
 664 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 665 ;;;; was sufficiently stale that the functions it called were no
 666 ;;;; longer defined, so I (William Harold Newman) deleted it.
 667 ;;;;
 668 ;;;; In case someone in the future is trying to make sense of FOP layout,
 669 ;;;; it might be worth recording that the Dylan FOPs were
 670 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 671 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 672 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 673 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 674 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 675 \f
 676 ;;;; assemblerish fops
 677
 678 (define-fop (fop-foreign-fixup 147)
 679   (let* ((kind (pop-stack))
 680          (code-object (pop-stack))
 681          (len (read-arg 1))
 682          (sym (make-string len)))
 683     (read-n-bytes *fasl-input-stream* sym 0 len)
 684     (sb!vm:fixup-code-object code-object
 685                              (read-arg 4)
 686                              (foreign-symbol-address-as-integer sym)
 687                              kind)
 688     code-object))
 689
 690 (define-fop (fop-assembler-code 144)
 691   (error "cannot load assembler code except at cold load"))
 692
 693 (define-fop (fop-assembler-routine 145)
 694   (error "cannot load assembler code except at cold load"))
 695
 696 (define-fop (fop-assembler-fixup 148)
 697   (let ((routine (pop-stack))
 698         (kind (pop-stack))
 699         (code-object (pop-stack)))
 700     (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 701       (unless found
 702         (error "undefined assembler routine: ~S" routine))
 703       (sb!vm:fixup-code-object code-object (read-arg 4) value kind))
 704     code-object))
 705
 706 (define-fop (fop-code-object-fixup 149)
 707   (let ((kind (pop-stack))
 708         (code-object (pop-stack)))
 709     ;; Note: We don't have to worry about GC moving the code-object after
 710     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 711     ;; we can only use code-object fixups when code-objects don't move.
 712     (sb!vm:fixup-code-object code-object (read-arg 4)
 713                              (get-lisp-obj-address code-object) kind)
 714     code-object))