src/code/package.lisp

   1 ;;;; that part of the CMU CL package.lisp file which can run on the
   2 ;;;; cross-compilation host
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; the PACKAGE-HASHTABLE structure
  16
  17 ;;; comment from CMU CL:
  18 ;;;      Packages are implemented using a special kind of hashtable. It is
  19 ;;;   an open hashtable with a parallel 8-bit I-vector of hash-codes. The
  20 ;;;   primary purpose of the hash for each entry is to reduce paging by
  21 ;;;   allowing collisions and misses to be detected without paging in the
  22 ;;;   symbol and pname for an entry. If the hash for an entry doesn't
  23 ;;;   match that for the symbol that we are looking for, then we can
  24 ;;;   go on without touching the symbol, pname, or even hastable vector.
  25 ;;;      It turns out that, contrary to my expectations, paging is a very
  26 ;;;   important consideration the design of the package representation.
  27 ;;;   Using a similar scheme without the entry hash, the fasloader was
  28 ;;;   spending more than half its time paging in INTERN.
  29 ;;;      The hash code also indicates the status of an entry. If it zero,
  30 ;;;   the entry is unused. If it is one, then it is deleted.
  31 ;;;   Double-hashing is used for collision resolution.
  32
  33 (def!type hash-vector () '(simple-array (unsigned-byte 8) (*)))
  34
  35 (def!struct (package-hashtable
  36              (:constructor %make-package-hashtable
  37                            (table hash size &aux (free size)))
  38              (:copier nil))
  39   ;; The g-vector of symbols.
  40   (table (missing-arg) :type simple-vector)
  41   ;; The i-vector of pname hash values.
  42   (hash (missing-arg) :type hash-vector)
  43   ;; The total number of entries allowed before resizing.
  44   ;;
  45   ;; FIXME: CAPACITY would be a more descriptive name. (This is
  46   ;; related to but not quite the same as HASH-TABLE-SIZE, so calling
  47   ;; it SIZE seems somewhat misleading.)
  48   (size (missing-arg) :type index)
  49   ;; The remaining number of entries that can be made before we have to rehash.
  50   (free (missing-arg) :type index)
  51   ;; The number of deleted entries.
  52   (deleted 0 :type index))
  53 \f
  54 ;;;; the PACKAGE structure
  55
  56 ;;; KLUDGE: We use DEF!STRUCT to define this not because we need to
  57 ;;; manipulate target package objects on the cross-compilation host,
  58 ;;; but only because its MAKE-LOAD-FORM function needs to be hooked
  59 ;;; into the pre-CLOS DEF!STRUCT MAKE-LOAD-FORM system so that we can
  60 ;;; compile things like IN-PACKAGE in warm init before CLOS is set up.
  61 ;;; The DEF!STRUCT side effect of defining a new PACKAGE type on the
  62 ;;; cross-compilation host is just a nuisance, and in order to avoid
  63 ;;; breaking the cross-compilation host, we need to work around it
  64 ;;; around by putting the new PACKAGE type (and the PACKAGEP predicate
  65 ;;; too..) into SB!XC. -- WHN 20000309
  66 (def!struct (sb!xc:package
  67              (:constructor internal-make-package)
  68              (:make-load-form-fun (lambda (p)
  69                                     (values `(find-undeleted-package-or-lose
  70                                               ',(package-name p))
  71                                             nil)))
  72              (:predicate sb!xc:packagep))
  73   #!+sb-doc
  74   "the standard structure for the description of a package"
  75   ;; the name of the package, or NIL for a deleted package
  76   (%name nil :type (or simple-string null))
  77   ;; nickname strings
  78   (%nicknames () :type list)
  79   ;; packages used by this package
  80   (%use-list () :type list)
  81   ;; a list of all the hashtables for inherited symbols. This is
  82   ;; derived from %USE-LIST, but maintained separately from %USE-LIST
  83   ;; for some reason. (Perhaps the reason is that when FIND-SYMBOL*
  84   ;; hits an inherited symbol, it pulls it to the head of the list.)
  85   ;;
  86   ;; FIXME: This needs a more-descriptive name
  87   ;; (USED-PACKAGE-HASH-TABLES?). It also needs an explanation of why
  88   ;; the last entry is NIL. Perhaps it should even just go away and
  89   ;; let us do indirection on the fly through %USE-LIST. (If so,
  90   ;; benchmark to make sure that performance doesn't get stomped..)
  91   ;; (If benchmark performance is important, this should prob'ly
  92   ;; become a vector instead of a list.)
  93   (tables (list nil) :type list)
  94   ;; packages that use this package
  95   (%used-by-list () :type list)
  96   ;; PACKAGE-HASHTABLEs of internal & external symbols
  97   (internal-symbols (missing-arg) :type package-hashtable)
  98   (external-symbols (missing-arg) :type package-hashtable)
  99   ;; shadowing symbols
 100   (%shadowing-symbols () :type list)
 101   ;; documentation string for this package
 102   (doc-string nil :type (or simple-string null))
 103   ;; package locking
 104   #!+sb-package-locks
 105   (lock nil :type boolean)
 106   #!+sb-package-locks
 107   (%implementation-packages nil :type list)
 108   ;; Definition source location
 109   (source-location nil :type (or null sb!c:definition-source-location)))
 110 \f
 111 ;;;; iteration macros
 112
 113 (defmacro-mundanely do-symbols ((var &optional
 114                                      (package '*package*)
 115                                      result-form)
 116                                 &body body-decls)
 117   #!+sb-doc
 118   "DO-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECLARATION}* {TAG | FORM}*
 119    Executes the FORMs at least once for each symbol accessible in the given
 120    PACKAGE with VAR bound to the current symbol."
 121   (multiple-value-bind (body decls)
 122       (parse-body body-decls :doc-string-allowed nil)
 123     (let ((flet-name (sb!xc:gensym "DO-SYMBOLS-")))
 124       `(block nil
 125          (flet ((,flet-name (,var)
 126                   ,@decls
 127                   (tagbody ,@body)))
 128            (let* ((package (find-undeleted-package-or-lose ,package))
 129                   (shadows (package-%shadowing-symbols package)))
 130              (flet ((iterate-over-hash-table (table ignore)
 131                       (let ((hash-vec (package-hashtable-hash table))
 132                             (sym-vec (package-hashtable-table table)))
 133                         (dotimes (i (length sym-vec))
 134                           (when (>= (aref hash-vec i) 2)
 135                             (let ((sym (aref sym-vec i)))
 136                               (declare (inline member))
 137                               (unless (member sym ignore :test #'string=)
 138                                 (,flet-name sym))))))))
 139                (iterate-over-hash-table (package-internal-symbols package) nil)
 140                (iterate-over-hash-table (package-external-symbols package) nil)
 141                (dolist (use (package-%use-list package))
 142                  (iterate-over-hash-table (package-external-symbols use)
 143                                           shadows)))))
 144          (let ((,var nil))
 145            (declare (ignorable ,var))
 146            ,@decls
 147            ,result-form)))))
 148
 149 (defmacro-mundanely do-external-symbols ((var &optional
 150                                               (package '*package*)
 151                                               result-form)
 152                                          &body body-decls)
 153   #!+sb-doc
 154   "DO-EXTERNAL-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECL}* {TAG | FORM}*
 155    Executes the FORMs once for each external symbol in the given PACKAGE with
 156    VAR bound to the current symbol."
 157   (multiple-value-bind (body decls)
 158       (parse-body body-decls :doc-string-allowed nil)
 159     (let ((flet-name (sb!xc:gensym "DO-SYMBOLS-")))
 160       `(block nil
 161          (flet ((,flet-name (,var)
 162                   ,@decls
 163                   (tagbody ,@body)))
 164            (let* ((package (find-undeleted-package-or-lose ,package))
 165                   (table (package-external-symbols package))
 166                   (hash-vec (package-hashtable-hash table))
 167                   (sym-vec (package-hashtable-table table)))
 168              (dotimes (i (length sym-vec))
 169                (when (>= (aref hash-vec i) 2)
 170                  (,flet-name (aref sym-vec i))))))
 171          (let ((,var nil))
 172            (declare (ignorable ,var))
 173            ,@decls
 174            ,result-form)))))
 175
 176 (defmacro-mundanely do-all-symbols ((var &optional
 177                                          result-form)
 178                                     &body body-decls)
 179   #!+sb-doc
 180   "DO-ALL-SYMBOLS (VAR [RESULT-FORM]) {DECLARATION}* {TAG | FORM}*
 181    Executes the FORMs once for each symbol in every package with VAR bound
 182    to the current symbol."
 183   (multiple-value-bind (body decls)
 184       (parse-body body-decls :doc-string-allowed nil)
 185     (let ((flet-name (sb!xc:gensym "DO-SYMBOLS-")))
 186       `(block nil
 187          (flet ((,flet-name (,var)
 188                   ,@decls
 189                   (tagbody ,@body)))
 190            (dolist (package (list-all-packages))
 191              (flet ((iterate-over-hash-table (table)
 192                       (let ((hash-vec (package-hashtable-hash table))
 193                             (sym-vec (package-hashtable-table table)))
 194                         (dotimes (i (length sym-vec))
 195                           (when (>= (aref hash-vec i) 2)
 196                             (,flet-name (aref sym-vec i)))))))
 197                (iterate-over-hash-table (package-internal-symbols package))
 198                (iterate-over-hash-table (package-external-symbols package)))))
 199          (let ((,var nil))
 200            (declare (ignorable ,var))
 201            ,@decls
 202            ,result-form)))))
 203 \f
 204 ;;;; WITH-PACKAGE-ITERATOR
 205
 206 (defmacro-mundanely with-package-iterator ((mname package-list
 207                                                   &rest symbol-types)
 208                                            &body body)
 209   #!+sb-doc
 210   "Within the lexical scope of the body forms, MNAME is defined via macrolet
 211 such that successive invocations of (MNAME) will return the symbols, one by
 212 one, from the packages in PACKAGE-LIST. SYMBOL-TYPES may be any
 213 of :INHERITED :EXTERNAL :INTERNAL."
 214   (with-unique-names (packages these-packages counter kind hash-vector vector
 215                       package-use-list init-macro end-test-macro real-symbol-p
 216                       inherited-symbol-p BLOCK)
 217     (let ((ordered-types (let ((res nil))
 218                            (dolist (kind '(:inherited :external :internal) res)
 219                              (when (member kind symbol-types)
 220                                (push kind res))))))  ; Order SYMBOL-TYPES.
 221       `(let* ((,these-packages ,package-list)
 222               (,packages `,(mapcar (lambda (package)
 223                                      (if (packagep package)
 224                                          package
 225                                          ;; Maybe FIND-PACKAGE-OR-DIE?
 226                                          (or (find-package package)
 227                                              (error 'simple-package-error
 228                                                     ;; could be a character
 229                                                     :package (string package)
 230                                                     :format-control "~@<~S does not name a package ~:>"
 231                                                     :format-arguments (list package)))))
 232                                    (if (consp ,these-packages)
 233                                        ,these-packages
 234                                        (list ,these-packages))))
 235               (,counter nil)
 236               (,kind (car ,packages))
 237               (,hash-vector nil)
 238               (,vector nil)
 239               (,package-use-list nil))
 240         ,(if (member :inherited ordered-types)
 241              `(setf ,package-use-list (package-%use-list (car ,packages)))
 242              `(declare (ignore ,package-use-list)))
 243         (macrolet ((,init-macro (next-kind)
 244                      (declare (optimize (inhibit-warnings 3)))
 245                      (let ((symbols (gensym)))
 246                        `(progn
 247                          (setf ,',kind ,next-kind)
 248                          (setf ,',counter nil)
 249                          ,(case next-kind
 250                                 (:internal
 251                                  `(let ((,symbols (package-internal-symbols
 252                                                    (car ,',packages))))
 253                                    (when ,symbols
 254                                      (setf ,',vector (package-hashtable-table ,symbols))
 255                                      (setf ,',hash-vector
 256                                            (package-hashtable-hash ,symbols)))))
 257                                 (:external
 258                                  `(let ((,symbols (package-external-symbols
 259                                                    (car ,',packages))))
 260                                    (when ,symbols
 261                                      (setf ,',vector (package-hashtable-table ,symbols))
 262                                      (setf ,',hash-vector
 263                                            (package-hashtable-hash ,symbols)))))
 264                                 (:inherited
 265                                  `(let ((,symbols (and ,',package-use-list
 266                                                        (package-external-symbols
 267                                                         (car ,',package-use-list)))))
 268                                    (when ,symbols
 269                                      (setf ,',vector (package-hashtable-table ,symbols))
 270                                      (setf ,',hash-vector
 271                                            (package-hashtable-hash ,symbols)))))))))
 272                    (,end-test-macro (this-kind)
 273                      `,(let ((next-kind (cadr (member this-kind
 274                                                       ',ordered-types))))
 275                             (if next-kind
 276                                 `(,',init-macro ,next-kind)
 277                                 `(if (endp (setf ,',packages (cdr ,',packages)))
 278                                   (return-from ,',BLOCK)
 279                                   (,',init-macro ,(car ',ordered-types)))))))
 280           (when ,packages
 281             ,(when (null symbol-types)
 282                    (error 'simple-program-error
 283                           :format-control
 284                           "At least one of :INTERNAL, :EXTERNAL, or ~
 285                       :INHERITED must be supplied."))
 286             ,(dolist (symbol symbol-types)
 287                      (unless (member symbol '(:internal :external :inherited))
 288                        (error 'simple-program-error
 289                               :format-control
 290                               "~S is not one of :INTERNAL, :EXTERNAL, or :INHERITED."
 291                               :format-arguments (list symbol))))
 292             (,init-macro ,(car ordered-types))
 293             (flet ((,real-symbol-p (number)
 294                      (> number 1)))
 295               (macrolet ((,mname ()
 296                            (declare (optimize (inhibit-warnings 3)))
 297                            `(block ,',BLOCK
 298                              (loop
 299                               (case ,',kind
 300                                 ,@(when (member :internal ',ordered-types)
 301                                         `((:internal
 302                                            (setf ,',counter
 303                                             (position-if #',',real-symbol-p
 304                                                          (the hash-vector ,',hash-vector)
 305                                                          :start (if ,',counter
 306                                                                     (1+ ,',counter)
 307                                                                     0)))
 308                                            (if ,',counter
 309                                                (return-from ,',BLOCK
 310                                                  (values t (svref ,',vector ,',counter)
 311                                                          ,',kind (car ,',packages)))
 312                                                (,',end-test-macro :internal)))))
 313                                 ,@(when (member :external ',ordered-types)
 314                                         `((:external
 315                                            (setf ,',counter
 316                                             (position-if #',',real-symbol-p
 317                                                          (the hash-vector ,',hash-vector)
 318                                                          :start (if ,',counter
 319                                                                     (1+ ,',counter)
 320                                                                     0)))
 321                                            (if ,',counter
 322                                                (return-from ,',BLOCK
 323                                                  (values t (svref ,',vector ,',counter)
 324                                                          ,',kind (car ,',packages)))
 325                                                (,',end-test-macro :external)))))
 326                                 ,@(when (member :inherited ',ordered-types)
 327                                         `((:inherited
 328                                            (flet ((,',inherited-symbol-p (number)
 329                                                     (when (,',real-symbol-p number)
 330                                                       (let* ((p (position
 331                                                                  number
 332                                                                  (the hash-vector
 333                                                                    ,',hash-vector)
 334                                                                  :start (if ,',counter
 335                                                                             (1+ ,',counter)
 336                                                                             0)))
 337                                                              (s (svref ,',vector p)))
 338                                                         (eql (nth-value
 339                                                               1 (find-symbol
 340                                                                  (symbol-name s)
 341                                                                  (car ,',packages)))
 342                                                              :inherited)))))
 343                                              (setf ,',counter
 344                                                    (when ,',hash-vector
 345                                                      (position-if #',',inherited-symbol-p
 346                                                                   (the hash-vector
 347                                                                     ,',hash-vector)
 348                                                                   :start (if ,',counter
 349                                                                              (1+ ,',counter)
 350                                                                              0)))))
 351                                            (cond (,',counter
 352                                                   (return-from
 353                                                    ,',BLOCK
 354                                                     (values t (svref ,',vector ,',counter)
 355                                                             ,',kind (car ,',packages))
 356                                                     ))
 357                                                  (t
 358                                                   (setf ,',package-use-list
 359                                                         (cdr ,',package-use-list))
 360                                                   (cond ((endp ,',package-use-list)
 361                                                          (setf ,',packages (cdr ,',packages))
 362                                                          (when (endp ,',packages)
 363                                                            (return-from ,',BLOCK))
 364                                                          (setf ,',package-use-list
 365                                                                (package-%use-list
 366                                                                 (car ,',packages)))
 367                                                          (,',init-macro ,(car
 368                                                                           ',ordered-types)))
 369                                                         (t (,',init-macro :inherited)
 370                                                            (setf ,',counter nil)))))))))))))
 371                 ,@body))))))))
 372
 373 (defmacro-mundanely with-package-graph ((&key) &body forms)
 374   `(flet ((thunk () ,@forms))
 375      (declare (dynamic-extent #'thunk))
 376      (call-with-package-graph #'thunk)))