src/code/interr.lisp

   1 ;;;; functions and macros to define and deal with internal errors
   2 ;;;; (i.e. problems that can be signaled from assembler code)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14 \f
  15 ;;;; internal errors
  16
  17 (defvar *internal-errors*
  18   #.(map 'vector #'cdr sb!c:*backend-internal-errors*))
  19
  20 (eval-when (:compile-toplevel :execute)
  21
  22 (sb!xc:defmacro deferr (name args &rest body)
  23   (let* ((rest-pos (position '&rest args))
  24          (required (if rest-pos (subseq args 0 rest-pos) args))
  25          (fn-name (symbolicate name "-HANDLER")))
  26     (with-unique-names (fp context sc-offsets)
  27       `(progn
  28          ;; FIXME: Having a separate full DEFUN for each error doesn't
  29          ;; seem to add much value, and it takes a lot of space. Perhaps
  30          ;; we could do this dispatch with a big CASE statement instead?
  31          (defun ,fn-name (name ,fp ,context ,sc-offsets)
  32            ;; FIXME: It would probably be good to do *STACK-TOP-HINT*
  33            ;; tricks to hide this internal error-handling logic from the
  34            ;; poor high level user, so his debugger tells him about
  35            ;; where his error was detected instead of telling him where
  36            ;; he ended up inside the system error-handling logic.
  37            (declare (ignorable name ,fp ,context ,sc-offsets))
  38            (let (,@(let ((offset -1))
  39                         (mapcar (lambda (var)
  40                                   `(,var (sb!di::sub-access-debug-var-slot
  41                                           ,fp
  42                                           (nth ,(incf offset)
  43                                            ,sc-offsets)
  44                                           ,context)))
  45                                 required))
  46                  ,@(when rest-pos
  47                      `((,(nth (1+ rest-pos) args)
  48                         (mapcar (lambda (sc-offset)
  49                                   (sb!di::sub-access-debug-var-slot
  50                                    ,fp
  51                                    sc-offset
  52                                    ,context))
  53                          (nthcdr ,rest-pos ,sc-offsets))))))
  54              ,@body))
  55         (setf (svref *internal-errors* ,(error-number-or-lose name))
  56               #',fn-name)))))
  57
  58 ) ; EVAL-WHEN
  59
  60 (deferr unknown-error (&rest args)
  61   (error "unknown error:~{ ~S~})" args))
  62
  63 (deferr object-not-fun-error (object)
  64   (error 'type-error
  65          :datum object
  66          :expected-type 'function))
  67
  68 (deferr object-not-list-error (object)
  69   (error 'type-error
  70          :datum object
  71          :expected-type 'list))
  72
  73 (deferr object-not-bignum-error (object)
  74   (error 'type-error
  75          :datum object
  76          :expected-type 'bignum))
  77
  78 (deferr object-not-ratio-error (object)
  79   (error 'type-error
  80          :datum object
  81          :expected-type 'ratio))
  82
  83 (deferr object-not-single-float-error (object)
  84   (error 'type-error
  85          :datum object
  86          :expected-type 'single-float))
  87
  88 (deferr object-not-double-float-error (object)
  89   (error 'type-error
  90          :datum object
  91          :expected-type 'double-float))
  92
  93 #!+long-float
  94 (deferr object-not-long-float-error (object)
  95   (error 'type-error
  96          :datum object
  97          :expected-type 'long-float))
  98
  99 (deferr object-not-simple-string-error (object)
 100   (error 'type-error
 101          :datum object
 102          :expected-type 'simple-string))
 103
 104 (deferr object-not-fixnum-error (object)
 105   (error 'type-error
 106          :datum object
 107          :expected-type 'fixnum))
 108
 109 (deferr object-not-vector-error (object)
 110   (error 'type-error
 111          :datum object
 112          :expected-type 'vector))
 113
 114 (deferr object-not-string-error (object)
 115   (error 'type-error
 116          :datum object
 117          :expected-type 'string))
 118
 119 (deferr object-not-base-string-error (object)
 120   (error 'type-error
 121          :datum object
 122          :expected-type 'base-string))
 123
 124 (deferr object-not-vector-nil-error (object)
 125   (error 'type-error
 126          :datum object
 127          :expected-type '(vector nil)))
 128
 129 #!+sb-unicode
 130 (deferr object-not-character-string-error (object)
 131   (error 'type-error
 132          :datum object
 133          :expected-type '(vector character)))
 134
 135 (deferr object-not-bit-vector-error (object)
 136   (error 'type-error
 137          :datum object
 138          :expected-type 'bit-vector))
 139
 140 (deferr object-not-array-error (object)
 141   (error 'type-error
 142          :datum object
 143          :expected-type 'array))
 144
 145 (deferr object-not-number-error (object)
 146   (error 'type-error
 147          :datum object
 148          :expected-type 'number))
 149
 150 (deferr object-not-rational-error (object)
 151   (error 'type-error
 152          :datum object
 153          :expected-type 'rational))
 154
 155 (deferr object-not-float-error (object)
 156   (error 'type-error
 157          :datum object
 158          :expected-type 'float))
 159
 160 (deferr object-not-real-error (object)
 161   (error 'type-error
 162          :datum object
 163          :expected-type 'real))
 164
 165 (deferr object-not-integer-error (object)
 166   (error 'type-error
 167          :datum object
 168          :expected-type 'integer))
 169
 170 (deferr object-not-cons-error (object)
 171   (error 'type-error
 172          :datum object
 173          :expected-type 'cons))
 174
 175 (deferr object-not-symbol-error (object)
 176   (error 'type-error
 177          :datum object
 178          :expected-type 'symbol))
 179
 180 (deferr undefined-fun-error (fdefn-or-symbol)
 181   (error 'undefined-function
 182          :name (etypecase fdefn-or-symbol
 183                  (symbol fdefn-or-symbol)
 184                  (fdefn (fdefn-name fdefn-or-symbol)))))
 185
 186 (deferr invalid-arg-count-error (nargs)
 187   (error 'simple-program-error
 188          :format-control "invalid number of arguments: ~S"
 189          :format-arguments (list nargs)))
 190
 191 (deferr bogus-arg-to-values-list-error (list)
 192   (error 'simple-type-error
 193          :datum list
 194          :expected-type 'list
 195          :format-control
 196          "~@<attempt to use VALUES-LIST on a dotted list: ~2I~_~S~:>"
 197          :format-arguments (list list)))
 198
 199 (deferr unbound-symbol-error (symbol)
 200   (error 'unbound-variable :name symbol))
 201
 202 (deferr object-not-character-error (object)
 203   (error 'type-error
 204          :datum object
 205          :expected-type 'character))
 206
 207 (deferr object-not-sap-error (object)
 208   (error 'type-error
 209          :datum object
 210          :expected-type 'system-area-pointer))
 211
 212 (deferr invalid-unwind-error ()
 213   (error 'simple-control-error
 214          :format-control
 215          "attempt to RETURN-FROM a block or GO to a tag that no longer exists"
 216          ))
 217
 218 (deferr unseen-throw-tag-error (tag)
 219   (error 'simple-control-error
 220          :format-control "attempt to THROW to a tag that does not exist: ~S"
 221          :format-arguments (list tag)))
 222
 223 (deferr nil-fun-returned-error (function)
 224   (error 'simple-control-error
 225          :format-control
 226          "A function with declared result type NIL returned:~%  ~S"
 227          :format-arguments (list function)))
 228
 229 (deferr nil-array-accessed-error (array)
 230   (error 'nil-array-accessed-error
 231          :datum array :expected-type '(not (array nil))))
 232
 233 (deferr division-by-zero-error (this that)
 234   (error 'division-by-zero
 235          :operation 'division
 236          :operands (list this that)))
 237
 238 (deferr object-not-type-error (object type)
 239   (if (invalid-array-p object)
 240       (invalid-array-error object)
 241       (error (if (and (%instancep object)
 242                       (layout-invalid (%instance-layout object)))
 243                  'layout-invalid
 244                  'type-error)
 245              :datum object
 246              :expected-type type)))
 247
 248 (deferr layout-invalid-error (object layout)
 249   (error 'layout-invalid
 250          :datum object
 251          :expected-type (layout-classoid layout)))
 252
 253 (deferr odd-key-args-error ()
 254   (error 'simple-program-error
 255          :format-control "odd number of &KEY arguments"))
 256
 257 (deferr unknown-key-arg-error (key-name)
 258   (error 'simple-program-error
 259          :format-control "unknown &KEY argument: ~S"
 260          :format-arguments (list key-name)))
 261
 262 (deferr invalid-array-index-error (array bound index)
 263   (invalid-array-index-error array index bound))
 264
 265 (deferr object-not-simple-array-error (object)
 266   (error 'type-error
 267          :datum object
 268          :expected-type 'simple-array))
 269
 270 (deferr object-not-signed-byte-32-error (object)
 271   (error 'type-error
 272          :datum object
 273          :expected-type '(signed-byte 32)))
 274
 275 (deferr object-not-unsigned-byte-32-error (object)
 276   (error 'type-error
 277          :datum object
 278          :expected-type '(unsigned-byte 32)))
 279
 280 (deferr tls-exhausted-error ()
 281   ;; There is nothing we can do about it. A number of entries in the
 282   ;; tls could be reserved and made available for recovery but since
 283   ;; tls indices are never reused it would be kind of silly and
 284   ;; without it signalling an error is more than likely to end in a
 285   ;; recursive error.
 286   (%primitive print "Thread local storage exhausted.")
 287   (sb!impl::%halt))
 288
 289 (macrolet
 290     ((define-simple-array-internal-errors ()
 291          `(progn
 292            ,@(map 'list
 293                   (lambda (saetp)
 294                     `(deferr ,(symbolicate
 295                                "OBJECT-NOT-"
 296                                (sb!vm:saetp-primitive-type-name saetp)
 297                                "-ERROR")
 298                               (object)
 299                       (error 'type-error
 300                              :datum object
 301                              :expected-type '(simple-array
 302                                               ,(sb!vm:saetp-specifier saetp)
 303                                               (*)))))
 304                   sb!vm:*specialized-array-element-type-properties*))))
 305   (define-simple-array-internal-errors))
 306
 307 (deferr object-not-complex-error (object)
 308   (error 'type-error
 309          :datum object
 310          :expected-type 'complex))
 311
 312 (deferr object-not-complex-rational-error (object)
 313   (error 'type-error
 314          :datum object
 315          :expected-type '(complex rational)))
 316
 317 (deferr object-not-complex-single-float-error (object)
 318   (error 'type-error
 319          :datum object
 320          :expected-type '(complex single-float)))
 321
 322 (deferr object-not-complex-double-float-error (object)
 323   (error 'type-error
 324          :datum object
 325          :expected-type '(complex double-float)))
 326
 327 #!+long-float
 328 (deferr object-not-complex-long-float-error (object)
 329   (error 'type-error
 330          :datum object
 331          :expected-type '(complex long-float)))
 332
 333 #!+sb-simd-pack
 334 (deferr object-not-simd-pack-error (object)
 335   (error 'type-error
 336          :datum object
 337          :expected-type 'simd-pack))
 338
 339 (deferr object-not-weak-pointer-error (object)
 340   (error 'type-error
 341          :datum object
 342          :expected-type 'weak-pointer))
 343
 344 (deferr object-not-instance-error (object)
 345   (error 'type-error
 346          :datum object
 347          :expected-type 'instance))
 348
 349 (deferr object-not-complex-vector-error (object)
 350   (error 'type-error
 351          :datum object
 352          :expected-type '(and vector (not simple-array))))
 353 \f
 354 ;;;; fetching errorful function name
 355
 356 ;;; This flag is used to prevent infinite recursive lossage when
 357 ;;; we can't find the caller for some reason.
 358 (defvar *finding-name* nil)
 359
 360 (defun find-caller-name-and-frame ()
 361   (if *finding-name*
 362       (values "<error finding caller name -- already finding name>" nil)
 363       (handler-case
 364           (let* ((*finding-name* t)
 365                  (frame (sb!di:frame-down (sb!di:frame-down (sb!di:top-frame))))
 366                  (name (sb!di:debug-fun-name
 367                         (sb!di:frame-debug-fun frame))))
 368             (sb!di:flush-frames-above frame)
 369             (values name frame))
 370         (error ()
 371           (values "<error finding caller name -- trapped error>" nil))
 372         (sb!di:debug-condition ()
 373           (values "<error finding caller name -- trapped debug-condition>"
 374                   nil)))))
 375
 376 (defun find-interrupted-name-and-frame ()
 377   (/show0 "entering FIND-INTERRUPTED-NAME-AND-FRAME")
 378   (if *finding-name*
 379       (values "<error finding interrupted name -- already finding name>" nil)
 380       (handler-case
 381           (let ((*finding-name* t))
 382             (/show0 "in ordinary case")
 383             (do ((frame (sb!di:top-frame) (sb!di:frame-down frame)))
 384                 ((null frame)
 385                  (/show0 "null frame")
 386                  (values "<error finding interrupted name -- null frame>" nil))
 387               (/show0 "at head of DO loop")
 388               (when (and (sb!di::compiled-frame-p frame)
 389                          (sb!di::compiled-frame-escaped frame))
 390                 (sb!di:flush-frames-above frame)
 391                 (/show0 "returning from within DO loop")
 392                 (return (values (sb!di:debug-fun-name
 393                                  (sb!di:frame-debug-fun frame))
 394                                 frame)))))
 395         (error ()
 396           (/show0 "trapped ERROR")
 397           (values "<error finding interrupted name -- trapped error>" nil))
 398         (sb!di:debug-condition ()
 399           (/show0 "trapped DEBUG-CONDITION")
 400           (values "<error finding interrupted name -- trapped debug-condition>"
 401                   nil)))))
 402
 403 (defun find-caller-of-named-frame (name)
 404   (unless *finding-name*
 405     (handler-case
 406         (let ((*finding-name* t))
 407           (do ((frame (sb!di:top-frame) (sb!di:frame-down frame)))
 408               ((null frame))
 409             (when (and (sb!di::compiled-frame-p frame)
 410                        (eq name (sb!di:debug-fun-name
 411                                  (sb!di:frame-debug-fun frame))))
 412               (let ((caller (sb!di:frame-down frame)))
 413                 (sb!di:flush-frames-above caller)
 414                 (return caller)))))
 415       ((or error sb!di:debug-condition) ()
 416         nil)
 417       (sb!di:debug-condition ()
 418         nil))))
 419 \f
 420
 421 ;;;; INTERNAL-ERROR signal handler
 422
 423 (defun internal-error (context continuable)
 424   (declare (type system-area-pointer context))
 425   (declare (ignore continuable))
 426   (/show0 "entering INTERNAL-ERROR, CONTEXT=..")
 427   (/hexstr context)
 428   (infinite-error-protect
 429    (/show0 "about to bind ALIEN-CONTEXT")
 430    (let* ((alien-context (locally
 431                              (declare (optimize (inhibit-warnings 3)))
 432                            (sb!alien:sap-alien context (* os-context-t))))
 433           #!+c-stack-is-control-stack
 434           (*saved-fp-and-pcs*
 435            (cons (cons (%make-lisp-obj (sb!vm:context-register
 436                                         alien-context
 437                                         sb!vm::cfp-offset))
 438                        (sb!vm:context-pc alien-context))
 439                  (when (boundp '*saved-fp-and-pcs*)
 440                    *saved-fp-and-pcs*))))
 441      (declare (truly-dynamic-extent *saved-fp-and-pcs*))
 442      (/show0 "about to bind ERROR-NUMBER and ARGUMENTS")
 443      (multiple-value-bind (error-number arguments)
 444          (sb!vm:internal-error-args alien-context)
 445
 446        ;; There's a limit to how much error reporting we can usefully
 447        ;; do before initialization is complete, but try to be a little
 448        ;; bit helpful before we die.
 449        (/show0 "back from INTERNAL-ERROR-ARGS, ERROR-NUMBER=..")
 450        (/hexstr error-number)
 451        (/show0 "cold/low ARGUMENTS=..")
 452        (/hexstr arguments)
 453        (unless *cold-init-complete-p*
 454          (%primitive print "can't recover from error in cold init, halting")
 455          (%primitive sb!c:halt))
 456
 457        (with-interrupt-bindings
 458          (multiple-value-bind (name sb!debug:*stack-top-hint*)
 459              (find-interrupted-name-and-frame)
 460            (/show0 "back from FIND-INTERRUPTED-NAME")
 461            (let ((fp (int-sap (sb!vm:context-register alien-context
 462                                                       sb!vm::cfp-offset)))
 463                  (handler (and (< -1 error-number (length *internal-errors*))
 464                                (svref *internal-errors* error-number))))
 465              (cond ((null handler)
 466                     (error 'simple-error
 467                            :format-control
 468                            "unknown internal error, ~D, args=~S"
 469                            :format-arguments
 470                            (list error-number
 471                                  (mapcar (lambda (sc-offset)
 472                                            (sb!di::sub-access-debug-var-slot
 473                                             fp sc-offset alien-context))
 474                                          arguments))))
 475                    ((not (functionp handler))
 476                     (error 'simple-error
 477                            :format-control "internal error ~D: ~A; args=~S"
 478                            :format-arguments
 479                            (list error-number
 480                                  handler
 481                                  (mapcar (lambda (sc-offset)
 482                                            (sb!di::sub-access-debug-var-slot
 483                                             fp sc-offset alien-context))
 484                                          arguments))))
 485                    (t
 486                     (funcall handler name fp alien-context arguments))))))))))
 487
 488 (defun control-stack-exhausted-error ()
 489   (let ((sb!debug:*stack-top-hint* nil))
 490     (infinite-error-protect
 491      (format *error-output*
 492              "Control stack guard page temporarily disabled: proceed with caution~%")
 493      (error 'control-stack-exhausted))))
 494
 495 (defun binding-stack-exhausted-error ()
 496   (let ((sb!debug:*stack-top-hint* nil))
 497     (infinite-error-protect
 498      (format *error-output*
 499              "Binding stack guard page temporarily disabled: proceed with caution~%")
 500      (error 'binding-stack-exhausted))))
 501
 502 (defun alien-stack-exhausted-error ()
 503   (let ((sb!debug:*stack-top-hint* nil))
 504     (infinite-error-protect
 505      (format *error-output*
 506              "Alien stack guard page temporarily disabled: proceed with caution~%")
 507      (error 'alien-stack-exhausted))))
 508
 509 ;;; KLUDGE: we keep a single HEAP-EXHAUSTED-ERROR object around, so
 510 ;;; that we don't need to allocate it when running out of
 511 ;;; memory. Similarly we pass the amounts in special variables as
 512 ;;; there may be multiple threads running into trouble at the same
 513 ;;; time. The condition is created by GC-REINIT.
 514 (defvar *heap-exhausted-error-condition*)
 515 (defvar *heap-exhausted-error-available-bytes*)
 516 (defvar *heap-exhausted-error-requested-bytes*)
 517
 518 (defun heap-exhausted-error (available requested)
 519   (infinite-error-protect
 520    (let ((*heap-exhausted-error-available-bytes* available)
 521          (*heap-exhausted-error-requested-bytes* requested))
 522      (error *heap-exhausted-error-condition*))))
 523
 524 (defun undefined-alien-variable-error ()
 525   (error 'undefined-alien-variable-error))
 526
 527 (defun undefined-alien-function-error ()
 528   (error 'undefined-alien-function-error))
 529
 530 #!-win32
 531 (define-alien-variable current-memory-fault-address unsigned)
 532
 533 #!-win32
 534 (defun memory-fault-error ()
 535   (error 'memory-fault-error
 536          :address current-memory-fault-address))
 537
 538 ;;; This is SIGTRAP / EXCEPTION_BREAKPOINT that runtime could not deal
 539 ;;; with. Prior to Windows we just had a Lisp side handler for
 540 ;;; SIGTRAP, but now we need to deal with this portably.
 541 (defun unhandled-trap-error (context-sap)
 542   (declare (type system-area-pointer context-sap))
 543   (infinite-error-protect
 544    (let ((context (sap-alien context-sap (* os-context-t))))
 545      (error 'breakpoint-error
 546             :context context
 547             :address (sap-int (sb!vm:context-pc context))))))