src/code/macros.lisp

   1 ;;;; lots of basic macros for the target SBCL
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; ASSERT and CHECK-TYPE
  15
  16 ;;; ASSERT is written this way, to call ASSERT-ERROR, because of how
  17 ;;; closures are compiled. RESTART-CASE has forms with closures that
  18 ;;; the compiler causes to be generated at the top of any function
  19 ;;; using RESTART-CASE, regardless of whether they are needed. Thus if
  20 ;;; we just wrapped a RESTART-CASE around the call to ERROR, we'd have
  21 ;;; to do a significant amount of work at runtime allocating and
  22 ;;; deallocating the closures regardless of whether they were ever
  23 ;;; needed.
  24 ;;;
  25 ;;; ASSERT-ERROR isn't defined until a later file because it uses the
  26 ;;; macro RESTART-CASE, which isn't defined until a later file.
  27 (defmacro-mundanely assert (test-form &optional places datum &rest arguments)
  28   #!+sb-doc
  29   "Signals an error if the value of test-form is nil. Continuing from this
  30    error using the CONTINUE restart will allow the user to alter the value of
  31    some locations known to SETF, starting over with test-form. Returns NIL."
  32   `(do () (,test-form)
  33      (assert-error ',test-form ',places ,datum ,@arguments)
  34      ,@(mapcar (lambda (place)
  35                  `(setf ,place (assert-prompt ',place ,place)))
  36                places)))
  37
  38 (defun assert-prompt (name value)
  39   (cond ((y-or-n-p "The old value of ~S is ~S.~
  40                   ~%Do you want to supply a new value? "
  41                    name value)
  42          (format *query-io* "~&Type a form to be evaluated:~%")
  43          (flet ((read-it () (eval (read *query-io*))))
  44            (if (symbolp name) ;help user debug lexical variables
  45                (progv (list name) (list value) (read-it))
  46                (read-it))))
  47         (t value)))
  48
  49 ;;; CHECK-TYPE is written this way, to call CHECK-TYPE-ERROR, because
  50 ;;; of how closures are compiled. RESTART-CASE has forms with closures
  51 ;;; that the compiler causes to be generated at the top of any
  52 ;;; function using RESTART-CASE, regardless of whether they are
  53 ;;; needed. Because it would be nice if CHECK-TYPE were cheap to use,
  54 ;;; and some things (e.g., READ-CHAR) can't afford this excessive
  55 ;;; consing, we bend backwards a little.
  56 ;;;
  57 ;;; FIXME: In reality, this restart cruft is needed hardly anywhere in
  58 ;;; the system. Write NEED and NEED-TYPE to replace ASSERT and
  59 ;;; CHECK-TYPE inside the system. (CL:CHECK-TYPE must still be
  60 ;;; defined, since it's specified by ANSI and it is sometimes nice for
  61 ;;; whipping up little things. But as far as I can tell it's not
  62 ;;; usually very helpful deep inside the guts of a complex system like
  63 ;;; SBCL.)
  64 ;;;
  65 ;;; CHECK-TYPE-ERROR isn't defined until a later file because it uses
  66 ;;; the macro RESTART-CASE, which isn't defined until a later file.
  67 (defmacro-mundanely check-type (place type &optional type-string)
  68   #!+sb-doc
  69   "Signal a restartable error of type TYPE-ERROR if the value of PLACE is
  70   not of the specified type. If an error is signalled and the restart is
  71   used to return, this can only return if the STORE-VALUE restart is
  72   invoked. In that case it will store into PLACE and start over."
  73   (let ((place-value (gensym)))
  74     `(do ((,place-value ,place ,place))
  75          ((typep ,place-value ',type))
  76        (setf ,place
  77              (check-type-error ',place ,place-value ',type ,type-string)))))
  78 \f
  79 ;;;; DEFINE-SYMBOL-MACRO
  80
  81 (defmacro-mundanely define-symbol-macro (name expansion)
  82   `(eval-when (:compile-toplevel :load-toplevel :execute)
  83     (sb!c::%define-symbol-macro ',name ',expansion)))
  84
  85 (defun sb!c::%define-symbol-macro (name expansion)
  86   (unless (symbolp name)
  87     (error 'simple-type-error :datum name :expected-type 'symbol
  88            :format-control "Symbol macro name is not a symbol: ~S."
  89            :format-arguments (list name)))
  90   (ecase (info :variable :kind name)
  91     ((:macro :global nil)
  92      (setf (info :variable :kind name) :macro)
  93      (setf (info :variable :macro-expansion name) expansion))
  94     (:special
  95      (error 'simple-program-error
  96             :format-control "Symbol macro name already declared special: ~S."
  97             :format-arguments (list name)))
  98     (:constant
  99      (error 'simple-program-error
 100             :format-control "Symbol macro name already declared constant: ~S."
 101             :format-arguments (list name))))
 102   name)
 103
 104 \f
 105 ;;;; DEFINE-COMPILER-MACRO
 106
 107 (defmacro-mundanely define-compiler-macro (name lambda-list &body body)
 108   #!+sb-doc
 109   "Define a compiler-macro for NAME."
 110   (legal-fun-name-or-type-error name)
 111   (when (consp name)
 112     ;; It's fairly clear that the user intends the compiler macro to
 113     ;; expand when he does (SETF (FOO ...) X). And that's even a
 114     ;; useful and reasonable thing to want. Unfortunately,
 115     ;; (SETF (FOO ...) X) macroexpands into (FUNCALL (SETF FOO) X ...),
 116     ;; and it's not at all clear that it's valid to expand a FUNCALL form,
 117     ;; and the ANSI standard doesn't seem to say anything else which
 118     ;; would justify us expanding the compiler macro the way the user
 119     ;; wants. So instead we rely on 3.2.2.1.3 "When Compiler Macros Are
 120     ;; Used" which says they never have to be used, so by ignoring such
 121     ;; macros we're erring on the safe side. But any user who does
 122     ;; (DEFINE-COMPILER-MACRO (SETF FOO) ...) could easily be surprised
 123     ;; by this way of complying with a rather screwy aspect of the ANSI
 124     ;; spec, so at least we can warn him...
 125     (sb!c::compiler-style-warn
 126      "defining compiler macro of (SETF ...), which will not be expanded"))
 127   (when (and (symbolp name) (special-operator-p name))
 128     (error 'simple-program-error
 129            :format-control "cannot define a compiler-macro for a special operator: ~S"
 130            :format-arguments (list name)))
 131   (let ((whole (gensym "WHOLE-"))
 132         (environment (gensym "ENV-")))
 133     (multiple-value-bind (body local-decs doc)
 134         (parse-defmacro lambda-list whole body name 'define-compiler-macro
 135                         :environment environment)
 136       (let ((def `(lambda (,whole ,environment)
 137                     ,@local-decs
 138                     (block ,(fun-name-block-name name)
 139                       ,body)))
 140             (debug-name (debug-namify "DEFINE-COMPILER-MACRO ~S" name)))
 141         `(eval-when (:compile-toplevel :load-toplevel :execute)
 142           (sb!c::%define-compiler-macro ',name #',def ',lambda-list ,doc ,debug-name))))))
 143
 144 ;;; FIXME: This will look remarkably similar to those who have already
 145 ;;; seen the code for %DEFMACRO in src/code/defmacro.lisp.  Various
 146 ;;; bits of logic should be shared (notably arglist setting).
 147 (macrolet
 148     ((def (times set-p)
 149          `(eval-when (,@times)
 150            (defun sb!c::%define-compiler-macro
 151                (name definition lambda-list doc debug-name)
 152              ,@(unless set-p
 153                  '((declare (ignore lambda-list debug-name))))
 154              ;; FIXME: warn about incompatible lambda list with
 155              ;; respect to parent function?
 156              (setf (sb!xc:compiler-macro-function name) definition)
 157              ;; FIXME: Add support for (SETF FDOCUMENTATION) when
 158              ;; object is a list and type is COMPILER-MACRO. (Until
 159              ;; then, we have to discard any compiler macro
 160              ;; documentation for (SETF FOO).)
 161              (unless (listp name)
 162                (setf (fdocumentation name 'compiler-macro) doc))
 163              ,(when set-p
 164                     `(case (widetag-of definition)
 165                       (#.sb!vm:closure-header-widetag
 166                        (setf (%simple-fun-arglist (%closure-fun definition))
 167                              lambda-list
 168                              (%simple-fun-name (%closure-fun definition))
 169                              debug-name))
 170                       ((#.sb!vm:simple-fun-header-widetag
 171                         #.sb!vm:closure-fun-header-widetag)
 172                        (setf (%simple-fun-arglist definition) lambda-list
 173                              (%simple-fun-name definition) debug-name))))
 174              name))))
 175   (progn
 176     (def (:load-toplevel :execute) #-sb-xc-host t #+sb-xc-host nil)
 177     (def (:compile-toplevel) nil)))
 178 \f
 179 ;;;; CASE, TYPECASE, and friends
 180
 181 (eval-when (:compile-toplevel :load-toplevel :execute)
 182
 183 ;;; CASE-BODY returns code for all the standard "case" macros. NAME is
 184 ;;; the macro name, and KEYFORM is the thing to case on. MULTI-P
 185 ;;; indicates whether a branch may fire off a list of keys; otherwise,
 186 ;;; a key that is a list is interpreted in some way as a single key.
 187 ;;; When MULTI-P, TEST is applied to the value of KEYFORM and each key
 188 ;;; for a given branch; otherwise, TEST is applied to the value of
 189 ;;; KEYFORM and the entire first element, instead of each part, of the
 190 ;;; case branch. When ERRORP, no T or OTHERWISE branch is permitted,
 191 ;;; and an ERROR form is generated. When PROCEEDP, it is an error to
 192 ;;; omit ERRORP, and the ERROR form generated is executed within a
 193 ;;; RESTART-CASE allowing KEYFORM to be set and retested.
 194 (defun case-body (name keyform cases multi-p test errorp proceedp needcasesp)
 195   (unless (or cases (not needcasesp))
 196     (warn "no clauses in ~S" name))
 197   (let ((keyform-value (gensym))
 198         (clauses ())
 199         (keys ()))
 200     (dolist (case cases)
 201       (unless (list-of-length-at-least-p case 1)
 202         (error "~S -- bad clause in ~S" case name))
 203       (destructuring-bind (keyoid &rest forms) case
 204         (cond ((memq keyoid '(t otherwise))
 205                (if errorp
 206                    (progn
 207                      ;; FIXME: this message could probably do with
 208                      ;; some loving pretty-printer format controls.
 209                      (style-warn "Treating bare ~A in ~A as introducing a normal-clause, not an otherwise-clause" keyoid name)
 210                      (push keyoid keys)
 211                      (push `((,test ,keyform-value ',keyoid) nil ,@forms)
 212                            clauses))
 213                    (push `(t nil ,@forms) clauses)))
 214               ((and multi-p (listp keyoid))
 215                (setf keys (append keyoid keys))
 216                (push `((or ,@(mapcar (lambda (key)
 217                                        `(,test ,keyform-value ',key))
 218                                      keyoid))
 219                        nil
 220                        ,@forms)
 221                      clauses))
 222               (t
 223                (push keyoid keys)
 224                (push `((,test ,keyform-value ',keyoid)
 225                        nil
 226                        ,@forms)
 227                      clauses)))))
 228     (case-body-aux name keyform keyform-value clauses keys errorp proceedp
 229                    `(,(if multi-p 'member 'or) ,@keys))))
 230
 231 ;;; CASE-BODY-AUX provides the expansion once CASE-BODY has groveled
 232 ;;; all the cases. Note: it is not necessary that the resulting code
 233 ;;; signal case-failure conditions, but that's what KMP's prototype
 234 ;;; code did. We call CASE-BODY-ERROR, because of how closures are
 235 ;;; compiled. RESTART-CASE has forms with closures that the compiler
 236 ;;; causes to be generated at the top of any function using the case
 237 ;;; macros, regardless of whether they are needed.
 238 ;;;
 239 ;;; The CASE-BODY-ERROR function is defined later, when the
 240 ;;; RESTART-CASE macro has been defined.
 241 (defun case-body-aux (name keyform keyform-value clauses keys
 242                       errorp proceedp expected-type)
 243   (if proceedp
 244       (let ((block (gensym))
 245             (again (gensym)))
 246         `(let ((,keyform-value ,keyform))
 247            (block ,block
 248              (tagbody
 249               ,again
 250               (return-from
 251                ,block
 252                (cond ,@(nreverse clauses)
 253                      (t
 254                       (setf ,keyform-value
 255                             (setf ,keyform
 256                                   (case-body-error
 257                                    ',name ',keyform ,keyform-value
 258                                    ',expected-type ',keys)))
 259                       (go ,again))))))))
 260       `(let ((,keyform-value ,keyform))
 261          (declare (ignorable ,keyform-value)) ; e.g. (CASE KEY (T))
 262          (cond
 263           ,@(nreverse clauses)
 264           ,@(if errorp
 265                 `((t (error 'case-failure
 266                             :name ',name
 267                             :datum ,keyform-value
 268                             :expected-type ',expected-type
 269                             :possibilities ',keys))))))))
 270 ) ; EVAL-WHEN
 271
 272 (defmacro-mundanely case (keyform &body cases)
 273   #!+sb-doc
 274   "CASE Keyform {({(Key*) | Key} Form*)}*
 275   Evaluates the Forms in the first clause with a Key EQL to the value of
 276   Keyform. If a singleton key is T then the clause is a default clause."
 277   (case-body 'case keyform cases t 'eql nil nil nil))
 278
 279 (defmacro-mundanely ccase (keyform &body cases)
 280   #!+sb-doc
 281   "CCASE Keyform {({(Key*) | Key} Form*)}*
 282   Evaluates the Forms in the first clause with a Key EQL to the value of
 283   Keyform. If none of the keys matches then a correctable error is
 284   signalled."
 285   (case-body 'ccase keyform cases t 'eql t t t))
 286
 287 (defmacro-mundanely ecase (keyform &body cases)
 288   #!+sb-doc
 289   "ECASE Keyform {({(Key*) | Key} Form*)}*
 290   Evaluates the Forms in the first clause with a Key EQL to the value of
 291   Keyform. If none of the keys matches then an error is signalled."
 292   (case-body 'ecase keyform cases t 'eql t nil t))
 293
 294 (defmacro-mundanely typecase (keyform &body cases)
 295   #!+sb-doc
 296   "TYPECASE Keyform {(Type Form*)}*
 297   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 298   is true."
 299   (case-body 'typecase keyform cases nil 'typep nil nil nil))
 300
 301 (defmacro-mundanely ctypecase (keyform &body cases)
 302   #!+sb-doc
 303   "CTYPECASE Keyform {(Type Form*)}*
 304   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 305   is true. If no form is satisfied then a correctable error is signalled."
 306   (case-body 'ctypecase keyform cases nil 'typep t t t))
 307
 308 (defmacro-mundanely etypecase (keyform &body cases)
 309   #!+sb-doc
 310   "ETYPECASE Keyform {(Type Form*)}*
 311   Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
 312   is true. If no form is satisfied then an error is signalled."
 313   (case-body 'etypecase keyform cases nil 'typep t nil t))
 314 \f
 315 ;;;; WITH-FOO i/o-related macros
 316
 317 (defmacro-mundanely with-open-stream ((var stream) &body forms-decls)
 318   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 319     (let ((abortp (gensym)))
 320       `(let ((,var ,stream)
 321              (,abortp t))
 322          ,@decls
 323          (unwind-protect
 324              (multiple-value-prog1
 325               (progn ,@forms)
 326               (setq ,abortp nil))
 327            (when ,var
 328              (close ,var :abort ,abortp)))))))
 329
 330 (defmacro-mundanely with-open-file ((stream filespec &rest options)
 331                                     &body body)
 332   `(with-open-stream (,stream (open ,filespec ,@options))
 333      ,@body))
 334
 335 (defmacro-mundanely with-input-from-string ((var string &key index start end)
 336                                             &body forms-decls)
 337   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 338     ;; The ONCE-ONLY inhibits compiler note for unreachable code when
 339     ;; END is true.
 340     (once-only ((string string))
 341       `(let ((,var
 342               ,(cond ((null end)
 343                       `(make-string-input-stream ,string ,(or start 0)))
 344                      ((symbolp end)
 345                       `(if ,end
 346                            (make-string-input-stream ,string
 347                                                      ,(or start 0)
 348                                                      ,end)
 349                            (make-string-input-stream ,string
 350                                                      ,(or start 0))))
 351                      (t
 352                       `(make-string-input-stream ,string
 353                                                  ,(or start 0)
 354                                                  ,end)))))
 355          ,@decls
 356          (unwind-protect
 357              (progn ,@forms)
 358            (close ,var)
 359            ,@(when index
 360                `((setf ,index (string-input-stream-current ,var)))))))))
 361
 362 (defmacro-mundanely with-output-to-string ((var &optional string)
 363                                            &body forms-decls)
 364   (multiple-value-bind (forms decls) (parse-body forms-decls nil)
 365     (if string
 366       `(let ((,var (make-fill-pointer-output-stream ,string)))
 367          ,@decls
 368          (unwind-protect
 369              (progn ,@forms)
 370            (close ,var)))
 371       `(let ((,var (make-string-output-stream)))
 372          ,@decls
 373          (unwind-protect
 374              (progn ,@forms)
 375            (close ,var))
 376          (get-output-stream-string ,var)))))
 377 \f
 378 ;;;; miscellaneous macros
 379
 380 (defmacro-mundanely nth-value (n form)
 381   #!+sb-doc
 382   "Evaluate FORM and return the Nth value (zero based). This involves no
 383   consing when N is a trivial constant integer."
 384   (if (integerp n)
 385       (let ((dummy-list nil)
 386             (keeper (gensym "KEEPER-")))
 387         ;; We build DUMMY-LIST, a list of variables to bind to useless
 388         ;; values, then we explicitly IGNORE those bindings and return
 389         ;; KEEPER, the only thing we're really interested in right now.
 390         (dotimes (i n)
 391           (push (gensym "IGNORE-") dummy-list))
 392         `(multiple-value-bind (,@dummy-list ,keeper) ,form
 393            (declare (ignore ,@dummy-list))
 394            ,keeper))
 395       (once-only ((n n))
 396         `(case (the fixnum ,n)
 397            (0 (nth-value 0 ,form))
 398            (1 (nth-value 1 ,form))
 399            (2 (nth-value 2 ,form))
 400            (t (nth (the fixnum ,n) (multiple-value-list ,form)))))))
 401
 402 (defmacro-mundanely declaim (&rest specs)
 403   #!+sb-doc
 404   "DECLAIM Declaration*
 405   Do a declaration or declarations for the global environment."
 406   `(eval-when (:compile-toplevel :load-toplevel :execute)
 407      ,@(mapcar (lambda (spec) `(sb!xc:proclaim ',spec))
 408                specs)))
 409
 410 (defmacro-mundanely print-unreadable-object ((object stream &key type identity)
 411                                              &body body)
 412   "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
 413   with object-type prefix and object-identity suffix, and executing the
 414   code in BODY to provide possible further output."
 415   `(%print-unreadable-object ,object ,stream ,type ,identity
 416                              ,(if body
 417                                   `(lambda () ,@body)
 418                                   nil)))
 419
 420 (defmacro-mundanely ignore-errors (&rest forms)
 421   #!+sb-doc
 422   "Execute FORMS handling ERROR conditions, returning the result of the last
 423   form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
 424   `(handler-case (progn ,@forms)
 425      (error (condition) (values nil condition))))