src/code/pred.lisp

   1 ;;;; predicate functions (EQUAL and friends, and type predicates)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; miscellaneous non-primitive predicates
  15
  16 #!-sb-fluid (declaim (inline streamp))
  17 (defun streamp (stream)
  18   (typep stream 'stream))
  19
  20 ;;; Is X a (VECTOR T)?
  21 (defun vector-t-p (x)
  22   (or (simple-vector-p x)
  23       (and (complex-vector-p x)
  24            (simple-vector-p (%array-data-vector x)))))
  25 \f
  26 ;;;; primitive predicates. These must be supported directly by the
  27 ;;;; compiler.
  28
  29 (defun not (object)
  30   #!+sb-doc
  31   "Return T if X is NIL, otherwise return NIL."
  32   (not object))
  33
  34 ;;; All the primitive type predicate wrappers share a parallel form..
  35 (macrolet ((def-type-predicate-wrapper (pred)
  36              (let* ((name (symbol-name pred))
  37                     (stem (string-left-trim "%" (string-right-trim "P-" name)))
  38                     (article (if (position (schar name 0) "AEIOU") "an" "a")))
  39                `(defun ,pred (object)
  40                   ,(format nil
  41                            "Return true if OBJECT is ~A ~A, and NIL otherwise."
  42                            article
  43                            stem)
  44                   ;; (falling through to low-level implementation)
  45                   (,pred object)))))
  46   (def-type-predicate-wrapper array-header-p)
  47   (def-type-predicate-wrapper arrayp)
  48   (def-type-predicate-wrapper atom)
  49   (def-type-predicate-wrapper base-char-p)
  50   (def-type-predicate-wrapper base-string-p)
  51   #!+sb-unicode (def-type-predicate-wrapper character-string-p)
  52   (def-type-predicate-wrapper bignump)
  53   (def-type-predicate-wrapper bit-vector-p)
  54   (def-type-predicate-wrapper characterp)
  55   (def-type-predicate-wrapper code-component-p)
  56   (def-type-predicate-wrapper consp)
  57   (def-type-predicate-wrapper compiled-function-p)
  58   (def-type-predicate-wrapper complexp)
  59   (def-type-predicate-wrapper complex-double-float-p)
  60   (def-type-predicate-wrapper complex-float-p)
  61   #!+long-float (def-type-predicate-wrapper complex-long-float-p)
  62   (def-type-predicate-wrapper complex-rational-p)
  63   (def-type-predicate-wrapper complex-single-float-p)
  64   ;; (COMPLEX-VECTOR-P is not included here since it's awkward to express
  65   ;; the type it tests for in the Common Lisp type system, and since it's
  66   ;; only used in the implementation of a few specialized things.)
  67   (def-type-predicate-wrapper double-float-p)
  68   (def-type-predicate-wrapper extended-char-p)
  69   (def-type-predicate-wrapper fdefn-p)
  70   (def-type-predicate-wrapper fixnump)
  71   (def-type-predicate-wrapper floatp)
  72   (def-type-predicate-wrapper functionp)
  73   (def-type-predicate-wrapper integerp)
  74   (def-type-predicate-wrapper listp)
  75   (def-type-predicate-wrapper long-float-p)
  76   (def-type-predicate-wrapper lra-p)
  77   (def-type-predicate-wrapper null)
  78   (def-type-predicate-wrapper numberp)
  79   (def-type-predicate-wrapper rationalp)
  80   (def-type-predicate-wrapper ratiop)
  81   (def-type-predicate-wrapper realp)
  82   (def-type-predicate-wrapper short-float-p)
  83   (def-type-predicate-wrapper simple-array-p)
  84   (def-type-predicate-wrapper simple-bit-vector-p)
  85   (def-type-predicate-wrapper simple-base-string-p)
  86   #!+sb-unicode (def-type-predicate-wrapper simple-character-string-p)
  87   (def-type-predicate-wrapper simple-string-p)
  88   (def-type-predicate-wrapper simple-vector-p)
  89   (def-type-predicate-wrapper single-float-p)
  90   (def-type-predicate-wrapper stringp)
  91   (def-type-predicate-wrapper %instancep)
  92   (def-type-predicate-wrapper symbolp)
  93   (def-type-predicate-wrapper system-area-pointer-p)
  94   (def-type-predicate-wrapper weak-pointer-p)
  95   (def-type-predicate-wrapper vectorp)
  96   (def-type-predicate-wrapper unsigned-byte-32-p)
  97   (def-type-predicate-wrapper signed-byte-32-p)
  98   (def-type-predicate-wrapper simple-array-nil-p)
  99   (def-type-predicate-wrapper simple-array-unsigned-byte-2-p)
 100   (def-type-predicate-wrapper simple-array-unsigned-byte-4-p)
 101   (def-type-predicate-wrapper simple-array-unsigned-byte-8-p)
 102   (def-type-predicate-wrapper simple-array-unsigned-byte-16-p)
 103   (def-type-predicate-wrapper simple-array-unsigned-byte-32-p)
 104   (def-type-predicate-wrapper simple-array-signed-byte-8-p)
 105   (def-type-predicate-wrapper simple-array-signed-byte-16-p)
 106   (def-type-predicate-wrapper simple-array-signed-byte-30-p)
 107   (def-type-predicate-wrapper simple-array-signed-byte-32-p)
 108   (def-type-predicate-wrapper simple-array-single-float-p)
 109   (def-type-predicate-wrapper simple-array-double-float-p)
 110   #!+long-float (def-type-predicate-wrapper simple-array-long-float-p)
 111   (def-type-predicate-wrapper simple-array-complex-single-float-p)
 112   (def-type-predicate-wrapper simple-array-complex-double-float-p)
 113   #!+long-float (def-type-predicate-wrapper simple-array-complex-long-float-p))
 114 \f
 115 ;;; Return the specifier for the type of object. This is not simply
 116 ;;; (TYPE-SPECIFIER (CTYPE-OF OBJECT)) because CTYPE-OF has different
 117 ;;; goals than TYPE-OF. In particular, speed is more important than
 118 ;;; precision, and it is not permitted to return member types.
 119 (defun type-of (object)
 120   #!+sb-doc
 121   "Return the type of OBJECT."
 122   (typecase object
 123     (fixnum
 124      (cond
 125        ((<= 0 object 1) 'bit)
 126        ((< object 0) 'fixnum)
 127        (t '(integer 0 #.sb!xc:most-positive-fixnum))))
 128     (integer
 129      (if (>= object 0)
 130          '(integer #.(1+ sb!xc:most-positive-fixnum))
 131          'bignum))
 132     (standard-char 'standard-char)
 133     (base-char 'base-char)
 134     (extended-char 'extended-char)
 135     ((member t) 'boolean)
 136     (keyword 'keyword)
 137     ((or array complex) (type-specifier (ctype-of object)))
 138     (t
 139      (let* ((classoid (layout-classoid (layout-of object)))
 140             (name (classoid-name classoid)))
 141        (if (typep object 'instance)
 142            (case name
 143              (sb!alien-internals:alien-value
 144               `(sb!alien:alien
 145                 ,(sb!alien-internals:unparse-alien-type
 146                   (sb!alien-internals:alien-value-type object))))
 147              (t
 148               (let ((pname (classoid-proper-name classoid)))
 149                 (if (classoid-p pname)
 150                     (classoid-pcl-class pname)
 151                     pname))))
 152            name)))))
 153 \f
 154 ;;;; equality predicates
 155
 156 ;;; This is real simple, 'cause the compiler takes care of it.
 157 (defun eq (obj1 obj2)
 158   #!+sb-doc
 159   "Return T if OBJ1 and OBJ2 are the same object, otherwise NIL."
 160   (eq obj1 obj2))
 161
 162 (defun bit-vector-= (x y)
 163   (declare (type bit-vector x y))
 164   (if (and (simple-bit-vector-p x)
 165            (simple-bit-vector-p y))
 166       (bit-vector-= x y) ; DEFTRANSFORM
 167       (and (= (length x) (length y))
 168            (do ((i 0 (1+ i))
 169                 (length (length x)))
 170                ((= i length) t)
 171              (declare (fixnum i))
 172              (unless (= (bit x i) (bit y i))
 173                (return nil))))))
 174
 175 (defun equal (x y)
 176   #!+sb-doc
 177   "Return T if X and Y are EQL or if they are structured components
 178   whose elements are EQUAL. Strings and bit-vectors are EQUAL if they
 179   are the same length and have identical components. Other arrays must be
 180   EQ to be EQUAL."
 181   (cond ((eql x y) t)
 182         ((consp x)
 183          (and (consp y)
 184               (equal (car x) (car y))
 185               (equal (cdr x) (cdr y))))
 186         ((stringp x)
 187          (and (stringp y) (string= x y)))
 188         ((pathnamep x)
 189          (and (pathnamep y) (pathname= x y)))
 190         ((bit-vector-p x)
 191          (and (bit-vector-p y)
 192               (bit-vector-= x y)))
 193         (t nil)))
 194
 195 ;;; EQUALP comparison of HASH-TABLE values
 196 (defun hash-table-equalp (x y)
 197   (declare (type hash-table x y))
 198   (or (eq x y)
 199       (and (hash-table-p y)
 200            (eql (hash-table-count x) (hash-table-count y))
 201            (eql (hash-table-test x) (hash-table-test y))
 202            (block comparison-of-entries
 203              (maphash (lambda (key x-value)
 204                         (multiple-value-bind (y-value y-value-p)
 205                             (gethash key y)
 206                           (unless (and y-value-p (equalp x-value y-value))
 207                             (return-from comparison-of-entries nil))))
 208                       x)
 209              t))))
 210
 211 (defun equalp (x y)
 212   #+nil ; KLUDGE: If doc string, should be accurate: Talk about structures
 213   ; and HASH-TABLEs.
 214   "This is like EQUAL, except more liberal in several respects.
 215   Numbers may be of different types, as long as the values are identical
 216   after coercion. Characters may differ in alphabetic case. Vectors and
 217   arrays must have identical dimensions and EQUALP elements, but may differ
 218   in their type restriction."
 219   (cond ((eq x y) t)
 220         ((characterp x) (and (characterp y) (char-equal x y)))
 221         ((numberp x) (and (numberp y) (= x y)))
 222         ((consp x)
 223          (and (consp y)
 224               (equalp (car x) (car y))
 225               (equalp (cdr x) (cdr y))))
 226         ((pathnamep x)
 227          (and (pathnamep y) (pathname= x y)))
 228         ((hash-table-p x)
 229          (and (hash-table-p y)
 230               (hash-table-equalp x y)))
 231         ((typep x 'instance)
 232          (let* ((layout-x (%instance-layout x))
 233                 (len (layout-length layout-x)))
 234            (and (typep y 'instance)
 235                 (eq layout-x (%instance-layout y))
 236                 (structure-classoid-p (layout-classoid layout-x))
 237                 (do ((i 1 (1+ i)))
 238                     ((= i len) t)
 239                   (declare (fixnum i))
 240                   (let ((x-el (%instance-ref x i))
 241                         (y-el (%instance-ref y i)))
 242                     (unless (or (eq x-el y-el)
 243                                 (equalp x-el y-el))
 244                       (return nil)))))))
 245         ((vectorp x)
 246          (let ((length (length x)))
 247            (and (vectorp y)
 248                 (= length (length y))
 249                 (dotimes (i length t)
 250                   (let ((x-el (aref x i))
 251                         (y-el (aref y i)))
 252                     (unless (or (eq x-el y-el)
 253                                 (equalp x-el y-el))
 254                       (return nil)))))))
 255         ((arrayp x)
 256          (and (arrayp y)
 257               (= (array-rank x) (array-rank y))
 258               (dotimes (axis (array-rank x) t)
 259                 (unless (= (array-dimension x axis)
 260                            (array-dimension y axis))
 261                   (return nil)))
 262               (dotimes (index (array-total-size x) t)
 263                 (let ((x-el (row-major-aref x index))
 264                       (y-el (row-major-aref y index)))
 265                   (unless (or (eq x-el y-el)
 266                               (equalp x-el y-el))
 267                     (return nil))))))
 268         (t nil)))
 269
 270 (/show0 "about to do test cases in pred.lisp")
 271 #!+sb-test
 272 (let ((test-cases `((0.0 ,(load-time-value (make-unportable-float :single-float-negative-zero)) t)
 273                     (0.0 1.0 nil)
 274                     (#c(1 0) #c(1.0 0) t)
 275                     (#c(1.1 0) #c(11/10 0) nil) ; due to roundoff error
 276                     ("Hello" "hello" t)
 277                     ("Hello" #(#\h #\E #\l #\l #\o) t)
 278                     ("Hello" "goodbye" nil))))
 279   (/show0 "TEST-CASES bound in pred.lisp")
 280   (dolist (test-case test-cases)
 281     (/show0 "about to do a TEST-CASE in pred.lisp")
 282     (destructuring-bind (x y expected-result) test-case
 283       (let* ((result (equalp x y))
 284              (bresult (if result 1 0))
 285              (expected-bresult (if expected-result 1 0)))
 286         (unless (= bresult expected-bresult)
 287           (/show0 "failing test in pred.lisp")
 288           (error "failed test (EQUALP ~S ~S)" x y))))))
 289 (/show0 "done with test cases in pred.lisp")