src/code/host-alieneval.lisp

   1 ;;;; the part of the Alien implementation which is needed at
   2 ;;;; cross-compilation time
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "host-alieneval.lisp 15")
  16 \f
  17 ;;;; utility functions
  18
  19 (defun align-offset (offset alignment)
  20   (let ((extra (rem offset alignment)))
  21     (if (zerop extra) offset (+ offset (- alignment extra)))))
  22
  23 (defun guess-alignment (bits)
  24   (cond ((null bits) nil)
  25         #!-(or (and x86 (not win32)) (and ppc darwin)) ((> bits 32) 64)
  26         ((> bits 16) 32)
  27         ((> bits 8) 16)
  28         ((> bits 1) 8)
  29         (t 1)))
  30 \f
  31 ;;;; ALIEN-TYPE-INFO stuff
  32
  33 (eval-when (#-sb-xc :compile-toplevel :execute :load-toplevel)
  34
  35 (defstruct (alien-type-class (:copier nil))
  36   (name nil :type symbol)
  37   (include nil :type (or null alien-type-class))
  38   (unparse nil :type (or null function))
  39   (type= nil :type (or null function))
  40   (lisp-rep nil :type (or null function))
  41   (alien-rep nil :type (or null function))
  42   (extract-gen nil :type (or null function))
  43   (deposit-gen nil :type (or null function))
  44   (naturalize-gen nil :type (or null function))
  45   (deport-gen nil :type (or null function))
  46   (deport-alloc-gen nil :type (or null function))
  47   (deport-pin-p nil :type (or null function))
  48   ;; Cast?
  49   (arg-tn nil :type (or null function))
  50   (result-tn nil :type (or null function))
  51   (subtypep nil :type (or null function)))
  52 (def!method print-object ((type-class alien-type-class) stream)
  53   (print-unreadable-object (type-class stream :type t)
  54     (prin1 (alien-type-class-name type-class) stream)))
  55
  56 (defun alien-type-class-or-lose (name)
  57   (or (gethash name *alien-type-classes*)
  58       (error "no alien type class ~S" name)))
  59
  60 (defun create-alien-type-class-if-necessary (name include)
  61   (let ((old (gethash name *alien-type-classes*))
  62         (include (and include (alien-type-class-or-lose include))))
  63     (if old
  64         (setf (alien-type-class-include old) include)
  65         (setf (gethash name *alien-type-classes*)
  66               (make-alien-type-class :name name :include include)))))
  67
  68 (defparameter *method-slot-alist*
  69   '((:unparse . alien-type-class-unparse)
  70     (:type= . alien-type-class-type=)
  71     (:subtypep . alien-type-class-subtypep)
  72     (:lisp-rep . alien-type-class-lisp-rep)
  73     (:alien-rep . alien-type-class-alien-rep)
  74     (:extract-gen . alien-type-class-extract-gen)
  75     (:deposit-gen . alien-type-class-deposit-gen)
  76     (:naturalize-gen . alien-type-class-naturalize-gen)
  77     (:deport-gen . alien-type-class-deport-gen)
  78     (:deport-alloc-gen . alien-type-class-deport-alloc-gen)
  79     (:deport-pin-p . alien-type-class-deport-pin-p)
  80     ;; cast?
  81     (:arg-tn . alien-type-class-arg-tn)
  82     (:result-tn . alien-type-class-result-tn)))
  83
  84 (defun method-slot (method)
  85   (cdr (or (assoc method *method-slot-alist*)
  86            (error "no method ~S" method))))
  87
  88 ) ; EVAL-WHEN
  89
  90 ;;; We define a keyword "BOA" constructor so that we can reference the
  91 ;;; slot names in init forms.
  92 (def!macro define-alien-type-class ((name &key include include-args)
  93                                     &rest slots)
  94   (let ((defstruct-name (symbolicate "ALIEN-" name "-TYPE")))
  95     (multiple-value-bind (include include-defstruct overrides)
  96         (etypecase include
  97           (null
  98            (values nil 'alien-type nil))
  99           (symbol
 100            (values
 101             include
 102             (symbolicate "ALIEN-" include "-TYPE")
 103             nil))
 104           (list
 105            (values
 106             (car include)
 107             (symbolicate "ALIEN-" (car include) "-TYPE")
 108             (cdr include))))
 109       `(progn
 110          (eval-when (:compile-toplevel :load-toplevel :execute)
 111            (create-alien-type-class-if-necessary ',name ',(or include 'root)))
 112          (def!struct (,defstruct-name
 113                         (:include ,include-defstruct
 114                                   (class ',name)
 115                                   ,@overrides)
 116                         (:constructor
 117                          ,(symbolicate "MAKE-" defstruct-name)
 118                          (&key class bits alignment
 119                                ,@(mapcar (lambda (x)
 120                                            (if (atom x) x (car x)))
 121                                          slots)
 122                                ,@include-args
 123                                ;; KLUDGE
 124                                &aux (alignment (or alignment (guess-alignment bits))))))
 125            ,@slots)))))
 126
 127 (def!macro define-alien-type-method ((class method) lambda-list &rest body)
 128   (let ((defun-name (symbolicate class "-" method "-METHOD")))
 129     `(progn
 130        (defun ,defun-name ,lambda-list
 131          ,@body)
 132        (setf (,(method-slot method) (alien-type-class-or-lose ',class))
 133              #',defun-name))))
 134
 135 (def!macro invoke-alien-type-method (method type &rest args)
 136   (let ((slot (method-slot method)))
 137     (once-only ((type type))
 138       `(funcall (do ((class (alien-type-class-or-lose (alien-type-class ,type))
 139                             (alien-type-class-include class)))
 140                     ((null class)
 141                      (error "method ~S not defined for ~S"
 142                             ',method (alien-type-class ,type)))
 143                   (let ((fn (,slot class)))
 144                     (when fn
 145                       (return fn))))
 146                 ,type ,@args))))
 147 \f
 148 ;;;; type parsing and unparsing
 149
 150 ;;; CMU CL used COMPILER-LET to bind *AUXILIARY-TYPE-DEFINITIONS*, and
 151 ;;; COMPILER-LET is no longer supported by ANSI or SBCL. Instead, we
 152 ;;; follow the suggestion in CLTL2 of using SYMBOL-MACROLET to achieve
 153 ;;; a similar effect.
 154 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 155   (defun auxiliary-type-definitions (env)
 156     (multiple-value-bind (result expanded-p)
 157         (sb!xc:macroexpand '&auxiliary-type-definitions& env)
 158       (if expanded-p
 159           result
 160           ;; This is like having the global symbol-macro definition be
 161           ;; NIL, but global symbol-macros make me vaguely queasy, so
 162           ;; I do it this way instead.
 163           nil))))
 164
 165 ;;; Process stuff in a new scope.
 166 (def!macro with-auxiliary-alien-types (env &body body)
 167   ``(symbol-macrolet ((&auxiliary-type-definitions&
 168                        ,(append *new-auxiliary-types*
 169                                 (auxiliary-type-definitions ,env))))
 170       ,(let ((*new-auxiliary-types* nil))
 171          ,@body)))
 172
 173 ;;; Parse TYPE as an alien type specifier and return the resultant
 174 ;;; ALIEN-TYPE structure.
 175 (defun parse-alien-type (type env)
 176   (declare (type (or sb!kernel:lexenv null) env))
 177   (if (consp type)
 178       (let ((translator (info :alien-type :translator (car type))))
 179         (unless translator
 180           (error "unknown alien type: ~S" type))
 181         (funcall translator type env))
 182       (ecase (info :alien-type :kind type)
 183         (:primitive
 184          (let ((translator (info :alien-type :translator type)))
 185            (unless translator
 186              (error "no translator for primitive alien type ~S" type))
 187            (funcall translator (list type) env)))
 188         (:defined
 189          (or (info :alien-type :definition type)
 190              (error "no definition for alien type ~S" type)))
 191         (:unknown
 192          (error "unknown alien type: ~S" type)))))
 193
 194 (defun auxiliary-alien-type (kind name env)
 195   (declare (type (or sb!kernel:lexenv null) env))
 196   (flet ((aux-defn-matches (x)
 197            (and (eq (first x) kind) (eq (second x) name))))
 198     (let ((in-auxiliaries
 199            (or (find-if #'aux-defn-matches *new-auxiliary-types*)
 200                (find-if #'aux-defn-matches (auxiliary-type-definitions env)))))
 201       (if in-auxiliaries
 202           (values (third in-auxiliaries) t)
 203           (ecase kind
 204             (:struct
 205              (info :alien-type :struct name))
 206             (:union
 207              (info :alien-type :union name))
 208             (:enum
 209              (info :alien-type :enum name)))))))
 210
 211 (defun (setf auxiliary-alien-type) (new-value kind name env)
 212   (declare (type (or sb!kernel:lexenv null) env))
 213   (flet ((aux-defn-matches (x)
 214            (and (eq (first x) kind) (eq (second x) name))))
 215     (when (find-if #'aux-defn-matches *new-auxiliary-types*)
 216       (error "attempt to multiply define ~A ~S" kind name))
 217     (when (find-if #'aux-defn-matches (auxiliary-type-definitions env))
 218       (error "attempt to shadow definition of ~A ~S" kind name)))
 219   (push (list kind name new-value) *new-auxiliary-types*)
 220   new-value)
 221
 222 (defun verify-local-auxiliaries-okay ()
 223   (dolist (info *new-auxiliary-types*)
 224     (destructuring-bind (kind name defn) info
 225       (declare (ignore defn))
 226       (when (ecase kind
 227               (:struct
 228                (info :alien-type :struct name))
 229               (:union
 230                (info :alien-type :union name))
 231               (:enum
 232                (info :alien-type :enum name)))
 233         (error "attempt to shadow definition of ~A ~S" kind name)))))
 234
 235 (defun unparse-alien-type (type)
 236   #!+sb-doc
 237   "Convert the alien-type structure TYPE back into a list specification of
 238    the type."
 239   (declare (type alien-type type))
 240   (let ((*record-types-already-unparsed* nil))
 241     (%unparse-alien-type type)))
 242
 243 ;;; Does all the work of UNPARSE-ALIEN-TYPE. It's separate because we
 244 ;;; need to recurse inside the binding of
 245 ;;; *RECORD-TYPES-ALREADY-UNPARSED*.
 246 (defun %unparse-alien-type (type)
 247   (invoke-alien-type-method :unparse type))
 248 \f
 249 ;;;; alien type defining stuff
 250
 251 (def!macro define-alien-type-translator (name lambda-list &body body)
 252   (with-unique-names (whole env)
 253     (let ((defun-name (symbolicate "ALIEN-" name "-TYPE-TRANSLATOR")))
 254       (multiple-value-bind (body decls docs)
 255           (sb!kernel:parse-defmacro lambda-list whole body name
 256                                     'define-alien-type-translator
 257                                     :environment env)
 258         `(eval-when (:compile-toplevel :load-toplevel :execute)
 259            (defun ,defun-name (,whole ,env)
 260              (declare (ignorable ,env))
 261              ,@decls
 262              (block ,name
 263                ,body))
 264            (%define-alien-type-translator ',name #',defun-name ,docs))))))
 265
 266 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 267   (defun %define-alien-type-translator (name translator docs)
 268     (declare (ignore docs))
 269     (setf (info :alien-type :kind name) :primitive)
 270     (setf (info :alien-type :translator name) translator)
 271     (clear-info :alien-type :definition name)
 272     #+nil
 273     (setf (fdocumentation name 'alien-type) docs)
 274     name))
 275
 276 (def!macro define-alien-type (name type &environment env)
 277   #!+sb-doc
 278   "Define the alien type NAME to be equivalent to TYPE. Name may be NIL for
 279    STRUCT and UNION types, in which case the name is taken from the type
 280    specifier."
 281   (with-auxiliary-alien-types env
 282     (let ((alien-type (parse-alien-type type env)))
 283       `(eval-when (:compile-toplevel :load-toplevel :execute)
 284          ,@(when *new-auxiliary-types*
 285              `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
 286          ,@(when name
 287              `((%define-alien-type ',name ',alien-type)))))))
 288
 289 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 290   (defun %def-auxiliary-alien-types (types)
 291     (dolist (info types)
 292       ;; Clear up the type we're about to define from the toplevel
 293       ;; *new-auxiliary-types* (local scopes take care of themselves).
 294       ;; Unless this is done we never actually get back the full type
 295       ;; from INFO, since the *new-auxiliary-types* have precendence.
 296       (setf *new-auxiliary-types*
 297             (remove info *new-auxiliary-types*
 298                     :test (lambda (a b)
 299                             (and (eq (first a) (first b))
 300                                  (eq (second a) (second b))))))
 301       (destructuring-bind (kind name defn) info
 302         (macrolet ((frob (kind)
 303                          `(let ((old (info :alien-type ,kind name)))
 304                             (unless (or (null old) (alien-type-= old defn))
 305                               (warn
 306                                "redefining ~A ~S to be:~%  ~S,~%was:~%  ~S"
 307                                kind name defn old))
 308                             (setf (info :alien-type ,kind name) defn))))
 309           (ecase kind
 310             (:struct (frob :struct))
 311             (:union (frob :union))
 312             (:enum (frob :enum)))))))
 313   (defun %define-alien-type (name new)
 314     (ecase (info :alien-type :kind name)
 315       (:primitive
 316        (error "~S is a built-in alien type." name))
 317       (:defined
 318        (let ((old (info :alien-type :definition name)))
 319          (unless (or (null old) (alien-type-= new old))
 320            (warn "redefining ~S to be:~%  ~S,~%was~%  ~S"
 321                  name
 322                  (unparse-alien-type new)
 323                  (unparse-alien-type old)))))
 324       (:unknown))
 325     (setf (info :alien-type :definition name) new)
 326     (setf (info :alien-type :kind name) :defined)
 327     name))
 328 \f
 329 ;;;; the root alien type
 330
 331 (eval-when (:compile-toplevel :load-toplevel :execute)
 332   (create-alien-type-class-if-necessary 'root nil))
 333
 334 (def!struct (alien-type
 335              (:make-load-form-fun sb!kernel:just-dump-it-normally)
 336              (:constructor make-alien-type (&key class bits alignment
 337                                             &aux (alignment (or alignment (guess-alignment bits))))))
 338   (class 'root :type symbol)
 339   (bits nil :type (or null unsigned-byte))
 340   (alignment nil :type (or null unsigned-byte)))
 341 (def!method print-object ((type alien-type) stream)
 342   (print-unreadable-object (type stream :type t)
 343     (prin1 (unparse-alien-type type) stream)))
 344 \f
 345 ;;;; the SAP type
 346
 347 (define-alien-type-class (system-area-pointer))
 348
 349 (define-alien-type-translator system-area-pointer ()
 350   (make-alien-system-area-pointer-type
 351    :bits #!-alpha sb!vm:n-word-bits #!+alpha 64))
 352
 353 (define-alien-type-method (system-area-pointer :unparse) (type)
 354   (declare (ignore type))
 355   'system-area-pointer)
 356
 357 (define-alien-type-method (system-area-pointer :lisp-rep) (type)
 358   (declare (ignore type))
 359   'system-area-pointer)
 360
 361 (define-alien-type-method (system-area-pointer :alien-rep) (type)
 362   (declare (ignore type))
 363   'system-area-pointer)
 364
 365 (define-alien-type-method (system-area-pointer :naturalize-gen) (type alien)
 366   (declare (ignore type))
 367   alien)
 368
 369 (define-alien-type-method (system-area-pointer :deport-gen) (type object)
 370   (declare (ignore type))
 371   (/noshow "doing alien type method SYSTEM-AREA-POINTER :DEPORT-GEN" object)
 372   object)
 373
 374 (define-alien-type-method (system-area-pointer :extract-gen) (type sap offset)
 375   (declare (ignore type))
 376   `(sap-ref-sap ,sap (/ ,offset sb!vm:n-byte-bits)))
 377 \f
 378 ;;;; the ALIEN-VALUE type
 379
 380 (define-alien-type-class (alien-value :include system-area-pointer))
 381
 382 (define-alien-type-method (alien-value :lisp-rep) (type)
 383   (declare (ignore type))
 384   nil)
 385
 386 (define-alien-type-method (alien-value :naturalize-gen) (type alien)
 387   `(%sap-alien ,alien ',type))
 388
 389 (define-alien-type-method (alien-value :deport-gen) (type value)
 390   (declare (ignore type))
 391   (/noshow "doing alien type method ALIEN-VALUE :DEPORT-GEN" value)
 392   `(alien-sap ,value))
 393 \f
 394 ;;; HEAP-ALIEN-INFO -- defstruct.
 395 ;;;
 396 ;;; Information describing a heap-allocated alien.
 397 (def!struct (heap-alien-info
 398              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 399   ;; The type of this alien.
 400   (type (missing-arg) :type alien-type)
 401   ;; The form to evaluate to produce the SAP pointing to where in the heap
 402   ;; it is.
 403   (sap-form (missing-arg)))
 404 (def!method print-object ((info heap-alien-info) stream)
 405   (print-unreadable-object (info stream :type t)
 406     (funcall (formatter "~S ~S")
 407              stream
 408              (heap-alien-info-sap-form info)
 409              (unparse-alien-type (heap-alien-info-type info)))))
 410 \f
 411 ;;;; Interfaces to the different methods
 412
 413 (defun alien-type-= (type1 type2)
 414   #!+sb-doc
 415   "Return T iff TYPE1 and TYPE2 describe equivalent alien types."
 416   (or (eq type1 type2)
 417       (and (eq (alien-type-class type1)
 418                (alien-type-class type2))
 419            (invoke-alien-type-method :type= type1 type2))))
 420
 421 (defun alien-subtype-p (type1 type2)
 422   #!+sb-doc
 423   "Return T iff the alien type TYPE1 is a subtype of TYPE2. Currently, the
 424    only supported subtype relationships are is that any pointer type is a
 425    subtype of (* t), and any array type first dimension will match
 426    (array <eltype> nil ...). Otherwise, the two types have to be
 427    ALIEN-TYPE-=."
 428   (or (eq type1 type2)
 429       (invoke-alien-type-method :subtypep type1 type2)))
 430
 431 (defun compute-naturalize-lambda (type)
 432   `(lambda (alien ignore)
 433      (declare (ignore ignore))
 434      ,(invoke-alien-type-method :naturalize-gen type 'alien)))
 435
 436 (defun compute-deport-lambda (type)
 437   (declare (type alien-type type))
 438   (/noshow "entering COMPUTE-DEPORT-LAMBDA" type)
 439   (multiple-value-bind (form value-type)
 440       (invoke-alien-type-method :deport-gen type 'value)
 441     `(lambda (value ignore)
 442        (declare (type ,(or value-type
 443                            (compute-lisp-rep-type type)
 444                            `(alien ,type))
 445                       value)
 446                 (ignore ignore))
 447        ,form)))
 448
 449 (defun compute-deport-alloc-lambda (type)
 450   `(lambda (value ignore)
 451      (declare (ignore ignore))
 452      ,(invoke-alien-type-method :deport-alloc-gen type 'value)))
 453
 454 (defun compute-extract-lambda (type)
 455   `(lambda (sap offset ignore)
 456      (declare (type system-area-pointer sap)
 457               (type unsigned-byte offset)
 458               (ignore ignore))
 459      (naturalize ,(invoke-alien-type-method :extract-gen type 'sap 'offset)
 460                  ',type)))
 461
 462 (def!macro maybe-with-pinned-objects (variables types &body body)
 463   (declare (ignorable variables types))
 464   (let ((pin-variables
 465          ;; Only pin things on x86/x86-64, since on non-conservative
 466          ;; gcs it'd imply disabling the GC. Which is something we
 467          ;; don't want to do every time we're calling to C.
 468          #!+(or x86 x86-64)
 469          (loop for variable in variables
 470             for type in types
 471             when (invoke-alien-type-method :deport-pin-p type)
 472             collect variable)))
 473     (if pin-variables
 474         `(with-pinned-objects ,pin-variables
 475            ,@body)
 476         `(progn
 477            ,@body))))
 478
 479 (defun compute-deposit-lambda (type)
 480   (declare (type alien-type type))
 481   `(lambda (sap offset ignore value)
 482      (declare (type system-area-pointer sap)
 483               (type unsigned-byte offset)
 484               (ignore ignore))
 485      (let ((alloc-tmp (deport-alloc value ',type)))
 486        (maybe-with-pinned-objects (alloc-tmp) (,type)
 487          (let ((value (deport alloc-tmp  ',type)))
 488            ,(invoke-alien-type-method :deposit-gen type 'sap 'offset 'value)
 489            ;; Note: the reason we don't just return the pre-deported value
 490            ;; is because that would inhibit any (deport (naturalize ...))
 491            ;; optimizations that might have otherwise happen. Re-naturalizing
 492            ;; the value might cause extra consing, but is flushable, so probably
 493            ;; results in better code.
 494            (naturalize value ',type))))))
 495
 496 (defun compute-lisp-rep-type (type)
 497   (invoke-alien-type-method :lisp-rep type))
 498
 499 (defun compute-alien-rep-type (type)
 500   (invoke-alien-type-method :alien-rep type))
 501 \f
 502 ;;;; default methods
 503
 504 (define-alien-type-method (root :unparse) (type)
 505   `(<unknown-alien-type> ,(type-of type)))
 506
 507 (define-alien-type-method (root :type=) (type1 type2)
 508   (declare (ignore type1 type2))
 509   t)
 510
 511 (define-alien-type-method (root :subtypep) (type1 type2)
 512   (alien-type-= type1 type2))
 513
 514 (define-alien-type-method (root :lisp-rep) (type)
 515   (declare (ignore type))
 516   nil)
 517
 518 (define-alien-type-method (root :alien-rep) (type)
 519   (declare (ignore type))
 520   '*)
 521
 522 (define-alien-type-method (root :naturalize-gen) (type alien)
 523   (declare (ignore alien))
 524   (error "cannot represent ~S typed aliens" type))
 525
 526 (define-alien-type-method (root :deport-gen) (type object)
 527   (declare (ignore object))
 528   (error "cannot represent ~S typed aliens" type))
 529
 530 (define-alien-type-method (root :deport-alloc-gen) (type object)
 531   (declare (ignore type))
 532   object)
 533
 534 (define-alien-type-method (root :deport-pin-p) (type)
 535   (declare (ignore type))
 536   ;; Override this method to return T for classes which take a SAP to a
 537   ;; GCable lisp object when deporting.
 538   nil)
 539
 540 (define-alien-type-method (root :extract-gen) (type sap offset)
 541   (declare (ignore sap offset))
 542   (error "cannot represent ~S typed aliens" type))
 543
 544 (define-alien-type-method (root :deposit-gen) (type sap offset value)
 545   `(setf ,(invoke-alien-type-method :extract-gen type sap offset) ,value))
 546
 547 (define-alien-type-method (root :arg-tn) (type state)
 548   (declare (ignore state))
 549   (error "Aliens of type ~S cannot be passed as arguments to CALL-OUT."
 550          (unparse-alien-type type)))
 551
 552 (define-alien-type-method (root :result-tn) (type state)
 553   (declare (ignore state))
 554   (error "Aliens of type ~S cannot be returned from CALL-OUT."
 555          (unparse-alien-type type)))
 556 \f
 557 ;;;; the INTEGER type
 558
 559 (define-alien-type-class (integer)
 560   (signed t :type (member t nil)))
 561
 562 (define-alien-type-translator signed (&optional (bits sb!vm:n-word-bits))
 563   (make-alien-integer-type :bits bits))
 564
 565 (define-alien-type-translator integer (&optional (bits sb!vm:n-word-bits))
 566   (make-alien-integer-type :bits bits))
 567
 568 (define-alien-type-translator unsigned (&optional (bits sb!vm:n-word-bits))
 569   (make-alien-integer-type :bits bits :signed nil))
 570
 571 (define-alien-type-method (integer :unparse) (type)
 572   (list (if (alien-integer-type-signed type) 'signed 'unsigned)
 573         (alien-integer-type-bits type)))
 574
 575 (define-alien-type-method (integer :type=) (type1 type2)
 576   (and (eq (alien-integer-type-signed type1)
 577            (alien-integer-type-signed type2))
 578        (= (alien-integer-type-bits type1)
 579           (alien-integer-type-bits type2))))
 580
 581 (define-alien-type-method (integer :lisp-rep) (type)
 582   (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 583         (alien-integer-type-bits type)))
 584
 585 (define-alien-type-method (integer :alien-rep) (type)
 586   (list (if (alien-integer-type-signed type) 'signed-byte 'unsigned-byte)
 587         (alien-integer-type-bits type)))
 588
 589 (define-alien-type-method (integer :naturalize-gen) (type alien)
 590   (declare (ignore type))
 591   alien)
 592
 593 (define-alien-type-method (integer :deport-gen) (type value)
 594   (declare (ignore type))
 595   value)
 596
 597 (define-alien-type-method (integer :extract-gen) (type sap offset)
 598   (declare (type alien-integer-type type))
 599   (let ((ref-fun
 600          (if (alien-integer-type-signed type)
 601           (case (alien-integer-type-bits type)
 602             (8 'signed-sap-ref-8)
 603             (16 'signed-sap-ref-16)
 604             (32 'signed-sap-ref-32)
 605             (64 'signed-sap-ref-64))
 606           (case (alien-integer-type-bits type)
 607             (8 'sap-ref-8)
 608             (16 'sap-ref-16)
 609             (32 'sap-ref-32)
 610             (64 'sap-ref-64)))))
 611     (if ref-fun
 612         `(,ref-fun ,sap (/ ,offset sb!vm:n-byte-bits))
 613         (error "cannot extract ~W-bit integers"
 614                (alien-integer-type-bits type)))))
 615 \f
 616 ;;;; the BOOLEAN type
 617
 618 (define-alien-type-class (boolean :include integer :include-args (signed)))
 619
 620 ;;; FIXME: Check to make sure that we aren't attaching user-readable
 621 ;;; stuff to CL:BOOLEAN in any way which impairs ANSI compliance.
 622 (define-alien-type-translator boolean (&optional (bits sb!vm:n-word-bits))
 623   (make-alien-boolean-type :bits bits :signed nil))
 624
 625 (define-alien-type-method (boolean :unparse) (type)
 626   `(boolean ,(alien-boolean-type-bits type)))
 627
 628 (define-alien-type-method (boolean :lisp-rep) (type)
 629   (declare (ignore type))
 630   `(member t nil))
 631
 632 (define-alien-type-method (boolean :naturalize-gen) (type alien)
 633   (declare (ignore type))
 634   `(not (zerop ,alien)))
 635
 636 (define-alien-type-method (boolean :deport-gen) (type value)
 637   (declare (ignore type))
 638   `(if ,value 1 0))
 639 \f
 640 ;;;; the ENUM type
 641
 642 (define-alien-type-class (enum :include (integer (bits 32))
 643                                :include-args (signed))
 644   name          ; name of this enum (if any)
 645   from          ; alist from symbols to integers
 646   to            ; alist or vector from integers to symbols
 647   kind          ; kind of from mapping, :VECTOR or :ALIST
 648   offset)       ; offset to add to value for :VECTOR from mapping
 649
 650 (define-alien-type-translator enum (&whole
 651                                  type name
 652                                  &rest mappings
 653                                  &environment env)
 654   (cond (mappings
 655          (let ((result (parse-enum name mappings)))
 656            (when name
 657              (multiple-value-bind (old old-p)
 658                  (auxiliary-alien-type :enum name env)
 659                (when old-p
 660                  (unless (alien-type-= result old)
 661                    (warn "redefining alien enum ~S" name))))
 662              (setf (auxiliary-alien-type :enum name env) result))
 663            result))
 664         (name
 665          (multiple-value-bind (result found)
 666              (auxiliary-alien-type :enum name env)
 667            (unless found
 668              (error "unknown enum type: ~S" name))
 669            result))
 670         (t
 671          (error "empty enum type: ~S" type))))
 672
 673 (defun parse-enum (name elements)
 674   (when (null elements)
 675     (error "An enumeration must contain at least one element."))
 676   (let ((min nil)
 677         (max nil)
 678         (from-alist ())
 679         (prev -1))
 680     (declare (list from-alist))
 681     (dolist (el elements)
 682       (multiple-value-bind (sym val)
 683           (if (listp el)
 684               (values (first el) (second el))
 685               (values el (1+ prev)))
 686         (setf prev val)
 687         (unless (symbolp sym)
 688           (error "The enumeration element ~S is not a symbol." sym))
 689         (unless (integerp val)
 690           (error "The element value ~S is not an integer." val))
 691         (unless (and max (> max val)) (setq max val))
 692         (unless (and min (< min val)) (setq min val))
 693         (when (rassoc val from-alist)
 694           (style-warn "The element value ~S is used more than once." val))
 695         (when (assoc sym from-alist :test #'eq)
 696           (error "The enumeration element ~S is used more than once." sym))
 697         (push (cons sym val) from-alist)))
 698     (let* ((signed (minusp min))
 699            (min-bits (if signed
 700                          (1+ (max (integer-length min)
 701                                   (integer-length max)))
 702                          (integer-length max))))
 703       (when (> min-bits 32)
 704         (error "can't represent enums needing more than 32 bits"))
 705       (setf from-alist (sort from-alist #'< :key #'cdr))
 706       (cond
 707        ;; If range is at least 20% dense, use vector mapping. Crossover
 708        ;; point solely on basis of space would be 25%. Vector mapping
 709        ;; is always faster, so give the benefit of the doubt.
 710        ((< 0.2 (/ (float (length from-alist)) (float (1+ (- max min)))))
 711         ;; If offset is small and ignorable, ignore it to save time.
 712         (when (< 0 min 10) (setq min 0))
 713         (let ((to (make-array (1+ (- max min)))))
 714           (dolist (el from-alist)
 715             (setf (svref to (- (cdr el) min)) (car el)))
 716           (make-alien-enum-type :name name :signed signed
 717                                 :from from-alist :to to :kind
 718                                 :vector :offset (- min))))
 719        (t
 720         (make-alien-enum-type :name name :signed signed
 721                               :from from-alist
 722                               :to (mapcar (lambda (x) (cons (cdr x) (car x)))
 723                                           from-alist)
 724                               :kind :alist))))))
 725
 726 (define-alien-type-method (enum :unparse) (type)
 727   `(enum ,(alien-enum-type-name type)
 728          ,@(let ((prev -1))
 729              (mapcar (lambda (mapping)
 730                        (let ((sym (car mapping))
 731                              (value (cdr mapping)))
 732                          (prog1
 733                              (if (= (1+ prev) value)
 734                                  sym
 735                                  `(,sym ,value))
 736                            (setf prev value))))
 737                      (alien-enum-type-from type)))))
 738
 739 (define-alien-type-method (enum :type=) (type1 type2)
 740   (and (eq (alien-enum-type-name type1)
 741            (alien-enum-type-name type2))
 742        (equal (alien-enum-type-from type1)
 743               (alien-enum-type-from type2))))
 744
 745 (define-alien-type-method (enum :lisp-rep) (type)
 746   `(member ,@(mapcar #'car (alien-enum-type-from type))))
 747
 748 (define-alien-type-method (enum :naturalize-gen) (type alien)
 749   (ecase (alien-enum-type-kind type)
 750     (:vector
 751      `(svref ',(alien-enum-type-to type)
 752              (+ ,alien ,(alien-enum-type-offset type))))
 753     (:alist
 754      `(ecase ,alien
 755         ,@(mapcar (lambda (mapping)
 756                     `(,(car mapping) ',(cdr mapping)))
 757                   (alien-enum-type-to type))))))
 758
 759 (define-alien-type-method (enum :deport-gen) (type value)
 760   `(ecase ,value
 761      ,@(mapcar (lambda (mapping)
 762                  `(,(car mapping) ,(cdr mapping)))
 763                (alien-enum-type-from type))))
 764 \f
 765 ;;;; the FLOAT types
 766
 767 (define-alien-type-class (float)
 768   (type (missing-arg) :type symbol))
 769
 770 (define-alien-type-method (float :unparse) (type)
 771   (alien-float-type-type type))
 772
 773 (define-alien-type-method (float :lisp-rep) (type)
 774   (alien-float-type-type type))
 775
 776 (define-alien-type-method (float :alien-rep) (type)
 777   (alien-float-type-type type))
 778
 779 (define-alien-type-method (float :naturalize-gen) (type alien)
 780   (declare (ignore type))
 781   alien)
 782
 783 (define-alien-type-method (float :deport-gen) (type value)
 784   (declare (ignore type))
 785   value)
 786
 787 (define-alien-type-class (single-float :include (float (bits 32))
 788                                        :include-args (type)))
 789
 790 (define-alien-type-translator single-float ()
 791   (make-alien-single-float-type :type 'single-float))
 792
 793 (define-alien-type-method (single-float :extract-gen) (type sap offset)
 794   (declare (ignore type))
 795   `(sap-ref-single ,sap (/ ,offset sb!vm:n-byte-bits)))
 796
 797 (define-alien-type-class (double-float :include (float (bits 64))
 798                                        :include-args (type)))
 799
 800 (define-alien-type-translator double-float ()
 801   (make-alien-double-float-type :type 'double-float))
 802
 803 (define-alien-type-method (double-float :extract-gen) (type sap offset)
 804   (declare (ignore type))
 805   `(sap-ref-double ,sap (/ ,offset sb!vm:n-byte-bits)))
 806
 807 \f
 808 ;;;; the POINTER type
 809
 810 (define-alien-type-class (pointer :include (alien-value (bits
 811                                                          #!-alpha
 812                                                          sb!vm:n-word-bits
 813                                                          #!+alpha 64)))
 814   (to nil :type (or alien-type null)))
 815
 816 (define-alien-type-translator * (to &environment env)
 817   (make-alien-pointer-type :to (if (eq to t) nil (parse-alien-type to env))))
 818
 819 (define-alien-type-method (pointer :unparse) (type)
 820   (let ((to (alien-pointer-type-to type)))
 821     `(* ,(if to
 822              (%unparse-alien-type to)
 823              t))))
 824
 825 (define-alien-type-method (pointer :type=) (type1 type2)
 826   (let ((to1 (alien-pointer-type-to type1))
 827         (to2 (alien-pointer-type-to type2)))
 828     (if to1
 829         (if to2
 830             (alien-type-= to1 to2)
 831             nil)
 832         (null to2))))
 833
 834 (define-alien-type-method (pointer :subtypep) (type1 type2)
 835   (and (alien-pointer-type-p type2)
 836        (let ((to1 (alien-pointer-type-to type1))
 837              (to2 (alien-pointer-type-to type2)))
 838          (if to1
 839              (if to2
 840                  (alien-subtype-p to1 to2)
 841                  t)
 842              (null to2)))))
 843
 844 (define-alien-type-method (pointer :deport-gen) (type value)
 845   (/noshow "doing alien type method POINTER :DEPORT-GEN" type value)
 846   (values
 847    ;; FIXME: old version, highlighted a bug in xc optimization
 848    `(etypecase ,value
 849       (null
 850        (int-sap 0))
 851       (system-area-pointer
 852        ,value)
 853       ((alien ,type)
 854        (alien-sap ,value)))
 855    ;; new version, works around bug in xc optimization
 856    #+nil
 857    `(etypecase ,value
 858       (system-area-pointer
 859        ,value)
 860       ((alien ,type)
 861        (alien-sap ,value))
 862       (null
 863        (int-sap 0)))
 864    `(or null system-area-pointer (alien ,type))))
 865 \f
 866 ;;;; the MEM-BLOCK type
 867
 868 (define-alien-type-class (mem-block :include alien-value))
 869
 870 (define-alien-type-method (mem-block :extract-gen) (type sap offset)
 871   (declare (ignore type))
 872   `(sap+ ,sap (/ ,offset sb!vm:n-byte-bits)))
 873
 874 (define-alien-type-method (mem-block :deposit-gen) (type sap offset value)
 875   (let ((bytes (truncate (alien-mem-block-type-bits type) sb!vm:n-byte-bits)))
 876     (unless bytes
 877       (error "can't deposit aliens of type ~S (unknown size)" type))
 878     `(sb!kernel:system-area-ub8-copy ,value 0 ,sap ,offset ',bytes)))
 879 \f
 880 ;;;; the ARRAY type
 881
 882 (define-alien-type-class (array :include mem-block)
 883   (element-type (missing-arg) :type alien-type)
 884   (dimensions (missing-arg) :type list))
 885
 886 (define-alien-type-translator array (ele-type &rest dims &environment env)
 887
 888   (when dims
 889     (unless (typep (first dims) '(or index null))
 890       (error "The first dimension is not a non-negative fixnum or NIL: ~S"
 891              (first dims)))
 892     (let ((loser (find-if-not (lambda (x) (typep x 'index))
 893                               (rest dims))))
 894       (when loser
 895         (error "A dimension is not a non-negative fixnum: ~S" loser))))
 896
 897   (let ((parsed-ele-type (parse-alien-type ele-type env)))
 898     (make-alien-array-type
 899      :element-type parsed-ele-type
 900      :dimensions dims
 901      :alignment (alien-type-alignment parsed-ele-type)
 902      :bits (if (and (alien-type-bits parsed-ele-type)
 903                     (every #'integerp dims))
 904                (* (align-offset (alien-type-bits parsed-ele-type)
 905                                 (alien-type-alignment parsed-ele-type))
 906                   (reduce #'* dims))))))
 907
 908 (define-alien-type-method (array :unparse) (type)
 909   `(array ,(%unparse-alien-type (alien-array-type-element-type type))
 910           ,@(alien-array-type-dimensions type)))
 911
 912 (define-alien-type-method (array :type=) (type1 type2)
 913   (and (equal (alien-array-type-dimensions type1)
 914               (alien-array-type-dimensions type2))
 915        (alien-type-= (alien-array-type-element-type type1)
 916                      (alien-array-type-element-type type2))))
 917
 918 (define-alien-type-method (array :subtypep) (type1 type2)
 919   (and (alien-array-type-p type2)
 920        (let ((dim1 (alien-array-type-dimensions type1))
 921              (dim2 (alien-array-type-dimensions type2)))
 922          (and (= (length dim1) (length dim2))
 923               (or (and dim2
 924                        (null (car dim2))
 925                        (equal (cdr dim1) (cdr dim2)))
 926                   (equal dim1 dim2))
 927               (alien-subtype-p (alien-array-type-element-type type1)
 928                                (alien-array-type-element-type type2))))))
 929 \f
 930 ;;;; the RECORD type
 931
 932 (def!struct (alien-record-field
 933              (:make-load-form-fun sb!kernel:just-dump-it-normally))
 934   (name (missing-arg) :type symbol)
 935   (type (missing-arg) :type alien-type)
 936   (bits nil :type (or unsigned-byte null))
 937   (offset 0 :type unsigned-byte))
 938 (def!method print-object ((field alien-record-field) stream)
 939   (print-unreadable-object (field stream :type t)
 940     (format stream
 941             "~S ~S~@[:~D~]"
 942             (alien-record-field-type field)
 943             (alien-record-field-name field)
 944             (alien-record-field-bits field))))
 945
 946 (define-alien-type-class (record :include mem-block)
 947   (kind :struct :type (member :struct :union))
 948   (name nil :type (or symbol null))
 949   (fields nil :type list))
 950
 951 (define-alien-type-translator struct (name &rest fields &environment env)
 952   (parse-alien-record-type :struct name fields env))
 953
 954 (define-alien-type-translator union (name &rest fields &environment env)
 955   (parse-alien-record-type :union name fields env))
 956
 957 ;;; FIXME: This is really pretty horrible: we avoid creating new
 958 ;;; ALIEN-RECORD-TYPE objects when a live one is flitting around the
 959 ;;; system already. This way forwrd-references sans fields get get
 960 ;;; "updated" for free to contain the field info. Maybe rename
 961 ;;; MAKE-ALIEN-RECORD-TYPE to %MAKE-ALIEN-RECORD-TYPE and use
 962 ;;; ENSURE-ALIEN-RECORD-TYPE instead. --NS 20040729
 963 (defun parse-alien-record-type (kind name fields env)
 964   (declare (type (or sb!kernel:lexenv null) env))
 965   (cond (fields
 966          (let* ((old (and name (auxiliary-alien-type kind name env)))
 967                 (old-fields (and old (alien-record-type-fields old))))
 968            ;; KLUDGE: We can't easily compare the new fields
 969            ;; against the old fields, since the old fields have
 970            ;; already been parsed into an internal
 971            ;; representation, so we just punt, assuming that
 972            ;; they're consistent. -- WHN 200000505
 973            #|
 974              (unless (equal fields old-fields)
 975                ;; FIXME: Perhaps this should be a warning, and we
 976                ;; should overwrite the old definition and proceed?
 977                (error "mismatch in fields for ~S~%  old ~S~%  new ~S"
 978                       name old-fields fields))
 979            |#
 980            (if old-fields
 981                old
 982                (let ((type (or old (make-alien-record-type :name name :kind kind))))
 983                  (when (and name (not old))
 984                    (setf (auxiliary-alien-type kind name env) type))
 985                  (parse-alien-record-fields type fields env)
 986                  type))))
 987         (name
 988          (or (auxiliary-alien-type kind name env)
 989              (setf (auxiliary-alien-type kind name env)
 990                    (make-alien-record-type :name name :kind kind))))
 991         (t
 992          (make-alien-record-type :kind kind))))
 993
 994 ;;; This is used by PARSE-ALIEN-TYPE to parse the fields of struct and
 995 ;;; union types. RESULT holds the record type we are paring the fields
 996 ;;; of, and FIELDS is the list of field specifications.
 997 (defun parse-alien-record-fields (result fields env)
 998   (declare (type alien-record-type result)
 999            (type list fields))
1000   (let ((total-bits 0)
1001         (overall-alignment 1)
1002         (parsed-fields nil))
1003     (dolist (field fields)
1004       (destructuring-bind (var type &key alignment) field
1005         (let* ((field-type (parse-alien-type type env))
1006                (bits (alien-type-bits field-type))
1007                (parsed-field
1008                 (make-alien-record-field :type field-type
1009                                          :name var)))
1010           (unless alignment
1011             (setf alignment (alien-type-alignment field-type)))
1012           (push parsed-field parsed-fields)
1013           (when (null bits)
1014             (error "unknown size: ~S" (unparse-alien-type field-type)))
1015           (when (null alignment)
1016             (error "unknown alignment: ~S" (unparse-alien-type field-type)))
1017           (setf overall-alignment (max overall-alignment alignment))
1018           (ecase (alien-record-type-kind result)
1019             (:struct
1020              (let ((offset (align-offset total-bits alignment)))
1021                (setf (alien-record-field-offset parsed-field) offset)
1022                (setf total-bits (+ offset bits))))
1023             (:union
1024              (setf total-bits (max total-bits bits)))))))
1025     (let ((new (nreverse parsed-fields)))
1026       (setf (alien-record-type-fields result) new))
1027     (setf (alien-record-type-alignment result) overall-alignment)
1028     (setf (alien-record-type-bits result)
1029           (align-offset total-bits overall-alignment))))
1030
1031 (define-alien-type-method (record :unparse) (type)
1032   `(,(case (alien-record-type-kind type)
1033        (:struct 'struct)
1034        (:union 'union)
1035        (t '???))
1036     ,(alien-record-type-name type)
1037     ,@(unless (member type *record-types-already-unparsed* :test #'eq)
1038         (push type *record-types-already-unparsed*)
1039         (mapcar (lambda (field)
1040                   `(,(alien-record-field-name field)
1041                     ,(%unparse-alien-type (alien-record-field-type field))
1042                     ,@(if (alien-record-field-bits field)
1043                           (list (alien-record-field-bits field)))))
1044                 (alien-record-type-fields type)))))
1045
1046 ;;; Test the record fields. Keep a hashtable table of already compared
1047 ;;; types to detect cycles.
1048 (defun record-fields-match-p (field1 field2)
1049   (and (eq (alien-record-field-name field1)
1050            (alien-record-field-name field2))
1051        (eql (alien-record-field-bits field1)
1052             (alien-record-field-bits field2))
1053        (eql (alien-record-field-offset field1)
1054             (alien-record-field-offset field2))
1055        (alien-type-= (alien-record-field-type field1)
1056                      (alien-record-field-type field2))))
1057
1058 (defvar *alien-type-matches* nil
1059   "A hashtable used to detect cycles while comparing record types.")
1060
1061 (define-alien-type-method (record :type=) (type1 type2)
1062   (and (eq (alien-record-type-name type1)
1063            (alien-record-type-name type2))
1064        (eq (alien-record-type-kind type1)
1065            (alien-record-type-kind type2))
1066        (eql (alien-type-bits type1)
1067             (alien-type-bits type2))
1068        (eql (alien-type-alignment type1)
1069             (alien-type-alignment type2))
1070        (flet ((match-fields (&optional old)
1071                 (setf (gethash type1 *alien-type-matches*) (cons type2 old))
1072                 (every #'record-fields-match-p
1073                        (alien-record-type-fields type1)
1074                        (alien-record-type-fields type2))))
1075          (if *alien-type-matches*
1076              (let ((types (gethash type1 *alien-type-matches*)))
1077                (or (memq type2 types) (match-fields types)))
1078              (let ((*alien-type-matches* (make-hash-table :test #'eq)))
1079                (match-fields))))))
1080 \f
1081 ;;;; the FUNCTION and VALUES alien types
1082
1083 (define-alien-type-class (fun :include mem-block)
1084   (result-type (missing-arg) :type alien-type)
1085   (arg-types (missing-arg) :type list)
1086   (stub nil :type (or null function)))
1087
1088 (define-alien-type-translator function (result-type &rest arg-types
1089                                                     &environment env)
1090   (make-alien-fun-type
1091    :result-type (let ((*values-type-okay* t))
1092                   (parse-alien-type result-type env))
1093    :arg-types (mapcar (lambda (arg-type) (parse-alien-type arg-type env))
1094                       arg-types)))
1095
1096 (define-alien-type-method (fun :unparse) (type)
1097   `(function ,(%unparse-alien-type (alien-fun-type-result-type type))
1098              ,@(mapcar #'%unparse-alien-type
1099                        (alien-fun-type-arg-types type))))
1100
1101 (define-alien-type-method (fun :type=) (type1 type2)
1102   (and (alien-type-= (alien-fun-type-result-type type1)
1103                      (alien-fun-type-result-type type2))
1104        (= (length (alien-fun-type-arg-types type1))
1105           (length (alien-fun-type-arg-types type2)))
1106        (every #'alien-type-=
1107               (alien-fun-type-arg-types type1)
1108               (alien-fun-type-arg-types type2))))
1109
1110 (define-alien-type-class (values)
1111   (values (missing-arg) :type list))
1112
1113 (define-alien-type-translator values (&rest values &environment env)
1114   (unless *values-type-okay*
1115     (error "cannot use values types here"))
1116   (let ((*values-type-okay* nil))
1117     (make-alien-values-type
1118      :values (mapcar (lambda (alien-type) (parse-alien-type alien-type env))
1119                      values))))
1120
1121 (define-alien-type-method (values :unparse) (type)
1122   `(values ,@(mapcar #'%unparse-alien-type
1123                      (alien-values-type-values type))))
1124
1125 (define-alien-type-method (values :type=) (type1 type2)
1126   (and (= (length (alien-values-type-values type1))
1127           (length (alien-values-type-values type2)))
1128        (every #'alien-type-=
1129               (alien-values-type-values type1)
1130               (alien-values-type-values type2))))
1131 \f
1132 ;;;; a structure definition needed both in the target and in the
1133 ;;;; cross-compilation host
1134
1135 ;;; information about local aliens. The WITH-ALIEN macro builds one of
1136 ;;; these structures and LOCAL-ALIEN and friends communicate
1137 ;;; information about how that local alien is represented.
1138 (def!struct (local-alien-info
1139              (:make-load-form-fun sb!kernel:just-dump-it-normally)
1140              (:constructor make-local-alien-info
1141                            (&key type force-to-memory-p
1142                             &aux (force-to-memory-p (or force-to-memory-p
1143                                                         (alien-array-type-p type)
1144                                                         (alien-record-type-p type))))))
1145   ;; the type of the local alien
1146   (type (missing-arg) :type alien-type)
1147   ;; Must this local alien be forced into memory? Using the ADDR macro
1148   ;; on a local alien will set this.
1149   (force-to-memory-p nil :type (member t nil)))
1150 (def!method print-object ((info local-alien-info) stream)
1151   (print-unreadable-object (info stream :type t)
1152     (format stream
1153             "~:[~;(forced to stack) ~]~S"
1154             (local-alien-info-force-to-memory-p info)
1155             (unparse-alien-type (local-alien-info-type info)))))
1156 \f
1157 ;;;; the ADDR macro
1158
1159 (defmacro-mundanely addr (expr &environment env)
1160   #!+sb-doc
1161   "Return an Alien pointer to the data addressed by Expr, which must be a call
1162    to SLOT or DEREF, or a reference to an Alien variable."
1163   (let ((form (sb!xc:macroexpand expr env)))
1164     (or (typecase form
1165           (cons
1166            (case (car form)
1167              (slot
1168               (cons '%slot-addr (cdr form)))
1169              (deref
1170               (cons '%deref-addr (cdr form)))
1171              (%heap-alien
1172               (cons '%heap-alien-addr (cdr form)))
1173              (local-alien
1174               (let ((info (let ((info-arg (second form)))
1175                             (and (consp info-arg)
1176                                  (eq (car info-arg) 'quote)
1177                                  (second info-arg)))))
1178                 (unless (local-alien-info-p info)
1179                   (error "Something is wrong, LOCAL-ALIEN-INFO not found: ~S"
1180                          form))
1181                 (setf (local-alien-info-force-to-memory-p info) t))
1182               (cons '%local-alien-addr (cdr form)))))
1183           (symbol
1184            (let ((kind (info :variable :kind form)))
1185              (when (eq kind :alien)
1186                `(%heap-alien-addr ',(info :variable :alien-info form))))))
1187         (error "~S is not a valid L-value." form))))
1188
1189 (/show0 "host-alieneval.lisp end of file")