src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 (eval-when (:compile-toplevel :load-toplevel :execute)
  39   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  40 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  41
  42 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  43 ;;; getting nonconforming behavior by messing around with
  44 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  45 ;;; now we just don't worry about it. If for some reason it becomes
  46 ;;; worrisome and the magic value needs replacement:
  47 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  48 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  49 ;;;     work when compiled into a file and loaded back into SBCL.
  50 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  51 ;;;   * The replacement value needs to be acceptable to the
  52 ;;;     low-level gencgc.lisp hash table scavenging code.
  53 ;;;   * The change will break binary compatibility, since comparisons
  54 ;;;     against the value used at the time of compilation are wired
  55 ;;;     into FASL files.
  56 ;;; -- WHN 20000622
  57 \f
  58 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  59
  60 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  61   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  62     (let* ((r-inits nil) ; accumulator for reversed list
  63            (r-steps nil) ; accumulator for reversed list
  64            (label-1 (gensym))
  65            (label-2 (gensym)))
  66       ;; Check for illegal old-style DO.
  67       (when (or (not (listp varlist)) (atom endlist))
  68         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  69       ;; Parse VARLIST to get R-INITS and R-STEPS.
  70       (dolist (v varlist)
  71         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  72                ;; defined in terms of CL:SETF, and CL:SETF can be
  73                ;; defined in terms of CL:DO, and CL:DO can be defined
  74                ;; in terms of the current function.)
  75                (push-on-r-inits (x)
  76                  (setq r-inits (cons x r-inits)))
  77                ;; common error-handling
  78                (illegal-varlist ()
  79                  (error "~S is an illegal form for a ~S varlist." v name)))
  80           (cond ((symbolp v) (push-on-r-inits v))
  81                 ((listp v)
  82                  (unless (symbolp (first v))
  83                    (error "~S step variable is not a symbol: ~S"
  84                           name
  85                           (first v)))
  86                  (let ((lv (length v)))
  87                    ;; (We avoid using CL:CASE here so that CL:CASE can
  88                    ;; be defined in terms of CL:SETF, and CL:SETF can
  89                    ;; be defined in terms of CL:DO, and CL:DO can be
  90                    ;; defined in terms of the current function.)
  91                    (cond ((= lv 1)
  92                           (push-on-r-inits (first v)))
  93                          ((= lv 2)
  94                           (push-on-r-inits v))
  95                          ((= lv 3)
  96                           (push-on-r-inits (list (first v) (second v)))
  97                           (setq r-steps (list* (third v) (first v) r-steps)))
  98                          (t (illegal-varlist)))))
  99                 (t (illegal-varlist)))))
 100       ;; Construct the new form.
 101       (multiple-value-bind (code decls) (parse-body decls-and-code nil)
 102         `(block ,block
 103            (,bind ,(nreverse r-inits)
 104                   ,@decls
 105                   (tagbody
 106                    (go ,label-2)
 107                    ,label-1
 108                    ,@code
 109                    (,step ,@(nreverse r-steps))
 110                    ,label-2
 111                    (unless ,(first endlist) (go ,label-1))
 112                    (return-from ,block (progn ,@(rest endlist))))))))))
 113
 114 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 115 ;;; initialized in parallel to the value of the specified INIT form.
 116 ;;; On subsequent iterations, the VARS are assigned the value of the
 117 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 118 ;;; evaluation of the body FORMS. When the TEST is true, the
 119 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 120 ;;; value of the DO.
 121 (defmacro do-anonymous (varlist endlist &rest body)
 122   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 123 \f
 124 ;;;; GENSYM tricks
 125
 126 ;;; Automate an idiom often found in macros:
 127 ;;;   (LET ((FOO (GENSYM "FOO"))
 128 ;;;         (MAX-INDEX (GENSYM "MAX-INDEX-")))
 129 ;;;     ...)
 130 ;;;
 131 ;;; "Good notation eliminates thought." -- Eric Siggia
 132 ;;;
 133 ;;; Incidentally, this is essentially the same operator which
 134 ;;; _On Lisp_ calls WITH-GENSYMS.
 135 (defmacro with-unique-names (symbols &body body)
 136   `(let ,(mapcar (lambda (symbol)
 137                    (let* ((symbol-name (symbol-name symbol))
 138                           (stem (if (every #'alpha-char-p symbol-name)
 139                                     symbol-name
 140                                     (concatenate 'string symbol-name "-"))))
 141                      `(,symbol (gensym ,stem))))
 142                  symbols)
 143      ,@body))
 144
 145 ;;; Return a list of N gensyms. (This is a common suboperation in
 146 ;;; macros and other code-manipulating code.)
 147 (declaim (ftype (function (index) list) make-gensym-list))
 148 (defun make-gensym-list (n)
 149   (loop repeat n collect (gensym)))
 150 \f
 151 ;;;; miscellany
 152
 153 ;;; Lots of code wants to get to the KEYWORD package or the
 154 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 155 ;;; variables. TO DO: How much does this actually buy us? It sounds
 156 ;;; sensible, but I don't know for sure that it saves space or time..
 157 ;;; -- WHN 19990521
 158 ;;;
 159 ;;; (The initialization forms here only matter on the cross-compilation
 160 ;;; host; In the target SBCL, these variables are set in cold init.)
 161 (declaim (type package *cl-package* *keyword-package*))
 162 (defvar *cl-package*      (find-package "COMMON-LISP"))
 163 (defvar *keyword-package* (find-package "KEYWORD"))
 164
 165 ;;; Concatenate together the names of some strings and symbols,
 166 ;;; producing a symbol in the current package.
 167 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 168   (defun symbolicate (&rest things)
 169     (let ((name (case (length things)
 170                   ;; why isn't this just the value in the T branch?
 171                   ;; Well, this is called early in cold-init, before
 172                   ;; the type system is set up; however, now that we
 173                   ;; check for bad lengths, the type system is needed
 174                   ;; for calls to CONCATENATE. So we need to make sure
 175                   ;; that the calls are transformed away:
 176                   (1 (concatenate 'string (the simple-string (string (car things)))))
 177                   (2 (concatenate 'string
 178                                   (the simple-string (string (car things)))
 179                                   (the simple-string (string (cadr things)))))
 180                   (3 (concatenate 'string
 181                                   (the simple-string (string (car things)))
 182                                   (the simple-string (string (cadr things)))
 183                                   (the simple-string (string (caddr things)))))
 184                   (t (apply #'concatenate 'string (mapcar #'string things))))))
 185     (values (intern name)))))
 186
 187 ;;; like SYMBOLICATE, but producing keywords
 188 (defun keywordicate (&rest things)
 189   (let ((*package* *keyword-package*))
 190     (apply #'symbolicate things)))
 191
 192 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 193 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 194 ;;; assignment is undefined behavior, so it's sort of reasonable for
 195 ;;; it to cause the system to go totally insane afterwards, but it's a
 196 ;;; fairly easy mistake to make, so let's try to recover gracefully
 197 ;;; instead.)
 198 (defun sane-package ()
 199   (let ((maybe-package *package*))
 200     (cond ((and (packagep maybe-package)
 201                 ;; For good measure, we also catch the problem of
 202                 ;; *PACKAGE* being bound to a deleted package.
 203                 ;; Technically, this is not undefined behavior in itself,
 204                 ;; but it will immediately lead to undefined to behavior,
 205                 ;; since almost any operation on a deleted package is
 206                 ;; undefined.
 207                 (package-name maybe-package))
 208            maybe-package)
 209           (t
 210            ;; We're in the undefined behavior zone. First, munge the
 211            ;; system back into a defined state.
 212            (let ((really-package (find-package :cl-user)))
 213              (setf *package* really-package)
 214              ;; Then complain.
 215              (error 'simple-type-error
 216                     :datum maybe-package
 217                     :expected-type '(and package (satisfies package-name))
 218                     :format-control
 219                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 220                     :format-arguments (list '*package*
 221                                             (if (packagep maybe-package)
 222                                                 "deleted package"
 223                                                 (type-of maybe-package))
 224                                             '*package* really-package)))))))
 225
 226 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 227 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 228 ;;; actually need to reset the variable when it's silly, since even
 229 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 230 ;;; in a state where it's hard to recover interactively.)
 231 (defun sane-default-pathname-defaults ()
 232   (let* ((dfd *default-pathname-defaults*)
 233          (dfd-dir (pathname-directory dfd)))
 234     ;; It's generally not good to use a relative pathname for
 235     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 236     ;; are defined by merging into a default pathname (which is,
 237     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 238     (when (and (consp dfd-dir)
 239                (eql (first dfd-dir) :relative))
 240       (warn
 241        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 242        '*default-pathname-defaults*))
 243     dfd))
 244
 245 ;;; Give names to elements of a numeric sequence.
 246 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 247                    &rest identifiers)
 248   (let ((results nil)
 249         (index 0)
 250         (start (eval start))
 251         (step (eval step)))
 252     (dolist (id identifiers)
 253       (when id
 254         (multiple-value-bind (root docs)
 255             (if (consp id)
 256                 (values (car id) (cdr id))
 257                 (values id nil))
 258           (push `(def!constant ,(symbolicate prefix root suffix)
 259                    ,(+ start (* step index))
 260                    ,@docs)
 261                 results)))
 262       (incf index))
 263     `(progn
 264        ,@(nreverse results))))
 265
 266 ;;; generalization of DEFCONSTANT to values which are the same not
 267 ;;; under EQL but under e.g. EQUAL or EQUALP
 268 ;;;
 269 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 270 ;;; which are appropriately compared using the function given by the
 271 ;;; EQX argument instead of EQL.
 272 ;;;
 273 ;;; Note: Be careful when using this macro, since it's easy to
 274 ;;; unintentionally pessimize your code. A good time to use this macro
 275 ;;; is when the values defined will be fed into optimization
 276 ;;; transforms and never actually appear in the generated code; this
 277 ;;; is especially common when defining BYTE expressions. Unintentional
 278 ;;; pessimization can result when the values defined by this macro are
 279 ;;; actually used in generated code: because of the way that the
 280 ;;; dump/load system works, you'll typically get one copy of consed
 281 ;;; structure for each object file which contains code referring to
 282 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 283 ;;; the constant. If you don't want that to happen, you should
 284 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 285 ;;; need to avoid runtime indirection through a symbol, you might be
 286 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 287 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 288   `(def!constant ,symbol
 289      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 290      ,@(when doc (list doc))))
 291 (defun %defconstant-eqx-value (symbol expr eqx)
 292   (declare (type function eqx))
 293   (flet ((bummer (explanation)
 294            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 295                   symbol
 296                   expr
 297                   explanation
 298                   (symbol-value symbol))))
 299     (cond ((not (boundp symbol))
 300            expr)
 301           ((not (constantp symbol))
 302            (bummer "already bound as a non-constant"))
 303           ((not (funcall eqx (symbol-value symbol) expr))
 304            (bummer "already bound as a different constant value"))
 305           (t
 306            (symbol-value symbol)))))
 307 \f
 308 ;;; a helper function for various macros which expect clauses of a
 309 ;;; given length, etc.
 310 ;;;
 311 ;;; Return true if X is a proper list whose length is between MIN and
 312 ;;; MAX (inclusive).
 313 (defun proper-list-of-length-p (x min &optional (max min))
 314   ;; FIXME: This implementation will hang on circular list
 315   ;; structure. Since this is an error-checking utility, i.e. its
 316   ;; job is to deal with screwed-up input, it'd be good style to fix
 317   ;; it so that it can deal with circular list structure.
 318   (cond ((minusp max) nil)
 319         ((null x) (zerop min))
 320         ((consp x)
 321          (and (plusp max)
 322               (proper-list-of-length-p (cdr x)
 323                                        (if (plusp (1- min))
 324                                            (1- min)
 325                                            0)
 326                                        (1- max))))
 327         (t nil)))