src/code/late-type.lisp

   1 ;;;; This file contains the definition of non-CLASS types (e.g.
   2 ;;;; subtypes of interesting BUILT-IN-CLASSes) and the interfaces to
   3 ;;;; the type system. Common Lisp type specifiers are parsed into a
   4 ;;;; somewhat canonical internal type representation that supports
   5 ;;;; type union, intersection, etc. (Except that ALIEN types have
   6 ;;;; moved out..)
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!KERNEL")
  18
  19 (/show0 "late-type.lisp 19")
  20
  21 (!begin-collecting-cold-init-forms)
  22
  23 ;;; ### Remaining incorrectnesses:
  24 ;;;
  25 ;;; There are all sorts of nasty problems with open bounds on FLOAT
  26 ;;; types (and probably FLOAT types in general.)
  27
  28 ;;; This condition is signalled whenever we make a UNKNOWN-TYPE so that
  29 ;;; compiler warnings can be emitted as appropriate.
  30 (define-condition parse-unknown-type (condition)
  31   ((specifier :reader parse-unknown-type-specifier :initarg :specifier)))
  32
  33 ;;; FIXME: This really should go away. Alas, it doesn't seem to be so
  34 ;;; simple to make it go away.. (See bug 123 in BUGS file.)
  35 (defvar *use-implementation-types* t ; actually initialized in cold init
  36   #!+sb-doc
  37   "*USE-IMPLEMENTATION-TYPES* is a semi-public flag which determines how
  38    restrictive we are in determining type membership. If two types are the
  39    same in the implementation, then we will consider them them the same when
  40    this switch is on. When it is off, we try to be as restrictive as the
  41    language allows, allowing us to detect more errors. Currently, this only
  42    affects array types.")
  43 (!cold-init-forms (setq *use-implementation-types* t))
  44
  45 ;;; These functions are used as method for types which need a complex
  46 ;;; subtypep method to handle some superclasses, but cover a subtree
  47 ;;; of the type graph (i.e. there is no simple way for any other type
  48 ;;; class to be a subtype.) There are always still complex ways,
  49 ;;; namely UNION and MEMBER types, so we must give TYPE1's method a
  50 ;;; chance to run, instead of immediately returning NIL, T.
  51 (defun delegate-complex-subtypep-arg2 (type1 type2)
  52   (let ((subtypep-arg1
  53          (type-class-complex-subtypep-arg1
  54           (type-class-info type1))))
  55     (if subtypep-arg1
  56         (funcall subtypep-arg1 type1 type2)
  57         (values nil t))))
  58 (defun delegate-complex-intersection2 (type1 type2)
  59   (let ((method (type-class-complex-intersection2 (type-class-info type1))))
  60     (if (and method (not (eq method #'delegate-complex-intersection2)))
  61         (funcall method type2 type1)
  62         (hierarchical-intersection2 type1 type2))))
  63
  64 ;;; This is used by !DEFINE-SUPERCLASSES to define the SUBTYPE-ARG1
  65 ;;; method. INFO is a list of conses
  66 ;;;   (SUPERCLASS-CLASS . {GUARD-TYPE-SPECIFIER | NIL}).
  67 (defun !has-superclasses-complex-subtypep-arg1 (type1 type2 info)
  68   ;; If TYPE2 might be concealing something related to our class
  69   ;; hierarchy
  70   (if (type-might-contain-other-types-p type2)
  71       ;; too confusing, gotta punt
  72       (values nil nil)
  73       ;; ordinary case expected by old CMU CL code, where the taxonomy
  74       ;; of TYPE2's representation accurately reflects the taxonomy of
  75       ;; the underlying set
  76       (values
  77        ;; FIXME: This old CMU CL code probably deserves a comment
  78        ;; explaining to us mere mortals how it works...
  79        (and (sb!xc:typep type2 'classoid)
  80             (dolist (x info nil)
  81               (when (or (not (cdr x))
  82                         (csubtypep type1 (specifier-type (cdr x))))
  83                 (return
  84                  (or (eq type2 (car x))
  85                      (let ((inherits (layout-inherits
  86                                       (classoid-layout (car x)))))
  87                        (dotimes (i (length inherits) nil)
  88                          (when (eq type2 (layout-classoid (svref inherits i)))
  89                            (return t)))))))))
  90        t)))
  91
  92 ;;; This function takes a list of specs, each of the form
  93 ;;;    (SUPERCLASS-NAME &OPTIONAL GUARD).
  94 ;;; Consider one spec (with no guard): any instance of the named
  95 ;;; TYPE-CLASS is also a subtype of the named superclass and of any of
  96 ;;; its superclasses. If there are multiple specs, then some will have
  97 ;;; guards. We choose the first spec whose guard is a supertype of
  98 ;;; TYPE1 and use its superclass. In effect, a sequence of guards
  99 ;;;    G0, G1, G2
 100 ;;; is actually
 101 ;;;    G0,(and G1 (not G0)), (and G2 (not (or G0 G1))).
 102 ;;;
 103 ;;; WHEN controls when the forms are executed.
 104 (defmacro !define-superclasses (type-class-name specs when)
 105   (with-unique-names (type-class info)
 106     `(,when
 107        (let ((,type-class (type-class-or-lose ',type-class-name))
 108              (,info (mapcar (lambda (spec)
 109                               (destructuring-bind
 110                                   (super &optional guard)
 111                                   spec
 112                                 (cons (find-classoid super) guard)))
 113                             ',specs)))
 114          (setf (type-class-complex-subtypep-arg1 ,type-class)
 115                (lambda (type1 type2)
 116                  (!has-superclasses-complex-subtypep-arg1 type1 type2 ,info)))
 117          (setf (type-class-complex-subtypep-arg2 ,type-class)
 118                #'delegate-complex-subtypep-arg2)
 119          (setf (type-class-complex-intersection2 ,type-class)
 120                #'delegate-complex-intersection2)))))
 121 \f
 122 ;;;; FUNCTION and VALUES types
 123 ;;;;
 124 ;;;; Pretty much all of the general type operations are illegal on
 125 ;;;; VALUES types, since we can't discriminate using them, do
 126 ;;;; SUBTYPEP, etc. FUNCTION types are acceptable to the normal type
 127 ;;;; operations, but are generally considered to be equivalent to
 128 ;;;; FUNCTION. These really aren't true types in any type theoretic
 129 ;;;; sense, but we still parse them into CTYPE structures for two
 130 ;;;; reasons:
 131
 132 ;;;; -- Parsing and unparsing work the same way, and indeed we can't
 133 ;;;;    tell whether a type is a function or values type without
 134 ;;;;    parsing it.
 135 ;;;; -- Many of the places that can be annotated with real types can
 136 ;;;;    also be annotated with function or values types.
 137
 138 ;;; the description of a &KEY argument
 139 (defstruct (key-info #-sb-xc-host (:pure t)
 140                      (:copier nil))
 141   ;; the key (not necessarily a keyword in ANSI Common Lisp)
 142   (name (missing-arg) :type symbol)
 143   ;; the type of the argument value
 144   (type (missing-arg) :type ctype))
 145
 146 (!define-type-method (values :simple-subtypep :complex-subtypep-arg1)
 147                      (type1 type2)
 148   (declare (ignore type2))
 149   ;; FIXME: should be TYPE-ERROR, here and in next method
 150   (error "SUBTYPEP is illegal on this type:~%  ~S" (type-specifier type1)))
 151
 152 (!define-type-method (values :complex-subtypep-arg2)
 153                      (type1 type2)
 154   (declare (ignore type1))
 155   (error "SUBTYPEP is illegal on this type:~%  ~S" (type-specifier type2)))
 156
 157 (!define-type-method (values :negate) (type)
 158   (error "NOT VALUES too confusing on ~S" (type-specifier type)))
 159
 160 (!define-type-method (values :unparse) (type)
 161   (cons 'values
 162         (let ((unparsed (unparse-args-types type)))
 163           (if (or (values-type-optional type)
 164                   (values-type-rest type)
 165                   (values-type-allowp type))
 166               unparsed
 167               (nconc unparsed '(&optional))))))
 168
 169 ;;; Return true if LIST1 and LIST2 have the same elements in the same
 170 ;;; positions according to TYPE=. We return NIL, NIL if there is an
 171 ;;; uncertain comparison.
 172 (defun type=-list (list1 list2)
 173   (declare (list list1 list2))
 174   (do ((types1 list1 (cdr types1))
 175        (types2 list2 (cdr types2)))
 176       ((or (null types1) (null types2))
 177        (if (or types1 types2)
 178            (values nil t)
 179            (values t t)))
 180     (multiple-value-bind (val win)
 181         (type= (first types1) (first types2))
 182       (unless win
 183         (return (values nil nil)))
 184       (unless val
 185         (return (values nil t))))))
 186
 187 (!define-type-method (values :simple-=) (type1 type2)
 188   (type=-args type1 type2))
 189
 190 (!define-type-class function)
 191
 192 ;;; a flag that we can bind to cause complex function types to be
 193 ;;; unparsed as FUNCTION. This is useful when we want a type that we
 194 ;;; can pass to TYPEP.
 195 (defvar *unparse-fun-type-simplify*)
 196 (!cold-init-forms (setq *unparse-fun-type-simplify* nil))
 197
 198 (!define-type-method (function :negate) (type)
 199   (error "NOT FUNCTION too confusing on ~S" (type-specifier type)))
 200
 201 (!define-type-method (function :unparse) (type)
 202   (if *unparse-fun-type-simplify*
 203       'function
 204       (list 'function
 205             (if (fun-type-wild-args type)
 206                 '*
 207                 (unparse-args-types type))
 208             (type-specifier
 209              (fun-type-returns type)))))
 210
 211 ;;; The meaning of this is a little confused. On the one hand, all
 212 ;;; function objects are represented the same way regardless of the
 213 ;;; arglists and return values, and apps don't get to ask things like
 214 ;;; (TYPEP #'FOO (FUNCTION (FIXNUM) *)) in any meaningful way. On the
 215 ;;; other hand, Python wants to reason about function types. So...
 216 (!define-type-method (function :simple-subtypep) (type1 type2)
 217  (flet ((fun-type-simple-p (type)
 218           (not (or (fun-type-rest type)
 219                    (fun-type-keyp type))))
 220         (every-csubtypep (types1 types2)
 221           (loop
 222              for a1 in types1
 223              for a2 in types2
 224              do (multiple-value-bind (res sure-p)
 225                     (csubtypep a1 a2)
 226                   (unless res (return (values res sure-p))))
 227              finally (return (values t t)))))
 228    (and/type (values-subtypep (fun-type-returns type1)
 229                               (fun-type-returns type2))
 230              (cond ((fun-type-wild-args type2) (values t t))
 231                    ((fun-type-wild-args type1)
 232                     (cond ((fun-type-keyp type2) (values nil nil))
 233                           ((not (fun-type-rest type2)) (values nil t))
 234                           ((not (null (fun-type-required type2)))
 235                            (values nil t))
 236                           (t (and/type (type= *universal-type*
 237                                               (fun-type-rest type2))
 238                                        (every/type #'type=
 239                                                    *universal-type*
 240                                                    (fun-type-optional
 241                                                     type2))))))
 242                    ((not (and (fun-type-simple-p type1)
 243                               (fun-type-simple-p type2)))
 244                     (values nil nil))
 245                    (t (multiple-value-bind (min1 max1) (fun-type-nargs type1)
 246                         (multiple-value-bind (min2 max2) (fun-type-nargs type2)
 247                           (cond ((or (> max1 max2) (< min1 min2))
 248                                  (values nil t))
 249                                 ((and (= min1 min2) (= max1 max2))
 250                                  (and/type (every-csubtypep
 251                                             (fun-type-required type1)
 252                                             (fun-type-required type2))
 253                                            (every-csubtypep
 254                                             (fun-type-optional type1)
 255                                             (fun-type-optional type2))))
 256                                 (t (every-csubtypep
 257                                     (concatenate 'list
 258                                                  (fun-type-required type1)
 259                                                  (fun-type-optional type1))
 260                                     (concatenate 'list
 261                                                  (fun-type-required type2)
 262                                                  (fun-type-optional type2))))))))))))
 263
 264 (!define-superclasses function ((function)) !cold-init-forms)
 265
 266 ;;; The union or intersection of two FUNCTION types is FUNCTION.
 267 (!define-type-method (function :simple-union2) (type1 type2)
 268   (declare (ignore type1 type2))
 269   (specifier-type 'function))
 270 (!define-type-method (function :simple-intersection2) (type1 type2)
 271   (let ((ftype (specifier-type 'function)))
 272     (cond ((eq type1 ftype) type2)
 273           ((eq type2 ftype) type1)
 274           (t (let ((rtype (values-type-intersection (fun-type-returns type1)
 275                                                     (fun-type-returns type2))))
 276                (flet ((change-returns (ftype rtype)
 277                         (declare (type fun-type ftype) (type ctype rtype))
 278                         (make-fun-type :required (fun-type-required ftype)
 279                                        :optional (fun-type-optional ftype)
 280                                        :keyp (fun-type-keyp ftype)
 281                                        :keywords (fun-type-keywords ftype)
 282                                        :allowp (fun-type-allowp ftype)
 283                                        :returns rtype)))
 284                (cond
 285                  ((fun-type-wild-args type1)
 286                   (if (fun-type-wild-args type2)
 287                       (make-fun-type :wild-args t
 288                                      :returns rtype)
 289                       (change-returns type2 rtype)))
 290                  ((fun-type-wild-args type2)
 291                   (change-returns type1 rtype))
 292                  (t (multiple-value-bind (req opt rest)
 293                         (args-type-op type1 type2 #'type-intersection #'max)
 294                       (make-fun-type :required req
 295                                      :optional opt
 296                                      :rest rest
 297                                      ;; FIXME: :keys
 298                                      :allowp (and (fun-type-allowp type1)
 299                                                   (fun-type-allowp type2))
 300                                      :returns rtype))))))))))
 301
 302 ;;; The union or intersection of a subclass of FUNCTION with a
 303 ;;; FUNCTION type is somewhat complicated.
 304 (!define-type-method (function :complex-intersection2) (type1 type2)
 305   (cond
 306     ((type= type1 (specifier-type 'function)) type2)
 307     ((csubtypep type1 (specifier-type 'function)) nil)
 308     (t :call-other-method)))
 309 (!define-type-method (function :complex-union2) (type1 type2)
 310   (declare (ignore type2))
 311   ;; TYPE2 is a FUNCTION type.  If TYPE1 is a classoid type naming
 312   ;; FUNCTION, then it is the union of the two; otherwise, there is no
 313   ;; special union.
 314   (cond
 315     ((type= type1 (specifier-type 'function)) type1)
 316     (t nil)))
 317
 318 (!define-type-method (function :simple-=) (type1 type2)
 319   (macrolet ((compare (comparator field)
 320                (let ((reader (symbolicate '#:fun-type- field)))
 321                  `(,comparator (,reader type1) (,reader type2)))))
 322     (and/type (compare type= returns)
 323               (cond ((neq (fun-type-wild-args type1) (fun-type-wild-args type2))
 324                      (values nil t))
 325                     ((eq (fun-type-wild-args type1) t)
 326                      (values t t))
 327                     (t (type=-args type1 type2))))))
 328
 329 (!define-type-class constant :inherits values)
 330
 331 (!define-type-method (constant :negate) (type)
 332   (error "NOT CONSTANT too confusing on ~S" (type-specifier type)))
 333
 334 (!define-type-method (constant :unparse) (type)
 335   `(constant-arg ,(type-specifier (constant-type-type type))))
 336
 337 (!define-type-method (constant :simple-=) (type1 type2)
 338   (type= (constant-type-type type1) (constant-type-type type2)))
 339
 340 (!def-type-translator constant-arg (type)
 341   (make-constant-type :type (single-value-specifier-type type)))
 342
 343 ;;; Return the lambda-list-like type specification corresponding
 344 ;;; to an ARGS-TYPE.
 345 (declaim (ftype (function (args-type) list) unparse-args-types))
 346 (defun unparse-args-types (type)
 347   (collect ((result))
 348
 349     (dolist (arg (args-type-required type))
 350       (result (type-specifier arg)))
 351
 352     (when (args-type-optional type)
 353       (result '&optional)
 354       (dolist (arg (args-type-optional type))
 355         (result (type-specifier arg))))
 356
 357     (when (args-type-rest type)
 358       (result '&rest)
 359       (result (type-specifier (args-type-rest type))))
 360
 361     (when (args-type-keyp type)
 362       (result '&key)
 363       (dolist (key (args-type-keywords type))
 364         (result (list (key-info-name key)
 365                       (type-specifier (key-info-type key))))))
 366
 367     (when (args-type-allowp type)
 368       (result '&allow-other-keys))
 369
 370     (result)))
 371
 372 (!def-type-translator function (&optional (args '*) (result '*))
 373   (make-fun-type :args args
 374                  :returns (coerce-to-values (values-specifier-type result))))
 375
 376 (!def-type-translator values (&rest values)
 377   (make-values-type :args values))
 378 \f
 379 ;;;; VALUES types interfaces
 380 ;;;;
 381 ;;;; We provide a few special operations that can be meaningfully used
 382 ;;;; on VALUES types (as well as on any other type).
 383
 384 (defun type-single-value-p (type)
 385   (and (values-type-p type)
 386        (not (values-type-rest type))
 387        (null (values-type-optional type))
 388        (singleton-p (values-type-required type))))
 389
 390 ;;; Return the type of the first value indicated by TYPE. This is used
 391 ;;; by people who don't want to have to deal with VALUES types.
 392 #!-sb-fluid (declaim (freeze-type values-type))
 393 ; (inline single-value-type))
 394 (defun single-value-type (type)
 395   (declare (type ctype type))
 396   (cond ((eq type *wild-type*)
 397          *universal-type*)
 398         ((eq type *empty-type*)
 399          *empty-type*)
 400         ((not (values-type-p type))
 401          type)
 402         (t (or (car (args-type-required type))
 403                (car (args-type-optional type))
 404                (args-type-rest type)
 405                (specifier-type 'null)))))
 406
 407 ;;; Return the minimum number of arguments that a function can be
 408 ;;; called with, and the maximum number or NIL. If not a function
 409 ;;; type, return NIL, NIL.
 410 (defun fun-type-nargs (type)
 411   (declare (type ctype type))
 412   (if (and (fun-type-p type) (not (fun-type-wild-args type)))
 413       (let ((fixed (length (args-type-required type))))
 414         (if (or (args-type-rest type)
 415                 (args-type-keyp type)
 416                 (args-type-allowp type))
 417             (values fixed nil)
 418             (values fixed (+ fixed (length (args-type-optional type))))))
 419       (values nil nil)))
 420
 421 ;;; Determine whether TYPE corresponds to a definite number of values.
 422 ;;; The first value is a list of the types for each value, and the
 423 ;;; second value is the number of values. If the number of values is
 424 ;;; not fixed, then return NIL and :UNKNOWN.
 425 (defun values-types (type)
 426   (declare (type ctype type))
 427   (cond ((or (eq type *wild-type*) (eq type *empty-type*))
 428          (values nil :unknown))
 429         ((or (args-type-optional type)
 430              (args-type-rest type))
 431          (values nil :unknown))
 432         (t
 433          (let ((req (args-type-required type)))
 434            (values req (length req))))))
 435
 436 ;;; Return two values:
 437 ;;; 1. A list of all the positional (fixed and optional) types.
 438 ;;; 2. The &REST type (if any). If no &REST, then the DEFAULT-TYPE.
 439 (defun values-type-types (type &optional (default-type *empty-type*))
 440   (declare (type ctype type))
 441   (if (eq type *wild-type*)
 442       (values nil *universal-type*)
 443       (values (append (args-type-required type)
 444                       (args-type-optional type))
 445               (cond ((args-type-rest type))
 446                     (t default-type)))))
 447
 448 ;;; types of values in (the <type> (values o_1 ... o_n))
 449 (defun values-type-out (type count)
 450   (declare (type ctype type) (type unsigned-byte count))
 451   (if (eq type *wild-type*)
 452       (make-list count :initial-element *universal-type*)
 453       (collect ((res))
 454         (flet ((process-types (types)
 455                  (loop for type in types
 456                        while (plusp count)
 457                        do (decf count)
 458                        do (res type))))
 459           (process-types (values-type-required type))
 460           (process-types (values-type-optional type))
 461           (when (plusp count)
 462             (loop with rest = (the ctype (values-type-rest type))
 463                   repeat count
 464                   do (res rest))))
 465         (res))))
 466
 467 ;;; types of variable in (m-v-bind (v_1 ... v_n) (the <type> ...
 468 (defun values-type-in (type count)
 469   (declare (type ctype type) (type unsigned-byte count))
 470   (if (eq type *wild-type*)
 471       (make-list count :initial-element *universal-type*)
 472       (collect ((res))
 473         (let ((null-type (specifier-type 'null)))
 474           (loop for type in (values-type-required type)
 475              while (plusp count)
 476              do (decf count)
 477              do (res type))
 478           (loop for type in (values-type-optional type)
 479              while (plusp count)
 480              do (decf count)
 481              do (res (type-union type null-type)))
 482           (when (plusp count)
 483             (loop with rest = (acond ((values-type-rest type)
 484                                       (type-union it null-type))
 485                                      (t null-type))
 486                repeat count
 487                do (res rest))))
 488         (res))))
 489
 490 ;;; Return a list of OPERATION applied to the types in TYPES1 and
 491 ;;; TYPES2, padding with REST2 as needed. TYPES1 must not be shorter
 492 ;;; than TYPES2. The second value is T if OPERATION always returned a
 493 ;;; true second value.
 494 (defun fixed-values-op (types1 types2 rest2 operation)
 495   (declare (list types1 types2) (type ctype rest2) (type function operation))
 496   (let ((exact t))
 497     (values (mapcar (lambda (t1 t2)
 498                       (multiple-value-bind (res win)
 499                           (funcall operation t1 t2)
 500                         (unless win
 501                           (setq exact nil))
 502                         res))
 503                     types1
 504                     (append types2
 505                             (make-list (- (length types1) (length types2))
 506                                        :initial-element rest2)))
 507             exact)))
 508
 509 ;;; If TYPE isn't a values type, then make it into one.
 510 (defun-cached (%coerce-to-values
 511                :hash-bits 8
 512                :hash-function (lambda (type)
 513                                 (logand (type-hash-value type)
 514                                         #xff)))
 515     ((type eq))
 516   (cond ((multiple-value-bind (res sure)
 517              (csubtypep (specifier-type 'null) type)
 518            (and (not res) sure))
 519          ;; FIXME: What should we do with (NOT SURE)?
 520          (make-values-type :required (list type) :rest *universal-type*))
 521         (t
 522          (make-values-type :optional (list type) :rest *universal-type*))))
 523
 524 (defun coerce-to-values (type)
 525   (declare (type ctype type))
 526   (cond ((or (eq type *universal-type*)
 527              (eq type *wild-type*))
 528          *wild-type*)
 529         ((values-type-p type)
 530          type)
 531         (t (%coerce-to-values type))))
 532
 533 ;;; Return type, corresponding to ANSI short form of VALUES type
 534 ;;; specifier.
 535 (defun make-short-values-type (types)
 536   (declare (list types))
 537   (let ((last-required (position-if
 538                         (lambda (type)
 539                           (not/type (csubtypep (specifier-type 'null) type)))
 540                         types
 541                         :from-end t)))
 542     (if last-required
 543         (make-values-type :required (subseq types 0 (1+ last-required))
 544                           :optional (subseq types (1+ last-required))
 545                           :rest *universal-type*)
 546         (make-values-type :optional types :rest *universal-type*))))
 547
 548 (defun make-single-value-type (type)
 549   (make-values-type :required (list type)))
 550
 551 ;;; Do the specified OPERATION on TYPE1 and TYPE2, which may be any
 552 ;;; type, including VALUES types. With VALUES types such as:
 553 ;;;    (VALUES a0 a1)
 554 ;;;    (VALUES b0 b1)
 555 ;;; we compute the more useful result
 556 ;;;    (VALUES (<operation> a0 b0) (<operation> a1 b1))
 557 ;;; rather than the precise result
 558 ;;;    (<operation> (values a0 a1) (values b0 b1))
 559 ;;; This has the virtue of always keeping the VALUES type specifier
 560 ;;; outermost, and retains all of the information that is really
 561 ;;; useful for static type analysis. We want to know what is always
 562 ;;; true of each value independently. It is worthless to know that if
 563 ;;; the first value is B0 then the second will be B1.
 564 ;;;
 565 ;;; If the VALUES count signatures differ, then we produce a result with
 566 ;;; the required VALUE count chosen by NREQ when applied to the number
 567 ;;; of required values in TYPE1 and TYPE2. Any &KEY values become
 568 ;;; &REST T (anyone who uses keyword values deserves to lose.)
 569 ;;;
 570 ;;; The second value is true if the result is definitely empty or if
 571 ;;; OPERATION returned true as its second value each time we called
 572 ;;; it. Since we approximate the intersection of VALUES types, the
 573 ;;; second value being true doesn't mean the result is exact.
 574 (defun args-type-op (type1 type2 operation nreq)
 575   (declare (type ctype type1 type2)
 576            (type function operation nreq))
 577   (when (eq type1 type2)
 578     (values type1 t))
 579   (multiple-value-bind (types1 rest1)
 580       (values-type-types type1)
 581     (multiple-value-bind (types2 rest2)
 582         (values-type-types type2)
 583       (multiple-value-bind (rest rest-exact)
 584           (funcall operation rest1 rest2)
 585         (multiple-value-bind (res res-exact)
 586             (if (< (length types1) (length types2))
 587                 (fixed-values-op types2 types1 rest1 operation)
 588                 (fixed-values-op types1 types2 rest2 operation))
 589           (let* ((req (funcall nreq
 590                                (length (args-type-required type1))
 591                                (length (args-type-required type2))))
 592                  (required (subseq res 0 req))
 593                  (opt (subseq res req)))
 594             (values required opt rest
 595                     (and rest-exact res-exact))))))))
 596
 597 (defun values-type-op (type1 type2 operation nreq)
 598   (multiple-value-bind (required optional rest exactp)
 599       (args-type-op type1 type2 operation nreq)
 600     (values (make-values-type :required required
 601                               :optional optional
 602                               :rest rest)
 603             exactp)))
 604
 605 (defun type=-args (type1 type2)
 606   (macrolet ((compare (comparator field)
 607                (let ((reader (symbolicate '#:args-type- field)))
 608                  `(,comparator (,reader type1) (,reader type2)))))
 609     (and/type
 610      (cond ((null (args-type-rest type1))
 611             (values (null (args-type-rest type2)) t))
 612            ((null (args-type-rest type2))
 613             (values nil t))
 614            (t
 615             (compare type= rest)))
 616      (and/type (and/type (compare type=-list required)
 617                          (compare type=-list optional))
 618                (if (or (args-type-keyp type1) (args-type-keyp type2))
 619                    (values nil nil)
 620                    (values t t))))))
 621
 622 ;;; Do a union or intersection operation on types that might be values
 623 ;;; types. The result is optimized for utility rather than exactness,
 624 ;;; but it is guaranteed that it will be no smaller (more restrictive)
 625 ;;; than the precise result.
 626 ;;;
 627 ;;; The return convention seems to be analogous to
 628 ;;; TYPES-EQUAL-OR-INTERSECT. -- WHN 19990910.
 629 (defun-cached (values-type-union :hash-function type-cache-hash
 630                                  :hash-bits 8
 631                                  :default nil
 632                                  :init-wrapper !cold-init-forms)
 633     ((type1 eq) (type2 eq))
 634   (declare (type ctype type1 type2))
 635   (cond ((or (eq type1 *wild-type*) (eq type2 *wild-type*)) *wild-type*)
 636         ((eq type1 *empty-type*) type2)
 637         ((eq type2 *empty-type*) type1)
 638         (t
 639          (values (values-type-op type1 type2 #'type-union #'min)))))
 640
 641 (defun-cached (values-type-intersection :hash-function type-cache-hash
 642                                         :hash-bits 8
 643                                         :default (values nil)
 644                                         :init-wrapper !cold-init-forms)
 645     ((type1 eq) (type2 eq))
 646   (declare (type ctype type1 type2))
 647   (cond ((eq type1 *wild-type*)
 648          (coerce-to-values type2))
 649         ((or (eq type2 *wild-type*) (eq type2 *universal-type*))
 650          type1)
 651         ((or (eq type1 *empty-type*) (eq type2 *empty-type*))
 652          *empty-type*)
 653         ((and (not (values-type-p type2))
 654               (values-type-required type1))
 655          (let ((req1 (values-type-required type1)))
 656            (make-values-type :required (cons (type-intersection (first req1) type2)
 657                                              (rest req1))
 658                              :optional (values-type-optional type1)
 659                              :rest (values-type-rest type1)
 660                              :allowp (values-type-allowp type1))))
 661         (t
 662          (values (values-type-op type1 (coerce-to-values type2)
 663                                  #'type-intersection
 664                                  #'max)))))
 665
 666 ;;; This is like TYPES-EQUAL-OR-INTERSECT, except that it sort of
 667 ;;; works on VALUES types. Note that due to the semantics of
 668 ;;; VALUES-TYPE-INTERSECTION, this might return (VALUES T T) when
 669 ;;; there isn't really any intersection.
 670 (defun values-types-equal-or-intersect (type1 type2)
 671   (cond ((or (eq type1 *empty-type*) (eq type2 *empty-type*))
 672          (values t t))
 673         ((or (eq type1 *wild-type*) (eq type2 *wild-type*))
 674          (values t t))
 675         (t
 676          (let ((res (values-type-intersection type1 type2)))
 677            (values (not (eq res *empty-type*))
 678                    t)))))
 679
 680 ;;; a SUBTYPEP-like operation that can be used on any types, including
 681 ;;; VALUES types
 682 (defun-cached (values-subtypep :hash-function type-cache-hash
 683                                :hash-bits 8
 684                                :values 2
 685                                :default (values nil :empty)
 686                                :init-wrapper !cold-init-forms)
 687     ((type1 eq) (type2 eq))
 688   (declare (type ctype type1 type2))
 689   (cond ((or (eq type2 *wild-type*) (eq type2 *universal-type*)
 690              (eq type1 *empty-type*))
 691          (values t t))
 692         ((eq type1 *wild-type*)
 693          (values (eq type2 *wild-type*) t))
 694         ((or (eq type2 *empty-type*)
 695              (not (values-types-equal-or-intersect type1 type2)))
 696          (values nil t))
 697         ((and (not (values-type-p type2))
 698               (values-type-required type1))
 699          (csubtypep (first (values-type-required type1))
 700                     type2))
 701         (t (setq type2 (coerce-to-values type2))
 702            (multiple-value-bind (types1 rest1) (values-type-types type1)
 703              (multiple-value-bind (types2 rest2) (values-type-types type2)
 704                (cond ((< (length (values-type-required type1))
 705                          (length (values-type-required type2)))
 706                       (values nil t))
 707                      ((< (length types1) (length types2))
 708                       (values nil nil))
 709                      (t
 710                       (do ((t1 types1 (rest t1))
 711                            (t2 types2 (rest t2)))
 712                           ((null t2)
 713                            (csubtypep rest1 rest2))
 714                         (multiple-value-bind (res win-p)
 715                             (csubtypep (first t1) (first t2))
 716                           (unless win-p
 717                             (return (values nil nil)))
 718                           (unless res
 719                             (return (values nil t))))))))))))
 720 \f
 721 ;;;; type method interfaces
 722
 723 ;;; like SUBTYPEP, only works on CTYPE structures
 724 (defun-cached (csubtypep :hash-function type-cache-hash
 725                          :hash-bits 8
 726                          :values 2
 727                          :default (values nil :empty)
 728                          :init-wrapper !cold-init-forms)
 729               ((type1 eq) (type2 eq))
 730   (declare (type ctype type1 type2))
 731   (cond ((or (eq type1 type2)
 732              (eq type1 *empty-type*)
 733              (eq type2 *universal-type*))
 734          (values t t))
 735         #+nil
 736         ((eq type1 *universal-type*)
 737          (values nil t))
 738         (t
 739          (!invoke-type-method :simple-subtypep :complex-subtypep-arg2
 740                               type1 type2
 741                               :complex-arg1 :complex-subtypep-arg1))))
 742
 743 ;;; Just parse the type specifiers and call CSUBTYPE.
 744 (defun sb!xc:subtypep (type1 type2 &optional environment)
 745   #!+sb-doc
 746   "Return two values indicating the relationship between type1 and type2.
 747   If values are T and T, type1 definitely is a subtype of type2.
 748   If values are NIL and T, type1 definitely is not a subtype of type2.
 749   If values are NIL and NIL, it couldn't be determined."
 750   (declare (ignore environment))
 751   (csubtypep (specifier-type type1) (specifier-type type2)))
 752
 753 ;;; If two types are definitely equivalent, return true. The second
 754 ;;; value indicates whether the first value is definitely correct.
 755 ;;; This should only fail in the presence of HAIRY types.
 756 (defun-cached (type= :hash-function type-cache-hash
 757                      :hash-bits 8
 758                      :values 2
 759                      :default (values nil :empty)
 760                      :init-wrapper !cold-init-forms)
 761               ((type1 eq) (type2 eq))
 762   (declare (type ctype type1 type2))
 763   (if (eq type1 type2)
 764       (values t t)
 765       (!invoke-type-method :simple-= :complex-= type1 type2)))
 766
 767 ;;; Not exactly the negation of TYPE=, since when the relationship is
 768 ;;; uncertain, we still return NIL, NIL. This is useful in cases where
 769 ;;; the conservative assumption is =.
 770 (defun type/= (type1 type2)
 771   (declare (type ctype type1 type2))
 772   (multiple-value-bind (res win) (type= type1 type2)
 773     (if win
 774         (values (not res) t)
 775         (values nil nil))))
 776
 777 ;;; the type method dispatch case of TYPE-UNION2
 778 (defun %type-union2 (type1 type2)
 779   ;; As in %TYPE-INTERSECTION2, it seems to be a good idea to give
 780   ;; both argument orders a chance at COMPLEX-INTERSECTION2. Unlike
 781   ;; %TYPE-INTERSECTION2, though, I don't have a specific case which
 782   ;; demonstrates this is actually necessary. Also unlike
 783   ;; %TYPE-INTERSECTION2, there seems to be no need to distinguish
 784   ;; between not finding a method and having a method return NIL.
 785   (flet ((1way (x y)
 786            (!invoke-type-method :simple-union2 :complex-union2
 787                                 x y
 788                                 :default nil)))
 789     (declare (inline 1way))
 790     (or (1way type1 type2)
 791         (1way type2 type1))))
 792
 793 ;;; Find a type which includes both types. Any inexactness is
 794 ;;; represented by the fuzzy element types; we return a single value
 795 ;;; that is precise to the best of our knowledge. This result is
 796 ;;; simplified into the canonical form, thus is not a UNION-TYPE
 797 ;;; unless we find no other way to represent the result.
 798 (defun-cached (type-union2 :hash-function type-cache-hash
 799                            :hash-bits 8
 800                            :init-wrapper !cold-init-forms)
 801               ((type1 eq) (type2 eq))
 802   ;; KLUDGE: This was generated from TYPE-INTERSECTION2 by Ye Olde Cut And
 803   ;; Paste technique of programming. If it stays around (as opposed to
 804   ;; e.g. fading away in favor of some CLOS solution) the shared logic
 805   ;; should probably become shared code. -- WHN 2001-03-16
 806   (declare (type ctype type1 type2))
 807   (cond ((eq type1 type2)
 808          type1)
 809         ((csubtypep type1 type2) type2)
 810         ((csubtypep type2 type1) type1)
 811         ((or (union-type-p type1)
 812              (union-type-p type2))
 813          ;; Unions of UNION-TYPE should have the UNION-TYPE-TYPES
 814          ;; values broken out and united separately. The full TYPE-UNION
 815          ;; function knows how to do this, so let it handle it.
 816          (type-union type1 type2))
 817         (t
 818          ;; the ordinary case: we dispatch to type methods
 819          (%type-union2 type1 type2))))
 820
 821 ;;; the type method dispatch case of TYPE-INTERSECTION2
 822 (defun %type-intersection2 (type1 type2)
 823   ;; We want to give both argument orders a chance at
 824   ;; COMPLEX-INTERSECTION2. Without that, the old CMU CL type
 825   ;; methods could give noncommutative results, e.g.
 826   ;;   (TYPE-INTERSECTION2 *EMPTY-TYPE* SOME-HAIRY-TYPE)
 827   ;;     => NIL, NIL
 828   ;;   (TYPE-INTERSECTION2 SOME-HAIRY-TYPE *EMPTY-TYPE*)
 829   ;;     => #<NAMED-TYPE NIL>, T
 830   ;; We also need to distinguish between the case where we found a
 831   ;; type method, and it returned NIL, and the case where we fell
 832   ;; through without finding any type method. An example of the first
 833   ;; case is the intersection of a HAIRY-TYPE with some ordinary type.
 834   ;; An example of the second case is the intersection of two
 835   ;; completely-unrelated types, e.g. CONS and NUMBER, or SYMBOL and
 836   ;; ARRAY.
 837   ;;
 838   ;; (Why yes, CLOS probably *would* be nicer..)
 839   (flet ((1way (x y)
 840            (!invoke-type-method :simple-intersection2 :complex-intersection2
 841                                 x y
 842                                 :default :call-other-method)))
 843     (declare (inline 1way))
 844     (let ((xy (1way type1 type2)))
 845       (or (and (not (eql xy :call-other-method)) xy)
 846           (let ((yx (1way type2 type1)))
 847             (or (and (not (eql yx :call-other-method)) yx)
 848                 (cond ((and (eql xy :call-other-method)
 849                             (eql yx :call-other-method))
 850                        *empty-type*)
 851                       (t
 852                        (aver (and (not xy) (not yx))) ; else handled above
 853                        nil))))))))
 854
 855 (defun-cached (type-intersection2 :hash-function type-cache-hash
 856                                   :hash-bits 8
 857                                   :values 1
 858                                   :default nil
 859                                   :init-wrapper !cold-init-forms)
 860               ((type1 eq) (type2 eq))
 861   (declare (type ctype type1 type2))
 862   (cond ((eq type1 type2)
 863          ;; FIXME: For some reason, this doesn't catch e.g. type1 =
 864          ;; type2 = (SPECIFIER-TYPE
 865          ;; 'SOME-UNKNOWN-TYPE). Investigate. - CSR, 2002-04-10
 866          type1)
 867         ((or (intersection-type-p type1)
 868              (intersection-type-p type2))
 869          ;; Intersections of INTERSECTION-TYPE should have the
 870          ;; INTERSECTION-TYPE-TYPES values broken out and intersected
 871          ;; separately. The full TYPE-INTERSECTION function knows how
 872          ;; to do that, so let it handle it.
 873          (type-intersection type1 type2))
 874         (t
 875          ;; the ordinary case: we dispatch to type methods
 876          (%type-intersection2 type1 type2))))
 877
 878 ;;; Return as restrictive and simple a type as we can discover that is
 879 ;;; no more restrictive than the intersection of TYPE1 and TYPE2. At
 880 ;;; worst, we arbitrarily return one of the arguments as the first
 881 ;;; value (trying not to return a hairy type).
 882 (defun type-approx-intersection2 (type1 type2)
 883   (cond ((type-intersection2 type1 type2))
 884         ((hairy-type-p type1) type2)
 885         (t type1)))
 886
 887 ;;; a test useful for checking whether a derived type matches a
 888 ;;; declared type
 889 ;;;
 890 ;;; The first value is true unless the types don't intersect and
 891 ;;; aren't equal. The second value is true if the first value is
 892 ;;; definitely correct. NIL is considered to intersect with any type.
 893 ;;; If T is a subtype of either type, then we also return T, T. This
 894 ;;; way we recognize that hairy types might intersect with T.
 895 (defun types-equal-or-intersect (type1 type2)
 896   (declare (type ctype type1 type2))
 897   (if (or (eq type1 *empty-type*) (eq type2 *empty-type*))
 898       (values t t)
 899       (let ((intersection2 (type-intersection2 type1 type2)))
 900         (cond ((not intersection2)
 901                (if (or (csubtypep *universal-type* type1)
 902                        (csubtypep *universal-type* type2))
 903                    (values t t)
 904                    (values t nil)))
 905               ((eq intersection2 *empty-type*) (values nil t))
 906               (t (values t t))))))
 907
 908 ;;; Return a Common Lisp type specifier corresponding to the TYPE
 909 ;;; object.
 910 (defun type-specifier (type)
 911   (declare (type ctype type))
 912   (funcall (type-class-unparse (type-class-info type)) type))
 913
 914 (defun-cached (type-negation :hash-function (lambda (type)
 915                                               (logand (type-hash-value type)
 916                                                       #xff))
 917                              :hash-bits 8
 918                              :values 1
 919                              :default nil
 920                              :init-wrapper !cold-init-forms)
 921               ((type eq))
 922   (declare (type ctype type))
 923   (funcall (type-class-negate (type-class-info type)) type))
 924
 925 ;;; (VALUES-SPECIFIER-TYPE and SPECIFIER-TYPE moved from here to
 926 ;;; early-type.lisp by WHN ca. 19990201.)
 927
 928 ;;; Take a list of type specifiers, computing the translation of each
 929 ;;; specifier and defining it as a builtin type.
 930 (declaim (ftype (function (list) (values)) precompute-types))
 931 (defun precompute-types (specs)
 932   (dolist (spec specs)
 933     (let ((res (specifier-type spec)))
 934       (unless (unknown-type-p res)
 935         (setf (info :type :builtin spec) res)
 936         ;; KLUDGE: the three copies of this idiom in this file (and
 937         ;; the one in class.lisp as at sbcl-0.7.4.1x) should be
 938         ;; coalesced, or perhaps the error-detecting code that
 939         ;; disallows redefinition of :PRIMITIVE types should be
 940         ;; rewritten to use *TYPE-SYSTEM-FINALIZED* (rather than
 941         ;; *TYPE-SYSTEM-INITIALIZED*). The effect of this is not to
 942         ;; cause redefinition errors when precompute-types is called
 943         ;; for a second time while building the target compiler using
 944         ;; the cross-compiler. -- CSR, trying to explain why this
 945         ;; isn't completely wrong, 2002-06-07
 946         (setf (info :type :kind spec) #+sb-xc-host :defined #-sb-xc-host :primitive))))
 947   (values))
 948 \f
 949 ;;;; general TYPE-UNION and TYPE-INTERSECTION operations
 950 ;;;;
 951 ;;;; These are fully general operations on CTYPEs: they'll always
 952 ;;;; return a CTYPE representing the result.
 953
 954 ;;; shared logic for unions and intersections: Return a list of
 955 ;;; types representing the same types as INPUT-TYPES, but with
 956 ;;; COMPOUND-TYPEs satisfying %COMPOUND-TYPE-P broken up into their
 957 ;;; component types, and with any SIMPLY2 simplifications applied.
 958 (macrolet
 959     ((def (name compound-type-p simplify2)
 960          `(defun ,name (types)
 961             (when types
 962               (multiple-value-bind (first rest)
 963                   (if (,compound-type-p (car types))
 964                       (values (car (compound-type-types (car types)))
 965                               (append (cdr (compound-type-types (car types)))
 966                                       (cdr types)))
 967                       (values (car types) (cdr types)))
 968                 (let ((rest (,name rest)) u)
 969                   (dolist (r rest (cons first rest))
 970                     (when (setq u (,simplify2 first r))
 971                       (return (,name (nsubstitute u r rest)))))))))))
 972   (def simplify-intersections intersection-type-p type-intersection2)
 973   (def simplify-unions union-type-p type-union2))
 974
 975 (defun maybe-distribute-one-union (union-type types)
 976   (let* ((intersection (apply #'type-intersection types))
 977          (union (mapcar (lambda (x) (type-intersection x intersection))
 978                         (union-type-types union-type))))
 979     (if (notany (lambda (x) (or (hairy-type-p x)
 980                                 (intersection-type-p x)))
 981                 union)
 982         union
 983         nil)))
 984
 985 (defun type-intersection (&rest input-types)
 986   (%type-intersection input-types))
 987 (defun-cached (%type-intersection :hash-bits 8
 988                                   :hash-function (lambda (x)
 989                                                    (logand (sxhash x) #xff)))
 990     ((input-types equal))
 991   (let ((simplified-types (simplify-intersections input-types)))
 992     (declare (type list simplified-types))
 993     ;; We want to have a canonical representation of types (or failing
 994     ;; that, punt to HAIRY-TYPE). Canonical representation would have
 995     ;; intersections inside unions but not vice versa, since you can
 996     ;; always achieve that by the distributive rule. But we don't want
 997     ;; to just apply the distributive rule, since it would be too easy
 998     ;; to end up with unreasonably huge type expressions. So instead
 999     ;; we try to generate a simple type by distributing the union; if
1000     ;; the type can't be made simple, we punt to HAIRY-TYPE.
1001     (if (and (cdr simplified-types) (some #'union-type-p simplified-types))
1002         (let* ((first-union (find-if #'union-type-p simplified-types))
1003                (other-types (coerce (remove first-union simplified-types)
1004                                     'list))
1005                (distributed (maybe-distribute-one-union first-union
1006                                                         other-types)))
1007           (if distributed
1008               (apply #'type-union distributed)
1009               (make-hairy-type
1010                :specifier `(and ,@(map 'list
1011                                        #'type-specifier
1012                                        simplified-types)))))
1013         (cond
1014           ((null simplified-types) *universal-type*)
1015           ((null (cdr simplified-types)) (car simplified-types))
1016           (t (%make-intersection-type
1017               (some #'type-enumerable simplified-types)
1018               simplified-types))))))
1019
1020 (defun type-union (&rest input-types)
1021   (%type-union input-types))
1022 (defun-cached (%type-union :hash-bits 8
1023                            :hash-function (lambda (x)
1024                                             (logand (sxhash x) #xff)))
1025     ((input-types equal))
1026   (let ((simplified-types (simplify-unions input-types)))
1027     (cond
1028       ((null simplified-types) *empty-type*)
1029       ((null (cdr simplified-types)) (car simplified-types))
1030       (t (make-union-type
1031           (every #'type-enumerable simplified-types)
1032           simplified-types)))))
1033 \f
1034 ;;;; built-in types
1035
1036 (!define-type-class named)
1037
1038 (!cold-init-forms
1039  (macrolet ((frob (name var)
1040               `(progn
1041                  (setq ,var (make-named-type :name ',name))
1042                  (setf (info :type :kind ',name)
1043                        #+sb-xc-host :defined #-sb-xc-host :primitive)
1044                  (setf (info :type :builtin ',name) ,var))))
1045    ;; KLUDGE: In ANSI, * isn't really the name of a type, it's just a
1046    ;; special symbol which can be stuck in some places where an
1047    ;; ordinary type can go, e.g. (ARRAY * 1) instead of (ARRAY T 1).
1048    ;; In SBCL it also used to denote universal VALUES type.
1049    (frob * *wild-type*)
1050    (frob nil *empty-type*)
1051    (frob t *universal-type*))
1052  (setf *universal-fun-type*
1053        (make-fun-type :wild-args t
1054                       :returns *wild-type*)))
1055
1056 (!define-type-method (named :simple-=) (type1 type2)
1057   ;;(aver (not (eq type1 *wild-type*))) ; * isn't really a type.
1058   (values (eq type1 type2) t))
1059
1060 (defun cons-type-might-be-empty-type (type)
1061   (declare (type cons-type type))
1062   (let ((car-type (cons-type-car-type type))
1063         (cdr-type (cons-type-cdr-type type)))
1064     (or
1065      (if (cons-type-p car-type)
1066          (cons-type-might-be-empty-type car-type)
1067          (multiple-value-bind (yes surep)
1068              (type= car-type *empty-type*)
1069            (aver (not yes))
1070            (not surep)))
1071      (if (cons-type-p cdr-type)
1072          (cons-type-might-be-empty-type cdr-type)
1073          (multiple-value-bind (yes surep)
1074              (type= cdr-type *empty-type*)
1075            (aver (not yes))
1076            (not surep))))))
1077
1078 (!define-type-method (named :complex-=) (type1 type2)
1079   (cond
1080     ((and (eq type2 *empty-type*)
1081           (or (and (intersection-type-p type1)
1082                    ;; not allowed to be unsure on these... FIXME: keep
1083                    ;; the list of CL types that are intersection types
1084                    ;; once and only once.
1085                    (not (or (type= type1 (specifier-type 'ratio))
1086                             (type= type1 (specifier-type 'keyword)))))
1087               (and (cons-type-p type1)
1088                    (cons-type-might-be-empty-type type1))))
1089      ;; things like (AND (EQL 0) (SATISFIES ODDP)) or (AND FUNCTION
1090      ;; STREAM) can get here.  In general, we can't really tell
1091      ;; whether these are equal to NIL or not, so
1092      (values nil nil))
1093     ((type-might-contain-other-types-p type1)
1094      (invoke-complex-=-other-method type1 type2))
1095     (t (values nil t))))
1096
1097 (!define-type-method (named :simple-subtypep) (type1 type2)
1098   (aver (not (eq type1 *wild-type*))) ; * isn't really a type.
1099   (values (or (eq type1 *empty-type*) (eq type2 *wild-type*)) t))
1100
1101 (!define-type-method (named :complex-subtypep-arg1) (type1 type2)
1102   ;; This AVER causes problems if we write accurate methods for the
1103   ;; union (and possibly intersection) types which then delegate to
1104   ;; us; while a user shouldn't get here, because of the odd status of
1105   ;; *wild-type* a type-intersection executed by the compiler can. -
1106   ;; CSR, 2002-04-10
1107   ;;
1108   ;; (aver (not (eq type1 *wild-type*))) ; * isn't really a type.
1109   (cond ((eq type1 *empty-type*)
1110          t)
1111         (;; When TYPE2 might be the universal type in disguise
1112          (type-might-contain-other-types-p type2)
1113          ;; Now that the UNION and HAIRY COMPLEX-SUBTYPEP-ARG2 methods
1114          ;; can delegate to us (more or less as CALL-NEXT-METHOD) when
1115          ;; they're uncertain, we can't just barf on COMPOUND-TYPE and
1116          ;; HAIRY-TYPEs as we used to. Instead we deal with the
1117          ;; problem (where at least part of the problem is cases like
1118          ;;   (SUBTYPEP T '(SATISFIES FOO))
1119          ;; or
1120          ;;   (SUBTYPEP T '(AND (SATISFIES FOO) (SATISFIES BAR)))
1121          ;; where the second type is a hairy type like SATISFIES, or
1122          ;; is a compound type which might contain a hairy type) by
1123          ;; returning uncertainty.
1124          (values nil nil))
1125         (t
1126          ;; By elimination, TYPE1 is the universal type.
1127          (aver (eq type1 *universal-type*))
1128          ;; This case would have been picked off by the SIMPLE-SUBTYPEP
1129          ;; method, and so shouldn't appear here.
1130          (aver (not (eq type2 *universal-type*)))
1131          ;; Since TYPE2 is not EQ *UNIVERSAL-TYPE* and is not the
1132          ;; universal type in disguise, TYPE2 is not a superset of TYPE1.
1133          (values nil t))))
1134
1135 (!define-type-method (named :complex-subtypep-arg2) (type1 type2)
1136   (aver (not (eq type2 *wild-type*))) ; * isn't really a type.
1137   (cond ((eq type2 *universal-type*)
1138          (values t t))
1139         ((or (type-might-contain-other-types-p type1)
1140              (and (cons-type-p type1)
1141                   (cons-type-might-be-empty-type type1)))
1142          ;; those types can be *EMPTY-TYPE* or *UNIVERSAL-TYPE* in
1143          ;; disguise.  So we'd better delegate.
1144          (invoke-complex-subtypep-arg1-method type1 type2))
1145         (t
1146          ;; FIXME: This seems to rely on there only being 2 or 3
1147          ;; NAMED-TYPE values, and the exclusion of various
1148          ;; possibilities above. It would be good to explain it and/or
1149          ;; rewrite it so that it's clearer.
1150          (values (not (eq type2 *empty-type*)) t))))
1151
1152 (!define-type-method (named :complex-intersection2) (type1 type2)
1153   ;; FIXME: This assertion failed when I added it in sbcl-0.6.11.13.
1154   ;; Perhaps when bug 85 is fixed it can be reenabled.
1155   ;;(aver (not (eq type2 *wild-type*))) ; * isn't really a type.
1156   (hierarchical-intersection2 type1 type2))
1157
1158 (!define-type-method (named :complex-union2) (type1 type2)
1159   ;; Perhaps when bug 85 is fixed this can be reenabled.
1160   ;;(aver (not (eq type2 *wild-type*))) ; * isn't really a type.
1161   (hierarchical-union2 type1 type2))
1162
1163 (!define-type-method (named :negate) (x)
1164   (aver (not (eq x *wild-type*)))
1165   (cond
1166     ((eq x *universal-type*) *empty-type*)
1167     ((eq x *empty-type*) *universal-type*)
1168     (t (bug "NAMED type not universal, wild or empty: ~S" x))))
1169
1170 (!define-type-method (named :unparse) (x)
1171   (named-type-name x))
1172 \f
1173 ;;;; hairy and unknown types
1174
1175 (!define-type-method (hairy :negate) (x)
1176   (make-negation-type :type x))
1177
1178 (!define-type-method (hairy :unparse) (x)
1179   (hairy-type-specifier x))
1180
1181 (!define-type-method (hairy :simple-subtypep) (type1 type2)
1182   (let ((hairy-spec1 (hairy-type-specifier type1))
1183         (hairy-spec2 (hairy-type-specifier type2)))
1184     (cond ((equal-but-no-car-recursion hairy-spec1 hairy-spec2)
1185            (values t t))
1186           (t
1187            (values nil nil)))))
1188
1189 (!define-type-method (hairy :complex-subtypep-arg2) (type1 type2)
1190   (invoke-complex-subtypep-arg1-method type1 type2))
1191
1192 (!define-type-method (hairy :complex-subtypep-arg1) (type1 type2)
1193   (declare (ignore type1 type2))
1194   (values nil nil))
1195
1196 (!define-type-method (hairy :complex-=) (type1 type2)
1197   (if (and (unknown-type-p type2)
1198            (let* ((specifier2 (unknown-type-specifier type2))
1199                   (name2 (if (consp specifier2)
1200                              (car specifier2)
1201                              specifier2)))
1202              (info :type :kind name2)))
1203       (let ((type2 (specifier-type (unknown-type-specifier type2))))
1204         (if (unknown-type-p type2)
1205             (values nil nil)
1206             (type= type1 type2)))
1207   (values nil nil)))
1208
1209 (!define-type-method (hairy :simple-intersection2 :complex-intersection2)
1210                      (type1 type2)
1211   (if (type= type1 type2)
1212       type1
1213       nil))
1214
1215 (!define-type-method (hairy :simple-union2)
1216                      (type1 type2)
1217   (if (type= type1 type2)
1218       type1
1219       nil))
1220
1221 (!define-type-method (hairy :simple-=) (type1 type2)
1222   (if (equal-but-no-car-recursion (hairy-type-specifier type1)
1223                                   (hairy-type-specifier type2))
1224       (values t t)
1225       (values nil nil)))
1226
1227 (!def-type-translator satisfies (&whole whole fun)
1228   (declare (ignore fun))
1229   ;; Check legality of arguments.
1230   (destructuring-bind (satisfies predicate-name) whole
1231     (declare (ignore satisfies))
1232     (unless (symbolp predicate-name)
1233       (error 'simple-type-error
1234              :datum predicate-name
1235              :expected-type 'symbol
1236              :format-control "The SATISFIES predicate name is not a symbol: ~S"
1237              :format-arguments (list predicate-name))))
1238   ;; Create object.
1239   (make-hairy-type :specifier whole))
1240 \f
1241 ;;;; negation types
1242
1243 (!define-type-method (negation :negate) (x)
1244   (negation-type-type x))
1245
1246 (!define-type-method (negation :unparse) (x)
1247   (if (type= (negation-type-type x) (specifier-type 'cons))
1248       'atom
1249       `(not ,(type-specifier (negation-type-type x)))))
1250
1251 (!define-type-method (negation :simple-subtypep) (type1 type2)
1252   (csubtypep (negation-type-type type2) (negation-type-type type1)))
1253
1254 (!define-type-method (negation :complex-subtypep-arg2) (type1 type2)
1255   (let* ((complement-type2 (negation-type-type type2))
1256          (intersection2 (type-intersection2 type1
1257                                             complement-type2)))
1258     (if intersection2
1259         ;; FIXME: if uncertain, maybe try arg1?
1260         (type= intersection2 *empty-type*)
1261         (invoke-complex-subtypep-arg1-method type1 type2))))
1262
1263 (!define-type-method (negation :complex-subtypep-arg1) (type1 type2)
1264   ;; "Incrementally extended heuristic algorithms tend inexorably toward the
1265   ;; incomprehensible." -- http://www.unlambda.com/~james/lambda/lambda.txt
1266   ;;
1267   ;; You may not believe this. I couldn't either. But then I sat down
1268   ;; and drew lots of Venn diagrams. Comments involving a and b refer
1269   ;; to the call (subtypep '(not a) 'b) -- CSR, 2002-02-27.
1270   (block nil
1271     ;; (Several logical truths in this block are true as long as
1272     ;; b/=T. As of sbcl-0.7.1.28, it seems impossible to construct a
1273     ;; case with b=T where we actually reach this type method, but
1274     ;; we'll test for and exclude this case anyway, since future
1275     ;; maintenance might make it possible for it to end up in this
1276     ;; code.)
1277     (multiple-value-bind (equal certain)
1278         (type= type2 *universal-type*)
1279       (unless certain
1280         (return (values nil nil)))
1281       (when equal
1282         (return (values t t))))
1283     (let ((complement-type1 (negation-type-type type1)))
1284       ;; Do the special cases first, in order to give us a chance if
1285       ;; subtype/supertype relationships are hairy.
1286       (multiple-value-bind (equal certain)
1287           (type= complement-type1 type2)
1288         ;; If a = b, ~a is not a subtype of b (unless b=T, which was
1289         ;; excluded above).
1290         (unless certain
1291           (return (values nil nil)))
1292         (when equal
1293           (return (values nil t))))
1294       ;; KLUDGE: ANSI requires that the SUBTYPEP result between any
1295       ;; two built-in atomic type specifiers never be uncertain. This
1296       ;; is hard to do cleanly for the built-in types whose
1297       ;; definitions include (NOT FOO), i.e. CONS and RATIO. However,
1298       ;; we can do it with this hack, which uses our global knowledge
1299       ;; that our implementation of the type system uses disjoint
1300       ;; implementation types to represent disjoint sets (except when
1301       ;; types are contained in other types).  (This is a KLUDGE
1302       ;; because it's fragile. Various changes in internal
1303       ;; representation in the type system could make it start
1304       ;; confidently returning incorrect results.) -- WHN 2002-03-08
1305       (unless (or (type-might-contain-other-types-p complement-type1)
1306                   (type-might-contain-other-types-p type2))
1307         ;; Because of the way our types which don't contain other
1308         ;; types are disjoint subsets of the space of possible values,
1309         ;; (SUBTYPEP '(NOT AA) 'B)=NIL when AA and B are simple (and B
1310         ;; is not T, as checked above).
1311         (return (values nil t)))
1312       ;; The old (TYPE= TYPE1 TYPE2) branch would never be taken, as
1313       ;; TYPE1 and TYPE2 will only be equal if they're both NOT types,
1314       ;; and then the :SIMPLE-SUBTYPEP method would be used instead.
1315       ;; But a CSUBTYPEP relationship might still hold:
1316       (multiple-value-bind (equal certain)
1317           (csubtypep complement-type1 type2)
1318         ;; If a is a subtype of b, ~a is not a subtype of b (unless
1319         ;; b=T, which was excluded above).
1320         (unless certain
1321           (return (values nil nil)))
1322         (when equal
1323           (return (values nil t))))
1324       (multiple-value-bind (equal certain)
1325           (csubtypep type2 complement-type1)
1326         ;; If b is a subtype of a, ~a is not a subtype of b.  (FIXME:
1327         ;; That's not true if a=T. Do we know at this point that a is
1328         ;; not T?)
1329         (unless certain
1330           (return (values nil nil)))
1331         (when equal
1332           (return (values nil t))))
1333       ;; old CSR comment ca. 0.7.2, now obsoleted by the SIMPLE-CTYPE?
1334       ;; KLUDGE case above: Other cases here would rely on being able
1335       ;; to catch all possible cases, which the fragility of this type
1336       ;; system doesn't inspire me; for instance, if a is type= to ~b,
1337       ;; then we want T, T; if this is not the case and the types are
1338       ;; disjoint (have an intersection of *empty-type*) then we want
1339       ;; NIL, T; else if the union of a and b is the *universal-type*
1340       ;; then we want T, T. So currently we still claim to be unsure
1341       ;; about e.g. (subtypep '(not fixnum) 'single-float).
1342       ;;
1343       ;; OTOH we might still get here:
1344       (values nil nil))))
1345
1346 (!define-type-method (negation :complex-=) (type1 type2)
1347   ;; (NOT FOO) isn't equivalent to anything that's not a negation
1348   ;; type, except possibly a type that might contain it in disguise.
1349   (declare (ignore type2))
1350   (if (type-might-contain-other-types-p type1)
1351       (values nil nil)
1352       (values nil t)))
1353
1354 (!define-type-method (negation :simple-intersection2) (type1 type2)
1355   (let ((not1 (negation-type-type type1))
1356         (not2 (negation-type-type type2)))
1357     (cond
1358       ((csubtypep not1 not2) type2)
1359       ((csubtypep not2 not1) type1)
1360       ;; Why no analagous clause to the disjoint in the SIMPLE-UNION2
1361       ;; method, below?  The clause would read
1362       ;;
1363       ;; ((EQ (TYPE-UNION NOT1 NOT2) *UNIVERSAL-TYPE*) *EMPTY-TYPE*)
1364       ;;
1365       ;; but with proper canonicalization of negation types, there's
1366       ;; no way of constructing two negation types with union of their
1367       ;; negations being the universal type.
1368       (t
1369        (aver (not (eq (type-union not1 not2) *universal-type*)))
1370        nil))))
1371
1372 (!define-type-method (negation :complex-intersection2) (type1 type2)
1373   (cond
1374     ((csubtypep type1 (negation-type-type type2)) *empty-type*)
1375     ((eq (type-intersection type1 (negation-type-type type2)) *empty-type*)
1376      type1)
1377     (t nil)))
1378
1379 (!define-type-method (negation :simple-union2) (type1 type2)
1380   (let ((not1 (negation-type-type type1))
1381         (not2 (negation-type-type type2)))
1382     (cond
1383       ((csubtypep not1 not2) type1)
1384       ((csubtypep not2 not1) type2)
1385       ((eq (type-intersection not1 not2) *empty-type*)
1386        *universal-type*)
1387       (t nil))))
1388
1389 (!define-type-method (negation :complex-union2) (type1 type2)
1390   (cond
1391     ((csubtypep (negation-type-type type2) type1) *universal-type*)
1392     ((eq (type-intersection type1 (negation-type-type type2)) *empty-type*)
1393      type2)
1394     (t nil)))
1395
1396 (!define-type-method (negation :simple-=) (type1 type2)
1397   (type= (negation-type-type type1) (negation-type-type type2)))
1398
1399 (!def-type-translator not (typespec)
1400   (type-negation (specifier-type typespec)))
1401 \f
1402 ;;;; numeric types
1403
1404 (!define-type-class number)
1405
1406 (declaim (inline numeric-type-equal))
1407 (defun numeric-type-equal (type1 type2)
1408   (and (eq (numeric-type-class type1) (numeric-type-class type2))
1409        (eq (numeric-type-format type1) (numeric-type-format type2))
1410        (eq (numeric-type-complexp type1) (numeric-type-complexp type2))))
1411
1412 (!define-type-method (number :simple-=) (type1 type2)
1413   (values
1414    (and (numeric-type-equal type1 type2)
1415         (equalp (numeric-type-low type1) (numeric-type-low type2))
1416         (equalp (numeric-type-high type1) (numeric-type-high type2)))
1417    t))
1418
1419 (!define-type-method (number :negate) (type)
1420   (if (and (null (numeric-type-low type)) (null (numeric-type-high type)))
1421       (make-negation-type :type type)
1422       (type-union
1423        (make-negation-type
1424         :type (modified-numeric-type type :low nil :high nil))
1425        (cond
1426          ((null (numeric-type-low type))
1427           (modified-numeric-type
1428            type
1429            :low (let ((h (numeric-type-high type)))
1430                   (if (consp h) (car h) (list h)))
1431            :high nil))
1432          ((null (numeric-type-high type))
1433           (modified-numeric-type
1434            type
1435            :low nil
1436            :high (let ((l (numeric-type-low type)))
1437                    (if (consp l) (car l) (list l)))))
1438          (t (type-union
1439              (modified-numeric-type
1440               type
1441               :low nil
1442               :high (let ((l (numeric-type-low type)))
1443                       (if (consp l) (car l) (list l))))
1444              (modified-numeric-type
1445               type
1446               :low (let ((h (numeric-type-high type)))
1447                      (if (consp h) (car h) (list h)))
1448               :high nil)))))))
1449
1450 (!define-type-method (number :unparse) (type)
1451   (let* ((complexp (numeric-type-complexp type))
1452          (low (numeric-type-low type))
1453          (high (numeric-type-high type))
1454          (base (case (numeric-type-class type)
1455                  (integer 'integer)
1456                  (rational 'rational)
1457                  (float (or (numeric-type-format type) 'float))
1458                  (t 'real))))
1459     (let ((base+bounds
1460            (cond ((and (eq base 'integer) high low)
1461                   (let ((high-count (logcount high))
1462                         (high-length (integer-length high)))
1463                     (cond ((= low 0)
1464                            (cond ((= high 0) '(integer 0 0))
1465                                  ((= high 1) 'bit)
1466                                  ((and (= high-count high-length)
1467                                        (plusp high-length))
1468                                   `(unsigned-byte ,high-length))
1469                                  (t
1470                                   `(mod ,(1+ high)))))
1471                           ((and (= low sb!xc:most-negative-fixnum)
1472                                 (= high sb!xc:most-positive-fixnum))
1473                            'fixnum)
1474                           ((and (= low (lognot high))
1475                                 (= high-count high-length)
1476                                 (> high-count 0))
1477                            `(signed-byte ,(1+ high-length)))
1478                           (t
1479                            `(integer ,low ,high)))))
1480                  (high `(,base ,(or low '*) ,high))
1481                  (low
1482                   (if (and (eq base 'integer) (= low 0))
1483                       'unsigned-byte
1484                       `(,base ,low)))
1485                  (t base))))
1486       (ecase complexp
1487         (:real
1488          base+bounds)
1489         (:complex
1490          (aver (neq base+bounds 'real))
1491          `(complex ,base+bounds))
1492         ((nil)
1493          (aver (eq base+bounds 'real))
1494          'number)))))
1495
1496 ;;; Return true if X is "less than or equal" to Y, taking open bounds
1497 ;;; into consideration. CLOSED is the predicate used to test the bound
1498 ;;; on a closed interval (e.g. <=), and OPEN is the predicate used on
1499 ;;; open bounds (e.g. <). Y is considered to be the outside bound, in
1500 ;;; the sense that if it is infinite (NIL), then the test succeeds,
1501 ;;; whereas if X is infinite, then the test fails (unless Y is also
1502 ;;; infinite).
1503 ;;;
1504 ;;; This is for comparing bounds of the same kind, e.g. upper and
1505 ;;; upper. Use NUMERIC-BOUND-TEST* for different kinds of bounds.
1506 (defmacro numeric-bound-test (x y closed open)
1507   `(cond ((not ,y) t)
1508          ((not ,x) nil)
1509          ((consp ,x)
1510           (if (consp ,y)
1511               (,closed (car ,x) (car ,y))
1512               (,closed (car ,x) ,y)))
1513          (t
1514           (if (consp ,y)
1515               (,open ,x (car ,y))
1516               (,closed ,x ,y)))))
1517
1518 ;;; This is used to compare upper and lower bounds. This is different
1519 ;;; from the same-bound case:
1520 ;;; -- Since X = NIL is -infinity, whereas y = NIL is +infinity, we
1521 ;;;    return true if *either* arg is NIL.
1522 ;;; -- an open inner bound is "greater" and also squeezes the interval,
1523 ;;;    causing us to use the OPEN test for those cases as well.
1524 (defmacro numeric-bound-test* (x y closed open)
1525   `(cond ((not ,y) t)
1526          ((not ,x) t)
1527          ((consp ,x)
1528           (if (consp ,y)
1529               (,open (car ,x) (car ,y))
1530               (,open (car ,x) ,y)))
1531          (t
1532           (if (consp ,y)
1533               (,open ,x (car ,y))
1534               (,closed ,x ,y)))))
1535
1536 ;;; Return whichever of the numeric bounds X and Y is "maximal"
1537 ;;; according to the predicates CLOSED (e.g. >=) and OPEN (e.g. >).
1538 ;;; This is only meaningful for maximizing like bounds, i.e. upper and
1539 ;;; upper. If MAX-P is true, then we return NIL if X or Y is NIL,
1540 ;;; otherwise we return the other arg.
1541 (defmacro numeric-bound-max (x y closed open max-p)
1542   (once-only ((n-x x)
1543               (n-y y))
1544     `(cond ((not ,n-x) ,(if max-p nil n-y))
1545            ((not ,n-y) ,(if max-p nil n-x))
1546            ((consp ,n-x)
1547             (if (consp ,n-y)
1548                 (if (,closed (car ,n-x) (car ,n-y)) ,n-x ,n-y)
1549                 (if (,open (car ,n-x) ,n-y) ,n-x ,n-y)))
1550            (t
1551             (if (consp ,n-y)
1552                 (if (,open (car ,n-y) ,n-x) ,n-y ,n-x)
1553                 (if (,closed ,n-y ,n-x) ,n-y ,n-x))))))
1554
1555 (!define-type-method (number :simple-subtypep) (type1 type2)
1556   (let ((class1 (numeric-type-class type1))
1557         (class2 (numeric-type-class type2))
1558         (complexp2 (numeric-type-complexp type2))
1559         (format2 (numeric-type-format type2))
1560         (low1 (numeric-type-low type1))
1561         (high1 (numeric-type-high type1))
1562         (low2 (numeric-type-low type2))
1563         (high2 (numeric-type-high type2)))
1564     ;; If one is complex and the other isn't, they are disjoint.
1565     (cond ((not (or (eq (numeric-type-complexp type1) complexp2)
1566                     (null complexp2)))
1567            (values nil t))
1568           ;; If the classes are specified and different, the types are
1569           ;; disjoint unless type2 is RATIONAL and type1 is INTEGER.
1570           ;; [ or type1 is INTEGER and type2 is of the form (RATIONAL
1571           ;; X X) for integral X, but this is dealt with in the
1572           ;; canonicalization inside MAKE-NUMERIC-TYPE ]
1573           ((not (or (eq class1 class2)
1574                     (null class2)
1575                     (and (eq class1 'integer) (eq class2 'rational))))
1576            (values nil t))
1577           ;; If the float formats are specified and different, the types
1578           ;; are disjoint.
1579           ((not (or (eq (numeric-type-format type1) format2)
1580                     (null format2)))
1581            (values nil t))
1582           ;; Check the bounds.
1583           ((and (numeric-bound-test low1 low2 >= >)
1584                 (numeric-bound-test high1 high2 <= <))
1585            (values t t))
1586           (t
1587            (values nil t)))))
1588
1589 (!define-superclasses number ((number)) !cold-init-forms)
1590
1591 ;;; If the high bound of LOW is adjacent to the low bound of HIGH,
1592 ;;; then return true, otherwise NIL.
1593 (defun numeric-types-adjacent (low high)
1594   (let ((low-bound (numeric-type-high low))
1595         (high-bound (numeric-type-low high)))
1596     (cond ((not (and low-bound high-bound)) nil)
1597           ((and (consp low-bound) (consp high-bound)) nil)
1598           ((consp low-bound)
1599            (let ((low-value (car low-bound)))
1600              (or (eql low-value high-bound)
1601                  (and (eql low-value
1602                            (load-time-value (make-unportable-float
1603                                              :single-float-negative-zero)))
1604                       (eql high-bound 0f0))
1605                  (and (eql low-value 0f0)
1606                       (eql high-bound
1607                            (load-time-value (make-unportable-float
1608                                              :single-float-negative-zero))))
1609                  (and (eql low-value
1610                            (load-time-value (make-unportable-float
1611                                              :double-float-negative-zero)))
1612                       (eql high-bound 0d0))
1613                  (and (eql low-value 0d0)
1614                       (eql high-bound
1615                            (load-time-value (make-unportable-float
1616                                              :double-float-negative-zero)))))))
1617           ((consp high-bound)
1618            (let ((high-value (car high-bound)))
1619              (or (eql high-value low-bound)
1620                  (and (eql high-value
1621                            (load-time-value (make-unportable-float
1622                                              :single-float-negative-zero)))
1623                       (eql low-bound 0f0))
1624                  (and (eql high-value 0f0)
1625                       (eql low-bound
1626                            (load-time-value (make-unportable-float
1627                                              :single-float-negative-zero))))
1628                  (and (eql high-value
1629                            (load-time-value (make-unportable-float
1630                                              :double-float-negative-zero)))
1631                       (eql low-bound 0d0))
1632                  (and (eql high-value 0d0)
1633                       (eql low-bound
1634                            (load-time-value (make-unportable-float
1635                                              :double-float-negative-zero)))))))
1636           ((and (eq (numeric-type-class low) 'integer)
1637                 (eq (numeric-type-class high) 'integer))
1638            (eql (1+ low-bound) high-bound))
1639           (t
1640            nil))))
1641
1642 ;;; Return a numeric type that is a supertype for both TYPE1 and TYPE2.
1643 ;;;
1644 ;;; Old comment, probably no longer applicable:
1645 ;;;
1646 ;;;   ### Note: we give up early to keep from dropping lots of
1647 ;;;   information on the floor by returning overly general types.
1648 (!define-type-method (number :simple-union2) (type1 type2)
1649   (declare (type numeric-type type1 type2))
1650   (cond ((csubtypep type1 type2) type2)
1651         ((csubtypep type2 type1) type1)
1652         (t
1653          (let ((class1 (numeric-type-class type1))
1654                (format1 (numeric-type-format type1))
1655                (complexp1 (numeric-type-complexp type1))
1656                (class2 (numeric-type-class type2))
1657                (format2 (numeric-type-format type2))
1658                (complexp2 (numeric-type-complexp type2)))
1659            (cond
1660              ((and (eq class1 class2)
1661                    (eq format1 format2)
1662                    (eq complexp1 complexp2)
1663                    (or (numeric-types-intersect type1 type2)
1664                        (numeric-types-adjacent type1 type2)
1665                        (numeric-types-adjacent type2 type1)))
1666               (make-numeric-type
1667                :class class1
1668                :format format1
1669                :complexp complexp1
1670                :low (numeric-bound-max (numeric-type-low type1)
1671                                        (numeric-type-low type2)
1672                                        <= < t)
1673                :high (numeric-bound-max (numeric-type-high type1)
1674                                         (numeric-type-high type2)
1675                                         >= > t)))
1676              ;; FIXME: These two clauses are almost identical, and the
1677              ;; consequents are in fact identical in every respect.
1678              ((and (eq class1 'rational)
1679                    (eq class2 'integer)
1680                    (eq format1 format2)
1681                    (eq complexp1 complexp2)
1682                    (integerp (numeric-type-low type2))
1683                    (integerp (numeric-type-high type2))
1684                    (= (numeric-type-low type2) (numeric-type-high type2))
1685                    (or (numeric-types-adjacent type1 type2)
1686                        (numeric-types-adjacent type2 type1)))
1687               (make-numeric-type
1688                :class 'rational
1689                :format format1
1690                :complexp complexp1
1691                :low (numeric-bound-max (numeric-type-low type1)
1692                                        (numeric-type-low type2)
1693                                        <= < t)
1694                :high (numeric-bound-max (numeric-type-high type1)
1695                                         (numeric-type-high type2)
1696                                         >= > t)))
1697              ((and (eq class1 'integer)
1698                    (eq class2 'rational)
1699                    (eq format1 format2)
1700                    (eq complexp1 complexp2)
1701                    (integerp (numeric-type-low type1))
1702                    (integerp (numeric-type-high type1))
1703                    (= (numeric-type-low type1) (numeric-type-high type1))
1704                    (or (numeric-types-adjacent type1 type2)
1705                        (numeric-types-adjacent type2 type1)))
1706               (make-numeric-type
1707                :class 'rational
1708                :format format1
1709                :complexp complexp1
1710                :low (numeric-bound-max (numeric-type-low type1)
1711                                        (numeric-type-low type2)
1712                                        <= < t)
1713                :high (numeric-bound-max (numeric-type-high type1)
1714                                         (numeric-type-high type2)
1715                                         >= > t)))
1716              (t nil))))))
1717
1718
1719 (!cold-init-forms
1720   (setf (info :type :kind 'number)
1721         #+sb-xc-host :defined #-sb-xc-host :primitive)
1722   (setf (info :type :builtin 'number)
1723         (make-numeric-type :complexp nil)))
1724
1725 (!def-type-translator complex (&optional (typespec '*))
1726   (if (eq typespec '*)
1727       (specifier-type '(complex real))
1728       (labels ((not-numeric ()
1729                  (error "The component type for COMPLEX is not numeric: ~S"
1730                         typespec))
1731                (not-real ()
1732                  (error "The component type for COMPLEX is not a subtype of REAL: ~S"
1733                         typespec))
1734                (complex1 (component-type)
1735                  (unless (numeric-type-p component-type)
1736                    (not-numeric))
1737                  (when (eq (numeric-type-complexp component-type) :complex)
1738                    (not-real))
1739                  (if (csubtypep component-type (specifier-type '(eql 0)))
1740                      *empty-type*
1741                      (modified-numeric-type component-type
1742                                             :complexp :complex))))
1743         (let ((ctype (specifier-type typespec)))
1744           (cond
1745             ((eq ctype *empty-type*) *empty-type*)
1746             ((eq ctype *universal-type*) (not-real))
1747             ((typep ctype 'numeric-type) (complex1 ctype))
1748             ((typep ctype 'union-type)
1749              (apply #'type-union
1750                     ;; FIXME: This code could suffer from (admittedly
1751                     ;; very obscure) cases of bug 145 e.g. when TYPE
1752                     ;; is
1753                     ;;   (OR (AND INTEGER (SATISFIES ODDP))
1754                     ;;       (AND FLOAT (SATISFIES FOO))
1755                     ;; and not even report the problem very well.
1756                     (mapcar #'complex1 (union-type-types ctype))))
1757             ((typep ctype 'member-type)
1758              (apply #'type-union
1759                     (mapcar (lambda (x) (complex1 (ctype-of x)))
1760                             (member-type-members ctype))))
1761             ((and (typep ctype 'intersection-type)
1762                   ;; FIXME: This is very much a
1763                   ;; not-quite-worst-effort, but we are required to do
1764                   ;; something here because of our representation of
1765                   ;; RATIO as (AND RATIONAL (NOT INTEGER)): we must
1766                   ;; allow users to ask about (COMPLEX RATIO).  This
1767                   ;; will of course fail to work right on such types
1768                   ;; as (AND INTEGER (SATISFIES ZEROP))...
1769                   (let ((numbers (remove-if-not
1770                                   #'numeric-type-p
1771                                   (intersection-type-types ctype))))
1772                     (and (car numbers)
1773                          (null (cdr numbers))
1774                          (eq (numeric-type-complexp (car numbers)) :real)
1775                          (complex1 (car numbers))))))
1776             (t
1777              (multiple-value-bind (subtypep certainly)
1778                  (csubtypep ctype (specifier-type 'real))
1779                (if (and (not subtypep) certainly)
1780                    (not-real)
1781                    ;; ANSI just says that TYPESPEC is any subtype of
1782                    ;; type REAL, not necessarily a NUMERIC-TYPE. In
1783                    ;; particular, at this point TYPESPEC could legally
1784                    ;; be a hairy type like (AND NUMBER (SATISFIES
1785                    ;; REALP) (SATISFIES ZEROP)), in which case we fall
1786                    ;; through the logic above and end up here,
1787                    ;; stumped.
1788                    (bug "~@<(known bug #145): The type ~S is too hairy to be ~
1789                          used for a COMPLEX component.~:@>"
1790                         typespec)))))))))
1791
1792 ;;; If X is *, return NIL, otherwise return the bound, which must be a
1793 ;;; member of TYPE or a one-element list of a member of TYPE.
1794 #!-sb-fluid (declaim (inline canonicalized-bound))
1795 (defun canonicalized-bound (bound type)
1796   (cond ((eq bound '*) nil)
1797         ((or (sb!xc:typep bound type)
1798              (and (consp bound)
1799                   (sb!xc:typep (car bound) type)
1800                   (null (cdr bound))))
1801           bound)
1802         (t
1803          (error "Bound is not ~S, a ~S or a list of a ~S: ~S"
1804                 '*
1805                 type
1806                 type
1807                 bound))))
1808
1809 (!def-type-translator integer (&optional (low '*) (high '*))
1810   (let* ((l (canonicalized-bound low 'integer))
1811          (lb (if (consp l) (1+ (car l)) l))
1812          (h (canonicalized-bound high 'integer))
1813          (hb (if (consp h) (1- (car h)) h)))
1814     (if (and hb lb (< hb lb))
1815         *empty-type*
1816       (make-numeric-type :class 'integer
1817                          :complexp :real
1818                          :enumerable (not (null (and l h)))
1819                          :low lb
1820                          :high hb))))
1821
1822 (defmacro !def-bounded-type (type class format)
1823   `(!def-type-translator ,type (&optional (low '*) (high '*))
1824      (let ((lb (canonicalized-bound low ',type))
1825            (hb (canonicalized-bound high ',type)))
1826        (if (not (numeric-bound-test* lb hb <= <))
1827            *empty-type*
1828          (make-numeric-type :class ',class
1829                             :format ',format
1830                             :low lb
1831                             :high hb)))))
1832
1833 (!def-bounded-type rational rational nil)
1834
1835 ;;; Unlike CMU CL, we represent the types FLOAT and REAL as
1836 ;;; UNION-TYPEs of more primitive types, in order to make
1837 ;;; type representation more unique, avoiding problems in the
1838 ;;; simplification of things like
1839 ;;;   (subtypep '(or (single-float -1.0 1.0) (single-float 0.1))
1840 ;;;             '(or (real -1 7) (single-float 0.1) (single-float -1.0 1.0)))
1841 ;;; When we allowed REAL to remain as a separate NUMERIC-TYPE,
1842 ;;; it was too easy for the first argument to be simplified to
1843 ;;; '(SINGLE-FLOAT -1.0), and for the second argument to be simplified
1844 ;;; to '(OR (REAL -1 7) (SINGLE-FLOAT 0.1)) and then for the
1845 ;;; SUBTYPEP to fail (returning NIL,T instead of T,T) because
1846 ;;; the first argument can't be seen to be a subtype of any of the
1847 ;;; terms in the second argument.
1848 ;;;
1849 ;;; The old CMU CL way was:
1850 ;;;   (!def-bounded-type float float nil)
1851 ;;;   (!def-bounded-type real nil nil)
1852 ;;;
1853 ;;; FIXME: If this new way works for a while with no weird new
1854 ;;; problems, we can go back and rip out support for separate FLOAT
1855 ;;; and REAL flavors of NUMERIC-TYPE. The new way was added in
1856 ;;; sbcl-0.6.11.22, 2001-03-21.
1857 ;;;
1858 ;;; FIXME: It's probably necessary to do something to fix the
1859 ;;; analogous problem with INTEGER and RATIONAL types. Perhaps
1860 ;;; bounded RATIONAL types should be represented as (OR RATIO INTEGER).
1861 (defun coerce-bound (bound type upperp inner-coerce-bound-fun)
1862   (declare (type function inner-coerce-bound-fun))
1863   (if (eql bound '*)
1864       bound
1865       (funcall inner-coerce-bound-fun bound type upperp)))
1866 (defun inner-coerce-real-bound (bound type upperp)
1867   #+sb-xc-host (declare (ignore upperp))
1868   (let #+sb-xc-host ()
1869        #-sb-xc-host
1870        ((nl (load-time-value (symbol-value 'sb!xc:most-negative-long-float)))
1871         (pl (load-time-value (symbol-value 'sb!xc:most-positive-long-float))))
1872     (let ((nbound (if (consp bound) (car bound) bound))
1873           (consp (consp bound)))
1874       (ecase type
1875         (rational
1876          (if consp
1877              (list (rational nbound))
1878              (rational nbound)))
1879         (float
1880          (cond
1881            ((floatp nbound) bound)
1882            (t
1883             ;; Coerce to the widest float format available, to avoid
1884             ;; unnecessary loss of precision, but don't coerce
1885             ;; unrepresentable numbers, except on the host where we
1886             ;; shouldn't be making these types (but KLUDGE: can't even
1887             ;; assert portably that we're not).
1888             #-sb-xc-host
1889             (ecase upperp
1890               ((nil)
1891                (when (< nbound nl) (return-from inner-coerce-real-bound nl)))
1892               ((t)
1893                (when (> nbound pl) (return-from inner-coerce-real-bound pl))))
1894             (let ((result (coerce nbound 'long-float)))
1895               (if consp (list result) result)))))))))
1896 (defun inner-coerce-float-bound (bound type upperp)
1897   #+sb-xc-host (declare (ignore upperp))
1898   (let #+sb-xc-host ()
1899        #-sb-xc-host
1900        ((nd (load-time-value (symbol-value 'sb!xc:most-negative-double-float)))
1901         (pd (load-time-value (symbol-value 'sb!xc:most-positive-double-float)))
1902         (ns (load-time-value (symbol-value 'sb!xc:most-negative-single-float)))
1903         (ps (load-time-value
1904              (symbol-value 'sb!xc:most-positive-single-float))))
1905     (let ((nbound (if (consp bound) (car bound) bound))
1906           (consp (consp bound)))
1907       (ecase type
1908         (single-float
1909          (cond
1910            ((typep nbound 'single-float) bound)
1911            (t
1912             #-sb-xc-host
1913             (ecase upperp
1914               ((nil)
1915                (when (< nbound ns) (return-from inner-coerce-float-bound ns)))
1916               ((t)
1917                (when (> nbound ps) (return-from inner-coerce-float-bound ps))))
1918             (let ((result (coerce nbound 'single-float)))
1919               (if consp (list result) result)))))
1920         (double-float
1921          (cond
1922            ((typep nbound 'double-float) bound)
1923            (t
1924             #-sb-xc-host
1925             (ecase upperp
1926               ((nil)
1927                (when (< nbound nd) (return-from inner-coerce-float-bound nd)))
1928               ((t)
1929                (when (> nbound pd) (return-from inner-coerce-float-bound pd))))
1930             (let ((result (coerce nbound 'double-float)))
1931               (if consp (list result) result)))))))))
1932 (defun coerced-real-bound (bound type upperp)
1933   (coerce-bound bound type upperp #'inner-coerce-real-bound))
1934 (defun coerced-float-bound (bound type upperp)
1935   (coerce-bound bound type upperp #'inner-coerce-float-bound))
1936 (!def-type-translator real (&optional (low '*) (high '*))
1937   (specifier-type `(or (float ,(coerced-real-bound  low 'float nil)
1938                               ,(coerced-real-bound high 'float t))
1939                        (rational ,(coerced-real-bound  low 'rational nil)
1940                                  ,(coerced-real-bound high 'rational t)))))
1941 (!def-type-translator float (&optional (low '*) (high '*))
1942   (specifier-type
1943    `(or (single-float ,(coerced-float-bound  low 'single-float nil)
1944                       ,(coerced-float-bound high 'single-float t))
1945         (double-float ,(coerced-float-bound  low 'double-float nil)
1946                       ,(coerced-float-bound high 'double-float t))
1947         #!+long-float ,(error "stub: no long float support yet"))))
1948
1949 (defmacro !define-float-format (f)
1950   `(!def-bounded-type ,f float ,f))
1951
1952 (!define-float-format short-float)
1953 (!define-float-format single-float)
1954 (!define-float-format double-float)
1955 (!define-float-format long-float)
1956
1957 (defun numeric-types-intersect (type1 type2)
1958   (declare (type numeric-type type1 type2))
1959   (let* ((class1 (numeric-type-class type1))
1960          (class2 (numeric-type-class type2))
1961          (complexp1 (numeric-type-complexp type1))
1962          (complexp2 (numeric-type-complexp type2))
1963          (format1 (numeric-type-format type1))
1964          (format2 (numeric-type-format type2))
1965          (low1 (numeric-type-low type1))
1966          (high1 (numeric-type-high type1))
1967          (low2 (numeric-type-low type2))
1968          (high2 (numeric-type-high type2)))
1969     ;; If one is complex and the other isn't, then they are disjoint.
1970     (cond ((not (or (eq complexp1 complexp2)
1971                     (null complexp1) (null complexp2)))
1972            nil)
1973           ;; If either type is a float, then the other must either be
1974           ;; specified to be a float or unspecified. Otherwise, they
1975           ;; are disjoint.
1976           ((and (eq class1 'float)
1977                 (not (member class2 '(float nil)))) nil)
1978           ((and (eq class2 'float)
1979                 (not (member class1 '(float nil)))) nil)
1980           ;; If the float formats are specified and different, the
1981           ;; types are disjoint.
1982           ((not (or (eq format1 format2) (null format1) (null format2)))
1983            nil)
1984           (t
1985            ;; Check the bounds. This is a bit odd because we must
1986            ;; always have the outer bound of the interval as the
1987            ;; second arg.
1988            (if (numeric-bound-test high1 high2 <= <)
1989                (or (and (numeric-bound-test low1 low2 >= >)
1990                         (numeric-bound-test* low1 high2 <= <))
1991                    (and (numeric-bound-test low2 low1 >= >)
1992                         (numeric-bound-test* low2 high1 <= <)))
1993                (or (and (numeric-bound-test* low2 high1 <= <)
1994                         (numeric-bound-test low2 low1 >= >))
1995                    (and (numeric-bound-test high2 high1 <= <)
1996                         (numeric-bound-test* high2 low1 >= >))))))))
1997
1998 ;;; Take the numeric bound X and convert it into something that can be
1999 ;;; used as a bound in a numeric type with the specified CLASS and
2000 ;;; FORMAT. If UP-P is true, then we round up as needed, otherwise we
2001 ;;; round down. UP-P true implies that X is a lower bound, i.e. (N) > N.
2002 ;;;
2003 ;;; This is used by NUMERIC-TYPE-INTERSECTION to mash the bound into
2004 ;;; the appropriate type number. X may only be a float when CLASS is
2005 ;;; FLOAT.
2006 ;;;
2007 ;;; ### Note: it is possible for the coercion to a float to overflow
2008 ;;; or underflow. This happens when the bound doesn't fit in the
2009 ;;; specified format. In this case, we should really return the
2010 ;;; appropriate {Most | Least}-{Positive | Negative}-XXX-Float float
2011 ;;; of desired format. But these conditions aren't currently signalled
2012 ;;; in any useful way.
2013 ;;;
2014 ;;; Also, when converting an open rational bound into a float we
2015 ;;; should probably convert it to a closed bound of the closest float
2016 ;;; in the specified format. KLUDGE: In general, open float bounds are
2017 ;;; screwed up. -- (comment from original CMU CL)
2018 (defun round-numeric-bound (x class format up-p)
2019   (if x
2020       (let ((cx (if (consp x) (car x) x)))
2021         (ecase class
2022           ((nil rational) x)
2023           (integer
2024            (if (and (consp x) (integerp cx))
2025                (if up-p (1+ cx) (1- cx))
2026                (if up-p (ceiling cx) (floor cx))))
2027           (float
2028            (let ((res (if format (coerce cx format) (float cx))))
2029              (if (consp x) (list res) res)))))
2030       nil))
2031
2032 ;;; Handle the case of type intersection on two numeric types. We use
2033 ;;; TYPES-EQUAL-OR-INTERSECT to throw out the case of types with no
2034 ;;; intersection. If an attribute in TYPE1 is unspecified, then we use
2035 ;;; TYPE2's attribute, which must be at least as restrictive. If the
2036 ;;; types intersect, then the only attributes that can be specified
2037 ;;; and different are the class and the bounds.
2038 ;;;
2039 ;;; When the class differs, we use the more restrictive class. The
2040 ;;; only interesting case is RATIONAL/INTEGER, since RATIONAL includes
2041 ;;; INTEGER.
2042 ;;;
2043 ;;; We make the result lower (upper) bound the maximum (minimum) of
2044 ;;; the argument lower (upper) bounds. We convert the bounds into the
2045 ;;; appropriate numeric type before maximizing. This avoids possible
2046 ;;; confusion due to mixed-type comparisons (but I think the result is
2047 ;;; the same).
2048 (!define-type-method (number :simple-intersection2) (type1 type2)
2049   (declare (type numeric-type type1 type2))
2050   (if (numeric-types-intersect type1 type2)
2051       (let* ((class1 (numeric-type-class type1))
2052              (class2 (numeric-type-class type2))
2053              (class (ecase class1
2054                       ((nil) class2)
2055                       ((integer float) class1)
2056                       (rational (if (eq class2 'integer)
2057                                        'integer
2058                                        'rational))))
2059              (format (or (numeric-type-format type1)
2060                          (numeric-type-format type2))))
2061         (make-numeric-type
2062          :class class
2063          :format format
2064          :complexp (or (numeric-type-complexp type1)
2065                        (numeric-type-complexp type2))
2066          :low (numeric-bound-max
2067                (round-numeric-bound (numeric-type-low type1)
2068                                     class format t)
2069                (round-numeric-bound (numeric-type-low type2)
2070                                     class format t)
2071                > >= nil)
2072          :high (numeric-bound-max
2073                 (round-numeric-bound (numeric-type-high type1)
2074                                      class format nil)
2075                 (round-numeric-bound (numeric-type-high type2)
2076                                      class format nil)
2077                 < <= nil)))
2078       *empty-type*))
2079
2080 ;;; Given two float formats, return the one with more precision. If
2081 ;;; either one is null, return NIL.
2082 (defun float-format-max (f1 f2)
2083   (when (and f1 f2)
2084     (dolist (f *float-formats* (error "bad float format: ~S" f1))
2085       (when (or (eq f f1) (eq f f2))
2086         (return f)))))
2087
2088 ;;; Return the result of an operation on TYPE1 and TYPE2 according to
2089 ;;; the rules of numeric contagion. This is always NUMBER, some float
2090 ;;; format (possibly complex) or RATIONAL. Due to rational
2091 ;;; canonicalization, there isn't much we can do here with integers or
2092 ;;; rational complex numbers.
2093 ;;;
2094 ;;; If either argument is not a NUMERIC-TYPE, then return NUMBER. This
2095 ;;; is useful mainly for allowing types that are technically numbers,
2096 ;;; but not a NUMERIC-TYPE.
2097 (defun numeric-contagion (type1 type2)
2098   (if (and (numeric-type-p type1) (numeric-type-p type2))
2099       (let ((class1 (numeric-type-class type1))
2100             (class2 (numeric-type-class type2))
2101             (format1 (numeric-type-format type1))
2102             (format2 (numeric-type-format type2))
2103             (complexp1 (numeric-type-complexp type1))
2104             (complexp2 (numeric-type-complexp type2)))
2105         (cond ((or (null complexp1)
2106                    (null complexp2))
2107                (specifier-type 'number))
2108               ((eq class1 'float)
2109                (make-numeric-type
2110                 :class 'float
2111                 :format (ecase class2
2112                           (float (float-format-max format1 format2))
2113                           ((integer rational) format1)
2114                           ((nil)
2115                            ;; A double-float with any real number is a
2116                            ;; double-float.
2117                            #!-long-float
2118                            (if (eq format1 'double-float)
2119                              'double-float
2120                              nil)
2121                            ;; A long-float with any real number is a
2122                            ;; long-float.
2123                            #!+long-float
2124                            (if (eq format1 'long-float)
2125                              'long-float
2126                              nil)))
2127                 :complexp (if (or (eq complexp1 :complex)
2128                                   (eq complexp2 :complex))
2129                               :complex
2130                               :real)))
2131               ((eq class2 'float) (numeric-contagion type2 type1))
2132               ((and (eq complexp1 :real) (eq complexp2 :real))
2133                (make-numeric-type
2134                 :class (and class1 class2 'rational)
2135                 :complexp :real))
2136               (t
2137                (specifier-type 'number))))
2138       (specifier-type 'number)))
2139 \f
2140 ;;;; array types
2141
2142 (!define-type-class array)
2143
2144 ;;; What this does depends on the setting of the
2145 ;;; *USE-IMPLEMENTATION-TYPES* switch. If true, return the specialized
2146 ;;; element type, otherwise return the original element type.
2147 (defun specialized-element-type-maybe (type)
2148   (declare (type array-type type))
2149   (if *use-implementation-types*
2150       (array-type-specialized-element-type type)
2151       (array-type-element-type type)))
2152
2153 (!define-type-method (array :simple-=) (type1 type2)
2154   (if (or (unknown-type-p (array-type-element-type type1))
2155           (unknown-type-p (array-type-element-type type2)))
2156       (multiple-value-bind (equalp certainp)
2157           (type= (array-type-element-type type1)
2158                  (array-type-element-type type2))
2159         ;; By its nature, the call to TYPE= should never return NIL,
2160         ;; T, as we don't know what the UNKNOWN-TYPE will grow up to
2161         ;; be.  -- CSR, 2002-08-19
2162         (aver (not (and (not equalp) certainp)))
2163         (values equalp certainp))
2164       (values (and (equal (array-type-dimensions type1)
2165                           (array-type-dimensions type2))
2166                    (eq (array-type-complexp type1)
2167                        (array-type-complexp type2))
2168                    (type= (specialized-element-type-maybe type1)
2169                           (specialized-element-type-maybe type2)))
2170               t)))
2171
2172 (!define-type-method (array :negate) (type)
2173   ;; FIXME (and hint to PFD): we're vulnerable here to attacks of the
2174   ;; form "are (AND ARRAY (NOT (ARRAY T))) and (OR (ARRAY BIT) (ARRAY
2175   ;; NIL) (ARRAY CHAR) ...) equivalent?" -- CSR, 2003-12-10
2176   (make-negation-type :type type))
2177
2178 (!define-type-method (array :unparse) (type)
2179   (let ((dims (array-type-dimensions type))
2180         (eltype (type-specifier (array-type-element-type type)))
2181         (complexp (array-type-complexp type)))
2182     (cond ((eq dims '*)
2183            (if (eq eltype '*)
2184                (if complexp 'array 'simple-array)
2185                (if complexp `(array ,eltype) `(simple-array ,eltype))))
2186           ((= (length dims) 1)
2187            (if complexp
2188                (if (eq (car dims) '*)
2189                    (case eltype
2190                      (bit 'bit-vector)
2191                      ((base-char #!-sb-unicode character) 'base-string)
2192                      (* 'vector)
2193                      (t `(vector ,eltype)))
2194                    (case eltype
2195                      (bit `(bit-vector ,(car dims)))
2196                      ((base-char #!-sb-unicode character)
2197                       `(base-string ,(car dims)))
2198                      (t `(vector ,eltype ,(car dims)))))
2199                (if (eq (car dims) '*)
2200                    (case eltype
2201                      (bit 'simple-bit-vector)
2202                      ((base-char #!-sb-unicode character) 'simple-base-string)
2203                      ((t) 'simple-vector)
2204                      (t `(simple-array ,eltype (*))))
2205                    (case eltype
2206                      (bit `(simple-bit-vector ,(car dims)))
2207                      ((base-char #!-sb-unicode character)
2208                       `(simple-base-string ,(car dims)))
2209                      ((t) `(simple-vector ,(car dims)))
2210                      (t `(simple-array ,eltype ,dims))))))
2211           (t
2212            (if complexp
2213                `(array ,eltype ,dims)
2214                `(simple-array ,eltype ,dims))))))
2215
2216 (!define-type-method (array :simple-subtypep) (type1 type2)
2217   (let ((dims1 (array-type-dimensions type1))
2218         (dims2 (array-type-dimensions type2))
2219         (complexp2 (array-type-complexp type2)))
2220     (cond (;; not subtypep unless dimensions are compatible
2221            (not (or (eq dims2 '*)
2222                     (and (not (eq dims1 '*))
2223                          ;; (sbcl-0.6.4 has trouble figuring out that
2224                          ;; DIMS1 and DIMS2 must be lists at this
2225                          ;; point, and knowing that is important to
2226                          ;; compiling EVERY efficiently.)
2227                          (= (length (the list dims1))
2228                             (length (the list dims2)))
2229                          (every (lambda (x y)
2230                                   (or (eq y '*) (eql x y)))
2231                                 (the list dims1)
2232                                 (the list dims2)))))
2233            (values nil t))
2234           ;; not subtypep unless complexness is compatible
2235           ((not (or (eq complexp2 :maybe)
2236                     (eq (array-type-complexp type1) complexp2)))
2237            (values nil t))
2238           ;; Since we didn't fail any of the tests above, we win
2239           ;; if the TYPE2 element type is wild.
2240           ((eq (array-type-element-type type2) *wild-type*)
2241            (values t t))
2242           (;; Since we didn't match any of the special cases above, we
2243            ;; can't give a good answer unless both the element types
2244            ;; have been defined.
2245            (or (unknown-type-p (array-type-element-type type1))
2246                (unknown-type-p (array-type-element-type type2)))
2247            (values nil nil))
2248           (;; Otherwise, the subtype relationship holds iff the
2249            ;; types are equal, and they're equal iff the specialized
2250            ;; element types are identical.
2251            t
2252            (values (type= (specialized-element-type-maybe type1)
2253                           (specialized-element-type-maybe type2))
2254                    t)))))
2255
2256 ;;; FIXME: is this dead?
2257 (!define-superclasses array
2258   ((base-string base-string)
2259    (vector vector)
2260    (array))
2261   !cold-init-forms)
2262
2263 (defun array-types-intersect (type1 type2)
2264   (declare (type array-type type1 type2))
2265   (let ((dims1 (array-type-dimensions type1))
2266         (dims2 (array-type-dimensions type2))
2267         (complexp1 (array-type-complexp type1))
2268         (complexp2 (array-type-complexp type2)))
2269     ;; See whether dimensions are compatible.
2270     (cond ((not (or (eq dims1 '*) (eq dims2 '*)
2271                     (and (= (length dims1) (length dims2))
2272                          (every (lambda (x y)
2273                                   (or (eq x '*) (eq y '*) (= x y)))
2274                                 dims1 dims2))))
2275            (values nil t))
2276           ;; See whether complexpness is compatible.
2277           ((not (or (eq complexp1 :maybe)
2278                     (eq complexp2 :maybe)
2279                     (eq complexp1 complexp2)))
2280            (values nil t))
2281           ;; Old comment:
2282           ;;
2283           ;;   If either element type is wild, then they intersect.
2284           ;;   Otherwise, the types must be identical.
2285           ;;
2286           ;; FIXME: There seems to have been a fair amount of
2287           ;; confusion about the distinction between requested element
2288           ;; type and specialized element type; here is one of
2289           ;; them. If we request an array to hold objects of an
2290           ;; unknown type, we can do no better than represent that
2291           ;; type as an array specialized on wild-type.  We keep the
2292           ;; requested element-type in the -ELEMENT-TYPE slot, and
2293           ;; *WILD-TYPE* in the -SPECIALIZED-ELEMENT-TYPE.  So, here,
2294           ;; we must test for the SPECIALIZED slot being *WILD-TYPE*,
2295           ;; not just the ELEMENT-TYPE slot.  Maybe the return value
2296           ;; in that specific case should be T, NIL?  Or maybe this
2297           ;; function should really be called
2298           ;; ARRAY-TYPES-COULD-POSSIBLY-INTERSECT?  In any case, this
2299           ;; was responsible for bug #123, and this whole issue could
2300           ;; do with a rethink and/or a rewrite.  -- CSR, 2002-08-21
2301           ((or (eq (array-type-specialized-element-type type1) *wild-type*)
2302                (eq (array-type-specialized-element-type type2) *wild-type*)
2303                (type= (specialized-element-type-maybe type1)
2304                       (specialized-element-type-maybe type2)))
2305
2306            (values t t))
2307           (t
2308            (values nil t)))))
2309
2310 (!define-type-method (array :simple-intersection2) (type1 type2)
2311   (declare (type array-type type1 type2))
2312   (if (array-types-intersect type1 type2)
2313       (let ((dims1 (array-type-dimensions type1))
2314             (dims2 (array-type-dimensions type2))
2315             (complexp1 (array-type-complexp type1))
2316             (complexp2 (array-type-complexp type2))
2317             (eltype1 (array-type-element-type type1))
2318             (eltype2 (array-type-element-type type2)))
2319         (specialize-array-type
2320          (make-array-type
2321           :dimensions (cond ((eq dims1 '*) dims2)
2322                             ((eq dims2 '*) dims1)
2323                             (t
2324                              (mapcar (lambda (x y) (if (eq x '*) y x))
2325                                      dims1 dims2)))
2326           :complexp (if (eq complexp1 :maybe) complexp2 complexp1)
2327           :element-type (cond
2328                           ((eq eltype1 *wild-type*) eltype2)
2329                           ((eq eltype2 *wild-type*) eltype1)
2330                           (t (type-intersection eltype1 eltype2))))))
2331       *empty-type*))
2332
2333 ;;; Check a supplied dimension list to determine whether it is legal,
2334 ;;; and return it in canonical form (as either '* or a list).
2335 (defun canonical-array-dimensions (dims)
2336   (typecase dims
2337     ((member *) dims)
2338     (integer
2339      (when (minusp dims)
2340        (error "Arrays can't have a negative number of dimensions: ~S" dims))
2341      (when (>= dims sb!xc:array-rank-limit)
2342        (error "array type with too many dimensions: ~S" dims))
2343      (make-list dims :initial-element '*))
2344     (list
2345      (when (>= (length dims) sb!xc:array-rank-limit)
2346        (error "array type with too many dimensions: ~S" dims))
2347      (dolist (dim dims)
2348        (unless (eq dim '*)
2349          (unless (and (integerp dim)
2350                       (>= dim 0)
2351                       (< dim sb!xc:array-dimension-limit))
2352            (error "bad dimension in array type: ~S" dim))))
2353      dims)
2354     (t
2355      (error "Array dimensions is not a list, integer or *:~%  ~S" dims))))
2356 \f
2357 ;;;; MEMBER types
2358
2359 (!define-type-class member)
2360
2361 (!define-type-method (member :negate) (type)
2362   (let ((members (member-type-members type)))
2363     (if (some #'floatp members)
2364         (let (floats)
2365           (dolist (pair `((0.0f0 . ,(load-time-value (make-unportable-float :single-float-negative-zero)))
2366                           (0.0d0 . ,(load-time-value (make-unportable-float :double-float-negative-zero)))
2367                           #!+long-float
2368                           (0.0l0 . ,(load-time-value (make-unportable-float :long-float-negative-zero)))))
2369             (when (member (car pair) members)
2370               (aver (not (member (cdr pair) members)))
2371               (push (cdr pair) floats)
2372               (setf members (remove (car pair) members)))
2373             (when (member (cdr pair) members)
2374               (aver (not (member (car pair) members)))
2375               (push (car pair) floats)
2376               (setf members (remove (cdr pair) members))))
2377           (apply #'type-intersection
2378                  (if (null members)
2379                      *universal-type*
2380                      (make-negation-type
2381                       :type (make-member-type :members members)))
2382                  (mapcar
2383                   (lambda (x)
2384                     (let ((type (ctype-of x)))
2385                       (type-union
2386                        (make-negation-type
2387                         :type (modified-numeric-type type
2388                                                      :low nil :high nil))
2389                        (modified-numeric-type type
2390                                               :low nil :high (list x))
2391                        (make-member-type :members (list x))
2392                        (modified-numeric-type type
2393                                               :low (list x) :high nil))))
2394                   floats)))
2395         (make-negation-type :type type))))
2396
2397 (!define-type-method (member :unparse) (type)
2398   (let ((members (member-type-members type)))
2399     (cond
2400       ((equal members '(nil)) 'null)
2401       ((type= type (specifier-type 'standard-char)) 'standard-char)
2402       (t `(member ,@members)))))
2403
2404 (!define-type-method (member :simple-subtypep) (type1 type2)
2405   (values (subsetp (member-type-members type1) (member-type-members type2))
2406           t))
2407
2408 (!define-type-method (member :complex-subtypep-arg1) (type1 type2)
2409   (every/type (swapped-args-fun #'ctypep)
2410               type2
2411               (member-type-members type1)))
2412
2413 ;;; We punt if the odd type is enumerable and intersects with the
2414 ;;; MEMBER type. If not enumerable, then it is definitely not a
2415 ;;; subtype of the MEMBER type.
2416 (!define-type-method (member :complex-subtypep-arg2) (type1 type2)
2417   (cond ((not (type-enumerable type1)) (values nil t))
2418         ((types-equal-or-intersect type1 type2)
2419          (invoke-complex-subtypep-arg1-method type1 type2))
2420         (t (values nil t))))
2421
2422 (!define-type-method (member :simple-intersection2) (type1 type2)
2423   (let ((mem1 (member-type-members type1))
2424         (mem2 (member-type-members type2)))
2425     (cond ((subsetp mem1 mem2) type1)
2426           ((subsetp mem2 mem1) type2)
2427           (t
2428            (let ((res (intersection mem1 mem2)))
2429              (if res
2430                  (make-member-type :members res)
2431                  *empty-type*))))))
2432
2433 (!define-type-method (member :complex-intersection2) (type1 type2)
2434   (block punt
2435     (collect ((members))
2436       (let ((mem2 (member-type-members type2)))
2437         (dolist (member mem2)
2438           (multiple-value-bind (val win) (ctypep member type1)
2439             (unless win
2440               (return-from punt nil))
2441             (when val (members member))))
2442         (cond ((subsetp mem2 (members)) type2)
2443               ((null (members)) *empty-type*)
2444               (t
2445                (make-member-type :members (members))))))))
2446
2447 ;;; We don't need a :COMPLEX-UNION2, since the only interesting case is
2448 ;;; a union type, and the member/union interaction is handled by the
2449 ;;; union type method.
2450 (!define-type-method (member :simple-union2) (type1 type2)
2451   (let ((mem1 (member-type-members type1))
2452         (mem2 (member-type-members type2)))
2453     (cond ((subsetp mem1 mem2) type2)
2454           ((subsetp mem2 mem1) type1)
2455           (t
2456            (make-member-type :members (union mem1 mem2))))))
2457
2458 (!define-type-method (member :simple-=) (type1 type2)
2459   (let ((mem1 (member-type-members type1))
2460         (mem2 (member-type-members type2)))
2461     (values (and (subsetp mem1 mem2)
2462                  (subsetp mem2 mem1))
2463             t)))
2464
2465 (!define-type-method (member :complex-=) (type1 type2)
2466   (if (type-enumerable type1)
2467       (multiple-value-bind (val win) (csubtypep type2 type1)
2468         (if (or val (not win))
2469             (values nil nil)
2470             (values nil t)))
2471       (values nil t)))
2472
2473 (!def-type-translator member (&rest members)
2474   (if members
2475       (let (ms numbers char-codes)
2476         (dolist (m (remove-duplicates members))
2477           (typecase m
2478             (float (if (zerop m)
2479                        (push m ms)
2480                        (push (ctype-of m) numbers)))
2481             (real (push (ctype-of m) numbers))
2482            (character (push (sb!xc:char-code m) char-codes))
2483             (t (push m ms))))
2484         (apply #'type-union
2485                (if ms
2486                    (make-member-type :members ms)
2487                    *empty-type*)
2488               (if char-codes
2489                   (make-character-set-type
2490                    :pairs (mapcar (lambda (x) (cons x x))
2491                                   (sort char-codes #'<)))
2492                   *empty-type*)
2493                (nreverse numbers)))
2494       *empty-type*))
2495 \f
2496 ;;;; intersection types
2497 ;;;;
2498 ;;;; Until version 0.6.10.6, SBCL followed the original CMU CL approach
2499 ;;;; of punting on all AND types, not just the unreasonably complicated
2500 ;;;; ones. The change was motivated by trying to get the KEYWORD type
2501 ;;;; to behave sensibly:
2502 ;;;;    ;; reasonable definition
2503 ;;;;    (DEFTYPE KEYWORD () '(AND SYMBOL (SATISFIES KEYWORDP)))
2504 ;;;;    ;; reasonable behavior
2505 ;;;;    (AVER (SUBTYPEP 'KEYWORD 'SYMBOL))
2506 ;;;; Without understanding a little about the semantics of AND, we'd
2507 ;;;; get (SUBTYPEP 'KEYWORD 'SYMBOL)=>NIL,NIL and, for entirely
2508 ;;;; parallel reasons, (SUBTYPEP 'RATIO 'NUMBER)=>NIL,NIL. That's
2509 ;;;; not so good..)
2510 ;;;;
2511 ;;;; We still follow the example of CMU CL to some extent, by punting
2512 ;;;; (to the opaque HAIRY-TYPE) on sufficiently complicated types
2513 ;;;; involving AND.
2514
2515 (!define-type-class intersection)
2516
2517 (!define-type-method (intersection :negate) (type)
2518   (apply #'type-union
2519          (mapcar #'type-negation (intersection-type-types type))))
2520
2521 ;;; A few intersection types have special names. The others just get
2522 ;;; mechanically unparsed.
2523 (!define-type-method (intersection :unparse) (type)
2524   (declare (type ctype type))
2525   (or (find type '(ratio keyword) :key #'specifier-type :test #'type=)
2526       `(and ,@(mapcar #'type-specifier (intersection-type-types type)))))
2527
2528 ;;; shared machinery for type equality: true if every type in the set
2529 ;;; TYPES1 matches a type in the set TYPES2 and vice versa
2530 (defun type=-set (types1 types2)
2531   (flet ((type<=-set (x y)
2532            (declare (type list x y))
2533            (every/type (lambda (x y-element)
2534                          (any/type #'type= y-element x))
2535                        x y)))
2536     (and/type (type<=-set types1 types2)
2537               (type<=-set types2 types1))))
2538
2539 ;;; Two intersection types are equal if their subtypes are equal sets.
2540 ;;;
2541 ;;; FIXME: Might it be better to use
2542 ;;;   (AND (SUBTYPEP X Y) (SUBTYPEP Y X))
2543 ;;; instead, since SUBTYPEP is the usual relationship that we care
2544 ;;; most about, so it would be good to leverage any ingenuity there
2545 ;;; in this more obscure method?
2546 (!define-type-method (intersection :simple-=) (type1 type2)
2547   (type=-set (intersection-type-types type1)
2548              (intersection-type-types type2)))
2549
2550 (defun %intersection-complex-subtypep-arg1 (type1 type2)
2551   (type= type1 (type-intersection type1 type2)))
2552
2553 (defun %intersection-simple-subtypep (type1 type2)
2554   (every/type #'%intersection-complex-subtypep-arg1
2555               type1
2556               (intersection-type-types type2)))
2557
2558 (!define-type-method (intersection :simple-subtypep) (type1 type2)
2559   (%intersection-simple-subtypep type1 type2))
2560
2561 (!define-type-method (intersection :complex-subtypep-arg1) (type1 type2)
2562   (%intersection-complex-subtypep-arg1 type1 type2))
2563
2564 (defun %intersection-complex-subtypep-arg2 (type1 type2)
2565   (every/type #'csubtypep type1 (intersection-type-types type2)))
2566
2567 (!define-type-method (intersection :complex-subtypep-arg2) (type1 type2)
2568   (%intersection-complex-subtypep-arg2 type1 type2))
2569
2570 ;;; FIXME: This will look eeriely familiar to readers of the UNION
2571 ;;; :SIMPLE-INTERSECTION2 :COMPLEX-INTERSECTION2 method.  That's
2572 ;;; because it was generated by cut'n'paste methods.  Given that
2573 ;;; intersections and unions have all sorts of symmetries known to
2574 ;;; mathematics, it shouldn't be beyond the ken of some programmers to
2575 ;;; reflect those symmetries in code in a way that ties them together
2576 ;;; more strongly than having two independent near-copies :-/
2577 (!define-type-method (intersection :simple-union2 :complex-union2)
2578                      (type1 type2)
2579   ;; Within this method, type2 is guaranteed to be an intersection
2580   ;; type:
2581   (aver (intersection-type-p type2))
2582   ;; Make sure to call only the applicable methods...
2583   (cond ((and (intersection-type-p type1)
2584               (%intersection-simple-subtypep type1 type2)) type2)
2585         ((and (intersection-type-p type1)
2586               (%intersection-simple-subtypep type2 type1)) type1)
2587         ((and (not (intersection-type-p type1))
2588               (%intersection-complex-subtypep-arg2 type1 type2))
2589          type2)
2590         ((and (not (intersection-type-p type1))
2591               (%intersection-complex-subtypep-arg1 type2 type1))
2592          type1)
2593         ;; KLUDGE: This special (and somewhat hairy) magic is required
2594         ;; to deal with the RATIONAL/INTEGER special case.  The UNION
2595         ;; of (INTEGER * -1) and (AND (RATIONAL * -1/2) (NOT INTEGER))
2596         ;; should be (RATIONAL * -1/2) -- CSR, 2003-02-28
2597         ((and (csubtypep type2 (specifier-type 'ratio))
2598               (numeric-type-p type1)
2599               (csubtypep type1 (specifier-type 'integer))
2600               (csubtypep type2
2601                          (make-numeric-type
2602                           :class 'rational
2603                           :complexp nil
2604                           :low (if (null (numeric-type-low type1))
2605                                    nil
2606                                    (list (1- (numeric-type-low type1))))
2607                           :high (if (null (numeric-type-high type1))
2608                                     nil
2609                                     (list (1+ (numeric-type-high type1)))))))
2610          (type-union type1
2611                      (apply #'type-intersection
2612                             (remove (specifier-type '(not integer))
2613                                     (intersection-type-types type2)
2614                                     :test #'type=))))
2615         (t
2616          (let ((accumulator *universal-type*))
2617            (do ((t2s (intersection-type-types type2) (cdr t2s)))
2618                ((null t2s) accumulator)
2619              (let ((union (type-union type1 (car t2s))))
2620                (when (union-type-p union)
2621                  ;; we have to give up here -- there are all sorts of
2622                  ;; ordering worries, but it's better than before.
2623                  ;; Doing exactly the same as in the UNION
2624                  ;; :SIMPLE/:COMPLEX-INTERSECTION2 method causes stack
2625                  ;; overflow with the mutual recursion never bottoming
2626                  ;; out.
2627                  (if (and (eq accumulator *universal-type*)
2628                           (null (cdr t2s)))
2629                      ;; KLUDGE: if we get here, we have a partially
2630                      ;; simplified result.  While this isn't by any
2631                      ;; means a universal simplification, including
2632                      ;; this logic here means that we can get (OR
2633                      ;; KEYWORD (NOT KEYWORD)) canonicalized to T.
2634                      (return union)
2635                      (return nil)))
2636                (setf accumulator
2637                      (type-intersection accumulator union))))))))
2638
2639 (!def-type-translator and (&whole whole &rest type-specifiers)
2640   (apply #'type-intersection
2641          (mapcar #'specifier-type type-specifiers)))
2642 \f
2643 ;;;; union types
2644
2645 (!define-type-class union)
2646
2647 (!define-type-method (union :negate) (type)
2648   (declare (type ctype type))
2649   (apply #'type-intersection
2650          (mapcar #'type-negation (union-type-types type))))
2651
2652 ;;; The LIST, FLOAT and REAL types have special names.  Other union
2653 ;;; types just get mechanically unparsed.
2654 (!define-type-method (union :unparse) (type)
2655   (declare (type ctype type))
2656   (cond
2657     ((type= type (specifier-type 'list)) 'list)
2658     ((type= type (specifier-type 'float)) 'float)
2659     ((type= type (specifier-type 'real)) 'real)
2660     ((type= type (specifier-type 'sequence)) 'sequence)
2661     ((type= type (specifier-type 'bignum)) 'bignum)
2662     ((type= type (specifier-type 'simple-string)) 'simple-string)
2663     ((type= type (specifier-type 'string)) 'string)
2664     ((type= type (specifier-type 'complex)) 'complex)
2665     ((type= type (specifier-type 'standard-char)) 'standard-char)
2666     (t `(or ,@(mapcar #'type-specifier (union-type-types type))))))
2667
2668 ;;; Two union types are equal if they are each subtypes of each
2669 ;;; other. We need to be this clever because our complex subtypep
2670 ;;; methods are now more accurate; we don't get infinite recursion
2671 ;;; because the simple-subtypep method delegates to complex-subtypep
2672 ;;; of the individual types of type1. - CSR, 2002-04-09
2673 ;;;
2674 ;;; Previous comment, now obsolete, but worth keeping around because
2675 ;;; it is true, though too strong a condition:
2676 ;;;
2677 ;;; Two union types are equal if their subtypes are equal sets.
2678 (!define-type-method (union :simple-=) (type1 type2)
2679   (multiple-value-bind (subtype certain?)
2680       (csubtypep type1 type2)
2681     (if subtype
2682         (csubtypep type2 type1)
2683         ;; we might as well become as certain as possible.
2684         (if certain?
2685             (values nil t)
2686             (multiple-value-bind (subtype certain?)
2687                 (csubtypep type2 type1)
2688               (declare (ignore subtype))
2689               (values nil certain?))))))
2690
2691 (!define-type-method (union :complex-=) (type1 type2)
2692   (declare (ignore type1))
2693   (if (some #'type-might-contain-other-types-p
2694             (union-type-types type2))
2695       (values nil nil)
2696       (values nil t)))
2697
2698 ;;; Similarly, a union type is a subtype of another if and only if
2699 ;;; every element of TYPE1 is a subtype of TYPE2.
2700 (defun union-simple-subtypep (type1 type2)
2701   (every/type (swapped-args-fun #'union-complex-subtypep-arg2)
2702               type2
2703               (union-type-types type1)))
2704
2705 (!define-type-method (union :simple-subtypep) (type1 type2)
2706   (union-simple-subtypep type1 type2))
2707
2708 (defun union-complex-subtypep-arg1 (type1 type2)
2709   (every/type (swapped-args-fun #'csubtypep)
2710               type2
2711               (union-type-types type1)))
2712
2713 (!define-type-method (union :complex-subtypep-arg1) (type1 type2)
2714   (union-complex-subtypep-arg1 type1 type2))
2715
2716 (defun union-complex-subtypep-arg2 (type1 type2)
2717   (multiple-value-bind (sub-value sub-certain?)
2718       ;; was: (any/type #'csubtypep type1 (union-type-types type2)),
2719       ;; which turns out to be too restrictive, causing bug 91.
2720       ;;
2721       ;; the following reimplementation might look dodgy.  It is
2722       ;; dodgy. It depends on the union :complex-= method not doing
2723       ;; very much work -- certainly, not using subtypep. Reasoning:
2724       (progn
2725         ;; At this stage, we know that type2 is a union type and type1
2726         ;; isn't. We might as well check this, though:
2727         (aver (union-type-p type2))
2728         (aver (not (union-type-p type1)))
2729         ;;     A is a subset of (B1 u B2)
2730         ;; <=> A n (B1 u B2) = A
2731         ;; <=> (A n B1) u (A n B2) = A
2732         ;;
2733         ;; But, we have to be careful not to delegate this type= to
2734         ;; something that could invoke subtypep, which might get us
2735         ;; back here -> stack explosion. We therefore ensure that the
2736         ;; second type (which is the one that's dispatched on) is
2737         ;; either a union type (where we've ensured that the complex-=
2738         ;; method will not call subtypep) or something with no union
2739         ;; types involved, in which case we'll never come back here.
2740         ;;
2741         ;; If we don't do this, then e.g.
2742         ;; (SUBTYPEP '(MEMBER 3) '(OR (SATISFIES FOO) (SATISFIES BAR)))
2743         ;; would loop infinitely, as the member :complex-= method is
2744         ;; implemented in terms of subtypep.
2745         ;;
2746         ;; Ouch. - CSR, 2002-04-10
2747         (type= type1
2748                (apply #'type-union
2749                       (mapcar (lambda (x) (type-intersection type1 x))
2750                               (union-type-types type2)))))
2751     (if sub-certain?
2752         (values sub-value sub-certain?)
2753         ;; The ANY/TYPE expression above is a sufficient condition for
2754         ;; subsetness, but not a necessary one, so we might get a more
2755         ;; certain answer by this CALL-NEXT-METHOD-ish step when the
2756         ;; ANY/TYPE expression is uncertain.
2757         (invoke-complex-subtypep-arg1-method type1 type2))))
2758
2759 (!define-type-method (union :complex-subtypep-arg2) (type1 type2)
2760   (union-complex-subtypep-arg2 type1 type2))
2761
2762 (!define-type-method (union :simple-intersection2 :complex-intersection2)
2763                      (type1 type2)
2764   ;; The CSUBTYPEP clauses here let us simplify e.g.
2765   ;;   (TYPE-INTERSECTION2 (SPECIFIER-TYPE 'LIST)
2766   ;;                       (SPECIFIER-TYPE '(OR LIST VECTOR)))
2767   ;; (where LIST is (OR CONS NULL)).
2768   ;;
2769   ;; The tests are more or less (CSUBTYPEP TYPE1 TYPE2) and vice
2770   ;; versa, but it's important that we pre-expand them into
2771   ;; specialized operations on individual elements of
2772   ;; UNION-TYPE-TYPES, instead of using the ordinary call to
2773   ;; CSUBTYPEP, in order to avoid possibly invoking any methods which
2774   ;; might in turn invoke (TYPE-INTERSECTION2 TYPE1 TYPE2) and thus
2775   ;; cause infinite recursion.
2776   ;;
2777   ;; Within this method, type2 is guaranteed to be a union type:
2778   (aver (union-type-p type2))
2779   ;; Make sure to call only the applicable methods...
2780   (cond ((and (union-type-p type1)
2781               (union-simple-subtypep type1 type2)) type1)
2782         ((and (union-type-p type1)
2783               (union-simple-subtypep type2 type1)) type2)
2784         ((and (not (union-type-p type1))
2785               (union-complex-subtypep-arg2 type1 type2))
2786          type1)
2787         ((and (not (union-type-p type1))
2788               (union-complex-subtypep-arg1 type2 type1))
2789          type2)
2790         (t
2791          ;; KLUDGE: This code accumulates a sequence of TYPE-UNION2
2792          ;; operations in a particular order, and gives up if any of
2793          ;; the sub-unions turn out not to be simple. In other cases
2794          ;; ca. sbcl-0.6.11.15, that approach to taking a union was a
2795          ;; bad idea, since it can overlook simplifications which
2796          ;; might occur if the terms were accumulated in a different
2797          ;; order. It's possible that that will be a problem here too.
2798          ;; However, I can't think of a good example to demonstrate
2799          ;; it, and without an example to demonstrate it I can't write
2800          ;; test cases, and without test cases I don't want to
2801          ;; complicate the code to address what's still a hypothetical
2802          ;; problem. So I punted. -- WHN 2001-03-20
2803          (let ((accumulator *empty-type*))
2804            (dolist (t2 (union-type-types type2) accumulator)
2805              (setf accumulator
2806                    (type-union accumulator
2807                                (type-intersection type1 t2))))))))
2808
2809 (!def-type-translator or (&rest type-specifiers)
2810   (apply #'type-union
2811          (mapcar #'specifier-type
2812                  type-specifiers)))
2813 \f
2814 ;;;; CONS types
2815
2816 (!define-type-class cons)
2817
2818 (!def-type-translator cons (&optional (car-type-spec '*) (cdr-type-spec '*))
2819   (let ((car-type (single-value-specifier-type car-type-spec))
2820         (cdr-type (single-value-specifier-type cdr-type-spec)))
2821     (make-cons-type car-type cdr-type)))
2822
2823 (!define-type-method (cons :negate) (type)
2824   (if (and (eq (cons-type-car-type type) *universal-type*)
2825            (eq (cons-type-cdr-type type) *universal-type*))
2826       (make-negation-type :type type)
2827       (type-union
2828        (make-negation-type :type (specifier-type 'cons))
2829        (cond
2830          ((and (not (eq (cons-type-car-type type) *universal-type*))
2831                (not (eq (cons-type-cdr-type type) *universal-type*)))
2832           (type-union
2833            (make-cons-type
2834             (type-negation (cons-type-car-type type))
2835             *universal-type*)
2836            (make-cons-type
2837             *universal-type*
2838             (type-negation (cons-type-cdr-type type)))))
2839          ((not (eq (cons-type-car-type type) *universal-type*))
2840           (make-cons-type
2841            (type-negation (cons-type-car-type type))
2842            *universal-type*))
2843          ((not (eq (cons-type-cdr-type type) *universal-type*))
2844           (make-cons-type
2845            *universal-type*
2846            (type-negation (cons-type-cdr-type type))))
2847          (t (bug "Weird CONS type ~S" type))))))
2848
2849 (!define-type-method (cons :unparse) (type)
2850   (let ((car-eltype (type-specifier (cons-type-car-type type)))
2851         (cdr-eltype (type-specifier (cons-type-cdr-type type))))
2852     (if (and (member car-eltype '(t *))
2853              (member cdr-eltype '(t *)))
2854         'cons
2855         `(cons ,car-eltype ,cdr-eltype))))
2856
2857 (!define-type-method (cons :simple-=) (type1 type2)
2858   (declare (type cons-type type1 type2))
2859   (and (type= (cons-type-car-type type1) (cons-type-car-type type2))
2860        (type= (cons-type-cdr-type type1) (cons-type-cdr-type type2))))
2861
2862 (!define-type-method (cons :simple-subtypep) (type1 type2)
2863   (declare (type cons-type type1 type2))
2864   (multiple-value-bind (val-car win-car)
2865       (csubtypep (cons-type-car-type type1) (cons-type-car-type type2))
2866     (multiple-value-bind (val-cdr win-cdr)
2867         (csubtypep (cons-type-cdr-type type1) (cons-type-cdr-type type2))
2868       (if (and val-car val-cdr)
2869           (values t (and win-car win-cdr))
2870           (values nil (or (and (not val-car) win-car)
2871                           (and (not val-cdr) win-cdr)))))))
2872
2873 ;;; Give up if a precise type is not possible, to avoid returning
2874 ;;; overly general types.
2875 (!define-type-method (cons :simple-union2) (type1 type2)
2876   (declare (type cons-type type1 type2))
2877   (let ((car-type1 (cons-type-car-type type1))
2878         (car-type2 (cons-type-car-type type2))
2879         (cdr-type1 (cons-type-cdr-type type1))
2880         (cdr-type2 (cons-type-cdr-type type2))
2881         car-not1
2882         car-not2)
2883     ;; UGH.  -- CSR, 2003-02-24
2884     (macrolet ((frob-car (car1 car2 cdr1 cdr2
2885                           &optional (not1 nil not1p))
2886                  `(type-union
2887                    (make-cons-type ,car1 (type-union ,cdr1 ,cdr2))
2888                    (make-cons-type
2889                     (type-intersection ,car2
2890                      ,(if not1p
2891                           not1
2892                           `(type-negation ,car1)))
2893                     ,cdr2))))
2894       (cond ((type= car-type1 car-type2)
2895              (make-cons-type car-type1
2896                              (type-union cdr-type1 cdr-type2)))
2897             ((type= cdr-type1 cdr-type2)
2898              (make-cons-type (type-union car-type1 car-type2)
2899                              cdr-type1))
2900             ((csubtypep car-type1 car-type2)
2901              (frob-car car-type1 car-type2 cdr-type1 cdr-type2))
2902             ((csubtypep car-type2 car-type1)
2903              (frob-car car-type2 car-type1 cdr-type2 cdr-type1))
2904             ;; more general case of the above, but harder to compute
2905             ((progn
2906                (setf car-not1 (type-negation car-type1))
2907                (not (csubtypep car-type2 car-not1)))
2908              (frob-car car-type1 car-type2 cdr-type1 cdr-type2 car-not1))
2909             ((progn
2910                (setf car-not2 (type-negation car-type2))
2911                (not (csubtypep car-type1 car-not2)))
2912              (frob-car car-type2 car-type1 cdr-type2 cdr-type1 car-not2))
2913             ;; Don't put these in -- consider the effect of taking the
2914             ;; union of (CONS (INTEGER 0 2) (INTEGER 5 7)) and
2915             ;; (CONS (INTEGER 0 3) (INTEGER 5 6)).
2916             #+nil
2917             ((csubtypep cdr-type1 cdr-type2)
2918              (frob-cdr car-type1 car-type2 cdr-type1 cdr-type2))
2919             #+nil
2920             ((csubtypep cdr-type2 cdr-type1)
2921              (frob-cdr car-type2 car-type1 cdr-type2 cdr-type1))))))
2922
2923 (!define-type-method (cons :simple-intersection2) (type1 type2)
2924   (declare (type cons-type type1 type2))
2925   (let ((car-int2 (type-intersection2 (cons-type-car-type type1)
2926                                       (cons-type-car-type type2)))
2927         (cdr-int2 (type-intersection2 (cons-type-cdr-type type1)
2928                                       (cons-type-cdr-type type2))))
2929     (cond
2930       ((and car-int2 cdr-int2) (make-cons-type car-int2 cdr-int2))
2931       (car-int2 (make-cons-type car-int2
2932                                 (type-intersection
2933                                  (cons-type-cdr-type type1)
2934                                  (cons-type-cdr-type type2))))
2935       (cdr-int2 (make-cons-type
2936                  (type-intersection (cons-type-car-type type1)
2937                                     (cons-type-car-type type2))
2938                  cdr-int2)))))
2939 \f
2940 ;;;; CHARACTER-SET types
2941
2942 (!define-type-class character-set)
2943
2944 (!def-type-translator character-set
2945     (&optional (pairs '((0 . #.(1- sb!xc:char-code-limit)))))
2946   (make-character-set-type :pairs pairs))
2947
2948 (!define-type-method (character-set :negate) (type)
2949   (let ((pairs (character-set-type-pairs type)))
2950     (if (and (= (length pairs) 1)
2951             (= (caar pairs) 0)
2952             (= (cdar pairs) (1- sb!xc:char-code-limit)))
2953        (make-negation-type :type type)
2954        (let ((not-character
2955               (make-negation-type
2956                :type (make-character-set-type
2957                       :pairs '((0 . #.(1- sb!xc:char-code-limit)))))))
2958          (type-union
2959           not-character
2960           (make-character-set-type
2961            :pairs (let (not-pairs)
2962                     (when (> (caar pairs) 0)
2963                       (push (cons 0 (1- (caar pairs))) not-pairs))
2964                     (do* ((tail pairs (cdr tail))
2965                           (high1 (cdar tail))
2966                           (low2 (caadr tail)))
2967                          ((null (cdr tail))
2968                           (when (< (cdar tail) (1- sb!xc:char-code-limit))
2969                             (push (cons (1+ (cdar tail))
2970                                         (1- sb!xc:char-code-limit))
2971                                   not-pairs))
2972                           (nreverse not-pairs))
2973                       (push (cons (1+ high1) (1- low2)) not-pairs)))))))))
2974
2975 (!define-type-method (character-set :unparse) (type)
2976   (cond
2977     ((type= type (specifier-type 'character)) 'character)
2978     ((type= type (specifier-type 'base-char)) 'base-char)
2979     ((type= type (specifier-type 'extended-char)) 'extended-char)
2980     ((type= type (specifier-type 'standard-char)) 'standard-char)
2981     (t (let ((pairs (character-set-type-pairs type)))
2982         `(member ,@(loop for (low . high) in pairs
2983                          nconc (loop for code from low upto high
2984                                      collect (sb!xc:code-char code))))))))
2985
2986 (!define-type-method (character-set :simple-=) (type1 type2)
2987   (let ((pairs1 (character-set-type-pairs type1))
2988        (pairs2 (character-set-type-pairs type2)))
2989     (values (equal pairs1 pairs2) t)))
2990
2991 (!define-type-method (character-set :simple-subtypep) (type1 type2)
2992   (values
2993    (dolist (pair (character-set-type-pairs type1) t)
2994      (unless (position pair (character-set-type-pairs type2)
2995                       :test (lambda (x y) (and (>= (car x) (car y))
2996                                                (<= (cdr x) (cdr y)))))
2997        (return nil)))
2998    t))
2999
3000 (!define-type-method (character-set :simple-union2) (type1 type2)
3001   ;; KLUDGE: the canonizing in the MAKE-CHARACTER-SET-TYPE function
3002   ;; actually does the union for us.  It might be a little fragile to
3003   ;; rely on it.
3004   (make-character-set-type
3005    :pairs (merge 'list
3006                 (copy-alist (character-set-type-pairs type1))
3007                 (copy-alist (character-set-type-pairs type2))
3008                 #'< :key #'car)))
3009
3010 (!define-type-method (character-set :simple-intersection2) (type1 type2)
3011   ;; KLUDGE: brute force.
3012 #|
3013   (let (pairs)
3014     (dolist (pair1 (character-set-type-pairs type1)
3015             (make-character-set-type
3016              :pairs (sort pairs #'< :key #'car)))
3017       (dolist (pair2 (character-set-type-pairs type2))
3018        (cond
3019          ((<= (car pair1) (car pair2) (cdr pair1))
3020           (push (cons (car pair2) (min (cdr pair1) (cdr pair2))) pairs))
3021          ((<= (car pair2) (car pair1) (cdr pair2))
3022           (push (cons (car pair1) (min (cdr pair1) (cdr pair2))) pairs))))))
3023 |#
3024   (make-character-set-type
3025    :pairs (intersect-type-pairs
3026            (character-set-type-pairs type1)
3027            (character-set-type-pairs type2))))
3028
3029 ;;;
3030 ;;; Intersect two ordered lists of pairs
3031 ;;; Each list is of the form ((start1 . end1) ... (startn . endn)),
3032 ;;; where start1 <= end1 < start2 <= end2 < ... < startn <= endn.
3033 ;;; Each pair represents the integer interval start..end.
3034 ;;;
3035 (defun intersect-type-pairs (alist1 alist2)
3036   (if (and alist1 alist2)
3037       (let ((res nil)
3038             (pair1 (pop alist1))
3039             (pair2 (pop alist2)))
3040         (loop
3041          (when (> (car pair1) (car pair2))
3042            (rotatef pair1 pair2)
3043            (rotatef alist1 alist2))
3044          (let ((pair1-cdr (cdr pair1)))
3045            (cond
3046             ((> (car pair2) pair1-cdr)
3047              ;; No over lap -- discard pair1
3048              (unless alist1 (return))
3049              (setq pair1 (pop alist1)))
3050             ((<= (cdr pair2) pair1-cdr)
3051              (push (cons (car pair2) (cdr pair2)) res)
3052              (cond
3053               ((= (cdr pair2) pair1-cdr)
3054                (unless alist1 (return))
3055                (unless alist2 (return))
3056                (setq pair1 (pop alist1)
3057                      pair2 (pop alist2)))
3058               (t ;; (< (cdr pair2) pair1-cdr)
3059                (unless alist2 (return))
3060                (setq pair1 (cons (1+ (cdr pair2)) pair1-cdr))
3061                (setq pair2 (pop alist2)))))
3062             (t ;; (> (cdr pair2) (cdr pair1))
3063              (push (cons (car pair2) pair1-cdr) res)
3064              (unless alist1 (return))
3065              (setq pair2 (cons (1+ pair1-cdr) (cdr pair2)))
3066              (setq pair1 (pop alist1))))))
3067         (nreverse res))
3068     nil))
3069
3070 \f
3071 ;;; Return the type that describes all objects that are in X but not
3072 ;;; in Y. If we can't determine this type, then return NIL.
3073 ;;;
3074 ;;; For now, we only are clever dealing with union and member types.
3075 ;;; If either type is not a union type, then we pretend that it is a
3076 ;;; union of just one type. What we do is remove from X all the types
3077 ;;; that are a subtype any type in Y. If any type in X intersects with
3078 ;;; a type in Y but is not a subtype, then we give up.
3079 ;;;
3080 ;;; We must also special-case any member type that appears in the
3081 ;;; union. We remove from X's members all objects that are TYPEP to Y.
3082 ;;; If Y has any members, we must be careful that none of those
3083 ;;; members are CTYPEP to any of Y's non-member types. We give up in
3084 ;;; this case, since to compute that difference we would have to break
3085 ;;; the type from X into some collection of types that represents the
3086 ;;; type without that particular element. This seems too hairy to be
3087 ;;; worthwhile, given its low utility.
3088 (defun type-difference (x y)
3089   (let ((x-types (if (union-type-p x) (union-type-types x) (list x)))
3090         (y-types (if (union-type-p y) (union-type-types y) (list y))))
3091     (collect ((res))
3092       (dolist (x-type x-types)
3093         (if (member-type-p x-type)
3094             (collect ((members))
3095               (dolist (mem (member-type-members x-type))
3096                 (multiple-value-bind (val win) (ctypep mem y)
3097                   (unless win (return-from type-difference nil))
3098                   (unless val
3099                     (members mem))))
3100               (when (members)
3101                 (res (make-member-type :members (members)))))
3102             (dolist (y-type y-types (res x-type))
3103               (multiple-value-bind (val win) (csubtypep x-type y-type)
3104                 (unless win (return-from type-difference nil))
3105                 (when val (return))
3106                 (when (types-equal-or-intersect x-type y-type)
3107                   (return-from type-difference nil))))))
3108       (let ((y-mem (find-if #'member-type-p y-types)))
3109         (when y-mem
3110           (let ((members (member-type-members y-mem)))
3111             (dolist (x-type x-types)
3112               (unless (member-type-p x-type)
3113                 (dolist (member members)
3114                   (multiple-value-bind (val win) (ctypep member x-type)
3115                     (when (or (not win) val)
3116                       (return-from type-difference nil)))))))))
3117       (apply #'type-union (res)))))
3118 \f
3119 (!def-type-translator array (&optional (element-type '*)
3120                                        (dimensions '*))
3121   (specialize-array-type
3122    (make-array-type :dimensions (canonical-array-dimensions dimensions)
3123                     :complexp :maybe
3124                     :element-type (if (eq element-type '*)
3125                                       *wild-type*
3126                                       (specifier-type element-type)))))
3127
3128 (!def-type-translator simple-array (&optional (element-type '*)
3129                                               (dimensions '*))
3130   (specialize-array-type
3131    (make-array-type :dimensions (canonical-array-dimensions dimensions)
3132                     :complexp nil
3133                     :element-type (if (eq element-type '*)
3134                                       *wild-type*
3135                                       (specifier-type element-type)))))
3136 \f
3137 ;;;; utilities shared between cross-compiler and target system
3138
3139 ;;; Does the type derived from compilation of an actual function
3140 ;;; definition satisfy declarations of a function's type?
3141 (defun defined-ftype-matches-declared-ftype-p (defined-ftype declared-ftype)
3142   (declare (type ctype defined-ftype declared-ftype))
3143   (flet ((is-built-in-class-function-p (ctype)
3144            (and (built-in-classoid-p ctype)
3145                 (eq (built-in-classoid-name ctype) 'function))))
3146     (cond (;; DECLARED-FTYPE could certainly be #<BUILT-IN-CLASS FUNCTION>;
3147            ;; that's what happens when we (DECLAIM (FTYPE FUNCTION FOO)).
3148            (is-built-in-class-function-p declared-ftype)
3149            ;; In that case, any definition satisfies the declaration.
3150            t)
3151           (;; It's not clear whether or how DEFINED-FTYPE might be
3152            ;; #<BUILT-IN-CLASS FUNCTION>, but it's not obviously
3153            ;; invalid, so let's handle that case too, just in case.
3154            (is-built-in-class-function-p defined-ftype)
3155            ;; No matter what DECLARED-FTYPE might be, we can't prove
3156            ;; that an object of type FUNCTION doesn't satisfy it, so
3157            ;; we return success no matter what.
3158            t)
3159           (;; Otherwise both of them must be FUN-TYPE objects.
3160            t
3161            ;; FIXME: For now we only check compatibility of the return
3162            ;; type, not argument types, and we don't even check the
3163            ;; return type very precisely (as per bug 94a). It would be
3164            ;; good to do a better job. Perhaps to check the
3165            ;; compatibility of the arguments, we should (1) redo
3166            ;; VALUES-TYPES-EQUAL-OR-INTERSECT as
3167            ;; ARGS-TYPES-EQUAL-OR-INTERSECT, and then (2) apply it to
3168            ;; the ARGS-TYPE slices of the FUN-TYPEs. (ARGS-TYPE
3169            ;; is a base class both of VALUES-TYPE and of FUN-TYPE.)
3170            (values-types-equal-or-intersect
3171             (fun-type-returns defined-ftype)
3172             (fun-type-returns declared-ftype))))))
3173
3174 ;;; This messy case of CTYPE for NUMBER is shared between the
3175 ;;; cross-compiler and the target system.
3176 (defun ctype-of-number (x)
3177   (let ((num (if (complexp x) (realpart x) x)))
3178     (multiple-value-bind (complexp low high)
3179         (if (complexp x)
3180             (let ((imag (imagpart x)))
3181               (values :complex (min num imag) (max num imag)))
3182             (values :real num num))
3183       (make-numeric-type :class (etypecase num
3184                                   (integer (if (complexp x)
3185                                                (if (integerp (imagpart x))
3186                                                    'integer
3187                                                    'rational)
3188                                                'integer))
3189                                   (rational 'rational)
3190                                   (float 'float))
3191                          :format (and (floatp num) (float-format-name num))
3192                          :complexp complexp
3193                          :low low
3194                          :high high))))
3195 \f
3196 (locally
3197   ;; Why SAFETY 0? To suppress the is-it-the-right-structure-type
3198   ;; checking for declarations in structure accessors. Otherwise we
3199   ;; can get caught in a chicken-and-egg bootstrapping problem, whose
3200   ;; symptom on x86 OpenBSD sbcl-0.pre7.37.flaky5.22 is an illegal
3201   ;; instruction trap. I haven't tracked it down, but I'm guessing it
3202   ;; has to do with setting LAYOUTs when the LAYOUT hasn't been set
3203   ;; yet. -- WHN
3204   (declare (optimize (safety 0)))
3205   (!defun-from-collected-cold-init-forms !late-type-cold-init))
3206
3207 (/show0 "late-type.lisp end of file")