src/code/pred.lisp

   1 ;;;; predicate functions (EQUAL and friends, and type predicates)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; miscellaneous non-primitive predicates
  15
  16 #!-sb-fluid (declaim (inline streamp))
  17 (defun streamp (stream)
  18   (typep stream 'stream))
  19
  20 ;;; Is X a (VECTOR T)?
  21 (defun vector-t-p (x)
  22   (or (simple-vector-p x)
  23       (and (complex-vector-p x)
  24            (simple-vector-p (%array-data-vector x)))))
  25 \f
  26 ;;;; primitive predicates. These must be supported directly by the
  27 ;;;; compiler.
  28
  29 (defun not (object)
  30   #!+sb-doc
  31   "Return T if X is NIL, otherwise return NIL."
  32   (not object))
  33
  34 ;;; All the primitive type predicate wrappers share a parallel form..
  35 (macrolet ((def-type-predicate-wrapper (pred)
  36              (let* ((name (symbol-name pred))
  37                     (stem (string-left-trim "%" (string-right-trim "P-" name)))
  38                     (article (if (position (schar name 0) "AEIOU") "an" "a")))
  39                `(defun ,pred (object)
  40                   ,(format nil
  41                            "Return true if OBJECT is ~A ~A, and NIL otherwise."
  42                            article
  43                            stem)
  44                   ;; (falling through to low-level implementation)
  45                   (,pred object)))))
  46   (def-type-predicate-wrapper array-header-p)
  47   (def-type-predicate-wrapper arrayp)
  48   (def-type-predicate-wrapper atom)
  49   (def-type-predicate-wrapper base-char-p)
  50   (def-type-predicate-wrapper base-string-p)
  51   (def-type-predicate-wrapper bignump)
  52   (def-type-predicate-wrapper bit-vector-p)
  53   (def-type-predicate-wrapper characterp)
  54   (def-type-predicate-wrapper code-component-p)
  55   (def-type-predicate-wrapper consp)
  56   (def-type-predicate-wrapper compiled-function-p)
  57   (def-type-predicate-wrapper complexp)
  58   (def-type-predicate-wrapper complex-double-float-p)
  59   (def-type-predicate-wrapper complex-float-p)
  60   #!+long-float (def-type-predicate-wrapper complex-long-float-p)
  61   (def-type-predicate-wrapper complex-rational-p)
  62   (def-type-predicate-wrapper complex-single-float-p)
  63   ;; (COMPLEX-VECTOR-P is not included here since it's awkward to express
  64   ;; the type it tests for in the Common Lisp type system, and since it's
  65   ;; only used in the implementation of a few specialized things.)
  66   (def-type-predicate-wrapper double-float-p)
  67   (def-type-predicate-wrapper extended-char-p)
  68   (def-type-predicate-wrapper fdefn-p)
  69   (def-type-predicate-wrapper fixnump)
  70   (def-type-predicate-wrapper floatp)
  71   (def-type-predicate-wrapper functionp)
  72   (def-type-predicate-wrapper integerp)
  73   (def-type-predicate-wrapper listp)
  74   (def-type-predicate-wrapper long-float-p)
  75   (def-type-predicate-wrapper lra-p)
  76   (def-type-predicate-wrapper null)
  77   (def-type-predicate-wrapper numberp)
  78   (def-type-predicate-wrapper rationalp)
  79   (def-type-predicate-wrapper ratiop)
  80   (def-type-predicate-wrapper realp)
  81   (def-type-predicate-wrapper short-float-p)
  82   (def-type-predicate-wrapper simple-array-p)
  83   (def-type-predicate-wrapper simple-bit-vector-p)
  84   (def-type-predicate-wrapper simple-base-string-p)
  85   (def-type-predicate-wrapper simple-string-p)
  86   (def-type-predicate-wrapper simple-vector-p)
  87   (def-type-predicate-wrapper single-float-p)
  88   (def-type-predicate-wrapper stringp)
  89   (def-type-predicate-wrapper %instancep)
  90   (def-type-predicate-wrapper symbolp)
  91   (def-type-predicate-wrapper system-area-pointer-p)
  92   (def-type-predicate-wrapper weak-pointer-p)
  93   (def-type-predicate-wrapper vectorp)
  94   (def-type-predicate-wrapper unsigned-byte-32-p)
  95   (def-type-predicate-wrapper signed-byte-32-p)
  96   (def-type-predicate-wrapper simple-array-nil-p)
  97   (def-type-predicate-wrapper simple-array-unsigned-byte-2-p)
  98   (def-type-predicate-wrapper simple-array-unsigned-byte-4-p)
  99   (def-type-predicate-wrapper simple-array-unsigned-byte-8-p)
 100   (def-type-predicate-wrapper simple-array-unsigned-byte-16-p)
 101   (def-type-predicate-wrapper simple-array-unsigned-byte-32-p)
 102   (def-type-predicate-wrapper simple-array-signed-byte-8-p)
 103   (def-type-predicate-wrapper simple-array-signed-byte-16-p)
 104   (def-type-predicate-wrapper simple-array-signed-byte-30-p)
 105   (def-type-predicate-wrapper simple-array-signed-byte-32-p)
 106   (def-type-predicate-wrapper simple-array-single-float-p)
 107   (def-type-predicate-wrapper simple-array-double-float-p)
 108   #!+long-float (def-type-predicate-wrapper simple-array-long-float-p)
 109   (def-type-predicate-wrapper simple-array-complex-single-float-p)
 110   (def-type-predicate-wrapper simple-array-complex-double-float-p)
 111   #!+long-float (def-type-predicate-wrapper simple-array-complex-long-float-p))
 112 \f
 113 ;;; Return the specifier for the type of object. This is not simply
 114 ;;; (TYPE-SPECIFIER (CTYPE-OF OBJECT)) because CTYPE-OF has different
 115 ;;; goals than TYPE-OF. In particular, speed is more important than
 116 ;;; precision, and it is not permitted to return member types.
 117 (defun type-of (object)
 118   #!+sb-doc
 119   "Return the type of OBJECT."
 120   (typecase object
 121     (fixnum
 122      (cond
 123        ((<= 0 object 1) 'bit)
 124        ((< object 0) 'fixnum)
 125        (t '(integer 0 #.sb!xc:most-positive-fixnum))))
 126     (integer
 127      (if (>= object 0)
 128          '(integer #.(1+ sb!xc:most-positive-fixnum))
 129          'bignum))
 130     (standard-char 'standard-char)
 131     ((member t) 'boolean)
 132     (keyword 'keyword)
 133     ((or array complex) (type-specifier (ctype-of object)))
 134     (t
 135      (let* ((classoid (layout-classoid (layout-of object)))
 136             (name (classoid-name classoid)))
 137        (if (typep object 'instance)
 138            (case name
 139              (sb!alien-internals:alien-value
 140               `(sb!alien:alien
 141                 ,(sb!alien-internals:unparse-alien-type
 142                   (sb!alien-internals:alien-value-type object))))
 143              (t
 144               (let ((pname (classoid-proper-name classoid)))
 145                 (if (classoid-p pname)
 146                     (classoid-pcl-class pname)
 147                     pname))))
 148            name)))))
 149 \f
 150 ;;;; equality predicates
 151
 152 ;;; This is real simple, 'cause the compiler takes care of it.
 153 (defun eq (obj1 obj2)
 154   #!+sb-doc
 155   "Return T if OBJ1 and OBJ2 are the same object, otherwise NIL."
 156   (eq obj1 obj2))
 157
 158 (defun bit-vector-= (x y)
 159   (declare (type bit-vector x y))
 160   (if (and (simple-bit-vector-p x)
 161            (simple-bit-vector-p y))
 162       (bit-vector-= x y) ; DEFTRANSFORM
 163       (and (= (length x) (length y))
 164            (do ((i 0 (1+ i))
 165                 (length (length x)))
 166                ((= i length) t)
 167              (declare (fixnum i))
 168              (unless (= (bit x i) (bit y i))
 169                (return nil))))))
 170
 171 (defun equal (x y)
 172   #!+sb-doc
 173   "Return T if X and Y are EQL or if they are structured components
 174   whose elements are EQUAL. Strings and bit-vectors are EQUAL if they
 175   are the same length and have identical components. Other arrays must be
 176   EQ to be EQUAL."
 177   (cond ((eql x y) t)
 178         ((consp x)
 179          (and (consp y)
 180               (equal (car x) (car y))
 181               (equal (cdr x) (cdr y))))
 182         ((stringp x)
 183          (and (stringp y) (string= x y)))
 184         ((pathnamep x)
 185          (and (pathnamep y) (pathname= x y)))
 186         ((bit-vector-p x)
 187          (and (bit-vector-p y)
 188               (bit-vector-= x y)))
 189         (t nil)))
 190
 191 ;;; EQUALP comparison of HASH-TABLE values
 192 (defun hash-table-equalp (x y)
 193   (declare (type hash-table x y))
 194   (or (eq x y)
 195       (and (hash-table-p y)
 196            (eql (hash-table-count x) (hash-table-count y))
 197            (eql (hash-table-test x) (hash-table-test y))
 198            (block comparison-of-entries
 199              (maphash (lambda (key x-value)
 200                         (multiple-value-bind (y-value y-value-p)
 201                             (gethash key y)
 202                           (unless (and y-value-p (equalp x-value y-value))
 203                             (return-from comparison-of-entries nil))))
 204                       x)
 205              t))))
 206
 207 (defun equalp (x y)
 208   #+nil ; KLUDGE: If doc string, should be accurate: Talk about structures
 209   ; and HASH-TABLEs.
 210   "This is like EQUAL, except more liberal in several respects.
 211   Numbers may be of different types, as long as the values are identical
 212   after coercion. Characters may differ in alphabetic case. Vectors and
 213   arrays must have identical dimensions and EQUALP elements, but may differ
 214   in their type restriction."
 215   (cond ((eq x y) t)
 216         ((characterp x) (and (characterp y) (char-equal x y)))
 217         ((numberp x) (and (numberp y) (= x y)))
 218         ((consp x)
 219          (and (consp y)
 220               (equalp (car x) (car y))
 221               (equalp (cdr x) (cdr y))))
 222         ((pathnamep x)
 223          (and (pathnamep y) (pathname= x y)))
 224         ((hash-table-p x)
 225          (and (hash-table-p y)
 226               (hash-table-equalp x y)))
 227         ((typep x 'instance)
 228          (let* ((layout-x (%instance-layout x))
 229                 (len (layout-length layout-x)))
 230            (and (typep y 'instance)
 231                 (eq layout-x (%instance-layout y))
 232                 (structure-classoid-p (layout-classoid layout-x))
 233                 (do ((i 1 (1+ i)))
 234                     ((= i len) t)
 235                   (declare (fixnum i))
 236                   (let ((x-el (%instance-ref x i))
 237                         (y-el (%instance-ref y i)))
 238                     (unless (or (eq x-el y-el)
 239                                 (equalp x-el y-el))
 240                       (return nil)))))))
 241         ((vectorp x)
 242          (let ((length (length x)))
 243            (and (vectorp y)
 244                 (= length (length y))
 245                 (dotimes (i length t)
 246                   (let ((x-el (aref x i))
 247                         (y-el (aref y i)))
 248                     (unless (or (eq x-el y-el)
 249                                 (equalp x-el y-el))
 250                       (return nil)))))))
 251         ((arrayp x)
 252          (and (arrayp y)
 253               (= (array-rank x) (array-rank y))
 254               (dotimes (axis (array-rank x) t)
 255                 (unless (= (array-dimension x axis)
 256                            (array-dimension y axis))
 257                   (return nil)))
 258               (dotimes (index (array-total-size x) t)
 259                 (let ((x-el (row-major-aref x index))
 260                       (y-el (row-major-aref y index)))
 261                   (unless (or (eq x-el y-el)
 262                               (equalp x-el y-el))
 263                     (return nil))))))
 264         (t nil)))
 265
 266 (/show0 "about to do test cases in pred.lisp")
 267 #!+sb-test
 268 (let ((test-cases `((0.0 ,(load-time-value (make-unportable-float :single-float-negative-zero)) t)
 269                     (0.0 1.0 nil)
 270                     (#c(1 0) #c(1.0 0) t)
 271                     (#c(1.1 0) #c(11/10 0) nil) ; due to roundoff error
 272                     ("Hello" "hello" t)
 273                     ("Hello" #(#\h #\E #\l #\l #\o) t)
 274                     ("Hello" "goodbye" nil))))
 275   (/show0 "TEST-CASES bound in pred.lisp")
 276   (dolist (test-case test-cases)
 277     (/show0 "about to do a TEST-CASE in pred.lisp")
 278     (destructuring-bind (x y expected-result) test-case
 279       (let* ((result (equalp x y))
 280              (bresult (if result 1 0))
 281              (expected-bresult (if expected-result 1 0)))
 282         (unless (= bresult expected-bresult)
 283           (/show0 "failing test in pred.lisp")
 284           (error "failed test (EQUALP ~S ~S)" x y))))))
 285 (/show0 "done with test cases in pred.lisp")