src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 (eval-when (:compile-toplevel :load-toplevel :execute)
  39   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  40 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  41
  42 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  43 ;;; getting nonconforming behavior by messing around with
  44 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  45 ;;; now we just don't worry about it. If for some reason it becomes
  46 ;;; worrisome and the magic value needs replacement:
  47 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  48 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  49 ;;;     work when compiled into a file and loaded back into SBCL.
  50 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  51 ;;;   * The replacement value needs to be acceptable to the
  52 ;;;     low-level gencgc.lisp hash table scavenging code.
  53 ;;;   * The change will break binary compatibility, since comparisons
  54 ;;;     against the value used at the time of compilation are wired
  55 ;;;     into FASL files.
  56 ;;; -- WHN 20000622
  57 \f
  58 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  59
  60 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  61   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  62     (let* ((r-inits nil) ; accumulator for reversed list
  63            (r-steps nil) ; accumulator for reversed list
  64            (label-1 (gensym))
  65            (label-2 (gensym)))
  66       ;; Check for illegal old-style DO.
  67       (when (or (not (listp varlist)) (atom endlist))
  68         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  69       ;; Parse VARLIST to get R-INITS and R-STEPS.
  70       (dolist (v varlist)
  71         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  72                ;; defined in terms of CL:SETF, and CL:SETF can be
  73                ;; defined in terms of CL:DO, and CL:DO can be defined
  74                ;; in terms of the current function.)
  75                (push-on-r-inits (x)
  76                  (setq r-inits (cons x r-inits)))
  77                ;; common error-handling
  78                (illegal-varlist ()
  79                  (error "~S is an illegal form for a ~S varlist." v name)))
  80           (cond ((symbolp v) (push-on-r-inits v))
  81                 ((listp v)
  82                  (unless (symbolp (first v))
  83                    (error "~S step variable is not a symbol: ~S"
  84                           name
  85                           (first v)))
  86                  (let ((lv (length v)))
  87                    ;; (We avoid using CL:CASE here so that CL:CASE can
  88                    ;; be defined in terms of CL:SETF, and CL:SETF can
  89                    ;; be defined in terms of CL:DO, and CL:DO can be
  90                    ;; defined in terms of the current function.)
  91                    (cond ((= lv 1)
  92                           (push-on-r-inits (first v)))
  93                          ((= lv 2)
  94                           (push-on-r-inits v))
  95                          ((= lv 3)
  96                           (push-on-r-inits (list (first v) (second v)))
  97                           (setq r-steps (list* (third v) (first v) r-steps)))
  98                          (t (illegal-varlist)))))
  99                 (t (illegal-varlist)))))
 100       ;; Construct the new form.
 101       (multiple-value-bind (code decls)
 102           (parse-body decls-and-code :doc-string-allowed nil)
 103         `(block ,block
 104            (,bind ,(nreverse r-inits)
 105                   ,@decls
 106                   (tagbody
 107                      (go ,label-2)
 108                      ,label-1
 109                      (tagbody ,@code)
 110                      (,step ,@(nreverse r-steps))
 111                      ,label-2
 112                      (unless ,(first endlist) (go ,label-1))
 113                      (return-from ,block (progn ,@(rest endlist))))))))))
 114
 115 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 116 ;;; initialized in parallel to the value of the specified INIT form.
 117 ;;; On subsequent iterations, the VARS are assigned the value of the
 118 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 119 ;;; evaluation of the body FORMS. When the TEST is true, the
 120 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 121 ;;; value of the DO.
 122 (defmacro do-anonymous (varlist endlist &rest body)
 123   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 124 \f
 125 ;;;; GENSYM tricks
 126
 127 ;;; GENSYM variant for easier debugging and better backtraces: append
 128 ;;; the closest enclosing non-nil block name to the provided stem.
 129 (defun block-gensym (&optional (name "G") (env (when (boundp 'sb!c::*lexenv*)
 130                                              (symbol-value 'sb!c::*lexenv*))))
 131   (let ((block-name (when env
 132                       (car (find-if #'car (sb!c::lexenv-blocks env))))))
 133     (if block-name
 134         (gensym (format nil "~A[~S]" name block-name))
 135         (gensym name))))
 136
 137 ;;; Automate an idiom often found in macros:
 138 ;;;   (LET ((FOO (GENSYM "FOO"))
 139 ;;;         (MAX-INDEX (GENSYM "MAX-INDEX-")))
 140 ;;;     ...)
 141 ;;;
 142 ;;; "Good notation eliminates thought." -- Eric Siggia
 143 ;;;
 144 ;;; Incidentally, this is essentially the same operator which
 145 ;;; _On Lisp_ calls WITH-GENSYMS.
 146 (defmacro with-unique-names (symbols &body body)
 147   `(let ,(mapcar (lambda (symbol)
 148                    (let* ((symbol-name (symbol-name symbol))
 149                           (stem (if (every #'alpha-char-p symbol-name)
 150                                     symbol-name
 151                                     (concatenate 'string symbol-name "-"))))
 152                      `(,symbol (block-gensym ,stem))))
 153                  symbols)
 154      ,@body))
 155
 156 ;;; Return a list of N gensyms. (This is a common suboperation in
 157 ;;; macros and other code-manipulating code.)
 158 (declaim (ftype (function (index) list) make-gensym-list))
 159 (defun make-gensym-list (n)
 160   (loop repeat n collect (block-gensym)))
 161 \f
 162 ;;;; miscellany
 163
 164 ;;; Lots of code wants to get to the KEYWORD package or the
 165 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 166 ;;; variables. TO DO: How much does this actually buy us? It sounds
 167 ;;; sensible, but I don't know for sure that it saves space or time..
 168 ;;; -- WHN 19990521
 169 ;;;
 170 ;;; (The initialization forms here only matter on the cross-compilation
 171 ;;; host; In the target SBCL, these variables are set in cold init.)
 172 (declaim (type package *cl-package* *keyword-package*))
 173 (defvar *cl-package*      (find-package "COMMON-LISP"))
 174 (defvar *keyword-package* (find-package "KEYWORD"))
 175
 176 ;;; Concatenate together the names of some strings and symbols,
 177 ;;; producing a symbol in the current package.
 178 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 179   (defun symbolicate (&rest things)
 180     (let* ((length (reduce #'+ things
 181                            :key (lambda (x) (length (string x)))))
 182            (name (make-array length :element-type 'character)))
 183       (let ((index 0))
 184         (dolist (thing things (values (intern name)))
 185           (let* ((x (string thing))
 186                  (len (length x)))
 187             (replace name x :start1 index)
 188             (incf index len)))))))
 189
 190 ;;; like SYMBOLICATE, but producing keywords
 191 (defun keywordicate (&rest things)
 192   (let ((*package* *keyword-package*))
 193     (apply #'symbolicate things)))
 194
 195 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 196 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 197 ;;; assignment is undefined behavior, so it's sort of reasonable for
 198 ;;; it to cause the system to go totally insane afterwards, but it's a
 199 ;;; fairly easy mistake to make, so let's try to recover gracefully
 200 ;;; instead.)
 201 (defun sane-package ()
 202   (let ((maybe-package *package*))
 203     (cond ((and (packagep maybe-package)
 204                 ;; For good measure, we also catch the problem of
 205                 ;; *PACKAGE* being bound to a deleted package.
 206                 ;; Technically, this is not undefined behavior in itself,
 207                 ;; but it will immediately lead to undefined to behavior,
 208                 ;; since almost any operation on a deleted package is
 209                 ;; undefined.
 210                 (package-name maybe-package))
 211            maybe-package)
 212           (t
 213            ;; We're in the undefined behavior zone. First, munge the
 214            ;; system back into a defined state.
 215            (let ((really-package (find-package :cl-user)))
 216              (setf *package* really-package)
 217              ;; Then complain.
 218              (error 'simple-type-error
 219                     :datum maybe-package
 220                     :expected-type '(and package (satisfies package-name))
 221                     :format-control
 222                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 223                     :format-arguments (list '*package*
 224                                             (if (packagep maybe-package)
 225                                                 "deleted package"
 226                                                 (type-of maybe-package))
 227                                             '*package* really-package)))))))
 228
 229 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 230 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 231 ;;; actually need to reset the variable when it's silly, since even
 232 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 233 ;;; in a state where it's hard to recover interactively.)
 234 (defun sane-default-pathname-defaults ()
 235   (let* ((dfd *default-pathname-defaults*)
 236          (dfd-dir (pathname-directory dfd)))
 237     ;; It's generally not good to use a relative pathname for
 238     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 239     ;; are defined by merging into a default pathname (which is,
 240     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 241     (when (and (consp dfd-dir)
 242                (eql (first dfd-dir) :relative))
 243       (warn
 244        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 245        '*default-pathname-defaults*))
 246     dfd))
 247
 248 ;;; Give names to elements of a numeric sequence.
 249 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 250                    &rest identifiers)
 251   (let ((results nil)
 252         (index 0)
 253         (start (eval start))
 254         (step (eval step)))
 255     (dolist (id identifiers)
 256       (when id
 257         (multiple-value-bind (root docs)
 258             (if (consp id)
 259                 (values (car id) (cdr id))
 260                 (values id nil))
 261           (push `(def!constant ,(symbolicate prefix root suffix)
 262                    ,(+ start (* step index))
 263                    ,@docs)
 264                 results)))
 265       (incf index))
 266     `(progn
 267        ,@(nreverse results))))
 268
 269 ;;; generalization of DEFCONSTANT to values which are the same not
 270 ;;; under EQL but under e.g. EQUAL or EQUALP
 271 ;;;
 272 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 273 ;;; which are appropriately compared using the function given by the
 274 ;;; EQX argument instead of EQL.
 275 ;;;
 276 ;;; Note: Be careful when using this macro, since it's easy to
 277 ;;; unintentionally pessimize your code. A good time to use this macro
 278 ;;; is when the values defined will be fed into optimization
 279 ;;; transforms and never actually appear in the generated code; this
 280 ;;; is especially common when defining BYTE expressions. Unintentional
 281 ;;; pessimization can result when the values defined by this macro are
 282 ;;; actually used in generated code: because of the way that the
 283 ;;; dump/load system works, you'll typically get one copy of consed
 284 ;;; structure for each object file which contains code referring to
 285 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 286 ;;; the constant. If you don't want that to happen, you should
 287 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 288 ;;; need to avoid runtime indirection through a symbol, you might be
 289 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 290 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 291   `(def!constant ,symbol
 292      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 293      ,@(when doc (list doc))))
 294 (defun %defconstant-eqx-value (symbol expr eqx)
 295   (declare (type function eqx))
 296   (flet ((bummer (explanation)
 297            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 298                   symbol
 299                   expr
 300                   explanation
 301                   (symbol-value symbol))))
 302     (cond ((not (boundp symbol))
 303            expr)
 304           ((not (constantp symbol))
 305            (bummer "already bound as a non-constant"))
 306           ((not (funcall eqx (symbol-value symbol) expr))
 307            (bummer "already bound as a different constant value"))
 308           (t
 309            (symbol-value symbol)))))
 310 \f
 311 ;;; a helper function for various macros which expect clauses of a
 312 ;;; given length, etc.
 313 ;;;
 314 ;;; Return true if X is a proper list whose length is between MIN and
 315 ;;; MAX (inclusive).
 316 (defun proper-list-of-length-p (x min &optional (max min))
 317   ;; FIXME: This implementation will hang on circular list
 318   ;; structure. Since this is an error-checking utility, i.e. its
 319   ;; job is to deal with screwed-up input, it'd be good style to fix
 320   ;; it so that it can deal with circular list structure.
 321   (cond ((minusp max) nil)
 322         ((null x) (zerop min))
 323         ((consp x)
 324          (and (plusp max)
 325               (proper-list-of-length-p (cdr x)
 326                                        (if (plusp (1- min))
 327                                            (1- min)
 328                                            0)
 329                                        (1- max))))
 330         (t nil)))
 331
 332 ;;; Helpers for defining error-signalling NOP's for "not supported
 333 ;;; here" operations.
 334 (defmacro define-unsupported-fun (name &optional
 335                                   (doc "Unsupported on this platform.")
 336                                   (control
 337                                    "~S is unsupported on this platform ~
 338                                     (OS, CPU, whatever)."
 339                                    controlp)
 340                                   arguments)
 341   `(defun ,name (&rest args)
 342     ,doc
 343     (declare (ignore args))
 344     (error 'unsupported-operator
 345      :format-control ,control
 346      :format-arguments (if ,controlp ',arguments (list ',name)))))