src/code/host-c-call.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!ALIEN")
  11
  12 (/show0 "host-c-call.lisp 12")
  13
  14 (define-alien-type-class (c-string :include pointer :include-args (to))
  15   (external-format :default :type keyword)
  16   (element-type 'character :type (member character base-char)))
  17
  18 (define-alien-type-translator c-string
  19     (&key (external-format :default)
  20           (element-type 'character))
  21   (make-alien-c-string-type
  22    :to (parse-alien-type 'char (sb!kernel:make-null-lexenv))
  23    :element-type element-type
  24    :external-format external-format))
  25
  26 (defun c-string-external-format (type)
  27   (let ((external-format (alien-c-string-type-external-format type)))
  28     (if (eq external-format :default)
  29         (default-c-string-external-format)
  30         external-format)))
  31
  32 (define-alien-type-method (c-string :unparse) (type)
  33   (list 'c-string
  34         :external-format (alien-c-string-type-external-format type)
  35         :element-type (alien-c-string-type-element-type type)))
  36
  37 (define-alien-type-method (c-string :lisp-rep) (type)
  38   (declare (ignore type))
  39   '(or simple-string null (alien (* char)) (simple-array (unsigned-byte 8))))
  40
  41 (define-alien-type-method (c-string :deport-pin-p) (type)
  42   (declare (ignore type))
  43   t)
  44
  45 (defun c-string-needs-conversion-p (type)
  46   #+sb-xc-host
  47   t
  48   #-sb-xc-host
  49   (let ((external-format (sb!impl::get-external-format
  50                           ;; Can't use C-STRING-EXTERNAL-FORMAT here,
  51                           ;; since the meaning of :DEFAULT can change
  52                           ;; when *DEFAULT-C-STRING-EXTERNAL-FORMAT*
  53                           ;; changes.
  54                           (alien-c-string-type-external-format type))))
  55     (not (and external-format
  56               (or (eq (caar external-format) :ascii)
  57                   ;; On non-SB-UNICODE all latin-1 codepoints will fit
  58                   ;; into a base-char, on SB-UNICODE they won't.
  59                   #!-sb-unicode
  60                   (eq (caar external-format) :latin-1))))))
  61
  62 (define-alien-type-method (c-string :naturalize-gen) (type alien)
  63   `(if (zerop (sap-int ,alien))
  64        nil
  65        ;; Check whether we need to do a full external-format
  66        ;; conversion, or whether we can just do a cheap byte-by-byte
  67        ;; copy of the c-string data.
  68        ;;
  69        ;; On SB-UNICODE we can never do the cheap copy, even if the
  70        ;; external format and element-type are suitable, since
  71        ;; simple-base-strings may not contain ISO-8859-1 characters.
  72        ;; If we need to check for non-ascii data in the input, we
  73        ;; might as well go through the usual external-format machinery
  74        ;; instead of rewriting another version of it.
  75        ,(if #!+sb-unicode t
  76             #!-sb-unicode (c-string-needs-conversion-p type)
  77             `(sb!alien::c-string-to-string ,alien
  78                                            (c-string-external-format ,type)
  79                                            (alien-c-string-type-element-type
  80                                             ,type))
  81             `(%naturalize-c-string ,alien))))
  82
  83 (define-alien-type-method (c-string :deport-gen) (type value)
  84   (declare (ignore type))
  85   `(etypecase ,value
  86      (null (int-sap 0))
  87      ((alien (* char)) (alien-sap ,value))
  88      (vector (vector-sap ,value))))
  89
  90 (define-alien-type-method (c-string :deport-alloc-gen) (type value)
  91   `(etypecase ,value
  92      (null nil)
  93      ((alien (* char)) ,value)
  94      (simple-base-string
  95       ,(if (c-string-needs-conversion-p type)
  96            ;; If the alien type is not ascii-compatible (+SB-UNICODE)
  97            ;; or latin-1-compatible (-SB-UNICODE), we need to do
  98            ;; external format conversion.
  99            `(string-to-c-string ,value
 100                                 (c-string-external-format ,type))
 101            ;; Otherwise we can just pass it uncopied.
 102            value))
 103      (simple-string
 104       (string-to-c-string ,value
 105                           (c-string-external-format ,type)))))
 106
 107 (/show0 "host-c-call.lisp end of file")