src/code/interr.lisp

   1 ;;;; functions and macros to define and deal with internal errors
   2 ;;;; (i.e. problems that can be signaled from assembler code)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14 \f
  15 ;;;; internal errors
  16
  17 (defvar *internal-errors*
  18   #.(map 'vector #'cdr sb!c:*backend-internal-errors*))
  19
  20 (eval-when (:compile-toplevel :execute)
  21
  22 (sb!xc:defmacro deferr (name args &rest body)
  23   (let* ((rest-pos (position '&rest args))
  24          (required (if rest-pos (subseq args 0 rest-pos) args))
  25          (fp (gensym))
  26          (context (gensym))
  27          (sc-offsets (gensym))
  28          (fn-name (symbolicate name "-HANDLER")))
  29     `(progn
  30        ;; FIXME: Having a separate full DEFUN for each error doesn't
  31        ;; seem to add much value, and it takes a lot of space. Perhaps
  32        ;; we could do this dispatch with a big CASE statement instead?
  33        (defun ,fn-name (name ,fp ,context ,sc-offsets)
  34          ;; FIXME: It would probably be good to do *STACK-TOP-HINT*
  35          ;; tricks to hide this internal error-handling logic from the
  36          ;; poor high level user, so his debugger tells him about
  37          ;; where his error was detected instead of telling him where
  38          ;; he ended up inside the system error-handling logic.
  39          (declare (ignorable name ,fp ,context ,sc-offsets))
  40          (let (,@(let ((offset -1))
  41                    (mapcar (lambda (var)
  42                              `(,var (sb!di::sub-access-debug-var-slot
  43                                      ,fp
  44                                      (nth ,(incf offset)
  45                                           ,sc-offsets)
  46                                      ,context)))
  47                            required))
  48                ,@(when rest-pos
  49                    `((,(nth (1+ rest-pos) args)
  50                       (mapcar (lambda (sc-offset)
  51                                 (sb!di::sub-access-debug-var-slot
  52                                  ,fp
  53                                  sc-offset
  54                                  ,context))
  55                               (nthcdr ,rest-pos ,sc-offsets))))))
  56            ,@body))
  57        (setf (svref *internal-errors* ,(error-number-or-lose name))
  58              #',fn-name))))
  59
  60 ) ; EVAL-WHEN
  61
  62 (deferr unknown-error (&rest args)
  63   (error "unknown error:~{ ~S~})" args))
  64
  65 (deferr object-not-fun-error (object)
  66   (error 'type-error
  67          :datum object
  68          :expected-type 'function))
  69
  70 (deferr object-not-list-error (object)
  71   (error 'type-error
  72          :datum object
  73          :expected-type 'list))
  74
  75 (deferr object-not-bignum-error (object)
  76   (error 'type-error
  77          :datum object
  78          :expected-type 'bignum))
  79
  80 (deferr object-not-ratio-error (object)
  81   (error 'type-error
  82          :datum object
  83          :expected-type 'ratio))
  84
  85 (deferr object-not-single-float-error (object)
  86   (error 'type-error
  87          :datum object
  88          :expected-type 'single-float))
  89
  90 (deferr object-not-double-float-error (object)
  91   (error 'type-error
  92          :datum object
  93          :expected-type 'double-float))
  94
  95 #!+long-float
  96 (deferr object-not-long-float-error (object)
  97   (error 'type-error
  98          :datum object
  99          :expected-type 'long-float))
 100
 101 (deferr object-not-simple-string-error (object)
 102   (error 'type-error
 103          :datum object
 104          :expected-type 'simple-string))
 105
 106 (deferr object-not-simple-bit-vector-error (object)
 107   (error 'type-error
 108          :datum object
 109          :expected-type 'simple-bit-vector))
 110
 111 (deferr object-not-simple-vector-error (object)
 112   (error 'type-error
 113          :datum object
 114          :expected-type 'simple-vector))
 115
 116 (deferr object-not-fixnum-error (object)
 117   (error 'type-error
 118          :datum object
 119          :expected-type 'fixnum))
 120
 121 (deferr object-not-vector-error (object)
 122   (error 'type-error
 123          :datum object
 124          :expected-type 'vector))
 125
 126 (deferr object-not-string-error (object)
 127   (error 'type-error
 128          :datum object
 129          :expected-type 'string))
 130
 131 (deferr object-not-bit-vector-error (object)
 132   (error 'type-error
 133          :datum object
 134          :expected-type 'bit-vector))
 135
 136 (deferr object-not-array-error (object)
 137   (error 'type-error
 138          :datum object
 139          :expected-type 'array))
 140
 141 (deferr object-not-number-error (object)
 142   (error 'type-error
 143          :datum object
 144          :expected-type 'number))
 145
 146 (deferr object-not-rational-error (object)
 147   (error 'type-error
 148          :datum object
 149          :expected-type 'rational))
 150
 151 (deferr object-not-float-error (object)
 152   (error 'type-error
 153          :datum object
 154          :expected-type 'float))
 155
 156 (deferr object-not-real-error (object)
 157   (error 'type-error
 158          :datum object
 159          :expected-type 'real))
 160
 161 (deferr object-not-integer-error (object)
 162   (error 'type-error
 163          :datum object
 164          :expected-type 'integer))
 165
 166 (deferr object-not-cons-error (object)
 167   (error 'type-error
 168          :datum object
 169          :expected-type 'cons))
 170
 171 (deferr object-not-symbol-error (object)
 172   (error 'type-error
 173          :datum object
 174          :expected-type 'symbol))
 175
 176 (deferr undefined-fun-error (fdefn-or-symbol)
 177   (error 'undefined-function
 178          :name (etypecase fdefn-or-symbol
 179                  (symbol fdefn-or-symbol)
 180                  (fdefn (fdefn-name fdefn-or-symbol)))))
 181
 182 (deferr invalid-arg-count-error (nargs)
 183   (error 'simple-program-error
 184          :format-control "invalid number of arguments: ~S"
 185          :format-arguments (list nargs)))
 186
 187 (deferr bogus-arg-to-values-list-error (list)
 188   (error 'simple-type-error
 189          :datum list
 190          :expected-type 'list
 191          :format-control
 192          "~@<attempt to use VALUES-LIST on a dotted list: ~2I~_~S~:>"
 193          :format-arguments (list list)))
 194
 195 (deferr unbound-symbol-error (symbol)
 196   (error 'unbound-variable :name symbol))
 197
 198 (deferr object-not-base-char-error (object)
 199   (error 'type-error
 200          :datum object
 201          :expected-type 'base-char))
 202
 203 (deferr object-not-sap-error (object)
 204   (error 'type-error
 205          :datum object
 206          :expected-type 'system-area-pointer))
 207
 208 (deferr invalid-unwind-error ()
 209   (error 'simple-control-error
 210          :format-control
 211          "attempt to RETURN-FROM a block or GO to a tag that no longer exists"
 212          ))
 213
 214 (deferr unseen-throw-tag-error (tag)
 215   (error 'simple-control-error
 216          :format-control "attempt to THROW to a tag that does not exist: ~S"
 217          :format-arguments (list tag)))
 218
 219 (deferr nil-fun-returned-error (function)
 220   (error 'simple-control-error
 221          :format-control
 222          "A function with declared result type NIL returned:~%  ~S"
 223          :format-arguments (list function)))
 224
 225 (deferr division-by-zero-error (this that)
 226   (error 'division-by-zero
 227          :operation 'division
 228          :operands (list this that)))
 229
 230 (deferr object-not-type-error (object type)
 231   (error (if (and (typep object 'instance)
 232                   (layout-invalid (%instance-layout object)))
 233              'layout-invalid
 234              'type-error)
 235          :datum object
 236          :expected-type type))
 237
 238 (deferr layout-invalid-error (object layout)
 239   (error 'layout-invalid
 240          :datum object
 241          :expected-type (layout-class layout)))
 242
 243 (deferr odd-key-args-error ()
 244   (error 'simple-program-error
 245          :format-control "odd number of &KEY arguments"))
 246
 247 (deferr unknown-key-arg-error (key-name)
 248   (error 'simple-program-error
 249          :format-control "unknown &KEY argument: ~S"
 250          :format-arguments (list key-name)))
 251
 252 (deferr invalid-array-index-error (array bound index)
 253   (error 'simple-error
 254          :format-control
 255          "invalid array index ~W for ~S (should be nonnegative and <~W)"
 256          :format-arguments (list index array bound)))
 257
 258 (deferr object-not-simple-array-error (object)
 259   (error 'type-error
 260          :datum object
 261          :expected-type 'simple-array))
 262
 263 (deferr object-not-signed-byte-32-error (object)
 264   (error 'type-error
 265          :datum object
 266          :expected-type '(signed-byte 32)))
 267
 268 (deferr object-not-unsigned-byte-32-error (object)
 269   (error 'type-error
 270          :datum object
 271          :expected-type '(unsigned-byte 32)))
 272
 273 (deferr object-not-simple-array-unsigned-byte-2-error (object)
 274   (error 'type-error
 275          :datum object
 276          :expected-type '(simple-array (unsigned-byte 2) (*))))
 277
 278 (deferr object-not-simple-array-unsigned-byte-4-error (object)
 279   (error 'type-error
 280          :datum object
 281          :expected-type '(simple-array (unsigned-byte 4) (*))))
 282
 283 (deferr object-not-simple-array-unsigned-byte-8-error (object)
 284   (error 'type-error
 285          :datum object
 286          :expected-type '(simple-array (unsigned-byte 8) (*))))
 287
 288 (deferr object-not-simple-array-unsigned-byte-16-error (object)
 289   (error 'type-error
 290          :datum object
 291          :expected-type '(simple-array (unsigned-byte 16) (*))))
 292
 293 (deferr object-not-simple-array-unsigned-byte-32-error (object)
 294   (error 'type-error
 295          :datum object
 296          :expected-type '(simple-array (unsigned-byte 32) (*))))
 297
 298 (deferr object-not-simple-array-signed-byte-8-error (object)
 299   (error 'type-error
 300          :datum object
 301          :expected-type '(simple-array (signed-byte 8) (*))))
 302
 303 (deferr object-not-simple-array-signed-byte-16-error (object)
 304   (error 'type-error
 305          :datum object
 306          :expected-type '(simple-array (signed-byte 16) (*))))
 307
 308 (deferr object-not-simple-array-signed-byte-30-error (object)
 309   (error 'type-error
 310          :datum object
 311          :expected-type '(simple-array (signed-byte 30) (*))))
 312
 313 (deferr object-not-simple-array-signed-byte-32-error (object)
 314   (error 'type-error
 315          :datum object
 316          :expected-type '(simple-array (signed-byte 32) (*))))
 317
 318 (deferr object-not-simple-array-single-float-error (object)
 319   (error 'type-error
 320          :datum object
 321          :expected-type '(simple-array single-float (*))))
 322
 323 (deferr object-not-simple-array-double-float-error (object)
 324   (error 'type-error
 325          :datum object
 326          :expected-type '(simple-array double-float (*))))
 327
 328 (deferr object-not-simple-array-complex-single-float-error (object)
 329   (error 'type-error
 330          :datum object
 331          :expected-type '(simple-array (complex single-float) (*))))
 332
 333 (deferr object-not-simple-array-complex-double-float-error (object)
 334   (error 'type-error
 335          :datum object
 336          :expected-type '(simple-array (complex double-float) (*))))
 337
 338 #!+long-float
 339 (deferr object-not-simple-array-complex-long-float-error (object)
 340   (error 'type-error
 341          :datum object
 342          :expected-type '(simple-array (complex long-float) (*))))
 343
 344 (deferr object-not-complex-error (object)
 345   (error 'type-error
 346          :datum object
 347          :expected-type 'complex))
 348
 349 (deferr object-not-complex-rational-error (object)
 350   (error 'type-error
 351          :datum object
 352          :expected-type '(complex rational)))
 353
 354 (deferr object-not-complex-single-float-error (object)
 355   (error 'type-error
 356          :datum object
 357          :expected-type '(complex single-float)))
 358
 359 (deferr object-not-complex-double-float-error (object)
 360   (error 'type-error
 361          :datum object
 362          :expected-type '(complex double-float)))
 363
 364 #!+long-float
 365 (deferr object-not-complex-long-float-error (object)
 366   (error 'type-error
 367          :datum object
 368          :expected-type '(complex long-float)))
 369
 370 (deferr object-not-weak-pointer-error (object)
 371   (error 'type-error
 372          :datum object
 373          :expected-type 'weak-pointer))
 374
 375 (deferr object-not-instance-error (object)
 376   (error 'type-error
 377          :datum object
 378          :expected-type 'instance))
 379
 380 (deferr object-not-complex-vector-error (object)
 381   (error 'type-error
 382          :datum object
 383          :expected-type '(and vector (not simple-array))))
 384 \f
 385 ;;;; fetching errorful function name
 386
 387 ;;; This flag is used to prevent infinite recursive lossage when
 388 ;;; we can't find the caller for some reason.
 389 (defvar *finding-name* nil)
 390
 391 (defun find-caller-name-and-frame ()
 392   (if *finding-name*
 393       (values "<error finding caller name -- already finding name>" nil)
 394       (handler-case
 395           (let* ((*finding-name* t)
 396                  (frame (sb!di:frame-down (sb!di:frame-down (sb!di:top-frame))))
 397                  (name (sb!di:debug-fun-name
 398                         (sb!di:frame-debug-fun frame))))
 399             (sb!di:flush-frames-above frame)
 400             (values name frame))
 401         (error ()
 402           (values "<error finding caller name -- trapped error>" nil))
 403         (sb!di:debug-condition ()
 404           (values "<error finding caller name -- trapped debug-condition>"
 405                   nil)))))
 406
 407 (defun find-interrupted-name ()
 408   (/show0 "entering FIND-INTERRUPTED-NAME")
 409   (if *finding-name*
 410       (values "<error finding interrupted name -- already finding name>" nil)
 411       (handler-case
 412           (let ((*finding-name* t))
 413             (/show0 "in ordinary case")
 414             (do ((frame (sb!di:top-frame) (sb!di:frame-down frame)))
 415                 ((null frame)
 416                  (/show0 "null frame")
 417                  (values "<error finding interrupted name -- null frame>" nil))
 418               (/show0 "at head of DO loop")
 419               (when (and (sb!di::compiled-frame-p frame)
 420                          (sb!di::compiled-frame-escaped frame))
 421                 (sb!di:flush-frames-above frame)
 422                 (/show0 "returning from within DO loop")
 423                 (return (values (sb!di:debug-fun-name
 424                                  (sb!di:frame-debug-fun frame))
 425                                 frame)))))
 426         (error ()
 427           (/show0 "trapped ERROR")
 428           (values "<error finding interrupted name -- trapped error>" nil))
 429         (sb!di:debug-condition ()
 430           (/show0 "trapped DEBUG-CONDITION")
 431           (values "<error finding interrupted name -- trapped debug-condition>"
 432                   nil)))))
 433 \f
 434 ;;;; INTERNAL-ERROR signal handler
 435
 436 (defvar *internal-error-args*)
 437
 438 (defun internal-error (context continuable)
 439   (declare (type system-area-pointer context))
 440   (declare (ignore continuable))
 441   (/show0 "entering INTERNAL-ERROR, CONTEXT=..")
 442   (/hexstr context)
 443   (infinite-error-protect
 444    (/show0 "about to bind ALIEN-CONTEXT")
 445    (let ((alien-context (locally
 446                           (declare (optimize (inhibit-warnings 3)))
 447                           (sb!alien:sap-alien context (* os-context-t)))))
 448      (/show0 "about to bind ERROR-NUMBER and ARGUMENTS")
 449      (multiple-value-bind (error-number arguments)
 450          (sb!vm:internal-error-args alien-context)
 451        (/show0 "back from INTERNAL-ERROR-ARGS, ERROR-NUMBER=..")
 452        (/hexstr error-number)
 453        (/show0 "cold/low ARGUMENTS=..")
 454        (/hexstr arguments)
 455
 456        (multiple-value-bind (name sb!debug:*stack-top-hint*)
 457            (find-interrupted-name)
 458          (/show0 "back from FIND-INTERRUPTED-NAME")
 459          (let ((fp (int-sap (sb!vm:context-register alien-context
 460                                                     sb!vm::cfp-offset)))
 461                (handler (and (< -1 error-number (length *internal-errors*))
 462                              (svref *internal-errors* error-number))))
 463            (cond ((null handler)
 464                   (error 'simple-error
 465                          :format-control
 466                          "unknown internal error, ~D, args=~S"
 467                          :format-arguments
 468                          (list error-number
 469                                (mapcar (lambda (sc-offset)
 470                                          (sb!di::sub-access-debug-var-slot
 471                                           fp sc-offset alien-context))
 472                                        arguments))))
 473                  ((not (functionp handler))
 474                   (error 'simple-error
 475                          :format-control "internal error ~D: ~A; args=~S"
 476                          :format-arguments
 477                          (list error-number
 478                                handler
 479                                (mapcar (lambda (sc-offset)
 480                                          (sb!di::sub-access-debug-var-slot
 481                                           fp sc-offset alien-context))
 482                                        arguments))))
 483                  (t
 484                   (funcall handler name fp alien-context arguments)))))))))