src/code/load.lisp

   1 ;;;; parts of the loader which make sense in the cross-compilation
   2 ;;;; host (and which are useful in the host, because they're used by
   3 ;;;; GENESIS)
   4 ;;;;
   5 ;;;; based on the CMU CL load.lisp code, written by Skef Wholey and
   6 ;;;; Rob Maclachlan
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!IMPL")
  18 \f
  19 ;;;; variables
  20
  21 ;;; FIXME: It's awkward having LOAD stuff in SB!IMPL and dump stuff in
  22 ;;; SB!C. Among other things, it makes it hard to figure out where
  23 ;;; *FASL-HEADER-STRING-START-STRING* and
  24 ;;; *FASL-HEADER-STRING-STOP-CHAR-CODE* should go. Perhaps we should
  25 ;;; make a package called SB-DUMP or SB-LD which includes all
  26 ;;; knowledge of both loading and dumping.
  27
  28 ;;; This value is used to identify fasl files. Even though this is not
  29 ;;; declared as a constant (because ANSI Common Lisp has no facility
  30 ;;; for declaring values which are constant under EQUAL but not EQL),
  31 ;;; obviously you shouldn't mess with it lightly. If you do set a new
  32 ;;; value for some reason, keep these things in mind:
  33 ;;; * To avoid confusion with the similar but incompatible CMU CL
  34 ;;;   fasl file format, the value should not be "FASL FILE", which
  35 ;;;   is what CMU CL used for the same purpose.
  36 ;;; * Since its presence at the head of a file is used by LOAD to
  37 ;;;   decide whether a file is to be fasloaded or sloloaded, the value
  38 ;;;   should be something which can't legally appear at the head of a
  39 ;;;   Lisp source file.
  40 ;;; * The value should not contain any line-terminating characters,
  41 ;;;   because they're hard to express portably and because the LOAD
  42 ;;;   code might reasonably use READ-LINE to get the value to compare
  43 ;;;   against.
  44 (defparameter sb!c:*fasl-header-string-start-string* "# FASL"
  45   #!+sb-doc
  46   "a string which appears at the start of a fasl file header")
  47
  48 (defparameter sb!c:*fasl-header-string-stop-char-code* 255
  49   #!+sb-doc
  50   "the code for a character which terminates a fasl file header")
  51
  52 (defvar *load-depth* 0
  53   #!+sb-doc
  54   "the current number of recursive loads")
  55 (declaim (type index *load-depth*))
  56
  57 ;;; the FASL file we're reading from
  58 (defvar *fasl-file*)
  59 (declaim (type lisp-stream *fasl-file*))
  60
  61 (defvar *load-print* nil
  62   #!+sb-doc
  63   "the default for the :PRINT argument to LOAD")
  64 (defvar *load-verbose* nil
  65   ;; Note that CMU CL's default for this was T, and ANSI says it's
  66   ;; implementation-dependent. We choose NIL on the theory that it's
  67   ;; a nicer default behavior for Unix programs.
  68   #!+sb-doc
  69   "the default for the :VERBOSE argument to LOAD")
  70 \f
  71 ;;;; miscellaneous load utilities
  72
  73 ;;; Output the current number of semicolons after a fresh-line.
  74 ;;; FIXME: non-mnemonic name
  75 (defun load-fresh-line ()
  76   (fresh-line)
  77   (let ((semicolons ";;;;;;;;;;;;;;;;"))
  78     (do ((count *load-depth* (- count (length semicolons))))
  79         ((< count (length semicolons))
  80          (write-string semicolons *standard-output* :end count))
  81       (declare (fixnum count))
  82       (write-string semicolons))
  83     (write-char #\space)))
  84
  85 ;;; If VERBOSE, output (to *STANDARD-OUTPUT*) a message about how we're
  86 ;;; loading from STREAM-WE-ARE-LOADING-FROM.
  87 ;;; FIXME: non-mnemonic name
  88 (defun do-load-verbose (stream-we-are-loading-from verbose)
  89   (when verbose
  90     (load-fresh-line)
  91     (let ((name #-sb-xc-host (file-name stream-we-are-loading-from)
  92                 #+sb-xc-host nil))
  93       (if name
  94           (format t "loading ~S~%" name)
  95           (format t "loading stuff from ~S~%" stream-we-are-loading-from)))))
  96 \f
  97 ;;;; utilities for reading from fasl files
  98
  99 #!-sb-fluid (declaim (inline read-byte))
 100
 101 ;;;    Expands into code to read an N-byte unsigned integer using
 102 ;;; fast-read-byte.
 103 (defmacro fast-read-u-integer (n)
 104   (declare (optimize (speed 0)))
 105   (do ((res '(fast-read-byte)
 106             `(logior (fast-read-byte)
 107                      (ash ,res 8)))
 108        (cnt 1 (1+ cnt)))
 109       ((>= cnt n) res)))
 110
 111 ;;; Like Fast-Read-U-Integer, but the size may be determined at run time.
 112 (defmacro fast-read-variable-u-integer (n)
 113   (let ((n-pos (gensym))
 114         (n-res (gensym))
 115         (n-cnt (gensym)))
 116     `(do ((,n-pos 8 (+ ,n-pos 8))
 117           (,n-cnt (1- ,n) (1- ,n-cnt))
 118           (,n-res
 119            (fast-read-byte)
 120            (dpb (fast-read-byte) (byte 8 ,n-pos) ,n-res)))
 121          ((zerop ,n-cnt) ,n-res)
 122        (declare (type index ,n-pos ,n-cnt)))))
 123
 124 ;;; Read a signed integer.
 125 (defmacro fast-read-s-integer (n)
 126   (declare (optimize (speed 0)))
 127   (let ((n-last (gensym)))
 128     (do ((res `(let ((,n-last (fast-read-byte)))
 129                  (if (zerop (logand ,n-last #x80))
 130                      ,n-last
 131                      (logior ,n-last #x-100)))
 132               `(logior (fast-read-byte)
 133                        (ash (the (signed-byte ,(* cnt 8)) ,res) 8)))
 134          (cnt 1 (1+ cnt)))
 135         ((>= cnt n) res))))
 136
 137 ;;; Read an N-byte unsigned integer from the *FASL-FILE*
 138 (defmacro read-arg (n)
 139   (declare (optimize (speed 0)))
 140   (if (= n 1)
 141       `(the (unsigned-byte 8) (read-byte *fasl-file*))
 142       `(prepare-for-fast-read-byte *fasl-file*
 143          (prog1
 144           (fast-read-u-integer ,n)
 145           (done-with-fast-read-byte)))))
 146 ;;; FIXME: This deserves a more descriptive name, and should probably
 147 ;;; be implemented as an ordinary function, not a macro.
 148 ;;;
 149 ;;; (for the names: There seem to be only two cases, so it could be
 150 ;;; named READ-U-INTEGER-8 and READ-U-INTEGER-32 or something.)
 151 \f
 152 ;;;; the fop table
 153
 154 ;;; The table is implemented as a simple-vector indexed by the table
 155 ;;; offset. We may need to have several, since LOAD can be called
 156 ;;; recursively.
 157
 158 (defvar *free-fop-tables* (list (make-array 1000))
 159   #!+sb-doc
 160   "List of free fop tables for the fasloader.")
 161
 162 ;;; the current fop table
 163 (defvar *current-fop-table*)
 164 (declaim (simple-vector *current-fop-table*))
 165
 166 ;;; the length of the current fop table
 167 (defvar *current-fop-table-size*)
 168 (declaim (type index *current-fop-table-size*))
 169
 170 ;;; the index in the fop-table of the next entry to be used
 171 (defvar *current-fop-table-index*)
 172 (declaim (type index *current-fop-table-index*))
 173
 174 (defun grow-fop-table ()
 175   (let* ((new-size (* *current-fop-table-size* 2))
 176          (new-table (make-array new-size)))
 177     (declare (fixnum new-size) (simple-vector new-table))
 178     (replace new-table (the simple-vector *current-fop-table*))
 179     (setq *current-fop-table* new-table)
 180     (setq *current-fop-table-size* new-size)))
 181
 182 (defmacro push-fop-table (thing)
 183   (let ((n-index (gensym)))
 184     `(let ((,n-index *current-fop-table-index*))
 185        (declare (fixnum ,n-index))
 186        (when (= ,n-index (the fixnum *current-fop-table-size*))
 187          (grow-fop-table))
 188        (setq *current-fop-table-index* (1+ ,n-index))
 189        (setf (svref *current-fop-table* ,n-index) ,thing))))
 190 \f
 191 ;;;; the fop stack
 192
 193 ;;; (This is in a SIMPLE-VECTOR, but it grows down, since it is
 194 ;;; somewhat cheaper to test for overflow that way.)
 195 (defvar *fop-stack* (make-array 100))
 196 (declaim (simple-vector *fop-stack*))
 197
 198 ;;; the index of the most recently pushed item on the fop stack
 199 (defvar *fop-stack-pointer* 100)
 200
 201 ;;; the current index into the fop stack when we last recursively
 202 ;;; entered LOAD
 203 (defvar *fop-stack-pointer-on-entry*)
 204 (declaim (type index *fop-stack-pointer* *fop-stack-pointer-on-entry*))
 205
 206 (defun grow-fop-stack ()
 207   (let* ((size (length (the simple-vector *fop-stack*)))
 208          (new-size (* size 2))
 209          (new-stack (make-array new-size)))
 210     (declare (fixnum size new-size) (simple-vector new-stack))
 211     (replace new-stack (the simple-vector *fop-stack*) :start1 size)
 212     (incf *fop-stack-pointer-on-entry* size)
 213     (setq *fop-stack-pointer* size)
 214     (setq *fop-stack* new-stack)))
 215
 216 ;;; Cache information about the fop stack in local variables. Define a
 217 ;;; local macro to pop from the stack. Push the result of evaluation
 218 ;;; if specified.
 219 (defmacro with-fop-stack (pushp &body forms)
 220   (aver (member pushp '(nil t :nope)))
 221   (let ((n-stack (gensym))
 222         (n-index (gensym))
 223         (n-res (gensym)))
 224     `(let ((,n-stack *fop-stack*)
 225            (,n-index *fop-stack-pointer*))
 226        (declare (simple-vector ,n-stack) (type index ,n-index))
 227        (macrolet ((pop-stack ()
 228                     `(prog1
 229                       (svref ,',n-stack ,',n-index)
 230                       (incf ,',n-index)))
 231                   (call-with-popped-things (fun n)
 232                     (let ((n-start (gensym)))
 233                       `(let ((,n-start (+ ,',n-index ,n)))
 234                          (declare (type index ,n-start))
 235                          (setq ,',n-index ,n-start)
 236                          (,fun ,@(make-list n :initial-element
 237                                             `(svref ,',n-stack
 238                                                     (decf ,n-start))))))))
 239          ,(if pushp
 240               `(let ((,n-res (progn ,@forms)))
 241                  (when (zerop ,n-index)
 242                    (grow-fop-stack)
 243                    (setq ,n-index *fop-stack-pointer*
 244                          ,n-stack *fop-stack*))
 245                  (decf ,n-index)
 246                  (setq *fop-stack-pointer* ,n-index)
 247                  (setf (svref ,n-stack ,n-index) ,n-res))
 248               `(prog1
 249                 (progn ,@forms)
 250                 (setq *fop-stack-pointer* ,n-index)))))))
 251 \f
 252 ;;;; FASLOAD
 253 ;;;;
 254 ;;;; Note: FASLOAD is used not only by LOAD, but also (after suitable
 255 ;;;; modification of the fop table) in genesis. Therefore, it's needed
 256 ;;;; not only in the target Lisp, but also in the cross-compilation
 257 ;;;; host.
 258
 259 ;;; a helper function for LOAD-FASL-GROUP
 260 ;;;
 261 ;;; Return true if we successfully read a FASL header from the stream,
 262 ;;; or NIL if EOF was hit before anything was read. Signal an error if
 263 ;;; we encounter garbage.
 264 (defun check-fasl-header (stream)
 265
 266   (let ((byte (read-byte stream nil)))
 267     (when byte
 268
 269       ;; Read the string part of the fasl header, or die.
 270       (let* ((fhsss sb!c:*fasl-header-string-start-string*)
 271              (fhsss-length (length fhsss)))
 272         (unless (= byte (char-code (schar fhsss 0)))
 273           (error "illegal fasl file header"))
 274         (do ((byte (read-byte stream) (read-byte stream))
 275              (count 1 (1+ count)))
 276             ((= byte sb!c:*fasl-header-string-stop-char-code*)
 277              t)
 278           (declare (fixnum byte count))
 279           (when (and (< count fhsss-length)
 280                      (not (eql byte (char-code (schar fhsss count)))))
 281             (error "illegal fasl file header"))))
 282
 283       ;; Read and validate implementation and version, or die.
 284       (let* ((implementation-length (read-arg 4))
 285              (implementation-string (make-string implementation-length))
 286              (ignore (read-string-as-bytes stream implementation-string))
 287              (implementation (keywordicate implementation-string))
 288              ;; FIXME: The logic above to read a keyword from the fasl file
 289              ;; could probably be shared with the read-a-keyword fop.
 290              (version (read-arg 4)))
 291         (declare (ignore ignore))
 292         (flet ((check-version (variant possible-implementation needed-version)
 293                  (when (string= possible-implementation implementation)
 294                    (unless (= version needed-version)
 295                      (error "~@<~S is in ~A fasl file format version ~D, ~
 296                              but this version of SBCL uses ~
 297                              format version ~D.~:@>"
 298                             stream
 299                             variant
 300                             version
 301                             needed-version))
 302                    t)))
 303           (or (check-version "native code"
 304                              #.sb!c:*backend-fasl-file-implementation*
 305                              #.sb!c:*backend-fasl-file-version*)
 306               (check-version "byte code"
 307                              #.(sb!c:backend-byte-fasl-file-implementation)
 308                              sb!c:byte-fasl-file-version)
 309               (error "~S was compiled for implementation ~A, but this is a ~A."
 310                      stream
 311                      implementation
 312                      sb!c:*backend-fasl-file-implementation*)))))))
 313
 314 ;; Setting this variable gives you a trace of fops as they are loaded and
 315 ;; executed.
 316 #!+sb-show
 317 (defvar *show-fops-p* nil)
 318
 319 ;;; a helper function for FASLOAD
 320 ;;;
 321 ;;; Return true if we successfully load a group from the stream, or NIL if EOF
 322 ;;; was encountered while trying to read from the stream. Dispatch to the right
 323 ;;; function for each fop. Special-case FOP-BYTE-PUSH since it is real common.
 324 (defun load-fasl-group (stream)
 325   (when (check-fasl-header stream)
 326     (catch 'fasl-group-end
 327       (let ((*current-fop-table-index* 0))
 328         (loop
 329           (let ((byte (read-byte stream)))
 330
 331             ;; Do some debugging output.
 332             #!+sb-show
 333             (when *show-fops-p*
 334               (let ((ptr *fop-stack-pointer*)
 335                     (stack *fop-stack*))
 336                 (fresh-line *trace-output*)
 337                 ;; The FOP operations are stack based, so it's sorta
 338                 ;; logical to display the operand before the operator.
 339                 ;; ("reverse Polish notation")
 340                 (unless (= ptr (length stack))
 341                   (write-char #\space *trace-output*)
 342                   (prin1 (svref stack ptr) *trace-output*)
 343                   (terpri *trace-output*))
 344                 ;; Display the operator.
 345                 (format *trace-output*
 346                         "~&~S (#X~X at ~D) (~S)~%"
 347                         (svref *fop-names* byte)
 348                         byte
 349                         (1- (file-position stream))
 350                         (svref *fop-functions* byte))))
 351
 352             ;; Actually execute the fop.
 353             (if (eql byte 3)
 354               ;; FIXME: This is the special case for FOP-BYTE-PUSH.
 355               ;; Benchmark to see whether it's really worth special
 356               ;; casing it. If it is, at least express the test in
 357               ;; terms of a symbolic name for the FOP-BYTE-PUSH code,
 358               ;; not a bare '3' (!). Failing that, remove the special
 359               ;; case (and the comment at the head of this function
 360               ;; which mentions it).
 361               (let ((index *fop-stack-pointer*))
 362                 (declare (type index index))
 363                 (when (zerop index)
 364                   (grow-fop-stack)
 365                   (setq index *fop-stack-pointer*))
 366                 (decf index)
 367                 (setq *fop-stack-pointer* index)
 368                 (setf (svref *fop-stack* index)
 369                       (svref *current-fop-table* (read-byte stream))))
 370               (funcall (the function (svref *fop-functions* byte))))))))))
 371
 372 (defun fasload (stream verbose print)
 373   ;; KLUDGE: ANSI says it's good to do something with the :PRINT
 374   ;; argument to LOAD when we're fasloading a file, but currently we
 375   ;; don't. (CMU CL did, but implemented it in a non-ANSI way, and I
 376   ;; just disabled that instead of rewriting it.) -- WHN 20000131
 377   (declare (ignore print))
 378   (when (zerop (file-length stream))
 379     (error "attempt to load an empty FASL file:~%  ~S" (namestring stream)))
 380   (do-load-verbose stream verbose)
 381   (let* ((*fasl-file* stream)
 382          (*current-fop-table* (or (pop *free-fop-tables*) (make-array 1000)))
 383          (*current-fop-table-size* (length *current-fop-table*))
 384          (*fop-stack-pointer-on-entry* *fop-stack-pointer*))
 385     (unwind-protect
 386         ;; FIXME: This should probably become
 387         ;;   (LOOP WHILE (LOAD-FASL-GROUP-STREAM))
 388         ;; but as a LOOP newbie I don't want to do that until I can
 389         ;; test it.
 390         (do ((loaded-group (load-fasl-group stream) (load-fasl-group stream)))
 391             ((not loaded-group)))
 392       (setq *fop-stack-pointer* *fop-stack-pointer-on-entry*)
 393       (push *current-fop-table* *free-fop-tables*)
 394       ;; NIL out the stack and table, so that we don't hold onto garbage.
 395       ;;
 396       ;; FIXME: Couldn't we just get rid of the free fop table pool so
 397       ;; that some of this NILing out would go away?
 398       (fill *fop-stack* nil :end *fop-stack-pointer-on-entry*)
 399       (fill *current-fop-table* nil)))
 400   t)
 401 \f
 402 ;;;; stuff for debugging/tuning by collecting statistics on FOPs (?)
 403
 404 #|
 405 (defvar *fop-counts* (make-array 256 :initial-element 0))
 406 (defvar *fop-times* (make-array 256 :initial-element 0))
 407 (defvar *print-fops* nil)
 408
 409 (defun clear-counts ()
 410   (fill (the simple-vector *fop-counts*) 0)
 411   (fill (the simple-vector *fop-times*) 0)
 412   t)
 413
 414 (defun analyze-counts ()
 415   (let ((counts ())
 416         (total-count 0)
 417         (times ())
 418         (total-time 0))
 419     (macrolet ((breakdown (lvar tvar vec)
 420                  `(progn
 421                    (dotimes (i 255)
 422                      (declare (fixnum i))
 423                      (let ((n (svref ,vec i)))
 424                        (push (cons (svref *fop-names* i) n) ,lvar)
 425                        (incf ,tvar n)))
 426                    (setq ,lvar (subseq (sort ,lvar #'(lambda (x y)
 427                                                        (> (cdr x) (cdr y))))
 428                                        0 10)))))
 429
 430       (breakdown counts total-count *fop-counts*)
 431       (breakdown times total-time *fop-times*)
 432       (format t "Total fop count is ~D~%" total-count)
 433       (dolist (c counts)
 434         (format t "~30S: ~4D~%" (car c) (cdr c)))
 435       (format t "~%Total fop time is ~D~%" (/ (float total-time) 60.0))
 436       (dolist (m times)
 437         (format t "~30S: ~6,2F~%" (car m) (/ (float (cdr m)) 60.0))))))
 438 |#
 439