src/code/interr.lisp

   1 ;;;; functions and macros to define and deal with internal errors
   2 ;;;; (i.e. problems that can be signaled from assembler code)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14 \f
  15 ;;;; internal errors
  16
  17 (defvar *internal-errors*
  18   #.(map 'vector #'cdr sb!c:*backend-internal-errors*))
  19
  20 (eval-when (:compile-toplevel :execute)
  21
  22 (sb!xc:defmacro deferr (name args &rest body)
  23   (let* ((rest-pos (position '&rest args))
  24          (required (if rest-pos (subseq args 0 rest-pos) args))
  25          (fp (gensym))
  26          (context (gensym))
  27          (sc-offsets (gensym))
  28          (fn-name (symbolicate name "-HANDLER")))
  29     `(progn
  30        ;; FIXME: Having a separate full DEFUN for each error doesn't
  31        ;; seem to add much value, and it takes a lot of space. Perhaps
  32        ;; we could do this dispatch with a big CASE statement instead?
  33        (defun ,fn-name (name ,fp ,context ,sc-offsets)
  34          ;; FIXME: It would probably be good to do *STACK-TOP-HINT*
  35          ;; tricks to hide this internal error-handling logic from the
  36          ;; poor high level user, so his debugger tells him about
  37          ;; where his error was detected instead of telling him where
  38          ;; he ended up inside the system error-handling logic.
  39          (declare (ignorable name ,fp ,context ,sc-offsets))
  40          (let (,@(let ((offset -1))
  41                    (mapcar (lambda (var)
  42                              `(,var (sb!di::sub-access-debug-var-slot
  43                                      ,fp
  44                                      (nth ,(incf offset)
  45                                           ,sc-offsets)
  46                                      ,context)))
  47                            required))
  48                ,@(when rest-pos
  49                    `((,(nth (1+ rest-pos) args)
  50                       (mapcar (lambda (sc-offset)
  51                                 (sb!di::sub-access-debug-var-slot
  52                                  ,fp
  53                                  sc-offset
  54                                  ,context))
  55                               (nthcdr ,rest-pos ,sc-offsets))))))
  56            ,@body))
  57        (setf (svref *internal-errors* ,(error-number-or-lose name))
  58              #',fn-name))))
  59
  60 ) ; EVAL-WHEN
  61
  62 (deferr unknown-error (&rest args)
  63   (error "unknown error:~{ ~S~})" args))
  64
  65 (deferr object-not-fun-error (object)
  66   (error 'type-error
  67          :datum object
  68          :expected-type 'function))
  69
  70 (deferr object-not-list-error (object)
  71   (error 'type-error
  72          :datum object
  73          :expected-type 'list))
  74
  75 (deferr object-not-bignum-error (object)
  76   (error 'type-error
  77          :datum object
  78          :expected-type 'bignum))
  79
  80 (deferr object-not-ratio-error (object)
  81   (error 'type-error
  82          :datum object
  83          :expected-type 'ratio))
  84
  85 (deferr object-not-single-float-error (object)
  86   (error 'type-error
  87          :datum object
  88          :expected-type 'single-float))
  89
  90 (deferr object-not-double-float-error (object)
  91   (error 'type-error
  92          :datum object
  93          :expected-type 'double-float))
  94
  95 #!+long-float
  96 (deferr object-not-long-float-error (object)
  97   (error 'type-error
  98          :datum object
  99          :expected-type 'long-float))
 100
 101 (deferr object-not-simple-string-error (object)
 102   (error 'type-error
 103          :datum object
 104          :expected-type 'simple-string))
 105
 106 (deferr object-not-fixnum-error (object)
 107   (error 'type-error
 108          :datum object
 109          :expected-type 'fixnum))
 110
 111 (deferr object-not-vector-error (object)
 112   (error 'type-error
 113          :datum object
 114          :expected-type 'vector))
 115
 116 (deferr object-not-string-error (object)
 117   (error 'type-error
 118          :datum object
 119          :expected-type 'string))
 120
 121 (deferr object-not-base-string-error (object)
 122   (error 'type-error
 123          :datum object
 124          :expected-type 'base-string))
 125
 126 (deferr object-not-vector-nil-error (object)
 127   (error 'type-error
 128          :datum object
 129          :expected-type '(vector nil)))
 130
 131 #!+sb-unicode
 132 (deferr object-not-character-string-error (object)
 133   (error 'type-error
 134          :datum object
 135          :expected-type '(vector character)))
 136
 137 (deferr object-not-bit-vector-error (object)
 138   (error 'type-error
 139          :datum object
 140          :expected-type 'bit-vector))
 141
 142 (deferr object-not-array-error (object)
 143   (error 'type-error
 144          :datum object
 145          :expected-type 'array))
 146
 147 (deferr object-not-number-error (object)
 148   (error 'type-error
 149          :datum object
 150          :expected-type 'number))
 151
 152 (deferr object-not-rational-error (object)
 153   (error 'type-error
 154          :datum object
 155          :expected-type 'rational))
 156
 157 (deferr object-not-float-error (object)
 158   (error 'type-error
 159          :datum object
 160          :expected-type 'float))
 161
 162 (deferr object-not-real-error (object)
 163   (error 'type-error
 164          :datum object
 165          :expected-type 'real))
 166
 167 (deferr object-not-integer-error (object)
 168   (error 'type-error
 169          :datum object
 170          :expected-type 'integer))
 171
 172 (deferr object-not-cons-error (object)
 173   (error 'type-error
 174          :datum object
 175          :expected-type 'cons))
 176
 177 (deferr object-not-symbol-error (object)
 178   (error 'type-error
 179          :datum object
 180          :expected-type 'symbol))
 181
 182 (deferr undefined-fun-error (fdefn-or-symbol)
 183   (error 'undefined-function
 184          :name (etypecase fdefn-or-symbol
 185                  (symbol fdefn-or-symbol)
 186                  (fdefn (fdefn-name fdefn-or-symbol)))))
 187
 188 (deferr invalid-arg-count-error (nargs)
 189   (error 'simple-program-error
 190          :format-control "invalid number of arguments: ~S"
 191          :format-arguments (list nargs)))
 192
 193 (deferr bogus-arg-to-values-list-error (list)
 194   (error 'simple-type-error
 195          :datum list
 196          :expected-type 'list
 197          :format-control
 198          "~@<attempt to use VALUES-LIST on a dotted list: ~2I~_~S~:>"
 199          :format-arguments (list list)))
 200
 201 (deferr unbound-symbol-error (symbol)
 202   (error 'unbound-variable :name symbol))
 203
 204 (deferr object-not-character-error (object)
 205   (error 'type-error
 206          :datum object
 207          :expected-type 'character))
 208
 209 (deferr object-not-sap-error (object)
 210   (error 'type-error
 211          :datum object
 212          :expected-type 'system-area-pointer))
 213
 214 (deferr invalid-unwind-error ()
 215   (error 'simple-control-error
 216          :format-control
 217          "attempt to RETURN-FROM a block or GO to a tag that no longer exists"
 218          ))
 219
 220 (deferr unseen-throw-tag-error (tag)
 221   (error 'simple-control-error
 222          :format-control "attempt to THROW to a tag that does not exist: ~S"
 223          :format-arguments (list tag)))
 224
 225 (deferr nil-fun-returned-error (function)
 226   (error 'simple-control-error
 227          :format-control
 228          "A function with declared result type NIL returned:~%  ~S"
 229          :format-arguments (list function)))
 230
 231 (deferr nil-array-accessed-error (array)
 232   (error 'nil-array-accessed-error
 233          :datum array :expected-type '(not (array nil))))
 234
 235 (deferr division-by-zero-error (this that)
 236   (error 'division-by-zero
 237          :operation 'division
 238          :operands (list this that)))
 239
 240 (deferr object-not-type-error (object type)
 241   (error (if (and (%instancep object)
 242                   (layout-invalid (%instance-layout object)))
 243              'layout-invalid
 244              'type-error)
 245          :datum object
 246          :expected-type type))
 247
 248 (deferr layout-invalid-error (object layout)
 249   (error 'layout-invalid
 250          :datum object
 251          :expected-type (layout-classoid layout)))
 252
 253 (deferr odd-key-args-error ()
 254   (error 'simple-program-error
 255          :format-control "odd number of &KEY arguments"))
 256
 257 (deferr unknown-key-arg-error (key-name)
 258   (error 'simple-program-error
 259          :format-control "unknown &KEY argument: ~S"
 260          :format-arguments (list key-name)))
 261
 262 (deferr invalid-array-index-error (array bound index)
 263   (error 'simple-type-error
 264          :format-control
 265          "invalid array index ~W for ~S (should be nonnegative and <~W)"
 266          :format-arguments (list index array bound)
 267          :datum index
 268          :expected-type `(integer 0 (,bound))))
 269
 270 (deferr object-not-simple-array-error (object)
 271   (error 'type-error
 272          :datum object
 273          :expected-type 'simple-array))
 274
 275 (deferr object-not-signed-byte-32-error (object)
 276   (error 'type-error
 277          :datum object
 278          :expected-type '(signed-byte 32)))
 279
 280 (deferr object-not-unsigned-byte-32-error (object)
 281   (error 'type-error
 282          :datum object
 283          :expected-type '(unsigned-byte 32)))
 284
 285 (macrolet
 286     ((define-simple-array-internal-errors ()
 287          `(progn
 288            ,@(map 'list
 289                   (lambda (saetp)
 290                     `(deferr ,(symbolicate
 291                                "OBJECT-NOT-"
 292                                (sb!vm:saetp-primitive-type-name saetp)
 293                                "-ERROR")
 294                               (object)
 295                       (error 'type-error
 296                              :datum object
 297                              :expected-type '(simple-array
 298                                               ,(sb!vm:saetp-specifier saetp)
 299                                               (*)))))
 300                   sb!vm:*specialized-array-element-type-properties*))))
 301   (define-simple-array-internal-errors))
 302
 303 (deferr object-not-complex-error (object)
 304   (error 'type-error
 305          :datum object
 306          :expected-type 'complex))
 307
 308 (deferr object-not-complex-rational-error (object)
 309   (error 'type-error
 310          :datum object
 311          :expected-type '(complex rational)))
 312
 313 (deferr object-not-complex-single-float-error (object)
 314   (error 'type-error
 315          :datum object
 316          :expected-type '(complex single-float)))
 317
 318 (deferr object-not-complex-double-float-error (object)
 319   (error 'type-error
 320          :datum object
 321          :expected-type '(complex double-float)))
 322
 323 #!+long-float
 324 (deferr object-not-complex-long-float-error (object)
 325   (error 'type-error
 326          :datum object
 327          :expected-type '(complex long-float)))
 328
 329 (deferr object-not-weak-pointer-error (object)
 330   (error 'type-error
 331          :datum object
 332          :expected-type 'weak-pointer))
 333
 334 (deferr object-not-instance-error (object)
 335   (error 'type-error
 336          :datum object
 337          :expected-type 'instance))
 338
 339 (deferr object-not-complex-vector-error (object)
 340   (error 'type-error
 341          :datum object
 342          :expected-type '(and vector (not simple-array))))
 343 \f
 344 ;;;; fetching errorful function name
 345
 346 ;;; This flag is used to prevent infinite recursive lossage when
 347 ;;; we can't find the caller for some reason.
 348 (defvar *finding-name* nil)
 349
 350 (defun find-caller-name-and-frame ()
 351   (if *finding-name*
 352       (values "<error finding caller name -- already finding name>" nil)
 353       (handler-case
 354           (let* ((*finding-name* t)
 355                  (frame (sb!di:frame-down (sb!di:frame-down (sb!di:top-frame))))
 356                  (name (sb!di:debug-fun-name
 357                         (sb!di:frame-debug-fun frame))))
 358             (sb!di:flush-frames-above frame)
 359             (values name frame))
 360         (error ()
 361           (values "<error finding caller name -- trapped error>" nil))
 362         (sb!di:debug-condition ()
 363           (values "<error finding caller name -- trapped debug-condition>"
 364                   nil)))))
 365
 366 (defun find-interrupted-name-and-frame ()
 367   (/show0 "entering FIND-INTERRUPTED-NAME-AND-FRAME")
 368   (if *finding-name*
 369       (values "<error finding interrupted name -- already finding name>" nil)
 370       (handler-case
 371           (let ((*finding-name* t))
 372             (/show0 "in ordinary case")
 373             (do ((frame (sb!di:top-frame) (sb!di:frame-down frame)))
 374                 ((null frame)
 375                  (/show0 "null frame")
 376                  (values "<error finding interrupted name -- null frame>" nil))
 377               (/show0 "at head of DO loop")
 378               (when (and (sb!di::compiled-frame-p frame)
 379                          (sb!di::compiled-frame-escaped frame))
 380                 (sb!di:flush-frames-above frame)
 381                 (/show0 "returning from within DO loop")
 382                 (return (values (sb!di:debug-fun-name
 383                                  (sb!di:frame-debug-fun frame))
 384                                 frame)))))
 385         (error ()
 386           (/show0 "trapped ERROR")
 387           (values "<error finding interrupted name -- trapped error>" nil))
 388         (sb!di:debug-condition ()
 389           (/show0 "trapped DEBUG-CONDITION")
 390           (values "<error finding interrupted name -- trapped debug-condition>"
 391                   nil)))))
 392 \f
 393
 394 ;;; Special variable to store away the signal context passed to
 395 ;;; internal error. internal-error stores the context for use by
 396 ;;; sb-di:top-frame to figure out what the frame pointer and pc were
 397 ;;; when the error was signalled. This is done since on some platforms
 398 ;;; we have problems tracing through signal handler frames.
 399 (defparameter *internal-error-context* nil)
 400
 401 ;;;; INTERNAL-ERROR signal handler
 402
 403 (defun internal-error (context continuable)
 404   (declare (type system-area-pointer context))
 405   (declare (ignore continuable))
 406   (let ((*internal-error-context* context))
 407     (/show0 "entering INTERNAL-ERROR, CONTEXT=..")
 408     (/hexstr context)
 409     (infinite-error-protect
 410      (/show0 "about to bind ALIEN-CONTEXT")
 411      (let ((alien-context (locally
 412                               (declare (optimize (inhibit-warnings 3)))
 413                             (sb!alien:sap-alien context (* os-context-t)))))
 414        (/show0 "about to bind ERROR-NUMBER and ARGUMENTS")
 415        (multiple-value-bind (error-number arguments)
 416            (sb!vm:internal-error-args alien-context)
 417
 418          ;; There's a limit to how much error reporting we can usefully
 419          ;; do before initialization is complete, but try to be a little
 420          ;; bit helpful before we die.
 421          (/show0 "back from INTERNAL-ERROR-ARGS, ERROR-NUMBER=..")
 422          (/hexstr error-number)
 423          (/show0 "cold/low ARGUMENTS=..")
 424          (/hexstr arguments)
 425          (unless *cold-init-complete-p*
 426            (%primitive print "can't recover from error in cold init, halting")
 427            (%primitive sb!c:halt))
 428
 429          (multiple-value-bind (name sb!debug:*stack-top-hint*)
 430              (find-interrupted-name-and-frame)
 431            (/show0 "back from FIND-INTERRUPTED-NAME")
 432            (let ((fp (int-sap (sb!vm:context-register alien-context
 433                                                       sb!vm::cfp-offset)))
 434                  (handler (and (< -1 error-number (length *internal-errors*))
 435                                (svref *internal-errors* error-number))))
 436              (cond ((null handler)
 437                     (error 'simple-error
 438                            :format-control
 439                            "unknown internal error, ~D, args=~S"
 440                            :format-arguments
 441                            (list error-number
 442                                  (mapcar (lambda (sc-offset)
 443                                            (sb!di::sub-access-debug-var-slot
 444                                             fp sc-offset alien-context))
 445                                          arguments))))
 446                    ((not (functionp handler))
 447                     (error 'simple-error
 448                            :format-control "internal error ~D: ~A; args=~S"
 449                            :format-arguments
 450                            (list error-number
 451                                  handler
 452                                  (mapcar (lambda (sc-offset)
 453                                            (sb!di::sub-access-debug-var-slot
 454                                             fp sc-offset alien-context))
 455                                          arguments))))
 456                    (t
 457                     (funcall handler name fp alien-context arguments))))))))))
 458
 459 (defun control-stack-exhausted-error ()
 460   (let ((sb!debug:*stack-top-hint* nil))
 461     (infinite-error-protect
 462      (format *error-output*
 463              "Control stack guard page temporarily disabled: proceed with caution~%")
 464      (error 'control-stack-exhausted))))
 465
 466 ;;; KLUDGE: we keep a single HEAP-EXHAUSTED-ERROR object around, so
 467 ;;; that we don't need to allocate it when running out of memory. Similarly
 468 ;;; we pass the amounts in special variables as there may be multiple threads
 469 ;;; running into trouble at the same time. The condition is created by GC-REINIT.
 470 (defvar *heap-exhausted-error-condition*)
 471 (defvar *heap-exhausted-error-available-bytes*)
 472 (defvar *heap-exhausted-error-requested-bytes*)
 473
 474 (defun heap-exhausted-error (available requested)
 475   (infinite-error-protect
 476    (let ((*heap-exhausted-error-available-bytes* available)
 477          (*heap-exhausted-error-requested-bytes* requested))
 478      (error *heap-exhausted-error-condition*))))
 479
 480 (defun undefined-alien-variable-error ()
 481   (error 'undefined-alien-variable-error))
 482
 483 (defun undefined-alien-function-error ()
 484   (error 'undefined-alien-function-error))
 485
 486 #!-win32
 487 (define-alien-variable current-memory-fault-address long)
 488
 489 #!-win32
 490 (defun memory-fault-error ()
 491   (error 'memory-fault-error
 492          :address current-memory-fault-address))
 493
 494 ;;; This is SIGTRAP / EXCEPTION_BREAKPOINT that runtime could not deal
 495 ;;; with. Prior to Windows we just had a Lisp side handler for
 496 ;;; SIGTRAP, but now we need to deal this portably.
 497 (defun unhandled-trap-error (context-sap)
 498   (declare (type system-area-pointer context-sap))
 499   (infinite-error-protect
 500    (let ((context (sap-alien context-sap (* os-context-t))))
 501      (error "Unhandled breakpoint/trap at #x~X."
 502             (sap-int (sb!vm:context-pc context))))))