src/code/gc.lisp

   1 ;;;; garbage collection and allocation-related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13 \f
  14 ;;;; DYNAMIC-USAGE and friends
  15
  16 (declaim (special sb!vm:*read-only-space-free-pointer*
  17                   sb!vm:*static-space-free-pointer*))
  18
  19 (eval-when (:compile-toplevel :execute)
  20   (sb!xc:defmacro def-c-var-fun (lisp-fun c-var-name)
  21     `(defun ,lisp-fun ()
  22        (sb!alien:extern-alien ,c-var-name (sb!alien:unsigned 32)))))
  23
  24 #!-sb-fluid
  25 (declaim (inline current-dynamic-space-start))
  26 #!+gencgc
  27 (defun current-dynamic-space-start () sb!vm:dynamic-space-start)
  28 #!-gencgc
  29 (def-c-var-fun current-dynamic-space-start "current_dynamic_space")
  30
  31 #!-sb-fluid
  32 (declaim (inline dynamic-usage))
  33 #!+gencgc
  34 (def-c-var-fun dynamic-usage "bytes_allocated")
  35 #!-gencgc
  36 (defun dynamic-usage ()
  37   (the (unsigned-byte 32)
  38        (- (sb!sys:sap-int (sb!c::dynamic-space-free-pointer))
  39           (current-dynamic-space-start))))
  40
  41 (defun static-space-usage ()
  42   (- (* sb!vm:*static-space-free-pointer* sb!vm:n-word-bytes)
  43      sb!vm:static-space-start))
  44
  45 (defun read-only-space-usage ()
  46   (- (* sb!vm::*read-only-space-free-pointer* sb!vm:n-word-bytes)
  47      sb!vm:read-only-space-start))
  48
  49 (defun control-stack-usage ()
  50   #!-stack-grows-downward-not-upward
  51   (- (sb!sys:sap-int (sb!c::control-stack-pointer-sap))
  52      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-start*)))
  53   #!+stack-grows-downward-not-upward
  54   (- (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
  55      (sb!sys:sap-int (sb!c::control-stack-pointer-sap))))
  56
  57 (defun binding-stack-usage ()
  58   (- (sb!sys:sap-int (sb!c::binding-stack-pointer-sap))
  59      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*binding-stack-start*))))
  60 \f
  61 ;;;; ROOM
  62
  63 (defun room-minimal-info ()
  64   (format t "Dynamic space usage is:   ~10:D bytes.~%" (dynamic-usage))
  65   (format t "Read-only space usage is: ~10:D bytes.~%" (read-only-space-usage))
  66   (format t "Static space usage is:    ~10:D bytes.~%" (static-space-usage))
  67   (format t "Control stack usage is:   ~10:D bytes.~%" (control-stack-usage))
  68   (format t "Binding stack usage is:   ~10:D bytes.~%" (binding-stack-usage))
  69   #!+sb-thread
  70   (format t
  71           "Control and binding stack usage is for the current thread only.~%")
  72   (format t "Garbage collection is currently ~:[enabled~;DISABLED~].~%"
  73           *gc-inhibit*))
  74
  75 (defun room-intermediate-info ()
  76   (room-minimal-info)
  77   (sb!vm:memory-usage :count-spaces '(:dynamic)
  78                       :print-spaces t
  79                       :cutoff 0.05f0
  80                       :print-summary nil))
  81
  82 (defun room-maximal-info ()
  83   ;; FIXME: SB!VM:INSTANCE-USAGE calls suppressed until bug 344 is fixed
  84   (room-intermediate-info)
  85   ;; old way, could be restored when bug 344 fixed:
  86   ;;x (room-minimal-info)
  87   ;;x (sb!vm:memory-usage :count-spaces '(:static :dynamic))
  88   ;;x (sb!vm:instance-usage :dynamic :top-n 10)
  89   ;;x (sb!vm:instance-usage :static :top-n 10)
  90   )
  91
  92 (defun room (&optional (verbosity :default))
  93   #!+sb-doc
  94   "Print to *STANDARD-OUTPUT* information about the state of internal
  95   storage and its management. The optional argument controls the
  96   verbosity of output. If it is T, ROOM prints out a maximal amount of
  97   information. If it is NIL, ROOM prints out a minimal amount of
  98   information. If it is :DEFAULT or it is not supplied, ROOM prints out
  99   an intermediate amount of information."
 100   (fresh-line)
 101   (ecase verbosity
 102     ((t)
 103      (room-maximal-info))
 104     ((nil)
 105      (room-minimal-info))
 106     (:default
 107      (room-intermediate-info)))
 108   (values))
 109 \f
 110 ;;;; GET-BYTES-CONSED
 111
 112 ;;; the total number of bytes freed so far (including any freeing
 113 ;;; which goes on in PURIFY)
 114 ;;;
 115 ;;; (We save this so that we can calculate the total number of bytes
 116 ;;; ever allocated by adding this to the number of bytes currently
 117 ;;; allocated and never freed.)
 118 (declaim (type unsigned-byte *n-bytes-freed-or-purified*))
 119 (defvar *n-bytes-freed-or-purified* 0)
 120 (defun gc-reinit ()
 121   (gc-on)
 122   (gc)
 123   (setf *n-bytes-freed-or-purified* 0
 124         *gc-run-time* 0
 125         ;; See comment in interr.lisp
 126         *heap-exhausted-error-condition* (make-condition 'heap-exhausted-error)))
 127
 128 (declaim (ftype (sfunction () unsigned-byte) get-bytes-consed))
 129 (defun get-bytes-consed ()
 130   #!+sb-doc
 131   "Return the number of bytes consed since the program began. Typically
 132 this result will be a consed bignum, so if you have an application (e.g.
 133 profiling) which can't tolerate the overhead of consing bignums, you'll
 134 probably want either to hack in at a lower level (as the code in the
 135 SB-PROFILE package does), or to design a more microefficient interface
 136 and submit it as a patch."
 137   (+ (dynamic-usage)
 138      *n-bytes-freed-or-purified*))
 139 \f
 140 ;;;; GC hooks
 141
 142 (defvar *after-gc-hooks* nil
 143   "Called after each garbage collection, except for garbage collections
 144 triggered during thread exits. In a multithreaded environment these hooks may
 145 run in any thread.")
 146
 147 \f
 148 ;;;; internal GC
 149
 150 (sb!alien:define-alien-routine collect-garbage sb!alien:int
 151   (#!+gencgc last-gen #!-gencgc ignore sb!alien:int))
 152
 153 #!+sb-thread
 154 (progn
 155   (sb!alien:define-alien-routine gc-stop-the-world sb!alien:void)
 156   (sb!alien:define-alien-routine gc-start-the-world sb!alien:void))
 157 #!-sb-thread
 158 (progn
 159   (defun gc-stop-the-world ())
 160   (defun gc-start-the-world ()))
 161
 162 \f
 163 ;;;; SUB-GC
 164
 165 ;;; SUB-GC does a garbage collection.  This is called from three places:
 166 ;;; (1) The C runtime will call here when it detects that we've consed
 167 ;;;     enough to exceed the gc trigger threshold.  This is done in
 168 ;;;     alloc() for gencgc or interrupt_maybe_gc() for cheneygc
 169 ;;; (2) The user may request a collection using GC, below
 170 ;;; (3) At the end of a WITHOUT-GCING section, we are called if
 171 ;;;     *NEED-TO-COLLECT-GARBAGE* is true
 172 ;;;
 173 ;;; This is different from the behaviour in 0.7 and earlier: it no
 174 ;;; longer decides whether to GC based on thresholds.  If you call
 175 ;;; SUB-GC you will definitely get a GC either now or when the
 176 ;;; WITHOUT-GCING is over
 177
 178 ;;; For GENCGC all generations < GEN will be GC'ed.
 179
 180 (defvar *already-in-gc*
 181   (sb!thread:make-mutex :name "GC lock") "ID of thread running SUB-GC")
 182
 183 ;;; A unique GC id. This is supplied for code that needs to detect
 184 ;;; whether a GC has happened since some earlier point in time. For
 185 ;;; example:
 186 ;;;
 187 ;;;   (let ((epoch *gc-epoch*))
 188 ;;;      ...
 189 ;;;      (unless (eql epoch *gc-epoch)
 190 ;;;        ....))
 191 ;;;
 192 ;;; This isn't just a fixnum counter since then we'd have theoretical
 193 ;;; problems when exactly 2^29 GCs happen between epoch
 194 ;;; comparisons. Unlikely, but the cost of using a cons instead is too
 195 ;;; small to measure. -- JES, 2007-09-30
 196 (declaim (type cons *gc-epoch*))
 197 (defvar *gc-epoch* (cons nil nil))
 198
 199 (defun sub-gc (&key (gen 0))
 200   (unless (eq sb!thread:*current-thread*
 201               (sb!thread:mutex-value *already-in-gc*))
 202     ;; With gencgc, unless *GC-PENDING* every allocation in this
 203     ;; function triggers another gc, potentially exceeding maximum
 204     ;; interrupt nesting. If *GC-INHIBIT* is not true, however,
 205     ;; there is no guarantee that we would ever check for pending
 206     ;; GC -- so in that case we must first disable interrupts, which
 207     ;; needs to be done for GC anyways...
 208     (cond (*gc-inhibit*
 209            (setf *gc-pending* t))
 210           (t
 211            (without-interrupts
 212              (setf *gc-pending* t)
 213              (sb!thread:with-mutex (*already-in-gc*)
 214                (let ((old-usage (dynamic-usage))
 215                      (new-usage 0))
 216                  (unsafe-clear-roots)
 217
 218                  (gc-stop-the-world)
 219                  (let ((start-time (get-internal-run-time)))
 220                    (collect-garbage gen)
 221                    (setf *gc-epoch* (cons nil nil))
 222                    (incf *gc-run-time*
 223                          (- (get-internal-run-time) start-time)))
 224                  (setf *gc-pending* nil
 225                        new-usage (dynamic-usage))
 226                  (gc-start-the-world)
 227
 228                  ;; In a multithreaded environment the other threads will
 229                  ;; see *n-b-f-o-p* change a little late, but that's OK.
 230                  (let ((freed (- old-usage new-usage)))
 231                    ;; GENCGC occasionally reports negative here, but the
 232                    ;; current belief is that it is part of the normal order
 233                    ;; of things and not a bug.
 234                    (when (plusp freed)
 235                      (incf *n-bytes-freed-or-purified* freed))))))
 236
 237            ;; Outside the mutex, interrupts enabled: these may cause
 238            ;; another GC. FIXME: it can potentially exceed maximum
 239            ;; interrupt nesting by triggering GCs.
 240            ;;
 241            ;; Can that be avoided by having the finalizers and hooks
 242            ;; run only from the outermost SUB-GC?
 243            ;;
 244            ;; KLUDGE: Don't run the hooks in GC's triggered by dying
 245            ;; threads, so that user-code never runs with
 246            ;;   (thread-alive-p *current-thread*) => nil
 247            ;; The long-term solution will be to keep a separate thread
 248            ;; for finalizers and after-gc hooks.
 249            (when (sb!thread:thread-alive-p sb!thread:*current-thread*)
 250              (run-pending-finalizers)
 251              (call-hooks "after-GC" *after-gc-hooks* :on-error :warn))))))
 252
 253 ;;; This is the user-advertised garbage collection function.
 254 (defun gc (&key (gen 0) (full nil) &allow-other-keys)
 255   #!+(and sb-doc gencgc)
 256   "Initiate a garbage collection. GEN controls the number of generations
 257   to garbage collect."
 258   #!+(and sb-doc (not gencgc))
 259   "Initiate a garbage collection. GEN may be provided for compatibility with
 260   generational garbage collectors, but is ignored in this implementation."
 261   (sub-gc :gen (if full 6 gen)))
 262
 263 (defun unsafe-clear-roots ()
 264   ;; KLUDGE: Do things in an attempt to get rid of extra roots. Unsafe
 265   ;; as having these cons more then we have space left leads to huge
 266   ;; badness.
 267   (scrub-control-stack)
 268   ;; Power cache of the bignum printer: drops overly large bignums and
 269   ;; removes duplicate entries.
 270   (scrub-power-cache)
 271   ;; FIXME: CTYPE-OF-CACHE-CLEAR isn't thread-safe.
 272   #!-sb-thread
 273   (ctype-of-cache-clear))
 274
 275 \f
 276 ;;;; auxiliary functions
 277
 278 (defun bytes-consed-between-gcs ()
 279   #!+sb-doc
 280   "Return the amount of memory that will be allocated before the next garbage
 281    collection is initiated. This can be set with SETF."
 282   (sb!alien:extern-alien "bytes_consed_between_gcs"
 283                          (sb!alien:unsigned 32)))
 284
 285 (defun (setf bytes-consed-between-gcs) (val)
 286   (declare (type index val))
 287   (setf (sb!alien:extern-alien "bytes_consed_between_gcs"
 288                                (sb!alien:unsigned 32))
 289         val))
 290
 291 (declaim (inline maybe-handle-pending-gc))
 292 (defun maybe-handle-pending-gc ()
 293   (when (and (not *gc-inhibit*)
 294              (or #!+sb-thread *stop-for-gc-pending*
 295                  *gc-pending*))
 296     (sb!unix::receive-pending-interrupt)))
 297
 298 ;;; These work both regardless of whether we're inside WITHOUT-GCING
 299 ;;; or not.
 300 (defun gc-on ()
 301   #!+sb-doc
 302   "Enable the garbage collector."
 303   (setq *gc-inhibit* nil)
 304   (maybe-handle-pending-gc)
 305   nil)
 306
 307 (defun gc-off ()
 308   #!+sb-doc
 309   "Disable the garbage collector."
 310   (setq *gc-inhibit* t)
 311   nil)