src/code/pred.lisp

   1 ;;;; predicate functions (EQUAL and friends, and type predicates)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; miscellaneous non-primitive predicates
  15
  16 #!-sb-fluid (declaim (inline streamp))
  17 (defun streamp (stream)
  18   (typep stream 'stream))
  19
  20 ;;; Is X a (VECTOR T)?
  21 (defun vector-t-p (x)
  22   (or (simple-vector-p x)
  23       (and (complex-vector-p x)
  24            (simple-vector-p (%array-data-vector x)))))
  25 \f
  26 ;;;; primitive predicates. These must be supported directly by the
  27 ;;;; compiler.
  28
  29 (defun not (object)
  30   #!+sb-doc
  31   "Return T if X is NIL, otherwise return NIL."
  32   (not object))
  33
  34 ;;; All the primitive type predicate wrappers share a parallel form..
  35 (macrolet ((def-type-predicate-wrapper (pred)
  36              (let* ((name (symbol-name pred))
  37                     (stem (string-left-trim "%" (string-right-trim "P-" name)))
  38                     (article (if (position (schar name 0) "AEIOU") "an" "a")))
  39                `(defun ,pred (object)
  40                   ,(format nil
  41                            "Return true if OBJECT is ~A ~A, and NIL otherwise."
  42                            article
  43                            stem)
  44                   ;; (falling through to low-level implementation)
  45                   (,pred object)))))
  46   (def-type-predicate-wrapper array-header-p)
  47   (def-type-predicate-wrapper arrayp)
  48   (def-type-predicate-wrapper atom)
  49   (def-type-predicate-wrapper base-char-p)
  50   (def-type-predicate-wrapper bignump)
  51   (def-type-predicate-wrapper bit-vector-p)
  52   (def-type-predicate-wrapper characterp)
  53   (def-type-predicate-wrapper code-component-p)
  54   (def-type-predicate-wrapper consp)
  55   (def-type-predicate-wrapper compiled-function-p)
  56   (def-type-predicate-wrapper complexp)
  57   (def-type-predicate-wrapper complex-double-float-p)
  58   (def-type-predicate-wrapper complex-float-p)
  59   #!+long-float (def-type-predicate-wrapper complex-long-float-p)
  60   (def-type-predicate-wrapper complex-rational-p)
  61   (def-type-predicate-wrapper complex-single-float-p)
  62   ;; (COMPLEX-VECTOR-P is not included here since it's awkward to express
  63   ;; the type it tests for in the Common Lisp type system, and since it's
  64   ;; only used in the implementation of a few specialized things.)
  65   (def-type-predicate-wrapper double-float-p)
  66   (def-type-predicate-wrapper fdefn-p)
  67   (def-type-predicate-wrapper fixnump)
  68   (def-type-predicate-wrapper floatp)
  69   (def-type-predicate-wrapper functionp)
  70   (def-type-predicate-wrapper integerp)
  71   (def-type-predicate-wrapper listp)
  72   (def-type-predicate-wrapper long-float-p)
  73   (def-type-predicate-wrapper lra-p)
  74   (def-type-predicate-wrapper null)
  75   (def-type-predicate-wrapper numberp)
  76   (def-type-predicate-wrapper rationalp)
  77   (def-type-predicate-wrapper ratiop)
  78   (def-type-predicate-wrapper realp)
  79   (def-type-predicate-wrapper short-float-p)
  80   (def-type-predicate-wrapper sb!kernel:simple-array-p)
  81   (def-type-predicate-wrapper simple-bit-vector-p)
  82   (def-type-predicate-wrapper simple-string-p)
  83   (def-type-predicate-wrapper simple-vector-p)
  84   (def-type-predicate-wrapper single-float-p)
  85   (def-type-predicate-wrapper stringp)
  86   (def-type-predicate-wrapper %instancep)
  87   (def-type-predicate-wrapper symbolp)
  88   (def-type-predicate-wrapper system-area-pointer-p)
  89   (def-type-predicate-wrapper weak-pointer-p)
  90   (def-type-predicate-wrapper vectorp)
  91   (def-type-predicate-wrapper unsigned-byte-32-p)
  92   (def-type-predicate-wrapper signed-byte-32-p)
  93   (def-type-predicate-wrapper simple-array-unsigned-byte-2-p)
  94   (def-type-predicate-wrapper simple-array-unsigned-byte-4-p)
  95   (def-type-predicate-wrapper simple-array-unsigned-byte-8-p)
  96   (def-type-predicate-wrapper simple-array-unsigned-byte-16-p)
  97   (def-type-predicate-wrapper simple-array-unsigned-byte-32-p)
  98   (def-type-predicate-wrapper simple-array-signed-byte-8-p)
  99   (def-type-predicate-wrapper simple-array-signed-byte-16-p)
 100   (def-type-predicate-wrapper simple-array-signed-byte-30-p)
 101   (def-type-predicate-wrapper simple-array-signed-byte-32-p)
 102   (def-type-predicate-wrapper simple-array-single-float-p)
 103   (def-type-predicate-wrapper simple-array-double-float-p)
 104   #!+long-float (def-type-predicate-wrapper simple-array-long-float-p)
 105   (def-type-predicate-wrapper simple-array-complex-single-float-p)
 106   (def-type-predicate-wrapper simple-array-complex-double-float-p)
 107   #!+long-float (def-type-predicate-wrapper simple-array-complex-long-float-p))
 108 \f
 109 ;;; Return the specifier for the type of object. This is not simply
 110 ;;; (TYPE-SPECIFIER (CTYPE-OF OBJECT)) because CTYPE-OF has different
 111 ;;; goals than TYPE-OF. In particular, speed is more important than
 112 ;;; precision, and it is not permitted to return member types.
 113 (defun type-of (object)
 114   #!+sb-doc
 115   "Return the type of OBJECT."
 116   (if (typep object '(or function array complex))
 117     (type-specifier (ctype-of object))
 118     (let* ((classoid (layout-classoid (layout-of object)))
 119            (name (classoid-name classoid)))
 120       (if (typep object 'instance)
 121       (case name
 122         (sb!alien-internals:alien-value
 123          `(sb!alien:alien
 124            ,(sb!alien-internals:unparse-alien-type
 125              (sb!alien-internals:alien-value-type object))))
 126         (t
 127          (classoid-proper-name classoid)))
 128       name))))
 129 \f
 130 ;;;; equality predicates
 131
 132 ;;; This is real simple, 'cause the compiler takes care of it.
 133 (defun eq (obj1 obj2)
 134   #!+sb-doc
 135   "Return T if OBJ1 and OBJ2 are the same object, otherwise NIL."
 136   (eq obj1 obj2))
 137
 138 (defun bit-vector-= (x y)
 139   (declare (type bit-vector x y))
 140   (if (and (simple-bit-vector-p x)
 141            (simple-bit-vector-p y))
 142       (bit-vector-= x y) ; DEFTRANSFORM
 143       (and (= (length x) (length y))
 144            (do ((i 0 (1+ i))
 145                 (length (length x)))
 146                ((= i length) t)
 147              (declare (fixnum i))
 148              (unless (= (bit x i) (bit y i))
 149                (return nil))))))
 150
 151 (defun equal (x y)
 152   #!+sb-doc
 153   "Return T if X and Y are EQL or if they are structured components
 154   whose elements are EQUAL. Strings and bit-vectors are EQUAL if they
 155   are the same length and have identical components. Other arrays must be
 156   EQ to be EQUAL."
 157   (cond ((eql x y) t)
 158         ((consp x)
 159          (and (consp y)
 160               (equal (car x) (car y))
 161               (equal (cdr x) (cdr y))))
 162         ((stringp x)
 163          (and (stringp y) (string= x y)))
 164         ((pathnamep x)
 165          (and (pathnamep y) (pathname= x y)))
 166         ((bit-vector-p x)
 167          (and (bit-vector-p y)
 168               (bit-vector-= x y)))
 169         (t nil)))
 170
 171 ;;; EQUALP comparison of HASH-TABLE values
 172 (defun hash-table-equalp (x y)
 173   (declare (type hash-table x y))
 174   (or (eq x y)
 175       (and (hash-table-p y)
 176            (eql (hash-table-count x) (hash-table-count y))
 177            (eql (hash-table-test x) (hash-table-test y))
 178            (block comparison-of-entries
 179              (maphash (lambda (key x-value)
 180                         (multiple-value-bind (y-value y-value-p)
 181                             (gethash key y)
 182                           (unless (and y-value-p (equalp x-value y-value))
 183                             (return-from comparison-of-entries nil))))
 184                       x)
 185              t))))
 186
 187 (defun equalp (x y)
 188   #+nil ; KLUDGE: If doc string, should be accurate: Talk about structures
 189   ; and HASH-TABLEs.
 190   "This is like EQUAL, except more liberal in several respects.
 191   Numbers may be of different types, as long as the values are identical
 192   after coercion. Characters may differ in alphabetic case. Vectors and
 193   arrays must have identical dimensions and EQUALP elements, but may differ
 194   in their type restriction."
 195   (cond ((eq x y) t)
 196         ((characterp x) (and (characterp y) (char-equal x y)))
 197         ((numberp x) (and (numberp y) (= x y)))
 198         ((consp x)
 199          (and (consp y)
 200               (equalp (car x) (car y))
 201               (equalp (cdr x) (cdr y))))
 202         ((pathnamep x)
 203          (and (pathnamep y) (pathname= x y)))
 204         ((hash-table-p x)
 205          (and (hash-table-p y)
 206               (hash-table-equalp x y)))
 207         ((typep x 'instance)
 208          (let* ((layout-x (%instance-layout x))
 209                 (len (layout-length layout-x)))
 210            (and (typep y 'instance)
 211                 (eq layout-x (%instance-layout y))
 212                 (structure-classoid-p (layout-classoid layout-x))
 213                 (do ((i 1 (1+ i)))
 214                     ((= i len) t)
 215                   (declare (fixnum i))
 216                   (let ((x-el (%instance-ref x i))
 217                         (y-el (%instance-ref y i)))
 218                     (unless (or (eq x-el y-el)
 219                                 (equalp x-el y-el))
 220                       (return nil)))))))
 221         ((vectorp x)
 222          (let ((length (length x)))
 223            (and (vectorp y)
 224                 (= length (length y))
 225                 (dotimes (i length t)
 226                   (let ((x-el (aref x i))
 227                         (y-el (aref y i)))
 228                     (unless (or (eq x-el y-el)
 229                                 (equalp x-el y-el))
 230                       (return nil)))))))
 231         ((arrayp x)
 232          (and (arrayp y)
 233               (= (array-rank x) (array-rank y))
 234               (dotimes (axis (array-rank x) t)
 235                 (unless (= (array-dimension x axis)
 236                            (array-dimension y axis))
 237                   (return nil)))
 238               (dotimes (index (array-total-size x) t)
 239                 (let ((x-el (row-major-aref x index))
 240                       (y-el (row-major-aref y index)))
 241                   (unless (or (eq x-el y-el)
 242                               (equalp x-el y-el))
 243                     (return nil))))))
 244         (t nil)))
 245
 246 (/show0 "about to do test cases in pred.lisp")
 247 #!+sb-test
 248 (let ((test-cases '((0.0 -0.0 t)
 249                     (0.0 1.0 nil)
 250                     (#c(1 0) #c(1.0 0) t)
 251                     (#c(1.1 0) #c(11/10 0) nil) ; due to roundoff error
 252                     ("Hello" "hello" t)
 253                     ("Hello" #(#\h #\E #\l #\l #\o) t)
 254                     ("Hello" "goodbye" nil))))
 255   (/show0 "TEST-CASES bound in pred.lisp")
 256   (dolist (test-case test-cases)
 257     (/show0 "about to do a TEST-CASE in pred.lisp")
 258     (destructuring-bind (x y expected-result) test-case
 259       (let* ((result (equalp x y))
 260              (bresult (if result 1 0))
 261              (expected-bresult (if expected-result 1 0)))
 262         (unless (= bresult expected-bresult)
 263           (/show0 "failing test in pred.lisp")
 264           (error "failed test (EQUALP ~S ~S)" x y))))))
 265 (/show0 "done with test cases in pred.lisp")