src/code/gc.lisp

   1 ;;;; garbage collection and allocation-related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13 \f
  14 ;;;; DYNAMIC-USAGE and friends
  15
  16 #!-sb-fluid
  17 (declaim (inline current-dynamic-space-start))
  18 #!+gencgc
  19 (defun current-dynamic-space-start () sb!vm:dynamic-space-start)
  20 #!-gencgc
  21 (defun current-dynamic-space-start ()
  22   (sb!alien:extern-alien "current_dynamic_space" sb!alien:unsigned-long))
  23
  24 #!-sb-fluid
  25 (declaim (inline dynamic-usage))
  26 #!+gencgc
  27 (defun dynamic-usage ()
  28   (sb!alien:extern-alien "bytes_allocated" os-vm-size-t))
  29 #!-gencgc
  30 (defun dynamic-usage ()
  31   (the (unsigned-byte 32)
  32        (- (sb!sys:sap-int (sb!c::dynamic-space-free-pointer))
  33           (current-dynamic-space-start))))
  34
  35 (defun static-space-usage ()
  36   (- (ash sb!vm:*static-space-free-pointer* sb!vm:n-fixnum-tag-bits)
  37      sb!vm:static-space-start))
  38
  39 (defun read-only-space-usage ()
  40   (- (ash sb!vm::*read-only-space-free-pointer* sb!vm:n-fixnum-tag-bits)
  41      sb!vm:read-only-space-start))
  42
  43 (defun control-stack-usage ()
  44   #!-stack-grows-downward-not-upward
  45   (- (sb!sys:sap-int (sb!c::control-stack-pointer-sap))
  46      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-start*)))
  47   #!+stack-grows-downward-not-upward
  48   (- (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
  49      (sb!sys:sap-int (sb!c::control-stack-pointer-sap))))
  50
  51 (defun binding-stack-usage ()
  52   (- (sb!sys:sap-int (sb!c::binding-stack-pointer-sap))
  53      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*binding-stack-start*))))
  54 \f
  55 ;;;; ROOM
  56
  57 (defun room-minimal-info ()
  58   (format t "Dynamic space usage is:   ~10:D bytes.~%" (dynamic-usage))
  59   (format t "Read-only space usage is: ~10:D bytes.~%" (read-only-space-usage))
  60   (format t "Static space usage is:    ~10:D bytes.~%" (static-space-usage))
  61   (format t "Control stack usage is:   ~10:D bytes.~%" (control-stack-usage))
  62   (format t "Binding stack usage is:   ~10:D bytes.~%" (binding-stack-usage))
  63   #!+sb-thread
  64   (format t
  65           "Control and binding stack usage is for the current thread only.~%")
  66   (format t "Garbage collection is currently ~:[enabled~;DISABLED~].~%"
  67           *gc-inhibit*))
  68
  69 (defun room-intermediate-info ()
  70   (room-minimal-info)
  71   (sb!vm:memory-usage :count-spaces '(:dynamic)
  72                       :print-spaces t
  73                       :cutoff 0.05f0
  74                       :print-summary nil))
  75
  76 (defun room-maximal-info ()
  77   ;; FIXME: SB!VM:INSTANCE-USAGE calls suppressed until bug 344 is fixed
  78   (room-intermediate-info)
  79   ;; old way, could be restored when bug 344 fixed:
  80   ;;x (room-minimal-info)
  81   ;;x (sb!vm:memory-usage :count-spaces '(:static :dynamic))
  82   ;;x (sb!vm:instance-usage :dynamic :top-n 10)
  83   ;;x (sb!vm:instance-usage :static :top-n 10)
  84   )
  85
  86 (defun room (&optional (verbosity :default))
  87   #!+sb-doc
  88   "Print to *STANDARD-OUTPUT* information about the state of internal
  89   storage and its management. The optional argument controls the
  90   verbosity of output. If it is T, ROOM prints out a maximal amount of
  91   information. If it is NIL, ROOM prints out a minimal amount of
  92   information. If it is :DEFAULT or it is not supplied, ROOM prints out
  93   an intermediate amount of information."
  94   (fresh-line)
  95   (ecase verbosity
  96     ((t)
  97      (room-maximal-info))
  98     ((nil)
  99      (room-minimal-info))
 100     (:default
 101      (room-intermediate-info)))
 102   (values))
 103 \f
 104 ;;;; GET-BYTES-CONSED
 105
 106 ;;; the total number of bytes freed so far (including any freeing
 107 ;;; which goes on in PURIFY)
 108 ;;;
 109 ;;; (We save this so that we can calculate the total number of bytes
 110 ;;; ever allocated by adding this to the number of bytes currently
 111 ;;; allocated and never freed.)
 112 (declaim (type unsigned-byte *n-bytes-freed-or-purified*))
 113 (defvar *n-bytes-freed-or-purified* 0)
 114 (defun gc-reinit ()
 115   (setq *gc-inhibit* nil)
 116   (gc)
 117   (setf *n-bytes-freed-or-purified* 0
 118         *gc-run-time* 0
 119         ;; See comment in interr.lisp
 120         *heap-exhausted-error-condition* (make-condition 'heap-exhausted-error)))
 121
 122 (declaim (ftype (sfunction () unsigned-byte) get-bytes-consed))
 123 (defun get-bytes-consed ()
 124   #!+sb-doc
 125   "Return the number of bytes consed since the program began. Typically
 126 this result will be a consed bignum, so if you have an application (e.g.
 127 profiling) which can't tolerate the overhead of consing bignums, you'll
 128 probably want either to hack in at a lower level (as the code in the
 129 SB-PROFILE package does), or to design a more microefficient interface
 130 and submit it as a patch."
 131   (+ (dynamic-usage)
 132      *n-bytes-freed-or-purified*))
 133 \f
 134 ;;;; GC hooks
 135
 136 (defvar *after-gc-hooks* nil
 137   "Called after each garbage collection, except for garbage collections
 138 triggered during thread exits. In a multithreaded environment these hooks may
 139 run in any thread.")
 140
 141 \f
 142 ;;;; internal GC
 143
 144 (sb!alien:define-alien-routine collect-garbage sb!alien:int
 145   (#!+gencgc last-gen #!-gencgc ignore sb!alien:int))
 146
 147 #!+sb-thread
 148 (progn
 149   (sb!alien:define-alien-routine gc-stop-the-world sb!alien:void)
 150   (sb!alien:define-alien-routine gc-start-the-world sb!alien:void))
 151 #!-sb-thread
 152 (progn
 153   (defun gc-stop-the-world ())
 154   (defun gc-start-the-world ()))
 155
 156 #!+gencgc
 157 (progn
 158   (sb!alien:define-alien-variable ("gc_logfile" %gc-logfile) (* char))
 159   (defun (setf gc-logfile) (pathname)
 160     (let ((new (when pathname
 161                  (sb!alien:make-alien-string
 162                   (native-namestring (translate-logical-pathname pathname)
 163                                      :as-file t))))
 164           (old %gc-logfile))
 165       (setf %gc-logfile new)
 166       (when old
 167         (sb!alien:free-alien old))
 168       pathname))
 169   (defun gc-logfile ()
 170     #!+sb-doc
 171     "Return the pathname used to log garbage collections. Can be SETF.
 172 Default is NIL, meaning collections are not logged. If non-null, the
 173 designated file is opened before and after each collection, and generation
 174 statistics are appended to it."
 175     (let ((val (cast %gc-logfile c-string)))
 176       (when val
 177         (native-pathname val))))
 178   (declaim (inline dynamic-space-size))
 179   (defun dynamic-space-size ()
 180     "Size of the dynamic space in bytes."
 181     (sb!alien:extern-alien "dynamic_space_size" os-vm-size-t)))
 182 \f
 183 ;;;; SUB-GC
 184
 185 ;;; SUB-GC does a garbage collection.  This is called from three places:
 186 ;;; (1) The C runtime will call here when it detects that we've consed
 187 ;;;     enough to exceed the gc trigger threshold.  This is done in
 188 ;;;     alloc() for gencgc or interrupt_maybe_gc() for cheneygc
 189 ;;; (2) The user may request a collection using GC, below
 190 ;;; (3) At the end of a WITHOUT-GCING section, we are called if
 191 ;;;     *NEED-TO-COLLECT-GARBAGE* is true
 192 ;;;
 193 ;;; This is different from the behaviour in 0.7 and earlier: it no
 194 ;;; longer decides whether to GC based on thresholds.  If you call
 195 ;;; SUB-GC you will definitely get a GC either now or when the
 196 ;;; WITHOUT-GCING is over
 197
 198 ;;; For GENCGC all generations < GEN will be GC'ed.
 199
 200 (defvar *already-in-gc* (sb!thread:make-mutex :name "GC lock"))
 201
 202 ;;; A unique GC id. This is supplied for code that needs to detect
 203 ;;; whether a GC has happened since some earlier point in time. For
 204 ;;; example:
 205 ;;;
 206 ;;;   (let ((epoch *gc-epoch*))
 207 ;;;      ...
 208 ;;;      (unless (eql epoch *gc-epoch)
 209 ;;;        ....))
 210 ;;;
 211 ;;; This isn't just a fixnum counter since then we'd have theoretical
 212 ;;; problems when exactly 2^29 GCs happen between epoch
 213 ;;; comparisons. Unlikely, but the cost of using a cons instead is too
 214 ;;; small to measure. -- JES, 2007-09-30
 215 (declaim (type cons *gc-epoch*))
 216 (defvar *gc-epoch* (cons nil nil))
 217
 218 (defun sub-gc (&key (gen 0))
 219   (cond (*gc-inhibit*
 220          (setf *gc-pending* t)
 221          nil)
 222         (t
 223          (without-interrupts
 224            (setf *gc-pending* :in-progress)
 225            ;; Tricks to to prevent triggerring a recursive gc. This is
 226            ;; like a WITHOUT-GCING inside the lock except that we
 227            ;; cannot call MAYBE-HANDLE-PENDING-GC at the end, because
 228            ;; that would lead to a recursive attempt on the lock. In
 229            ;; case you are wondering, wrapping the lock in a
 230            ;; WITHOUT-GCING would also deadlock. The
 231            ;; *IN-WITHOUT-GCING* part is used to tell the runtime that
 232            ;; it's ok to have a pending gc even though *GC-INHIBIT* is
 233            ;; NIL.
 234            ;;
 235            ;; Now, if GET-MUTEX did not cons, that would be enough.
 236            ;; Because it does, we need the :IN-PROGRESS bit above to
 237            ;; tell the runtime not to trigger gcs.
 238            (sb!thread::without-thread-waiting-for (:already-without-interrupts t)
 239              (let* ((sb!impl::*in-without-gcing* t)
 240                     (sb!impl::*deadline* nil)
 241                     (sb!impl::*deadline-seconds* nil))
 242                (sb!thread:with-mutex (*already-in-gc*)
 243                  (let ((*gc-inhibit* t))
 244                    (let ((old-usage (dynamic-usage))
 245                          (new-usage 0))
 246                      (unsafe-clear-roots gen)
 247                      (gc-stop-the-world)
 248                      (let ((start-time (get-internal-run-time)))
 249                        (collect-garbage gen)
 250                        (setf *gc-epoch* (cons nil nil))
 251                        (let ((run-time (- (get-internal-run-time) start-time)))
 252                          ;; KLUDGE: Sometimes we see the second getrusage() call
 253                          ;; return a smaller value than the first, which can
 254                          ;; lead to *GC-RUN-TIME* to going negative, which in
 255                          ;; turn is a type-error.
 256                          (when (plusp run-time)
 257                            (incf *gc-run-time* run-time))))
 258                      #!+sb-safepoint
 259                      (setf *stop-for-gc-pending* nil)
 260                      (setf *gc-pending* nil
 261                            new-usage (dynamic-usage))
 262                      #!+sb-thread
 263                      (assert (not *stop-for-gc-pending*))
 264                      (gc-start-the-world)
 265                      ;; In a multithreaded environment the other threads
 266                      ;; will see *n-b-f-o-p* change a little late, but
 267                      ;; that's OK.
 268                      (let ((freed (- old-usage new-usage)))
 269                        ;; GENCGC occasionally reports negative here, but
 270                        ;; the current belief is that it is part of the
 271                        ;; normal order of things and not a bug.
 272                        (when (plusp freed)
 273                          (incf *n-bytes-freed-or-purified* freed))))))))
 274            ;; While holding the mutex we were protected from
 275            ;; SIG_STOP_FOR_GC and recursive GCs. Now, in order to
 276            ;; preserve the invariant (*GC-PENDING* ->
 277            ;; pseudo-atomic-interrupted or *GC-INHIBIT*), let's check
 278            ;; explicitly for a pending gc before interrupts are
 279            ;; enabled again.
 280            (maybe-handle-pending-gc))
 281          t)))
 282
 283 (defun post-gc ()
 284   ;; Outside the mutex, interrupts may be enabled: these may cause
 285   ;; another GC. FIXME: it can potentially exceed maximum interrupt
 286   ;; nesting by triggering GCs.
 287   ;;
 288   ;; Can that be avoided by having the finalizers and hooks run only
 289   ;; from the outermost SUB-GC? If the nested GCs happen in interrupt
 290   ;; handlers that's not enough.
 291   ;;
 292   ;; KLUDGE: Don't run the hooks in GC's if:
 293   ;;
 294   ;; A) this thread is dying, so that user-code never runs with
 295   ;;    (thread-alive-p *current-thread*) => nil
 296   ;;
 297   ;; B) interrupts are disabled somewhere up the call chain since we
 298   ;;    don't want to run user code in such a case.
 299   ;;
 300   ;; The long-term solution will be to keep a separate thread for
 301   ;; finalizers and after-gc hooks.
 302   (when (sb!thread:thread-alive-p sb!thread:*current-thread*)
 303     (when *allow-with-interrupts*
 304       (sb!thread::without-thread-waiting-for ()
 305         (with-interrupts
 306           (run-pending-finalizers)
 307           (call-hooks "after-GC" *after-gc-hooks* :on-error :warn))))))
 308
 309 ;;; This is the user-advertised garbage collection function.
 310 (defun gc (&key (full nil) (gen 0) &allow-other-keys)
 311   #!+(and sb-doc gencgc)
 312   "Initiate a garbage collection.
 313
 314 The default is to initiate a nursery collection, which may in turn
 315 trigger a collection of one or more older generations as well. If FULL
 316 is true, all generations are collected. If GEN is provided, it can be
 317 used to specify the oldest generation guaranteed to be collected.
 318
 319 On CheneyGC platforms arguments FULL and GEN take no effect: a full
 320 collection is always preformed."
 321   #!+(and sb-doc (not gencgc))
 322   "Initiate a garbage collection.
 323
 324 The collection is always a full collection.
 325
 326 Arguments FULL and GEN can be used for compatibility with GENCGC
 327 platforms: there the default is to initiate a nursery collection,
 328 which may in turn trigger a collection of one or more older
 329 generations as well. If FULL is true, all generations are collected.
 330 If GEN is provided, it can be used to specify the oldest generation
 331 guaranteed to be collected."
 332   (when (sub-gc :gen (if full 6 gen))
 333     (post-gc)))
 334
 335 (define-alien-routine scrub-control-stack sb!alien:void)
 336
 337 (defun unsafe-clear-roots (gen)
 338   #!-gencgc (declare (ignore gen))
 339   ;; KLUDGE: Do things in an attempt to get rid of extra roots. Unsafe
 340   ;; as having these cons more then we have space left leads to huge
 341   ;; badness.
 342   (scrub-control-stack)
 343   ;; Power cache of the bignum printer: drops overly large bignums and
 344   ;; removes duplicate entries.
 345   (scrub-power-cache)
 346   ;; Clear caches depending on the generation being collected.
 347   #!+gencgc
 348   (cond ((eql 0 gen))
 349         ((eql 1 gen)
 350          (ctype-of-cache-clear))
 351         (t
 352          (drop-all-hash-caches)))
 353   #!-gencgc
 354   (drop-all-hash-caches))
 355 \f
 356 ;;;; auxiliary functions
 357
 358 (defun bytes-consed-between-gcs ()
 359   #!+sb-doc
 360   "The amount of memory that will be allocated before the next garbage
 361 collection is initiated. This can be set with SETF.
 362
 363 On GENCGC platforms this is the nursery size, and defaults to 5% of dynamic
 364 space size.
 365
 366 Note: currently changes to this value are lost when saving core."
 367   (sb!alien:extern-alien "bytes_consed_between_gcs" os-vm-size-t))
 368
 369 (defun (setf bytes-consed-between-gcs) (val)
 370   (declare (type index val))
 371   (setf (sb!alien:extern-alien "bytes_consed_between_gcs" os-vm-size-t)
 372         val))
 373
 374 (declaim (inline maybe-handle-pending-gc))
 375 (defun maybe-handle-pending-gc ()
 376   (when (and (not *gc-inhibit*)
 377              (or #!+sb-thread *stop-for-gc-pending*
 378                  *gc-pending*))
 379     (sb!unix::receive-pending-interrupt)))
 380
 381 ;;;; GENCGC specifics
 382 ;;;;
 383 ;;;; For documentation convenience, these have stubs on non-GENCGC platforms
 384 ;;;; as well.
 385 #!+gencgc
 386 (deftype generation-index ()
 387   '(integer 0 #.sb!vm:+pseudo-static-generation+))
 388
 389 ;;; FIXME: GENERATION (and PAGE, as seen in room.lisp) should probably be
 390 ;;; defined in Lisp, and written to header files by genesis, instead of this
 391 ;;; OAOOMiness -- this duplicates the struct definition in gencgc.c.
 392 #!+gencgc
 393 (define-alien-type generation
 394     (struct generation
 395             (alloc-start-page page-index-t)
 396             (alloc-unboxed-start-page page-index-t)
 397             (alloc-large-start-page page-index-t)
 398             (alloc-large-unboxed-start-page page-index-t)
 399             (bytes-allocated os-vm-size-t)
 400             (gc-trigger os-vm-size-t)
 401             (bytes-consed-between-gcs os-vm-size-t)
 402             (number-of-gcs int)
 403             (number-of-gcs-before-promotion int)
 404             (cum-sum-bytes-allocated os-vm-size-t)
 405             (minimum-age-before-gc double)))
 406
 407 #!+gencgc
 408 (define-alien-variable generations
 409     (array generation #.(1+ sb!vm:+pseudo-static-generation+)))
 410
 411 (macrolet ((def (slot doc &optional setfp)
 412              (declare (ignorable doc))
 413              `(progn
 414                 (defun ,(symbolicate "GENERATION-" slot) (generation)
 415                   #!+sb-doc
 416                   ,doc
 417                   #!+gencgc
 418                   (declare (generation-index generation))
 419                   #!-gencgc
 420                   (declare (ignore generation))
 421                   #!-gencgc
 422                   (error "~S is a GENCGC only function and unavailable in this build"
 423                          ',slot)
 424                   #!+gencgc
 425                   (slot (deref generations generation) ',slot))
 426                 ,@(when setfp
 427                         `((defun (setf ,(symbolicate "GENERATION-" slot)) (value generation)
 428                             #!+gencgc
 429                             (declare (generation-index generation))
 430                             #!-gencgc
 431                             (declare (ignore value generation))
 432                             #!-gencgc
 433                             (error "(SETF ~S) is a GENCGC only function and unavailable in this build"
 434                                    ',slot)
 435                             #!+gencgc
 436                             (setf (slot (deref generations generation) ',slot) value)))))))
 437   (def bytes-consed-between-gcs
 438       "Number of bytes that can be allocated to GENERATION before that
 439 generation is considered for garbage collection. This value is meaningless for
 440 generation 0 (the nursery): see BYTES-CONSED-BETWEEN-GCS instead. Default is
 441 5% of the dynamic space size divided by the number of non-nursery generations.
 442 Can be assigned to using SETF. Available on GENCGC platforms only.
 443
 444 Experimental: interface subject to change."
 445     t)
 446   (def minimum-age-before-gc
 447       "Minimum average age of objects allocated to GENERATION before that
 448 generation is may be garbage collected. Default is 0.75. See also
 449 GENERATION-AVERAGE-AGE. Can be assigned to using SETF. Available on GENCGC
 450 platforms only.
 451
 452 Experimental: interface subject to change."
 453     t)
 454   (def number-of-gcs-before-promotion
 455       "Number of times garbage collection is done on GENERATION before
 456 automatic promotion to the next generation is triggered. Default is 1. Can be
 457 assigned to using SETF. Available on GENCGC platforms only.
 458
 459 Experimental: interface subject to change."
 460     t)
 461   (def bytes-allocated
 462       "Number of bytes allocated to GENERATION currently. Available on GENCGC
 463 platforms only.
 464
 465 Experimental: interface subject to change.")
 466   (def number-of-gcs
 467       "Number of times garbage collection has been done on GENERATION without
 468 promotion. Available on GENCGC platforms only.
 469
 470 Experimental: interface subject to change."))
 471   (defun generation-average-age (generation)
 472     "Average age of memory allocated to GENERATION: average number of times
 473 objects allocated to the generation have seen younger objects promoted to it.
 474 Available on GENCGC platforms only.
 475
 476 Experimental: interface subject to change."
 477     #!+gencgc
 478     (declare (generation-index generation))
 479     #!-gencgc (declare (ignore generation))
 480     #!-gencgc
 481     (error "~S is a GENCGC only function and unavailable in this build."
 482            'generation-average-age)
 483     #!+gencgc
 484     (alien-funcall (extern-alien "generation_average_age"
 485                                  (function double generation-index-t))
 486                    generation))