src/code/foreign.lisp

   1 ;;;; Foreign symbol linkage
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-(or elf mach-o win32)
  15 (error "Not an ELF, Mach-O, or Win32 platform?")
  16
  17 (defun extern-alien-name (name)
  18   (handler-case
  19       #!+(or elf (and mach-o (not dlshim))) (coerce name 'base-string)
  20       #!+(or (and mach-o dlshim) win32) (concatenate 'base-string "_" name)
  21     (error ()
  22       (error "invalid external alien name: ~S" name))))
  23
  24 ;;; *STATIC-FOREIGN-SYMBOLS* are static as opposed to "dynamic" (not
  25 ;;; as opposed to C's "extern"). The table contains symbols known at
  26 ;;; the time that the program was built, but not symbols defined in
  27 ;;; object files which have been loaded dynamically since then.
  28 (declaim (type hash-table *static-foreign-symbols*))
  29 (defvar *static-foreign-symbols* (make-hash-table :test 'equal))
  30
  31 (declaim
  32  (ftype (sfunction (string hash-table) (or integer null)) find-foreign-symbol-in-table))
  33 (defun find-foreign-symbol-in-table (name table)
  34   (let ((extern (extern-alien-name name)))
  35     (values
  36      (or (gethash extern table)
  37          (gethash (concatenate 'base-string
  38                                #!+(and mach-o dlshim) "_ldso_stub_"
  39                                #!+(and mach-o (not dlshim)) "ldso_stub__"
  40                                #!-mach-o "ldso_stub__"
  41                                extern) table)))))
  42
  43 (defun find-foreign-symbol-address (name)
  44   "Returns the address of the foreign symbol NAME, or NIL. Does not enter the
  45 symbol in the linkage table, and never returns an address in the linkage-table."
  46   (or (find-foreign-symbol-in-table name *static-foreign-symbols*)
  47       (find-dynamic-foreign-symbol-address name)))
  48
  49 (defun foreign-symbol-address (name &optional datap)
  50   "Returns the address of the foreign symbol NAME. DATAP must be true if the
  51 symbol designates a variable (used only on linkage-table platforms). Returns a
  52 secondary value that is true if DATAP was true and the symbol is a dynamic
  53 foreign symbol.
  54
  55 On linkage-table ports the returned address is always static: either direct
  56 address of a static symbol, or the linkage-table address of a dynamic one.
  57 Dynamic symbols are entered into the linkage-table if they aren't there already.
  58
  59 On non-linkage-table ports signals an error if the symbol isn't found."
  60   (declare (ignorable datap))
  61   (let ((static (find-foreign-symbol-in-table name  *static-foreign-symbols*)))
  62     (if static
  63         (values static nil)
  64         #!+os-provides-dlopen
  65         (progn
  66           #-sb-xc-host
  67           (values #!-linkage-table
  68                   (ensure-dynamic-foreign-symbol-address name)
  69                   #!+linkage-table
  70                   (ensure-foreign-symbol-linkage name datap)
  71                   t)
  72           #+sb-xc-host
  73           (error 'undefined-alien-error :name name))
  74         #!-os-provides-dlopen
  75         (error 'undefined-alien-error :name name))))
  76
  77 (defun foreign-symbol-sap (symbol &optional datap)
  78   "Returns a SAP corresponding to the foreign symbol. DATAP must be true if the
  79 symbol designates a variable (used only on linkage-table platforms). May enter
  80 the symbol into the linkage-table. On non-linkage-table ports signals an error
  81 if the symbol isn't found."
  82   (declare (ignorable datap))
  83   #!-linkage-table
  84   (int-sap (foreign-symbol-address symbol))
  85   #!+linkage-table
  86   (multiple-value-bind (addr sharedp)
  87       (foreign-symbol-address symbol datap)
  88     #+sb-xc-host
  89     (aver (not sharedp))
  90     ;; If the address is from linkage-table and refers to data
  91     ;; we need to do a bit of juggling. It is not the address of the
  92     ;; variable, but the address where the real address is stored.
  93     (if (and sharedp datap)
  94         (int-sap (sap-ref-word (int-sap addr) 0))
  95         (int-sap addr))))
  96
  97 #-sb-xc-host
  98 (defun foreign-reinit ()
  99   #!+os-provides-dlopen
 100   (reopen-shared-objects)
 101   #!+linkage-table
 102   ;; Don't warn about undefined aliens on startup. The same core can
 103   ;; reasonably be expected to work with different versions of the
 104   ;; same library.
 105   (handler-bind ((style-warning #'muffle-warning))
 106     (update-linkage-table)))
 107
 108 ;;; Cleanups before saving a core
 109 #-sb-xc-host
 110 (defun foreign-deinit ()
 111   #!+(and os-provides-dlopen (or (not linkage-table) win32))
 112   (when (dynamic-foreign-symbols-p)
 113     (warn "~@<Saving cores with alien definitions referring to non-static ~
 114            foreign symbols is unsupported on this platform: references to ~
 115            such foreign symbols from the restarted core will not work. You ~
 116            may be able to work around this limitation by reloading all ~
 117            foreign definitions and code using them in the restarted core, ~
 118            but no guarantees.~%~%Dynamic foreign symbols in this core: ~
 119            ~{~A~^, ~}~:@>" (list-dynamic-foreign-symbols)))
 120   #!+os-provides-dlopen
 121   (close-shared-objects))
 122
 123 (declaim (maybe-inline sap-foreign-symbol))
 124 (defun sap-foreign-symbol (sap)
 125   (declare (ignorable sap))
 126   #-sb-xc-host
 127   (let ((addr (sap-int sap)))
 128     (declare (ignorable addr))
 129     #!+linkage-table
 130     (when (<= sb!vm:linkage-table-space-start
 131               addr
 132               sb!vm:linkage-table-space-end)
 133       (dohash ((name-and-datap info) *linkage-info* :locked t)
 134         (let ((table-addr (linkage-info-address info)))
 135           (when (and (<= table-addr addr)
 136                      (< addr (+ table-addr sb!vm:linkage-table-entry-size)))
 137             (return-from sap-foreign-symbol (car name-and-datap))))))
 138     #!+os-provides-dladdr
 139     (with-alien ((info (struct dl-info
 140                                (filename c-string)
 141                                (base unsigned)
 142                                (symbol c-string)
 143                                (symbol-address unsigned)))
 144                  (dladdr (function unsigned unsigned (* (struct dl-info)))
 145                          :extern "dladdr"))
 146       (let ((err (alien-funcall dladdr addr (addr info))))
 147         (if (zerop err)
 148             nil
 149             (slot info 'symbol))))
 150     ;; FIXME: Even in the absence of dladdr we could search the
 151     ;; static foreign symbols (and *linkage-info*, for that matter).
 152     ))
 153
 154 ;;; How we learn about foreign symbols and dlhandles initially
 155 (defvar *!initial-foreign-symbols*)
 156
 157 #-sb-xc-host
 158 (defun !foreign-cold-init ()
 159   (dolist (symbol *!initial-foreign-symbols*)
 160     (setf (gethash (car symbol) *static-foreign-symbols*) (cdr symbol)))
 161   #!+(and os-provides-dlopen (not win32))
 162   (setf *runtime-dlhandle* (dlopen-or-lose))
 163   #!+os-provides-dlopen
 164   (setf *shared-objects* nil))
 165
 166 #!-os-provides-dlopen
 167 (define-unsupported-fun load-shared-object)