src/code/macros.lisp

   1 ;;;; lots of basic macros for the target SBCL
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; ASSERT and CHECK-TYPE
  15
  16 ;;; ASSERT is written this way, to call ASSERT-ERROR, because of how
  17 ;;; closures are compiled. RESTART-CASE has forms with closures that
  18 ;;; the compiler causes to be generated at the top of any function
  19 ;;; using RESTART-CASE, regardless of whether they are needed. Thus if
  20 ;;; we just wrapped a RESTART-CASE around the call to ERROR, we'd have
  21 ;;; to do a significant amount of work at runtime allocating and
  22 ;;; deallocating the closures regardless of whether they were ever
  23 ;;; needed.
  24 ;;;
  25 ;;; ASSERT-ERROR isn't defined until a later file because it uses the
  26 ;;; macro RESTART-CASE, which isn't defined until a later file.
  27 (defmacro-mundanely assert (test-form &optional places datum &rest arguments)
  28   #!+sb-doc
  29   "Signals an error if the value of test-form is nil. Continuing from this
  30    error using the CONTINUE restart will allow the user to alter the value of
  31    some locations known to SETF, starting over with test-form. Returns NIL."
  32   `(do () (,test-form)
  33      (assert-error ',test-form ',places ,datum ,@arguments)
  34      ,@(mapcar (lambda (place)
  35                  `(setf ,place (assert-prompt ',place ,place)))
  36                places)))
  37
  38 (defun assert-prompt (name value)
  39   (cond ((y-or-n-p "The old value of ~S is ~S.~
  40                   ~%Do you want to supply a new value? "
  41                    name value)
  42          (format *query-io* "~&Type a form to be evaluated:~%")
  43          (flet ((read-it () (eval (read *query-io*))))
  44            (if (symbolp name) ;help user debug lexical variables
  45                (progv (list name) (list value) (read-it))
  46                (read-it))))
  47         (t value)))
  48
  49 ;;; CHECK-TYPE is written this way, to call CHECK-TYPE-ERROR, because
  50 ;;; of how closures are compiled. RESTART-CASE has forms with closures
  51 ;;; that the compiler causes to be generated at the top of any
  52 ;;; function using RESTART-CASE, regardless of whether they are
  53 ;;; needed. Because it would be nice if CHECK-TYPE were cheap to use,
  54 ;;; and some things (e.g., READ-CHAR) can't afford this excessive
  55 ;;; consing, we bend backwards a little.
  56 ;;;
  57 ;;; FIXME: In reality, this restart cruft is needed hardly anywhere in
  58 ;;; the system. Write NEED and NEED-TYPE to replace ASSERT and
  59 ;;; CHECK-TYPE inside the system. (CL:CHECK-TYPE must still be
  60 ;;; defined, since it's specified by ANSI and it is sometimes nice for
  61 ;;; whipping up little things. But as far as I can tell it's not
  62 ;;; usually very helpful deep inside the guts of a complex system like
  63 ;;; SBCL.)
  64 ;;;
  65 ;;; CHECK-TYPE-ERROR isn't defined until a later file because it uses
  66 ;;; the macro RESTART-CASE, which isn't defined until a later file.
  67 (defmacro-mundanely check-type (place type &optional type-string)
  68   #!+sb-doc
  69   "Signal a restartable error of type TYPE-ERROR if the value of PLACE is
  70   not of the specified type. If an error is signalled and the restart is
  71   used to return, this can only return if the STORE-VALUE restart is
  72   invoked. In that case it will store into PLACE and start over."
  73   (let ((place-value (gensym)))
  74     `(do ((,place-value ,place ,place))
  75          ((typep ,place-value ',type))
  76        (setf ,place
  77              (check-type-error ',place ,place-value ',type ,type-string)))))
  78 \f
  79 ;;;; DEFINE-SYMBOL-MACRO
  80
  81 (defmacro-mundanely define-symbol-macro (name expansion)
  82   `(eval-when (:compile-toplevel :load-toplevel :execute)
  83     (sb!c::%define-symbol-macro ',name ',expansion)))
  84
  85 (defun sb!c::%define-symbol-macro (name expansion)
  86   (unless (symbolp name)
  87     (error 'simple-type-error :datum name :expected-type 'symbol
  88            :format-control "Symbol macro name is not a symbol: ~S."
  89            :format-arguments (list name)))
  90   (ecase (info :variable :kind name)
  91     ((:macro :global nil)
  92      (setf (info :variable :kind name) :macro)
  93      (setf (info :variable :macro-expansion name) expansion))
  94     (:special
  95      (error 'simple-program-error
  96             :format-control "Symbol macro name already declared special: ~S."
  97             :format-arguments (list name)))
  98     (:constant
  99      (error 'simple-program-error
 100             :format-control "Symbol macro name already declared constant: ~S."
 101             :format-arguments (list name))))
 102   name)
 103
 104 \f
 105 ;;;; DEFINE-COMPILER-MACRO
 106
 107 (defmacro-mundanely define-compiler-macro (name lambda-list &body body)
 108   #!+sb-doc
 109   "Define a compiler-macro for NAME."
 110   (legal-fun-name-or-type-error name)
 111   (when (consp name)
 112     ;; It's fairly clear that the user intends the compiler macro to
 113     ;; expand when he does (SETF (FOO ...) X). And that's even a
 114     ;; useful and reasonable thing to want. Unfortunately,
 115     ;; (SETF (FOO ...) X) macroexpands into (FUNCALL (SETF FOO) X ...),
 116     ;; and it's not at all clear that it's valid to expand a FUNCALL form,
 117     ;; and the ANSI standard doesn't seem to say anything else which
 118     ;; would justify us expanding the compiler macro the way the user
 119     ;; wants. So instead we rely on 3.2.2.1.3 "When Compiler Macros Are
 120     ;; Used" which says they never have to be used, so by ignoring such
 121     ;; macros we're erring on the safe side. But any user who does
 122     ;; (DEFINE-COMPILER-MACRO (SETF FOO) ...) could easily be surprised
 123     ;; by this way of complying with a rather screwy aspect of the ANSI
 124     ;; spec, so at least we can warn him...
 125     (compiler-style-warn
 126      "defining compiler macro of (SETF ...), which will not be expanded"))
 127   (let ((whole (gensym "WHOLE-"))
 128         (environment (gensym "ENV-")))
 129     (multiple-value-bind (body local-decs doc)
 130         (parse-defmacro lambda-list whole body name 'define-compiler-macro
 131                         :environment environment)
 132       (let ((def `(lambda (,whole ,environment)
 133                     ,@local-decs
 134                     (block ,(fun-name-block-name name)
 135                       ,body))))
 136         `(sb!c::%define-compiler-macro ',name #',def ',lambda-list ,doc)))))
 137 (defun sb!c::%define-compiler-macro (name definition lambda-list doc)
 138   (declare (ignore lambda-list))
 139   (sb!c::%%define-compiler-macro name definition doc))
 140 (defun sb!c::%%define-compiler-macro (name definition doc)
 141   (setf (sb!xc:compiler-macro-function name) definition)
 142   ;; FIXME: Add support for (SETF FDOCUMENTATION) when object is a list
 143   ;; and type is COMPILER-MACRO. (Until then, we have to discard any
 144   ;; compiler macro documentation for (SETF FOO).)
 145   (unless (listp name)
 146     (setf (fdocumentation name 'compiler-macro) doc))
 147   name)
 148 \f
 149 ;;;; CASE, TYPECASE, and friends
 150
 151 (eval-when (:compile-toplevel :load-toplevel :execute)
 152
 153 ;;; CASE-BODY returns code for all the standard "case" macros. NAME is
 154 ;;; the macro name, and KEYFORM is the thing to case on. MULTI-P
 155 ;;; indicates whether a branch may fire off a list of keys; otherwise,
 156 ;;; a key that is a list is interpreted in some way as a single key.
 157 ;;; When MULTI-P, TEST is applied to the value of KEYFORM and each key
 158 ;;; for a given branch; otherwise, TEST is applied to the value of
 159 ;;; KEYFORM and the entire first element, instead of each part, of the
 160 ;;; case branch. When ERRORP, no T or OTHERWISE branch is permitted,
 161 ;;; and an ERROR form is generated. When PROCEEDP, it is an error to
 162 ;;; omit ERRORP, and the ERROR form generated is executed within a
 163 ;;; RESTART-CASE allowing KEYFORM to be set and retested.
 164 (defun case-body (name keyform cases multi-p test errorp proceedp needcasesp)
 165   (unless (or cases (not needcasesp))
 166     (warn "no clauses in ~S" name))
 167   (let ((keyform-value (gensym))
 168         (clauses ())
 169         (keys ()))
 170     (dolist (case cases)
 171       (unless (list-of-length-at-least-p case 1)
 172         (error "~S -- bad clause in ~S" case name))
 173       (destructuring-bind (keyoid &rest forms) case
 174         (cond ((memq keyoid '(t otherwise))
 175                (if errorp
 176                    (error 'simple-program-error
 177                           :format-control
 178                           "No default clause is allowed in ~S: ~S"
 179                           :format-arguments (list name case))
 180                    (push `(t nil ,@forms) clauses)))
 181               ((and multi-p (listp keyoid))
 182                (setf keys (append keyoid keys))
 183                (push `((or ,@(mapcar (lambda (key)
 184                                        `(,test ,keyform-value ',key))
 185                                      keyoid))
 186                        nil
 187                        ,@forms)
 188                      clauses))
 189               (t
 190                (push keyoid keys)
 191                (push `((,test ,keyform-value ',keyoid)
 192                        nil
 193                        ,@forms)
 194                      clauses)))))
 195     (case-body-aux name keyform keyform-value clauses keys errorp proceedp
 196                    `(,(if multi-p 'member 'or) ,@keys))))
 197
 198 ;;; CASE-BODY-AUX provides the expansion once CASE-BODY has groveled
 199 ;;; all the cases. Note: it is not necessary that the resulting code
 200 ;;; signal case-failure conditions, but that's what KMP's prototype
 201 ;;; code did. We call CASE-BODY-ERROR, because of how closures are
 202 ;;; compiled. RESTART-CASE has forms with closures that the compiler
 203 ;;; causes to be generated at the top of any function using the case
 204 ;;; macros, regardless of whether they are needed.
 205 ;;;
 206 ;;; The CASE-BODY-ERROR function is defined later, when the
 207 ;;; RESTART-CASE macro has been defined.
 208 (defun case-body-aux (name keyform keyform-value clauses keys
 209                       errorp proceedp expected-type)
 210   (if proceedp
 211       (let ((block (gensym))
 212             (again (gensym)))
 213         `(let ((,keyform-value ,keyform))
 214            (block ,block
 215              (tagbody
 216               ,again
 217               (return-from
 218                ,block
 219                (cond ,@(nreverse clauses)
 220                      (t
 221                       (setf ,keyform-value
 222                             (setf ,keyform
 223                                   (case-body-error
 224                                    ',name ',keyform ,keyform-value
 225                                    ',expected-type ',keys)))
 226                       (go ,again))))))))
 227       `(let ((,keyform-value ,keyform))
 228          (declare (ignorable ,keyform-value)) ; e.g. (CASE KEY (T))
 229          (cond
 230           ,@(nreverse clauses)
 231           ,@(if errorp
 232                 `((t (error 'case-failure
 233                             :name ',name
 234                             :datum ,keyform-value
 235                             :expected-type ',expected-type
 236                             :possibilities ',keys))))))))
 237 ) ; EVAL-WHEN
 238
 239 (defmacro-mundanely case (keyform &body cases)
 240   #!+sb-doc
 241   "CASE Keyform {({(Key*) | Key} Form*)}*
 242   Evaluates the Forms in the first clause with a Key EQL to the value of
 243   Keyform. If a singleton key is T then the clause is a default clause."
 244   (case-body 'case keyform cases t 'eql nil nil nil))
 245
 246 (defmacro-mundanely ccase (keyform &body cases)
 247   #!+sb-doc
 248   "CCASE Keyform {({(Key*) | Key} Form*)}*
 249   Evaluates the Forms in the first clause with a Key EQL to the value of
 250   Keyform. If none of the keys matches then a correctable error is
 251   signalled."
 252   (case-body 'ccase keyform cases t 'eql t t t))
 253
 254 (defmacro-mundanely ecase (keyform &body cases)
 255   #!+sb-doc
 256   "ECASE Keyform {({(Key*) | Key} Form*)}*
 257   Evaluates the Forms in the first clause with a Key EQL to the value of
 258   Keyform. If none of the keys matches then an error is signalled."
 259   (case-body 'ecase keyform cases t 'eql t nil t))
 260
 261 (defmacro-mundanely typecase (keyform &body cases)
 262   #!+sb-doc
 263   "TYPECASE Keyform {(Type Form*)}*
 264   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 265   is true."
 266   (case-body 'typecase keyform cases nil 'typep nil nil nil))
 267
 268 (defmacro-mundanely ctypecase (keyform &body cases)
 269   #!+sb-doc
 270   "CTYPECASE Keyform {(Type Form*)}*
 271   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 272   is true. If no form is satisfied then a correctable error is signalled."
 273   (case-body 'ctypecase keyform cases nil 'typep t t t))
 274
 275 (defmacro-mundanely etypecase (keyform &body cases)
 276   #!+sb-doc
 277   "ETYPECASE Keyform {(Type Form*)}*
 278   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 279   is true. If no form is satisfied then an error is signalled."
 280   (case-body 'etypecase keyform cases nil 'typep t nil t))
 281 \f
 282 ;;;; WITH-FOO i/o-related macros
 283
 284 (defmacro-mundanely with-open-stream ((var stream) &body forms-decls)
 285   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 286     (let ((abortp (gensym)))
 287       `(let ((,var ,stream)
 288              (,abortp t))
 289          ,@decls
 290          (unwind-protect
 291              (multiple-value-prog1
 292               (progn ,@forms)
 293               (setq ,abortp nil))
 294            (when ,var
 295              (close ,var :abort ,abortp)))))))
 296
 297 (defmacro-mundanely with-open-file ((stream filespec &rest options)
 298                                     &body body)
 299   `(with-open-stream (,stream (open ,filespec ,@options))
 300      ,@body))
 301
 302 (defmacro-mundanely with-input-from-string ((var string &key index start end)
 303                                             &body forms-decls)
 304   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 305     ;; The ONCE-ONLY inhibits compiler note for unreachable code when
 306     ;; END is true.
 307     (once-only ((string string))
 308       `(let ((,var
 309               ,(cond ((null end)
 310                       `(make-string-input-stream ,string ,(or start 0)))
 311                      ((symbolp end)
 312                       `(if ,end
 313                            (make-string-input-stream ,string
 314                                                      ,(or start 0)
 315                                                      ,end)
 316                            (make-string-input-stream ,string
 317                                                      ,(or start 0))))
 318                      (t
 319                       `(make-string-input-stream ,string
 320                                                  ,(or start 0)
 321                                                  ,end)))))
 322          ,@decls
 323          (unwind-protect
 324              (progn ,@forms)
 325            (close ,var)
 326            ,@(when index
 327                `((setf ,index (string-input-stream-current ,var)))))))))
 328
 329 (defmacro-mundanely with-output-to-string ((var &optional string)
 330                                            &body forms-decls)
 331   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 332     (if string
 333       `(let ((,var (make-fill-pointer-output-stream ,string)))
 334          ,@decls
 335          (unwind-protect
 336              (progn ,@forms)
 337            (close ,var)))
 338       `(let ((,var (make-string-output-stream)))
 339          ,@decls
 340          (unwind-protect
 341              (progn ,@forms)
 342            (close ,var))
 343          (get-output-stream-string ,var)))))
 344 \f
 345 ;;;; miscellaneous macros
 346
 347 (defmacro-mundanely nth-value (n form)
 348   #!+sb-doc
 349   "Evaluate FORM and return the Nth value (zero based). This involves no
 350   consing when N is a trivial constant integer."
 351   (if (integerp n)
 352       (let ((dummy-list nil)
 353             (keeper (gensym "KEEPER-")))
 354         ;; We build DUMMY-LIST, a list of variables to bind to useless
 355         ;; values, then we explicitly IGNORE those bindings and return
 356         ;; KEEPER, the only thing we're really interested in right now.
 357         (dotimes (i n)
 358           (push (gensym "IGNORE-") dummy-list))
 359         `(multiple-value-bind (,@dummy-list ,keeper) ,form
 360            (declare (ignore ,@dummy-list))
 361            ,keeper))
 362       (once-only ((n n))
 363         `(case (the fixnum ,n)
 364            (0 (nth-value 0 ,form))
 365            (1 (nth-value 1 ,form))
 366            (2 (nth-value 2 ,form))
 367            (t (nth (the fixnum ,n) (multiple-value-list ,form)))))))
 368
 369 (defmacro-mundanely declaim (&rest specs)
 370   #!+sb-doc
 371   "DECLAIM Declaration*
 372   Do a declaration or declarations for the global environment."
 373   `(eval-when (:compile-toplevel :load-toplevel :execute)
 374      ,@(mapcar (lambda (spec) `(sb!xc:proclaim ',spec))
 375                specs)))
 376
 377 (defmacro-mundanely print-unreadable-object ((object stream &key type identity)
 378                                              &body body)
 379   "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
 380   with object-type prefix and object-identity suffix, and executing the
 381   code in BODY to provide possible further output."
 382   `(%print-unreadable-object ,object ,stream ,type ,identity
 383                              ,(if body
 384                                   `(lambda () ,@body)
 385                                   nil)))
 386
 387 (defmacro-mundanely ignore-errors (&rest forms)
 388   #!+sb-doc
 389   "Execute FORMS handling ERROR conditions, returning the result of the last
 390   form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
 391   `(handler-case (progn ,@forms)
 392      (error (condition) (values nil condition))))