src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!INT")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 ;;;
  39 ;;; FIXME: We end up doing two DEFCONSTANT forms because (1) LispWorks
  40 ;;; needs EVAL-WHEN wrapped around DEFCONSTANT, and (2) SBCL's
  41 ;;; DEFCONSTANT expansion doesn't seem to behave properly inside
  42 ;;; EVAL-WHEN, so that without this, the +EMPTY-HT-SLOT+ references in
  43 ;;; e.g. DOHASH macroexpansions don't end up being replaced by
  44 ;;; constant values, so that the system dies at cold init because
  45 ;;; '+EMPTY-HT-SLOT+ isn't bound yet. It's hard to fix this properly
  46 ;;; until SBCL's EVAL-WHEN is fixed, which is waiting for the IR1
  47 ;;; interpreter to go away, which is waiting for sbcl-0.7.x..
  48 (eval-when (:compile-toplevel :load-toplevel :execute)
  49   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  50 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  51 #+nil (defconstant +empty-ht-slot+ '#.+empty-ht-slot+) ; egads.. See FIXME above.
  52 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  53 ;;; getting nonconforming behavior by messing around with
  54 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  55 ;;; now we just don't worry about it. If for some reason it becomes
  56 ;;; worrisome and the magic value needs replacement:
  57 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  58 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  59 ;;;     work when compiled into a file and loaded back into SBCL.
  60 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  61 ;;;   * The replacement value needs to be acceptable to the
  62 ;;;     low-level gencgc.lisp hash table scavenging code.
  63 ;;;   * The change will break binary compatibility, since comparisons
  64 ;;;     against the value used at the time of compilation are wired
  65 ;;;     into FASL files.
  66 ;;; -- WHN 20000622
  67 \f
  68 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  69
  70 (eval-when (:compile-toplevel :load-toplevel :execute)
  71   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  72     (let* ((r-inits nil) ; accumulator for reversed list
  73            (r-steps nil) ; accumulator for reversed list
  74            (label-1 (gensym))
  75            (label-2 (gensym)))
  76       ;; Check for illegal old-style DO.
  77       (when (or (not (listp varlist)) (atom endlist))
  78         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  79       ;; Parse VARLIST to get R-INITS and R-STEPS.
  80       (dolist (v varlist)
  81         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  82                ;; defined in terms of CL:SETF, and CL:SETF can be
  83                ;; defined in terms of CL:DO, and CL:DO can be defined
  84                ;; in terms of the current function.)
  85                (push-on-r-inits (x)
  86                  (setq r-inits (cons x r-inits)))
  87                ;; common error-handling
  88                (illegal-varlist ()
  89                  (error "~S is an illegal form for a ~S varlist." v name)))
  90           (cond ((symbolp v) (push-on-r-inits v))
  91                 ((listp v)
  92                  (unless (symbolp (first v))
  93                    (error "~S step variable is not a symbol: ~S"
  94                           name
  95                           (first v)))
  96                  (let ((lv (length v)))
  97                    ;; (We avoid using CL:CASE here so that CL:CASE can
  98                    ;; be defined in terms of CL:SETF, and CL:SETF can
  99                    ;; be defined in terms of CL:DO, and CL:DO can be
 100                    ;; defined in terms of the current function.)
 101                    (cond ((= lv 1)
 102                           (push-on-r-inits (first v)))
 103                          ((= lv 2)
 104                           (push-on-r-inits v))
 105                          ((= lv 3)
 106                           (push-on-r-inits (list (first v) (second v)))
 107                           (setq r-steps (list* (third v) (first v) r-steps)))
 108                          (t (illegal-varlist)))))
 109                 (t (illegal-varlist)))))
 110       ;; Construct the new form.
 111       (multiple-value-bind (code decls) (parse-body decls-and-code nil)
 112         `(block ,block
 113            (,bind ,(nreverse r-inits)
 114                   ,@decls
 115                   (tagbody
 116                    (go ,label-2)
 117                    ,label-1
 118                    ,@code
 119                    (,step ,@(nreverse r-steps))
 120                    ,label-2
 121                    (unless ,(first endlist) (go ,label-1))
 122                    (return-from ,block (progn ,@(rest endlist))))))))))
 123
 124 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 125 ;;; initialized in parallel to the value of the specified INIT form.
 126 ;;; On subsequent iterations, the VARS are assigned the value of the
 127 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 128 ;;; evaluation of the body FORMS. When the TEST is true, the
 129 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 130 ;;; value of the DO.
 131 (defmacro do-anonymous (varlist endlist &rest body)
 132   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 133 \f
 134 ;;;; miscellany
 135
 136 ;;; Lots of code wants to get to the KEYWORD package or the
 137 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 138 ;;; variables. TO DO: How much does this actually buy us? It sounds
 139 ;;; sensible, but I don't know for sure that it saves space or time..
 140 ;;; -- WHN 19990521
 141 ;;;
 142 ;;; (The initialization forms here only matter on the cross-compilation
 143 ;;; host; In the target SBCL, these variables are set in cold init.)
 144 (declaim (type package *cl-package* *keyword-package*))
 145 (defvar *cl-package*      (find-package "COMMON-LISP"))
 146 (defvar *keyword-package* (find-package "KEYWORD"))
 147
 148 ;;; Concatenate together the names of some strings and symbols,
 149 ;;; producing a symbol in the current package.
 150 (eval-when (:compile-toplevel :load-toplevel :execute)
 151   (defun symbolicate (&rest things)
 152     (let ((name (case (length things)
 153                   ;; why isn't this just the value in the T branch?
 154                   ;; Well, this is called early in cold-init, before
 155                   ;; the type system is set up; however, now that we
 156                   ;; check for bad lengths, the type system is needed
 157                   ;; for calls to CONCATENATE. So we need to make sure
 158                   ;; that the calls are transformed away:
 159                   (1 (concatenate 'string (the simple-string (string (car things)))))
 160                   (2 (concatenate 'string
 161                                   (the simple-string (string (car things)))
 162                                   (the simple-string (string (cadr things)))))
 163                   (3 (concatenate 'string
 164                                   (the simple-string (string (car things)))
 165                                   (the simple-string (string (cadr things)))
 166                                   (the simple-string (string (caddr things)))))
 167                   (t (apply #'concatenate 'string (mapcar #'string things))))))
 168     (values (intern name)))))
 169
 170 ;;; like SYMBOLICATE, but producing keywords
 171 (defun keywordicate (&rest things)
 172   (let ((*package* *keyword-package*))
 173     (apply #'symbolicate things)))
 174
 175 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 176 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 177 ;;; assignment is undefined behavior, so it's sort of reasonable for
 178 ;;; it to cause the system to go totally insane afterwards, but it's a
 179 ;;; fairly easy mistake to make, so let's try to recover gracefully
 180 ;;; instead.)
 181 (defun sane-package ()
 182   (let ((maybe-package *package*))
 183     (cond ((and (packagep maybe-package)
 184                 ;; For good measure, we also catch the problem of
 185                 ;; *PACKAGE* being bound to a deleted package.
 186                 ;; Technically, this is not undefined behavior in itself,
 187                 ;; but it will immediately lead to undefined to behavior,
 188                 ;; since almost any operation on a deleted package is
 189                 ;; undefined.
 190                 (package-name maybe-package))
 191            maybe-package)
 192           (t
 193            ;; We're in the undefined behavior zone. First, munge the
 194            ;; system back into a defined state.
 195            (let ((really-package (find-package :cl-user)))
 196              (setf *package* really-package)
 197              ;; Then complain.
 198              (error 'simple-type-error
 199                     :datum maybe-package
 200                     :expected-type '(and package (satisfies package-name))
 201                     :format-control
 202                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 203                     :format-arguments (list '*package*
 204                                             (if (packagep maybe-package)
 205                                                 "deleted package"
 206                                                 (type-of maybe-package))
 207                                             '*package* really-package)))))))
 208
 209 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 210 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 211 ;;; actually need to reset the variable when it's silly, since even
 212 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 213 ;;; in a state where it's hard to recover interactively.)
 214 (defun sane-default-pathname-defaults ()
 215   (let* ((dfd *default-pathname-defaults*)
 216          (dfd-dir (pathname-directory dfd)))
 217     ;; It's generally not good to use a relative pathname for
 218     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 219     ;; are defined by merging into a default pathname (which is,
 220     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 221     (when (and (consp dfd-dir)
 222                (eql (first dfd-dir) :relative))
 223       (warn
 224        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 225        '*default-pathname-defaults*))
 226     dfd))
 227
 228 ;;; Give names to elements of a numeric sequence.
 229 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 230                    &rest identifiers)
 231   (let ((results nil)
 232         (index 0)
 233         (start (eval start))
 234         (step (eval step)))
 235     (dolist (id identifiers)
 236       (when id
 237         (multiple-value-bind (root docs)
 238             (if (consp id)
 239                 (values (car id) (cdr id))
 240                 (values id nil))
 241           (push `(def!constant ,(symbolicate prefix root suffix)
 242                    ,(+ start (* step index))
 243                    ,@docs)
 244                 results)))
 245       (incf index))
 246     `(progn
 247        ,@(nreverse results))))
 248
 249 ;;; generalization of DEFCONSTANT to values which are the same not
 250 ;;; under EQL but under e.g. EQUAL or EQUALP
 251 ;;;
 252 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 253 ;;; which are appropriately compared using the function given by the
 254 ;;; EQX argument instead of EQL.
 255 ;;;
 256 ;;; Note: Be careful when using this macro, since it's easy to
 257 ;;; unintentionally pessimize your code. A good time to use this macro
 258 ;;; is when the values defined will be fed into optimization
 259 ;;; transforms and never actually appear in the generated code; this
 260 ;;; is especially common when defining BYTE expressions. Unintentional
 261 ;;; pessimization can result when the values defined by this macro are
 262 ;;; actually used in generated code: because of the way that the
 263 ;;; dump/load system works, you'll typically get one copy of consed
 264 ;;; structure for each object file which contains code referring to
 265 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 266 ;;; the constant. If you don't want that to happen, you should
 267 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 268 ;;; need to avoid runtime indirection through a symbol, you might be
 269 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 270 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 271   `(def!constant ,symbol
 272      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 273      ,@(when doc (list doc))))
 274 (defun %defconstant-eqx-value (symbol expr eqx)
 275   (declare (type function eqx))
 276   (flet ((bummer (explanation)
 277            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 278                   symbol
 279                   expr
 280                   explanation
 281                   (symbol-value symbol))))
 282     (cond ((not (boundp symbol))
 283            expr)
 284           ((not (constantp symbol))
 285            (bummer "already bound as a non-constant"))
 286           ((not (funcall eqx (symbol-value symbol) expr))
 287            (bummer "already bound as a different constant value"))
 288           (t
 289            (symbol-value symbol)))))