src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!INT")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 ;;;
  39 ;;; FIXME: We end up doing two DEFCONSTANT forms because (1) LispWorks
  40 ;;; needs EVAL-WHEN wrapped around DEFCONSTANT, and (2) SBCL's
  41 ;;; DEFCONSTANT expansion doesn't seem to behave properly inside
  42 ;;; EVAL-WHEN, so that without this, the +EMPTY-HT-SLOT+ references in
  43 ;;; e.g. DOHASH macroexpansions don't end up being replaced by
  44 ;;; constant values, so that the system dies at cold init because
  45 ;;; '+EMPTY-HT-SLOT+ isn't bound yet. It's hard to fix this properly
  46 ;;; until SBCL's EVAL-WHEN is fixed, which is waiting for the IR1
  47 ;;; interpreter to go away, which is waiting for sbcl-0.7.x..
  48 (eval-when (:compile-toplevel :load-toplevel :execute)
  49   (defconstant +empty-ht-slot+ '%empty-ht-slot%))
  50 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  51 #+nil (defconstant +empty-ht-slot+ '#.+empty-ht-slot+) ; egads.. See FIXME above.
  52 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  53 ;;; getting nonconforming behavior by messing around with
  54 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  55 ;;; now we just don't worry about it. If for some reason it becomes
  56 ;;; worrisome and the magic value needs replacement:
  57 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  58 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  59 ;;;     work when compiled into a file and loaded back into SBCL.
  60 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  61 ;;;   * The replacement value needs to be acceptable to the
  62 ;;;     low-level gencgc.lisp hash table scavenging code.
  63 ;;;   * The change will break binary compatibility, since comparisons
  64 ;;;     against the value used at the time of compilation are wired
  65 ;;;     into FASL files.
  66 ;;; -- WHN 20000622
  67 \f
  68 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  69
  70 (eval-when (:compile-toplevel :load-toplevel :execute)
  71   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  72     (let* ((r-inits nil) ; accumulator for reversed list
  73            (r-steps nil) ; accumulator for reversed list
  74            (label-1 (gensym))
  75            (label-2 (gensym)))
  76       ;; Check for illegal old-style DO.
  77       (when (or (not (listp varlist)) (atom endlist))
  78         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  79       ;; Parse VARLIST to get R-INITS and R-STEPS.
  80       (dolist (v varlist)
  81         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  82                ;; defined in terms of CL:SETF, and CL:SETF can be
  83                ;; defined in terms of CL:DO, and CL:DO can be defined
  84                ;; in terms of the current function.)
  85                (push-on-r-inits (x)
  86                  (setq r-inits (cons x r-inits)))
  87                ;; common error-handling
  88                (illegal-varlist ()
  89                  (error "~S is an illegal form for a ~S varlist." v name)))
  90           (cond ((symbolp v) (push-on-r-inits v))
  91                 ((listp v)
  92                  (unless (symbolp (first v))
  93                    (error "~S step variable is not a symbol: ~S"
  94                           name
  95                           (first v)))
  96                  (let ((lv (length v)))
  97                    ;; (We avoid using CL:CASE here so that CL:CASE can
  98                    ;; be defined in terms of CL:SETF, and CL:SETF can
  99                    ;; be defined in terms of CL:DO, and CL:DO can be
 100                    ;; defined in terms of the current function.)
 101                    (cond ((= lv 1)
 102                           (push-on-r-inits (first v)))
 103                          ((= lv 2)
 104                           (push-on-r-inits v))
 105                          ((= lv 3)
 106                           (push-on-r-inits (list (first v) (second v)))
 107                           (setq r-steps (list* (third v) (first v) r-steps)))
 108                          (t (illegal-varlist)))))
 109                 (t (illegal-varlist)))))
 110       ;; Construct the new form.
 111       (multiple-value-bind (code decls) (parse-body decls-and-code nil)
 112         `(block ,block
 113            (,bind ,(nreverse r-inits)
 114                   ,@decls
 115                   (tagbody
 116                    (go ,label-2)
 117                    ,label-1
 118                    ,@code
 119                    (,step ,@(nreverse r-steps))
 120                    ,label-2
 121                    (unless ,(first endlist) (go ,label-1))
 122                    (return-from ,block (progn ,@(rest endlist))))))))))
 123
 124 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 125 ;;; initialized in parallel to the value of the specified INIT form.
 126 ;;; On subsequent iterations, the VARS are assigned the value of the
 127 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 128 ;;; evaluation of the body FORMS. When the TEST is true, the
 129 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 130 ;;; value of the DO.
 131 (defmacro do-anonymous (varlist endlist &rest body)
 132   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 133 \f
 134 ;;;; miscellany
 135
 136 ;;; Concatenate together the names of some strings and symbols,
 137 ;;; producing a symbol in the current package.
 138 (eval-when (:compile-toplevel :load-toplevel :execute)
 139   (defun symbolicate (&rest things)
 140     (values (intern (apply #'concatenate
 141                            'string
 142                            (mapcar #'string things))))))
 143
 144 ;;; like SYMBOLICATE, but producing keywords
 145 (defun keywordicate (&rest things)
 146   (let ((*package* *keyword-package*))
 147     (apply #'symbolicate things)))
 148
 149 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 150 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 151 ;;; assignment is undefined behavior, so it's sort of reasonable for
 152 ;;; it to cause the system to go totally insane afterwards, but it's a
 153 ;;; fairly easy mistake to make, so let's try to recover gracefully
 154 ;;; instead.)
 155 (defun sane-package ()
 156   (let ((maybe-package *package*))
 157     (cond ((and (packagep maybe-package)
 158                 ;; For good measure, we also catch the problem of
 159                 ;; *PACKAGE* being bound to a deleted package.
 160                 ;; Technically, this is not undefined behavior in itself,
 161                 ;; but it will immediately lead to undefined to behavior,
 162                 ;; since almost any operation on a deleted package is
 163                 ;; undefined.
 164                 (package-name maybe-package))
 165            maybe-package)
 166           (t
 167            ;; We're in the undefined behavior zone. First, munge the
 168            ;; system back into a defined state.
 169            (let ((really-package (find-package :cl-user)))
 170              (setf *package* really-package)
 171              ;; Then complain.
 172              (error 'simple-type-error
 173                     :datum maybe-package
 174                     :expected-type '(and package (satisfies package-name))
 175                     :format-control
 176                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 177                     :format-arguments (list '*package*
 178                                             (if (packagep maybe-package)
 179                                                 "deleted package"
 180                                                 (type-of maybe-package))
 181                                             '*package* really-package)))))))
 182
 183 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 184 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 185 ;;; actually need to reset the variable when it's silly, since even
 186 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 187 ;;; in a state where it's hard to recover interactively.)
 188 (defun sane-default-pathname-defaults ()
 189   (let* ((dfd *default-pathname-defaults*)
 190          (dfd-dir (pathname-directory dfd)))
 191     ;; It's generally not good to use a relative pathname for
 192     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 193     ;; are defined by merging into a default pathname (which is,
 194     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 195     (when (and (consp dfd-dir)
 196                (eql (first dfd-dir) :relative))
 197       (warn
 198        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 199        '*default-pathname-defaults*))
 200     dfd))
 201
 202 ;;; Give names to elements of a numeric sequence.
 203 (defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
 204                    &rest identifiers)
 205   (let ((results nil)
 206         (index 0)
 207         (start (eval start))
 208         (step (eval step)))
 209     (dolist (id identifiers)
 210       (when id
 211         (multiple-value-bind (root docs)
 212             (if (consp id)
 213                 (values (car id) (cdr id))
 214                 (values id nil))
 215           (push `(defconstant ,(symbolicate prefix root suffix)
 216                    ,(+ start (* step index))
 217                    ,@docs)
 218                 results)))
 219       (incf index))
 220     `(progn
 221        ,@(nreverse results))))
 222
 223 ;;; generalization of DEFCONSTANT to values which are the same not
 224 ;;; under EQL but under e.g. EQUAL or EQUALP
 225 ;;;
 226 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 227 ;;; which are appropriately compared using the function given by the
 228 ;;; EQX argument instead of EQL.
 229 ;;;
 230 ;;; Note: Be careful when using this macro, since it's easy to
 231 ;;; unintentionally pessimize your code. A good time to use this macro
 232 ;;; is when the values defined will be fed into optimization
 233 ;;; transforms and never actually appear in the generated code; this
 234 ;;; is especially common when defining BYTE expressions. Unintentional
 235 ;;; pessimization can result when the values defined by this macro are
 236 ;;; actually used in generated code: because of the way that the
 237 ;;; dump/load system works, you'll typically get one copy of consed
 238 ;;; structure for each object file which contains code referring to
 239 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 240 ;;; the constant. If you don't want that to happen, you should
 241 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 242 ;;; need to avoid runtime indirection through a symbol, you might be
 243 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 244 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 245   `(defconstant ,symbol
 246      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 247      ,@(when doc (list doc))))
 248 (defun %defconstant-eqx-value (symbol expr eqx)
 249   (flet ((bummer (explanation)
 250            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 251                   symbol
 252                   expr
 253                   explanation
 254                   (symbol-value symbol))))
 255     (cond ((not (boundp symbol))
 256            expr)
 257           ((not (constantp symbol))
 258            (bummer "already bound as a non-constant"))
 259           ((not (funcall eqx (symbol-value symbol) expr))
 260            (bummer "already bound as a different constant value"))
 261           (t
 262            (symbol-value symbol)))))