src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 (eval-when (:compile-toplevel :load-toplevel :execute)
  39   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  40 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  41
  42 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  43 ;;; getting nonconforming behavior by messing around with
  44 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  45 ;;; now we just don't worry about it. If for some reason it becomes
  46 ;;; worrisome and the magic value needs replacement:
  47 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  48 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  49 ;;;     work when compiled into a file and loaded back into SBCL.
  50 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  51 ;;;   * The replacement value needs to be acceptable to the
  52 ;;;     low-level gencgc.lisp hash table scavenging code.
  53 ;;;   * The change will break binary compatibility, since comparisons
  54 ;;;     against the value used at the time of compilation are wired
  55 ;;;     into FASL files.
  56 ;;; -- WHN 20000622
  57 \f
  58 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  59
  60 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  61   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  62     (let* ((r-inits nil) ; accumulator for reversed list
  63            (r-steps nil) ; accumulator for reversed list
  64            (label-1 (gensym))
  65            (label-2 (gensym)))
  66       ;; Check for illegal old-style DO.
  67       (when (or (not (listp varlist)) (atom endlist))
  68         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  69       ;; Parse VARLIST to get R-INITS and R-STEPS.
  70       (dolist (v varlist)
  71         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  72                ;; defined in terms of CL:SETF, and CL:SETF can be
  73                ;; defined in terms of CL:DO, and CL:DO can be defined
  74                ;; in terms of the current function.)
  75                (push-on-r-inits (x)
  76                  (setq r-inits (cons x r-inits)))
  77                ;; common error-handling
  78                (illegal-varlist ()
  79                  (error "~S is an illegal form for a ~S varlist." v name)))
  80           (cond ((symbolp v) (push-on-r-inits v))
  81                 ((listp v)
  82                  (unless (symbolp (first v))
  83                    (error "~S step variable is not a symbol: ~S"
  84                           name
  85                           (first v)))
  86                  (let ((lv (length v)))
  87                    ;; (We avoid using CL:CASE here so that CL:CASE can
  88                    ;; be defined in terms of CL:SETF, and CL:SETF can
  89                    ;; be defined in terms of CL:DO, and CL:DO can be
  90                    ;; defined in terms of the current function.)
  91                    (cond ((= lv 1)
  92                           (push-on-r-inits (first v)))
  93                          ((= lv 2)
  94                           (push-on-r-inits v))
  95                          ((= lv 3)
  96                           (push-on-r-inits (list (first v) (second v)))
  97                           (setq r-steps (list* (third v) (first v) r-steps)))
  98                          (t (illegal-varlist)))))
  99                 (t (illegal-varlist)))))
 100       ;; Construct the new form.
 101       (multiple-value-bind (code decls)
 102           (parse-body decls-and-code :doc-string-allowed nil)
 103         `(block ,block
 104            (,bind ,(nreverse r-inits)
 105                   ,@decls
 106                   (tagbody
 107                    (go ,label-2)
 108                    ,label-1
 109                    ,@code
 110                    (,step ,@(nreverse r-steps))
 111                    ,label-2
 112                    (unless ,(first endlist) (go ,label-1))
 113                    (return-from ,block (progn ,@(rest endlist))))))))))
 114
 115 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 116 ;;; initialized in parallel to the value of the specified INIT form.
 117 ;;; On subsequent iterations, the VARS are assigned the value of the
 118 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 119 ;;; evaluation of the body FORMS. When the TEST is true, the
 120 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 121 ;;; value of the DO.
 122 (defmacro do-anonymous (varlist endlist &rest body)
 123   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 124 \f
 125 ;;;; GENSYM tricks
 126
 127 ;;; Automate an idiom often found in macros:
 128 ;;;   (LET ((FOO (GENSYM "FOO"))
 129 ;;;         (MAX-INDEX (GENSYM "MAX-INDEX-")))
 130 ;;;     ...)
 131 ;;;
 132 ;;; "Good notation eliminates thought." -- Eric Siggia
 133 ;;;
 134 ;;; Incidentally, this is essentially the same operator which
 135 ;;; _On Lisp_ calls WITH-GENSYMS.
 136 (defmacro with-unique-names (symbols &body body)
 137   `(let ,(mapcar (lambda (symbol)
 138                    (let* ((symbol-name (symbol-name symbol))
 139                           (stem (if (every #'alpha-char-p symbol-name)
 140                                     symbol-name
 141                                     (concatenate 'string symbol-name "-"))))
 142                      `(,symbol (gensym ,stem))))
 143                  symbols)
 144      ,@body))
 145
 146 ;;; Return a list of N gensyms. (This is a common suboperation in
 147 ;;; macros and other code-manipulating code.)
 148 (declaim (ftype (function (index) list) make-gensym-list))
 149 (defun make-gensym-list (n)
 150   (loop repeat n collect (gensym)))
 151 \f
 152 ;;;; miscellany
 153
 154 ;;; Lots of code wants to get to the KEYWORD package or the
 155 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 156 ;;; variables. TO DO: How much does this actually buy us? It sounds
 157 ;;; sensible, but I don't know for sure that it saves space or time..
 158 ;;; -- WHN 19990521
 159 ;;;
 160 ;;; (The initialization forms here only matter on the cross-compilation
 161 ;;; host; In the target SBCL, these variables are set in cold init.)
 162 (declaim (type package *cl-package* *keyword-package*))
 163 (defvar *cl-package*      (find-package "COMMON-LISP"))
 164 (defvar *keyword-package* (find-package "KEYWORD"))
 165
 166 ;;; Concatenate together the names of some strings and symbols,
 167 ;;; producing a symbol in the current package.
 168 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 169   (defun symbolicate (&rest things)
 170     (let ((name (case (length things)
 171                   ;; why isn't this just the value in the T branch?
 172                   ;; Well, this is called early in cold-init, before
 173                   ;; the type system is set up; however, now that we
 174                   ;; check for bad lengths, the type system is needed
 175                   ;; for calls to CONCATENATE. So we need to make sure
 176                   ;; that the calls are transformed away:
 177                   (1 (concatenate 'string
 178                                   (the simple-base-string (string (car things)))))
 179                   (2 (concatenate 'string
 180                                   (the simple-base-string (string (car things)))
 181                                   (the simple-base-string (string (cadr things)))))
 182                   (3 (concatenate 'string
 183                                   (the simple-base-string (string (car things)))
 184                                   (the simple-base-string (string (cadr things)))
 185                                   (the simple-base-string (string (caddr things)))))
 186                   (t (apply #'concatenate 'string (mapcar #'string things))))))
 187     (values (intern name)))))
 188
 189 ;;; like SYMBOLICATE, but producing keywords
 190 (defun keywordicate (&rest things)
 191   (let ((*package* *keyword-package*))
 192     (apply #'symbolicate things)))
 193
 194 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 195 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 196 ;;; assignment is undefined behavior, so it's sort of reasonable for
 197 ;;; it to cause the system to go totally insane afterwards, but it's a
 198 ;;; fairly easy mistake to make, so let's try to recover gracefully
 199 ;;; instead.)
 200 (defun sane-package ()
 201   (let ((maybe-package *package*))
 202     (cond ((and (packagep maybe-package)
 203                 ;; For good measure, we also catch the problem of
 204                 ;; *PACKAGE* being bound to a deleted package.
 205                 ;; Technically, this is not undefined behavior in itself,
 206                 ;; but it will immediately lead to undefined to behavior,
 207                 ;; since almost any operation on a deleted package is
 208                 ;; undefined.
 209                 (package-name maybe-package))
 210            maybe-package)
 211           (t
 212            ;; We're in the undefined behavior zone. First, munge the
 213            ;; system back into a defined state.
 214            (let ((really-package (find-package :cl-user)))
 215              (setf *package* really-package)
 216              ;; Then complain.
 217              (error 'simple-type-error
 218                     :datum maybe-package
 219                     :expected-type '(and package (satisfies package-name))
 220                     :format-control
 221                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 222                     :format-arguments (list '*package*
 223                                             (if (packagep maybe-package)
 224                                                 "deleted package"
 225                                                 (type-of maybe-package))
 226                                             '*package* really-package)))))))
 227
 228 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 229 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 230 ;;; actually need to reset the variable when it's silly, since even
 231 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 232 ;;; in a state where it's hard to recover interactively.)
 233 (defun sane-default-pathname-defaults ()
 234   (let* ((dfd *default-pathname-defaults*)
 235          (dfd-dir (pathname-directory dfd)))
 236     ;; It's generally not good to use a relative pathname for
 237     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 238     ;; are defined by merging into a default pathname (which is,
 239     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 240     (when (and (consp dfd-dir)
 241                (eql (first dfd-dir) :relative))
 242       (warn
 243        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 244        '*default-pathname-defaults*))
 245     dfd))
 246
 247 ;;; Give names to elements of a numeric sequence.
 248 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 249                    &rest identifiers)
 250   (let ((results nil)
 251         (index 0)
 252         (start (eval start))
 253         (step (eval step)))
 254     (dolist (id identifiers)
 255       (when id
 256         (multiple-value-bind (root docs)
 257             (if (consp id)
 258                 (values (car id) (cdr id))
 259                 (values id nil))
 260           (push `(def!constant ,(symbolicate prefix root suffix)
 261                    ,(+ start (* step index))
 262                    ,@docs)
 263                 results)))
 264       (incf index))
 265     `(progn
 266        ,@(nreverse results))))
 267
 268 ;;; generalization of DEFCONSTANT to values which are the same not
 269 ;;; under EQL but under e.g. EQUAL or EQUALP
 270 ;;;
 271 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 272 ;;; which are appropriately compared using the function given by the
 273 ;;; EQX argument instead of EQL.
 274 ;;;
 275 ;;; Note: Be careful when using this macro, since it's easy to
 276 ;;; unintentionally pessimize your code. A good time to use this macro
 277 ;;; is when the values defined will be fed into optimization
 278 ;;; transforms and never actually appear in the generated code; this
 279 ;;; is especially common when defining BYTE expressions. Unintentional
 280 ;;; pessimization can result when the values defined by this macro are
 281 ;;; actually used in generated code: because of the way that the
 282 ;;; dump/load system works, you'll typically get one copy of consed
 283 ;;; structure for each object file which contains code referring to
 284 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 285 ;;; the constant. If you don't want that to happen, you should
 286 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 287 ;;; need to avoid runtime indirection through a symbol, you might be
 288 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 289 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 290   `(def!constant ,symbol
 291      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 292      ,@(when doc (list doc))))
 293 (defun %defconstant-eqx-value (symbol expr eqx)
 294   (declare (type function eqx))
 295   (flet ((bummer (explanation)
 296            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 297                   symbol
 298                   expr
 299                   explanation
 300                   (symbol-value symbol))))
 301     (cond ((not (boundp symbol))
 302            expr)
 303           ((not (constantp symbol))
 304            (bummer "already bound as a non-constant"))
 305           ((not (funcall eqx (symbol-value symbol) expr))
 306            (bummer "already bound as a different constant value"))
 307           (t
 308            (symbol-value symbol)))))
 309 \f
 310 ;;; a helper function for various macros which expect clauses of a
 311 ;;; given length, etc.
 312 ;;;
 313 ;;; Return true if X is a proper list whose length is between MIN and
 314 ;;; MAX (inclusive).
 315 (defun proper-list-of-length-p (x min &optional (max min))
 316   ;; FIXME: This implementation will hang on circular list
 317   ;; structure. Since this is an error-checking utility, i.e. its
 318   ;; job is to deal with screwed-up input, it'd be good style to fix
 319   ;; it so that it can deal with circular list structure.
 320   (cond ((minusp max) nil)
 321         ((null x) (zerop min))
 322         ((consp x)
 323          (and (plusp max)
 324               (proper-list-of-length-p (cdr x)
 325                                        (if (plusp (1- min))
 326                                            (1- min)
 327                                            0)
 328                                        (1- max))))
 329         (t nil)))