src/code/gc.lisp

   1 ;;;; garbage collection and allocation-related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13 \f
  14 ;;;; DYNAMIC-USAGE and friends
  15
  16 (declaim (special sb!vm:*read-only-space-free-pointer*
  17                   sb!vm:*static-space-free-pointer*))
  18
  19 (eval-when (:compile-toplevel :execute)
  20   (sb!xc:defmacro def-c-var-fun (lisp-fun c-var-name)
  21     `(defun ,lisp-fun ()
  22        (sb!alien:extern-alien ,c-var-name (sb!alien:unsigned 32)))))
  23
  24 #!-sb-fluid
  25 (declaim (inline current-dynamic-space-start))
  26 #!+gencgc
  27 (defun current-dynamic-space-start () sb!vm:dynamic-space-start)
  28 #!-gencgc
  29 (def-c-var-fun current-dynamic-space-start "current_dynamic_space")
  30
  31 #!-sb-fluid
  32 (declaim (inline dynamic-usage))
  33 #!+gencgc
  34 (def-c-var-fun dynamic-usage "bytes_allocated")
  35 #!-gencgc
  36 (defun dynamic-usage ()
  37   (the (unsigned-byte 32)
  38        (- (sb!sys:sap-int (sb!c::dynamic-space-free-pointer))
  39           (current-dynamic-space-start))))
  40
  41 (defun static-space-usage ()
  42   (- (* sb!vm:*static-space-free-pointer* sb!vm:n-word-bytes)
  43      sb!vm:static-space-start))
  44
  45 (defun read-only-space-usage ()
  46   (- (* sb!vm::*read-only-space-free-pointer* sb!vm:n-word-bytes)
  47      sb!vm:read-only-space-start))
  48
  49 (defun control-stack-usage ()
  50   #!-stack-grows-downward-not-upward
  51   (- (sb!sys:sap-int (sb!c::control-stack-pointer-sap))
  52      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-start*)))
  53   #!+stack-grows-downward-not-upward
  54   (- (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
  55      (sb!sys:sap-int (sb!c::control-stack-pointer-sap))))
  56
  57 (defun binding-stack-usage ()
  58   (- (sb!sys:sap-int (sb!c::binding-stack-pointer-sap))
  59      (sb!sys:sap-int (sb!di::descriptor-sap sb!vm:*binding-stack-start*))))
  60 \f
  61 ;;;; ROOM
  62
  63 (defun room-minimal-info ()
  64   (format t "Dynamic space usage is:   ~10:D bytes.~%" (dynamic-usage))
  65   (format t "Read-only space usage is: ~10:D bytes.~%" (read-only-space-usage))
  66   (format t "Static space usage is:    ~10:D bytes.~%" (static-space-usage))
  67   (format t "Control stack usage is:   ~10:D bytes.~%" (control-stack-usage))
  68   (format t "Binding stack usage is:   ~10:D bytes.~%" (binding-stack-usage))
  69   #!+sb-thread
  70   (format t
  71           "Control and binding stack usage is for the current thread only.~%")
  72   (format t "Garbage collection is currently ~:[enabled~;DISABLED~].~%"
  73           *gc-inhibit*))
  74
  75 (defun room-intermediate-info ()
  76   (room-minimal-info)
  77   (sb!vm:memory-usage :count-spaces '(:dynamic)
  78                       :print-spaces t
  79                       :cutoff 0.05f0
  80                       :print-summary nil))
  81
  82 (defun room-maximal-info ()
  83   ;; FIXME: SB!VM:INSTANCE-USAGE calls suppressed until bug 344 is fixed
  84   (room-intermediate-info)
  85   ;; old way, could be restored when bug 344 fixed:
  86   ;;x (room-minimal-info)
  87   ;;x (sb!vm:memory-usage :count-spaces '(:static :dynamic))
  88   ;;x (sb!vm:instance-usage :dynamic :top-n 10)
  89   ;;x (sb!vm:instance-usage :static :top-n 10)
  90   )
  91
  92 (defun room (&optional (verbosity :default))
  93   #!+sb-doc
  94   "Print to *STANDARD-OUTPUT* information about the state of internal
  95   storage and its management. The optional argument controls the
  96   verbosity of output. If it is T, ROOM prints out a maximal amount of
  97   information. If it is NIL, ROOM prints out a minimal amount of
  98   information. If it is :DEFAULT or it is not supplied, ROOM prints out
  99   an intermediate amount of information."
 100   (fresh-line)
 101   (ecase verbosity
 102     ((t)
 103      (room-maximal-info))
 104     ((nil)
 105      (room-minimal-info))
 106     (:default
 107      (room-intermediate-info)))
 108   (values))
 109 \f
 110 ;;;; GET-BYTES-CONSED
 111
 112 ;;; the total number of bytes freed so far (including any freeing
 113 ;;; which goes on in PURIFY)
 114 ;;;
 115 ;;; (We save this so that we can calculate the total number of bytes
 116 ;;; ever allocated by adding this to the number of bytes currently
 117 ;;; allocated and never freed.)
 118 (declaim (type unsigned-byte *n-bytes-freed-or-purified*))
 119 (defvar *n-bytes-freed-or-purified* 0)
 120 (defun gc-reinit ()
 121   (gc-on)
 122   (gc)
 123   (setf *n-bytes-freed-or-purified* 0))
 124
 125 (declaim (ftype (function () unsigned-byte) get-bytes-consed))
 126 (defun get-bytes-consed ()
 127   #!+sb-doc
 128   "Return the number of bytes consed since the program began. Typically
 129 this result will be a consed bignum, so if you have an application (e.g.
 130 profiling) which can't tolerate the overhead of consing bignums, you'll
 131 probably want either to hack in at a lower level (as the code in the
 132 SB-PROFILE package does), or to design a more microefficient interface
 133 and submit it as a patch."
 134   (+ (dynamic-usage)
 135      *n-bytes-freed-or-purified*))
 136 \f
 137 ;;;; GC hooks
 138
 139 (defvar *after-gc-hooks* nil
 140   "Called after each garbage collection. In a multithreaded
 141 environment these hooks may run in any thread.")
 142
 143 \f
 144 ;;;; internal GC
 145
 146 (sb!alien:define-alien-routine collect-garbage sb!alien:int
 147   (#!+gencgc last-gen #!-gencgc ignore sb!alien:int))
 148
 149 #!+sb-thread
 150 (progn
 151   (sb!alien:define-alien-routine gc-stop-the-world sb!alien:void)
 152   (sb!alien:define-alien-routine gc-start-the-world sb!alien:void))
 153 #!-sb-thread
 154 (progn
 155   (defun gc-stop-the-world ())
 156   (defun gc-start-the-world ()))
 157
 158 \f
 159 ;;;; SUB-GC
 160
 161 ;;; SUB-GC does a garbage collection.  This is called from three places:
 162 ;;; (1) The C runtime will call here when it detects that we've consed
 163 ;;;     enough to exceed the gc trigger threshold.  This is done in
 164 ;;;     alloc() for gencgc or interrupt_maybe_gc() for cheneygc
 165 ;;; (2) The user may request a collection using GC, below
 166 ;;; (3) At the end of a WITHOUT-GCING section, we are called if
 167 ;;;     *NEED-TO-COLLECT-GARBAGE* is true
 168 ;;;
 169 ;;; This is different from the behaviour in 0.7 and earlier: it no
 170 ;;; longer decides whether to GC based on thresholds.  If you call
 171 ;;; SUB-GC you will definitely get a GC either now or when the
 172 ;;; WITHOUT-GCING is over
 173
 174 ;;; For GENCGC all generations < GEN will be GC'ed.
 175
 176 (defvar *already-in-gc*
 177   (sb!thread:make-mutex :name "GC lock") "ID of thread running SUB-GC")
 178
 179 (defun sub-gc (&key (gen 0))
 180   (unless (eq sb!thread:*current-thread*
 181               (sb!thread::mutex-value *already-in-gc*))
 182     ;; With gencgc, unless *GC-PENDING* every allocation in this
 183     ;; function triggers another gc, potentially exceeding maximum
 184     ;; interrupt nesting.
 185     (setq *gc-pending* t)
 186     (unless *gc-inhibit*
 187       (sb!thread:with-mutex (*already-in-gc*)
 188         (let ((old-usage (dynamic-usage))
 189               (new-usage 0))
 190           (unsafe-clear-roots)
 191           ;; We need to disable interrupts for GC, but we also want
 192           ;; to run as little as possible without them.
 193           (without-interrupts
 194             (gc-stop-the-world)
 195             (let ((start-time (get-internal-run-time)))
 196               (collect-garbage gen)
 197               (incf *gc-run-time*
 198                     (- (get-internal-run-time) start-time)))
 199             (setf *gc-pending* nil
 200                   new-usage (dynamic-usage))
 201             (gc-start-the-world))
 202           ;; Interrupts re-enabled, but still inside the mutex.
 203           ;; In a multithreaded environment the other threads will
 204           ;; see *n-b-f-o-p* change a little late, but that's OK.
 205           (let ((freed (- old-usage new-usage)))
 206             ;; GENCGC occasionally reports negative here, but the
 207             ;; current belief is that it is part of the normal order
 208             ;; of things and not a bug.
 209             (when (plusp freed)
 210               (incf *n-bytes-freed-or-purified* freed)))))
 211       ;; Outside the mutex, these may cause another GC. FIXME: it can
 212       ;; potentially exceed maximum interrupt nesting by triggering
 213       ;; GCs.
 214       (run-pending-finalizers)
 215       (dolist (hook *after-gc-hooks*)
 216         (handler-case
 217             (funcall hook)
 218           (error (c)
 219             (warn "Error calling after GC hook ~S:~%  ~S" hook c)))))))
 220
 221 ;;; This is the user-advertised garbage collection function.
 222 (defun gc (&key (gen 0) (full nil) &allow-other-keys)
 223   #!+(and sb-doc gencgc)
 224   "Initiate a garbage collection. GEN controls the number of generations
 225   to garbage collect."
 226   #!+(and sb-doc (not gencgc))
 227   "Initiate a garbage collection. GEN may be provided for compatibility with
 228   generational garbage collectors, but is ignored in this implementation."
 229   (sub-gc :gen (if full 6 gen)))
 230
 231 (defun unsafe-clear-roots ()
 232   ;; KLUDGE: Do things in an attempt to get rid of extra roots. Unsafe
 233   ;; as having these cons more then we have space left leads to huge
 234   ;; badness.
 235   (scrub-control-stack)
 236   ;; FIXME: CTYPE-OF-CACHE-CLEAR isn't thread-safe.
 237   #!-sb-thread
 238   (ctype-of-cache-clear))
 239
 240 \f
 241 ;;;; auxiliary functions
 242
 243 (defun bytes-consed-between-gcs ()
 244   #!+sb-doc
 245   "Return the amount of memory that will be allocated before the next garbage
 246    collection is initiated. This can be set with SETF."
 247   (sb!alien:extern-alien "bytes_consed_between_gcs"
 248                          (sb!alien:unsigned 32)))
 249
 250 (defun (setf bytes-consed-between-gcs) (val)
 251   (declare (type index val))
 252   (setf (sb!alien:extern-alien "bytes_consed_between_gcs"
 253                                (sb!alien:unsigned 32))
 254         val))
 255
 256 (declaim (inline maybe-handle-pending-gc))
 257 (defun maybe-handle-pending-gc ()
 258   (when (and (not *gc-inhibit*)
 259              (or #!+sb-thread *stop-for-gc-pending*
 260                  *gc-pending*))
 261     (sb!unix::receive-pending-interrupt)))
 262
 263 ;;; These work both regardless of whether we're inside WITHOUT-GCING
 264 ;;; or not.
 265 (defun gc-on ()
 266   #!+sb-doc
 267   "Enable the garbage collector."
 268   (setq *gc-inhibit* nil)
 269   (maybe-handle-pending-gc)
 270   nil)
 271
 272 (defun gc-off ()
 273   #!+sb-doc
 274   "Disable the garbage collector."
 275   (setq *gc-inhibit* t)
 276   nil)