src/code/macros.lisp

   1 ;;;; lots of basic macros for the target SBCL
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; ASSERT and CHECK-TYPE
  15
  16 ;;; ASSERT is written this way, to call ASSERT-ERROR, because of how
  17 ;;; closures are compiled. RESTART-CASE has forms with closures that
  18 ;;; the compiler causes to be generated at the top of any function
  19 ;;; using RESTART-CASE, regardless of whether they are needed. Thus if
  20 ;;; we just wrapped a RESTART-CASE around the call to ERROR, we'd have
  21 ;;; to do a significant amount of work at runtime allocating and
  22 ;;; deallocating the closures regardless of whether they were ever
  23 ;;; needed.
  24 ;;;
  25 ;;; ASSERT-ERROR isn't defined until a later file because it uses the
  26 ;;; macro RESTART-CASE, which isn't defined until a later file.
  27 (defmacro-mundanely assert (test-form &optional places datum &rest arguments)
  28   #!+sb-doc
  29   "Signals an error if the value of test-form is nil. Continuing from this
  30    error using the CONTINUE restart will allow the user to alter the value of
  31    some locations known to SETF, starting over with test-form. Returns NIL."
  32   `(do () (,test-form)
  33      (assert-error ',test-form ',places ,datum ,@arguments)
  34      ,@(mapcar (lambda (place)
  35                  `(setf ,place (assert-prompt ',place ,place)))
  36                places)))
  37
  38 (defun assert-prompt (name value)
  39   (cond ((y-or-n-p "The old value of ~S is ~S.~
  40                     ~%Do you want to supply a new value? "
  41                    name value)
  42          (format *query-io* "~&Type a form to be evaluated:~%")
  43          (flet ((read-it () (eval (read *query-io*))))
  44            (if (symbolp name) ;help user debug lexical variables
  45                (progv (list name) (list value) (read-it))
  46                (read-it))))
  47         (t value)))
  48
  49 ;;; CHECK-TYPE is written this way, to call CHECK-TYPE-ERROR, because
  50 ;;; of how closures are compiled. RESTART-CASE has forms with closures
  51 ;;; that the compiler causes to be generated at the top of any
  52 ;;; function using RESTART-CASE, regardless of whether they are
  53 ;;; needed. Because it would be nice if CHECK-TYPE were cheap to use,
  54 ;;; and some things (e.g., READ-CHAR) can't afford this excessive
  55 ;;; consing, we bend backwards a little.
  56 ;;;
  57 ;;; CHECK-TYPE-ERROR isn't defined until a later file because it uses
  58 ;;; the macro RESTART-CASE, which isn't defined until a later file.
  59 (defmacro-mundanely check-type (place type &optional type-string
  60                                 &environment env)
  61   #!+sb-doc
  62   "Signal a restartable error of type TYPE-ERROR if the value of PLACE
  63 is not of the specified type. If an error is signalled and the restart
  64 is used to return, this can only return if the STORE-VALUE restart is
  65 invoked. In that case it will store into PLACE and start over."
  66   ;; Detect a common user-error.
  67   (when (and (consp type) (eq 'quote (car type)))
  68     (error 'simple-reference-error
  69            :format-control "Quoted type specifier in ~S: ~S"
  70            :format-arguments (list 'check-type type)
  71            :references (list '(:ansi-cl :macro check-type))))
  72   ;; KLUDGE: We use a simpler form of expansion if PLACE is just a
  73   ;; variable to work around Python's blind spot in type derivation.
  74   ;; For more complex places getting the type derived should not
  75   ;; matter so much anyhow.
  76   (let ((expanded (sb!xc:macroexpand place env)))
  77     (if (symbolp expanded)
  78         `(do ()
  79              ((typep ,place ',type))
  80           (setf ,place (check-type-error ',place ,place ',type ,type-string)))
  81         (let ((value (gensym)))
  82           `(do ((,value ,place ,place))
  83                ((typep ,value ',type))
  84             (setf ,place
  85                   (check-type-error ',place ,value ',type ,type-string)))))))
  86 \f
  87 ;;;; DEFINE-SYMBOL-MACRO
  88
  89 (defmacro-mundanely define-symbol-macro (name expansion)
  90   `(eval-when (:compile-toplevel :load-toplevel :execute)
  91     (sb!c::%define-symbol-macro ',name ',expansion (sb!c:source-location))))
  92
  93 (defun sb!c::%define-symbol-macro (name expansion source-location)
  94   (unless (symbolp name)
  95     (error 'simple-type-error :datum name :expected-type 'symbol
  96            :format-control "Symbol macro name is not a symbol: ~S."
  97            :format-arguments (list name)))
  98   (with-single-package-locked-error
  99       (:symbol name "defining ~A as a symbol-macro"))
 100   (sb!c:with-source-location (source-location)
 101     (setf (info :source-location :symbol-macro name) source-location))
 102   (let ((kind (info :variable :kind name)))
 103     (ecase kind
 104      ((:macro :unknown)
 105       (setf (info :variable :kind name) :macro)
 106       (setf (info :variable :macro-expansion name) expansion))
 107      ((:special :global)
 108       (error 'simple-program-error
 109              :format-control "Symbol macro name already declared ~A: ~S."
 110              :format-arguments (list kind name)))
 111      (:constant
 112       (error 'simple-program-error
 113              :format-control "Symbol macro name already defined as a constant: ~S."
 114              :format-arguments (list name)))))
 115   name)
 116 \f
 117 ;;;; DEFINE-COMPILER-MACRO
 118
 119 (defmacro-mundanely define-compiler-macro (name lambda-list &body body)
 120   #!+sb-doc
 121   "Define a compiler-macro for NAME."
 122   (legal-fun-name-or-type-error name)
 123   (when (and (symbolp name) (special-operator-p name))
 124     (error 'simple-program-error
 125            :format-control "cannot define a compiler-macro for a special operator: ~S"
 126            :format-arguments (list name)))
 127   (with-unique-names (whole environment)
 128     (multiple-value-bind (body local-decs doc)
 129         (parse-defmacro lambda-list whole body name 'define-compiler-macro
 130                         :environment environment)
 131       (let ((def `(lambda (,whole ,environment)
 132                     ,@local-decs
 133                     ,body))
 134             (debug-name (sb!c::debug-name 'compiler-macro-function name)))
 135         `(eval-when (:compile-toplevel :load-toplevel :execute)
 136            (sb!c::%define-compiler-macro ',name
 137                                          #',def
 138                                          ',lambda-list
 139                                          ,doc
 140                                          ',debug-name))))))
 141
 142 ;;; FIXME: This will look remarkably similar to those who have already
 143 ;;; seen the code for %DEFMACRO in src/code/defmacro.lisp.  Various
 144 ;;; bits of logic should be shared (notably arglist setting).
 145 (macrolet
 146     ((def (times set-p)
 147          `(eval-when (,@times)
 148            (defun sb!c::%define-compiler-macro
 149                (name definition lambda-list doc debug-name)
 150              ,@(unless set-p
 151                  '((declare (ignore lambda-list debug-name))))
 152              ;; FIXME: warn about incompatible lambda list with
 153              ;; respect to parent function?
 154              (setf (sb!xc:compiler-macro-function name) definition)
 155              #-sb-xc-host
 156              (setf (%fun-doc definition) doc)
 157              ,(when set-p
 158                     `(setf (%fun-lambda-list definition) lambda-list
 159                            (%fun-name definition) debug-name))
 160              name))))
 161   (progn
 162     (def (:load-toplevel :execute) #-sb-xc-host t #+sb-xc-host nil)
 163     #-sb-xc (def (:compile-toplevel) nil)))
 164 \f
 165 ;;;; CASE, TYPECASE, and friends
 166
 167 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 168
 169 (define-condition duplicate-case-key-warning (style-warning)
 170   ((key :initarg :key
 171         :reader case-warning-key)
 172    (case-kind :initarg :case-kind
 173               :reader case-warning-case-kind)
 174    (occurrences :initarg :occurrences
 175                 :type list
 176                 :reader duplicate-case-key-warning-occurrences))
 177   (:report
 178     (lambda (condition stream)
 179       (format stream
 180         "Duplicate key ~S in ~S form, ~
 181          occurring in~{~#[~; and~]~{ the ~:R clause:~%~<  ~S~:>~}~^,~}."
 182         (case-warning-key condition)
 183         (case-warning-case-kind condition)
 184         (duplicate-case-key-warning-occurrences condition)))))
 185
 186 ;;; CASE-BODY returns code for all the standard "case" macros. NAME is
 187 ;;; the macro name, and KEYFORM is the thing to case on. MULTI-P
 188 ;;; indicates whether a branch may fire off a list of keys; otherwise,
 189 ;;; a key that is a list is interpreted in some way as a single key.
 190 ;;; When MULTI-P, TEST is applied to the value of KEYFORM and each key
 191 ;;; for a given branch; otherwise, TEST is applied to the value of
 192 ;;; KEYFORM and the entire first element, instead of each part, of the
 193 ;;; case branch. When ERRORP, no OTHERWISE-CLAUSEs are recognized,
 194 ;;; and an ERROR form is generated where control falls off the end
 195 ;;; of the ordinary clauses. When PROCEEDP, it is an error to
 196 ;;; omit ERRORP, and the ERROR form generated is executed within a
 197 ;;; RESTART-CASE allowing KEYFORM to be set and retested.
 198 (defun case-body (name keyform cases multi-p test errorp proceedp needcasesp)
 199   (unless (or cases (not needcasesp))
 200     (warn "no clauses in ~S" name))
 201   (let ((keyform-value (gensym))
 202         (clauses ())
 203         (keys ())
 204         (keys-seen (make-hash-table :test #'eql)))
 205     (do* ((cases cases (cdr cases))
 206           (case (car cases) (car cases))
 207           (case-position 1 (1+ case-position)))
 208          ((null cases) nil)
 209       (flet ((check-clause (case-keys)
 210                (loop for k in case-keys
 211                      for existing = (gethash k keys-seen)
 212                      do (when existing
 213                           (let ((sb!c::*current-path*
 214                                  (when (boundp 'sb!c::*source-paths*)
 215                                    (or (sb!c::get-source-path case)
 216                                        sb!c::*current-path*))))
 217                             (warn 'duplicate-case-key-warning
 218                                   :key k
 219                                   :case-kind name
 220                                   :occurrences `(,existing (,case-position (,case)))))))
 221                (let ((record (list case-position (list case))))
 222                  (dolist (k case-keys)
 223                    (setf (gethash k keys-seen) record)))))
 224         (unless (list-of-length-at-least-p case 1)
 225           (error "~S -- bad clause in ~S" case name))
 226         (destructuring-bind (keyoid &rest forms) case
 227           (cond (;; an OTHERWISE-CLAUSE
 228                  ;;
 229                  ;; By the way... The old code here tried gave
 230                  ;; STYLE-WARNINGs for normal-clauses which looked as
 231                  ;; though they might've been intended to be
 232                  ;; otherwise-clauses. As Tony Martinez reported on
 233                  ;; sbcl-devel 2004-11-09 there are sometimes good
 234                  ;; reasons to write clauses like that; and as I noticed
 235                  ;; when trying to understand the old code so I could
 236                  ;; understand his patch, trying to guess which clauses
 237                  ;; don't have good reasons is fundamentally kind of a
 238                  ;; mess. SBCL does issue style warnings rather
 239                  ;; enthusiastically, and I have often justified that by
 240                  ;; arguing that we're doing that to detect issues which
 241                  ;; are tedious for programmers to detect for by
 242                  ;; proofreading (like small typoes in long symbol
 243                  ;; names, or duplicate function definitions in large
 244                  ;; files). This doesn't seem to be an issue like that,
 245                  ;; and I can't think of a comparably good justification
 246                  ;; for giving STYLE-WARNINGs for legal code here, so
 247                  ;; now we just hope the programmer knows what he's
 248                  ;; doing. -- WHN 2004-11-20
 249                  (and (not errorp) ; possible only in CASE or TYPECASE,
 250                                    ; not in [EC]CASE or [EC]TYPECASE
 251                       (memq keyoid '(t otherwise))
 252                       (null (cdr cases)))
 253                  (push `(t nil ,@forms) clauses))
 254                 ((and multi-p (listp keyoid))
 255                  (setf keys (append keyoid keys))
 256                  (check-clause keyoid)
 257                  (push `((or ,@(mapcar (lambda (key)
 258                                          `(,test ,keyform-value ',key))
 259                                        keyoid))
 260                          nil
 261                          ,@forms)
 262                        clauses))
 263                 (t
 264                  (push keyoid keys)
 265                  (check-clause (list keyoid))
 266                  (push `((,test ,keyform-value ',keyoid)
 267                          nil
 268                          ,@forms)
 269                        clauses))))))
 270     (case-body-aux name keyform keyform-value clauses keys errorp proceedp
 271                    `(,(if multi-p 'member 'or) ,@keys))))
 272
 273 ;;; CASE-BODY-AUX provides the expansion once CASE-BODY has groveled
 274 ;;; all the cases. Note: it is not necessary that the resulting code
 275 ;;; signal case-failure conditions, but that's what KMP's prototype
 276 ;;; code did. We call CASE-BODY-ERROR, because of how closures are
 277 ;;; compiled. RESTART-CASE has forms with closures that the compiler
 278 ;;; causes to be generated at the top of any function using the case
 279 ;;; macros, regardless of whether they are needed.
 280 ;;;
 281 ;;; The CASE-BODY-ERROR function is defined later, when the
 282 ;;; RESTART-CASE macro has been defined.
 283 (defun case-body-aux (name keyform keyform-value clauses keys
 284                       errorp proceedp expected-type)
 285   (if proceedp
 286       (let ((block (gensym))
 287             (again (gensym)))
 288         `(let ((,keyform-value ,keyform))
 289            (block ,block
 290              (tagbody
 291               ,again
 292               (return-from
 293                ,block
 294                (cond ,@(nreverse clauses)
 295                      (t
 296                       (setf ,keyform-value
 297                             (setf ,keyform
 298                                   (case-body-error
 299                                    ',name ',keyform ,keyform-value
 300                                    ',expected-type ',keys)))
 301                       (go ,again))))))))
 302       `(let ((,keyform-value ,keyform))
 303          (declare (ignorable ,keyform-value)) ; e.g. (CASE KEY (T))
 304          (cond
 305           ,@(nreverse clauses)
 306           ,@(if errorp
 307                 `((t (error 'case-failure
 308                             :name ',name
 309                             :datum ,keyform-value
 310                             :expected-type ',expected-type
 311                             :possibilities ',keys))))))))
 312 ) ; EVAL-WHEN
 313
 314 (defmacro-mundanely case (keyform &body cases)
 315   #!+sb-doc
 316   "CASE Keyform {({(Key*) | Key} Form*)}*
 317   Evaluates the Forms in the first clause with a Key EQL to the value of
 318   Keyform. If a singleton key is T then the clause is a default clause."
 319   (case-body 'case keyform cases t 'eql nil nil nil))
 320
 321 (defmacro-mundanely ccase (keyform &body cases)
 322   #!+sb-doc
 323   "CCASE Keyform {({(Key*) | Key} Form*)}*
 324   Evaluates the Forms in the first clause with a Key EQL to the value of
 325   Keyform. If none of the keys matches then a correctable error is
 326   signalled."
 327   (case-body 'ccase keyform cases t 'eql t t t))
 328
 329 (defmacro-mundanely ecase (keyform &body cases)
 330   #!+sb-doc
 331   "ECASE Keyform {({(Key*) | Key} Form*)}*
 332   Evaluates the Forms in the first clause with a Key EQL to the value of
 333   Keyform. If none of the keys matches then an error is signalled."
 334   (case-body 'ecase keyform cases t 'eql t nil t))
 335
 336 (defmacro-mundanely typecase (keyform &body cases)
 337   #!+sb-doc
 338   "TYPECASE Keyform {(Type Form*)}*
 339   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 340   is true."
 341   (case-body 'typecase keyform cases nil 'typep nil nil nil))
 342
 343 (defmacro-mundanely ctypecase (keyform &body cases)
 344   #!+sb-doc
 345   "CTYPECASE Keyform {(Type Form*)}*
 346   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 347   is true. If no form is satisfied then a correctable error is signalled."
 348   (case-body 'ctypecase keyform cases nil 'typep t t t))
 349
 350 (defmacro-mundanely etypecase (keyform &body cases)
 351   #!+sb-doc
 352   "ETYPECASE Keyform {(Type Form*)}*
 353   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 354   is true. If no form is satisfied then an error is signalled."
 355   (case-body 'etypecase keyform cases nil 'typep t nil t))
 356 \f
 357 ;;;; WITH-FOO i/o-related macros
 358
 359 (defmacro-mundanely with-open-stream ((var stream) &body forms-decls)
 360   (multiple-value-bind (forms decls)
 361       (parse-body forms-decls :doc-string-allowed nil)
 362     (let ((abortp (gensym)))
 363       `(let ((,var ,stream)
 364              (,abortp t))
 365          ,@decls
 366          (unwind-protect
 367              (multiple-value-prog1
 368               (progn ,@forms)
 369               (setq ,abortp nil))
 370            (when ,var
 371              (close ,var :abort ,abortp)))))))
 372
 373 (defmacro-mundanely with-open-file ((stream filespec &rest options)
 374                                     &body body)
 375   `(with-open-stream (,stream (open ,filespec ,@options))
 376      ,@body))
 377
 378 (defmacro-mundanely with-input-from-string ((var string &key index start end)
 379                                             &body forms-decls)
 380   (multiple-value-bind (forms decls)
 381       (parse-body forms-decls :doc-string-allowed nil)
 382     ;; The ONCE-ONLY inhibits compiler note for unreachable code when
 383     ;; END is true.
 384     (once-only ((string string))
 385       `(let ((,var
 386               ,(cond ((null end)
 387                       `(make-string-input-stream ,string ,(or start 0)))
 388                      ((symbolp end)
 389                       `(if ,end
 390                            (make-string-input-stream ,string
 391                                                      ,(or start 0)
 392                                                      ,end)
 393                            (make-string-input-stream ,string
 394                                                      ,(or start 0))))
 395                      (t
 396                       `(make-string-input-stream ,string
 397                                                  ,(or start 0)
 398                                                  ,end)))))
 399          ,@decls
 400          (multiple-value-prog1
 401              (unwind-protect
 402                   (progn ,@forms)
 403                (close ,var))
 404            ,@(when index
 405                `((setf ,index (string-input-stream-current ,var)))))))))
 406
 407 (defmacro-mundanely with-output-to-string
 408     ((var &optional string &key (element-type ''character))
 409      &body forms-decls)
 410   (multiple-value-bind (forms decls)
 411       (parse-body forms-decls :doc-string-allowed nil)
 412     (if string
 413         (let ((element-type-var (gensym)))
 414           `(let ((,var (make-fill-pointer-output-stream ,string))
 415                  ;; ELEMENT-TYPE isn't currently used for anything
 416                  ;; (see FILL-POINTER-OUTPUT-STREAM FIXME in stream.lisp),
 417                  ;; but it still has to be evaluated for side-effects.
 418                  (,element-type-var ,element-type))
 419             (declare (ignore ,element-type-var))
 420             ,@decls
 421             (unwind-protect
 422                  (progn ,@forms)
 423               (close ,var))))
 424       `(let ((,var (make-string-output-stream :element-type ,element-type)))
 425          ,@decls
 426          (unwind-protect
 427              (progn ,@forms)
 428            (close ,var))
 429          (get-output-stream-string ,var)))))
 430 \f
 431 ;;;; miscellaneous macros
 432
 433 (defmacro-mundanely nth-value (n form)
 434   #!+sb-doc
 435   "Evaluate FORM and return the Nth value (zero based). This involves no
 436   consing when N is a trivial constant integer."
 437   ;; FIXME: The above is true, if slightly misleading.  The
 438   ;; MULTIPLE-VALUE-BIND idiom [ as opposed to MULTIPLE-VALUE-CALL
 439   ;; (LAMBDA (&REST VALUES) (NTH N VALUES)) ] does indeed not cons at
 440   ;; runtime.  However, for large N (say N = 200), COMPILE on such a
 441   ;; form will take longer than can be described as adequate, as the
 442   ;; optional dispatch mechanism for the M-V-B gets increasingly
 443   ;; hairy.
 444   (if (integerp n)
 445       (let ((dummy-list (make-gensym-list n))
 446             (keeper (sb!xc:gensym "KEEPER")))
 447         `(multiple-value-bind (,@dummy-list ,keeper) ,form
 448            (declare (ignore ,@dummy-list))
 449            ,keeper))
 450       (once-only ((n n))
 451         `(case (the fixnum ,n)
 452            (0 (nth-value 0 ,form))
 453            (1 (nth-value 1 ,form))
 454            (2 (nth-value 2 ,form))
 455            (t (nth (the fixnum ,n) (multiple-value-list ,form)))))))
 456
 457 (defmacro-mundanely declaim (&rest specs)
 458   #!+sb-doc
 459   "DECLAIM Declaration*
 460   Do a declaration or declarations for the global environment."
 461   `(eval-when (:compile-toplevel :load-toplevel :execute)
 462      ,@(mapcar (lambda (spec) `(sb!xc:proclaim ',spec))
 463                specs)))
 464
 465 (defmacro-mundanely print-unreadable-object ((object stream &key type identity)
 466                                              &body body)
 467   "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
 468   with object-type prefix and object-identity suffix, and executing the
 469   code in BODY to provide possible further output."
 470   `(%print-unreadable-object ,object ,stream ,type ,identity
 471                              ,(if body
 472                                   `(lambda () ,@body)
 473                                   nil)))
 474
 475 (defmacro-mundanely ignore-errors (&rest forms)
 476   #!+sb-doc
 477   "Execute FORMS handling ERROR conditions, returning the result of the last
 478   form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
 479   `(handler-case (progn ,@forms)
 480      (error (condition) (values nil condition))))