src/code/late-type.lisp

   1 ;;;; This file contains the definition of non-CLASS types (e.g.
   2 ;;;; subtypes of interesting BUILT-IN-CLASSes) and the interfaces to
   3 ;;;; the type system. Common Lisp type specifiers are parsed into a
   4 ;;;; somewhat canonical internal type representation that supports
   5 ;;;; type union, intersection, etc. (Except that ALIEN types have
   6 ;;;; moved out..)
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!KERNEL")
  18
  19 (/show0 "late-type.lisp 19")
  20
  21 (!begin-collecting-cold-init-forms)
  22
  23 ;;; ### Remaining incorrectnesses:
  24 ;;;
  25 ;;; TYPE-UNION (and the OR type) doesn't properly canonicalize an
  26 ;;; exhaustive partition or coalesce contiguous ranges of numeric
  27 ;;; types.
  28 ;;;
  29 ;;; There are all sorts of nasty problems with open bounds on FLOAT
  30 ;;; types (and probably FLOAT types in general.)
  31 ;;;
  32 ;;; RATIO and BIGNUM are not recognized as numeric types.
  33
  34 ;;; FIXME: This really should go away. Alas, it doesn't seem to be so
  35 ;;; simple to make it go away.. (See bug 123 in BUGS file.)
  36 (defvar *use-implementation-types* t ; actually initialized in cold init
  37   #!+sb-doc
  38   "*USE-IMPLEMENTATION-TYPES* is a semi-public flag which determines how
  39    restrictive we are in determining type membership. If two types are the
  40    same in the implementation, then we will consider them them the same when
  41    this switch is on. When it is off, we try to be as restrictive as the
  42    language allows, allowing us to detect more errors. Currently, this only
  43    affects array types.")
  44 (!cold-init-forms (setq *use-implementation-types* t))
  45
  46 ;;; These functions are used as method for types which need a complex
  47 ;;; subtypep method to handle some superclasses, but cover a subtree
  48 ;;; of the type graph (i.e. there is no simple way for any other type
  49 ;;; class to be a subtype.) There are always still complex ways,
  50 ;;; namely UNION and MEMBER types, so we must give TYPE1's method a
  51 ;;; chance to run, instead of immediately returning NIL, T.
  52 (defun delegate-complex-subtypep-arg2 (type1 type2)
  53   (let ((subtypep-arg1
  54          (type-class-complex-subtypep-arg1
  55           (type-class-info type1))))
  56     (if subtypep-arg1
  57         (funcall subtypep-arg1 type1 type2)
  58         (values nil t))))
  59 (defun delegate-complex-intersection2 (type1 type2)
  60   (let ((method (type-class-complex-intersection2 (type-class-info type1))))
  61     (if (and method (not (eq method #'delegate-complex-intersection2)))
  62         (funcall method type2 type1)
  63         (hierarchical-intersection2 type1 type2))))
  64
  65 ;;; This is used by !DEFINE-SUPERCLASSES to define the SUBTYPE-ARG1
  66 ;;; method. INFO is a list of conses
  67 ;;;   (SUPERCLASS-CLASS . {GUARD-TYPE-SPECIFIER | NIL}).
  68 ;;; This will never be called with a hairy type as TYPE2, since the
  69 ;;; hairy type TYPE2 method gets first crack.
  70 (defun !has-superclasses-complex-subtypep-arg1 (type1 type2 info)
  71   (values
  72    (and (sb!xc:typep type2 'sb!xc:class)
  73         (dolist (x info nil)
  74           (when (or (not (cdr x))
  75                     (csubtypep type1 (specifier-type (cdr x))))
  76             (return
  77              (or (eq type2 (car x))
  78                  (let ((inherits (layout-inherits (class-layout (car x)))))
  79                    (dotimes (i (length inherits) nil)
  80                      (when (eq type2 (layout-class (svref inherits i)))
  81                        (return t)))))))))
  82    t))
  83
  84 ;;; This function takes a list of specs, each of the form
  85 ;;;    (SUPERCLASS-NAME &OPTIONAL GUARD).
  86 ;;; Consider one spec (with no guard): any instance of the named
  87 ;;; TYPE-CLASS is also a subtype of the named superclass and of any of
  88 ;;; its superclasses. If there are multiple specs, then some will have
  89 ;;; guards. We choose the first spec whose guard is a supertype of
  90 ;;; TYPE1 and use its superclass. In effect, a sequence of guards
  91 ;;;    G0, G1, G2
  92 ;;; is actually
  93 ;;;    G0,(and G1 (not G0)), (and G2 (not (or G0 G1))).
  94 ;;;
  95 ;;; WHEN controls when the forms are executed.
  96 (defmacro !define-superclasses (type-class-name specs when)
  97   (let ((type-class (gensym "TYPE-CLASS-"))
  98         (info (gensym "INFO")))
  99     `(,when
 100        (let ((,type-class (type-class-or-lose ',type-class-name))
 101              (,info (mapcar (lambda (spec)
 102                               (destructuring-bind
 103                                   (super &optional guard)
 104                                   spec
 105                                 (cons (sb!xc:find-class super) guard)))
 106                             ',specs)))
 107          (setf (type-class-complex-subtypep-arg1 ,type-class)
 108                (lambda (type1 type2)
 109                  (!has-superclasses-complex-subtypep-arg1 type1 type2 ,info)))
 110          (setf (type-class-complex-subtypep-arg2 ,type-class)
 111                #'delegate-complex-subtypep-arg2)
 112          (setf (type-class-complex-intersection2 ,type-class)
 113                #'delegate-complex-intersection2)))))
 114 \f
 115 ;;;; FUNCTION and VALUES types
 116 ;;;;
 117 ;;;; Pretty much all of the general type operations are illegal on
 118 ;;;; VALUES types, since we can't discriminate using them, do
 119 ;;;; SUBTYPEP, etc. FUNCTION types are acceptable to the normal type
 120 ;;;; operations, but are generally considered to be equivalent to
 121 ;;;; FUNCTION. These really aren't true types in any type theoretic
 122 ;;;; sense, but we still parse them into CTYPE structures for two
 123 ;;;; reasons:
 124
 125 ;;;; -- Parsing and unparsing work the same way, and indeed we can't
 126 ;;;;    tell whether a type is a function or values type without
 127 ;;;;    parsing it.
 128 ;;;; -- Many of the places that can be annotated with real types can
 129 ;;;;    also be annotated with function or values types.
 130
 131 ;;; the description of a &KEY argument
 132 (defstruct (key-info #-sb-xc-host (:pure t)
 133                      (:copier nil))
 134   ;; the key (not necessarily a keyword in ANSI Common Lisp)
 135   (name (missing-arg) :type symbol)
 136   ;; the type of the argument value
 137   (type (missing-arg) :type ctype))
 138
 139 (!define-type-method (values :simple-subtypep :complex-subtypep-arg1)
 140                      (type1 type2)
 141   (declare (ignore type2))
 142   ;; FIXME: should be TYPE-ERROR, here and in next method
 143   (error "SUBTYPEP is illegal on this type:~%  ~S" (type-specifier type1)))
 144
 145 (!define-type-method (values :complex-subtypep-arg2)
 146                      (type1 type2)
 147   (declare (ignore type1))
 148   (error "SUBTYPEP is illegal on this type:~%  ~S" (type-specifier type2)))
 149
 150 (!define-type-method (values :unparse) (type)
 151   (cons 'values (unparse-args-types type)))
 152
 153 ;;; Return true if LIST1 and LIST2 have the same elements in the same
 154 ;;; positions according to TYPE=. We return NIL, NIL if there is an
 155 ;;; uncertain comparison.
 156 (defun type=-list (list1 list2)
 157   (declare (list list1 list2))
 158   (do ((types1 list1 (cdr types1))
 159        (types2 list2 (cdr types2)))
 160       ((or (null types1) (null types2))
 161        (if (or types1 types2)
 162            (values nil t)
 163            (values t t)))
 164     (multiple-value-bind (val win)
 165         (type= (first types1) (first types2))
 166       (unless win
 167         (return (values nil nil)))
 168       (unless val
 169         (return (values nil t))))))
 170
 171 (!define-type-method (values :simple-=) (type1 type2)
 172   (let ((rest1 (args-type-rest type1))
 173         (rest2 (args-type-rest type2)))
 174     (cond ((or (args-type-keyp type1) (args-type-keyp type2)
 175                (args-type-allowp type1) (args-type-allowp type2))
 176            (values nil nil))
 177           ((and rest1 rest2 (type/= rest1 rest2))
 178            (type= rest1 rest2))
 179           ((or rest1 rest2)
 180            (values nil t))
 181           (t
 182            (multiple-value-bind (req-val req-win)
 183                (type=-list (values-type-required type1)
 184                            (values-type-required type2))
 185              (multiple-value-bind (opt-val opt-win)
 186                  (type=-list (values-type-optional type1)
 187                              (values-type-optional type2))
 188                (values (and req-val opt-val) (and req-win opt-win))))))))
 189
 190 (!define-type-class function)
 191
 192 ;;; a flag that we can bind to cause complex function types to be
 193 ;;; unparsed as FUNCTION. This is useful when we want a type that we
 194 ;;; can pass to TYPEP.
 195 (defvar *unparse-fun-type-simplify*)
 196 (!cold-init-forms (setq *unparse-fun-type-simplify* nil))
 197
 198 (!define-type-method (function :unparse) (type)
 199   (if *unparse-fun-type-simplify*
 200       'function
 201       (list 'function
 202             (if (fun-type-wild-args type)
 203                 '*
 204                 (unparse-args-types type))
 205             (type-specifier
 206              (fun-type-returns type)))))
 207
 208 ;;; Since all function types are equivalent to FUNCTION, they are all
 209 ;;; subtypes of each other.
 210 (!define-type-method (function :simple-subtypep) (type1 type2)
 211   (declare (ignore type1 type2))
 212   (values t t))
 213
 214 (!define-superclasses function ((function)) !cold-init-forms)
 215
 216 ;;; The union or intersection of two FUNCTION types is FUNCTION.
 217 (!define-type-method (function :simple-union2) (type1 type2)
 218   (declare (ignore type1 type2))
 219   (specifier-type 'function))
 220 (!define-type-method (function :simple-intersection2) (type1 type2)
 221   (declare (ignore type1 type2))
 222   (specifier-type 'function))
 223
 224 ;;; ### Not very real, but good enough for redefining transforms
 225 ;;; according to type:
 226 (!define-type-method (function :simple-=) (type1 type2)
 227   (values (equalp type1 type2) t))
 228
 229 (!define-type-class constant :inherits values)
 230
 231 (!define-type-method (constant :unparse) (type)
 232   `(constant-arg ,(type-specifier (constant-type-type type))))
 233
 234 (!define-type-method (constant :simple-=) (type1 type2)
 235   (type= (constant-type-type type1) (constant-type-type type2)))
 236
 237 (!def-type-translator constant-arg (type)
 238   (make-constant-type :type (specifier-type type)))
 239
 240 ;;; Given a LAMBDA-LIST-like values type specification and an ARGS-TYPE
 241 ;;; structure, fill in the slots in the structure accordingly. This is
 242 ;;; used for both FUNCTION and VALUES types.
 243 (declaim (ftype (function (list args-type) (values)) parse-args-types))
 244 (defun parse-args-types (lambda-list result)
 245   (multiple-value-bind (required optional restp rest keyp keys allowp aux)
 246       (parse-lambda-list lambda-list)
 247     (when aux
 248       (error "&AUX in a FUNCTION or VALUES type: ~S." lambda-list))
 249     (setf (args-type-required result) (mapcar #'specifier-type required))
 250     (setf (args-type-optional result) (mapcar #'specifier-type optional))
 251     (setf (args-type-rest result) (if restp (specifier-type rest) nil))
 252     (setf (args-type-keyp result) keyp)
 253     (collect ((key-info))
 254       (dolist (key keys)
 255         (unless (proper-list-of-length-p key 2)
 256           (error "Keyword type description is not a two-list: ~S." key))
 257         (let ((kwd (first key)))
 258           (when (find kwd (key-info) :key #'key-info-name)
 259             (error "~@<repeated keyword ~S in lambda list: ~2I~_~S~:>"
 260                    kwd lambda-list))
 261           (key-info (make-key-info :name kwd
 262                                    :type (specifier-type (second key))))))
 263       (setf (args-type-keywords result) (key-info)))
 264     (setf (args-type-allowp result) allowp)
 265     (values)))
 266
 267 ;;; Return the lambda-list-like type specification corresponding
 268 ;;; to an ARGS-TYPE.
 269 (declaim (ftype (function (args-type) list) unparse-args-types))
 270 (defun unparse-args-types (type)
 271   (collect ((result))
 272
 273     (dolist (arg (args-type-required type))
 274       (result (type-specifier arg)))
 275
 276     (when (args-type-optional type)
 277       (result '&optional)
 278       (dolist (arg (args-type-optional type))
 279         (result (type-specifier arg))))
 280
 281     (when (args-type-rest type)
 282       (result '&rest)
 283       (result (type-specifier (args-type-rest type))))
 284
 285     (when (args-type-keyp type)
 286       (result '&key)
 287       (dolist (key (args-type-keywords type))
 288         (result (list (key-info-name key)
 289                       (type-specifier (key-info-type key))))))
 290
 291     (when (args-type-allowp type)
 292       (result '&allow-other-keys))
 293
 294     (result)))
 295
 296 (!def-type-translator function (&optional (args '*) (result '*))
 297   (let ((res (make-fun-type :returns (values-specifier-type result))))
 298     (if (eq args '*)
 299         (setf (fun-type-wild-args res) t)
 300         (parse-args-types args res))
 301     res))
 302
 303 (!def-type-translator values (&rest values)
 304   (let ((res (make-values-type)))
 305     (parse-args-types values res)
 306     res))
 307 \f
 308 ;;;; VALUES types interfaces
 309 ;;;;
 310 ;;;; We provide a few special operations that can be meaningfully used
 311 ;;;; on VALUES types (as well as on any other type).
 312
 313 ;;; Return the type of the first value indicated by TYPE. This is used
 314 ;;; by people who don't want to have to deal with VALUES types.
 315 #!-sb-fluid (declaim (freeze-type values-type))
 316 ; (inline single-value-type))
 317 (defun single-value-type (type)
 318   (declare (type ctype type))
 319   (cond ((values-type-p type)
 320          (or (car (args-type-required type))
 321              (if (args-type-optional type)
 322                  (type-union (car (args-type-optional type))
 323                              (specifier-type 'null)))
 324              (args-type-rest type)
 325              (specifier-type 'null)))
 326         ((eq type *wild-type*)
 327          *universal-type*)
 328         (t
 329          type)))
 330
 331 ;;; Return the minimum number of arguments that a function can be
 332 ;;; called with, and the maximum number or NIL. If not a function
 333 ;;; type, return NIL, NIL.
 334 (defun fun-type-nargs (type)
 335   (declare (type ctype type))
 336   (if (fun-type-p type)
 337       (let ((fixed (length (args-type-required type))))
 338         (if (or (args-type-rest type)
 339                 (args-type-keyp type)
 340                 (args-type-allowp type))
 341             (values fixed nil)
 342             (values fixed (+ fixed (length (args-type-optional type))))))
 343       (values nil nil)))
 344
 345 ;;; Determine whether TYPE corresponds to a definite number of values.
 346 ;;; The first value is a list of the types for each value, and the
 347 ;;; second value is the number of values. If the number of values is
 348 ;;; not fixed, then return NIL and :UNKNOWN.
 349 (defun values-types (type)
 350   (declare (type ctype type))
 351   (cond ((eq type *wild-type*)
 352          (values nil :unknown))
 353         ((not (values-type-p type))
 354          (values (list type) 1))
 355         ((or (args-type-optional type)
 356              (args-type-rest type)
 357              (args-type-keyp type)
 358              (args-type-allowp type))
 359          (values nil :unknown))
 360         (t
 361          (let ((req (args-type-required type)))
 362            (values (mapcar #'single-value-type req) (length req))))))
 363
 364 ;;; Return two values:
 365 ;;; 1. A list of all the positional (fixed and optional) types.
 366 ;;; 2. The &REST type (if any). If keywords allowed, *UNIVERSAL-TYPE*.
 367 ;;;    If no keywords or &REST, then the DEFAULT-TYPE.
 368 (defun values-type-types (type &optional (default-type *empty-type*))
 369   (declare (type values-type type))
 370   (values (append (args-type-required type)
 371                   (args-type-optional type))
 372           (cond ((args-type-keyp type) *universal-type*)
 373                 ((args-type-rest type))
 374                 (t
 375                  default-type))))
 376
 377 ;;; Return a list of OPERATION applied to the types in TYPES1 and
 378 ;;; TYPES2, padding with REST2 as needed. TYPES1 must not be shorter
 379 ;;; than TYPES2. The second value is T if OPERATION always returned a
 380 ;;; true second value.
 381 (defun fixed-values-op (types1 types2 rest2 operation)
 382   (declare (list types1 types2) (type ctype rest2) (type function operation))
 383   (let ((exact t))
 384     (values (mapcar (lambda (t1 t2)
 385                       (multiple-value-bind (res win)
 386                           (funcall operation t1 t2)
 387                         (unless win
 388                           (setq exact nil))
 389                         res))
 390                     types1
 391                     (append types2
 392                             (make-list (- (length types1) (length types2))
 393                                        :initial-element rest2)))
 394             exact)))
 395
 396 ;;; If Type isn't a values type, then make it into one:
 397 ;;;    <type>  ==>  (values type &rest t)
 398 (defun coerce-to-values (type)
 399   (declare (type ctype type))
 400   (if (values-type-p type)
 401       type
 402       (make-values-type :required (list type) :rest *universal-type*)))
 403
 404 ;;; Do the specified OPERATION on TYPE1 and TYPE2, which may be any
 405 ;;; type, including VALUES types. With VALUES types such as:
 406 ;;;    (VALUES a0 a1)
 407 ;;;    (VALUES b0 b1)
 408 ;;; we compute the more useful result
 409 ;;;    (VALUES (<operation> a0 b0) (<operation> a1 b1))
 410 ;;; rather than the precise result
 411 ;;;    (<operation> (values a0 a1) (values b0 b1))
 412 ;;; This has the virtue of always keeping the VALUES type specifier
 413 ;;; outermost, and retains all of the information that is really
 414 ;;; useful for static type analysis. We want to know what is always
 415 ;;; true of each value independently. It is worthless to know that if
 416 ;;; the first value is B0 then the second will be B1.
 417 ;;;
 418 ;;; If the VALUES count signatures differ, then we produce a result with
 419 ;;; the required VALUE count chosen by NREQ when applied to the number
 420 ;;; of required values in TYPE1 and TYPE2. Any &KEY values become
 421 ;;; &REST T (anyone who uses keyword values deserves to lose.)
 422 ;;;
 423 ;;; The second value is true if the result is definitely empty or if
 424 ;;; OPERATION returned true as its second value each time we called
 425 ;;; it. Since we approximate the intersection of VALUES types, the
 426 ;;; second value being true doesn't mean the result is exact.
 427 (defun args-type-op (type1 type2 operation nreq default-type)
 428   (declare (type ctype type1 type2 default-type)
 429            (type function operation nreq))
 430   (if (or (values-type-p type1) (values-type-p type2))
 431       (let ((type1 (coerce-to-values type1))
 432             (type2 (coerce-to-values type2)))
 433         (multiple-value-bind (types1 rest1)
 434             (values-type-types type1 default-type)
 435           (multiple-value-bind (types2 rest2)
 436               (values-type-types type2 default-type)
 437             (multiple-value-bind (rest rest-exact)
 438                 (funcall operation rest1 rest2)
 439               (multiple-value-bind (res res-exact)
 440                   (if (< (length types1) (length types2))
 441                       (fixed-values-op types2 types1 rest1 operation)
 442                       (fixed-values-op types1 types2 rest2 operation))
 443                 (let* ((req (funcall nreq
 444                                      (length (args-type-required type1))
 445                                      (length (args-type-required type2))))
 446                        (required (subseq res 0 req))
 447                        (opt (subseq res req))
 448                        (opt-last (position rest opt :test-not #'type=
 449                                            :from-end t)))
 450                   (if (find *empty-type* required :test #'type=)
 451                       (values *empty-type* t)
 452                       (values (make-values-type
 453                                :required required
 454                                :optional (if opt-last
 455                                              (subseq opt 0 (1+ opt-last))
 456                                              ())
 457                                :rest (if (eq rest default-type) nil rest))
 458                               (and rest-exact res-exact)))))))))
 459       (funcall operation type1 type2)))
 460
 461 ;;; Do a union or intersection operation on types that might be values
 462 ;;; types. The result is optimized for utility rather than exactness,
 463 ;;; but it is guaranteed that it will be no smaller (more restrictive)
 464 ;;; than the precise result.
 465 ;;;
 466 ;;; The return convention seems to be analogous to
 467 ;;; TYPES-EQUAL-OR-INTERSECT. -- WHN 19990910.
 468 (defun-cached (values-type-union :hash-function type-cache-hash
 469                                  :hash-bits 8
 470                                  :default nil
 471                                  :init-wrapper !cold-init-forms)
 472               ((type1 eq) (type2 eq))
 473   (declare (type ctype type1 type2))
 474   (cond ((or (eq type1 *wild-type*) (eq type2 *wild-type*)) *wild-type*)
 475         ((eq type1 *empty-type*) type2)
 476         ((eq type2 *empty-type*) type1)
 477         (t
 478          (values (args-type-op type1 type2 #'type-union #'min *empty-type*)))))
 479 (defun-cached (values-type-intersection :hash-function type-cache-hash
 480                                         :hash-bits 8
 481                                         :values 2
 482                                         :default (values nil :empty)
 483                                         :init-wrapper !cold-init-forms)
 484               ((type1 eq) (type2 eq))
 485   (declare (type ctype type1 type2))
 486   (cond ((eq type1 *wild-type*) (values type2 t))
 487         ((eq type2 *wild-type*) (values type1 t))
 488         (t
 489          (args-type-op type1 type2
 490                        #'type-intersection
 491                        #'max
 492                        (specifier-type 'null)))))
 493
 494 ;;; This is like TYPES-EQUAL-OR-INTERSECT, except that it sort of
 495 ;;; works on VALUES types. Note that due to the semantics of
 496 ;;; VALUES-TYPE-INTERSECTION, this might return (VALUES T T) when
 497 ;;; there isn't really any intersection.
 498 (defun values-types-equal-or-intersect (type1 type2)
 499   (cond ((or (eq type1 *empty-type*) (eq type2 *empty-type*))
 500          (values t t))
 501         ((or (values-type-p type1) (values-type-p type2))
 502          (multiple-value-bind (res win) (values-type-intersection type1 type2)
 503            (values (not (eq res *empty-type*))
 504                    win)))
 505         (t
 506          (types-equal-or-intersect type1 type2))))
 507
 508 ;;; a SUBTYPEP-like operation that can be used on any types, including
 509 ;;; VALUES types
 510 (defun-cached (values-subtypep :hash-function type-cache-hash
 511                                :hash-bits 8
 512                                :values 2
 513                                :default (values nil :empty)
 514                                :init-wrapper !cold-init-forms)
 515               ((type1 eq) (type2 eq))
 516   (declare (type ctype type1 type2))
 517   (cond ((eq type2 *wild-type*) (values t t))
 518         ((eq type1 *wild-type*)
 519          (values (eq type2 *universal-type*) t))
 520         ((not (values-types-equal-or-intersect type1 type2))
 521          (values nil t))
 522         (t
 523          (if (or (values-type-p type1) (values-type-p type2))
 524              (let ((type1 (coerce-to-values type1))
 525                    (type2 (coerce-to-values type2)))
 526                (multiple-value-bind (types1 rest1) (values-type-types type1)
 527                  (multiple-value-bind (types2 rest2) (values-type-types type2)
 528                    (cond ((< (length (values-type-required type1))
 529                              (length (values-type-required type2)))
 530                           (values nil t))
 531                          ((< (length types1) (length types2))
 532                           (values nil nil))
 533                          ((or (values-type-keyp type1)
 534                               (values-type-keyp type2))
 535                           (values nil nil))
 536                          (t
 537                           (do ((t1 types1 (rest t1))
 538                                (t2 types2 (rest t2)))
 539                               ((null t2)
 540                                (csubtypep rest1 rest2))
 541                             (multiple-value-bind (res win-p)
 542                                 (csubtypep (first t1) (first t2))
 543                               (unless win-p
 544                                 (return (values nil nil)))
 545                               (unless res
 546                                 (return (values nil t))))))))))
 547              (csubtypep type1 type2)))))
 548 \f
 549 ;;;; type method interfaces
 550
 551 ;;; like SUBTYPEP, only works on CTYPE structures
 552 (defun-cached (csubtypep :hash-function type-cache-hash
 553                          :hash-bits 8
 554                          :values 2
 555                          :default (values nil :empty)
 556                          :init-wrapper !cold-init-forms)
 557               ((type1 eq) (type2 eq))
 558   (declare (type ctype type1 type2))
 559   (cond ((or (eq type1 type2)
 560              (eq type1 *empty-type*)
 561              (eq type2 *wild-type*))
 562          (values t t))
 563         ((or (eq type1 *wild-type*)
 564              (eq type2 *empty-type*))
 565          (values nil t))
 566         (t
 567          (!invoke-type-method :simple-subtypep :complex-subtypep-arg2
 568                               type1 type2
 569                               :complex-arg1 :complex-subtypep-arg1))))
 570
 571 ;;; Just parse the type specifiers and call CSUBTYPE.
 572 (defun sb!xc:subtypep (type1 type2)
 573   #!+sb-doc
 574   "Return two values indicating the relationship between type1 and type2.
 575   If values are T and T, type1 definitely is a subtype of type2.
 576   If values are NIL and T, type1 definitely is not a subtype of type2.
 577   If values are NIL and NIL, it couldn't be determined."
 578   (csubtypep (specifier-type type1) (specifier-type type2)))
 579
 580 ;;; If two types are definitely equivalent, return true. The second
 581 ;;; value indicates whether the first value is definitely correct.
 582 ;;; This should only fail in the presence of HAIRY types.
 583 (defun-cached (type= :hash-function type-cache-hash
 584                      :hash-bits 8
 585                      :values 2
 586                      :default (values nil :empty)
 587                      :init-wrapper !cold-init-forms)
 588               ((type1 eq) (type2 eq))
 589   (declare (type ctype type1 type2))
 590   (if (eq type1 type2)
 591       (values t t)
 592       (!invoke-type-method :simple-= :complex-= type1 type2)))
 593
 594 ;;; Not exactly the negation of TYPE=, since when the relationship is
 595 ;;; uncertain, we still return NIL, NIL. This is useful in cases where
 596 ;;; the conservative assumption is =.
 597 (defun type/= (type1 type2)
 598   (declare (type ctype type1 type2))
 599   (multiple-value-bind (res win) (type= type1 type2)
 600     (if win
 601         (values (not res) t)
 602         (values nil nil))))
 603
 604 ;;; the type method dispatch case of TYPE-UNION2
 605 (defun %type-union2 (type1 type2)
 606   ;; As in %TYPE-INTERSECTION2, it seems to be a good idea to give
 607   ;; both argument orders a chance at COMPLEX-INTERSECTION2. Unlike
 608   ;; %TYPE-INTERSECTION2, though, I don't have a specific case which
 609   ;; demonstrates this is actually necessary. Also unlike
 610   ;; %TYPE-INTERSECTION2, there seems to be no need to distinguish
 611   ;; between not finding a method and having a method return NIL.
 612   (flet ((1way (x y)
 613            (!invoke-type-method :simple-union2 :complex-union2
 614                                 x y
 615                                 :default nil)))
 616     (declare (inline 1way))
 617     (or (1way type1 type2)
 618         (1way type2 type1))))
 619
 620 ;;; Find a type which includes both types. Any inexactness is
 621 ;;; represented by the fuzzy element types; we return a single value
 622 ;;; that is precise to the best of our knowledge. This result is
 623 ;;; simplified into the canonical form, thus is not a UNION-TYPE
 624 ;;; unless we find no other way to represent the result.
 625 (defun-cached (type-union2 :hash-function type-cache-hash
 626                            :hash-bits 8
 627                            :init-wrapper !cold-init-forms)
 628               ((type1 eq) (type2 eq))
 629   ;; KLUDGE: This was generated from TYPE-INTERSECTION2 by Ye Olde Cut And
 630   ;; Paste technique of programming. If it stays around (as opposed to
 631   ;; e.g. fading away in favor of some CLOS solution) the shared logic
 632   ;; should probably become shared code. -- WHN 2001-03-16
 633   (declare (type ctype type1 type2))
 634   (cond ((eq type1 type2)
 635          type1)
 636         ((or (union-type-p type1)
 637              (union-type-p type2))
 638          ;; Unions of UNION-TYPE should have the UNION-TYPE-TYPES
 639          ;; values broken out and united separately. The full TYPE-UNION
 640          ;; function knows how to do this, so let it handle it.
 641          (type-union type1 type2))
 642         (t
 643          ;; the ordinary case: we dispatch to type methods
 644          (%type-union2 type1 type2))))
 645
 646 ;;; the type method dispatch case of TYPE-INTERSECTION2
 647 (defun %type-intersection2 (type1 type2)
 648   ;; We want to give both argument orders a chance at
 649   ;; COMPLEX-INTERSECTION2. Without that, the old CMU CL type
 650   ;; methods could give noncommutative results, e.g.
 651   ;;   (TYPE-INTERSECTION2 *EMPTY-TYPE* SOME-HAIRY-TYPE)
 652   ;;     => NIL, NIL
 653   ;;   (TYPE-INTERSECTION2 SOME-HAIRY-TYPE *EMPTY-TYPE*)
 654   ;;     => #<NAMED-TYPE NIL>, T
 655   ;; We also need to distinguish between the case where we found a
 656   ;; type method, and it returned NIL, and the case where we fell
 657   ;; through without finding any type method. An example of the first
 658   ;; case is the intersection of a HAIRY-TYPE with some ordinary type.
 659   ;; An example of the second case is the intersection of two
 660   ;; completely-unrelated types, e.g. CONS and NUMBER, or SYMBOL and
 661   ;; ARRAY.
 662   ;;
 663   ;; (Why yes, CLOS probably *would* be nicer..)
 664   (flet ((1way (x y)
 665            (!invoke-type-method :simple-intersection2 :complex-intersection2
 666                                 x y
 667                                 :default :no-type-method-found)))
 668     (declare (inline 1way))
 669     (let ((xy (1way type1 type2)))
 670       (or (and (not (eql xy :no-type-method-found)) xy)
 671           (let ((yx (1way type2 type1)))
 672             (or (and (not (eql yx :no-type-method-found)) yx)
 673                 (cond ((and (eql xy :no-type-method-found)
 674                             (eql yx :no-type-method-found))
 675                        *empty-type*)
 676                       (t
 677                        (aver (and (not xy) (not yx))) ; else handled above
 678                        nil))))))))
 679
 680 (defun-cached (type-intersection2 :hash-function type-cache-hash
 681                                   :hash-bits 8
 682                                   :values 1
 683                                   :default nil
 684                                   :init-wrapper !cold-init-forms)
 685               ((type1 eq) (type2 eq))
 686   (declare (type ctype type1 type2))
 687   (cond ((eq type1 type2)
 688          type1)
 689         ((or (intersection-type-p type1)
 690              (intersection-type-p type2))
 691          ;; Intersections of INTERSECTION-TYPE should have the
 692          ;; INTERSECTION-TYPE-TYPES values broken out and intersected
 693          ;; separately. The full TYPE-INTERSECTION function knows how
 694          ;; to do that, so let it handle it.
 695          (type-intersection type1 type2))
 696         (t
 697          ;; the ordinary case: we dispatch to type methods
 698          (%type-intersection2 type1 type2))))
 699
 700 ;;; Return as restrictive and simple a type as we can discover that is
 701 ;;; no more restrictive than the intersection of TYPE1 and TYPE2. At
 702 ;;; worst, we arbitrarily return one of the arguments as the first
 703 ;;; value (trying not to return a hairy type).
 704 (defun type-approx-intersection2 (type1 type2)
 705   (cond ((type-intersection2 type1 type2))
 706         ((hairy-type-p type1) type2)
 707         (t type1)))
 708
 709 ;;; a test useful for checking whether a derived type matches a
 710 ;;; declared type
 711 ;;;
 712 ;;; The first value is true unless the types don't intersect and
 713 ;;; aren't equal. The second value is true if the first value is
 714 ;;; definitely correct. NIL is considered to intersect with any type.
 715 ;;; If T is a subtype of either type, then we also return T, T. This
 716 ;;; way we recognize that hairy types might intersect with T.
 717 (defun types-equal-or-intersect (type1 type2)
 718   (declare (type ctype type1 type2))
 719   (if (or (eq type1 *empty-type*) (eq type2 *empty-type*))
 720       (values t t)
 721       (let ((intersection2 (type-intersection2 type1 type2)))
 722         (cond ((not intersection2)
 723                (if (or (csubtypep *universal-type* type1)
 724                        (csubtypep *universal-type* type2))
 725                    (values t t)
 726                    (values t nil)))
 727               ((eq intersection2 *empty-type*) (values nil t))
 728               (t (values t t))))))
 729
 730 ;;; Return a Common Lisp type specifier corresponding to the TYPE
 731 ;;; object.
 732 (defun type-specifier (type)
 733   (declare (type ctype type))
 734   (funcall (type-class-unparse (type-class-info type)) type))
 735
 736 ;;; (VALUES-SPECIFIER-TYPE and SPECIFIER-TYPE moved from here to
 737 ;;; early-type.lisp by WHN ca. 19990201.)
 738
 739 ;;; Take a list of type specifiers, computing the translation of each
 740 ;;; specifier and defining it as a builtin type.
 741 (declaim (ftype (function (list) (values)) precompute-types))
 742 (defun precompute-types (specs)
 743   (dolist (spec specs)
 744     (let ((res (specifier-type spec)))
 745       (unless (unknown-type-p res)
 746         (setf (info :type :builtin spec) res)
 747         (setf (info :type :kind spec) :primitive))))
 748   (values))
 749 \f
 750 ;;;; general TYPE-UNION and TYPE-INTERSECTION operations
 751 ;;;;
 752 ;;;; These are fully general operations on CTYPEs: they'll always
 753 ;;;; return a CTYPE representing the result.
 754
 755 ;;; shared logic for unions and intersections: Stuff TYPE into the
 756 ;;; vector TYPES, finding pairs of types which can be simplified by
 757 ;;; SIMPLIFY2 (TYPE-UNION2 or TYPE-INTERSECTION2) and replacing them
 758 ;;; by their simplified forms.
 759 (defun accumulate1-compound-type (type types %compound-type-p simplify2)
 760   (declare (type ctype type))
 761   (declare (type (vector ctype) types))
 762   (declare (type function simplify2))
 763   ;; Any input object satisfying %COMPOUND-TYPE-P should've been
 764   ;; broken into components before it reached us.
 765   (aver (not (funcall %compound-type-p type)))
 766   (dotimes (i (length types) (vector-push-extend type types))
 767     (let ((simplified2 (funcall simplify2 type (aref types i))))
 768       (when simplified2
 769         ;; Discard the old (AREF TYPES I).
 770         (setf (aref types i) (vector-pop types))
 771         ;; Merge the new SIMPLIFIED2 into TYPES, by tail recursing.
 772         ;; (Note that the tail recursion is indirect: we go through
 773         ;; ACCUMULATE, not ACCUMULATE1, so that if SIMPLIFIED2 is
 774         ;; handled properly if it satisfies %COMPOUND-TYPE-P.)
 775         (return (accumulate-compound-type simplified2
 776                                           types
 777                                           %compound-type-p
 778                                           simplify2)))))
 779   ;; Voila.
 780   (values))
 781
 782 ;;; shared logic for unions and intersections: Use
 783 ;;; ACCUMULATE1-COMPOUND-TYPE to merge TYPE into TYPES, either
 784 ;;; all in one step or, if %COMPOUND-TYPE-P is satisfied,
 785 ;;; component by component.
 786 (defun accumulate-compound-type (type types %compound-type-p simplify2)
 787   (declare (type function %compound-type-p simplify2))
 788   (flet ((accumulate1 (x)
 789            (accumulate1-compound-type x types %compound-type-p simplify2)))
 790     (declare (inline accumulate1))
 791     (if (funcall %compound-type-p type)
 792         (map nil #'accumulate1 (compound-type-types type))
 793         (accumulate1 type)))
 794   (values))
 795
 796 ;;; shared logic for unions and intersections: Return a vector of
 797 ;;; types representing the same types as INPUT-TYPES, but with
 798 ;;; COMPOUND-TYPEs satisfying %COMPOUND-TYPE-P broken up into their
 799 ;;; component types, and with any SIMPLY2 simplifications applied.
 800 (defun simplified-compound-types (input-types %compound-type-p simplify2)
 801   (let ((simplified-types (make-array (length input-types)
 802                                       :fill-pointer 0
 803                                       :element-type 'ctype
 804                                       ;; (This INITIAL-ELEMENT shouldn't
 805                                       ;; matter, but helps avoid type
 806                                       ;; warnings at compile time.)
 807                                       :initial-element *empty-type*)))
 808     (dolist (input-type input-types)
 809       (accumulate-compound-type input-type
 810                                 simplified-types
 811                                 %compound-type-p
 812                                 simplify2))
 813     simplified-types))
 814
 815 ;;; shared logic for unions and intersections: Make a COMPOUND-TYPE
 816 ;;; object whose components are the types in TYPES, or skip to special
 817 ;;; cases when TYPES is short.
 818 (defun make-compound-type-or-something (constructor types enumerable identity)
 819   (declare (type function constructor))
 820   (declare (type (vector ctype) types))
 821   (declare (type ctype identity))
 822   (case (length types)
 823     (0 identity)
 824     (1 (aref types 0))
 825     (t (funcall constructor
 826                 enumerable
 827                 ;; FIXME: This should be just (COERCE TYPES 'LIST), but as
 828                 ;; of sbcl-0.6.11.17 the COERCE optimizer is really
 829                 ;; brain-dead, so that would generate a full call to
 830                 ;; SPECIFIER-TYPE at runtime, so we get into bootstrap
 831                 ;; problems in cold init because 'LIST is a compound
 832                 ;; type, so we need to MAKE-COMPOUND-TYPE-OR-SOMETHING
 833                 ;; before we know what 'LIST is. Once the COERCE
 834                 ;; optimizer is less brain-dead, we can make this
 835                 ;; (COERCE TYPES 'LIST) again.
 836                 #+sb-xc-host (coerce types 'list)
 837                 #-sb-xc-host (coerce-to-list types)))))
 838
 839 (defun type-intersection (&rest input-types)
 840   (let ((simplified-types (simplified-compound-types input-types
 841                                                      #'intersection-type-p
 842                                                      #'type-intersection2)))
 843     (declare (type (vector ctype) simplified-types))
 844     ;; We want to have a canonical representation of types (or failing
 845     ;; that, punt to HAIRY-TYPE). Canonical representation would have
 846     ;; intersections inside unions but not vice versa, since you can
 847     ;; always achieve that by the distributive rule. But we don't want
 848     ;; to just apply the distributive rule, since it would be too easy
 849     ;; to end up with unreasonably huge type expressions. So instead
 850     ;; we punt to HAIRY-TYPE when this comes up.
 851     (if (and (> (length simplified-types) 1)
 852              (some #'union-type-p simplified-types))
 853         (make-hairy-type
 854          :specifier `(and ,@(map 'list #'type-specifier simplified-types)))
 855         (make-compound-type-or-something #'%make-intersection-type
 856                                          simplified-types
 857                                          (some #'type-enumerable
 858                                                simplified-types)
 859                                          *universal-type*))))
 860
 861 (defun type-union (&rest input-types)
 862   (let ((simplified-types (simplified-compound-types input-types
 863                                                      #'union-type-p
 864                                                      #'type-union2)))
 865     (make-compound-type-or-something #'%make-union-type
 866                                      simplified-types
 867                                      (every #'type-enumerable simplified-types)
 868                                      *empty-type*)))
 869 \f
 870 ;;;; built-in types
 871
 872 (!define-type-class named)
 873
 874 (defvar *wild-type*)
 875 (defvar *empty-type*)
 876 (defvar *universal-type*)
 877 (defvar *universal-fun-type*)
 878 (!cold-init-forms
 879  (macrolet ((frob (name var)
 880               `(progn
 881                  (setq ,var (make-named-type :name ',name))
 882                  (setf (info :type :kind ',name) :primitive)
 883                  (setf (info :type :builtin ',name) ,var))))
 884    ;; KLUDGE: In ANSI, * isn't really the name of a type, it's just a
 885    ;; special symbol which can be stuck in some places where an
 886    ;; ordinary type can go, e.g. (ARRAY * 1) instead of (ARRAY T 1).
 887    ;; At some point, in order to become more standard, we should
 888    ;; convert all the classic CMU CL legacy *s and *WILD-TYPE*s into
 889    ;; Ts and *UNIVERSAL-TYPE*s.
 890    (frob * *wild-type*)
 891    (frob nil *empty-type*)
 892    (frob t *universal-type*))
 893  (setf *universal-fun-type*
 894        (make-fun-type :wild-args t
 895                            :returns *wild-type*)))
 896
 897 (!define-type-method (named :simple-=) (type1 type2)
 898   ;; FIXME: BUG 85: This assertion failed when I added it in
 899   ;; sbcl-0.6.11.13. It probably shouldn't fail; but for now it's
 900   ;; just commented out.
 901   ;;(aver (not (eq type1 *wild-type*))) ; * isn't really a type.
 902   (values (eq type1 type2) t))
 903
 904 (!define-type-method (named :simple-subtypep) (type1 type2)
 905   (aver (not (eq type1 *wild-type*))) ; * isn't really a type.
 906   (values (or (eq type1 *empty-type*) (eq type2 *wild-type*)) t))
 907
 908 (!define-type-method (named :complex-subtypep-arg1) (type1 type2)
 909   (aver (not (eq type1 *wild-type*))) ; * isn't really a type.
 910   ;; FIXME: Why does this (old CMU CL) assertion hold? Perhaps 'cause
 911   ;; the HAIRY-TYPE COMPLEX-SUBTYPEP-ARG2 method takes precedence over
 912   ;; this COMPLEX-SUBTYPE-ARG1 method? (I miss CLOS..)
 913   (aver (not (hairy-type-p type2)))
 914   ;; Besides the old CMU CL assertion above, we also need to avoid
 915   ;; compound types, else we could get into trouble with
 916   ;;   (SUBTYPEP T '(OR (SATISFIES FOO) (SATISFIES BAR)))
 917   ;; or
 918   ;;   (SUBTYPEP T '(AND (SATISFIES FOO) (SATISFIES BAR))).
 919   (aver (not (compound-type-p type2)))
 920   ;; Then, since TYPE2 is reasonably tractable, we're good to go.
 921   (values (eq type1 *empty-type*) t))
 922
 923 (!define-type-method (named :complex-subtypep-arg2) (type1 type2)
 924   (aver (not (eq type2 *wild-type*))) ; * isn't really a type.
 925   (cond ((eq type2 *universal-type*)
 926          (values t t))
 927         ((hairy-type-p type1)
 928          (values nil nil))
 929         (t
 930          ;; FIXME: This seems to rely on there only being 2 or 3
 931          ;; HAIRY-TYPE values, and the exclusion of various
 932          ;; possibilities above. It would be good to explain it and/or
 933          ;; rewrite it so that it's clearer.
 934          (values (not (eq type2 *empty-type*)) t))))
 935
 936 (!define-type-method (named :complex-intersection2) (type1 type2)
 937   ;; FIXME: This assertion failed when I added it in sbcl-0.6.11.13.
 938   ;; Perhaps when bug 85 is fixed it can be reenabled.
 939   ;;(aver (not (eq type2 *wild-type*))) ; * isn't really a type.
 940   (hierarchical-intersection2 type1 type2))
 941
 942 (!define-type-method (named :complex-union2) (type1 type2)
 943   ;; Perhaps when bug 85 is fixed this can be reenabled.
 944   ;;(aver (not (eq type2 *wild-type*))) ; * isn't really a type.
 945   (hierarchical-union2 type1 type2))
 946
 947 (!define-type-method (named :unparse) (x)
 948   (named-type-name x))
 949 \f
 950 ;;;; hairy and unknown types
 951
 952 (!define-type-method (hairy :unparse) (x) (hairy-type-specifier x))
 953
 954 (!define-type-method (hairy :simple-subtypep) (type1 type2)
 955   (let ((hairy-spec1 (hairy-type-specifier type1))
 956         (hairy-spec2 (hairy-type-specifier type2)))
 957     (cond ((and (consp hairy-spec1) (eq (car hairy-spec1) 'not)
 958                 (consp hairy-spec2) (eq (car hairy-spec2) 'not))
 959            (csubtypep (specifier-type (cadr hairy-spec2))
 960                       (specifier-type (cadr hairy-spec1))))
 961           ((equal hairy-spec1 hairy-spec2)
 962            (values t t))
 963           (t
 964            (values nil nil)))))
 965
 966 (!define-type-method (hairy :complex-subtypep-arg2) (type1 type2)
 967   (let ((hairy-spec (hairy-type-specifier type2)))
 968     (cond ((and (consp hairy-spec) (eq (car hairy-spec) 'not))
 969            (let* ((complement-type2 (specifier-type (cadr hairy-spec)))
 970                   (intersection2 (type-intersection2 type1
 971                                                      complement-type2)))
 972              (if intersection2
 973                  (values (eq intersection2 *empty-type*) t)
 974                  (values nil nil))))
 975           (t
 976            (values nil nil)))))
 977
 978 (!define-type-method (hairy :complex-subtypep-arg1 :complex-=) (type1 type2)
 979   (declare (ignore type1 type2))
 980   (values nil nil))
 981
 982 (!define-type-method (hairy :simple-intersection2 :complex-intersection2)
 983                      (type1 type2)
 984   (declare (ignore type1 type2))
 985   nil)
 986
 987 (!define-type-method (hairy :simple-=) (type1 type2)
 988   (if (equal (hairy-type-specifier type1)
 989              (hairy-type-specifier type2))
 990       (values t t)
 991       (values nil nil)))
 992
 993 (!def-type-translator not (&whole whole type)
 994   (declare (ignore type))
 995   ;; Check legality of arguments.
 996   (destructuring-bind (not typespec) whole
 997     (declare (ignore not))
 998     (specifier-type typespec)) ; must be legal typespec
 999   ;; Create object.
1000   (make-hairy-type :specifier whole))
1001
1002 (!def-type-translator satisfies (&whole whole fun)
1003   (declare (ignore fun))
1004   ;; Check legality of arguments.
1005   (destructuring-bind (satisfies predicate-name) whole
1006     (declare (ignore satisfies))
1007     (unless (symbolp predicate-name)
1008       (error 'simple-type-error
1009              :datum predicate-name
1010              :expected-type 'symbol
1011              :format-control "~S is not a symbol."
1012              :format-arguments (list predicate-name))))
1013   ;; Create object.
1014   (make-hairy-type :specifier whole))
1015 \f
1016 ;;;; numeric types
1017
1018 (!define-type-class number)
1019
1020 (!define-type-method (number :simple-=) (type1 type2)
1021   (values
1022    (and (eq (numeric-type-class type1) (numeric-type-class type2))
1023         (eq (numeric-type-format type1) (numeric-type-format type2))
1024         (eq (numeric-type-complexp type1) (numeric-type-complexp type2))
1025         (equal (numeric-type-low type1) (numeric-type-low type2))
1026         (equal (numeric-type-high type1) (numeric-type-high type2)))
1027    t))
1028
1029 (!define-type-method (number :unparse) (type)
1030   (let* ((complexp (numeric-type-complexp type))
1031          (low (numeric-type-low type))
1032          (high (numeric-type-high type))
1033          (base (case (numeric-type-class type)
1034                  (integer 'integer)
1035                  (rational 'rational)
1036                  (float (or (numeric-type-format type) 'float))
1037                  (t 'real))))
1038     (let ((base+bounds
1039            (cond ((and (eq base 'integer) high low)
1040                   (let ((high-count (logcount high))
1041                         (high-length (integer-length high)))
1042                     (cond ((= low 0)
1043                            (cond ((= high 0) '(integer 0 0))
1044                                  ((= high 1) 'bit)
1045                                  ((and (= high-count high-length)
1046                                        (plusp high-length))
1047                                   `(unsigned-byte ,high-length))
1048                                  (t
1049                                   `(mod ,(1+ high)))))
1050                           ((and (= low sb!vm:*target-most-negative-fixnum*)
1051                                 (= high sb!vm:*target-most-positive-fixnum*))
1052                            'fixnum)
1053                           ((and (= low (lognot high))
1054                                 (= high-count high-length)
1055                                 (> high-count 0))
1056                            `(signed-byte ,(1+ high-length)))
1057                           (t
1058                            `(integer ,low ,high)))))
1059                  (high `(,base ,(or low '*) ,high))
1060                  (low
1061                   (if (and (eq base 'integer) (= low 0))
1062                       'unsigned-byte
1063                       `(,base ,low)))
1064                  (t base))))
1065       (ecase complexp
1066         (:real
1067          base+bounds)
1068         (:complex
1069          (if (eq base+bounds 'real)
1070              'complex
1071              `(complex ,base+bounds)))
1072         ((nil)
1073          (aver (eq base+bounds 'real))
1074          'number)))))
1075
1076 ;;; Return true if X is "less than or equal" to Y, taking open bounds
1077 ;;; into consideration. CLOSED is the predicate used to test the bound
1078 ;;; on a closed interval (e.g. <=), and OPEN is the predicate used on
1079 ;;; open bounds (e.g. <). Y is considered to be the outside bound, in
1080 ;;; the sense that if it is infinite (NIL), then the test succeeds,
1081 ;;; whereas if X is infinite, then the test fails (unless Y is also
1082 ;;; infinite).
1083 ;;;
1084 ;;; This is for comparing bounds of the same kind, e.g. upper and
1085 ;;; upper. Use NUMERIC-BOUND-TEST* for different kinds of bounds.
1086 #!-negative-zero-is-not-zero
1087 (defmacro numeric-bound-test (x y closed open)
1088   `(cond ((not ,y) t)
1089          ((not ,x) nil)
1090          ((consp ,x)
1091           (if (consp ,y)
1092               (,closed (car ,x) (car ,y))
1093               (,closed (car ,x) ,y)))
1094          (t
1095           (if (consp ,y)
1096               (,open ,x (car ,y))
1097               (,closed ,x ,y)))))
1098
1099 #!+negative-zero-is-not-zero
1100 (defmacro numeric-bound-test-zero (op x y)
1101   `(if (and (zerop ,x) (zerop ,y) (floatp ,x) (floatp ,y))
1102        (,op (float-sign ,x) (float-sign ,y))
1103        (,op ,x ,y)))
1104
1105 #!+negative-zero-is-not-zero
1106 (defmacro numeric-bound-test (x y closed open)
1107   `(cond ((not ,y) t)
1108          ((not ,x) nil)
1109          ((consp ,x)
1110           (if (consp ,y)
1111               (numeric-bound-test-zero ,closed (car ,x) (car ,y))
1112               (numeric-bound-test-zero ,closed (car ,x) ,y)))
1113          (t
1114           (if (consp ,y)
1115               (numeric-bound-test-zero ,open ,x (car ,y))
1116               (numeric-bound-test-zero ,closed ,x ,y)))))
1117
1118 ;;; This is used to compare upper and lower bounds. This is different
1119 ;;; from the same-bound case:
1120 ;;; -- Since X = NIL is -infinity, whereas y = NIL is +infinity, we
1121 ;;;    return true if *either* arg is NIL.
1122 ;;; -- an open inner bound is "greater" and also squeezes the interval,
1123 ;;;    causing us to use the OPEN test for those cases as well.
1124 #!-negative-zero-is-not-zero
1125 (defmacro numeric-bound-test* (x y closed open)
1126   `(cond ((not ,y) t)
1127          ((not ,x) t)
1128          ((consp ,x)
1129           (if (consp ,y)
1130               (,open (car ,x) (car ,y))
1131               (,open (car ,x) ,y)))
1132          (t
1133           (if (consp ,y)
1134               (,open ,x (car ,y))
1135               (,closed ,x ,y)))))
1136
1137 #!+negative-zero-is-not-zero
1138 (defmacro numeric-bound-test* (x y closed open)
1139   `(cond ((not ,y) t)
1140          ((not ,x) t)
1141          ((consp ,x)
1142           (if (consp ,y)
1143               (numeric-bound-test-zero ,open (car ,x) (car ,y))
1144               (numeric-bound-test-zero ,open (car ,x) ,y)))
1145          (t
1146           (if (consp ,y)
1147               (numeric-bound-test-zero ,open ,x (car ,y))
1148               (numeric-bound-test-zero ,closed ,x ,y)))))
1149
1150 ;;; Return whichever of the numeric bounds X and Y is "maximal"
1151 ;;; according to the predicates CLOSED (e.g. >=) and OPEN (e.g. >).
1152 ;;; This is only meaningful for maximizing like bounds, i.e. upper and
1153 ;;; upper. If MAX-P is true, then we return NIL if X or Y is NIL,
1154 ;;; otherwise we return the other arg.
1155 (defmacro numeric-bound-max (x y closed open max-p)
1156   (once-only ((n-x x)
1157               (n-y y))
1158     `(cond ((not ,n-x) ,(if max-p nil n-y))
1159            ((not ,n-y) ,(if max-p nil n-x))
1160            ((consp ,n-x)
1161             (if (consp ,n-y)
1162                 (if (,closed (car ,n-x) (car ,n-y)) ,n-x ,n-y)
1163                 (if (,open (car ,n-x) ,n-y) ,n-x ,n-y)))
1164            (t
1165             (if (consp ,n-y)
1166                 (if (,open (car ,n-y) ,n-x) ,n-y ,n-x)
1167                 (if (,closed ,n-y ,n-x) ,n-y ,n-x))))))
1168
1169 (!define-type-method (number :simple-subtypep) (type1 type2)
1170   (let ((class1 (numeric-type-class type1))
1171         (class2 (numeric-type-class type2))
1172         (complexp2 (numeric-type-complexp type2))
1173         (format2 (numeric-type-format type2))
1174         (low1 (numeric-type-low type1))
1175         (high1 (numeric-type-high type1))
1176         (low2 (numeric-type-low type2))
1177         (high2 (numeric-type-high type2)))
1178     ;; If one is complex and the other isn't, they are disjoint.
1179     (cond ((not (or (eq (numeric-type-complexp type1) complexp2)
1180                     (null complexp2)))
1181            (values nil t))
1182           ;; If the classes are specified and different, the types are
1183           ;; disjoint unless type2 is rational and type1 is integer.
1184           ((not (or (eq class1 class2)
1185                     (null class2)
1186                     (and (eq class1 'integer)
1187                          (eq class2 'rational))))
1188            (values nil t))
1189           ;; If the float formats are specified and different, the types
1190           ;; are disjoint.
1191           ((not (or (eq (numeric-type-format type1) format2)
1192                     (null format2)))
1193            (values nil t))
1194           ;; Check the bounds.
1195           ((and (numeric-bound-test low1 low2 >= >)
1196                 (numeric-bound-test high1 high2 <= <))
1197            (values t t))
1198           (t
1199            (values nil t)))))
1200
1201 (!define-superclasses number ((generic-number)) !cold-init-forms)
1202
1203 ;;; If the high bound of LOW is adjacent to the low bound of HIGH,
1204 ;;; then return true, otherwise NIL.
1205 (defun numeric-types-adjacent (low high)
1206   (let ((low-bound (numeric-type-high low))
1207         (high-bound (numeric-type-low high)))
1208     (cond ((not (and low-bound high-bound)) nil)
1209           ((and (consp low-bound) (consp high-bound)) nil)
1210           ((consp low-bound)
1211            #!-negative-zero-is-not-zero
1212            (let ((low-value (car low-bound)))
1213              (or (eql low-value high-bound)
1214                  (and (eql low-value -0f0) (eql high-bound 0f0))
1215                  (and (eql low-value 0f0) (eql high-bound -0f0))
1216                  (and (eql low-value -0d0) (eql high-bound 0d0))
1217                  (and (eql low-value 0d0) (eql high-bound -0d0))))
1218            #!+negative-zero-is-not-zero
1219            (eql (car low-bound) high-bound))
1220           ((consp high-bound)
1221            #!-negative-zero-is-not-zero
1222            (let ((high-value (car high-bound)))
1223              (or (eql high-value low-bound)
1224                  (and (eql high-value -0f0) (eql low-bound 0f0))
1225                  (and (eql high-value 0f0) (eql low-bound -0f0))
1226                  (and (eql high-value -0d0) (eql low-bound 0d0))
1227                  (and (eql high-value 0d0) (eql low-bound -0d0))))
1228            #!+negative-zero-is-not-zero
1229            (eql (car high-bound) low-bound))
1230           #!+negative-zero-is-not-zero
1231           ((or (and (eql low-bound -0f0) (eql high-bound 0f0))
1232                (and (eql low-bound -0d0) (eql high-bound 0d0))))
1233           ((and (eq (numeric-type-class low) 'integer)
1234                 (eq (numeric-type-class high) 'integer))
1235            (eql (1+ low-bound) high-bound))
1236           (t
1237            nil))))
1238
1239 ;;; Return a numeric type that is a supertype for both TYPE1 and TYPE2.
1240 ;;;
1241 ;;; ### Note: we give up early to keep from dropping lots of information on
1242 ;;; the floor by returning overly general types.
1243 (!define-type-method (number :simple-union2) (type1 type2)
1244   (declare (type numeric-type type1 type2))
1245   (cond ((csubtypep type1 type2) type2)
1246         ((csubtypep type2 type1) type1)
1247         (t
1248          (let ((class1 (numeric-type-class type1))
1249                (format1 (numeric-type-format type1))
1250                (complexp1 (numeric-type-complexp type1))
1251                (class2 (numeric-type-class type2))
1252                (format2 (numeric-type-format type2))
1253                (complexp2 (numeric-type-complexp type2)))
1254            (when (and (eq class1 class2)
1255                       (eq format1 format2)
1256                       (eq complexp1 complexp2)
1257                       (or (numeric-types-intersect type1 type2)
1258                           (numeric-types-adjacent type1 type2)
1259                           (numeric-types-adjacent type2 type1)))
1260              (make-numeric-type
1261               :class class1
1262               :format format1
1263               :complexp complexp1
1264               :low (numeric-bound-max (numeric-type-low type1)
1265                                       (numeric-type-low type2)
1266                                       <= < t)
1267               :high (numeric-bound-max (numeric-type-high type1)
1268                                        (numeric-type-high type2)
1269                                        >= > t)))))))
1270
1271 (!cold-init-forms
1272   (setf (info :type :kind 'number) :primitive)
1273   (setf (info :type :builtin 'number)
1274         (make-numeric-type :complexp nil)))
1275
1276 (!def-type-translator complex (&optional (typespec '*))
1277   (if (eq typespec '*)
1278       (make-numeric-type :complexp :complex)
1279       (labels ((not-numeric ()
1280                  (error "The component type for COMPLEX is not numeric: ~S"
1281                         typespec))
1282                (not-real ()
1283                  (error "The component type for COMPLEX is not real: ~S"
1284                         typespec))
1285                (complex1 (component-type)
1286                  (unless (numeric-type-p component-type)
1287                    (not-numeric))
1288                  (when (eq (numeric-type-complexp component-type) :complex)
1289                    (not-real))
1290                  (modified-numeric-type component-type :complexp :complex))
1291                (complex-union (component)
1292                  (unless (numberp component)
1293                    (not-numeric))
1294                  ;; KLUDGE: This TYPECASE more or less does
1295                  ;; (UPGRADED-COMPLEX-PART-TYPE (TYPE-OF COMPONENT)),
1296                  ;; (plus a small hack to treat (EQL COMPONENT 0) specially)
1297                  ;; but uses logic cut and pasted from the DEFUN of
1298                  ;; UPGRADED-COMPLEX-PART-TYPE. That's fragile, because
1299                  ;; changing the definition of UPGRADED-COMPLEX-PART-TYPE
1300                  ;; would tend to break the code here. Unfortunately,
1301                  ;; though, reusing UPGRADED-COMPLEX-PART-TYPE here
1302                  ;; would cause another kind of fragility, because
1303                  ;; ANSI's definition of TYPE-OF is so weak that e.g.
1304                  ;; (UPGRADED-COMPLEX-PART-TYPE (TYPE-OF 1/2)) could
1305                  ;; end up being (UPGRADED-COMPLEX-PART-TYPE 'REAL)
1306                  ;; instead of (UPGRADED-COMPLEX-PART-TYPE 'RATIONAL).
1307                  ;; So using TYPE-OF would mean that ANSI-conforming
1308                  ;; maintenance changes in TYPE-OF could break the code here.
1309                  ;; It's not clear how best to fix this. -- WHN 2002-01-21,
1310                  ;; trying to summarize CSR's concerns in his patch
1311                  (typecase component
1312                    (complex (error "The component type for COMPLEX (EQL X) ~
1313                                     is complex: ~S"
1314                                    component))
1315                    ((eql 0) (specifier-type nil)) ; as required by ANSI
1316                    (single-float (specifier-type '(complex single-float)))
1317                    (double-float (specifier-type '(complex double-float)))
1318                    #!+long-float
1319                    (long-float (specifier-type '(complex long-float)))
1320                    (rational (specifier-type '(complex rational)))
1321                    (t (specifier-type '(complex real))))))
1322         (let ((ctype (specifier-type typespec)))
1323           (typecase ctype
1324             (numeric-type (complex1 ctype))
1325             (union-type (apply #'type-union
1326                                ;; FIXME: This code could suffer from
1327                                ;; (admittedly very obscure) cases of
1328                                ;; bug 145 e.g. when TYPE is
1329                                ;;   (OR (AND INTEGER (SATISFIES ODDP))
1330                                ;;       (AND FLOAT (SATISFIES FOO))
1331                                ;; and not even report the problem very well.
1332                                (mapcar #'complex1
1333                                        (union-type-types ctype))))
1334             ;; MEMBER-TYPE is almost the same as UNION-TYPE, but
1335             ;; there's a gotcha: (COMPLEX (EQL 0)) is, according to
1336             ;; ANSI, equal to type NIL, the empty set.
1337             (member-type (apply #'type-union
1338                                 (mapcar #'complex-union
1339                                         (member-type-members ctype))))
1340             (t
1341              (multiple-value-bind (subtypep certainly)
1342                  (csubtypep ctype (specifier-type 'real))
1343                (if (and (not subtypep) certainly)
1344                    (not-real)
1345                    ;; ANSI just says that TYPESPEC is any subtype of
1346                    ;; type REAL, not necessarily a NUMERIC-TYPE. In
1347                    ;; particular, at this point TYPESPEC could legally be
1348                    ;; an intersection type like (AND REAL (SATISFIES ODDP)),
1349                    ;; in which case we fall through the logic above and
1350                    ;; end up here, stumped.
1351                    (bug "~@<(known bug #145): The type ~S is too hairy to be
1352                          used for a COMPLEX component.~:@>"
1353                         typespec)))))))))
1354
1355 ;;; If X is *, return NIL, otherwise return the bound, which must be a
1356 ;;; member of TYPE or a one-element list of a member of TYPE.
1357 #!-sb-fluid (declaim (inline canonicalized-bound))
1358 (defun canonicalized-bound (bound type)
1359   (cond ((eq bound '*) nil)
1360         ((or (sb!xc:typep bound type)
1361              (and (consp bound)
1362                   (sb!xc:typep (car bound) type)
1363                   (null (cdr bound))))
1364           bound)
1365         (t
1366          (error "Bound is not ~S, a ~S or a list of a ~S: ~S"
1367                 '*
1368                 type
1369                 type
1370                 bound))))
1371
1372 (!def-type-translator integer (&optional (low '*) (high '*))
1373   (let* ((l (canonicalized-bound low 'integer))
1374          (lb (if (consp l) (1+ (car l)) l))
1375          (h (canonicalized-bound high 'integer))
1376          (hb (if (consp h) (1- (car h)) h)))
1377     (when (and hb lb (< hb lb))
1378       (error "Lower bound ~S is greater than upper bound ~S." l h))
1379     (make-numeric-type :class 'integer
1380                        :complexp :real
1381                        :enumerable (not (null (and l h)))
1382                        :low lb
1383                        :high hb)))
1384
1385 (defmacro !def-bounded-type (type class format)
1386   `(!def-type-translator ,type (&optional (low '*) (high '*))
1387      (let ((lb (canonicalized-bound low ',type))
1388            (hb (canonicalized-bound high ',type)))
1389        (unless (numeric-bound-test* lb hb <= <)
1390          (error "Lower bound ~S is not less than upper bound ~S." low high))
1391        (make-numeric-type :class ',class :format ',format :low lb :high hb))))
1392
1393 (!def-bounded-type rational rational nil)
1394
1395 ;;; Unlike CMU CL, we represent the types FLOAT and REAL as
1396 ;;; UNION-TYPEs of more primitive types, in order to make
1397 ;;; type representation more unique, avoiding problems in the
1398 ;;; simplification of things like
1399 ;;;   (subtypep '(or (single-float -1.0 1.0) (single-float 0.1))
1400 ;;;             '(or (real -1 7) (single-float 0.1) (single-float -1.0 1.0)))
1401 ;;; When we allowed REAL to remain as a separate NUMERIC-TYPE,
1402 ;;; it was too easy for the first argument to be simplified to
1403 ;;; '(SINGLE-FLOAT -1.0), and for the second argument to be simplified
1404 ;;; to '(OR (REAL -1 7) (SINGLE-FLOAT 0.1)) and then for the
1405 ;;; SUBTYPEP to fail (returning NIL,T instead of T,T) because
1406 ;;; the first argument can't be seen to be a subtype of any of the
1407 ;;; terms in the second argument.
1408 ;;;
1409 ;;; The old CMU CL way was:
1410 ;;;   (!def-bounded-type float float nil)
1411 ;;;   (!def-bounded-type real nil nil)
1412 ;;;
1413 ;;; FIXME: If this new way works for a while with no weird new
1414 ;;; problems, we can go back and rip out support for separate FLOAT
1415 ;;; and REAL flavors of NUMERIC-TYPE. The new way was added in
1416 ;;; sbcl-0.6.11.22, 2001-03-21.
1417 ;;;
1418 ;;; FIXME: It's probably necessary to do something to fix the
1419 ;;; analogous problem with INTEGER and RATIONAL types. Perhaps
1420 ;;; bounded RATIONAL types should be represented as (OR RATIO INTEGER).
1421 (defun coerce-bound (bound type inner-coerce-bound-fun)
1422   (declare (type function inner-coerce-bound-fun))
1423   (cond ((eql bound '*)
1424          bound)
1425         ((consp bound)
1426          (destructuring-bind (inner-bound) bound
1427            (list (funcall inner-coerce-bound-fun inner-bound type))))
1428         (t
1429          (funcall inner-coerce-bound-fun bound type))))
1430 (defun inner-coerce-real-bound (bound type)
1431   (ecase type
1432     (rational (rationalize bound))
1433     (float (if (floatp bound)
1434                bound
1435                ;; Coerce to the widest float format available, to
1436                ;; avoid unnecessary loss of precision:
1437                (coerce bound 'long-float)))))
1438 (defun coerced-real-bound (bound type)
1439   (coerce-bound bound type #'inner-coerce-real-bound))
1440 (defun coerced-float-bound (bound type)
1441   (coerce-bound bound type #'coerce))
1442 (!def-type-translator real (&optional (low '*) (high '*))
1443   (specifier-type `(or (float ,(coerced-real-bound  low 'float)
1444                               ,(coerced-real-bound high 'float))
1445                        (rational ,(coerced-real-bound  low 'rational)
1446                                  ,(coerced-real-bound high 'rational)))))
1447 (!def-type-translator float (&optional (low '*) (high '*))
1448   (specifier-type
1449    `(or (single-float ,(coerced-float-bound  low 'single-float)
1450                       ,(coerced-float-bound high 'single-float))
1451         (double-float ,(coerced-float-bound  low 'double-float)
1452                       ,(coerced-float-bound high 'double-float))
1453         #!+long-float ,(error "stub: no long float support yet"))))
1454
1455 (defmacro !define-float-format (f)
1456   `(!def-bounded-type ,f float ,f))
1457
1458 (!define-float-format short-float)
1459 (!define-float-format single-float)
1460 (!define-float-format double-float)
1461 (!define-float-format long-float)
1462
1463 (defun numeric-types-intersect (type1 type2)
1464   (declare (type numeric-type type1 type2))
1465   (let* ((class1 (numeric-type-class type1))
1466          (class2 (numeric-type-class type2))
1467          (complexp1 (numeric-type-complexp type1))
1468          (complexp2 (numeric-type-complexp type2))
1469          (format1 (numeric-type-format type1))
1470          (format2 (numeric-type-format type2))
1471          (low1 (numeric-type-low type1))
1472          (high1 (numeric-type-high type1))
1473          (low2 (numeric-type-low type2))
1474          (high2 (numeric-type-high type2)))
1475     ;; If one is complex and the other isn't, then they are disjoint.
1476     (cond ((not (or (eq complexp1 complexp2)
1477                     (null complexp1) (null complexp2)))
1478            nil)
1479           ;; If either type is a float, then the other must either be
1480           ;; specified to be a float or unspecified. Otherwise, they
1481           ;; are disjoint.
1482           ((and (eq class1 'float)
1483                 (not (member class2 '(float nil)))) nil)
1484           ((and (eq class2 'float)
1485                 (not (member class1 '(float nil)))) nil)
1486           ;; If the float formats are specified and different, the
1487           ;; types are disjoint.
1488           ((not (or (eq format1 format2) (null format1) (null format2)))
1489            nil)
1490           (t
1491            ;; Check the bounds. This is a bit odd because we must
1492            ;; always have the outer bound of the interval as the
1493            ;; second arg.
1494            (if (numeric-bound-test high1 high2 <= <)
1495                (or (and (numeric-bound-test low1 low2 >= >)
1496                         (numeric-bound-test* low1 high2 <= <))
1497                    (and (numeric-bound-test low2 low1 >= >)
1498                         (numeric-bound-test* low2 high1 <= <)))
1499                (or (and (numeric-bound-test* low2 high1 <= <)
1500                         (numeric-bound-test low2 low1 >= >))
1501                    (and (numeric-bound-test high2 high1 <= <)
1502                         (numeric-bound-test* high2 low1 >= >))))))))
1503
1504 ;;; Take the numeric bound X and convert it into something that can be
1505 ;;; used as a bound in a numeric type with the specified CLASS and
1506 ;;; FORMAT. If UP-P is true, then we round up as needed, otherwise we
1507 ;;; round down. UP-P true implies that X is a lower bound, i.e. (N) > N.
1508 ;;;
1509 ;;; This is used by NUMERIC-TYPE-INTERSECTION to mash the bound into
1510 ;;; the appropriate type number. X may only be a float when CLASS is
1511 ;;; FLOAT.
1512 ;;;
1513 ;;; ### Note: it is possible for the coercion to a float to overflow
1514 ;;; or underflow. This happens when the bound doesn't fit in the
1515 ;;; specified format. In this case, we should really return the
1516 ;;; appropriate {Most | Least}-{Positive | Negative}-XXX-Float float
1517 ;;; of desired format. But these conditions aren't currently signalled
1518 ;;; in any useful way.
1519 ;;;
1520 ;;; Also, when converting an open rational bound into a float we
1521 ;;; should probably convert it to a closed bound of the closest float
1522 ;;; in the specified format. KLUDGE: In general, open float bounds are
1523 ;;; screwed up. -- (comment from original CMU CL)
1524 (defun round-numeric-bound (x class format up-p)
1525   (if x
1526       (let ((cx (if (consp x) (car x) x)))
1527         (ecase class
1528           ((nil rational) x)
1529           (integer
1530            (if (and (consp x) (integerp cx))
1531                (if up-p (1+ cx) (1- cx))
1532                (if up-p (ceiling cx) (floor cx))))
1533           (float
1534            (let ((res (if format (coerce cx format) (float cx))))
1535              (if (consp x) (list res) res)))))
1536       nil))
1537
1538 ;;; Handle the case of type intersection on two numeric types. We use
1539 ;;; TYPES-EQUAL-OR-INTERSECT to throw out the case of types with no
1540 ;;; intersection. If an attribute in TYPE1 is unspecified, then we use
1541 ;;; TYPE2's attribute, which must be at least as restrictive. If the
1542 ;;; types intersect, then the only attributes that can be specified
1543 ;;; and different are the class and the bounds.
1544 ;;;
1545 ;;; When the class differs, we use the more restrictive class. The
1546 ;;; only interesting case is RATIONAL/INTEGER, since RATIONAL includes
1547 ;;; INTEGER.
1548 ;;;
1549 ;;; We make the result lower (upper) bound the maximum (minimum) of
1550 ;;; the argument lower (upper) bounds. We convert the bounds into the
1551 ;;; appropriate numeric type before maximizing. This avoids possible
1552 ;;; confusion due to mixed-type comparisons (but I think the result is
1553 ;;; the same).
1554 (!define-type-method (number :simple-intersection2) (type1 type2)
1555   (declare (type numeric-type type1 type2))
1556   (if (numeric-types-intersect type1 type2)
1557       (let* ((class1 (numeric-type-class type1))
1558              (class2 (numeric-type-class type2))
1559              (class (ecase class1
1560                       ((nil) class2)
1561                       ((integer float) class1)
1562                       (rational (if (eq class2 'integer)
1563                                        'integer
1564                                        'rational))))
1565              (format (or (numeric-type-format type1)
1566                          (numeric-type-format type2))))
1567         (make-numeric-type
1568          :class class
1569          :format format
1570          :complexp (or (numeric-type-complexp type1)
1571                        (numeric-type-complexp type2))
1572          :low (numeric-bound-max
1573                (round-numeric-bound (numeric-type-low type1)
1574                                     class format t)
1575                (round-numeric-bound (numeric-type-low type2)
1576                                     class format t)
1577                > >= nil)
1578          :high (numeric-bound-max
1579                 (round-numeric-bound (numeric-type-high type1)
1580                                      class format nil)
1581                 (round-numeric-bound (numeric-type-high type2)
1582                                      class format nil)
1583                 < <= nil)))
1584       *empty-type*))
1585
1586 ;;; Given two float formats, return the one with more precision. If
1587 ;;; either one is null, return NIL.
1588 (defun float-format-max (f1 f2)
1589   (when (and f1 f2)
1590     (dolist (f *float-formats* (error "bad float format: ~S" f1))
1591       (when (or (eq f f1) (eq f f2))
1592         (return f)))))
1593
1594 ;;; Return the result of an operation on TYPE1 and TYPE2 according to
1595 ;;; the rules of numeric contagion. This is always NUMBER, some float
1596 ;;; format (possibly complex) or RATIONAL. Due to rational
1597 ;;; canonicalization, there isn't much we can do here with integers or
1598 ;;; rational complex numbers.
1599 ;;;
1600 ;;; If either argument is not a NUMERIC-TYPE, then return NUMBER. This
1601 ;;; is useful mainly for allowing types that are technically numbers,
1602 ;;; but not a NUMERIC-TYPE.
1603 (defun numeric-contagion (type1 type2)
1604   (if (and (numeric-type-p type1) (numeric-type-p type2))
1605       (let ((class1 (numeric-type-class type1))
1606             (class2 (numeric-type-class type2))
1607             (format1 (numeric-type-format type1))
1608             (format2 (numeric-type-format type2))
1609             (complexp1 (numeric-type-complexp type1))
1610             (complexp2 (numeric-type-complexp type2)))
1611         (cond ((or (null complexp1)
1612                    (null complexp2))
1613                (specifier-type 'number))
1614               ((eq class1 'float)
1615                (make-numeric-type
1616                 :class 'float
1617                 :format (ecase class2
1618                           (float (float-format-max format1 format2))
1619                           ((integer rational) format1)
1620                           ((nil)
1621                            ;; A double-float with any real number is a
1622                            ;; double-float.
1623                            #!-long-float
1624                            (if (eq format1 'double-float)
1625                              'double-float
1626                              nil)
1627                            ;; A long-float with any real number is a
1628                            ;; long-float.
1629                            #!+long-float
1630                            (if (eq format1 'long-float)
1631                              'long-float
1632                              nil)))
1633                 :complexp (if (or (eq complexp1 :complex)
1634                                   (eq complexp2 :complex))
1635                               :complex
1636                               :real)))
1637               ((eq class2 'float) (numeric-contagion type2 type1))
1638               ((and (eq complexp1 :real) (eq complexp2 :real))
1639                (make-numeric-type
1640                 :class (and class1 class2 'rational)
1641                 :complexp :real))
1642               (t
1643                (specifier-type 'number))))
1644       (specifier-type 'number)))
1645 \f
1646 ;;;; array types
1647
1648 (!define-type-class array)
1649
1650 ;;; What this does depends on the setting of the
1651 ;;; *USE-IMPLEMENTATION-TYPES* switch. If true, return the specialized
1652 ;;; element type, otherwise return the original element type.
1653 (defun specialized-element-type-maybe (type)
1654   (declare (type array-type type))
1655   (if *use-implementation-types*
1656       (array-type-specialized-element-type type)
1657       (array-type-element-type type)))
1658
1659 (!define-type-method (array :simple-=) (type1 type2)
1660   (values (and (equal (array-type-dimensions type1)
1661                       (array-type-dimensions type2))
1662                (eq (array-type-complexp type1)
1663                    (array-type-complexp type2))
1664                (type= (specialized-element-type-maybe type1)
1665                       (specialized-element-type-maybe type2)))
1666           t))
1667
1668 (!define-type-method (array :unparse) (type)
1669   (let ((dims (array-type-dimensions type))
1670         (eltype (type-specifier (array-type-element-type type)))
1671         (complexp (array-type-complexp type)))
1672     (cond ((eq dims '*)
1673            (if (eq eltype '*)
1674                (if complexp 'array 'simple-array)
1675                (if complexp `(array ,eltype) `(simple-array ,eltype))))
1676           ((= (length dims) 1)
1677            (if complexp
1678                (if (eq (car dims) '*)
1679                    (case eltype
1680                      (bit 'bit-vector)
1681                      (base-char 'base-string)
1682                      (character 'string)
1683                      (* 'vector)
1684                      (t `(vector ,eltype)))
1685                    (case eltype
1686                      (bit `(bit-vector ,(car dims)))
1687                      (base-char `(base-string ,(car dims)))
1688                      (character `(string ,(car dims)))
1689                      (t `(vector ,eltype ,(car dims)))))
1690                (if (eq (car dims) '*)
1691                    (case eltype
1692                      (bit 'simple-bit-vector)
1693                      (base-char 'simple-base-string)
1694                      (character 'simple-string)
1695                      ((t) 'simple-vector)
1696                      (t `(simple-array ,eltype (*))))
1697                    (case eltype
1698                      (bit `(simple-bit-vector ,(car dims)))
1699                      (base-char `(simple-base-string ,(car dims)))
1700                      (character `(simple-string ,(car dims)))
1701                      ((t) `(simple-vector ,(car dims)))
1702                      (t `(simple-array ,eltype ,dims))))))
1703           (t
1704            (if complexp
1705                `(array ,eltype ,dims)
1706                `(simple-array ,eltype ,dims))))))
1707
1708 (!define-type-method (array :simple-subtypep) (type1 type2)
1709   (let ((dims1 (array-type-dimensions type1))
1710         (dims2 (array-type-dimensions type2))
1711         (complexp2 (array-type-complexp type2)))
1712     (cond (;; not subtypep unless dimensions are compatible
1713            (not (or (eq dims2 '*)
1714                     (and (not (eq dims1 '*))
1715                          ;; (sbcl-0.6.4 has trouble figuring out that
1716                          ;; DIMS1 and DIMS2 must be lists at this
1717                          ;; point, and knowing that is important to
1718                          ;; compiling EVERY efficiently.)
1719                          (= (length (the list dims1))
1720                             (length (the list dims2)))
1721                          (every (lambda (x y)
1722                                   (or (eq y '*) (eql x y)))
1723                                 (the list dims1)
1724                                 (the list dims2)))))
1725            (values nil t))
1726           ;; not subtypep unless complexness is compatible
1727           ((not (or (eq complexp2 :maybe)
1728                     (eq (array-type-complexp type1) complexp2)))
1729            (values nil t))
1730           ;; Since we didn't fail any of the tests above, we win
1731           ;; if the TYPE2 element type is wild.
1732           ((eq (array-type-element-type type2) *wild-type*)
1733            (values t t))
1734           (;; Since we didn't match any of the special cases above, we
1735            ;; can't give a good answer unless both the element types
1736            ;; have been defined.
1737            (or (unknown-type-p (array-type-element-type type1))
1738                (unknown-type-p (array-type-element-type type2)))
1739            (values nil nil))
1740           (;; Otherwise, the subtype relationship holds iff the
1741            ;; types are equal, and they're equal iff the specialized
1742            ;; element types are identical.
1743            t
1744            (values (type= (specialized-element-type-maybe type1)
1745                           (specialized-element-type-maybe type2))
1746                    t)))))
1747
1748 (!define-superclasses array
1749   ((string string)
1750    (vector vector)
1751    (array))
1752   !cold-init-forms)
1753
1754 (defun array-types-intersect (type1 type2)
1755   (declare (type array-type type1 type2))
1756   (let ((dims1 (array-type-dimensions type1))
1757         (dims2 (array-type-dimensions type2))
1758         (complexp1 (array-type-complexp type1))
1759         (complexp2 (array-type-complexp type2)))
1760     ;; See whether dimensions are compatible.
1761     (cond ((not (or (eq dims1 '*) (eq dims2 '*)
1762                     (and (= (length dims1) (length dims2))
1763                          (every (lambda (x y)
1764                                   (or (eq x '*) (eq y '*) (= x y)))
1765                                 dims1 dims2))))
1766            (values nil t))
1767           ;; See whether complexpness is compatible.
1768           ((not (or (eq complexp1 :maybe)
1769                     (eq complexp2 :maybe)
1770                     (eq complexp1 complexp2)))
1771            (values nil t))
1772           ;; If either element type is wild, then they intersect.
1773           ;; Otherwise, the types must be identical.
1774           ((or (eq (array-type-element-type type1) *wild-type*)
1775                (eq (array-type-element-type type2) *wild-type*)
1776                (type= (specialized-element-type-maybe type1)
1777                       (specialized-element-type-maybe type2)))
1778
1779            (values t t))
1780           (t
1781            (values nil t)))))
1782
1783 (!define-type-method (array :simple-intersection2) (type1 type2)
1784   (declare (type array-type type1 type2))
1785   (if (array-types-intersect type1 type2)
1786       (let ((dims1 (array-type-dimensions type1))
1787             (dims2 (array-type-dimensions type2))
1788             (complexp1 (array-type-complexp type1))
1789             (complexp2 (array-type-complexp type2))
1790             (eltype1 (array-type-element-type type1))
1791             (eltype2 (array-type-element-type type2)))
1792         (specialize-array-type
1793          (make-array-type
1794           :dimensions (cond ((eq dims1 '*) dims2)
1795                             ((eq dims2 '*) dims1)
1796                             (t
1797                              (mapcar (lambda (x y) (if (eq x '*) y x))
1798                                      dims1 dims2)))
1799           :complexp (if (eq complexp1 :maybe) complexp2 complexp1)
1800           :element-type (if (eq eltype1 *wild-type*) eltype2 eltype1))))
1801       *empty-type*))
1802
1803 ;;; Check a supplied dimension list to determine whether it is legal,
1804 ;;; and return it in canonical form (as either '* or a list).
1805 (defun canonical-array-dimensions (dims)
1806   (typecase dims
1807     ((member *) dims)
1808     (integer
1809      (when (minusp dims)
1810        (error "Arrays can't have a negative number of dimensions: ~S" dims))
1811      (when (>= dims sb!xc:array-rank-limit)
1812        (error "array type with too many dimensions: ~S" dims))
1813      (make-list dims :initial-element '*))
1814     (list
1815      (when (>= (length dims) sb!xc:array-rank-limit)
1816        (error "array type with too many dimensions: ~S" dims))
1817      (dolist (dim dims)
1818        (unless (eq dim '*)
1819          (unless (and (integerp dim)
1820                       (>= dim 0)
1821                       (< dim sb!xc:array-dimension-limit))
1822            (error "bad dimension in array type: ~S" dim))))
1823      dims)
1824     (t
1825      (error "Array dimensions is not a list, integer or *:~%  ~S" dims))))
1826 \f
1827 ;;;; MEMBER types
1828
1829 (!define-type-class member)
1830
1831 (!define-type-method (member :unparse) (type)
1832   (let ((members (member-type-members type)))
1833     (if (equal members '(nil))
1834         'null
1835         `(member ,@members))))
1836
1837 (!define-type-method (member :simple-subtypep) (type1 type2)
1838   (values (subsetp (member-type-members type1) (member-type-members type2))
1839           t))
1840
1841 (!define-type-method (member :complex-subtypep-arg1) (type1 type2)
1842   (every/type (swapped-args-fun #'ctypep)
1843               type2
1844               (member-type-members type1)))
1845
1846 ;;; We punt if the odd type is enumerable and intersects with the
1847 ;;; MEMBER type. If not enumerable, then it is definitely not a
1848 ;;; subtype of the MEMBER type.
1849 (!define-type-method (member :complex-subtypep-arg2) (type1 type2)
1850   (cond ((not (type-enumerable type1)) (values nil t))
1851         ((types-equal-or-intersect type1 type2) (values nil nil))
1852         (t (values nil t))))
1853
1854 (!define-type-method (member :simple-intersection2) (type1 type2)
1855   (let ((mem1 (member-type-members type1))
1856         (mem2 (member-type-members type2)))
1857     (cond ((subsetp mem1 mem2) type1)
1858           ((subsetp mem2 mem1) type2)
1859           (t
1860            (let ((res (intersection mem1 mem2)))
1861              (if res
1862                  (make-member-type :members res)
1863                  *empty-type*))))))
1864
1865 (!define-type-method (member :complex-intersection2) (type1 type2)
1866   (block punt
1867     (collect ((members))
1868       (let ((mem2 (member-type-members type2)))
1869         (dolist (member mem2)
1870           (multiple-value-bind (val win) (ctypep member type1)
1871             (unless win
1872               (return-from punt nil))
1873             (when val (members member))))
1874         (cond ((subsetp mem2 (members)) type2)
1875               ((null (members)) *empty-type*)
1876               (t
1877                (make-member-type :members (members))))))))
1878
1879 ;;; We don't need a :COMPLEX-UNION2, since the only interesting case is
1880 ;;; a union type, and the member/union interaction is handled by the
1881 ;;; union type method.
1882 (!define-type-method (member :simple-union2) (type1 type2)
1883   (let ((mem1 (member-type-members type1))
1884         (mem2 (member-type-members type2)))
1885     (cond ((subsetp mem1 mem2) type2)
1886           ((subsetp mem2 mem1) type1)
1887           (t
1888            (make-member-type :members (union mem1 mem2))))))
1889
1890 (!define-type-method (member :simple-=) (type1 type2)
1891   (let ((mem1 (member-type-members type1))
1892         (mem2 (member-type-members type2)))
1893     (values (and (subsetp mem1 mem2)
1894                  (subsetp mem2 mem1))
1895             t)))
1896
1897 (!define-type-method (member :complex-=) (type1 type2)
1898   (if (type-enumerable type1)
1899       (multiple-value-bind (val win) (csubtypep type2 type1)
1900         (if (or val (not win))
1901             (values nil nil)
1902             (values nil t)))
1903       (values nil t)))
1904
1905 (!def-type-translator member (&rest members)
1906   (if members
1907     (make-member-type :members (remove-duplicates members))
1908     *empty-type*))
1909 \f
1910 ;;;; intersection types
1911 ;;;;
1912 ;;;; Until version 0.6.10.6, SBCL followed the original CMU CL approach
1913 ;;;; of punting on all AND types, not just the unreasonably complicated
1914 ;;;; ones. The change was motivated by trying to get the KEYWORD type
1915 ;;;; to behave sensibly:
1916 ;;;;    ;; reasonable definition
1917 ;;;;    (DEFTYPE KEYWORD () '(AND SYMBOL (SATISFIES KEYWORDP)))
1918 ;;;;    ;; reasonable behavior
1919 ;;;;    (AVER (SUBTYPEP 'KEYWORD 'SYMBOL))
1920 ;;;; Without understanding a little about the semantics of AND, we'd
1921 ;;;; get (SUBTYPEP 'KEYWORD 'SYMBOL)=>NIL,NIL and, for entirely
1922 ;;;; parallel reasons, (SUBTYPEP 'RATIO 'NUMBER)=>NIL,NIL. That's
1923 ;;;; not so good..)
1924 ;;;;
1925 ;;;; We still follow the example of CMU CL to some extent, by punting
1926 ;;;; (to the opaque HAIRY-TYPE) on sufficiently complicated types
1927 ;;;; involving AND.
1928
1929 (!define-type-class intersection)
1930
1931 ;;; A few intersection types have special names. The others just get
1932 ;;; mechanically unparsed.
1933 (!define-type-method (intersection :unparse) (type)
1934   (declare (type ctype type))
1935   (or (find type '(ratio bignum keyword) :key #'specifier-type :test #'type=)
1936       `(and ,@(mapcar #'type-specifier (intersection-type-types type)))))
1937
1938 ;;; shared machinery for type equality: true if every type in the set
1939 ;;; TYPES1 matches a type in the set TYPES2 and vice versa
1940 (defun type=-set (types1 types2)
1941   (flet (;; true if every type in the set X matches a type in the set Y
1942          (type<=-set (x y)
1943            (declare (type list x y))
1944            (every (lambda (xelement)
1945                     (position xelement y :test #'type=))
1946                   x)))
1947     (values (and (type<=-set types1 types2)
1948                  (type<=-set types2 types1))
1949             t)))
1950
1951 ;;; Two intersection types are equal if their subtypes are equal sets.
1952 ;;;
1953 ;;; FIXME: Might it be better to use
1954 ;;;   (AND (SUBTYPEP X Y) (SUBTYPEP Y X))
1955 ;;; instead, since SUBTYPEP is the usual relationship that we care
1956 ;;; most about, so it would be good to leverage any ingenuity there
1957 ;;; in this more obscure method?
1958 (!define-type-method (intersection :simple-=) (type1 type2)
1959   (type=-set (intersection-type-types type1)
1960              (intersection-type-types type2)))
1961
1962 (defun %intersection-complex-subtypep-arg1 (type1 type2)
1963   (any/type (swapped-args-fun #'csubtypep)
1964             type2
1965             (intersection-type-types type1)))
1966
1967 (!define-type-method (intersection :simple-subtypep) (type1 type2)
1968   (every/type #'%intersection-complex-subtypep-arg1
1969               type1
1970               (intersection-type-types type2)))
1971
1972 (!define-type-method (intersection :complex-subtypep-arg1) (type1 type2)
1973   (%intersection-complex-subtypep-arg1 type1 type2))
1974
1975 (!define-type-method (intersection :complex-subtypep-arg2) (type1 type2)
1976   (every/type #'csubtypep type1 (intersection-type-types type2)))
1977
1978 (!def-type-translator and (&whole whole &rest type-specifiers)
1979   (apply #'type-intersection
1980          (mapcar #'specifier-type
1981                  type-specifiers)))
1982 \f
1983 ;;;; union types
1984
1985 (!define-type-class union)
1986
1987 ;;; The LIST type has a special name. Other union types just get
1988 ;;; mechanically unparsed.
1989 (!define-type-method (union :unparse) (type)
1990   (declare (type ctype type))
1991   (if (type= type (specifier-type 'list))
1992       'list
1993       `(or ,@(mapcar #'type-specifier (union-type-types type)))))
1994
1995 ;;; Two union types are equal if their subtypes are equal sets.
1996 (!define-type-method (union :simple-=) (type1 type2)
1997   (type=-set (union-type-types type1)
1998              (union-type-types type2)))
1999
2000 ;;; Similarly, a union type is a subtype of another if every element
2001 ;;; of TYPE1 is a subtype of some element of TYPE2.
2002 (!define-type-method (union :simple-subtypep) (type1 type2)
2003   (every/type (swapped-args-fun #'union-complex-subtypep-arg2)
2004               type2
2005               (union-type-types type1)))
2006
2007 (defun union-complex-subtypep-arg1 (type1 type2)
2008   (every/type (swapped-args-fun #'csubtypep)
2009               type2
2010               (union-type-types type1)))
2011 (!define-type-method (union :complex-subtypep-arg1) (type1 type2)
2012   (union-complex-subtypep-arg1 type1 type2))
2013
2014 (defun union-complex-subtypep-arg2 (type1 type2)
2015   (any/type #'csubtypep type1 (union-type-types type2)))
2016 (!define-type-method (union :complex-subtypep-arg2) (type1 type2)
2017   (union-complex-subtypep-arg2 type1 type2))
2018
2019 (!define-type-method (union :simple-intersection2 :complex-intersection2)
2020                      (type1 type2)
2021   ;; The CSUBTYPEP clauses here let us simplify e.g.
2022   ;;   (TYPE-INTERSECTION2 (SPECIFIER-TYPE 'LIST)
2023   ;;                       (SPECIFIER-TYPE '(OR LIST VECTOR)))
2024   ;; (where LIST is (OR CONS NULL)).
2025   ;;
2026   ;; The tests are more or less (CSUBTYPEP TYPE1 TYPE2) and vice
2027   ;; versa, but it's important that we pre-expand them into
2028   ;; specialized operations on individual elements of
2029   ;; UNION-TYPE-TYPES, instead of using the ordinary call to
2030   ;; CSUBTYPEP, in order to avoid possibly invoking any methods which
2031   ;; might in turn invoke (TYPE-INTERSECTION2 TYPE1 TYPE2) and thus
2032   ;; cause infinite recursion.
2033   (cond ((union-complex-subtypep-arg2 type1 type2)
2034          type1)
2035         ((union-complex-subtypep-arg1 type2 type1)
2036          type2)
2037         (t
2038          ;; KLUDGE: This code accumulates a sequence of TYPE-UNION2
2039          ;; operations in a particular order, and gives up if any of
2040          ;; the sub-unions turn out not to be simple. In other cases
2041          ;; ca. sbcl-0.6.11.15, that approach to taking a union was a
2042          ;; bad idea, since it can overlook simplifications which
2043          ;; might occur if the terms were accumulated in a different
2044          ;; order. It's possible that that will be a problem here too.
2045          ;; However, I can't think of a good example to demonstrate
2046          ;; it, and without an example to demonstrate it I can't write
2047          ;; test cases, and without test cases I don't want to
2048          ;; complicate the code to address what's still a hypothetical
2049          ;; problem. So I punted. -- WHN 2001-03-20
2050          (let ((accumulator *empty-type*))
2051            (dolist (t2 (union-type-types type2) accumulator)
2052              (setf accumulator
2053                    (type-union2 accumulator
2054                                 (type-intersection type1 t2)))
2055              ;; When our result isn't simple any more (because
2056              ;; TYPE-UNION2 was unable to give us a simple result)
2057              (unless accumulator
2058                (return nil)))))))
2059
2060 (!def-type-translator or (&rest type-specifiers)
2061   (apply #'type-union
2062          (mapcar #'specifier-type
2063                  type-specifiers)))
2064 \f
2065 ;;;; CONS types
2066
2067 (!define-type-class cons)
2068
2069 (!def-type-translator cons (&optional (car-type-spec '*) (cdr-type-spec '*))
2070   (make-cons-type (specifier-type car-type-spec)
2071                   (specifier-type cdr-type-spec)))
2072
2073 (!define-type-method (cons :unparse) (type)
2074   (let ((car-eltype (type-specifier (cons-type-car-type type)))
2075         (cdr-eltype (type-specifier (cons-type-cdr-type type))))
2076     (if (and (member car-eltype '(t *))
2077              (member cdr-eltype '(t *)))
2078         'cons
2079         `(cons ,car-eltype ,cdr-eltype))))
2080
2081 (!define-type-method (cons :simple-=) (type1 type2)
2082   (declare (type cons-type type1 type2))
2083   (and (type= (cons-type-car-type type1) (cons-type-car-type type2))
2084        (type= (cons-type-cdr-type type1) (cons-type-cdr-type type2))))
2085
2086 (!define-type-method (cons :simple-subtypep) (type1 type2)
2087   (declare (type cons-type type1 type2))
2088   (multiple-value-bind (val-car win-car)
2089       (csubtypep (cons-type-car-type type1) (cons-type-car-type type2))
2090     (multiple-value-bind (val-cdr win-cdr)
2091         (csubtypep (cons-type-cdr-type type1) (cons-type-cdr-type type2))
2092       (if (and val-car val-cdr)
2093           (values t (and win-car win-cdr))
2094           (values nil (or win-car win-cdr))))))
2095
2096 ;;; Give up if a precise type is not possible, to avoid returning
2097 ;;; overly general types.
2098 (!define-type-method (cons :simple-union2) (type1 type2)
2099   (declare (type cons-type type1 type2))
2100   (let ((car-type1 (cons-type-car-type type1))
2101         (car-type2 (cons-type-car-type type2))
2102         (cdr-type1 (cons-type-cdr-type type1))
2103         (cdr-type2 (cons-type-cdr-type type2)))
2104     (cond ((type= car-type1 car-type2)
2105            (make-cons-type car-type1
2106                            (type-union cdr-type1 cdr-type2)))
2107           ((type= cdr-type1 cdr-type2)
2108            (make-cons-type (type-union cdr-type1 cdr-type2)
2109                            cdr-type1)))))
2110
2111 (!define-type-method (cons :simple-intersection2) (type1 type2)
2112   (declare (type cons-type type1 type2))
2113   (let (car-int2
2114         cdr-int2)
2115     (and (setf car-int2 (type-intersection2 (cons-type-car-type type1)
2116                                             (cons-type-car-type type2)))
2117          (setf cdr-int2 (type-intersection2 (cons-type-cdr-type type1)
2118                                             (cons-type-cdr-type type2)))
2119          (make-cons-type car-int2 cdr-int2))))
2120 \f
2121 ;;; Return the type that describes all objects that are in X but not
2122 ;;; in Y. If we can't determine this type, then return NIL.
2123 ;;;
2124 ;;; For now, we only are clever dealing with union and member types.
2125 ;;; If either type is not a union type, then we pretend that it is a
2126 ;;; union of just one type. What we do is remove from X all the types
2127 ;;; that are a subtype any type in Y. If any type in X intersects with
2128 ;;; a type in Y but is not a subtype, then we give up.
2129 ;;;
2130 ;;; We must also special-case any member type that appears in the
2131 ;;; union. We remove from X's members all objects that are TYPEP to Y.
2132 ;;; If Y has any members, we must be careful that none of those
2133 ;;; members are CTYPEP to any of Y's non-member types. We give up in
2134 ;;; this case, since to compute that difference we would have to break
2135 ;;; the type from X into some collection of types that represents the
2136 ;;; type without that particular element. This seems too hairy to be
2137 ;;; worthwhile, given its low utility.
2138 (defun type-difference (x y)
2139   (let ((x-types (if (union-type-p x) (union-type-types x) (list x)))
2140         (y-types (if (union-type-p y) (union-type-types y) (list y))))
2141     (collect ((res))
2142       (dolist (x-type x-types)
2143         (if (member-type-p x-type)
2144             (collect ((members))
2145               (dolist (mem (member-type-members x-type))
2146                 (multiple-value-bind (val win) (ctypep mem y)
2147                   (unless win (return-from type-difference nil))
2148                   (unless val
2149                     (members mem))))
2150               (when (members)
2151                 (res (make-member-type :members (members)))))
2152             (dolist (y-type y-types (res x-type))
2153               (multiple-value-bind (val win) (csubtypep x-type y-type)
2154                 (unless win (return-from type-difference nil))
2155                 (when val (return))
2156                 (when (types-equal-or-intersect x-type y-type)
2157                   (return-from type-difference nil))))))
2158       (let ((y-mem (find-if #'member-type-p y-types)))
2159         (when y-mem
2160           (let ((members (member-type-members y-mem)))
2161             (dolist (x-type x-types)
2162               (unless (member-type-p x-type)
2163                 (dolist (member members)
2164                   (multiple-value-bind (val win) (ctypep member x-type)
2165                     (when (or (not win) val)
2166                       (return-from type-difference nil)))))))))
2167       (apply #'type-union (res)))))
2168 \f
2169 (!def-type-translator array (&optional (element-type '*)
2170                                        (dimensions '*))
2171   (specialize-array-type
2172    (make-array-type :dimensions (canonical-array-dimensions dimensions)
2173                     :element-type (specifier-type element-type))))
2174
2175 (!def-type-translator simple-array (&optional (element-type '*)
2176                                               (dimensions '*))
2177   (specialize-array-type
2178    (make-array-type :dimensions (canonical-array-dimensions dimensions)
2179                     :element-type (specifier-type element-type)
2180                     :complexp nil)))
2181 \f
2182 ;;;; utilities shared between cross-compiler and target system
2183
2184 ;;; Does the type derived from compilation of an actual function
2185 ;;; definition satisfy declarations of a function's type?
2186 (defun defined-ftype-matches-declared-ftype-p (defined-ftype declared-ftype)
2187   (declare (type ctype defined-ftype declared-ftype))
2188   (flet ((is-built-in-class-function-p (ctype)
2189            (and (built-in-class-p ctype)
2190                 (eq (built-in-class-%name ctype) 'function))))
2191     (cond (;; DECLARED-FTYPE could certainly be #<BUILT-IN-CLASS FUNCTION>;
2192            ;; that's what happens when we (DECLAIM (FTYPE FUNCTION FOO)).
2193            (is-built-in-class-function-p declared-ftype)
2194            ;; In that case, any definition satisfies the declaration.
2195            t)
2196           (;; It's not clear whether or how DEFINED-FTYPE might be
2197            ;; #<BUILT-IN-CLASS FUNCTION>, but it's not obviously
2198            ;; invalid, so let's handle that case too, just in case.
2199            (is-built-in-class-function-p defined-ftype)
2200            ;; No matter what DECLARED-FTYPE might be, we can't prove
2201            ;; that an object of type FUNCTION doesn't satisfy it, so
2202            ;; we return success no matter what.
2203            t)
2204           (;; Otherwise both of them must be FUN-TYPE objects.
2205            t
2206            ;; FIXME: For now we only check compatibility of the return
2207            ;; type, not argument types, and we don't even check the
2208            ;; return type very precisely (as per bug 94a). It would be
2209            ;; good to do a better job. Perhaps to check the
2210            ;; compatibility of the arguments, we should (1) redo
2211            ;; VALUES-TYPES-EQUAL-OR-INTERSECT as
2212            ;; ARGS-TYPES-EQUAL-OR-INTERSECT, and then (2) apply it to
2213            ;; the ARGS-TYPE slices of the FUN-TYPEs. (ARGS-TYPE
2214            ;; is a base class both of VALUES-TYPE and of FUN-TYPE.)
2215            (values-types-equal-or-intersect
2216             (fun-type-returns defined-ftype)
2217             (fun-type-returns declared-ftype))))))
2218
2219 ;;; This messy case of CTYPE for NUMBER is shared between the
2220 ;;; cross-compiler and the target system.
2221 (defun ctype-of-number (x)
2222   (let ((num (if (complexp x) (realpart x) x)))
2223     (multiple-value-bind (complexp low high)
2224         (if (complexp x)
2225             (let ((imag (imagpart x)))
2226               (values :complex (min num imag) (max num imag)))
2227             (values :real num num))
2228       (make-numeric-type :class (etypecase num
2229                                   (integer 'integer)
2230                                   (rational 'rational)
2231                                   (float 'float))
2232                          :format (and (floatp num) (float-format-name num))
2233                          :complexp complexp
2234                          :low low
2235                          :high high))))
2236 \f
2237 (locally
2238   ;; Why SAFETY 0? To suppress the is-it-the-right-structure-type
2239   ;; checking for declarations in structure accessors. Otherwise we
2240   ;; can get caught in a chicken-and-egg bootstrapping problem, whose
2241   ;; symptom on x86 OpenBSD sbcl-0.pre7.37.flaky5.22 is an illegal
2242   ;; instruction trap. I haven't tracked it down, but I'm guessing it
2243   ;; has to do with setting LAYOUTs when the LAYOUT hasn't been set
2244   ;; yet. -- WHN
2245   (declare (optimize (safety 0)))
2246   (!defun-from-collected-cold-init-forms !late-type-cold-init))
2247
2248 (/show0 "late-type.lisp end of file")