src/code/pred.lisp

   1 ;;;; predicate functions (EQUAL and friends, and type predicates)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; miscellaneous non-primitive predicates
  15
  16 #!-sb-fluid (declaim (inline streamp))
  17 (defun streamp (stream)
  18   (typep stream 'stream))
  19
  20 ;;; various (VECTOR FOO) type predicates, not implemented as simple
  21 ;;; widetag tests
  22 (macrolet
  23     ((def ()
  24        `(progn
  25           ,@(loop for (name spec) in *vector-without-complex-typecode-infos*
  26                   collect `(defun ,name (x)
  27                              (or (typep x '(simple-array ,spec (*)))
  28                                  (and (complex-vector-p x)
  29                                       (do ((data (%array-data-vector x) (%array-data-vector data)))
  30                                           ((not (array-header-p data)) (typep data '(simple-array ,spec (*))))))))))))
  31   (def))
  32
  33 ;;; Is X an extended sequence?
  34 (defun extended-sequence-p (x)
  35   (and (not (listp x))
  36        (not (vectorp x))
  37        (let* ((slayout #.(info :type :compiler-layout 'sequence))
  38              (depthoid #.(layout-depthoid (info :type :compiler-layout 'sequence)))
  39              (layout (layout-of x)))
  40         (when (layout-invalid layout)
  41           (setq layout (update-object-layout-or-invalid x slayout)))
  42         (if (eq layout slayout)
  43             t
  44             (let ((inherits (layout-inherits layout)))
  45               (declare (optimize (safety 0)))
  46               (and (> (length inherits) depthoid)
  47                    (eq (svref inherits depthoid) slayout)))))))
  48
  49 ;;; Is X a SEQUENCE?  Harder than just (OR VECTOR LIST)
  50 (defun sequencep (x)
  51   (or (listp x)
  52       (vectorp x)
  53       (let* ((slayout #.(info :type :compiler-layout 'sequence))
  54              (depthoid #.(layout-depthoid (info :type :compiler-layout 'sequence)))
  55              (layout (layout-of x)))
  56         (when (layout-invalid layout)
  57           (setq layout (update-object-layout-or-invalid x slayout)))
  58         (if (eq layout slayout)
  59             t
  60             (let ((inherits (layout-inherits layout)))
  61               (declare (optimize (safety 0)))
  62               (and (> (length inherits) depthoid)
  63                    (eq (svref inherits depthoid) slayout)))))))
  64 \f
  65 ;;;; primitive predicates. These must be supported directly by the
  66 ;;;; compiler.
  67
  68 (defun not (object)
  69   #!+sb-doc
  70   "Return T if X is NIL, otherwise return NIL."
  71   (not object))
  72
  73 ;;; All the primitive type predicate wrappers share a parallel form..
  74 (macrolet ((def-type-predicate-wrapper (pred)
  75              (let* ((name (symbol-name pred))
  76                     (stem (string-left-trim "%" (string-right-trim "P-" name)))
  77                     (article (if (position (schar name 0) "AEIOU") "an" "a")))
  78                `(defun ,pred (object)
  79                   ,(format nil
  80                            "Return true if OBJECT is ~A ~A, and NIL otherwise."
  81                            article
  82                            stem)
  83                   ;; (falling through to low-level implementation)
  84                   (,pred object)))))
  85   (def-type-predicate-wrapper array-header-p)
  86   (def-type-predicate-wrapper arrayp)
  87   (def-type-predicate-wrapper atom)
  88   (def-type-predicate-wrapper base-char-p)
  89   (def-type-predicate-wrapper base-string-p)
  90   #!+sb-unicode (def-type-predicate-wrapper character-string-p)
  91   (def-type-predicate-wrapper bignump)
  92   (def-type-predicate-wrapper bit-vector-p)
  93   (def-type-predicate-wrapper characterp)
  94   (def-type-predicate-wrapper code-component-p)
  95   (def-type-predicate-wrapper consp)
  96   (def-type-predicate-wrapper compiled-function-p)
  97   (def-type-predicate-wrapper complexp)
  98   (def-type-predicate-wrapper complex-double-float-p)
  99   (def-type-predicate-wrapper complex-float-p)
 100   #!+long-float (def-type-predicate-wrapper complex-long-float-p)
 101   (def-type-predicate-wrapper complex-rational-p)
 102   (def-type-predicate-wrapper complex-single-float-p)
 103   ;; (COMPLEX-VECTOR-P is not included here since it's awkward to express
 104   ;; the type it tests for in the Common Lisp type system, and since it's
 105   ;; only used in the implementation of a few specialized things.)
 106   (def-type-predicate-wrapper double-float-p)
 107   (def-type-predicate-wrapper extended-char-p)
 108   (def-type-predicate-wrapper fdefn-p)
 109   (def-type-predicate-wrapper fixnump)
 110   (def-type-predicate-wrapper floatp)
 111   (def-type-predicate-wrapper functionp)
 112   (def-type-predicate-wrapper integerp)
 113   (def-type-predicate-wrapper listp)
 114   (def-type-predicate-wrapper long-float-p)
 115   (def-type-predicate-wrapper lra-p)
 116   (def-type-predicate-wrapper null)
 117   (def-type-predicate-wrapper numberp)
 118   (def-type-predicate-wrapper rationalp)
 119   (def-type-predicate-wrapper ratiop)
 120   (def-type-predicate-wrapper realp)
 121   (def-type-predicate-wrapper short-float-p)
 122   (def-type-predicate-wrapper single-float-p)
 123   (def-type-predicate-wrapper %instancep)
 124   (def-type-predicate-wrapper symbolp)
 125   (def-type-predicate-wrapper %other-pointer-p)
 126   (def-type-predicate-wrapper system-area-pointer-p)
 127   (def-type-predicate-wrapper weak-pointer-p)
 128   #!+#.(cl:if (cl:= 32 sb!vm:n-word-bits) '(and) '(or))
 129   (progn
 130     (def-type-predicate-wrapper unsigned-byte-32-p)
 131     (def-type-predicate-wrapper signed-byte-32-p))
 132   #!+#.(cl:if (cl:= 64 sb!vm:n-word-bits) '(and) '(or))
 133   (progn
 134     (def-type-predicate-wrapper unsigned-byte-64-p)
 135     (def-type-predicate-wrapper signed-byte-64-p))
 136   ;; Specialized array types
 137   (macrolet ((saetp-defs ()
 138                `(progn
 139                   ,@(map 'list
 140                          (lambda (saetp)
 141                            `(def-type-predicate-wrapper
 142                                 ,(symbolicate (sb!vm:saetp-primitive-type-name saetp) "-P")))
 143                          sb!vm:*specialized-array-element-type-properties*))))
 144     (saetp-defs))
 145   ;; Other array types
 146   (def-type-predicate-wrapper simple-array-p)
 147   (def-type-predicate-wrapper simple-string-p)
 148   (def-type-predicate-wrapper stringp)
 149   (def-type-predicate-wrapper vectorp)
 150   (def-type-predicate-wrapper vector-nil-p))
 151 \f
 152 ;;; Return the specifier for the type of object. This is not simply
 153 ;;; (TYPE-SPECIFIER (CTYPE-OF OBJECT)) because CTYPE-OF has different
 154 ;;; goals than TYPE-OF. In particular, speed is more important than
 155 ;;; precision, and it is not permitted to return member types.
 156 (defun type-of (object)
 157   #!+sb-doc
 158   "Return the type of OBJECT."
 159   (typecase object
 160     (fixnum
 161      (cond
 162        ((<= 0 object 1) 'bit)
 163        ((< object 0) 'fixnum)
 164        (t '(integer 0 #.sb!xc:most-positive-fixnum))))
 165     (integer
 166      (if (>= object 0)
 167          '(integer #.(1+ sb!xc:most-positive-fixnum))
 168          'bignum))
 169     (standard-char 'standard-char)
 170     (base-char 'base-char)
 171     (extended-char 'extended-char)
 172     ((member t) 'boolean)
 173     (keyword 'keyword)
 174     ((or array complex)
 175      (type-specifier (ctype-of object)))
 176     (t
 177      (let* ((classoid (layout-classoid (layout-of object)))
 178             (name (classoid-name classoid)))
 179        (if (%instancep object)
 180            (case name
 181              (sb!alien-internals:alien-value
 182               `(sb!alien:alien
 183                 ,(sb!alien-internals:unparse-alien-type
 184                   (sb!alien-internals:alien-value-type object))))
 185              (t
 186               (let ((pname (classoid-proper-name classoid)))
 187                 (if (classoid-p pname)
 188                     (classoid-pcl-class pname)
 189                     pname))))
 190            name)))))
 191 \f
 192 ;;;; equality predicates
 193
 194 ;;; This is real simple, 'cause the compiler takes care of it.
 195 (defun eq (obj1 obj2)
 196   #!+sb-doc
 197   "Return T if OBJ1 and OBJ2 are the same object, otherwise NIL."
 198   (eq obj1 obj2))
 199
 200 (declaim (inline %eql))
 201 (defun %eql (obj1 obj2)
 202   #!+sb-doc
 203   "Return T if OBJ1 and OBJ2 represent the same object, otherwise NIL."
 204   (or (eq obj1 obj2)
 205       (if (or (typep obj2 'fixnum)
 206               (not (typep obj2 'number)))
 207           nil
 208           (macrolet ((foo (&rest stuff)
 209                        `(typecase obj2
 210                           ,@(mapcar (lambda (foo)
 211                                       (let ((type (car foo))
 212                                             (fn (cadr foo)))
 213                                         `(,type
 214                                           (and (typep obj1 ',type)
 215                                                (,fn obj1 obj2)))))
 216                                     stuff))))
 217             (foo
 218              (single-float eql)
 219              (double-float eql)
 220              #!+long-float
 221              (long-float eql)
 222              (bignum
 223               (lambda (x y)
 224                 (zerop (bignum-compare x y))))
 225              (ratio
 226               (lambda (x y)
 227                 (and (eql (numerator x) (numerator y))
 228                      (eql (denominator x) (denominator y)))))
 229              (complex
 230               (lambda (x y)
 231                 (and (eql (realpart x) (realpart y))
 232                      (eql (imagpart x) (imagpart y))))))))))
 233
 234 (defun eql (x y)
 235   (%eql x y))
 236
 237 (defun bit-vector-= (x y)
 238   (declare (type bit-vector x y))
 239   (if (and (simple-bit-vector-p x)
 240            (simple-bit-vector-p y))
 241       (bit-vector-= x y) ; DEFTRANSFORM
 242       (and (= (length x) (length y))
 243            (do ((i 0 (1+ i))
 244                 (length (length x)))
 245                ((= i length) t)
 246              (declare (fixnum i))
 247              (unless (= (bit x i) (bit y i))
 248                (return nil))))))
 249
 250 (defun equal (x y)
 251   #!+sb-doc
 252   "Return T if X and Y are EQL or if they are structured components whose
 253 elements are EQUAL. Strings and bit-vectors are EQUAL if they are the same
 254 length and have identical components. Other arrays must be EQ to be EQUAL."
 255   ;; Non-tail self-recursion implemented with a local auxiliary function
 256   ;; is a lot faster than doing it the straightforward way (at least
 257   ;; on x86oids) due to calling convention differences. -- JES, 2005-12-30
 258   (labels ((equal-aux (x y)
 259              (cond ((%eql x y)
 260                     t)
 261                    ((consp x)
 262                     (and (consp y)
 263                          (equal-aux (car x) (car y))
 264                          (equal-aux (cdr x) (cdr y))))
 265                    ((stringp x)
 266                     (and (stringp y) (string= x y)))
 267                    ((pathnamep x)
 268                     (and (pathnamep y) (pathname= x y)))
 269                    ((bit-vector-p x)
 270                     (and (bit-vector-p y)
 271                          (bit-vector-= x y)))
 272                    (t nil))))
 273     ;; Use MAYBE-INLINE to get the inline expansion only once (instead
 274     ;; of 200 times with INLINE). -- JES, 2005-12-30
 275     (declare (maybe-inline equal-aux))
 276     (equal-aux x y)))
 277
 278 ;;; EQUALP comparison of HASH-TABLE values
 279 (defun hash-table-equalp (x y)
 280   (declare (type hash-table x y))
 281   (or (eq x y)
 282       (and (hash-table-p y)
 283            (eql (hash-table-count x) (hash-table-count y))
 284            (eql (hash-table-test x) (hash-table-test y))
 285            (block comparison-of-entries
 286              (maphash (lambda (key x-value)
 287                         (multiple-value-bind (y-value y-value-p)
 288                             (gethash key y)
 289                           (unless (and y-value-p (equalp x-value y-value))
 290                             (return-from comparison-of-entries nil))))
 291                       x)
 292              t))))
 293
 294 (defun equalp (x y)
 295   #+nil ; KLUDGE: If doc string, should be accurate: Talk about structures
 296   ; and HASH-TABLEs.
 297   "This is like EQUAL, except more liberal in several respects.
 298   Numbers may be of different types, as long as the values are identical
 299   after coercion. Characters may differ in alphabetic case. Vectors and
 300   arrays must have identical dimensions and EQUALP elements, but may differ
 301   in their type restriction."
 302   (cond ((eq x y) t)
 303         ((characterp x) (and (characterp y) (char-equal x y)))
 304         ((numberp x) (and (numberp y) (= x y)))
 305         ((consp x)
 306          (and (consp y)
 307               (equalp (car x) (car y))
 308               (equalp (cdr x) (cdr y))))
 309         ((pathnamep x)
 310          (and (pathnamep y) (pathname= x y)))
 311         ((hash-table-p x)
 312          (and (hash-table-p y)
 313               (hash-table-equalp x y)))
 314         ((%instancep x)
 315          (let* ((layout-x (%instance-layout x))
 316                 (raw-len (layout-n-untagged-slots layout-x))
 317                 (total-len (layout-length layout-x))
 318                 (normal-len (- total-len raw-len)))
 319            (and (%instancep y)
 320                 (eq layout-x (%instance-layout y))
 321                 (structure-classoid-p (layout-classoid layout-x))
 322                 (dotimes (i normal-len t)
 323                   (let ((x-el (%instance-ref x i))
 324                         (y-el (%instance-ref y i)))
 325                     (unless (or (eq x-el y-el)
 326                                 (equalp x-el y-el))
 327                       (return nil))))
 328                 (if (zerop raw-len)
 329                     t
 330                     (raw-instance-slots-equalp layout-x x y)))))
 331         ((vectorp x)
 332          (let ((length (length x)))
 333            (and (vectorp y)
 334                 (= length (length y))
 335                 (dotimes (i length t)
 336                   (let ((x-el (aref x i))
 337                         (y-el (aref y i)))
 338                     (unless (or (eq x-el y-el)
 339                                 (equalp x-el y-el))
 340                       (return nil)))))))
 341         ((arrayp x)
 342          (and (arrayp y)
 343               (= (array-rank x) (array-rank y))
 344               (dotimes (axis (array-rank x) t)
 345                 (unless (= (array-dimension x axis)
 346                            (array-dimension y axis))
 347                   (return nil)))
 348               (dotimes (index (array-total-size x) t)
 349                 (let ((x-el (row-major-aref x index))
 350                       (y-el (row-major-aref y index)))
 351                   (unless (or (eq x-el y-el)
 352                               (equalp x-el y-el))
 353                     (return nil))))))
 354         (t nil)))
 355
 356 (/show0 "about to do test cases in pred.lisp")
 357 #!+sb-test
 358 (let ((test-cases `((0.0 ,(load-time-value (make-unportable-float :single-float-negative-zero)) t)
 359                     (0.0 1.0 nil)
 360                     (#c(1 0) #c(1.0 0.0) t)
 361                     (#c(0 1) #c(0.0 1.0) t)
 362                     (#c(1.1 0.0) #c(11/10 0) nil) ; due to roundoff error
 363                     ("Hello" "hello" t)
 364                     ("Hello" #(#\h #\E #\l #\l #\o) t)
 365                     ("Hello" "goodbye" nil))))
 366   (/show0 "TEST-CASES bound in pred.lisp")
 367   (dolist (test-case test-cases)
 368     (/show0 "about to do a TEST-CASE in pred.lisp")
 369     (destructuring-bind (x y expected-result) test-case
 370       (let* ((result (equalp x y))
 371              (bresult (if result 1 0))
 372              (expected-bresult (if expected-result 1 0)))
 373         (unless (= bresult expected-bresult)
 374           (/show0 "failing test in pred.lisp")
 375           (error "failed test (EQUALP ~S ~S)" x y))))))
 376 (/show0 "done with test cases in pred.lisp")