src/code/ntrace.lisp

   1 ;;;; a tracing facility based on breakpoints
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB-DEBUG") ; (SB-, not SB!, since we're built in warm load.)
  13
  14 ;;; FIXME: Why, oh why, doesn't the SB-DEBUG package use the SB-DI
  15 ;;; package? That would let us get rid of a whole lot of stupid
  16 ;;; prefixes..
  17
  18 (defvar *trace-values* nil
  19   #+sb-doc
  20   "This is bound to the returned values when evaluating :BREAK-AFTER and
  21    :PRINT-AFTER forms.")
  22
  23 (defvar *trace-indentation-step* 2
  24   #+sb-doc
  25   "the increase in trace indentation at each call level")
  26
  27 (defvar *max-trace-indentation* 40
  28   #+sb-doc
  29   "If the trace indentation exceeds this value, then indentation restarts at
  30    0.")
  31
  32 (defvar *trace-encapsulate-default* t
  33   #+sb-doc
  34   "the default value for the :ENCAPSULATE option to TRACE")
  35 \f
  36 ;;;; internal state
  37
  38 ;;; a hash table that maps each traced function to the TRACE-INFO. The
  39 ;;; entry for a closure is the shared function entry object.
  40 (defvar *traced-funs* (make-hash-table :test 'eq))
  41
  42 ;;; A TRACE-INFO object represents all the information we need to
  43 ;;; trace a given function.
  44 (def!struct (trace-info
  45              (:make-load-form-fun sb-kernel:just-dump-it-normally)
  46              (:print-object (lambda (x stream)
  47                               (print-unreadable-object (x stream :type t)
  48                                 (prin1 (trace-info-what x) stream)))))
  49   ;; the original representation of the thing traced
  50   (what nil :type (or function cons symbol))
  51   ;; Is WHAT a function name whose definition we should track?
  52   (named nil)
  53   ;; Is tracing to be done by encapsulation rather than breakpoints?
  54   ;; T implies NAMED.
  55   (encapsulated *trace-encapsulate-default*)
  56   ;; Has this trace been untraced?
  57   (untraced nil)
  58   ;; breakpoints we set up to trigger tracing
  59   (start-breakpoint nil :type (or sb-di:breakpoint null))
  60   (end-breakpoint nil :type (or sb-di:breakpoint null))
  61   ;; the list of function names for WHEREIN, or NIL if unspecified
  62   (wherein nil :type list)
  63
  64   ;; The following slots represent the forms that we are supposed to
  65   ;; evaluate on each iteration. Each form is represented by a cons
  66   ;; (Form . Function), where the Function is the cached result of
  67   ;; coercing Form to a function. Forms which use the current
  68   ;; environment are converted with PREPROCESS-FOR-EVAL, which gives
  69   ;; us a one-arg function. Null environment forms also have one-arg
  70   ;; functions, but the argument is ignored. NIL means unspecified
  71   ;; (the default.)
  72
  73   ;; current environment forms
  74   (condition nil)
  75   (break nil)
  76   ;; List of current environment forms
  77   (print () :type list)
  78   ;; null environment forms
  79   (condition-after nil)
  80   (break-after nil)
  81   ;; list of null environment forms
  82   (print-after () :type list))
  83
  84 ;;; This is a list of conses (fun-end-cookie . condition-satisfied),
  85 ;;; which we use to note distinct dynamic entries into functions. When
  86 ;;; we enter a traced function, we add a entry to this list holding
  87 ;;; the new end-cookie and whether the trace condition was satisfied.
  88 ;;; We must save the trace condition so that the after breakpoint
  89 ;;; knows whether to print. The length of this list tells us the
  90 ;;; indentation to use for printing TRACE messages.
  91 ;;;
  92 ;;; This list also helps us synchronize the TRACE facility dynamically
  93 ;;; for detecting non-local flow of control. Whenever execution hits a
  94 ;;; :FUN-END breakpoint used for TRACE'ing, we look for the
  95 ;;; FUN-END-COOKIE at the top of *TRACED-ENTRIES*. If it is not
  96 ;;; there, we discard any entries that come before our cookie.
  97 ;;;
  98 ;;; When we trace using encapsulation, we bind this variable and add
  99 ;;; (NIL . CONDITION-SATISFIED), so a NIL "cookie" marks an
 100 ;;; encapsulated tracing.
 101 (defvar *traced-entries* ())
 102 (declaim (list *traced-entries*))
 103
 104 ;;; This variable is used to discourage infinite recursions when some
 105 ;;; trace action invokes a function that is itself traced. In this
 106 ;;; case, we quietly ignore the inner tracing.
 107 (defvar *in-trace* nil)
 108 \f
 109 ;;;; utilities
 110
 111 ;;; Given a function name, a function or a macro name, return the raw
 112 ;;; definition and some information. "Raw" means that if the result is
 113 ;;; a closure, we strip off the closure and return the bare code. The
 114 ;;; second value is T if the argument was a function name. The third
 115 ;;; value is one of :COMPILED, :COMPILED-CLOSURE, :INTERPRETED,
 116 ;;; :INTERPRETED-CLOSURE and :FUNCALLABLE-INSTANCE.
 117 (defun trace-fdefinition (x)
 118   (multiple-value-bind (res named-p)
 119       (typecase x
 120         (symbol
 121          (cond ((special-operator-p x)
 122                 (error "can't trace special form ~S" x))
 123                ((macro-function x))
 124                (t
 125                 (values (fdefinition x) t))))
 126         (function x)
 127         (t (values (fdefinition x) t)))
 128     (case (sb-kernel:widetag-of res)
 129       (#.sb-vm:closure-header-widetag
 130        (values (sb-kernel:%closure-fun res)
 131                named-p
 132                :compiled-closure))
 133       (#.sb-vm:funcallable-instance-header-widetag
 134        (values res named-p :funcallable-instance))
 135       (t (values res named-p :compiled)))))
 136
 137 ;;; When a function name is redefined, and we were tracing that name,
 138 ;;; then untrace the old definition and trace the new one.
 139 (defun trace-redefined-update (fname new-value)
 140   (when (fboundp fname)
 141     (let* ((fun (trace-fdefinition fname))
 142            (info (gethash fun *traced-funs*)))
 143       (when (and info (trace-info-named info))
 144         (untrace-1 fname)
 145         (trace-1 fname info new-value)))))
 146 (push #'trace-redefined-update *setf-fdefinition-hook*)
 147
 148 ;;; Annotate a FORM to evaluate with pre-converted functions. FORM is
 149 ;;; really a cons (EXP . FUNCTION). LOC is the code location to use
 150 ;;; for the lexical environment. If LOC is NIL, evaluate in the null
 151 ;;; environment. If FORM is NIL, just return NIL.
 152 (defun coerce-form (form loc)
 153   (when form
 154     (let ((exp (car form)))
 155       (if (sb-di:code-location-p loc)
 156           (let ((fun (sb-di:preprocess-for-eval exp loc)))
 157             (cons exp
 158                   (lambda (frame)
 159                     (let ((*current-frame* frame))
 160                       (funcall fun frame)))))
 161           (let* ((bod (ecase loc
 162                         ((nil) exp)
 163                         (:encapsulated
 164                          `(flet ((sb-debug:arg (n)
 165                                    (declare (special arg-list))
 166                                    (elt arg-list n)))
 167                             (declare (ignorable #'sb-debug:arg))
 168                             ,exp))))
 169                  (fun (coerce `(lambda () ,bod) 'function)))
 170             (cons exp
 171                   (lambda (frame)
 172                     (declare (ignore frame))
 173                     (let ((*current-frame* nil))
 174                       (funcall fun)))))))))
 175
 176 (defun coerce-form-list (forms loc)
 177   (mapcar (lambda (x) (coerce-form x loc)) forms))
 178
 179 ;;; Print indentation according to the number of trace entries.
 180 ;;; Entries whose condition was false don't count.
 181 (defun print-trace-indentation ()
 182   (let ((depth 0))
 183     (dolist (entry *traced-entries*)
 184       (when (cdr entry) (incf depth)))
 185     (format t
 186             "~V,0@T~W: "
 187             (+ (mod (* depth *trace-indentation-step*)
 188                     (- *max-trace-indentation* *trace-indentation-step*))
 189                *trace-indentation-step*)
 190             depth)))
 191
 192 ;;; Return true if any of the NAMES appears on the stack below FRAME.
 193 (defun trace-wherein-p (frame names)
 194   (do ((frame (sb-di:frame-down frame) (sb-di:frame-down frame)))
 195       ((not frame) nil)
 196     (when (member (sb-di:debug-fun-name (sb-di:frame-debug-fun frame))
 197                   names
 198                   :test #'equal)
 199       (return t))))
 200
 201 ;;; Handle PRINT and PRINT-AFTER options.
 202 (defun trace-print (frame forms)
 203   (dolist (ele forms)
 204     (fresh-line)
 205     (print-trace-indentation)
 206     (format t "~@<~S ~_= ~S~:>" (car ele) (funcall (cdr ele) frame))))
 207
 208 ;;; Test a BREAK option, and break if true.
 209 (defun trace-maybe-break (info break where frame)
 210   (when (and break (funcall (cdr break) frame))
 211     (sb-di:flush-frames-above frame)
 212     (let ((*stack-top-hint* frame))
 213       (break "breaking ~A traced call to ~S:"
 214              where
 215              (trace-info-what info)))))
 216
 217 ;;; Discard any invalid cookies on our simulated stack. Encapsulated
 218 ;;; entries are always valid, since we bind *TRACED-ENTRIES* in the
 219 ;;; encapsulation.
 220 (defun discard-invalid-entries (frame)
 221   (loop
 222     (when (or (null *traced-entries*)
 223               (let ((cookie (caar *traced-entries*)))
 224                 (or (not cookie)
 225                     (sb-di:fun-end-cookie-valid-p frame cookie))))
 226       (return))
 227     (pop *traced-entries*)))
 228 \f
 229 ;;;; hook functions
 230
 231 ;;; Return a closure that can be used for a function start breakpoint
 232 ;;; hook function and a closure that can be used as the
 233 ;;; FUN-END-COOKIE function. The first communicates the sense of
 234 ;;; the Condition to the second via a closure variable.
 235 (defun trace-start-breakpoint-fun (info)
 236   (let (conditionp)
 237     (values
 238
 239      (lambda (frame bpt)
 240        (declare (ignore bpt))
 241        (discard-invalid-entries frame)
 242        (let ((condition (trace-info-condition info))
 243              (wherein (trace-info-wherein info)))
 244          (setq conditionp
 245                (and (not *in-trace*)
 246                     (or (not condition)
 247                         (funcall (cdr condition) frame))
 248                     (or (not wherein)
 249                         (trace-wherein-p frame wherein)))))
 250        (when conditionp
 251          (let ((sb-kernel:*current-level-in-print* 0)
 252                (*standard-output* *trace-output*)
 253                (*in-trace* t))
 254            (fresh-line)
 255            (print-trace-indentation)
 256            (if (trace-info-encapsulated info)
 257                ;; FIXME: These special variables should be given
 258                ;; *FOO*-style names, and probably declared globally
 259                ;; with DEFVAR.
 260                (locally
 261                  (declare (special basic-definition arg-list))
 262                  (prin1 `(,(trace-info-what info) ,@arg-list)))
 263                (print-frame-call frame))
 264            (terpri)
 265            (trace-print frame (trace-info-print info)))
 266          (trace-maybe-break info (trace-info-break info) "before" frame)))
 267
 268      (lambda (frame cookie)
 269        (declare (ignore frame))
 270        (push (cons cookie conditionp) *traced-entries*)))))
 271
 272 ;;; This prints a representation of the return values delivered.
 273 ;;; First, this checks to see that cookie is at the top of
 274 ;;; *TRACED-ENTRIES*; if it is not, then we need to adjust this list
 275 ;;; to determine the correct indentation for output. We then check to
 276 ;;; see whether the function is still traced and that the condition
 277 ;;; succeeded before printing anything.
 278 (defun trace-end-breakpoint-fun (info)
 279   (lambda (frame bpt *trace-values* cookie)
 280     (declare (ignore bpt))
 281     (unless (eq cookie (caar *traced-entries*))
 282       (setf *traced-entries*
 283             (member cookie *traced-entries* :key #'car)))
 284
 285     (let ((entry (pop *traced-entries*)))
 286       (when (and (not (trace-info-untraced info))
 287                  (or (cdr entry)
 288                      (let ((cond (trace-info-condition-after info)))
 289                        (and cond (funcall (cdr cond) frame)))))
 290         (let ((sb-kernel:*current-level-in-print* 0)
 291               (*standard-output* *trace-output*)
 292               (*in-trace* t))
 293           (fresh-line)
 294           (pprint-logical-block (*standard-output* nil)
 295             (print-trace-indentation)
 296             (pprint-indent :current 2)
 297             (format t "~S returned" (trace-info-what info))
 298             (dolist (v *trace-values*)
 299               (write-char #\space)
 300               (pprint-newline :linear)
 301               (prin1 v)))
 302           (terpri)
 303           (trace-print frame (trace-info-print-after info)))
 304         (trace-maybe-break info
 305                            (trace-info-break-after info)
 306                            "after"
 307                            frame)))))
 308 \f
 309 ;;; This function is called by the trace encapsulation. It calls the
 310 ;;; breakpoint hook functions with NIL for the breakpoint and cookie,
 311 ;;; which we have cleverly contrived to work for our hook functions.
 312 (defun trace-call (info)
 313   (multiple-value-bind (start cookie) (trace-start-breakpoint-fun info)
 314     (let ((frame (sb-di:frame-down (sb-di:top-frame))))
 315       (funcall start frame nil)
 316       (let ((*traced-entries* *traced-entries*))
 317         (declare (special basic-definition arg-list))
 318         (funcall cookie frame nil)
 319         (let ((vals
 320                (multiple-value-list
 321                 (apply basic-definition arg-list))))
 322           (funcall (trace-end-breakpoint-fun info) frame nil vals nil)
 323           (values-list vals))))))
 324 \f
 325 ;;; Trace one function according to the specified options. We copy the
 326 ;;; trace info (it was a quoted constant), fill in the functions, and
 327 ;;; then install the breakpoints or encapsulation.
 328 ;;;
 329 ;;; If non-null, DEFINITION is the new definition of a function that
 330 ;;; we are automatically retracing.
 331 (defun trace-1 (function-or-name info &optional definition)
 332   (multiple-value-bind (fun named kind)
 333       (if definition
 334           (values definition t
 335                   (nth-value 2 (trace-fdefinition definition)))
 336           (trace-fdefinition function-or-name))
 337     (when (gethash fun *traced-funs*)
 338       (warn "~S is already TRACE'd, untracing it." function-or-name)
 339       (untrace-1 fun))
 340
 341     (let* ((debug-fun (sb-di:fun-debug-fun fun))
 342            (encapsulated
 343             (if (eq (trace-info-encapsulated info) :default)
 344                 (ecase kind
 345                   (:compiled nil)
 346                   (:compiled-closure
 347                    (unless (functionp function-or-name)
 348                      (warn "tracing shared code for ~S:~%  ~S"
 349                            function-or-name
 350                            fun))
 351                    nil)
 352                   ((:interpreted :interpreted-closure :funcallable-instance)
 353                    t))
 354                 (trace-info-encapsulated info)))
 355            (loc (if encapsulated
 356                     :encapsulated
 357                     (sb-di:debug-fun-start-location debug-fun)))
 358            (info (make-trace-info
 359                   :what function-or-name
 360                   :named named
 361                   :encapsulated encapsulated
 362                   :wherein (trace-info-wherein info)
 363                   :condition (coerce-form (trace-info-condition info) loc)
 364                   :break (coerce-form (trace-info-break info) loc)
 365                   :print (coerce-form-list (trace-info-print info) loc)
 366                   :break-after (coerce-form (trace-info-break-after info) nil)
 367                   :condition-after
 368                   (coerce-form (trace-info-condition-after info) nil)
 369                   :print-after
 370                   (coerce-form-list (trace-info-print-after info) nil))))
 371
 372       (dolist (wherein (trace-info-wherein info))
 373         (unless (or (stringp wherein)
 374                     (fboundp wherein))
 375           (warn ":WHEREIN name ~S is not a defined global function."
 376                 wherein)))
 377
 378       (cond
 379        (encapsulated
 380         (unless named
 381           (error "can't use encapsulation to trace anonymous function ~S"
 382                  fun))
 383         (encapsulate function-or-name 'trace `(trace-call ',info)))
 384        (t
 385         (multiple-value-bind (start-fun cookie-fun)
 386             (trace-start-breakpoint-fun info)
 387           (let ((start (sb-di:make-breakpoint start-fun debug-fun
 388                                               :kind :fun-start))
 389                 (end (sb-di:make-breakpoint
 390                       (trace-end-breakpoint-fun info)
 391                       debug-fun :kind :fun-end
 392                       :fun-end-cookie cookie-fun)))
 393             (setf (trace-info-start-breakpoint info) start)
 394             (setf (trace-info-end-breakpoint info) end)
 395             ;; The next two forms must be in the order in which they
 396             ;; appear, since the start breakpoint must run before the
 397             ;; fun-end breakpoint's start helper (which calls the
 398             ;; cookie function.) One reason is that cookie function
 399             ;; requires that the CONDITIONP shared closure variable be
 400             ;; initialized.
 401             (sb-di:activate-breakpoint start)
 402             (sb-di:activate-breakpoint end)))))
 403
 404       (setf (gethash fun *traced-funs*) info)))
 405
 406   function-or-name)
 407 \f
 408 ;;;; the TRACE macro
 409
 410 ;;; Parse leading trace options off of SPECS, modifying INFO
 411 ;;; accordingly. The remaining portion of the list is returned when we
 412 ;;; encounter a plausible function name.
 413 (defun parse-trace-options (specs info)
 414   (let ((current specs))
 415     (loop
 416       (when (endp current) (return))
 417       (let ((option (first current))
 418             (value (cons (second current) nil)))
 419         (case option
 420           (:report (error "stub: The :REPORT option is not yet implemented."))
 421           (:condition (setf (trace-info-condition info) value))
 422           (:condition-after
 423            (setf (trace-info-condition info) (cons nil nil))
 424            (setf (trace-info-condition-after info) value))
 425           (:condition-all
 426            (setf (trace-info-condition info) value)
 427            (setf (trace-info-condition-after info) value))
 428           (:wherein
 429            (setf (trace-info-wherein info)
 430                  (if (listp (car value)) (car value) value)))
 431           (:encapsulate
 432            (setf (trace-info-encapsulated info) (car value)))
 433           (:break (setf (trace-info-break info) value))
 434           (:break-after (setf (trace-info-break-after info) value))
 435           (:break-all
 436            (setf (trace-info-break info) value)
 437            (setf (trace-info-break-after info) value))
 438           (:print
 439            (setf (trace-info-print info)
 440                  (append (trace-info-print info) (list value))))
 441           (:print-after
 442            (setf (trace-info-print-after info)
 443                  (append (trace-info-print-after info) (list value))))
 444           (:print-all
 445            (setf (trace-info-print info)
 446                  (append (trace-info-print info) (list value)))
 447            (setf (trace-info-print-after info)
 448                  (append (trace-info-print-after info) (list value))))
 449           (t (return)))
 450         (pop current)
 451         (unless current
 452           (error "missing argument to ~S TRACE option" option))
 453         (pop current)))
 454     current))
 455
 456 ;;; Compute the expansion of TRACE in the non-trivial case (arguments
 457 ;;; specified.) If there are no :FUNCTION specs, then don't use a LET.
 458 ;;; This allows TRACE to be used without the full interpreter.
 459 (defun expand-trace (specs)
 460   (collect ((binds)
 461             (forms))
 462     (let* ((global-options (make-trace-info))
 463            (current (parse-trace-options specs global-options)))
 464       (loop
 465         (when (endp current) (return))
 466         (let ((name (pop current))
 467               (options (copy-trace-info global-options)))
 468           (cond
 469            ((eq name :function)
 470             (let ((temp (gensym)))
 471               (binds `(,temp ,(pop current)))
 472               (forms `(trace-1 ,temp ',options))))
 473            ((and (keywordp name)
 474                  (not (or (fboundp name) (macro-function name))))
 475             (error "unknown TRACE option: ~S" name))
 476            (t
 477             (forms `(trace-1 ',name ',options))))
 478           (setq current (parse-trace-options current options)))))
 479
 480     (if (binds)
 481         `(let ,(binds) (list ,@(forms)))
 482         `(list ,@(forms)))))
 483
 484 (defun %list-traced-funs ()
 485   (loop for x being each hash-value in *traced-funs*
 486         collect (trace-info-what x)))
 487
 488 (defmacro trace (&rest specs)
 489   #+sb-doc
 490   "TRACE {Option Global-Value}* {Name {Option Value}*}*
 491    TRACE is a debugging tool that provides information when specified functions
 492    are called. In its simplest form:
 493        (trace Name-1 Name-2 ...)
 494    (The Names are not evaluated.)
 495
 496    Options allow modification of the default behavior. Each option is a pair
 497    of an option keyword and a value form. Global options are specified before
 498    the first name, and affect all functions traced by a given use of TRACE.
 499    Options may also be interspersed with function names, in which case they
 500    act as local options, only affecting tracing of the immediately preceding
 501    function name. Local options override global options.
 502
 503    By default, TRACE causes a printout on *TRACE-OUTPUT* each time that
 504    one of the named functions is entered or returns. (This is the
 505    basic, ANSI Common Lisp behavior of TRACE.) As an SBCL extension, the
 506    :REPORT SB-EXT:PROFILE option can be used to instead cause information
 507    to be silently recorded to be inspected later using the SB-EXT:PROFILE
 508    function.
 509
 510    The following options are defined:
 511
 512    :REPORT Report-Type
 513        If Report-Type is TRACE (the default) then information is reported
 514        by printing immediately. If Report-Type is SB-EXT:PROFILE, information
 515        is recorded for later summary by calls to SB-EXT:PROFILE. If
 516        Report-Type is NIL, then the only effect of the trace is to execute
 517        other options (e.g. PRINT or BREAK).
 518
 519    :CONDITION Form
 520    :CONDITION-AFTER Form
 521    :CONDITION-ALL Form
 522        If :CONDITION is specified, then TRACE does nothing unless Form
 523        evaluates to true at the time of the call. :CONDITION-AFTER is
 524        similar, but suppresses the initial printout, and is tested when the
 525        function returns. :CONDITION-ALL tries both before and after.
 526
 527    :BREAK Form
 528    :BREAK-AFTER Form
 529    :BREAK-ALL Form
 530        If specified, and Form evaluates to true, then the debugger is invoked
 531        at the start of the function, at the end of the function, or both,
 532        according to the respective option.
 533
 534    :PRINT Form
 535    :PRINT-AFTER Form
 536    :PRINT-ALL Form
 537        In addition to the usual printout, the result of evaluating Form is
 538        printed at the start of the function, at the end of the function, or
 539        both, according to the respective option. Multiple print options cause
 540        multiple values to be printed.
 541
 542    :WHEREIN Names
 543        If specified, Names is a function name or list of names. TRACE does
 544        nothing unless a call to one of those functions encloses the call to
 545        this function (i.e. it would appear in a backtrace.)  Anonymous
 546        functions have string names like \"DEFUN FOO\".
 547
 548    :ENCAPSULATE {:DEFAULT | T | NIL}
 549        If T, the tracing is done via encapsulation (redefining the function
 550        name) rather than by modifying the function. :DEFAULT is the default,
 551        and means to use encapsulation for interpreted functions and funcallable
 552        instances, breakpoints otherwise. When encapsulation is used, forms are
 553        *not* evaluated in the function's lexical environment, but SB-DEBUG:ARG
 554        can still be used.
 555
 556    :FUNCTION Function-Form
 557        This is a not really an option, but rather another way of specifying
 558        what function to trace. The Function-Form is evaluated immediately,
 559        and the resulting function is traced.
 560
 561    :CONDITION, :BREAK and :PRINT forms are evaluated in the lexical environment
 562    of the called function; SB-DEBUG:VAR and SB-DEBUG:ARG can be used. The
 563    -AFTER and -ALL forms are evaluated in the null environment."
 564   (if specs
 565       (expand-trace specs)
 566       '(%list-traced-funs)))
 567 \f
 568 ;;;; untracing
 569
 570 ;;; Untrace one function.
 571 (defun untrace-1 (function-or-name)
 572   (let* ((fun (trace-fdefinition function-or-name))
 573          (info (gethash fun *traced-funs*)))
 574     (cond
 575      ((not info)
 576       (warn "Function is not TRACEd: ~S" function-or-name))
 577      (t
 578       (cond
 579        ((trace-info-encapsulated info)
 580         (unencapsulate (trace-info-what info) 'trace))
 581        (t
 582         (sb-di:delete-breakpoint (trace-info-start-breakpoint info))
 583         (sb-di:delete-breakpoint (trace-info-end-breakpoint info))))
 584       (setf (trace-info-untraced info) t)
 585       (remhash fun *traced-funs*)))))
 586
 587 ;;; Untrace all traced functions.
 588 (defun untrace-all ()
 589   (dolist (fun (%list-traced-funs))
 590     (untrace-1 fun))
 591   t)
 592
 593 (defmacro untrace (&rest specs)
 594   #+sb-doc
 595   "Remove tracing from the specified functions. With no args, untrace all
 596    functions."
 597   (if specs
 598       (collect ((res))
 599         (let ((current specs))
 600           (loop
 601             (unless current (return))
 602             (let ((name (pop current)))
 603               (res (if (eq name :function)
 604                        `(untrace-1 ,(pop current))
 605                        `(untrace-1 ',name)))))
 606           `(progn ,@(res) t)))
 607       '(untrace-all)))