src/code/gc.lisp

   1 ;;;; garbage collection and allocation-related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13 \f
  14 ;;;; DYNAMIC-USAGE and friends
  15
  16 (declaim (special sb!vm:*read-only-space-free-pointer*
  17                   sb!vm:*static-space-free-pointer*))
  18
  19 (eval-when (:compile-toplevel :execute)
  20   (sb!xc:defmacro def-c-var-frob (lisp-fun c-var-name)
  21     `(progn
  22        #!-sb-fluid (declaim (inline ,lisp-fun))
  23        (defun ,lisp-fun ()
  24          (sb!alien:extern-alien ,c-var-name (sb!alien:unsigned 32))))))
  25
  26 #!-gencgc
  27 (progn
  28   ;; This is called once per PROFILEd function call, so it's worth a
  29   ;; little possible space cost to reduce its time cost.
  30   #!-sb-fluid
  31   (declaim (inline current-dynamic-space-start))
  32   (def-c-var-frob current-dynamic-space-start "current_dynamic_space"))
  33
  34 #!-sb-fluid
  35 (declaim (inline dynamic-usage)) ; to reduce PROFILEd call overhead
  36 #!+gencgc
  37 (def-c-var-frob dynamic-usage "bytes_allocated")
  38 #!-gencgc
  39 (defun dynamic-usage ()
  40   (the (unsigned-byte 32)
  41        (- (sb!sys:sap-int (sb!c::dynamic-space-free-pointer))
  42           (current-dynamic-space-start))))
  43
  44 (defun static-space-usage ()
  45   (- (* sb!vm:*static-space-free-pointer* sb!vm:n-word-bytes)
  46      sb!vm:static-space-start))
  47
  48 (defun read-only-space-usage ()
  49   (- (* sb!vm::*read-only-space-free-pointer* sb!vm:n-word-bytes)
  50      sb!vm:read-only-space-start))
  51
  52 (defun control-stack-usage ()
  53   #!-stack-grows-downward-not-upward
  54   (- (sb!sys:sap-int (sb!c::control-stack-pointer-sap))
  55      (sb!vm:fixnumize sb!vm:*control-stack-start*))
  56   #!+stack-grows-downward-not-upward
  57   (- (sb!vm:fixnumize sb!vm:*control-stack-end*)
  58      (sb!sys:sap-int (sb!c::control-stack-pointer-sap))))
  59
  60 (defun binding-stack-usage ()
  61   (- (sb!sys:sap-int (sb!c::binding-stack-pointer-sap))
  62      (sb!vm:fixnumize sb!vm:*binding-stack-start*)))
  63 \f
  64 ;;;; ROOM
  65
  66 (defun room-minimal-info ()
  67   (format t "Dynamic space usage is:   ~10:D bytes.~%" (dynamic-usage))
  68   (format t "Read-only space usage is: ~10:D bytes.~%" (read-only-space-usage))
  69   (format t "Static space usage is:    ~10:D bytes.~%" (static-space-usage))
  70   (format t "Control stack usage is:   ~10:D bytes.~%" (control-stack-usage))
  71   (format t "Binding stack usage is:   ~10:D bytes.~%" (binding-stack-usage))
  72   #!+sb-thread
  73   (format t
  74           "Control and binding stack usage is for the current thread only.~%")
  75   (format t "Garbage collection is currently ~:[enabled~;DISABLED~].~%"
  76           (> *gc-inhibit* 0)))
  77
  78 (defun room-intermediate-info ()
  79   (room-minimal-info)
  80   (sb!vm:memory-usage :count-spaces '(:dynamic)
  81                       :print-spaces t
  82                       :cutoff 0.05f0
  83                       :print-summary nil))
  84
  85 (defun room-maximal-info ()
  86   (room-minimal-info)
  87   (sb!vm:memory-usage :count-spaces '(:static :dynamic))
  88   (sb!vm:instance-usage :dynamic :top-n 10)
  89   (sb!vm:instance-usage :static :top-n 10))
  90
  91 (defun room (&optional (verbosity :default))
  92   #!+sb-doc
  93   "Print to *STANDARD-OUTPUT* information about the state of internal
  94   storage and its management. The optional argument controls the
  95   verbosity of output. If it is T, ROOM prints out a maximal amount of
  96   information. If it is NIL, ROOM prints out a minimal amount of
  97   information. If it is :DEFAULT or it is not supplied, ROOM prints out
  98   an intermediate amount of information."
  99   (fresh-line)
 100   (ecase verbosity
 101     ((t)
 102      (room-maximal-info))
 103     ((nil)
 104      (room-minimal-info))
 105     (:default
 106      (room-intermediate-info)))
 107   (values))
 108 \f
 109 ;;;; GET-BYTES-CONSED
 110
 111 ;;; the total number of bytes freed so far (including any freeing
 112 ;;; which goes on in PURIFY)
 113 ;;;
 114 ;;; (We save this so that we can calculate the total number of bytes
 115 ;;; ever allocated by adding this to the number of bytes currently
 116 ;;; allocated and never freed.)
 117 (declaim (type unsigned-byte *n-bytes-freed-or-purified*))
 118 (defvar *n-bytes-freed-or-purified* 0)
 119 (push (lambda ()
 120         (setf *n-bytes-freed-or-purified* 0))
 121       ;; KLUDGE: It's probably not quite safely right either to do
 122       ;; this in *BEFORE-SAVE-INITIALIZATIONS* (since consing, or even
 123       ;; worse, something which depended on (GET-BYTES-CONSED), might
 124       ;; happen after that) or in *AFTER-SAVE-INITIALIZATIONS*. But
 125       ;; it's probably not a big problem, and there seems to be no
 126       ;; other obvious time to do it. -- WHN 2001-07-30
 127       *after-save-initializations*)
 128
 129 (declaim (ftype (function () unsigned-byte) get-bytes-consed))
 130 (defun get-bytes-consed ()
 131   #!+sb-doc
 132   "Return the number of bytes consed since the program began. Typically
 133 this result will be a consed bignum, so if you have an application (e.g.
 134 profiling) which can't tolerate the overhead of consing bignums, you'll
 135 probably want either to hack in at a lower level (as the code in the
 136 SB-PROFILE package does), or to design a more microefficient interface
 137 and submit it as a patch."
 138   (+ (dynamic-usage)
 139      *n-bytes-freed-or-purified*))
 140 \f
 141 ;;;; variables and constants
 142
 143 ;;; the minimum amount of dynamic space which must be consed before a
 144 ;;; GC will be triggered
 145 ;;;
 146 ;;; Unlike CMU CL, we don't export this variable. (There's no need to,
 147 ;;; since our BYTES-CONSED-BETWEEN-GCS function is SETFable.)
 148 (defvar *bytes-consed-between-gcs*
 149   #!+gencgc (* 4 (expt 10 6))
 150   ;; Stop-and-copy GC is really really slow when used too often. CSR
 151   ;; reported that even on his old 64 Mb SPARC, 20 Mb is much faster
 152   ;; than 4 Mb when rebuilding SBCL ca. 0.7.1. For modern machines
 153   ;; with >> 128 Mb memory, the optimum could be significantly more
 154   ;; than this, but at least 20 Mb should be better than 4 Mb.
 155   #!-gencgc (* 20 (expt 10 6)))
 156 (declaim (type index *bytes-consed-between-gcs*))
 157
 158 ;;;; GC hooks
 159
 160 (defvar *before-gc-hooks* nil ; actually initialized in cold init
 161   #!+sb-doc
 162   "A list of functions that are called before garbage collection occurs.
 163   The functions should take no arguments.")
 164
 165 (defvar *after-gc-hooks* nil ; actually initialized in cold init
 166   #!+sb-doc
 167   "A list of functions that are called after garbage collection occurs.
 168   The functions should take no arguments.")
 169
 170 (defvar *gc-notify-stream* nil ; (actually initialized in cold init)
 171   #!+sb-doc
 172   "When non-NIL, this must be a STREAM; and the functions bound to
 173   *GC-NOTIFY-BEFORE* and *GC-NOTIFY-AFTER* are called with the
 174   STREAM value before and after a garbage collection occurs
 175   respectively.")
 176
 177 (defvar *gc-run-time* 0
 178   #!+sb-doc
 179   "the total CPU time spent doing garbage collection (as reported by
 180    GET-INTERNAL-RUN-TIME)")
 181 (declaim (type index *gc-run-time*))
 182
 183 ;;;; The following specials are used to control when garbage
 184 ;;;; collection occurs.
 185
 186 ;;; When the dynamic usage increases beyond this amount, the system
 187 ;;; notes that a garbage collection needs to occur by setting
 188 ;;; *NEED-TO-COLLECT-GARBAGE* to T. It starts out as NIL meaning
 189 ;;; nobody has figured out what it should be yet.
 190 ;;;
 191 ;;; FIXME: *GC-TRIGGER* seems to be denominated in bytes, not words.
 192 ;;; And limiting it to INDEX is fairly reasonable in order to avoid
 193 ;;; bignum arithmetic on every allocation, and to minimize the need
 194 ;;; for thought about weird gotchas of the GC-control mechanism itself
 195 ;;; consing as it operates. But as of sbcl-0.7.5, 512Mbytes of memory
 196 ;;; costs $54.95 at Fry's in Dallas but cheap consumer 64-bit machines
 197 ;;; are still over the horizon, so gratuitously limiting our heap size
 198 ;;; to FIXNUM bytes seems fairly stupid. It'd be reasonable to
 199 ;;; (1) allow arbitrary UNSIGNED-BYTE values of *GC-TRIGGER*, or
 200 ;;; (2) redenominate this variable in words instead of bytes, postponing
 201 ;;;     the problem to heaps which exceed 50% of the machine's address
 202 ;;;     space, or even
 203 ;;; (3) redemoninate this variable in CONS-sized two-word units,
 204 ;;;     allowing it to cover the entire memory space at the price of
 205 ;;;     possible loss of clarity.
 206 ;;; (And whatever is done, it'd also be good to rename the variable so
 207 ;;; that it's clear what unit it's denominated in.)
 208 (declaim (type (or index null) *gc-trigger*))
 209 (defvar *gc-trigger* nil)
 210
 211 ;;; When >0, inhibits garbage collection.
 212 (defvar *gc-inhibit*) ; initialized in cold init
 213
 214 ;;; When T, indicates that a GC should have happened but did not due to
 215 ;;; *GC-INHIBIT*.
 216 (defvar *need-to-collect-garbage* nil) ; initialized in cold init
 217 \f
 218 ;;;; internal GC
 219
 220 (sb!alien:define-alien-routine collect-garbage sb!alien:int
 221   (#!+gencgc last-gen #!-gencgc ignore sb!alien:int))
 222
 223 #!+sb-thread
 224 (def-c-var-frob gc-thread-pid "gc_thread_pid")
 225
 226
 227 \f
 228 ;;;; SUB-GC
 229
 230 ;;; This is used to carefully invoke hooks.
 231 (eval-when (:compile-toplevel :execute)
 232   (sb!xc:defmacro carefully-funcall (function &rest args)
 233     `(handler-case (funcall ,function ,@args)
 234        (error (cond)
 235               (warn "(FUNCALL ~S~{ ~S~}) lost:~%~A" ',function ',args cond)
 236               nil))))
 237
 238 ;;; SUB-GC does a garbage collection.  This is called from three places:
 239 ;;; (1) The C runtime will call here when it detects that we've consed
 240 ;;;     enough to exceed the gc trigger threshold
 241 ;;; (2) The user may request a collection using GC, below
 242 ;;; (3) At the end of a WITHOUT-GCING section, we are called if
 243 ;;;     *NEED-TO-COLLECT-GARBAGE* is true
 244 ;;;
 245 ;;; This is different from the behaviour in 0.7 and earlier: it no
 246 ;;; longer decides whether to GC based on thresholds.  If you call
 247 ;;; SUB-GC you will definitely get a GC either now or when the
 248 ;;; WITHOUT-GCING is over
 249
 250 ;;; For GENCGC all generations < GEN will be GC'ed.
 251
 252 #!+sb-thread
 253 (defun sub-gc (&key (gen 0))
 254   (setf *need-to-collect-garbage* t)
 255   (when (zerop *gc-inhibit*)
 256     (setf (sb!alien:extern-alien "maybe_gc_pending" (sb!alien:unsigned 32))
 257           (1+ gen))
 258     (if (zerop (sb!alien:extern-alien "stop_the_world" (sb!alien:unsigned 32)))
 259         (sb!unix:unix-kill (gc-thread-pid) :SIGALRM))
 260     (loop
 261      (when (zerop
 262             (sb!alien:extern-alien "maybe_gc_pending" (sb!alien:unsigned 32)))
 263        (return nil)))
 264     (setf *need-to-collect-garbage* nil)
 265     (scrub-control-stack))
 266   (values))
 267
 268 #!-sb-thread
 269 (defvar *already-in-gc* nil "System is running SUB-GC")
 270 #!-sb-thread
 271 (defun sub-gc (&key (gen 0))
 272   (when *already-in-gc* (return-from sub-gc nil))
 273   (setf *need-to-collect-garbage* t)
 274   (when (zerop *gc-inhibit*)
 275     (let ((*already-in-gc* t))
 276       (without-interrupts (collect-garbage gen))
 277       (setf *need-to-collect-garbage* nil))
 278     (scrub-control-stack))
 279   (values))
 280
 281
 282
 283 ;;; This is the user-advertised garbage collection function.
 284 (defun gc (&key (gen 0) (full nil) &allow-other-keys)
 285   #!+(and sb-doc gencgc)
 286   "Initiate a garbage collection. GEN controls the number of generations
 287   to garbage collect."
 288   #!+(and sb-doc (not gencgc))
 289   "Initiate a garbage collection. GEN may be provided for compatibility with
 290   generational garbage collectors, but is ignored in this implementation."
 291   (sub-gc  :gen (if full 6 gen)))
 292
 293 \f
 294 ;;;; auxiliary functions
 295
 296 (defun bytes-consed-between-gcs ()
 297   #!+sb-doc
 298   "Return the amount of memory that will be allocated before the next garbage
 299    collection is initiated. This can be set with SETF."
 300   (sb!alien:extern-alien "bytes_consed_between_gcs"
 301                          (sb!alien:unsigned 32)))
 302
 303 (defun (setf bytes-consed-between-gcs) (val)
 304   (declare (type index val))
 305   (setf (sb!alien:extern-alien "bytes_consed_between_gcs"
 306                                (sb!alien:unsigned 32))
 307         val))
 308
 309 (defun gc-on ()
 310   #!+sb-doc
 311   "Enable the garbage collector."
 312   (setq *gc-inhibit* 0)
 313   (when *need-to-collect-garbage*
 314     (sub-gc))
 315   nil)
 316
 317 (defun gc-off ()
 318   #!+sb-doc
 319   "Disable the garbage collector."
 320   (setq *gc-inhibit* 1)
 321   nil)
 322