src/code/host-alieneval.lisp

   1 ;;;; the part of the Alien implementation which is needed at
   2 ;;;; cross-compilation time
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "host-alieneval.lisp 15")
  16 \f
  17 ;;;; utility functions
  18
  19 (defun align-offset (offset alignment)
  20   (let ((extra (rem offset alignment)))
  21     (if (zerop extra) offset (+ offset (- alignment extra)))))
  22
  23 (defun guess-alignment (bits)
  24   (cond ((null bits) nil)
  25         #!-x86 ((> bits 32) 64)
  26         ((> bits 16) 32)
  27         ((> bits 8) 16)
  28         ((> bits 1) 8)
  29         (t 1)))
  30 \f
  31 ;;;; ALIEN-TYPE-INFO stuff
  32
  33 (eval-when (:compile-toplevel :execute :load-toplevel)
  34
  35 (defstruct (alien-type-class (:copier nil))
  36   (name nil :type symbol)
  37   (include nil :type (or null alien-type-class))
  38   (unparse nil :type (or null function))
  39   (type= nil :type (or null function))
  40   (lisp-rep nil :type (or null function))
  41   (alien-rep nil :type (or null function))
  42   (extract-gen nil :type (or null function))
  43   (deposit-gen nil :type (or null function))
  44   (naturalize-gen nil :type (or null function))
  45   (deport-gen nil :type (or null function))
  46   ;; Cast?
  47   (arg-tn nil :type (or null function))
  48   (result-tn nil :type (or null function))
  49   (subtypep nil :type (or null function)))
  50 (def!method print-object ((type-class alien-type-class) stream)
  51   (print-unreadable-object (type-class stream :type t)
  52     (prin1 (alien-type-class-name type-class) stream)))
  53
  54 (defun alien-type-class-or-lose (name)
  55   (or (gethash name *alien-type-classes*)
  56       (error "no alien type class ~S" name)))
  57
  58 (defun create-alien-type-class-if-necessary (name include)
  59   (let ((old (gethash name *alien-type-classes*))
  60         (include (and include (alien-type-class-or-lose include))))
  61     (if old
  62         (setf (alien-type-class-include old) include)
  63         (setf (gethash name *alien-type-classes*)
  64               (make-alien-type-class :name name :include include)))))
  65
  66 (defparameter *method-slot-alist*
  67   '((:unparse . alien-type-class-unparse)
  68     (:type= . alien-type-class-type=)
  69     (:subtypep . alien-type-class-subtypep)
  70     (:lisp-rep . alien-type-class-lisp-rep)
  71     (:alien-rep . alien-type-class-alien-rep)
  72     (:extract-gen . alien-type-class-extract-gen)
  73     (:deposit-gen . alien-type-class-deposit-gen)
  74     (:naturalize-gen . alien-type-class-naturalize-gen)
  75     (:deport-gen . alien-type-class-deport-gen)
  76     ;; cast?
  77     (:arg-tn . alien-type-class-arg-tn)
  78     (:result-tn . alien-type-class-result-tn)))
  79
  80 (defun method-slot (method)
  81   (cdr (or (assoc method *method-slot-alist*)
  82            (error "no method ~S" method))))
  83
  84 ) ; EVAL-WHEN
  85
  86 ;;; We define a keyword "BOA" constructor so that we can reference the
  87 ;;; slot names in init forms.
  88 (def!macro define-alien-type-class ((name &key include include-args)
  89                                     &rest slots)
  90   (let ((defstruct-name (symbolicate "ALIEN-" name "-TYPE")))
  91     (multiple-value-bind (include include-defstruct overrides)
  92         (etypecase include
  93           (null
  94            (values nil 'alien-type nil))
  95           (symbol
  96            (values
  97             include
  98             (symbolicate "ALIEN-" include "-TYPE")
  99             nil))
 100           (list
 101            (values
 102             (car include)
 103             (symbolicate "ALIEN-" (car include) "-TYPE")
 104             (cdr include))))
 105       `(progn
 106          (eval-when (:compile-toplevel :load-toplevel :execute)
 107            (create-alien-type-class-if-necessary ',name ',(or include 'root)))
 108          (def!struct (,defstruct-name
 109                         (:include ,include-defstruct
 110                                   (class ',name)
 111                                   ,@overrides)
 112                         (:constructor
 113                          ,(symbolicate "MAKE-" defstruct-name)
 114                          (&key class bits alignment
 115                                ,@(mapcar (lambda (x)
 116                                            (if (atom x) x (car x)))
 117                                          slots)
 118                                ,@include-args
 119                                ;; KLUDGE
 120                                &aux (alignment (or alignment (guess-alignment bits))))))
 121            ,@slots)))))
 122
 123 (def!macro define-alien-type-method ((class method) lambda-list &rest body)
 124   (let ((defun-name (symbolicate class "-" method "-METHOD")))
 125     `(progn
 126        (defun ,defun-name ,lambda-list
 127          ,@body)
 128        (setf (,(method-slot method) (alien-type-class-or-lose ',class))
 129              #',defun-name))))
 130
 131 (def!macro invoke-alien-type-method (method type &rest args)
 132   (let ((slot (method-slot method)))
 133     (once-only ((type type))
 134       `(funcall (do ((class (alien-type-class-or-lose (alien-type-class ,type))
 135                             (alien-type-class-include class)))
 136                     ((null class)
 137                      (error "method ~S not defined for ~S"
 138                             ',method (alien-type-class ,type)))
 139                   (let ((fn (,slot class)))
 140                     (when fn
 141                       (return fn))))
 142                 ,type ,@args))))
 143 \f
 144 ;;;; type parsing and unparsing
 145
 146 ;;; CMU CL used COMPILER-LET to bind *AUXILIARY-TYPE-DEFINITIONS*, and
 147 ;;; COMPILER-LET is no longer supported by ANSI or SBCL. Instead, we
 148 ;;; follow the suggestion in CLTL2 of using SYMBOL-MACROLET to achieve
 149 ;;; a similar effect.
 150 (eval-when (:compile-toplevel :load-toplevel :execute)
 151   (defun auxiliary-type-definitions (env)
 152     (multiple-value-bind (result expanded-p)
 153         (sb!xc:macroexpand '&auxiliary-type-definitions& env)
 154       (if expanded-p
 155           result
 156           ;; This is like having the global symbol-macro definition be
 157           ;; NIL, but global symbol-macros make me vaguely queasy, so
 158           ;; I do it this way instead.
 159           nil))))
 160
 161 ;;; Process stuff in a new scope.
 162 (def!macro with-auxiliary-alien-types (env &body body)
 163   ``(symbol-macrolet ((&auxiliary-type-definitions&
 164                        ,(append *new-auxiliary-types*
 165                                 (auxiliary-type-definitions ,env))))
 166       ,(let ((*new-auxiliary-types* nil))
 167          ,@body)))
 168
 169 ;;; Parse TYPE as an alien type specifier and return the resultant
 170 ;;; ALIEN-TYPE structure.
 171 (defun parse-alien-type (type env)
 172   (declare (type (or sb!kernel:lexenv null) env))
 173   (if (consp type)
 174       (let ((translator (info :alien-type :translator (car type))))
 175         (unless translator
 176           (error "unknown alien type: ~S" type))
 177         (funcall translator type env))
 178       (ecase (info :alien-type :kind type)
 179         (:primitive
 180          (let ((translator (info :alien-type :translator type)))
 181            (unless translator
 182              (error "no translator for primitive alien type ~S" type))
 183            (funcall translator (list type) env)))
 184         (:defined
 185          (or (info :alien-type :definition type)
 186              (error "no definition for alien type ~S" type)))
 187         (:unknown
 188          (error "unknown alien type: ~S" type)))))
 189
 190 (defun auxiliary-alien-type (kind name env)
 191   (declare (type (or sb!kernel:lexenv null) env))
 192   (flet ((aux-defn-matches (x)
 193            (and (eq (first x) kind) (eq (second x) name))))
 194     (let ((in-auxiliaries
 195            (or (find-if #'aux-defn-matches *new-auxiliary-types*)
 196                (find-if #'aux-defn-matches (auxiliary-type-definitions env)))))
 197       (if in-auxiliaries
 198           (values (third in-auxiliaries) t)
 199           (ecase kind
 200             (:struct
 201              (info :alien-type :struct name))
 202             (:union
 203              (info :alien-type :union name))
 204             (:enum
 205              (info :alien-type :enum name)))))))
 206
 207 (defun (setf auxiliary-alien-type) (new-value kind name env)
 208   (declare (type (or sb!kernel:lexenv null) env))
 209   (flet ((aux-defn-matches (x)
 210            (and (eq (first x) kind) (eq (second x) name))))
 211     (when (find-if #'aux-defn-matches *new-auxiliary-types*)
 212       (error "attempt to multiply define ~A ~S" kind name))
 213     (when (find-if #'aux-defn-matches (auxiliary-type-definitions env))
 214       (error "attempt to shadow definition of ~A ~S" kind name)))
 215   (push (list kind name new-value) *new-auxiliary-types*)
 216   new-value)
 217
 218 (defun verify-local-auxiliaries-okay ()
 219   (dolist (info *new-auxiliary-types*)
 220     (destructuring-bind (kind name defn) info
 221       (declare (ignore defn))
 222       (when (ecase kind
 223               (:struct
 224                (info :alien-type :struct name))
 225               (:union
 226                (info :alien-type :union name))
 227               (:enum
 228                (info :alien-type :enum name)))
 229         (error "attempt to shadow definition of ~A ~S" kind name)))))
 230
 231 (defun unparse-alien-type (type)
 232   #!+sb-doc
 233   "Convert the alien-type structure TYPE back into a list specification of
 234    the type."
 235   (declare (type alien-type type))
 236   (let ((*record-types-already-unparsed* nil))
 237     (%unparse-alien-type type)))
 238
 239 ;;; Does all the work of UNPARSE-ALIEN-TYPE. It's separate because we
 240 ;;; need to recurse inside the binding of
 241 ;;; *RECORD-TYPES-ALREADY-UNPARSED*.
 242 (defun %unparse-alien-type (type)
 243   (invoke-alien-type-method :unparse type))
 244 \f
 245 ;;;; alien type defining stuff
 246
 247 (def!macro define-alien-type-translator (name lambda-list &body body)
 248   (let ((whole (gensym "WHOLE"))
 249         (env (gensym "ENV"))
 250         (defun-name (symbolicate "ALIEN-" name "-TYPE-TRANSLATOR")))
 251     (multiple-value-bind (body decls docs)
 252         (sb!kernel:parse-defmacro lambda-list whole body name
 253                                   'define-alien-type-translator
 254                                   :environment env)
 255       `(eval-when (:compile-toplevel :load-toplevel :execute)
 256          (defun ,defun-name (,whole ,env)
 257            (declare (ignorable ,env))
 258            ,@decls
 259            (block ,name
 260              ,body))
 261          (%define-alien-type-translator ',name #',defun-name ,docs)))))
 262
 263 (eval-when (:compile-toplevel :load-toplevel :execute)
 264   (defun %define-alien-type-translator (name translator docs)
 265     (declare (ignore docs))
 266     (setf (info :alien-type :kind name) :primitive)
 267     (setf (info :alien-type :translator name) translator)
 268     (clear-info :alien-type :definition name)
 269     #+nil
 270     (setf (fdocumentation name 'alien-type) docs)
 271     name))
 272
 273 (def!macro define-alien-type (name type &environment env)
 274   #!+sb-doc
 275   "Define the alien type NAME to be equivalent to TYPE. Name may be NIL for
 276    STRUCT and UNION types, in which case the name is taken from the type
 277    specifier."
 278   (with-auxiliary-alien-types env
 279     (let ((alien-type (parse-alien-type type env)))
 280       `(eval-when (:compile-toplevel :load-toplevel :execute)
 281          ,@(when *new-auxiliary-types*
 282              `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
 283          ,@(when name
 284              `((%define-alien-type ',name ',alien-type)))))))
 285 (def!macro def-alien-type (&rest rest)
 286   (deprecation-warning 'def-alien-type 'define-alien-type)
 287   `(define-alien-type ,@rest))
 288
 289 (eval-when (:compile-toplevel :load-toplevel :execute)
 290   (defun %def-auxiliary-alien-types (types)
 291     (dolist (info types)
 292       (destructuring-bind (kind name defn) info
 293         (macrolet ((frob (kind)
 294                          `(let ((old (info :alien-type ,kind name)))
 295                             (unless (or (null old) (alien-type-= old defn))
 296                               (warn
 297                                "redefining ~A ~S to be:~%  ~S,~%was:~%  ~S"
 298                                kind name defn old))
 299                             (setf (info :alien-type ,kind name) defn))))
 300           (ecase kind
 301             (:struct (frob :struct))
 302             (:union (frob :union))
 303             (:enum (frob :enum)))))))
 304   (defun %define-alien-type (name new)
 305     (ecase (info :alien-type :kind name)
 306       (:primitive
 307        (error "~S is a built-in alien type." name))
 308       (:defined
 309        (let ((old (info :alien-type :definition name)))
 310          (unless (or (null old) (alien-type-= new old))
 311            (warn "redefining ~S to be:~%  ~S,~%was~%  ~S"
 312                  name
 313                  (unparse-alien-type new)
 314                  (unparse-alien-type old)))))
 315       (:unknown))
 316     (setf (info :alien-type :definition name) new)
 317     (setf (info :alien-type :kind name) :defined)
 318     name))
 319 \f
 320 ;;;; the root alien type
 321
 322 (eval-when (:compile-toplevel :load-toplevel :execute)
 323   (create-alien-type-class-if-necessary 'root nil))
 324
 325 (def!struct (alien-type
 326              (:make-load-form-fun sb!kernel:just-dump-it-normally)
 327              (:constructor make-alien-type (&key class bits alignment
 328                                             &aux (alignment (or alignment (guess-alignment bits))))))
 329   (class 'root :type symbol)
 330   (bits nil :type (or null unsigned-byte))
 331   (alignment nil :type (or null unsigned-byte)))
 332 (def!method print-object ((type alien-type) stream)
 333   (print-unreadable-object (type stream :type t)
 334     (prin1 (unparse-alien-type type) stream)))
 335 \f
 336 ;;;; the SAP type
 337
 338 (define-alien-type-class (system-area-pointer))
 339
 340 (define-alien-type-translator system-area-pointer ()
 341   (make-alien-system-area-pointer-type
 342    :bits #!-alpha sb!vm:n-word-bits #!+alpha 64))
 343
 344 (define-alien-type-method (system-area-pointer :unparse) (type)
 345   (declare (ignore type))
 346   'system-area-pointer)
 347
 348 (define-alien-type-method (system-area-pointer :lisp-rep) (type)
 349   (declare (ignore type))
 350   'system-area-pointer)
 351
 352 (define-alien-type-method (system-area-pointer :alien-rep) (type)
 353   (declare (ignore type))
 354   'system-area-pointer)
 355
 356 (define-alien-type-method (system-area-pointer :naturalize-gen) (type alien)
 357   (declare (ignore type))
 358   alien)
 359
 360 (define-alien-type-method (system-area-pointer :deport-gen) (type object)
 361   (declare (ignore type))
 362   (/noshow "doing alien type method SYSTEM-AREA-POINTER :DEPORT-GEN" object)
 363   object)
 364
 365 (define-alien-type-method (system-area-pointer :extract-gen) (type sap offset)
 366   (declare (ignore type))
 367   `(sap-ref-sap ,sap (/ ,offset sb!vm:n-byte-bits)))
 368 \f
 369 ;;;; the ALIEN-VALUE type
 370
 371 (define-alien-type-class (alien-value :include system-area-pointer))
 372
 373 (define-alien-type-method (alien-value :lisp-rep) (type)
 374   (declare (ignore type))
 375   nil)
 376
 377 (define-alien-type-method (alien-value :naturalize-gen) (type alien)
 378   `(%sap-alien ,alien ',type))
 379
 380 (define-alien-type-method (alien-value :deport-gen) (type value)
 381   (declare (ignore type))
 382   (/noshow "doing alien type method ALIEN-VALUE :DEPORT-GEN" value)
 383   `(alien-sap ,value))
 384 \f
 385 ;;; HEAP-ALIEN-INFO -- defstruct.
 386 ;;;
 387 ;;; Information describing a heap-allocated alien.
 388 (def!struct (heap-alien-info
 389              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 390   ;; The type of this alien.
 391   (type (missing-arg) :type alien-type)
 392   ;; The form to evaluate to produce the SAP pointing to where in the heap
 393   ;; it is.
 394   (sap-form (missing-arg)))
 395 (def!method print-object ((info heap-alien-info) stream)
 396   (print-unreadable-object (info stream :type t)
 397     (funcall (formatter "~S ~S")
 398              stream
 399              (heap-alien-info-sap-form info)
 400              (unparse-alien-type (heap-alien-info-type info)))))
 401 \f
 402 ;;;; Interfaces to the different methods
 403
 404 (defun alien-type-= (type1 type2)
 405   #!+sb-doc
 406   "Return T iff TYPE1 and TYPE2 describe equivalent alien types."
 407   (or (eq type1 type2)
 408       (and (eq (alien-type-class type1)
 409                (alien-type-class type2))
 410            (invoke-alien-type-method :type= type1 type2))))
 411
 412 (defun alien-subtype-p (type1 type2)
 413   #!+sb-doc
 414   "Return T iff the alien type TYPE1 is a subtype of TYPE2. Currently, the
 415    only supported subtype relationships are is that any pointer type is a
 416    subtype of (* t), and any array type first dimension will match
 417    (array <eltype> nil ...). Otherwise, the two types have to be
 418    ALIEN-TYPE-=."
 419   (or (eq type1 type2)
 420       (invoke-alien-type-method :subtypep type1 type2)))
 421
 422 (defun compute-naturalize-lambda (type)
 423   `(lambda (alien ignore)
 424      (declare (ignore ignore))
 425      ,(invoke-alien-type-method :naturalize-gen type 'alien)))
 426
 427 (defun compute-deport-lambda (type)
 428   (declare (type alien-type type))
 429   (/noshow "entering COMPUTE-DEPORT-LAMBDA" type)
 430   (multiple-value-bind (form value-type)
 431       (invoke-alien-type-method :deport-gen type 'value)
 432     `(lambda (value ignore)
 433        (declare (type ,(or value-type
 434                            (compute-lisp-rep-type type)
 435                            `(alien ,type))
 436                       value)
 437                 (ignore ignore))
 438        ,form)))
 439
 440 (defun compute-extract-lambda (type)
 441   `(lambda (sap offset ignore)
 442      (declare (type system-area-pointer sap)
 443               (type unsigned-byte offset)
 444               (ignore ignore))
 445      (naturalize ,(invoke-alien-type-method :extract-gen type 'sap 'offset)
 446                  ',type)))
 447
 448 (defun compute-deposit-lambda (type)
 449   (declare (type alien-type type))
 450   `(lambda (sap offset ignore value)
 451      (declare (type system-area-pointer sap)
 452               (type unsigned-byte offset)
 453               (ignore ignore))
 454      (let ((value (deport value ',type)))
 455        ,(invoke-alien-type-method :deposit-gen type 'sap 'offset 'value)
 456        ;; Note: the reason we don't just return the pre-deported value
 457        ;; is because that would inhibit any (deport (naturalize ...))
 458        ;; optimizations that might have otherwise happen. Re-naturalizing
 459        ;; the value might cause extra consing, but is flushable, so probably
 460        ;; results in better code.
 461        (naturalize value ',type))))
 462
 463 (defun compute-lisp-rep-type (type)
 464   (invoke-alien-type-method :lisp-rep type))
 465
 466 (defun compute-alien-rep-type (type)
 467   (invoke-alien-type-method :alien-rep type))
 468 \f
 469 ;;;; default methods
 470
 471 (define-alien-type-method (root :unparse) (type)
 472   `(<unknown-alien-type> ,(type-of type)))
 473
 474 (define-alien-type-method (root :type=) (type1 type2)
 475   (declare (ignore type1 type2))
 476   t)
 477
 478 (define-alien-type-method (root :subtypep) (type1 type2)
 479   (alien-type-= type1 type2))
 480
 481 (define-alien-type-method (root :lisp-rep) (type)
 482   (declare (ignore type))
 483   nil)
 484
 485 (define-alien-type-method (root :alien-rep) (type)
 486   (declare (ignore type))
 487   '*)
 488
 489 (define-alien-type-method (root :naturalize-gen) (type alien)
 490   (declare (ignore alien))
 491   (error "cannot represent ~S typed aliens" type))
 492
 493 (define-alien-type-method (root :deport-gen) (type object)
 494   (declare (ignore object))
 495   (error "cannot represent ~S typed aliens" type))
 496
 497 (define-alien-type-method (root :extract-gen) (type sap offset)
 498   (declare (ignore sap offset))
 499   (error "cannot represent ~S typed aliens" type))
 500
 501 (define-alien-type-method (root :deposit-gen) (type sap offset value)
 502   `(setf ,(invoke-alien-type-method :extract-gen type sap offset) ,value))
 503
 504 (define-alien-type-method (root :arg-tn) (type state)
 505   (declare (ignore state))
 506   (error "Aliens of type ~S cannot be passed as arguments to CALL-OUT."
 507          (unparse-alien-type type)))
 508
 509 (define-alien-type-method (root :result-tn) (type state)
 510   (declare (ignore state))
 511   (error "Aliens of type ~S cannot be returned from CALL-OUT."
 512          (unparse-alien-type type)))
 513 \f
 514 ;;;; the INTEGER type
 515
 516 (define-alien-type-class (integer)
 517   (signed t :type (member t nil)))
 518
 519 (define-alien-type-translator signed (&optional (bits sb!vm:n-word-bits))
 520   (make-alien-integer-type :bits bits))
 521
 522 (define-alien-type-translator integer (&optional (bits sb!vm:n-word-bits))
 523   (make-alien-integer-type :bits bits))
 524
 525 (define-alien-type-translator unsigned (&optional (bits sb!vm:n-word-bits))
 526   (make-alien-integer-type :bits bits :signed nil))
 527
 528 (define-alien-type-method (integer :unparse) (type)
 529   (list (if (alien-integer-type-signed type) 'signed 'unsigned)
 530         (alien-integer-type-bits type)))
 531
 532 (define-alien-type-method (integer :type=) (type1 type2)
 533   (and (eq (alien-integer-type-signed type1)
 534            (alien-integer-type-signed type2))
 535        (= (alien-integer-type-bits type1)
 536           (alien-integer-type-bits type2))))
 537
 538 (define-alien-type-method (integer :lisp-rep) (type)
 539   (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 540         (alien-integer-type-bits type)))
 541
 542 (define-alien-type-method (integer :alien-rep) (type)
 543   (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 544         (alien-integer-type-bits type)))
 545
 546 (define-alien-type-method (integer :naturalize-gen) (type alien)
 547   (declare (ignore type))
 548   alien)
 549
 550 (define-alien-type-method (integer :deport-gen) (type value)
 551   (declare (ignore type))
 552   value)
 553
 554 (define-alien-type-method (integer :extract-gen) (type sap offset)
 555   (declare (type alien-integer-type type))
 556   (let ((ref-fun
 557          (if (alien-integer-type-signed type)
 558           (case (alien-integer-type-bits type)
 559             (8 'signed-sap-ref-8)
 560             (16 'signed-sap-ref-16)
 561             (32 'signed-sap-ref-32)
 562             #!+alpha (64 'signed-sap-ref-64))
 563           (case (alien-integer-type-bits type)
 564             (8 'sap-ref-8)
 565             (16 'sap-ref-16)
 566             (32 'sap-ref-32)
 567             #!+alpha (64 'sap-ref-64)))))
 568     (if ref-fun
 569         `(,ref-fun ,sap (/ ,offset sb!vm:n-byte-bits))
 570         (error "cannot extract ~W-bit integers"
 571                (alien-integer-type-bits type)))))
 572 \f
 573 ;;;; the BOOLEAN type
 574
 575 (define-alien-type-class (boolean :include integer :include-args (signed)))
 576
 577 ;;; FIXME: Check to make sure that we aren't attaching user-readable
 578 ;;; stuff to CL:BOOLEAN in any way which impairs ANSI compliance.
 579 (define-alien-type-translator boolean (&optional (bits sb!vm:n-word-bits))
 580   (make-alien-boolean-type :bits bits :signed nil))
 581
 582 (define-alien-type-method (boolean :unparse) (type)
 583   `(boolean ,(alien-boolean-type-bits type)))
 584
 585 (define-alien-type-method (boolean :lisp-rep) (type)
 586   (declare (ignore type))
 587   `(member t nil))
 588
 589 (define-alien-type-method (boolean :naturalize-gen) (type alien)
 590   (declare (ignore type))
 591   `(not (zerop ,alien)))
 592
 593 (define-alien-type-method (boolean :deport-gen) (type value)
 594   (declare (ignore type))
 595   `(if ,value 1 0))
 596 \f
 597 ;;;; the ENUM type
 598
 599 (define-alien-type-class (enum :include (integer (bits 32))
 600                                :include-args (signed))
 601   name          ; name of this enum (if any)
 602   from          ; alist from keywords to integers
 603   to            ; alist or vector from integers to keywords
 604   kind          ; kind of from mapping, :VECTOR or :ALIST
 605   offset)       ; offset to add to value for :VECTOR from mapping
 606
 607 (define-alien-type-translator enum (&whole
 608                                  type name
 609                                  &rest mappings
 610                                  &environment env)
 611   (cond (mappings
 612          (let ((result (parse-enum name mappings)))
 613            (when name
 614              (multiple-value-bind (old old-p)
 615                  (auxiliary-alien-type :enum name env)
 616                (when old-p
 617                  (unless (alien-type-= result old)
 618                    (warn "redefining alien enum ~S" name))))
 619              (setf (auxiliary-alien-type :enum name env) result))
 620            result))
 621         (name
 622          (multiple-value-bind (result found)
 623              (auxiliary-alien-type :enum name env)
 624            (unless found
 625              (error "unknown enum type: ~S" name))
 626            result))
 627         (t
 628          (error "empty enum type: ~S" type))))
 629
 630 (defun parse-enum (name elements)
 631   (when (null elements)
 632     (error "An enumeration must contain at least one element."))
 633   (let ((min nil)
 634         (max nil)
 635         (from-alist ())
 636         (prev -1))
 637     (declare (list from-alist))
 638     (dolist (el elements)
 639       (multiple-value-bind (sym val)
 640           (if (listp el)
 641               (values (first el) (second el))
 642               (values el (1+ prev)))
 643         (setf prev val)
 644         (unless (keywordp sym)
 645           (error "The enumeration element ~S is not a keyword." sym))
 646         (unless (integerp val)
 647           (error "The element value ~S is not an integer." val))
 648         (unless (and max (> max val)) (setq max val))
 649         (unless (and min (< min val)) (setq min val))
 650         (when (rassoc val from-alist)
 651           (error "The element value ~S is used more than once." val))
 652         (when (assoc sym from-alist :test #'eq)
 653           (error "The enumeration element ~S is used more than once." sym))
 654         (push (cons sym val) from-alist)))
 655     (let* ((signed (minusp min))
 656            (min-bits (if signed
 657                          (1+ (max (integer-length min)
 658                                   (integer-length max)))
 659                          (integer-length max))))
 660       (when (> min-bits 32)
 661         (error "can't represent enums needing more than 32 bits"))
 662       (setf from-alist (sort from-alist #'< :key #'cdr))
 663       (cond
 664        ;; If range is at least 20% dense, use vector mapping. Crossover
 665        ;; point solely on basis of space would be 25%. Vector mapping
 666        ;; is always faster, so give the benefit of the doubt.
 667        ((< 0.2 (/ (float (length from-alist)) (float (- max min))))
 668         ;; If offset is small and ignorable, ignore it to save time.
 669         (when (< 0 min 10) (setq min 0))
 670         (let ((to (make-array (1+ (- max min)))))
 671           (dolist (el from-alist)
 672             (setf (svref to (- (cdr el) min)) (car el)))
 673           (make-alien-enum-type :name name :signed signed
 674                                 :from from-alist :to to :kind
 675                                 :vector :offset (- min))))
 676        (t
 677         (make-alien-enum-type :name name :signed signed
 678                               :from from-alist
 679                               :to (mapcar (lambda (x) (cons (cdr x) (car x)))
 680                                           from-alist)
 681                               :kind :alist))))))
 682
 683 (define-alien-type-method (enum :unparse) (type)
 684   `(enum ,(alien-enum-type-name type)
 685          ,@(let ((prev -1))
 686              (mapcar (lambda (mapping)
 687                        (let ((sym (car mapping))
 688                              (value (cdr mapping)))
 689                          (prog1
 690                              (if (= (1+ prev) value)
 691                                  sym
 692                                  `(,sym ,value))
 693                            (setf prev value))))
 694                      (alien-enum-type-from type)))))
 695
 696 (define-alien-type-method (enum :type=) (type1 type2)
 697   (and (eq (alien-enum-type-name type1)
 698            (alien-enum-type-name type2))
 699        (equal (alien-enum-type-from type1)
 700               (alien-enum-type-from type2))))
 701
 702 (define-alien-type-method (enum :lisp-rep) (type)
 703   `(member ,@(mapcar #'car (alien-enum-type-from type))))
 704
 705 (define-alien-type-method (enum :naturalize-gen) (type alien)
 706   (ecase (alien-enum-type-kind type)
 707     (:vector
 708      `(svref ',(alien-enum-type-to type)
 709              (+ ,alien ,(alien-enum-type-offset type))))
 710     (:alist
 711      `(ecase ,alien
 712         ,@(mapcar (lambda (mapping)
 713                     `(,(car mapping) ,(cdr mapping)))
 714                   (alien-enum-type-to type))))))
 715
 716 (define-alien-type-method (enum :deport-gen) (type value)
 717   `(ecase ,value
 718      ,@(mapcar (lambda (mapping)
 719                  `(,(car mapping) ,(cdr mapping)))
 720                (alien-enum-type-from type))))
 721 \f
 722 ;;;; the FLOAT types
 723
 724 (define-alien-type-class (float)
 725   (type (missing-arg) :type symbol))
 726
 727 (define-alien-type-method (float :unparse) (type)
 728   (alien-float-type-type type))
 729
 730 (define-alien-type-method (float :lisp-rep) (type)
 731   (alien-float-type-type type))
 732
 733 (define-alien-type-method (float :alien-rep) (type)
 734   (alien-float-type-type type))
 735
 736 (define-alien-type-method (float :naturalize-gen) (type alien)
 737   (declare (ignore type))
 738   alien)
 739
 740 (define-alien-type-method (float :deport-gen) (type value)
 741   (declare (ignore type))
 742   value)
 743
 744 (define-alien-type-class (single-float :include (float (bits 32))
 745                                        :include-args (type)))
 746
 747 (define-alien-type-translator single-float ()
 748   (make-alien-single-float-type :type 'single-float))
 749
 750 (define-alien-type-method (single-float :extract-gen) (type sap offset)
 751   (declare (ignore type))
 752   `(sap-ref-single ,sap (/ ,offset sb!vm:n-byte-bits)))
 753
 754 (define-alien-type-class (double-float :include (float (bits 64))
 755                                        :include-args (type)))
 756
 757 (define-alien-type-translator double-float ()
 758   (make-alien-double-float-type :type 'double-float))
 759
 760 (define-alien-type-method (double-float :extract-gen) (type sap offset)
 761   (declare (ignore type))
 762   `(sap-ref-double ,sap (/ ,offset sb!vm:n-byte-bits)))
 763
 764 #!+long-float
 765 (define-alien-type-class (long-float :include (float (bits #!+x86 96
 766                                                            #!+sparc 128))
 767                                      :include-args (type)))
 768
 769 #!+long-float
 770 (define-alien-type-translator long-float ()
 771   (make-alien-long-float-type :type 'long-float))
 772
 773 #!+long-float
 774 (define-alien-type-method (long-float :extract-gen) (type sap offset)
 775   (declare (ignore type))
 776   `(sap-ref-long ,sap (/ ,offset sb!vm:n-byte-bits)))
 777 \f
 778 ;;;; the POINTER type
 779
 780 (define-alien-type-class (pointer :include (alien-value (bits
 781                                                          #!-alpha
 782                                                          sb!vm:n-word-bits
 783                                                          #!+alpha 64)))
 784   (to nil :type (or alien-type null)))
 785
 786 (define-alien-type-translator * (to &environment env)
 787   (make-alien-pointer-type :to (if (eq to t) nil (parse-alien-type to env))))
 788
 789 (define-alien-type-method (pointer :unparse) (type)
 790   (let ((to (alien-pointer-type-to type)))
 791     `(* ,(if to
 792              (%unparse-alien-type to)
 793              t))))
 794
 795 (define-alien-type-method (pointer :type=) (type1 type2)
 796   (let ((to1 (alien-pointer-type-to type1))
 797         (to2 (alien-pointer-type-to type2)))
 798     (if to1
 799         (if to2
 800             (alien-type-= to1 to2)
 801             nil)
 802         (null to2))))
 803
 804 (define-alien-type-method (pointer :subtypep) (type1 type2)
 805   (and (alien-pointer-type-p type2)
 806        (let ((to1 (alien-pointer-type-to type1))
 807              (to2 (alien-pointer-type-to type2)))
 808          (if to1
 809              (if to2
 810                  (alien-subtype-p to1 to2)
 811                  t)
 812              (null to2)))))
 813
 814 (define-alien-type-method (pointer :deport-gen) (type value)
 815   (/noshow "doing alien type method POINTER :DEPORT-GEN" type value)
 816   (values
 817    ;; FIXME: old version, highlighted a bug in xc optimization
 818    `(etypecase ,value
 819       (null
 820        (int-sap 0))
 821       (system-area-pointer
 822        ,value)
 823       ((alien ,type)
 824        (alien-sap ,value)))
 825    ;; new version, works around bug in xc optimization
 826    #+nil
 827    `(etypecase ,value
 828       (system-area-pointer
 829        ,value)
 830       ((alien ,type)
 831        (alien-sap ,value))
 832       (null
 833        (int-sap 0)))
 834    `(or null system-area-pointer (alien ,type))))
 835 \f
 836 ;;;; the MEM-BLOCK type
 837
 838 (define-alien-type-class (mem-block :include alien-value))
 839
 840 (define-alien-type-method (mem-block :extract-gen) (type sap offset)
 841   (declare (ignore type))
 842   `(sap+ ,sap (/ ,offset sb!vm:n-byte-bits)))
 843
 844 (define-alien-type-method (mem-block :deposit-gen) (type sap offset value)
 845   (let ((bits (alien-mem-block-type-bits type)))
 846     (unless bits
 847       (error "can't deposit aliens of type ~S (unknown size)" type))
 848     `(sb!kernel:system-area-copy ,value 0 ,sap ,offset ',bits)))
 849 \f
 850 ;;;; the ARRAY type
 851
 852 (define-alien-type-class (array :include mem-block)
 853   (element-type (missing-arg) :type alien-type)
 854   (dimensions (missing-arg) :type list))
 855
 856 (define-alien-type-translator array (ele-type &rest dims &environment env)
 857
 858   (when dims
 859     (unless (typep (first dims) '(or index null))
 860       (error "The first dimension is not a non-negative fixnum or NIL: ~S"
 861              (first dims)))
 862     (let ((loser (find-if-not (lambda (x) (typep x 'index))
 863                               (rest dims))))
 864       (when loser
 865         (error "A dimension is not a non-negative fixnum: ~S" loser))))
 866
 867   (let ((parsed-ele-type (parse-alien-type ele-type env)))
 868     (make-alien-array-type
 869      :element-type parsed-ele-type
 870      :dimensions dims
 871      :alignment (alien-type-alignment parsed-ele-type)
 872      :bits (if (and (alien-type-bits parsed-ele-type)
 873                     (every #'integerp dims))
 874                (* (align-offset (alien-type-bits parsed-ele-type)
 875                                 (alien-type-alignment parsed-ele-type))
 876                   (reduce #'* dims))))))
 877
 878 (define-alien-type-method (array :unparse) (type)
 879   `(array ,(%unparse-alien-type (alien-array-type-element-type type))
 880           ,@(alien-array-type-dimensions type)))
 881
 882 (define-alien-type-method (array :type=) (type1 type2)
 883   (and (equal (alien-array-type-dimensions type1)
 884               (alien-array-type-dimensions type2))
 885        (alien-type-= (alien-array-type-element-type type1)
 886                      (alien-array-type-element-type type2))))
 887
 888 (define-alien-type-method (array :subtypep) (type1 type2)
 889   (and (alien-array-type-p type2)
 890        (let ((dim1 (alien-array-type-dimensions type1))
 891              (dim2 (alien-array-type-dimensions type2)))
 892          (and (= (length dim1) (length dim2))
 893               (or (and dim2
 894                        (null (car dim2))
 895                        (equal (cdr dim1) (cdr dim2)))
 896                   (equal dim1 dim2))
 897               (alien-subtype-p (alien-array-type-element-type type1)
 898                                (alien-array-type-element-type type2))))))
 899 \f
 900 ;;;; the RECORD type
 901
 902 (def!struct (alien-record-field
 903              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 904   (name (missing-arg) :type symbol)
 905   (type (missing-arg) :type alien-type)
 906   (bits nil :type (or unsigned-byte null))
 907   (offset 0 :type unsigned-byte))
 908 (def!method print-object ((field alien-record-field) stream)
 909   (print-unreadable-object (field stream :type t)
 910     (format stream
 911             "~S ~S~@[:~D~]"
 912             (alien-record-field-type field)
 913             (alien-record-field-name field)
 914             (alien-record-field-bits field))))
 915
 916 (define-alien-type-class (record :include mem-block)
 917   (kind :struct :type (member :struct :union))
 918   (name nil :type (or symbol null))
 919   (fields nil :type list))
 920
 921 (define-alien-type-translator struct (name &rest fields &environment env)
 922   (parse-alien-record-type :struct name fields env))
 923
 924 (define-alien-type-translator union (name &rest fields &environment env)
 925   (parse-alien-record-type :union name fields env))
 926
 927 (defun parse-alien-record-type (kind name fields env)
 928   (declare (type (or sb!kernel:lexenv null) env))
 929   (cond (fields
 930          (let* ((old (and name (auxiliary-alien-type kind name env)))
 931                 (old-fields (and old (alien-record-type-fields old))))
 932            (cond (old-fields
 933                   ;; KLUDGE: We can't easily compare the new fields
 934                   ;; against the old fields, since the old fields have
 935                   ;; already been parsed into an internal
 936                   ;; representation, so we just punt, assuming that
 937                   ;; they're consistent. -- WHN 200000505
 938                   #|
 939                   (unless (equal fields old-fields)
 940                     ;; FIXME: Perhaps this should be a warning, and we
 941                     ;; should overwrite the old definition and proceed?
 942                     (error "mismatch in fields for ~S~%  old ~S~%  new ~S"
 943                            name old-fields fields))
 944                   |#
 945                   old)
 946                  (t
 947                   (let ((new (make-alien-record-type :name name
 948                                                      :kind kind)))
 949                     (when name
 950                       (setf (auxiliary-alien-type kind name env) new))
 951                     (parse-alien-record-fields new fields env)
 952                     new)))))
 953         (name
 954          (or (auxiliary-alien-type kind name env)
 955              (setf (auxiliary-alien-type kind name env)
 956                    (make-alien-record-type :name name :kind kind))))
 957         (t
 958          (make-alien-record-type :kind kind))))
 959
 960 ;;; This is used by PARSE-ALIEN-TYPE to parse the fields of struct and
 961 ;;; union types. RESULT holds the record type we are paring the fields
 962 ;;; of, and FIELDS is the list of field specifications.
 963 (defun parse-alien-record-fields (result fields env)
 964   (declare (type alien-record-type result)
 965            (type list fields))
 966   (let ((total-bits 0)
 967         (overall-alignment 1)
 968         (parsed-fields nil))
 969     (dolist (field fields)
 970       (destructuring-bind (var type &optional bits) field
 971         (declare (ignore bits))
 972         (let* ((field-type (parse-alien-type type env))
 973                (bits (alien-type-bits field-type))
 974                (alignment (alien-type-alignment field-type))
 975                (parsed-field
 976                 (make-alien-record-field :type field-type
 977                                          :name var)))
 978           (push parsed-field parsed-fields)
 979           (when (null bits)
 980             (error "unknown size: ~S" (unparse-alien-type field-type)))
 981           (when (null alignment)
 982             (error "unknown alignment: ~S" (unparse-alien-type field-type)))
 983           (setf overall-alignment (max overall-alignment alignment))
 984           (ecase (alien-record-type-kind result)
 985             (:struct
 986              (let ((offset (align-offset total-bits alignment)))
 987                (setf (alien-record-field-offset parsed-field) offset)
 988                (setf total-bits (+ offset bits))))
 989             (:union
 990              (setf total-bits (max total-bits bits)))))))
 991     (let ((new (nreverse parsed-fields)))
 992       (setf (alien-record-type-fields result) new))
 993     (setf (alien-record-type-alignment result) overall-alignment)
 994     (setf (alien-record-type-bits result)
 995           (align-offset total-bits overall-alignment))))
 996
 997 (define-alien-type-method (record :unparse) (type)
 998   `(,(case (alien-record-type-kind type)
 999        (:struct 'struct)
1000        (:union 'union)
1001        (t '???))
1002     ,(alien-record-type-name type)
1003     ,@(unless (member type *record-types-already-unparsed* :test #'eq)
1004         (push type *record-types-already-unparsed*)
1005         (mapcar (lambda (field)
1006                   `(,(alien-record-field-name field)
1007                     ,(%unparse-alien-type (alien-record-field-type field))
1008                     ,@(if (alien-record-field-bits field)
1009                           (list (alien-record-field-bits field)))))
1010                 (alien-record-type-fields type)))))
1011
1012 ;;; Test the record fields. The depth is limiting in case of cyclic
1013 ;;; pointers.
1014 (defun record-fields-match (fields1 fields2 depth)
1015   (declare (type list fields1 fields2)
1016            (type (mod 64) depth))
1017   (labels ((record-type-= (type1 type2 depth)
1018              (and (eq (alien-record-type-name type1)
1019                       (alien-record-type-name type2))
1020                   (eq (alien-record-type-kind type1)
1021                       (alien-record-type-kind type2))
1022                   (= (length (alien-record-type-fields type1))
1023                      (length (alien-record-type-fields type2)))
1024                   (record-fields-match (alien-record-type-fields type1)
1025                                        (alien-record-type-fields type2)
1026                                        (1+ depth))))
1027            (pointer-type-= (type1 type2 depth)
1028              (let ((to1 (alien-pointer-type-to type1))
1029                    (to2 (alien-pointer-type-to type2)))
1030                (if to1
1031                    (if to2
1032                        (type-= to1 to2 (1+ depth))
1033                        nil)
1034                    (null to2))))
1035            (type-= (type1 type2 depth)
1036              (cond ((and (alien-pointer-type-p type1)
1037                          (alien-pointer-type-p type2))
1038                     (or (> depth 10)
1039                         (pointer-type-= type1 type2 depth)))
1040                    ((and (alien-record-type-p type1)
1041                          (alien-record-type-p type2))
1042                     (record-type-= type1 type2 depth))
1043                    (t
1044                     (alien-type-= type1 type2)))))
1045     (do ((fields1-rem fields1 (rest fields1-rem))
1046          (fields2-rem fields2 (rest fields2-rem)))
1047         ((or (eq fields1-rem fields2-rem)
1048              (endp fields1-rem) (endp fields2-rem))
1049          (eq fields1-rem fields2-rem))
1050       (let ((field1 (first fields1-rem))
1051             (field2 (first fields2-rem)))
1052         (declare (type alien-record-field field1 field2))
1053         (unless (and (eq (alien-record-field-name field1)
1054                          (alien-record-field-name field2))
1055                      (eql (alien-record-field-bits field1)
1056                           (alien-record-field-bits field2))
1057                      (eql (alien-record-field-offset field1)
1058                           (alien-record-field-offset field2))
1059                      (let ((field1 (alien-record-field-type field1))
1060                            (field2 (alien-record-field-type field2)))
1061                        (type-= field1 field2 (1+ depth))))
1062           (return nil))))))
1063
1064 (define-alien-type-method (record :type=) (type1 type2)
1065   (and (eq (alien-record-type-name type1)
1066            (alien-record-type-name type2))
1067        (eq (alien-record-type-kind type1)
1068            (alien-record-type-kind type2))
1069        (= (length (alien-record-type-fields type1))
1070           (length (alien-record-type-fields type2)))
1071        (record-fields-match (alien-record-type-fields type1)
1072                             (alien-record-type-fields type2) 0)))
1073 \f
1074 ;;;; the FUNCTION and VALUES alien types
1075
1076 ;;; not documented in CMU CL:-(
1077 ;;;
1078 ;;; reverse engineering observations:
1079 ;;;   * seems to be set when translating return values
1080 ;;;   * seems to enable the translation of (VALUES), which is the
1081 ;;;     Lisp idiom for C's return type "void" (which is likely
1082 ;;;     why it's set when when translating return values)
1083 (defvar *values-type-okay* nil)
1084
1085 (define-alien-type-class (fun :include mem-block)
1086   (result-type (missing-arg) :type alien-type)
1087   (arg-types (missing-arg) :type list)
1088   (stub nil :type (or null function)))
1089
1090 (define-alien-type-translator function (result-type &rest arg-types
1091                                                     &environment env)
1092   (make-alien-fun-type
1093    :result-type (let ((*values-type-okay* t))
1094                   (parse-alien-type result-type env))
1095    :arg-types (mapcar (lambda (arg-type) (parse-alien-type arg-type env))
1096                       arg-types)))
1097
1098 (define-alien-type-method (fun :unparse) (type)
1099   `(function ,(%unparse-alien-type (alien-fun-type-result-type type))
1100              ,@(mapcar #'%unparse-alien-type
1101                        (alien-fun-type-arg-types type))))
1102
1103 (define-alien-type-method (fun :type=) (type1 type2)
1104   (and (alien-type-= (alien-fun-type-result-type type1)
1105                      (alien-fun-type-result-type type2))
1106        (= (length (alien-fun-type-arg-types type1))
1107           (length (alien-fun-type-arg-types type2)))
1108        (every #'alien-type-=
1109               (alien-fun-type-arg-types type1)
1110               (alien-fun-type-arg-types type2))))
1111
1112 (define-alien-type-class (values)
1113   (values (missing-arg) :type list))
1114
1115 (define-alien-type-translator values (&rest values &environment env)
1116   (unless *values-type-okay*
1117     (error "cannot use values types here"))
1118   (let ((*values-type-okay* nil))
1119     (make-alien-values-type
1120      :values (mapcar (lambda (alien-type) (parse-alien-type alien-type env))
1121                      values))))
1122
1123 (define-alien-type-method (values :unparse) (type)
1124   `(values ,@(mapcar #'%unparse-alien-type
1125                      (alien-values-type-values type))))
1126
1127 (define-alien-type-method (values :type=) (type1 type2)
1128   (and (= (length (alien-values-type-values type1))
1129           (length (alien-values-type-values type2)))
1130        (every #'alien-type-=
1131               (alien-values-type-values type1)
1132               (alien-values-type-values type2))))
1133 \f
1134 ;;;; a structure definition needed both in the target and in the
1135 ;;;; cross-compilation host
1136
1137 ;;; information about local aliens. The WITH-ALIEN macro builds one of
1138 ;;; these structures and LOCAL-ALIEN and friends communicate
1139 ;;; information about how that local alien is represented.
1140 (def!struct (local-alien-info
1141              (:make-load-form-fun sb!kernel:just-dump-it-normally)
1142              (:constructor make-local-alien-info
1143                            (&key type force-to-memory-p
1144                             &aux (force-to-memory-p (or force-to-memory-p
1145                                                         (alien-array-type-p type)
1146                                                         (alien-record-type-p type))))))
1147   ;; the type of the local alien
1148   (type (missing-arg) :type alien-type)
1149   ;; Must this local alien be forced into memory? Using the ADDR macro
1150   ;; on a local alien will set this.
1151   (force-to-memory-p nil :type (member t nil)))
1152 (def!method print-object ((info local-alien-info) stream)
1153   (print-unreadable-object (info stream :type t)
1154     (format stream
1155             "~:[~;(forced to stack) ~]~S"
1156             (local-alien-info-force-to-memory-p info)
1157             (unparse-alien-type (local-alien-info-type info)))))
1158 \f
1159 ;;;; the ADDR macro
1160
1161 (defmacro-mundanely addr (expr &environment env)
1162   #!+sb-doc
1163   "Return an Alien pointer to the data addressed by Expr, which must be a call
1164    to SLOT or DEREF, or a reference to an Alien variable."
1165   (let ((form (sb!xc:macroexpand expr env)))
1166     (or (typecase form
1167           (cons
1168            (case (car form)
1169              (slot
1170               (cons '%slot-addr (cdr form)))
1171              (deref
1172               (cons '%deref-addr (cdr form)))
1173              (%heap-alien
1174               (cons '%heap-alien-addr (cdr form)))
1175              (local-alien
1176               (let ((info (let ((info-arg (second form)))
1177                             (and (consp info-arg)
1178                                  (eq (car info-arg) 'quote)
1179                                  (second info-arg)))))
1180                 (unless (local-alien-info-p info)
1181                   (error "Something is wrong, LOCAL-ALIEN-INFO not found: ~S"
1182                          form))
1183                 (setf (local-alien-info-force-to-memory-p info) t))
1184               (cons '%local-alien-addr (cdr form)))))
1185           (symbol
1186            (let ((kind (info :variable :kind form)))
1187              (when (eq kind :alien)
1188                `(%heap-alien-addr ',(info :variable :alien-info form))))))
1189         (error "~S is not a valid L-value." form))))
1190
1191 (/show0 "host-alieneval.lisp end of file")