src/code/irrat.lisp

   1 ;;;; This file contains all the irrational functions. (Actually, most
   2 ;;;; of the work is done by calling out to C.)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14 \f
  15 ;;;; miscellaneous constants, utility functions, and macros
  16
  17 (defconstant pi 3.14159265358979323846264338327950288419716939937511L0)
  18 ;(defconstant e 2.71828182845904523536028747135266249775724709369996L0)
  19
  20 ;;; Make these INLINE, since the call to C is at least as compact as a
  21 ;;; Lisp call, and saves number consing to boot.
  22 (eval-when (:compile-toplevel :execute)
  23
  24 (sb!xc:defmacro def-math-rtn (name num-args)
  25   (let ((function (symbolicate "%" (string-upcase name))))
  26     `(progn
  27        (proclaim '(inline ,function))
  28        (sb!alien:def-alien-routine (,name ,function) double-float
  29          ,@(let ((results nil))
  30              (dotimes (i num-args (nreverse results))
  31                (push (list (intern (format nil "ARG-~D" i))
  32                            'double-float)
  33                      results)))))))
  34
  35 (defun handle-reals (function var)
  36   `((((foreach fixnum single-float bignum ratio))
  37      (coerce (,function (coerce ,var 'double-float)) 'single-float))
  38     ((double-float)
  39      (,function ,var))))
  40
  41 ) ; EVAL-WHEN
  42 \f
  43 ;;;; stubs for the Unix math library
  44
  45 ;;; Please refer to the Unix man pages for details about these routines.
  46
  47 ;;; trigonometric
  48 #!-x86 (def-math-rtn "sin" 1)
  49 #!-x86 (def-math-rtn "cos" 1)
  50 #!-x86 (def-math-rtn "tan" 1)
  51 (def-math-rtn "asin" 1)
  52 (def-math-rtn "acos" 1)
  53 #!-x86 (def-math-rtn "atan" 1)
  54 #!-x86 (def-math-rtn "atan2" 2)
  55 (def-math-rtn "sinh" 1)
  56 (def-math-rtn "cosh" 1)
  57 (def-math-rtn "tanh" 1)
  58 (def-math-rtn "asinh" 1)
  59 (def-math-rtn "acosh" 1)
  60 (def-math-rtn "atanh" 1)
  61
  62 ;;; exponential and logarithmic
  63 #!-x86 (def-math-rtn "exp" 1)
  64 #!-x86 (def-math-rtn "log" 1)
  65 #!-x86 (def-math-rtn "log10" 1)
  66 (def-math-rtn "pow" 2)
  67 #!-x86 (def-math-rtn "sqrt" 1)
  68 (def-math-rtn "hypot" 2)
  69 #!-(or hpux x86) (def-math-rtn "log1p" 1)
  70
  71 #!+x86 ;; These are needed for use by byte-compiled files.
  72 (progn
  73   (defun %sin (x)
  74     (declare (double-float x)
  75              (values double-float))
  76     (%sin x))
  77   (defun %sin-quick (x)
  78     (declare (double-float x)
  79              (values double-float))
  80     (%sin-quick x))
  81   (defun %cos (x)
  82     (declare (double-float x)
  83              (values double-float))
  84     (%cos x))
  85   (defun %cos-quick (x)
  86     (declare (double-float x)
  87              (values double-float))
  88     (%cos-quick x))
  89   (defun %tan (x)
  90     (declare (double-float x)
  91              (values double-float))
  92     (%tan x))
  93   (defun %tan-quick (x)
  94     (declare (double-float x)
  95              (values double-float))
  96     (%tan-quick x))
  97   (defun %atan (x)
  98     (declare (double-float x)
  99              (values double-float))
 100     (%atan x))
 101   (defun %atan2 (x y)
 102     (declare (double-float x y)
 103              (values double-float))
 104     (%atan2 x y))
 105   (defun %exp (x)
 106     (declare (double-float x)
 107              (values double-float))
 108     (%exp x))
 109   (defun %log (x)
 110     (declare (double-float x)
 111              (values double-float))
 112     (%log x))
 113   (defun %log10 (x)
 114     (declare (double-float x)
 115              (values double-float))
 116     (%log10 x))
 117   #+nil ;; notyet
 118   (defun %pow (x y)
 119     (declare (type (double-float 0d0) x)
 120              (double-float y)
 121              (values (double-float 0d0)))
 122     (%pow x y))
 123   (defun %sqrt (x)
 124     (declare (double-float x)
 125              (values double-float))
 126     (%sqrt x))
 127   (defun %scalbn (f ex)
 128     (declare (double-float f)
 129              (type (signed-byte 32) ex)
 130              (values double-float))
 131     (%scalbn f ex))
 132   (defun %scalb (f ex)
 133     (declare (double-float f ex)
 134              (values double-float))
 135     (%scalb f ex))
 136   (defun %logb (x)
 137     (declare (double-float x)
 138              (values double-float))
 139     (%logb x))
 140   (defun %log1p (x)
 141     (declare (double-float x)
 142              (values double-float))
 143     (%log1p x))
 144   ) ; progn
 145 \f
 146 ;;;; power functions
 147
 148 (defun exp (number)
 149   #!+sb-doc
 150   "Return e raised to the power NUMBER."
 151   (number-dispatch ((number number))
 152     (handle-reals %exp number)
 153     ((complex)
 154      (* (exp (realpart number))
 155         (cis (imagpart number))))))
 156
 157 ;;; INTEXP -- Handle the rational base, integer power case.
 158
 159 ;;; FIXME: As long as the system dies on stack overflow or memory
 160 ;;; exhaustion, it seems reasonable to have this, but its default
 161 ;;; should be NIL, and when it's NIL, anything should be accepted.
 162 (defparameter *intexp-maximum-exponent* 10000)
 163
 164 ;;; This function precisely calculates base raised to an integral
 165 ;;; power. It separates the cases by the sign of power, for efficiency
 166 ;;; reasons, as powers can be calculated more efficiently if power is
 167 ;;; a positive integer. Values of power are calculated as positive
 168 ;;; integers, and inverted if negative.
 169 (defun intexp (base power)
 170   (when (> (abs power) *intexp-maximum-exponent*)
 171     ;; FIXME: should be ordinary error, not CERROR. (Once we set the
 172     ;; default for the variable to NIL, the un-continuable error will
 173     ;; be less obnoxious.)
 174     (cerror "Continue with calculation."
 175             "The absolute value of ~S exceeds ~S."
 176             power '*intexp-maximum-exponent* base power))
 177   (cond ((minusp power)
 178          (/ (intexp base (- power))))
 179         ((eql base 2)
 180          (ash 1 power))
 181         (t
 182          (do ((nextn (ash power -1) (ash power -1))
 183               (total (if (oddp power) base 1)
 184                      (if (oddp power) (* base total) total)))
 185              ((zerop nextn) total)
 186            (setq base (* base base))
 187            (setq power nextn)))))
 188
 189 ;;; If an integer power of a rational, use INTEXP above. Otherwise, do
 190 ;;; floating point stuff. If both args are real, we try %POW right
 191 ;;; off, assuming it will return 0 if the result may be complex. If
 192 ;;; so, we call COMPLEX-POW which directly computes the complex
 193 ;;; result. We also separate the complex-real and real-complex cases
 194 ;;; from the general complex case.
 195 (defun expt (base power)
 196   #!+sb-doc
 197   "Returns BASE raised to the POWER."
 198   (if (zerop power)
 199       (1+ (* base power))
 200     (labels (;; determine if the double float is an integer.
 201              ;;  0 - not an integer
 202              ;;  1 - an odd int
 203              ;;  2 - an even int
 204              (isint (ihi lo)
 205                (declare (type (unsigned-byte 31) ihi)
 206                         (type (unsigned-byte 32) lo)
 207                         (optimize (speed 3) (safety 0)))
 208                (let ((isint 0))
 209                  (declare (type fixnum isint))
 210                  (cond ((>= ihi #x43400000)     ; exponent >= 53
 211                         (setq isint 2))
 212                        ((>= ihi #x3ff00000)
 213                         (let ((k (- (ash ihi -20) #x3ff)))      ; exponent
 214                           (declare (type (mod 53) k))
 215                           (cond ((> k 20)
 216                                  (let* ((shift (- 52 k))
 217                                         (j (logand (ash lo (- shift))))
 218                                         (j2 (ash j shift)))
 219                                    (declare (type (mod 32) shift)
 220                                             (type (unsigned-byte 32) j j2))
 221                                    (when (= j2 lo)
 222                                      (setq isint (- 2 (logand j 1))))))
 223                                 ((= lo 0)
 224                                  (let* ((shift (- 20 k))
 225                                         (j (ash ihi (- shift)))
 226                                         (j2 (ash j shift)))
 227                                    (declare (type (mod 32) shift)
 228                                             (type (unsigned-byte 31) j j2))
 229                                    (when (= j2 ihi)
 230                                      (setq isint (- 2 (logand j 1))))))))))
 231                  isint))
 232              (real-expt (x y rtype)
 233                (let ((x (coerce x 'double-float))
 234                      (y (coerce y 'double-float)))
 235                  (declare (double-float x y))
 236                  (let* ((x-hi (sb!kernel:double-float-high-bits x))
 237                         (x-lo (sb!kernel:double-float-low-bits x))
 238                         (x-ihi (logand x-hi #x7fffffff))
 239                         (y-hi (sb!kernel:double-float-high-bits y))
 240                         (y-lo (sb!kernel:double-float-low-bits y))
 241                         (y-ihi (logand y-hi #x7fffffff)))
 242                    (declare (type (signed-byte 32) x-hi y-hi)
 243                             (type (unsigned-byte 31) x-ihi y-ihi)
 244                             (type (unsigned-byte 32) x-lo y-lo))
 245                    ;; y==zero: x**0 = 1
 246                    (when (zerop (logior y-ihi y-lo))
 247                      (return-from real-expt (coerce 1d0 rtype)))
 248                    ;; +-NaN return x+y
 249                    (when (or (> x-ihi #x7ff00000)
 250                              (and (= x-ihi #x7ff00000) (/= x-lo 0))
 251                              (> y-ihi #x7ff00000)
 252                              (and (= y-ihi #x7ff00000) (/= y-lo 0)))
 253                      (return-from real-expt (coerce (+ x y) rtype)))
 254                    (let ((yisint (if (< x-hi 0) (isint y-ihi y-lo) 0)))
 255                      (declare (type fixnum yisint))
 256                      ;; special value of y
 257                      (when (and (zerop y-lo) (= y-ihi #x7ff00000))
 258                        ;; y is +-inf
 259                        (return-from real-expt
 260                          (cond ((and (= x-ihi #x3ff00000) (zerop x-lo))
 261                                 ;; +-1**inf is NaN
 262                                 (coerce (- y y) rtype))
 263                                ((>= x-ihi #x3ff00000)
 264                                 ;; (|x|>1)**+-inf = inf,0
 265                                 (if (>= y-hi 0)
 266                                     (coerce y rtype)
 267                                     (coerce 0 rtype)))
 268                                (t
 269                                 ;; (|x|<1)**-,+inf = inf,0
 270                                 (if (< y-hi 0)
 271                                     (coerce (- y) rtype)
 272                                     (coerce 0 rtype))))))
 273
 274                      (let ((abs-x (abs x)))
 275                        (declare (double-float abs-x))
 276                        ;; special value of x
 277                        (when (and (zerop x-lo)
 278                                   (or (= x-ihi #x7ff00000) (zerop x-ihi)
 279                                       (= x-ihi #x3ff00000)))
 280                          ;; x is +-0,+-inf,+-1
 281                          (let ((z (if (< y-hi 0)
 282                                       (/ 1 abs-x)       ; z = (1/|x|)
 283                                       abs-x)))
 284                            (declare (double-float z))
 285                            (when (< x-hi 0)
 286                              (cond ((and (= x-ihi #x3ff00000) (zerop yisint))
 287                                     ;; (-1)**non-int
 288                                     (let ((y*pi (* y pi)))
 289                                       (declare (double-float y*pi))
 290                                       (return-from real-expt
 291                                         (complex
 292                                          (coerce (%cos y*pi) rtype)
 293                                          (coerce (%sin y*pi) rtype)))))
 294                                    ((= yisint 1)
 295                                     ;; (x<0)**odd = -(|x|**odd)
 296                                     (setq z (- z)))))
 297                            (return-from real-expt (coerce z rtype))))
 298
 299                        (if (>= x-hi 0)
 300                            ;; x>0
 301                            (coerce (sb!kernel::%pow x y) rtype)
 302                            ;; x<0
 303                            (let ((pow (sb!kernel::%pow abs-x y)))
 304                              (declare (double-float pow))
 305                              (case yisint
 306                                (1 ; odd
 307                                 (coerce (* -1d0 pow) rtype))
 308                                (2 ; even
 309                                 (coerce pow rtype))
 310                                (t ; non-integer
 311                                 (let ((y*pi (* y pi)))
 312                                   (declare (double-float y*pi))
 313                                   (complex
 314                                    (coerce (* pow (%cos y*pi))
 315                                            rtype)
 316                                    (coerce (* pow (%sin y*pi))
 317                                            rtype)))))))))))))
 318       (declare (inline real-expt))
 319       (number-dispatch ((base number) (power number))
 320         (((foreach fixnum (or bignum ratio) (complex rational)) integer)
 321          (intexp base power))
 322         (((foreach single-float double-float) rational)
 323          (real-expt base power '(dispatch-type base)))
 324         (((foreach fixnum (or bignum ratio) single-float)
 325           (foreach ratio single-float))
 326          (real-expt base power 'single-float))
 327         (((foreach fixnum (or bignum ratio) single-float double-float)
 328           double-float)
 329          (real-expt base power 'double-float))
 330         ((double-float single-float)
 331          (real-expt base power 'double-float))
 332         (((foreach (complex rational) (complex float)) rational)
 333          (* (expt (abs base) power)
 334             (cis (* power (phase base)))))
 335         (((foreach fixnum (or bignum ratio) single-float double-float)
 336           complex)
 337          (if (and (zerop base) (plusp (realpart power)))
 338              (* base power)
 339              (exp (* power (log base)))))
 340         (((foreach (complex float) (complex rational))
 341           (foreach complex double-float single-float))
 342          (if (and (zerop base) (plusp (realpart power)))
 343              (* base power)
 344              (exp (* power (log base)))))))))
 345
 346 (defun log (number &optional (base nil base-p))
 347   #!+sb-doc
 348   "Return the logarithm of NUMBER in the base BASE, which defaults to e."
 349   (if base-p
 350       (if (zerop base)
 351           base                          ; ANSI spec
 352           (/ (log number) (log base)))
 353       (number-dispatch ((number number))
 354         (((foreach fixnum bignum ratio))
 355          (if (minusp number)
 356              (complex (log (- number)) (coerce pi 'single-float))
 357              (coerce (%log (coerce number 'double-float)) 'single-float)))
 358         (((foreach single-float double-float))
 359          ;; Is (log -0) -infinity (libm.a) or -infinity + i*pi (Kahan)?
 360          ;; Since this doesn't seem to be an implementation issue
 361          ;; I (pw) take the Kahan result.
 362          (if (< (float-sign number)
 363                 (coerce 0 '(dispatch-type number)))
 364              (complex (log (- number)) (coerce pi '(dispatch-type number)))
 365              (coerce (%log (coerce number 'double-float))
 366                      '(dispatch-type number))))
 367         ((complex)
 368          (complex-log number)))))
 369
 370 (defun sqrt (number)
 371   #!+sb-doc
 372   "Return the square root of NUMBER."
 373   (number-dispatch ((number number))
 374     (((foreach fixnum bignum ratio))
 375      (if (minusp number)
 376          (complex-sqrt number)
 377          (coerce (%sqrt (coerce number 'double-float)) 'single-float)))
 378     (((foreach single-float double-float))
 379      (if (minusp number)
 380          (complex-sqrt number)
 381          (coerce (%sqrt (coerce number 'double-float))
 382                  '(dispatch-type number))))
 383      ((complex)
 384       (complex-sqrt number))))
 385 \f
 386 ;;;; trigonometic and related functions
 387
 388 (defun abs (number)
 389   #!+sb-doc
 390   "Returns the absolute value of the number."
 391   (number-dispatch ((number number))
 392     (((foreach single-float double-float fixnum rational))
 393      (abs number))
 394     ((complex)
 395      (let ((rx (realpart number))
 396            (ix (imagpart number)))
 397        (etypecase rx
 398          (rational
 399           (sqrt (+ (* rx rx) (* ix ix))))
 400          (single-float
 401           (coerce (%hypot (coerce rx 'double-float)
 402                           (coerce ix 'double-float))
 403                   'single-float))
 404          (double-float
 405           (%hypot rx ix)))))))
 406
 407 (defun phase (number)
 408   #!+sb-doc
 409   "Return the angle part of the polar representation of a complex number.
 410   For complex numbers, this is (atan (imagpart number) (realpart number)).
 411   For non-complex positive numbers, this is 0. For non-complex negative
 412   numbers this is PI."
 413   (etypecase number
 414     (rational
 415      (if (minusp number)
 416          (coerce pi 'single-float)
 417          0.0f0))
 418     (single-float
 419      (if (minusp (float-sign number))
 420          (coerce pi 'single-float)
 421          0.0f0))
 422     (double-float
 423      (if (minusp (float-sign number))
 424          (coerce pi 'double-float)
 425          0.0d0))
 426     (complex
 427      (atan (imagpart number) (realpart number)))))
 428
 429 (defun sin (number)
 430   #!+sb-doc
 431   "Return the sine of NUMBER."
 432   (number-dispatch ((number number))
 433     (handle-reals %sin number)
 434     ((complex)
 435      (let ((x (realpart number))
 436            (y (imagpart number)))
 437        (complex (* (sin x) (cosh y))
 438                 (* (cos x) (sinh y)))))))
 439
 440 (defun cos (number)
 441   #!+sb-doc
 442   "Return the cosine of NUMBER."
 443   (number-dispatch ((number number))
 444     (handle-reals %cos number)
 445     ((complex)
 446      (let ((x (realpart number))
 447            (y (imagpart number)))
 448        (complex (* (cos x) (cosh y))
 449                 (- (* (sin x) (sinh y))))))))
 450
 451 (defun tan (number)
 452   #!+sb-doc
 453   "Return the tangent of NUMBER."
 454   (number-dispatch ((number number))
 455     (handle-reals %tan number)
 456     ((complex)
 457      (complex-tan number))))
 458
 459 (defun cis (theta)
 460   #!+sb-doc
 461   "Return cos(Theta) + i sin(Theta), i.e. exp(i Theta)."
 462   (declare (type real theta))
 463   (complex (cos theta) (sin theta)))
 464
 465 (defun asin (number)
 466   #!+sb-doc
 467   "Return the arc sine of NUMBER."
 468   (number-dispatch ((number number))
 469     ((rational)
 470      (if (or (> number 1) (< number -1))
 471          (complex-asin number)
 472          (coerce (%asin (coerce number 'double-float)) 'single-float)))
 473     (((foreach single-float double-float))
 474      (if (or (> number (coerce 1 '(dispatch-type number)))
 475              (< number (coerce -1 '(dispatch-type number))))
 476          (complex-asin number)
 477          (coerce (%asin (coerce number 'double-float))
 478                  '(dispatch-type number))))
 479     ((complex)
 480      (complex-asin number))))
 481
 482 (defun acos (number)
 483   #!+sb-doc
 484   "Return the arc cosine of NUMBER."
 485   (number-dispatch ((number number))
 486     ((rational)
 487      (if (or (> number 1) (< number -1))
 488          (complex-acos number)
 489          (coerce (%acos (coerce number 'double-float)) 'single-float)))
 490     (((foreach single-float double-float))
 491      (if (or (> number (coerce 1 '(dispatch-type number)))
 492              (< number (coerce -1 '(dispatch-type number))))
 493          (complex-acos number)
 494          (coerce (%acos (coerce number 'double-float))
 495                  '(dispatch-type number))))
 496     ((complex)
 497      (complex-acos number))))
 498
 499 (defun atan (y &optional (x nil xp))
 500   #!+sb-doc
 501   "Return the arc tangent of Y if X is omitted or Y/X if X is supplied."
 502   (if xp
 503       (flet ((atan2 (y x)
 504                (declare (type double-float y x)
 505                         (values double-float))
 506                (if (zerop x)
 507                    (if (zerop y)
 508                        (if (plusp (float-sign x))
 509                            y
 510                            (float-sign y pi))
 511                        (float-sign y (/ pi 2)))
 512                    (%atan2 y x))))
 513         (number-dispatch ((y number) (x number))
 514           ((double-float
 515             (foreach double-float single-float fixnum bignum ratio))
 516            (atan2 y (coerce x 'double-float)))
 517           (((foreach single-float fixnum bignum ratio)
 518             double-float)
 519            (atan2 (coerce y 'double-float) x))
 520           (((foreach single-float fixnum bignum ratio)
 521             (foreach single-float fixnum bignum ratio))
 522            (coerce (atan2 (coerce y 'double-float) (coerce x 'double-float))
 523                    'single-float))))
 524       (number-dispatch ((y number))
 525         (handle-reals %atan y)
 526         ((complex)
 527          (complex-atan y)))))
 528
 529 ;; It seems that everyone has a C version of sinh, cosh, and
 530 ;; tanh. Let's use these for reals because the original
 531 ;; implementations based on the definitions lose big in round-off
 532 ;; error. These bad definitions also mean that sin and cos for
 533 ;; complex numbers can also lose big.
 534
 535 (defun sinh (number)
 536   #!+sb-doc
 537   "Return the hyperbolic sine of NUMBER."
 538   (number-dispatch ((number number))
 539     (handle-reals %sinh number)
 540     ((complex)
 541      (let ((x (realpart number))
 542            (y (imagpart number)))
 543        (complex (* (sinh x) (cos y))
 544                 (* (cosh x) (sin y)))))))
 545
 546 (defun cosh (number)
 547   #!+sb-doc
 548   "Return the hyperbolic cosine of NUMBER."
 549   (number-dispatch ((number number))
 550     (handle-reals %cosh number)
 551     ((complex)
 552      (let ((x (realpart number))
 553            (y (imagpart number)))
 554        (complex (* (cosh x) (cos y))
 555                 (* (sinh x) (sin y)))))))
 556
 557 (defun tanh (number)
 558   #!+sb-doc
 559   "Return the hyperbolic tangent of NUMBER."
 560   (number-dispatch ((number number))
 561     (handle-reals %tanh number)
 562     ((complex)
 563      (complex-tanh number))))
 564
 565 (defun asinh (number)
 566   #!+sb-doc
 567   "Return the hyperbolic arc sine of NUMBER."
 568   (number-dispatch ((number number))
 569     (handle-reals %asinh number)
 570     ((complex)
 571      (complex-asinh number))))
 572
 573 (defun acosh (number)
 574   #!+sb-doc
 575   "Return the hyperbolic arc cosine of NUMBER."
 576   (number-dispatch ((number number))
 577     ((rational)
 578      ;; acosh is complex if number < 1
 579      (if (< number 1)
 580          (complex-acosh number)
 581          (coerce (%acosh (coerce number 'double-float)) 'single-float)))
 582     (((foreach single-float double-float))
 583      (if (< number (coerce 1 '(dispatch-type number)))
 584          (complex-acosh number)
 585          (coerce (%acosh (coerce number 'double-float))
 586                  '(dispatch-type number))))
 587     ((complex)
 588      (complex-acosh number))))
 589
 590 (defun atanh (number)
 591   #!+sb-doc
 592   "Return the hyperbolic arc tangent of NUMBER."
 593   (number-dispatch ((number number))
 594     ((rational)
 595      ;; atanh is complex if |number| > 1
 596      (if (or (> number 1) (< number -1))
 597          (complex-atanh number)
 598          (coerce (%atanh (coerce number 'double-float)) 'single-float)))
 599     (((foreach single-float double-float))
 600      (if (or (> number (coerce 1 '(dispatch-type number)))
 601              (< number (coerce -1 '(dispatch-type number))))
 602          (complex-atanh number)
 603          (coerce (%atanh (coerce number 'double-float))
 604                  '(dispatch-type number))))
 605     ((complex)
 606      (complex-atanh number))))
 607
 608 ;;; HP-UX does not supply a C version of log1p, so use the definition.
 609 ;;;
 610 ;;; FIXME: This is really not a good definition. As per Raymond Toy
 611 ;;; working on CMU CL, "The definition really loses big-time in
 612 ;;; roundoff as x gets small."
 613 #!+hpux
 614 #!-sb-fluid (declaim (inline %log1p))
 615 #!+hpux
 616 (defun %log1p (number)
 617   (declare (double-float number)
 618            (optimize (speed 3) (safety 0)))
 619   (the double-float (log (the (double-float 0d0) (+ number 1d0)))))
 620 \f
 621 ;;;; not-OLD-SPECFUN stuff
 622 ;;;;
 623 ;;;; (This was conditional on #-OLD-SPECFUN in the CMU CL sources,
 624 ;;;; but OLD-SPECFUN was mentioned nowhere else, so it seems to be
 625 ;;;; the standard special function system.)
 626 ;;;;
 627 ;;;; This is a set of routines that implement many elementary
 628 ;;;; transcendental functions as specified by ANSI Common Lisp.  The
 629 ;;;; implementation is based on Kahan's paper.
 630 ;;;;
 631 ;;;; I believe I have accurately implemented the routines and are
 632 ;;;; correct, but you may want to check for your self.
 633 ;;;;
 634 ;;;; These functions are written for CMU Lisp and take advantage of
 635 ;;;; some of the features available there.  It may be possible,
 636 ;;;; however, to port this to other Lisps.
 637 ;;;;
 638 ;;;; Some functions are significantly more accurate than the original
 639 ;;;; definitions in CMU Lisp.  In fact, some functions in CMU Lisp
 640 ;;;; give the wrong answer like (acos #c(-2.0 0.0)), where the true
 641 ;;;; answer is pi + i*log(2-sqrt(3)).
 642 ;;;;
 643 ;;;; All of the implemented functions will take any number for an
 644 ;;;; input, but the result will always be a either a complex
 645 ;;;; single-float or a complex double-float.
 646 ;;;;
 647 ;;;; general functions:
 648 ;;;;   complex-sqrt
 649 ;;;;   complex-log
 650 ;;;;   complex-atanh
 651 ;;;;   complex-tanh
 652 ;;;;   complex-acos
 653 ;;;;   complex-acosh
 654 ;;;;   complex-asin
 655 ;;;;   complex-asinh
 656 ;;;;   complex-atan
 657 ;;;;   complex-tan
 658 ;;;;
 659 ;;;; utility functions:
 660 ;;;;   scalb logb
 661 ;;;;
 662 ;;;; internal functions:
 663 ;;;;    square coerce-to-complex-type cssqs complex-log-scaled
 664 ;;;;
 665 ;;;; references:
 666 ;;;;   Kahan, W. "Branch Cuts for Complex Elementary Functions, or Much
 667 ;;;;   Ado About Nothing's Sign Bit" in Iserles and Powell (eds.) "The
 668 ;;;;   State of the Art in Numerical Analysis", pp. 165-211, Clarendon
 669 ;;;;   Press, 1987
 670 ;;;;
 671 ;;;; The original CMU CL code requested:
 672 ;;;;   Please send any bug reports, comments, or improvements to
 673 ;;;;   Raymond Toy at toy@rtp.ericsson.se.
 674
 675 ;;; FIXME: In SBCL, the floating point infinity constants like
 676 ;;; SB!EXT:DOUBLE-FLOAT-POSITIVE-INFINITY aren't available as
 677 ;;; constants at cross-compile time, because the cross-compilation
 678 ;;; host might not have support for floating point infinities. Thus,
 679 ;;; they're effectively implemented as special variable references,
 680 ;;; and the code below which uses them might be unnecessarily
 681 ;;; inefficient. Perhaps some sort of MAKE-LOAD-TIME-VALUE hackery
 682 ;;; should be used instead?
 683
 684 (declaim (inline square))
 685 (defun square (x)
 686   (declare (double-float x))
 687   (* x x))
 688
 689 ;;; original CMU CL comment, apparently re. SCALB and LOGB and
 690 ;;; perhaps CSSQS:
 691 ;;;   If you have these functions in libm, perhaps they should be used
 692 ;;;   instead of these Lisp versions. These versions are probably good
 693 ;;;   enough, especially since they are portable.
 694
 695 ;;; Compute 2^N * X without computing 2^N first. (Use properties of
 696 ;;; the underlying floating-point format.)
 697 (declaim (inline scalb))
 698 (defun scalb (x n)
 699   (declare (type double-float x)
 700            (type double-float-exponent n))
 701   (scale-float x n))
 702
 703 ;;; This is like LOGB, but X is not infinity and non-zero and not a
 704 ;;; NaN, so we can always return an integer.
 705 (declaim (inline logb-finite))
 706 (defun logb-finite (x)
 707   (declare (type double-float x))
 708   (multiple-value-bind (signif exponent sign)
 709       (decode-float x)
 710     (declare (ignore signif sign))
 711     ;; DECODE-FLOAT is almost right, except that the exponent is off
 712     ;; by one.
 713     (1- exponent)))
 714
 715 ;;; Compute an integer N such that 1 <= |2^N * x| < 2.
 716 ;;; For the special cases, the following values are used:
 717 ;;;    x             logb
 718 ;;;   NaN            NaN
 719 ;;;   +/- infinity   +infinity
 720 ;;;   0              -infinity
 721 (defun logb (x)
 722   (declare (type double-float x))
 723   (cond ((float-nan-p x)
 724          x)
 725         ((float-infinity-p x)
 726          sb!ext:double-float-positive-infinity)
 727         ((zerop x)
 728          ;; The answer is negative infinity, but we are supposed to
 729           ;; signal divide-by-zero, so do the actual division
 730          (/ -1.0d0 x)
 731          )
 732         (t
 733           (logb-finite x))))
 734
 735 ;;; This function is used to create a complex number of the
 736 ;;; appropriate type:
 737 ;;;   Create complex number with real part X and imaginary part Y
 738 ;;;   such that has the same type as Z.  If Z has type (complex
 739 ;;;   rational), the X and Y are coerced to single-float.
 740 #!+long-float (eval-when (:compile-toplevel :load-toplevel :execute)
 741                 (error "needs work for long float support"))
 742 (declaim (inline coerce-to-complex-type))
 743 (defun coerce-to-complex-type (x y z)
 744   (declare (double-float x y)
 745            (number z))
 746   (if (subtypep (type-of (realpart z)) 'double-float)
 747       (complex x y)
 748       ;; Convert anything that's not a DOUBLE-FLOAT to a SINGLE-FLOAT.
 749       (complex (float x 1f0)
 750                (float y 1f0))))
 751
 752 ;;; Compute |(x+i*y)/2^k|^2 scaled to avoid over/underflow. The
 753 ;;; result is r + i*k, where k is an integer.
 754 #!+long-float (eval-when (:compile-toplevel :load-toplevel :execute)
 755                 (error "needs work for long float support"))
 756 (defun cssqs (z)
 757   (let ((x (float (realpart z) 1d0))
 758         (y (float (imagpart z) 1d0)))
 759     ;; Would this be better handled using an exception handler to
 760     ;; catch the overflow or underflow signal?  For now, we turn all
 761     ;; traps off and look at the accrued exceptions to see if any
 762     ;; signal would have been raised.
 763     (with-float-traps-masked (:underflow :overflow)
 764       (let ((rho (+ (square x) (square y))))
 765        (declare (optimize (speed 3) (space 0)))
 766       (cond ((and (or (float-nan-p rho)
 767                       (float-infinity-p rho))
 768                   (or (float-infinity-p (abs x))
 769                       (float-infinity-p (abs y))))
 770               (values sb!ext:double-float-positive-infinity 0))
 771             ((let ((threshold #.(/ least-positive-double-float
 772                                    double-float-epsilon))
 773                    (traps (ldb sb!vm::float-sticky-bits
 774                                (sb!vm:floating-point-modes))))
 775                 ;; Overflow raised or (underflow raised and rho <
 776                 ;; lambda/eps)
 777                (or (not (zerop (logand sb!vm:float-overflow-trap-bit traps)))
 778                    (and (not (zerop (logand sb!vm:float-underflow-trap-bit
 779                                             traps)))
 780                         (< rho threshold))))
 781               ;; If we're here, neither x nor y are infinity and at
 782               ;; least one is non-zero.. Thus logb returns a nice
 783               ;; integer.
 784               (let ((k (- (logb-finite (max (abs x) (abs y))))))
 785                 (values (+ (square (scalb x k))
 786                            (square (scalb y k)))
 787                         (- k))))
 788              (t
 789               (values rho 0)))))))
 790
 791 ;;; principal square root of Z
 792 ;;;
 793 ;;; Z may be any NUMBER, but the result is always a COMPLEX.
 794 (defun complex-sqrt (z)
 795   (declare (number z))
 796   (multiple-value-bind (rho k)
 797       (cssqs z)
 798     (declare (type (or (member 0d0) (double-float 0d0)) rho)
 799              (type fixnum k))
 800     (let ((x (float (realpart z) 1.0d0))
 801           (y (float (imagpart z) 1.0d0))
 802           (eta 0d0)
 803           (nu 0d0))
 804       (declare (double-float x y eta nu))
 805
 806       (locally
 807          ;; space 0 to get maybe-inline functions inlined.
 808          (declare (optimize (speed 3) (space 0)))
 809
 810       (if (not (float-nan-p x))
 811           (setf rho (+ (scalb (abs x) (- k)) (sqrt rho))))
 812
 813       (cond ((oddp k)
 814              (setf k (ash k -1)))
 815             (t
 816              (setf k (1- (ash k -1)))
 817              (setf rho (+ rho rho))))
 818
 819       (setf rho (scalb (sqrt rho) k))
 820
 821       (setf eta rho)
 822       (setf nu y)
 823
 824       (when (/= rho 0d0)
 825             (when (not (float-infinity-p (abs nu)))
 826                   (setf nu (/ (/ nu rho) 2d0)))
 827             (when (< x 0d0)
 828                   (setf eta (abs nu))
 829                   (setf nu (float-sign y rho))))
 830        (coerce-to-complex-type eta nu z)))))
 831
 832 ;;; Compute log(2^j*z).
 833 ;;;
 834 ;;; This is for use with J /= 0 only when |z| is huge.
 835 (defun complex-log-scaled (z j)
 836   (declare (number z)
 837            (fixnum j))
 838   ;; The constants t0, t1, t2 should be evaluated to machine
 839   ;; precision.  In addition, Kahan says the accuracy of log1p
 840   ;; influences the choices of these constants but doesn't say how to
 841   ;; choose them.  We'll just assume his choices matches our
 842   ;; implementation of log1p.
 843   (let ((t0 #.(/ 1 (sqrt 2.0d0)))
 844         (t1 1.2d0)
 845         (t2 3d0)
 846         (ln2 #.(log 2d0))
 847         (x (float (realpart z) 1.0d0))
 848         (y (float (imagpart z) 1.0d0)))
 849     (multiple-value-bind (rho k)
 850         (cssqs z)
 851       (declare (optimize (speed 3)))
 852       (let ((beta (max (abs x) (abs y)))
 853             (theta (min (abs x) (abs y))))
 854         (coerce-to-complex-type (if (and (zerop k)
 855                  (< t0 beta)
 856                  (or (<= beta t1)
 857                      (< rho t2)))
 858                                   (/ (%log1p (+ (* (- beta 1.0d0)
 859                                        (+ beta 1.0d0))
 860                                     (* theta theta)))
 861                                      2d0)
 862                                   (+ (/ (log rho) 2d0)
 863                                      (* (+ k j) ln2)))
 864                                 (atan y x)
 865                                 z)))))
 866
 867 ;;; log of Z = log |Z| + i * arg Z
 868 ;;;
 869 ;;; Z may be any number, but the result is always a complex.
 870 (defun complex-log (z)
 871   (declare (number z))
 872   (complex-log-scaled z 0))
 873
 874 ;;; KLUDGE: Let us note the following "strange" behavior. atanh 1.0d0
 875 ;;; is +infinity, but the following code returns approx 176 + i*pi/4.
 876 ;;; The reason for the imaginary part is caused by the fact that arg
 877 ;;; i*y is never 0 since we have positive and negative zeroes. -- rtoy
 878 ;;; Compute atanh z = (log(1+z) - log(1-z))/2.
 879 (defun complex-atanh (z)
 880   (declare (number z))
 881   (let* (;; constants
 882          (theta (/ (sqrt most-positive-double-float) 4.0d0))
 883          (rho (/ 4.0d0 (sqrt most-positive-double-float)))
 884          (half-pi (/ pi 2.0d0))
 885          (rp (float (realpart z) 1.0d0))
 886          (beta (float-sign rp 1.0d0))
 887          (x (* beta rp))
 888          (y (* beta (- (float (imagpart z) 1.0d0))))
 889          (eta 0.0d0)
 890          (nu 0.0d0))
 891     ;; Shouldn't need this declare.
 892     (declare (double-float x y))
 893     (locally
 894        (declare (optimize (speed 3)))
 895     (cond ((or (> x theta)
 896                (> (abs y) theta))
 897             ;; To avoid overflow...
 898            (setf eta (float-sign y half-pi))
 899            ;; nu is real part of 1/(x + iy).  This is x/(x^2+y^2),
 900            ;; which can cause overflow.  Arrange this computation so
 901            ;; that it won't overflow.
 902            (setf nu (let* ((x-bigger (> x (abs y)))
 903                            (r (if x-bigger (/ y x) (/ x y)))
 904                            (d (+ 1.0d0 (* r r))))
 905                       (if x-bigger
 906                           (/ (/ x) d)
 907                           (/ (/ r y) d)))))
 908           ((= x 1.0d0)
 909            ;; Should this be changed so that if y is zero, eta is set
 910            ;; to +infinity instead of approx 176?  In any case
 911            ;; tanh(176) is 1.0d0 within working precision.
 912            (let ((t1 (+ 4d0 (square y)))
 913                  (t2 (+ (abs y) rho)))
 914              (setf eta (log (/ (sqrt (sqrt t1)))
 915                             (sqrt t2)))
 916              (setf nu (* 0.5d0
 917                          (float-sign y
 918                                      (+ half-pi (atan (* 0.5d0 t2))))))))
 919           (t
 920            (let ((t1 (+ (abs y) rho)))
 921               ;; Normal case using log1p(x) = log(1 + x)
 922              (setf eta (* 0.25d0
 923                           (%log1p (/ (* 4.0d0 x)
 924                                      (+ (square (- 1.0d0 x))
 925                                         (square t1))))))
 926              (setf nu (* 0.5d0
 927                          (atan (* 2.0d0 y)
 928                                (- (* (- 1.0d0 x)
 929                                      (+ 1.0d0 x))
 930                                   (square t1))))))))
 931     (coerce-to-complex-type (* beta eta)
 932                             (- (* beta nu))
 933                              z))))
 934
 935 ;;; Compute tanh z = sinh z / cosh z.
 936 (defun complex-tanh (z)
 937   (declare (number z))
 938   (let ((x (float (realpart z) 1.0d0))
 939         (y (float (imagpart z) 1.0d0)))
 940     (locally
 941       ;; space 0 to get maybe-inline functions inlined
 942       (declare (optimize (speed 3) (space 0)))
 943     (cond ((> (abs x)
 944               #-(or linux hpux) #.(/ (asinh most-positive-double-float) 4d0)
 945               ;; This is more accurate under linux.
 946               #+(or linux hpux) #.(/ (+ (log 2.0d0)
 947                                           (log most-positive-double-float)) 4d0))
 948               (coerce-to-complex-type (float-sign x)
 949                                       (float-sign y) z))
 950           (t
 951            (let* ((tv (%tan y))
 952                   (beta (+ 1.0d0 (* tv tv)))
 953                   (s (sinh x))
 954                   (rho (sqrt (+ 1.0d0 (* s s)))))
 955              (if (float-infinity-p (abs tv))
 956                  (coerce-to-complex-type (/ rho s)
 957                                          (/ tv)
 958                                          z)
 959                  (let ((den (+ 1.0d0 (* beta s s))))
 960                    (coerce-to-complex-type (/ (* beta rho s)
 961                                               den)
 962                                            (/ tv den)
 963                                             z)))))))))
 964
 965 ;;; Compute acos z = pi/2 - asin z.
 966 ;;;
 967 ;;; Z may be any NUMBER, but the result is always a COMPLEX.
 968 (defun complex-acos (z)
 969   ;; Kahan says we should only compute the parts needed.  Thus, the
 970   ;; REALPART's below should only compute the real part, not the whole
 971   ;; complex expression.  Doing this can be important because we may get
 972   ;; spurious signals that occur in the part that we are not using.
 973   ;;
 974   ;; However, we take a pragmatic approach and just use the whole
 975   ;; expression.
 976   ;;
 977   ;; NOTE: The formula given by Kahan is somewhat ambiguous in whether
 978   ;; it's the conjugate of the square root or the square root of the
 979   ;; conjugate.  This needs to be checked.
 980   ;;
 981   ;; I checked.  It doesn't matter because (conjugate (sqrt z)) is the
 982   ;; same as (sqrt (conjugate z)) for all z.  This follows because
 983   ;;
 984   ;; (conjugate (sqrt z)) = exp(0.5*log |z|)*exp(-0.5*j*arg z).
 985   ;;
 986   ;; (sqrt (conjugate z)) = exp(0.5*log|z|)*exp(0.5*j*arg conj z)
 987   ;;
 988   ;; and these two expressions are equal if and only if arg conj z =
 989   ;; -arg z, which is clearly true for all z.
 990   (declare (number z))
 991   (let ((sqrt-1+z (complex-sqrt (+ 1 z)))
 992         (sqrt-1-z (complex-sqrt (- 1 z))))
 993     (with-float-traps-masked (:divide-by-zero)
 994       (complex (* 2 (atan (/ (realpart sqrt-1-z)
 995                              (realpart sqrt-1+z))))
 996                (asinh (imagpart (* (conjugate sqrt-1+z)
 997                                    sqrt-1-z)))))))
 998
 999 ;;; Compute acosh z = 2 * log(sqrt((z+1)/2) + sqrt((z-1)/2))
1000 ;;;
1001 ;;; Z may be any NUMBER, but the result is always a COMPLEX.
1002 (defun complex-acosh (z)
1003   (declare (number z))
1004   (let ((sqrt-z-1 (complex-sqrt (- z 1)))
1005         (sqrt-z+1 (complex-sqrt (+ z 1))))
1006     (with-float-traps-masked (:divide-by-zero)
1007       (complex (asinh (realpart (* (conjugate sqrt-z-1)
1008                                    sqrt-z+1)))
1009                (* 2 (atan (/ (imagpart sqrt-z-1)
1010                              (realpart sqrt-z+1))))))))
1011
1012 ;;; Compute asin z = asinh(i*z)/i.
1013 ;;;
1014 ;;; Z may be any NUMBER, but the result is always a COMPLEX.
1015 (defun complex-asin (z)
1016   (declare (number z))
1017   (let ((sqrt-1-z (complex-sqrt (- 1 z)))
1018         (sqrt-1+z (complex-sqrt (+ 1 z))))
1019     (with-float-traps-masked (:divide-by-zero)
1020       (complex (atan (/ (realpart z)
1021                         (realpart (* sqrt-1-z sqrt-1+z))))
1022                (asinh (imagpart (* (conjugate sqrt-1-z)
1023                                    sqrt-1+z)))))))
1024
1025 ;;; Compute asinh z = log(z + sqrt(1 + z*z)).
1026 ;;;
1027 ;;; Z may be any number, but the result is always a complex.
1028 (defun complex-asinh (z)
1029   (declare (number z))
1030   ;; asinh z = -i * asin (i*z)
1031   (let* ((iz (complex (- (imagpart z)) (realpart z)))
1032          (result (complex-asin iz)))
1033     (complex (imagpart result)
1034              (- (realpart result)))))
1035
1036 ;;; Compute atan z = atanh (i*z) / i.
1037 ;;;
1038 ;;; Z may be any number, but the result is always a complex.
1039 (defun complex-atan (z)
1040   (declare (number z))
1041   ;; atan z = -i * atanh (i*z)
1042   (let* ((iz (complex (- (imagpart z)) (realpart z)))
1043          (result (complex-atanh iz)))
1044     (complex (imagpart result)
1045              (- (realpart result)))))
1046
1047 ;;; Compute tan z = -i * tanh(i * z)
1048 ;;;
1049 ;;; Z may be any number, but the result is always a complex.
1050 (defun complex-tan (z)
1051   (declare (number z))
1052   ;; tan z = -i * tanh(i*z)
1053   (let* ((iz (complex (- (imagpart z)) (realpart z)))
1054          (result (complex-tanh iz)))
1055     (complex (imagpart result)
1056              (- (realpart result)))))