src/code/host-alieneval.lisp

   1 ;;;; the part of the Alien implementation which is needed at
   2 ;;;; cross-compilation time
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "host-alieneval.lisp 15")
  16 \f
  17 ;;;; utility functions
  18
  19 (defun align-offset (offset alignment)
  20   (let ((extra (rem offset alignment)))
  21     (if (zerop extra) offset (+ offset (- alignment extra)))))
  22
  23 (defun guess-alignment (bits)
  24   (cond ((null bits) nil)
  25         #!-(or (and x86 (not win32)) (and ppc darwin)) ((> bits 32) 64)
  26         ((> bits 16) 32)
  27         ((> bits 8) 16)
  28         ((> bits 1) 8)
  29         (t 1)))
  30 \f
  31 ;;;; ALIEN-TYPE-INFO stuff
  32
  33 (eval-when (#-sb-xc :compile-toplevel :execute :load-toplevel)
  34
  35 (defstruct (alien-type-class (:copier nil))
  36   (name nil :type symbol)
  37   (defstruct-name nil :type symbol)
  38   (include nil :type (or null alien-type-class))
  39   (unparse nil :type (or null function))
  40   (type= nil :type (or null function))
  41   (lisp-rep nil :type (or null function))
  42   (alien-rep nil :type (or null function))
  43   (extract-gen nil :type (or null function))
  44   (deposit-gen nil :type (or null function))
  45   (naturalize-gen nil :type (or null function))
  46   (deport-gen nil :type (or null function))
  47   (deport-alloc-gen nil :type (or null function))
  48   (deport-pin-p nil :type (or null function))
  49   ;; Cast?
  50   (arg-tn nil :type (or null function))
  51   (result-tn nil :type (or null function))
  52   (subtypep nil :type (or null function)))
  53 (def!method print-object ((type-class alien-type-class) stream)
  54   (print-unreadable-object (type-class stream :type t)
  55     (prin1 (alien-type-class-name type-class) stream)))
  56
  57 (defun alien-type-class-or-lose (name)
  58   (or (gethash name *alien-type-classes*)
  59       (error "no alien type class ~S" name)))
  60
  61 (defun create-alien-type-class-if-necessary (name defstruct-name include)
  62   (let ((old (gethash name *alien-type-classes*))
  63         (include (and include (alien-type-class-or-lose include))))
  64     (if old
  65         (setf (alien-type-class-include old) include)
  66         (setf (gethash name *alien-type-classes*)
  67               (make-alien-type-class :name name
  68                                      :defstruct-name defstruct-name
  69                                      :include include)))))
  70
  71 (defparameter *method-slot-alist*
  72   '((:unparse . alien-type-class-unparse)
  73     (:type= . alien-type-class-type=)
  74     (:subtypep . alien-type-class-subtypep)
  75     (:lisp-rep . alien-type-class-lisp-rep)
  76     (:alien-rep . alien-type-class-alien-rep)
  77     (:extract-gen . alien-type-class-extract-gen)
  78     (:deposit-gen . alien-type-class-deposit-gen)
  79     (:naturalize-gen . alien-type-class-naturalize-gen)
  80     (:deport-gen . alien-type-class-deport-gen)
  81     (:deport-alloc-gen . alien-type-class-deport-alloc-gen)
  82     (:deport-pin-p . alien-type-class-deport-pin-p)
  83     ;; cast?
  84     (:arg-tn . alien-type-class-arg-tn)
  85     (:result-tn . alien-type-class-result-tn)))
  86
  87 (defun method-slot (method)
  88   (cdr (or (assoc method *method-slot-alist*)
  89            (error "no method ~S" method))))
  90
  91 ) ; EVAL-WHEN
  92
  93 ;;; We define a keyword "BOA" constructor so that we can reference the
  94 ;;; slot names in init forms.
  95 (def!macro define-alien-type-class ((name &key include include-args)
  96                                     &rest slots)
  97   (let ((defstruct-name (symbolicate "ALIEN-" name "-TYPE")))
  98     (multiple-value-bind (include include-defstruct overrides)
  99         (etypecase include
 100           (null
 101            (values nil 'alien-type nil))
 102           (symbol
 103            (values
 104             include
 105             (alien-type-class-defstruct-name
 106              (alien-type-class-or-lose include))
 107             nil))
 108           (list
 109            (values
 110             (car include)
 111             (alien-type-class-defstruct-name
 112              (alien-type-class-or-lose (car include)))
 113             (cdr include))))
 114       `(progn
 115          (eval-when (:compile-toplevel :load-toplevel :execute)
 116            (create-alien-type-class-if-necessary ',name ',defstruct-name
 117                                                  ',(or include 'root)))
 118          (def!struct (,defstruct-name
 119                         (:include ,include-defstruct
 120                                   (class ',name)
 121                                   ,@overrides)
 122                         (:constructor
 123                          ,(symbolicate "MAKE-" defstruct-name)
 124                          (&key class bits alignment
 125                                ,@(mapcar (lambda (x)
 126                                            (if (atom x) x (car x)))
 127                                          slots)
 128                                ,@include-args
 129                                ;; KLUDGE
 130                                &aux (alignment (or alignment (guess-alignment bits))))))
 131            ,@slots)))))
 132
 133 (def!macro define-alien-type-method ((class method) lambda-list &rest body)
 134   (let ((defun-name (symbolicate class "-" method "-METHOD")))
 135     `(progn
 136        (defun ,defun-name ,lambda-list
 137          ,@body)
 138        (setf (,(method-slot method) (alien-type-class-or-lose ',class))
 139              #',defun-name))))
 140
 141 (def!macro invoke-alien-type-method (method type &rest args)
 142   (let ((slot (method-slot method)))
 143     (once-only ((type type))
 144       `(funcall (do ((class (alien-type-class-or-lose (alien-type-class ,type))
 145                             (alien-type-class-include class)))
 146                     ((null class)
 147                      (error "method ~S not defined for ~S"
 148                             ',method (alien-type-class ,type)))
 149                   (let ((fn (,slot class)))
 150                     (when fn
 151                       (return fn))))
 152                 ,type ,@args))))
 153 \f
 154 ;;;; type parsing and unparsing
 155
 156 ;;; CMU CL used COMPILER-LET to bind *AUXILIARY-TYPE-DEFINITIONS*, and
 157 ;;; COMPILER-LET is no longer supported by ANSI or SBCL. Instead, we
 158 ;;; follow the suggestion in CLTL2 of using SYMBOL-MACROLET to achieve
 159 ;;; a similar effect.
 160 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 161   (defun auxiliary-type-definitions (env)
 162     (multiple-value-bind (result expanded-p)
 163         (%macroexpand '&auxiliary-type-definitions& env)
 164       (if expanded-p
 165           result
 166           ;; This is like having the global symbol-macro definition be
 167           ;; NIL, but global symbol-macros make me vaguely queasy, so
 168           ;; I do it this way instead.
 169           nil))))
 170
 171 ;;; Process stuff in a new scope.
 172 (def!macro with-auxiliary-alien-types (env &body body)
 173   ``(symbol-macrolet ((&auxiliary-type-definitions&
 174                        ,(append *new-auxiliary-types*
 175                                 (auxiliary-type-definitions ,env))))
 176       ,(let ((*new-auxiliary-types* nil))
 177          ,@body)))
 178
 179 ;;; Parse TYPE as an alien type specifier and return the resultant
 180 ;;; ALIEN-TYPE structure.
 181 (defun parse-alien-type (type env)
 182   (declare (type (or sb!kernel:lexenv null) env))
 183   (if (consp type)
 184       (let ((translator (info :alien-type :translator (car type))))
 185         (unless translator
 186           (error "unknown alien type: ~S" type))
 187         (funcall translator type env))
 188       (ecase (info :alien-type :kind type)
 189         (:primitive
 190          (let ((translator (info :alien-type :translator type)))
 191            (unless translator
 192              (error "no translator for primitive alien type ~S" type))
 193            (funcall translator (list type) env)))
 194         (:defined
 195          (or (info :alien-type :definition type)
 196              (error "no definition for alien type ~S" type)))
 197         (:unknown
 198          (error "unknown alien type: ~S" type)))))
 199
 200 (defun auxiliary-alien-type (kind name env)
 201   (declare (type (or sb!kernel:lexenv null) env))
 202   (flet ((aux-defn-matches (x)
 203            (and (eq (first x) kind) (eq (second x) name))))
 204     (let ((in-auxiliaries
 205            (or (find-if #'aux-defn-matches *new-auxiliary-types*)
 206                (find-if #'aux-defn-matches (auxiliary-type-definitions env)))))
 207       (if in-auxiliaries
 208           (values (third in-auxiliaries) t)
 209           (ecase kind
 210             (:struct
 211              (info :alien-type :struct name))
 212             (:union
 213              (info :alien-type :union name))
 214             (:enum
 215              (info :alien-type :enum name)))))))
 216
 217 (defun (setf auxiliary-alien-type) (new-value kind name env)
 218   (declare (type (or sb!kernel:lexenv null) env))
 219   (flet ((aux-defn-matches (x)
 220            (and (eq (first x) kind) (eq (second x) name))))
 221     (when (find-if #'aux-defn-matches *new-auxiliary-types*)
 222       (error "attempt to multiply define ~A ~S" kind name))
 223     (when (find-if #'aux-defn-matches (auxiliary-type-definitions env))
 224       (error "attempt to shadow definition of ~A ~S" kind name)))
 225   (push (list kind name new-value) *new-auxiliary-types*)
 226   new-value)
 227
 228 (defun verify-local-auxiliaries-okay ()
 229   (dolist (info *new-auxiliary-types*)
 230     (destructuring-bind (kind name defn) info
 231       (declare (ignore defn))
 232       (when (ecase kind
 233               (:struct
 234                (info :alien-type :struct name))
 235               (:union
 236                (info :alien-type :union name))
 237               (:enum
 238                (info :alien-type :enum name)))
 239         (error "attempt to shadow definition of ~A ~S" kind name)))))
 240
 241 (defun unparse-alien-type (type)
 242   #!+sb-doc
 243   "Convert the alien-type structure TYPE back into a list specification of
 244    the type."
 245   (declare (type alien-type type))
 246   (let ((*record-types-already-unparsed* nil))
 247     (%unparse-alien-type type)))
 248
 249 ;;; Does all the work of UNPARSE-ALIEN-TYPE. It's separate because we
 250 ;;; need to recurse inside the binding of
 251 ;;; *RECORD-TYPES-ALREADY-UNPARSED*.
 252 (defun %unparse-alien-type (type)
 253   (invoke-alien-type-method :unparse type))
 254 \f
 255 ;;;; alien type defining stuff
 256
 257 (def!macro define-alien-type-translator (name lambda-list &body body)
 258   (with-unique-names (whole env)
 259     (let ((defun-name (symbolicate "ALIEN-" name "-TYPE-TRANSLATOR")))
 260       (multiple-value-bind (body decls docs)
 261           (sb!kernel:parse-defmacro lambda-list whole body name
 262                                     'define-alien-type-translator
 263                                     :environment env)
 264         `(eval-when (:compile-toplevel :load-toplevel :execute)
 265            (defun ,defun-name (,whole ,env)
 266              (declare (ignorable ,env))
 267              ,@decls
 268              (block ,name
 269                ,body))
 270            (%define-alien-type-translator ',name #',defun-name ,docs))))))
 271
 272 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 273   (defun %define-alien-type-translator (name translator docs)
 274     (declare (ignore docs))
 275     (setf (info :alien-type :kind name) :primitive)
 276     (setf (info :alien-type :translator name) translator)
 277     (clear-info :alien-type :definition name)
 278     #+nil
 279     (setf (fdocumentation name 'alien-type) docs)
 280     name))
 281
 282 (def!macro define-alien-type (name type &environment env)
 283   #!+sb-doc
 284   "Define the alien type NAME to be equivalent to TYPE. Name may be NIL for
 285    STRUCT and UNION types, in which case the name is taken from the type
 286    specifier."
 287   (with-auxiliary-alien-types env
 288     (let ((alien-type (parse-alien-type type env)))
 289       `(eval-when (:compile-toplevel :load-toplevel :execute)
 290          ,@(when *new-auxiliary-types*
 291              `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
 292          ,@(when name
 293              `((%define-alien-type ',name ',alien-type)))))))
 294
 295 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 296   (defun %def-auxiliary-alien-types (types)
 297     (dolist (info types)
 298       ;; Clear up the type we're about to define from the toplevel
 299       ;; *new-auxiliary-types* (local scopes take care of themselves).
 300       ;; Unless this is done we never actually get back the full type
 301       ;; from INFO, since the *new-auxiliary-types* have precendence.
 302       (setf *new-auxiliary-types*
 303             (remove info *new-auxiliary-types*
 304                     :test (lambda (a b)
 305                             (and (eq (first a) (first b))
 306                                  (eq (second a) (second b))))))
 307       (destructuring-bind (kind name defn) info
 308         (macrolet ((frob (kind)
 309                          `(let ((old (info :alien-type ,kind name)))
 310                             (unless (or (null old) (alien-type-= old defn))
 311                               (warn
 312                                "redefining ~A ~S to be:~%  ~S,~%was:~%  ~S"
 313                                kind name defn old))
 314                             (setf (info :alien-type ,kind name) defn))))
 315           (ecase kind
 316             (:struct (frob :struct))
 317             (:union (frob :union))
 318             (:enum (frob :enum)))))))
 319   (defun %define-alien-type (name new)
 320     (ecase (info :alien-type :kind name)
 321       (:primitive
 322        (error "~S is a built-in alien type." name))
 323       (:defined
 324        (let ((old (info :alien-type :definition name)))
 325          (unless (or (null old) (alien-type-= new old))
 326            (warn "redefining ~S to be:~%  ~S,~%was~%  ~S"
 327                  name
 328                  (unparse-alien-type new)
 329                  (unparse-alien-type old)))))
 330       (:unknown))
 331     (setf (info :alien-type :definition name) new)
 332     (setf (info :alien-type :kind name) :defined)
 333     name))
 334 \f
 335 ;;;; the root alien type
 336
 337 (eval-when (:compile-toplevel :load-toplevel :execute)
 338   (create-alien-type-class-if-necessary 'root 'alien-type nil))
 339
 340 (def!struct (alien-type
 341              (:make-load-form-fun sb!kernel:just-dump-it-normally)
 342              (:constructor make-alien-type (&key class bits alignment
 343                                             &aux (alignment (or alignment (guess-alignment bits))))))
 344   (class 'root :type symbol)
 345   (bits nil :type (or null unsigned-byte))
 346   (alignment nil :type (or null unsigned-byte)))
 347 (def!method print-object ((type alien-type) stream)
 348   (print-unreadable-object (type stream :type t)
 349     (prin1 (unparse-alien-type type) stream)))
 350 \f
 351 ;;;; the SAP type
 352
 353 (define-alien-type-class (system-area-pointer))
 354
 355 (define-alien-type-translator system-area-pointer ()
 356   (make-alien-system-area-pointer-type
 357    :bits #!-alpha sb!vm:n-word-bits #!+alpha 64))
 358
 359 (define-alien-type-method (system-area-pointer :unparse) (type)
 360   (declare (ignore type))
 361   'system-area-pointer)
 362
 363 (define-alien-type-method (system-area-pointer :lisp-rep) (type)
 364   (declare (ignore type))
 365   'system-area-pointer)
 366
 367 (define-alien-type-method (system-area-pointer :alien-rep) (type context)
 368   (declare (ignore type context))
 369   'system-area-pointer)
 370
 371 (define-alien-type-method (system-area-pointer :naturalize-gen) (type alien)
 372   (declare (ignore type))
 373   alien)
 374
 375 (define-alien-type-method (system-area-pointer :deport-gen) (type object)
 376   (declare (ignore type))
 377   (/noshow "doing alien type method SYSTEM-AREA-POINTER :DEPORT-GEN" object)
 378   object)
 379
 380 (define-alien-type-method (system-area-pointer :extract-gen) (type sap offset)
 381   (declare (ignore type))
 382   `(sap-ref-sap ,sap (/ ,offset sb!vm:n-byte-bits)))
 383 \f
 384 ;;;; the ALIEN-VALUE type
 385
 386 (define-alien-type-class (alien-value :include system-area-pointer))
 387
 388 (define-alien-type-method (alien-value :lisp-rep) (type)
 389   (declare (ignore type))
 390   nil)
 391
 392 (define-alien-type-method (alien-value :naturalize-gen) (type alien)
 393   `(%sap-alien ,alien ',type))
 394
 395 (define-alien-type-method (alien-value :deport-gen) (type value)
 396   (declare (ignore type))
 397   (/noshow "doing alien type method ALIEN-VALUE :DEPORT-GEN" value)
 398   `(alien-sap ,value))
 399 \f
 400 ;;; HEAP-ALIEN-INFO -- defstruct.
 401 ;;;
 402 ;;; Information describing a heap-allocated alien.
 403 (def!struct (heap-alien-info
 404              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 405   ;; The type of this alien.
 406   (type (missing-arg) :type alien-type)
 407   ;; Its name.
 408   (alien-name (missing-arg) :type simple-string)
 409   ;; Data or code?
 410   (datap (missing-arg) :type boolean))
 411 (def!method print-object ((info heap-alien-info) stream)
 412   (print-unreadable-object (info stream :type t)
 413     (funcall (formatter "~S ~S~@[ (data)~]")
 414              stream
 415              (heap-alien-info-alien-name info)
 416              (unparse-alien-type (heap-alien-info-type info))
 417              (heap-alien-info-datap info))))
 418
 419 ;;; The form to evaluate to produce the SAP pointing to where in the heap
 420 ;;; it is.
 421 (defun heap-alien-info-sap-form (info)
 422   `(foreign-symbol-sap ,(heap-alien-info-alien-name info)
 423                        ,(heap-alien-info-datap info)))
 424
 425 (defun heap-alien-info-sap (info)
 426   (foreign-symbol-sap (heap-alien-info-alien-name info)
 427                       (heap-alien-info-datap info)))
 428 \f
 429 ;;;; Interfaces to the different methods
 430
 431 (defun alien-type-= (type1 type2)
 432   #!+sb-doc
 433   "Return T iff TYPE1 and TYPE2 describe equivalent alien types."
 434   (or (eq type1 type2)
 435       (and (eq (alien-type-class type1)
 436                (alien-type-class type2))
 437            (invoke-alien-type-method :type= type1 type2))))
 438
 439 (defun alien-subtype-p (type1 type2)
 440   #!+sb-doc
 441   "Return T iff the alien type TYPE1 is a subtype of TYPE2. Currently, the
 442    only supported subtype relationships are is that any pointer type is a
 443    subtype of (* t), and any array type first dimension will match
 444    (array <eltype> nil ...). Otherwise, the two types have to be
 445    ALIEN-TYPE-=."
 446   (or (eq type1 type2)
 447       (invoke-alien-type-method :subtypep type1 type2)))
 448
 449 (defun compute-naturalize-lambda (type)
 450   `(lambda (alien ignore)
 451      (declare (ignore ignore))
 452      ,(invoke-alien-type-method :naturalize-gen type 'alien)))
 453
 454 (defun compute-deport-lambda (type)
 455   (declare (type alien-type type))
 456   (/noshow "entering COMPUTE-DEPORT-LAMBDA" type)
 457   (multiple-value-bind (form value-type)
 458       (invoke-alien-type-method :deport-gen type 'value)
 459     `(lambda (value ignore)
 460        (declare (type ,(or value-type
 461                            (compute-lisp-rep-type type)
 462                            `(alien ,type))
 463                       value)
 464                 (ignore ignore))
 465        ,form)))
 466
 467 (defun compute-deport-alloc-lambda (type)
 468   `(lambda (value ignore)
 469      (declare (ignore ignore))
 470      ,(invoke-alien-type-method :deport-alloc-gen type 'value)))
 471
 472 (defun compute-extract-lambda (type)
 473   `(lambda (sap offset ignore)
 474      (declare (type system-area-pointer sap)
 475               (type unsigned-byte offset)
 476               (ignore ignore))
 477      (naturalize ,(invoke-alien-type-method :extract-gen type 'sap 'offset)
 478                  ',type)))
 479
 480 (def!macro maybe-with-pinned-objects (variables types &body body)
 481   (declare (ignorable variables types))
 482   (let ((pin-variables
 483          ;; Only pin things on GENCGC, since on CHENEYGC it'd imply
 484          ;; disabling the GC.  Which is something we don't want to do
 485          ;; every time we're calling to C.
 486          #!+gencgc
 487          (loop for variable in variables
 488             for type in types
 489             when (invoke-alien-type-method :deport-pin-p type)
 490             collect variable)))
 491     (if pin-variables
 492         `(with-pinned-objects ,pin-variables
 493            ,@body)
 494         `(progn
 495            ,@body))))
 496
 497 (defun compute-deposit-lambda (type)
 498   (declare (type alien-type type))
 499   `(lambda (value sap offset ignore)
 500      (declare (type system-area-pointer sap)
 501               (type unsigned-byte offset)
 502               (ignore ignore))
 503      (let ((alloc-tmp (deport-alloc value ',type)))
 504        (maybe-with-pinned-objects (alloc-tmp) (,type)
 505          (let ((value (deport alloc-tmp  ',type)))
 506            ,(invoke-alien-type-method :deposit-gen type 'sap 'offset 'value)
 507            ;; Note: the reason we don't just return the pre-deported value
 508            ;; is because that would inhibit any (deport (naturalize ...))
 509            ;; optimizations that might have otherwise happen. Re-naturalizing
 510            ;; the value might cause extra consing, but is flushable, so probably
 511            ;; results in better code.
 512            (naturalize value ',type))))))
 513
 514 (defun compute-lisp-rep-type (type)
 515   (invoke-alien-type-method :lisp-rep type))
 516
 517 ;;; CONTEXT is either :NORMAL (the default) or :RESULT (alien function
 518 ;;; return values).  See the :ALIEN-REP method for INTEGER for
 519 ;;; details.
 520 (defun compute-alien-rep-type (type &optional (context :normal))
 521   (invoke-alien-type-method :alien-rep type context))
 522 \f
 523 ;;;; default methods
 524
 525 (define-alien-type-method (root :unparse) (type)
 526   `(<unknown-alien-type> ,(type-of type)))
 527
 528 (define-alien-type-method (root :type=) (type1 type2)
 529   (declare (ignore type1 type2))
 530   t)
 531
 532 (define-alien-type-method (root :subtypep) (type1 type2)
 533   (alien-type-= type1 type2))
 534
 535 (define-alien-type-method (root :lisp-rep) (type)
 536   (declare (ignore type))
 537   nil)
 538
 539 (define-alien-type-method (root :alien-rep) (type context)
 540   (declare (ignore type context))
 541   '*)
 542
 543 (define-alien-type-method (root :naturalize-gen) (type alien)
 544   (declare (ignore alien))
 545   (error "cannot represent ~S typed aliens" type))
 546
 547 (define-alien-type-method (root :deport-gen) (type object)
 548   (declare (ignore object))
 549   (error "cannot represent ~S typed aliens" type))
 550
 551 (define-alien-type-method (root :deport-alloc-gen) (type object)
 552   (declare (ignore type))
 553   object)
 554
 555 (define-alien-type-method (root :deport-pin-p) (type)
 556   (declare (ignore type))
 557   ;; Override this method to return T for classes which take a SAP to a
 558   ;; GCable lisp object when deporting.
 559   nil)
 560
 561 (define-alien-type-method (root :extract-gen) (type sap offset)
 562   (declare (ignore sap offset))
 563   (error "cannot represent ~S typed aliens" type))
 564
 565 (define-alien-type-method (root :deposit-gen) (type sap offset value)
 566   `(setf ,(invoke-alien-type-method :extract-gen type sap offset) ,value))
 567
 568 (define-alien-type-method (root :arg-tn) (type state)
 569   (declare (ignore state))
 570   (error "Aliens of type ~S cannot be passed as arguments to CALL-OUT."
 571          (unparse-alien-type type)))
 572
 573 (define-alien-type-method (root :result-tn) (type state)
 574   (declare (ignore state))
 575   (error "Aliens of type ~S cannot be returned from CALL-OUT."
 576          (unparse-alien-type type)))
 577 \f
 578 ;;;; the INTEGER type
 579
 580 (define-alien-type-class (integer)
 581   (signed t :type (member t nil)))
 582
 583 (define-alien-type-translator signed (&optional (bits sb!vm:n-word-bits))
 584   (make-alien-integer-type :bits bits))
 585
 586 (define-alien-type-translator integer (&optional (bits sb!vm:n-word-bits))
 587   (make-alien-integer-type :bits bits))
 588
 589 (define-alien-type-translator unsigned (&optional (bits sb!vm:n-word-bits))
 590   (make-alien-integer-type :bits bits :signed nil))
 591
 592 (define-alien-type-method (integer :unparse) (type)
 593   (list (if (alien-integer-type-signed type) 'signed 'unsigned)
 594         (alien-integer-type-bits type)))
 595
 596 (define-alien-type-method (integer :type=) (type1 type2)
 597   (and (eq (alien-integer-type-signed type1)
 598            (alien-integer-type-signed type2))
 599        (= (alien-integer-type-bits type1)
 600           (alien-integer-type-bits type2))))
 601
 602 (define-alien-type-method (integer :lisp-rep) (type)
 603   (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 604         (alien-integer-type-bits type)))
 605
 606 (define-alien-type-method (integer :alien-rep) (type context)
 607   ;; When returning integer values that are narrower than a machine
 608   ;; register from a function, some platforms leave the higher bits of
 609   ;; the register uninitialized.  On those platforms, we use an
 610   ;; alien-rep of the full register width when checking for purposes
 611   ;; of return values and override the naturalize method to perform
 612   ;; the sign extension (in compiler/target/c-call.lisp).
 613   (ecase context
 614     ((:normal #!-(or x86 x86-64) :result)
 615      (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 616            (alien-integer-type-bits type)))
 617     #!+(or x86 x86-64)
 618     (:result
 619      (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 620            sb!vm:n-word-bits))))
 621
 622 ;;; As per the comment in the :ALIEN-REP method above, this is defined
 623 ;;; elsewhere for x86oids.
 624 #!-(or x86 x86-64)
 625 (define-alien-type-method (integer :naturalize-gen) (type alien)
 626   (declare (ignore type))
 627   alien)
 628
 629 (define-alien-type-method (integer :deport-gen) (type value)
 630   (declare (ignore type))
 631   value)
 632
 633 (define-alien-type-method (integer :extract-gen) (type sap offset)
 634   (declare (type alien-integer-type type))
 635   (let ((ref-fun
 636          (if (alien-integer-type-signed type)
 637           (case (alien-integer-type-bits type)
 638             (8 'signed-sap-ref-8)
 639             (16 'signed-sap-ref-16)
 640             (32 'signed-sap-ref-32)
 641             (64 'signed-sap-ref-64))
 642           (case (alien-integer-type-bits type)
 643             (8 'sap-ref-8)
 644             (16 'sap-ref-16)
 645             (32 'sap-ref-32)
 646             (64 'sap-ref-64)))))
 647     (if ref-fun
 648         `(,ref-fun ,sap (/ ,offset sb!vm:n-byte-bits))
 649         (error "cannot extract ~W-bit integers"
 650                (alien-integer-type-bits type)))))
 651 \f
 652 ;;;; the BOOLEAN type
 653
 654 (define-alien-type-class (boolean :include integer :include-args (signed)))
 655
 656 ;;; FIXME: Check to make sure that we aren't attaching user-readable
 657 ;;; stuff to CL:BOOLEAN in any way which impairs ANSI compliance.
 658 (define-alien-type-translator boolean (&optional (bits sb!vm:n-word-bits))
 659   (make-alien-boolean-type :bits bits :signed nil))
 660
 661 (define-alien-type-method (boolean :unparse) (type)
 662   `(boolean ,(alien-boolean-type-bits type)))
 663
 664 (define-alien-type-method (boolean :lisp-rep) (type)
 665   (declare (ignore type))
 666   `(member t nil))
 667
 668 (define-alien-type-method (boolean :naturalize-gen) (type alien)
 669   (declare (ignore type))
 670   `(not (zerop ,alien)))
 671
 672 (define-alien-type-method (boolean :deport-gen) (type value)
 673   (declare (ignore type))
 674   `(if ,value 1 0))
 675 \f
 676 ;;;; the ENUM type
 677
 678 (define-alien-type-class (enum :include (integer (bits 32))
 679                                :include-args (signed))
 680   name          ; name of this enum (if any)
 681   from          ; alist from symbols to integers
 682   to            ; alist or vector from integers to symbols
 683   kind          ; kind of from mapping, :VECTOR or :ALIST
 684   offset)       ; offset to add to value for :VECTOR from mapping
 685
 686 (define-alien-type-translator enum (&whole
 687                                  type name
 688                                  &rest mappings
 689                                  &environment env)
 690   (cond (mappings
 691          (let ((result (parse-enum name mappings)))
 692            (when name
 693              (multiple-value-bind (old old-p)
 694                  (auxiliary-alien-type :enum name env)
 695                (when old-p
 696                  (unless (alien-type-= result old)
 697                    (cerror "Continue, clobbering the old definition"
 698                            "Incompatible alien enum type definition: ~S" name)
 699                    (setf (alien-type-from old) (alien-type-from result)
 700                          (alien-type-to old) (alien-type-to result)
 701                          (alien-type-kind old) (alien-type-kind result)
 702                          (alien-type-offset old) (alien-type-offset result)
 703                          (alien-type-signed old) (alien-type-signed result)))
 704                  (setf result old))
 705                (unless old-p
 706                  (setf (auxiliary-alien-type :enum name env) result))))
 707            result))
 708         (name
 709          (multiple-value-bind (result found)
 710              (auxiliary-alien-type :enum name env)
 711            (unless found
 712              (error "unknown enum type: ~S" name))
 713            result))
 714         (t
 715          (error "empty enum type: ~S" type))))
 716
 717 (defun parse-enum (name elements)
 718   (when (null elements)
 719     (error "An enumeration must contain at least one element."))
 720   (let ((min nil)
 721         (max nil)
 722         (from-alist ())
 723         (prev -1))
 724     (declare (list from-alist))
 725     (dolist (el elements)
 726       (multiple-value-bind (sym val)
 727           (if (listp el)
 728               (values (first el) (second el))
 729               (values el (1+ prev)))
 730         (setf prev val)
 731         (unless (symbolp sym)
 732           (error "The enumeration element ~S is not a symbol." sym))
 733         (unless (integerp val)
 734           (error "The element value ~S is not an integer." val))
 735         (unless (and max (> max val)) (setq max val))
 736         (unless (and min (< min val)) (setq min val))
 737         (when (rassoc val from-alist)
 738           (style-warn "The element value ~S is used more than once." val))
 739         (when (assoc sym from-alist :test #'eq)
 740           (error "The enumeration element ~S is used more than once." sym))
 741         (push (cons sym val) from-alist)))
 742     (let* ((signed (minusp min))
 743            (min-bits (if signed
 744                          (1+ (max (integer-length min)
 745                                   (integer-length max)))
 746                          (integer-length max))))
 747       (when (> min-bits 32)
 748         (error "can't represent enums needing more than 32 bits"))
 749       (setf from-alist (sort from-alist #'< :key #'cdr))
 750       (cond
 751        ;; If range is at least 20% dense, use vector mapping. Crossover
 752        ;; point solely on basis of space would be 25%. Vector mapping
 753        ;; is always faster, so give the benefit of the doubt.
 754        ((< 0.2 (/ (float (length from-alist)) (float (1+ (- max min)))))
 755         ;; If offset is small and ignorable, ignore it to save time.
 756         (when (< 0 min 10) (setq min 0))
 757         (let ((to (make-array (1+ (- max min)))))
 758           (dolist (el from-alist)
 759             (setf (svref to (- (cdr el) min)) (car el)))
 760           (make-alien-enum-type :name name :signed signed
 761                                 :from from-alist :to to :kind
 762                                 :vector :offset (- min))))
 763        (t
 764         (make-alien-enum-type :name name :signed signed
 765                               :from from-alist
 766                               :to (mapcar (lambda (x) (cons (cdr x) (car x)))
 767                                           from-alist)
 768                               :kind :alist))))))
 769
 770 (define-alien-type-method (enum :unparse) (type)
 771   `(enum ,(alien-enum-type-name type)
 772          ,@(let ((prev -1))
 773              (mapcar (lambda (mapping)
 774                        (let ((sym (car mapping))
 775                              (value (cdr mapping)))
 776                          (prog1
 777                              (if (= (1+ prev) value)
 778                                  sym
 779                                  `(,sym ,value))
 780                            (setf prev value))))
 781                      (alien-enum-type-from type)))))
 782
 783 (define-alien-type-method (enum :type=) (type1 type2)
 784   (and (eq (alien-enum-type-name type1)
 785            (alien-enum-type-name type2))
 786        (equal (alien-enum-type-from type1)
 787               (alien-enum-type-from type2))))
 788
 789 (define-alien-type-method (enum :lisp-rep) (type)
 790   `(member ,@(mapcar #'car (alien-enum-type-from type))))
 791
 792 (define-alien-type-method (enum :naturalize-gen) (type alien)
 793   (ecase (alien-enum-type-kind type)
 794     (:vector
 795      `(svref ',(alien-enum-type-to type)
 796              (+ ,alien ,(alien-enum-type-offset type))))
 797     (:alist
 798      `(ecase ,alien
 799         ,@(mapcar (lambda (mapping)
 800                     `(,(car mapping) ',(cdr mapping)))
 801                   (alien-enum-type-to type))))))
 802
 803 (define-alien-type-method (enum :deport-gen) (type value)
 804   `(ecase ,value
 805      ,@(mapcar (lambda (mapping)
 806                  `(,(car mapping) ,(cdr mapping)))
 807                (alien-enum-type-from type))))
 808 \f
 809 ;;;; the FLOAT types
 810
 811 (define-alien-type-class (float)
 812   (type (missing-arg) :type symbol))
 813
 814 (define-alien-type-method (float :unparse) (type)
 815   (alien-float-type-type type))
 816
 817 (define-alien-type-method (float :lisp-rep) (type)
 818   (alien-float-type-type type))
 819
 820 (define-alien-type-method (float :alien-rep) (type context)
 821   (declare (ignore context))
 822   (alien-float-type-type type))
 823
 824 (define-alien-type-method (float :naturalize-gen) (type alien)
 825   (declare (ignore type))
 826   alien)
 827
 828 (define-alien-type-method (float :deport-gen) (type value)
 829   (declare (ignore type))
 830   value)
 831
 832 (define-alien-type-class (single-float :include (float (bits 32))
 833                                        :include-args (type)))
 834
 835 (define-alien-type-translator single-float ()
 836   (make-alien-single-float-type :type 'single-float))
 837
 838 (define-alien-type-method (single-float :extract-gen) (type sap offset)
 839   (declare (ignore type))
 840   `(sap-ref-single ,sap (/ ,offset sb!vm:n-byte-bits)))
 841
 842 (define-alien-type-class (double-float :include (float (bits 64))
 843                                        :include-args (type)))
 844
 845 (define-alien-type-translator double-float ()
 846   (make-alien-double-float-type :type 'double-float))
 847
 848 (define-alien-type-method (double-float :extract-gen) (type sap offset)
 849   (declare (ignore type))
 850   `(sap-ref-double ,sap (/ ,offset sb!vm:n-byte-bits)))
 851
 852 \f
 853 ;;;; the POINTER type
 854
 855 (define-alien-type-class (pointer :include (alien-value (bits
 856                                                          #!-alpha
 857                                                          sb!vm:n-word-bits
 858                                                          #!+alpha 64)))
 859   (to nil :type (or alien-type null)))
 860
 861 (define-alien-type-translator * (to &environment env)
 862   (make-alien-pointer-type :to (if (eq to t) nil (parse-alien-type to env))))
 863
 864 (define-alien-type-method (pointer :unparse) (type)
 865   (let ((to (alien-pointer-type-to type)))
 866     `(* ,(if to
 867              (%unparse-alien-type to)
 868              t))))
 869
 870 (define-alien-type-method (pointer :type=) (type1 type2)
 871   (let ((to1 (alien-pointer-type-to type1))
 872         (to2 (alien-pointer-type-to type2)))
 873     (if to1
 874         (if to2
 875             (alien-type-= to1 to2)
 876             nil)
 877         (null to2))))
 878
 879 (define-alien-type-method (pointer :subtypep) (type1 type2)
 880   (and (alien-pointer-type-p type2)
 881        (let ((to1 (alien-pointer-type-to type1))
 882              (to2 (alien-pointer-type-to type2)))
 883          (if to1
 884              (if to2
 885                  (alien-subtype-p to1 to2)
 886                  t)
 887              (null to2)))))
 888
 889 (define-alien-type-method (pointer :deport-gen) (type value)
 890   (/noshow "doing alien type method POINTER :DEPORT-GEN" type value)
 891   (values
 892    ;; FIXME: old version, highlighted a bug in xc optimization
 893    `(etypecase ,value
 894       (null
 895        (int-sap 0))
 896       (system-area-pointer
 897        ,value)
 898       ((alien ,type)
 899        (alien-sap ,value)))
 900    ;; new version, works around bug in xc optimization
 901    #+nil
 902    `(etypecase ,value
 903       (system-area-pointer
 904        ,value)
 905       ((alien ,type)
 906        (alien-sap ,value))
 907       (null
 908        (int-sap 0)))
 909    `(or null system-area-pointer (alien ,type))))
 910 \f
 911 ;;;; the MEM-BLOCK type
 912
 913 (define-alien-type-class (mem-block :include alien-value))
 914
 915 (define-alien-type-method (mem-block :extract-gen) (type sap offset)
 916   (declare (ignore type))
 917   `(sap+ ,sap (truncate ,offset sb!vm:n-byte-bits)))
 918
 919 (define-alien-type-method (mem-block :deposit-gen) (type sap offset value)
 920   (let ((bits (alien-mem-block-type-bits type)))
 921     (unless bits
 922       (error "can't deposit aliens of type ~S (unknown size)" type))
 923     `(sb!kernel:system-area-ub8-copy ,value 0 ,sap
 924       (truncate ,offset sb!vm:n-byte-bits)
 925       ',(truncate bits sb!vm:n-byte-bits))))
 926 \f
 927 ;;;; the ARRAY type
 928
 929 (define-alien-type-class (array :include mem-block)
 930   (element-type (missing-arg) :type alien-type)
 931   (dimensions (missing-arg) :type list))
 932
 933 (define-alien-type-translator array (ele-type &rest dims &environment env)
 934
 935   (when dims
 936     (unless (typep (first dims) '(or index null))
 937       (error "The first dimension is not a non-negative fixnum or NIL: ~S"
 938              (first dims)))
 939     (let ((loser (find-if-not (lambda (x) (typep x 'index))
 940                               (rest dims))))
 941       (when loser
 942         (error "A dimension is not a non-negative fixnum: ~S" loser))))
 943
 944   (let ((parsed-ele-type (parse-alien-type ele-type env)))
 945     (make-alien-array-type
 946      :element-type parsed-ele-type
 947      :dimensions dims
 948      :alignment (alien-type-alignment parsed-ele-type)
 949      :bits (if (and (alien-type-bits parsed-ele-type)
 950                     (every #'integerp dims))
 951                (* (align-offset (alien-type-bits parsed-ele-type)
 952                                 (alien-type-alignment parsed-ele-type))
 953                   (reduce #'* dims))))))
 954
 955 (define-alien-type-method (array :unparse) (type)
 956   `(array ,(%unparse-alien-type (alien-array-type-element-type type))
 957           ,@(alien-array-type-dimensions type)))
 958
 959 (define-alien-type-method (array :type=) (type1 type2)
 960   (and (equal (alien-array-type-dimensions type1)
 961               (alien-array-type-dimensions type2))
 962        (alien-type-= (alien-array-type-element-type type1)
 963                      (alien-array-type-element-type type2))))
 964
 965 (define-alien-type-method (array :subtypep) (type1 type2)
 966   (and (alien-array-type-p type2)
 967        (let ((dim1 (alien-array-type-dimensions type1))
 968              (dim2 (alien-array-type-dimensions type2)))
 969          (and (= (length dim1) (length dim2))
 970               (or (and dim2
 971                        (null (car dim2))
 972                        (equal (cdr dim1) (cdr dim2)))
 973                   (equal dim1 dim2))
 974               (alien-subtype-p (alien-array-type-element-type type1)
 975                                (alien-array-type-element-type type2))))))
 976 \f
 977 ;;;; the RECORD type
 978
 979 (def!struct (alien-record-field
 980              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 981   (name (missing-arg) :type symbol)
 982   (type (missing-arg) :type alien-type)
 983   (bits nil :type (or unsigned-byte null))
 984   (offset 0 :type unsigned-byte))
 985 (def!method print-object ((field alien-record-field) stream)
 986   (print-unreadable-object (field stream :type t)
 987     (format stream
 988             "~S ~S~@[:~D~]"
 989             (alien-record-field-type field)
 990             (alien-record-field-name field)
 991             (alien-record-field-bits field))))
 992
 993 (define-alien-type-class (record :include mem-block)
 994   (kind :struct :type (member :struct :union))
 995   (name nil :type (or symbol null))
 996   (fields nil :type list))
 997
 998 (define-alien-type-translator struct (name &rest fields &environment env)
 999   (parse-alien-record-type :struct name fields env))
1000
1001 (define-alien-type-translator union (name &rest fields &environment env)
1002   (parse-alien-record-type :union name fields env))
1003
1004 ;;; FIXME: This is really pretty horrible: we avoid creating new
1005 ;;; ALIEN-RECORD-TYPE objects when a live one is flitting around the
1006 ;;; system already. This way forwrd-references sans fields get get
1007 ;;; "updated" for free to contain the field info. Maybe rename
1008 ;;; MAKE-ALIEN-RECORD-TYPE to %MAKE-ALIEN-RECORD-TYPE and use
1009 ;;; ENSURE-ALIEN-RECORD-TYPE instead. --NS 20040729
1010 (defun parse-alien-record-type (kind name fields env)
1011   (declare (type (or sb!kernel:lexenv null) env))
1012   (flet ((frob-type (type new-fields alignment bits)
1013            (setf (alien-record-type-fields type) new-fields
1014                  (alien-record-type-alignment type) alignment
1015                  (alien-record-type-bits type) bits)))
1016       (cond (fields
1017              (multiple-value-bind (new-fields alignment bits)
1018                  (parse-alien-record-fields kind fields env)
1019                (let* ((old (and name (auxiliary-alien-type kind name env)))
1020                       (old-fields (and old (alien-record-type-fields old))))
1021                  (when (and old-fields
1022                             (notevery #'record-fields-match-p old-fields new-fields))
1023                    (cerror "Continue, clobbering the old definition."
1024                            "Incompatible alien record type definition~%Old: ~S~%New: ~S"
1025                            (unparse-alien-type old)
1026                            `(,(unparse-alien-record-kind kind)
1027                               ,name
1028                               ,@(mapcar #'unparse-alien-record-field new-fields)))
1029                    (frob-type old new-fields alignment bits))
1030                  (if old-fields
1031                      old
1032                      (let ((type (or old (make-alien-record-type :name name :kind kind))))
1033                        (when (and name (not old))
1034                          (setf (auxiliary-alien-type kind name env) type))
1035                        (frob-type type new-fields alignment bits)
1036                        type)))))
1037             (name
1038              (or (auxiliary-alien-type kind name env)
1039                  (setf (auxiliary-alien-type kind name env)
1040                        (make-alien-record-type :name name :kind kind))))
1041             (t
1042              (make-alien-record-type :kind kind)))))
1043
1044 ;;; This is used by PARSE-ALIEN-TYPE to parse the fields of struct and union
1045 ;;; types. KIND is the kind we are paring the fields of, and FIELDS is the
1046 ;;; list of field specifications.
1047 ;;;
1048 ;;; Result is a list of field objects, overall alignment, and number of bits
1049 (defun parse-alien-record-fields (kind fields env)
1050   (declare (type list fields))
1051   (let ((total-bits 0)
1052         (overall-alignment 1)
1053         (parsed-fields nil))
1054     (dolist (field fields)
1055       (destructuring-bind (var type &key alignment) field
1056         (let* ((field-type (parse-alien-type type env))
1057                (bits (alien-type-bits field-type))
1058                (parsed-field
1059                 (make-alien-record-field :type field-type
1060                                          :name var)))
1061           (unless alignment
1062             (setf alignment (alien-type-alignment field-type)))
1063           (push parsed-field parsed-fields)
1064           (when (null bits)
1065             (error "unknown size: ~S" (unparse-alien-type field-type)))
1066           (when (null alignment)
1067             (error "unknown alignment: ~S" (unparse-alien-type field-type)))
1068           (setf overall-alignment (max overall-alignment alignment))
1069           (ecase kind
1070             (:struct
1071              (let ((offset (align-offset total-bits alignment)))
1072                (setf (alien-record-field-offset parsed-field) offset)
1073                (setf total-bits (+ offset bits))))
1074             (:union
1075              (setf total-bits (max total-bits bits)))))))
1076     (values (nreverse parsed-fields)
1077             overall-alignment
1078             (align-offset total-bits overall-alignment))))
1079
1080 (define-alien-type-method (record :unparse) (type)
1081   `(,(unparse-alien-record-kind (alien-record-type-kind type))
1082     ,(alien-record-type-name type)
1083     ,@(unless (member type *record-types-already-unparsed* :test #'eq)
1084         (push type *record-types-already-unparsed*)
1085         (mapcar #'unparse-alien-record-field
1086                 (alien-record-type-fields type)))))
1087
1088 (defun unparse-alien-record-kind (kind)
1089   (case kind
1090     (:struct 'struct)
1091     (:union 'union)
1092     (t '???)))
1093
1094 (defun unparse-alien-record-field (field)
1095   `(,(alien-record-field-name field)
1096      ,(%unparse-alien-type (alien-record-field-type field))
1097      ,@(when (alien-record-field-bits field)
1098              (list (alien-record-field-bits field)))))
1099
1100 ;;; Test the record fields. Keep a hashtable table of already compared
1101 ;;; types to detect cycles.
1102 (defun record-fields-match-p (field1 field2)
1103   (and (eq (alien-record-field-name field1)
1104            (alien-record-field-name field2))
1105        (eql (alien-record-field-bits field1)
1106             (alien-record-field-bits field2))
1107        (eql (alien-record-field-offset field1)
1108             (alien-record-field-offset field2))
1109        (alien-type-= (alien-record-field-type field1)
1110                      (alien-record-field-type field2))))
1111
1112 (defvar *alien-type-matches* nil
1113   "A hashtable used to detect cycles while comparing record types.")
1114
1115 (define-alien-type-method (record :type=) (type1 type2)
1116   (and (eq (alien-record-type-name type1)
1117            (alien-record-type-name type2))
1118        (eq (alien-record-type-kind type1)
1119            (alien-record-type-kind type2))
1120        (eql (alien-type-bits type1)
1121             (alien-type-bits type2))
1122        (eql (alien-type-alignment type1)
1123             (alien-type-alignment type2))
1124        (flet ((match-fields (&optional old)
1125                 (setf (gethash type1 *alien-type-matches*) (cons type2 old))
1126                 (every #'record-fields-match-p
1127                        (alien-record-type-fields type1)
1128                        (alien-record-type-fields type2))))
1129          (if *alien-type-matches*
1130              (let ((types (gethash type1 *alien-type-matches*)))
1131                (or (memq type2 types) (match-fields types)))
1132              (let ((*alien-type-matches* (make-hash-table :test #'eq)))
1133                (match-fields))))))
1134 \f
1135 ;;;; the FUNCTION and VALUES alien types
1136
1137 (define-alien-type-class (fun :include mem-block)
1138   (result-type (missing-arg) :type alien-type)
1139   (arg-types (missing-arg) :type list)
1140   (stub nil :type (or null function)))
1141
1142 (define-alien-type-translator function (result-type &rest arg-types
1143                                                     &environment env)
1144   (make-alien-fun-type
1145    :result-type (let ((*values-type-okay* t))
1146                   (parse-alien-type result-type env))
1147    :arg-types (mapcar (lambda (arg-type) (parse-alien-type arg-type env))
1148                       arg-types)))
1149
1150 (define-alien-type-method (fun :unparse) (type)
1151   `(function ,(%unparse-alien-type (alien-fun-type-result-type type))
1152              ,@(mapcar #'%unparse-alien-type
1153                        (alien-fun-type-arg-types type))))
1154
1155 (define-alien-type-method (fun :type=) (type1 type2)
1156   (and (alien-type-= (alien-fun-type-result-type type1)
1157                      (alien-fun-type-result-type type2))
1158        (= (length (alien-fun-type-arg-types type1))
1159           (length (alien-fun-type-arg-types type2)))
1160        (every #'alien-type-=
1161               (alien-fun-type-arg-types type1)
1162               (alien-fun-type-arg-types type2))))
1163
1164 (define-alien-type-class (values)
1165   (values (missing-arg) :type list))
1166
1167 (define-alien-type-translator values (&rest values &environment env)
1168   (unless *values-type-okay*
1169     (error "cannot use values types here"))
1170   (let ((*values-type-okay* nil))
1171     (make-alien-values-type
1172      :values (mapcar (lambda (alien-type) (parse-alien-type alien-type env))
1173                      values))))
1174
1175 (define-alien-type-method (values :unparse) (type)
1176   `(values ,@(mapcar #'%unparse-alien-type
1177                      (alien-values-type-values type))))
1178
1179 (define-alien-type-method (values :type=) (type1 type2)
1180   (and (= (length (alien-values-type-values type1))
1181           (length (alien-values-type-values type2)))
1182        (every #'alien-type-=
1183               (alien-values-type-values type1)
1184               (alien-values-type-values type2))))
1185 \f
1186 ;;;; a structure definition needed both in the target and in the
1187 ;;;; cross-compilation host
1188
1189 ;;; information about local aliens. The WITH-ALIEN macro builds one of
1190 ;;; these structures and LOCAL-ALIEN and friends communicate
1191 ;;; information about how that local alien is represented.
1192 (def!struct (local-alien-info
1193              (:make-load-form-fun sb!kernel:just-dump-it-normally)
1194              (:constructor make-local-alien-info
1195                            (&key type force-to-memory-p
1196                             &aux (force-to-memory-p (or force-to-memory-p
1197                                                         (alien-array-type-p type)
1198                                                         (alien-record-type-p type))))))
1199   ;; the type of the local alien
1200   (type (missing-arg) :type alien-type)
1201   ;; Must this local alien be forced into memory? Using the ADDR macro
1202   ;; on a local alien will set this.
1203   (force-to-memory-p nil :type (member t nil)))
1204 (def!method print-object ((info local-alien-info) stream)
1205   (print-unreadable-object (info stream :type t)
1206     (format stream
1207             "~:[~;(forced to stack) ~]~S"
1208             (local-alien-info-force-to-memory-p info)
1209             (unparse-alien-type (local-alien-info-type info)))))
1210 \f
1211 ;;;; the ADDR macro
1212
1213 (defmacro-mundanely addr (expr &environment env)
1214   #!+sb-doc
1215   "Return an Alien pointer to the data addressed by Expr, which must be a call
1216    to SLOT or DEREF, or a reference to an Alien variable."
1217   (let ((form (%macroexpand expr env)))
1218     (or (typecase form
1219           (cons
1220            (case (car form)
1221              (slot
1222               (cons '%slot-addr (cdr form)))
1223              (deref
1224               (cons '%deref-addr (cdr form)))
1225              (%heap-alien
1226               (cons '%heap-alien-addr (cdr form)))
1227              (local-alien
1228               (let ((info (let ((info-arg (second form)))
1229                             (and (consp info-arg)
1230                                  (eq (car info-arg) 'quote)
1231                                  (second info-arg)))))
1232                 (unless (local-alien-info-p info)
1233                   (error "Something is wrong, LOCAL-ALIEN-INFO not found: ~S"
1234                          form))
1235                 (setf (local-alien-info-force-to-memory-p info) t))
1236               (cons '%local-alien-addr (cdr form)))))
1237           (symbol
1238            (let ((kind (info :variable :kind form)))
1239              (when (eq kind :alien)
1240                `(%heap-alien-addr ',(info :variable :alien-info form))))))
1241         (error "~S is not a valid L-value." form))))
1242
1243 (/show0 "host-alieneval.lisp end of file")