src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 (eval-when (:compile-toplevel :load-toplevel :execute)
  39   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  40 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  41
  42 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  43 ;;; getting nonconforming behavior by messing around with
  44 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  45 ;;; now we just don't worry about it. If for some reason it becomes
  46 ;;; worrisome and the magic value needs replacement:
  47 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  48 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  49 ;;;     work when compiled into a file and loaded back into SBCL.
  50 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  51 ;;;   * The replacement value needs to be acceptable to the
  52 ;;;     low-level gencgc.lisp hash table scavenging code.
  53 ;;;   * The change will break binary compatibility, since comparisons
  54 ;;;     against the value used at the time of compilation are wired
  55 ;;;     into FASL files.
  56 ;;; -- WHN 20000622
  57 \f
  58 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  59
  60 (eval-when (:compile-toplevel :load-toplevel :execute)
  61   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  62     (let* ((r-inits nil) ; accumulator for reversed list
  63            (r-steps nil) ; accumulator for reversed list
  64            (label-1 (gensym))
  65            (label-2 (gensym)))
  66       ;; Check for illegal old-style DO.
  67       (when (or (not (listp varlist)) (atom endlist))
  68         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  69       ;; Parse VARLIST to get R-INITS and R-STEPS.
  70       (dolist (v varlist)
  71         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  72                ;; defined in terms of CL:SETF, and CL:SETF can be
  73                ;; defined in terms of CL:DO, and CL:DO can be defined
  74                ;; in terms of the current function.)
  75                (push-on-r-inits (x)
  76                  (setq r-inits (cons x r-inits)))
  77                ;; common error-handling
  78                (illegal-varlist ()
  79                  (error "~S is an illegal form for a ~S varlist." v name)))
  80           (cond ((symbolp v) (push-on-r-inits v))
  81                 ((listp v)
  82                  (unless (symbolp (first v))
  83                    (error "~S step variable is not a symbol: ~S"
  84                           name
  85                           (first v)))
  86                  (let ((lv (length v)))
  87                    ;; (We avoid using CL:CASE here so that CL:CASE can
  88                    ;; be defined in terms of CL:SETF, and CL:SETF can
  89                    ;; be defined in terms of CL:DO, and CL:DO can be
  90                    ;; defined in terms of the current function.)
  91                    (cond ((= lv 1)
  92                           (push-on-r-inits (first v)))
  93                          ((= lv 2)
  94                           (push-on-r-inits v))
  95                          ((= lv 3)
  96                           (push-on-r-inits (list (first v) (second v)))
  97                           (setq r-steps (list* (third v) (first v) r-steps)))
  98                          (t (illegal-varlist)))))
  99                 (t (illegal-varlist)))))
 100       ;; Construct the new form.
 101       (multiple-value-bind (code decls) (parse-body decls-and-code nil)
 102         `(block ,block
 103            (,bind ,(nreverse r-inits)
 104                   ,@decls
 105                   (tagbody
 106                    (go ,label-2)
 107                    ,label-1
 108                    ,@code
 109                    (,step ,@(nreverse r-steps))
 110                    ,label-2
 111                    (unless ,(first endlist) (go ,label-1))
 112                    (return-from ,block (progn ,@(rest endlist))))))))))
 113
 114 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 115 ;;; initialized in parallel to the value of the specified INIT form.
 116 ;;; On subsequent iterations, the VARS are assigned the value of the
 117 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 118 ;;; evaluation of the body FORMS. When the TEST is true, the
 119 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 120 ;;; value of the DO.
 121 (defmacro do-anonymous (varlist endlist &rest body)
 122   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 123 \f
 124 ;;;; miscellany
 125
 126 ;;; Lots of code wants to get to the KEYWORD package or the
 127 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 128 ;;; variables. TO DO: How much does this actually buy us? It sounds
 129 ;;; sensible, but I don't know for sure that it saves space or time..
 130 ;;; -- WHN 19990521
 131 ;;;
 132 ;;; (The initialization forms here only matter on the cross-compilation
 133 ;;; host; In the target SBCL, these variables are set in cold init.)
 134 (declaim (type package *cl-package* *keyword-package*))
 135 (defvar *cl-package*      (find-package "COMMON-LISP"))
 136 (defvar *keyword-package* (find-package "KEYWORD"))
 137
 138 ;;; Concatenate together the names of some strings and symbols,
 139 ;;; producing a symbol in the current package.
 140 (eval-when (:compile-toplevel :load-toplevel :execute)
 141   (defun symbolicate (&rest things)
 142     (let ((name (case (length things)
 143                   ;; why isn't this just the value in the T branch?
 144                   ;; Well, this is called early in cold-init, before
 145                   ;; the type system is set up; however, now that we
 146                   ;; check for bad lengths, the type system is needed
 147                   ;; for calls to CONCATENATE. So we need to make sure
 148                   ;; that the calls are transformed away:
 149                   (1 (concatenate 'string (the simple-string (string (car things)))))
 150                   (2 (concatenate 'string
 151                                   (the simple-string (string (car things)))
 152                                   (the simple-string (string (cadr things)))))
 153                   (3 (concatenate 'string
 154                                   (the simple-string (string (car things)))
 155                                   (the simple-string (string (cadr things)))
 156                                   (the simple-string (string (caddr things)))))
 157                   (t (apply #'concatenate 'string (mapcar #'string things))))))
 158     (values (intern name)))))
 159
 160 ;;; like SYMBOLICATE, but producing keywords
 161 (defun keywordicate (&rest things)
 162   (let ((*package* *keyword-package*))
 163     (apply #'symbolicate things)))
 164
 165 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 166 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 167 ;;; assignment is undefined behavior, so it's sort of reasonable for
 168 ;;; it to cause the system to go totally insane afterwards, but it's a
 169 ;;; fairly easy mistake to make, so let's try to recover gracefully
 170 ;;; instead.)
 171 (defun sane-package ()
 172   (let ((maybe-package *package*))
 173     (cond ((and (packagep maybe-package)
 174                 ;; For good measure, we also catch the problem of
 175                 ;; *PACKAGE* being bound to a deleted package.
 176                 ;; Technically, this is not undefined behavior in itself,
 177                 ;; but it will immediately lead to undefined to behavior,
 178                 ;; since almost any operation on a deleted package is
 179                 ;; undefined.
 180                 (package-name maybe-package))
 181            maybe-package)
 182           (t
 183            ;; We're in the undefined behavior zone. First, munge the
 184            ;; system back into a defined state.
 185            (let ((really-package (find-package :cl-user)))
 186              (setf *package* really-package)
 187              ;; Then complain.
 188              (error 'simple-type-error
 189                     :datum maybe-package
 190                     :expected-type '(and package (satisfies package-name))
 191                     :format-control
 192                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 193                     :format-arguments (list '*package*
 194                                             (if (packagep maybe-package)
 195                                                 "deleted package"
 196                                                 (type-of maybe-package))
 197                                             '*package* really-package)))))))
 198
 199 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 200 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 201 ;;; actually need to reset the variable when it's silly, since even
 202 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 203 ;;; in a state where it's hard to recover interactively.)
 204 (defun sane-default-pathname-defaults ()
 205   (let* ((dfd *default-pathname-defaults*)
 206          (dfd-dir (pathname-directory dfd)))
 207     ;; It's generally not good to use a relative pathname for
 208     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 209     ;; are defined by merging into a default pathname (which is,
 210     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 211     (when (and (consp dfd-dir)
 212                (eql (first dfd-dir) :relative))
 213       (warn
 214        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 215        '*default-pathname-defaults*))
 216     dfd))
 217
 218 ;;; Give names to elements of a numeric sequence.
 219 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 220                    &rest identifiers)
 221   (let ((results nil)
 222         (index 0)
 223         (start (eval start))
 224         (step (eval step)))
 225     (dolist (id identifiers)
 226       (when id
 227         (multiple-value-bind (root docs)
 228             (if (consp id)
 229                 (values (car id) (cdr id))
 230                 (values id nil))
 231           (push `(def!constant ,(symbolicate prefix root suffix)
 232                    ,(+ start (* step index))
 233                    ,@docs)
 234                 results)))
 235       (incf index))
 236     `(progn
 237        ,@(nreverse results))))
 238
 239 ;;; generalization of DEFCONSTANT to values which are the same not
 240 ;;; under EQL but under e.g. EQUAL or EQUALP
 241 ;;;
 242 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 243 ;;; which are appropriately compared using the function given by the
 244 ;;; EQX argument instead of EQL.
 245 ;;;
 246 ;;; Note: Be careful when using this macro, since it's easy to
 247 ;;; unintentionally pessimize your code. A good time to use this macro
 248 ;;; is when the values defined will be fed into optimization
 249 ;;; transforms and never actually appear in the generated code; this
 250 ;;; is especially common when defining BYTE expressions. Unintentional
 251 ;;; pessimization can result when the values defined by this macro are
 252 ;;; actually used in generated code: because of the way that the
 253 ;;; dump/load system works, you'll typically get one copy of consed
 254 ;;; structure for each object file which contains code referring to
 255 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 256 ;;; the constant. If you don't want that to happen, you should
 257 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 258 ;;; need to avoid runtime indirection through a symbol, you might be
 259 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 260 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 261   `(def!constant ,symbol
 262      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 263      ,@(when doc (list doc))))
 264 (defun %defconstant-eqx-value (symbol expr eqx)
 265   (declare (type function eqx))
 266   (flet ((bummer (explanation)
 267            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 268                   symbol
 269                   expr
 270                   explanation
 271                   (symbol-value symbol))))
 272     (cond ((not (boundp symbol))
 273            expr)
 274           ((not (constantp symbol))
 275            (bummer "already bound as a non-constant"))
 276           ((not (funcall eqx (symbol-value symbol) expr))
 277            (bummer "already bound as a different constant value"))
 278           (t
 279            (symbol-value symbol)))))
 280 \f
 281 ;;; a helper function for various macros which expect clauses of a
 282 ;;; given length, etc.
 283 ;;;
 284 ;;; Return true if X is a proper list whose length is between MIN and
 285 ;;; MAX (inclusive).
 286 (defun proper-list-of-length-p (x min &optional (max min))
 287   ;; FIXME: This implementation will hang on circular list
 288   ;; structure. Since this is an error-checking utility, i.e. its
 289   ;; job is to deal with screwed-up input, it'd be good style to fix
 290   ;; it so that it can deal with circular list structure.
 291   (cond ((minusp max) nil)
 292         ((null x) (zerop min))
 293         ((consp x)
 294          (and (plusp max)
 295               (proper-list-of-length-p (cdr x)
 296                                        (if (plusp (1- min))
 297                                            (1- min)
 298                                            0)
 299                                        (1- max))))
 300         (t nil)))