src/code/primordial-extensions.lisp

   1 ;;;; various user-level definitions which need to be done particularly
   2 ;;;; early
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; target constants which need to appear as early as possible
  16
  17 ;;; an internal tag for marking empty slots, which needs to be defined
  18 ;;; as early as possible because it appears in macroexpansions for
  19 ;;; iteration over hash tables
  20 ;;;
  21 ;;; CMU CL 18b used :EMPTY for this purpose, which was somewhat nasty
  22 ;;; since it's easily accessible to the user, so that e.g.
  23 ;;;     (DEFVAR *HT* (MAKE-HASH-TABLE))
  24 ;;;     (SETF (GETHASH :EMPTY *HT*) :EMPTY)
  25 ;;;     (MAPHASH (LAMBDA (K V) (FORMAT T "~&~S ~S~%" K V)))
  26 ;;; gives no output -- oops!
  27 ;;;
  28 ;;; FIXME: It'd probably be good to use the unbound marker for this.
  29 ;;; However, there might be some gotchas involving assumptions by
  30 ;;; e.g. AREF that they're not going to return the unbound marker,
  31 ;;; and there's also the noted-below problem that the C-level code
  32 ;;; contains implicit assumptions about this marker.
  33 ;;;
  34 ;;; KLUDGE: Note that as of version 0.pre7 there's a dependence in the
  35 ;;; gencgc.c code on this value being a symbol. (This is only one of
  36 ;;; several nasty dependencies between that code and this, alas.)
  37 ;;; -- WHN 2001-08-17
  38 (eval-when (:compile-toplevel :load-toplevel :execute)
  39   (def!constant +empty-ht-slot+ '%empty-ht-slot%))
  40 ;;; We shouldn't need this mess now that EVAL-WHEN works.
  41
  42 ;;; KLUDGE: Using a private symbol still leaves us vulnerable to users
  43 ;;; getting nonconforming behavior by messing around with
  44 ;;; DO-ALL-SYMBOLS. That seems like a fairly obscure problem, so for
  45 ;;; now we just don't worry about it. If for some reason it becomes
  46 ;;; worrisome and the magic value needs replacement:
  47 ;;;   * The replacement value needs to be LOADable with EQL preserved,
  48 ;;;     so that the macroexpansion for WITH-HASH-TABLE-ITERATOR will
  49 ;;;     work when compiled into a file and loaded back into SBCL.
  50 ;;;     (Thus, just uninterning %EMPTY-HT-SLOT% doesn't work.)
  51 ;;;   * The replacement value needs to be acceptable to the
  52 ;;;     low-level gencgc.lisp hash table scavenging code.
  53 ;;;   * The change will break binary compatibility, since comparisons
  54 ;;;     against the value used at the time of compilation are wired
  55 ;;;     into FASL files.
  56 ;;; -- WHN 20000622
  57 \f
  58 ;;;; DO-related stuff which needs to be visible on the cross-compilation host
  59
  60 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  61   (defun frob-do-body (varlist endlist decls-and-code bind step name block)
  62     (let* ((r-inits nil) ; accumulator for reversed list
  63            (r-steps nil) ; accumulator for reversed list
  64            (label-1 (gensym))
  65            (label-2 (gensym)))
  66       ;; Check for illegal old-style DO.
  67       (when (or (not (listp varlist)) (atom endlist))
  68         (error "ill-formed ~S -- possibly illegal old style DO?" name))
  69       ;; Parse VARLIST to get R-INITS and R-STEPS.
  70       (dolist (v varlist)
  71         (flet (;; (We avoid using CL:PUSH here so that CL:PUSH can be
  72                ;; defined in terms of CL:SETF, and CL:SETF can be
  73                ;; defined in terms of CL:DO, and CL:DO can be defined
  74                ;; in terms of the current function.)
  75                (push-on-r-inits (x)
  76                  (setq r-inits (cons x r-inits)))
  77                ;; common error-handling
  78                (illegal-varlist ()
  79                  (error "~S is an illegal form for a ~S varlist." v name)))
  80           (cond ((symbolp v) (push-on-r-inits v))
  81                 ((listp v)
  82                  (unless (symbolp (first v))
  83                    (error "~S step variable is not a symbol: ~S"
  84                           name
  85                           (first v)))
  86                  (let ((lv (length v)))
  87                    ;; (We avoid using CL:CASE here so that CL:CASE can
  88                    ;; be defined in terms of CL:SETF, and CL:SETF can
  89                    ;; be defined in terms of CL:DO, and CL:DO can be
  90                    ;; defined in terms of the current function.)
  91                    (cond ((= lv 1)
  92                           (push-on-r-inits (first v)))
  93                          ((= lv 2)
  94                           (push-on-r-inits v))
  95                          ((= lv 3)
  96                           (push-on-r-inits (list (first v) (second v)))
  97                           (setq r-steps (list* (third v) (first v) r-steps)))
  98                          (t (illegal-varlist)))))
  99                 (t (illegal-varlist)))))
 100       ;; Construct the new form.
 101       (multiple-value-bind (code decls)
 102           (parse-body decls-and-code :doc-string-allowed nil)
 103         `(block ,block
 104            (,bind ,(nreverse r-inits)
 105                   ,@decls
 106                   (tagbody
 107                      (go ,label-2)
 108                      ,label-1
 109                      (tagbody ,@code)
 110                      (,step ,@(nreverse r-steps))
 111                      ,label-2
 112                      (unless ,(first endlist) (go ,label-1))
 113                      (return-from ,block (progn ,@(rest endlist))))))))))
 114
 115 ;;; This is like DO, except it has no implicit NIL block. Each VAR is
 116 ;;; initialized in parallel to the value of the specified INIT form.
 117 ;;; On subsequent iterations, the VARS are assigned the value of the
 118 ;;; STEP form (if any) in parallel. The TEST is evaluated before each
 119 ;;; evaluation of the body FORMS. When the TEST is true, the
 120 ;;; EXIT-FORMS are evaluated as a PROGN, with the result being the
 121 ;;; value of the DO.
 122 (defmacro do-anonymous (varlist endlist &rest body)
 123   (frob-do-body varlist endlist body 'let 'psetq 'do-anonymous (gensym)))
 124 \f
 125 ;;;; GENSYM tricks
 126
 127 ;;; Compile a version of BODY for all TYPES, and dispatch to the
 128 ;;; correct one based on the value of VAR. This was originally used
 129 ;;; only for strings, hence the name. Renaming it to something more
 130 ;;; generic might not be a bad idea.
 131 (defmacro string-dispatch ((&rest types) var &body body)
 132   (let ((fun (sb!xc:gensym "STRING-DISPATCH-FUN")))
 133     `(flet ((,fun (,var)
 134               ,@body))
 135        (declare (inline ,fun))
 136        (etypecase ,var
 137          ,@(loop for type in types
 138                  ;; TRULY-THE allows transforms to take advantage of the type
 139                  ;; information without need for constraint propagation.
 140                  collect `(,type (,fun (truly-the ,type ,var))))))))
 141
 142 ;;; Automate an idiom often found in macros:
 143 ;;;   (LET ((FOO (GENSYM "FOO"))
 144 ;;;         (MAX-INDEX (GENSYM "MAX-INDEX-")))
 145 ;;;     ...)
 146 ;;;
 147 ;;; "Good notation eliminates thought." -- Eric Siggia
 148 ;;;
 149 ;;; Incidentally, this is essentially the same operator which
 150 ;;; _On Lisp_ calls WITH-GENSYMS.
 151 (defmacro with-unique-names (symbols &body body)
 152   `(let ,(mapcar (lambda (symbol)
 153                    (let* ((symbol-name (symbol-name symbol))
 154                           (stem (if (every #'alpha-char-p symbol-name)
 155                                     symbol-name
 156                                     (concatenate 'string symbol-name "-"))))
 157                      `(,symbol (sb!xc:gensym ,stem))))
 158                  symbols)
 159      ,@body))
 160
 161 ;;; Return a list of N gensyms. (This is a common suboperation in
 162 ;;; macros and other code-manipulating code.)
 163 (declaim (ftype (function (index &optional t) (values list &optional))
 164                 make-gensym-list))
 165 (defun make-gensym-list (n &optional name)
 166   (when (eq t name)
 167     (break))
 168   (if name
 169       (loop repeat n collect (sb!xc:gensym (string name)))
 170       (loop repeat n collect (sb!xc:gensym))))
 171 \f
 172 ;;;; miscellany
 173
 174 ;;; Lots of code wants to get to the KEYWORD package or the
 175 ;;; COMMON-LISP package without a lot of fuss, so we cache them in
 176 ;;; variables. TO DO: How much does this actually buy us? It sounds
 177 ;;; sensible, but I don't know for sure that it saves space or time..
 178 ;;; -- WHN 19990521
 179 ;;;
 180 ;;; (The initialization forms here only matter on the cross-compilation
 181 ;;; host; In the target SBCL, these variables are set in cold init.)
 182 (declaim (type package *cl-package* *keyword-package*))
 183 (defvar *cl-package*      (find-package "COMMON-LISP"))
 184 (defvar *keyword-package* (find-package "KEYWORD"))
 185
 186 ;;; Concatenate together the names of some strings and symbols,
 187 ;;; producing a symbol in the current package.
 188 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 189   (defun symbolicate (&rest things)
 190     (let* ((length (reduce #'+ things
 191                            :key (lambda (x) (length (string x)))))
 192            (name (make-array length :element-type 'character)))
 193       (let ((index 0))
 194         (dolist (thing things (values (intern name)))
 195           (let* ((x (string thing))
 196                  (len (length x)))
 197             (replace name x :start1 index)
 198             (incf index len)))))))
 199
 200 (defun gensymify (x)
 201   (if (symbolp x)
 202       (sb!xc:gensym (symbol-name x))
 203       (sb!xc:gensym)))
 204
 205 ;;; like SYMBOLICATE, but producing keywords
 206 (defun keywordicate (&rest things)
 207   (let ((*package* *keyword-package*))
 208     (apply #'symbolicate things)))
 209
 210 ;;; Access *PACKAGE* in a way which lets us recover when someone has
 211 ;;; done something silly like (SETF *PACKAGE* :CL-USER). (Such an
 212 ;;; assignment is undefined behavior, so it's sort of reasonable for
 213 ;;; it to cause the system to go totally insane afterwards, but it's a
 214 ;;; fairly easy mistake to make, so let's try to recover gracefully
 215 ;;; instead.)
 216 (defun sane-package ()
 217   (let ((maybe-package *package*))
 218     (cond ((and (packagep maybe-package)
 219                 ;; For good measure, we also catch the problem of
 220                 ;; *PACKAGE* being bound to a deleted package.
 221                 ;; Technically, this is not undefined behavior in itself,
 222                 ;; but it will immediately lead to undefined to behavior,
 223                 ;; since almost any operation on a deleted package is
 224                 ;; undefined.
 225                 #-sb-xc-host
 226                 (package-%name maybe-package))
 227            maybe-package)
 228           (t
 229            ;; We're in the undefined behavior zone. First, munge the
 230            ;; system back into a defined state.
 231            (let ((really-package (find-package :cl-user)))
 232              (setf *package* really-package)
 233              ;; Then complain.
 234              (error 'simple-type-error
 235                     :datum maybe-package
 236                     :expected-type '(and package (satisfies package-name))
 237                     :format-control
 238                     "~@<~S can't be a ~A: ~2I~_~S has been reset to ~S.~:>"
 239                     :format-arguments (list '*package*
 240                                             (if (packagep maybe-package)
 241                                                 "deleted package"
 242                                                 (type-of maybe-package))
 243                                             '*package* really-package)))))))
 244
 245 ;;; Access *DEFAULT-PATHNAME-DEFAULTS*, issuing a warning if its value
 246 ;;; is silly. (Unlike the vaguely-analogous SANE-PACKAGE, we don't
 247 ;;; actually need to reset the variable when it's silly, since even
 248 ;;; crazy values of *DEFAULT-PATHNAME-DEFAULTS* don't leave the system
 249 ;;; in a state where it's hard to recover interactively.)
 250 (defun sane-default-pathname-defaults ()
 251   (let* ((dfd *default-pathname-defaults*)
 252          (dfd-dir (pathname-directory dfd)))
 253     ;; It's generally not good to use a relative pathname for
 254     ;; *DEFAULT-PATHNAME-DEFAULTS*, since relative pathnames
 255     ;; are defined by merging into a default pathname (which is,
 256     ;; by default, *DEFAULT-PATHNAME-DEFAULTS*).
 257     (when (and (consp dfd-dir)
 258                (eql (first dfd-dir) :relative))
 259       (warn
 260        "~@<~S is a relative pathname. (But we'll try using it anyway.)~@:>"
 261        '*default-pathname-defaults*))
 262     dfd))
 263
 264 ;;; Give names to elements of a numeric sequence.
 265 (defmacro defenum ((&key (start 0) (step 1))
 266                    &rest identifiers)
 267   (let ((results nil)
 268         (index 0)
 269         (start (eval start))
 270         (step (eval step)))
 271     (dolist (id identifiers)
 272       (when id
 273         (multiple-value-bind (sym docs)
 274             (if (consp id)
 275                 (values (car id) (cdr id))
 276                 (values id nil))
 277           (push `(def!constant ,sym
 278                    ,(+ start (* step index))
 279                    ,@docs)
 280                 results)))
 281       (incf index))
 282     `(progn
 283        ,@(nreverse results))))
 284
 285 ;;; generalization of DEFCONSTANT to values which are the same not
 286 ;;; under EQL but under e.g. EQUAL or EQUALP
 287 ;;;
 288 ;;; DEFCONSTANT-EQX is to be used instead of DEFCONSTANT for values
 289 ;;; which are appropriately compared using the function given by the
 290 ;;; EQX argument instead of EQL.
 291 ;;;
 292 ;;; Note: Be careful when using this macro, since it's easy to
 293 ;;; unintentionally pessimize your code. A good time to use this macro
 294 ;;; is when the values defined will be fed into optimization
 295 ;;; transforms and never actually appear in the generated code; this
 296 ;;; is especially common when defining BYTE expressions. Unintentional
 297 ;;; pessimization can result when the values defined by this macro are
 298 ;;; actually used in generated code: because of the way that the
 299 ;;; dump/load system works, you'll typically get one copy of consed
 300 ;;; structure for each object file which contains code referring to
 301 ;;; the value, plus perhaps one more copy bound to the SYMBOL-VALUE of
 302 ;;; the constant. If you don't want that to happen, you should
 303 ;;; probably use DEFPARAMETER instead; or if you truly desperately
 304 ;;; need to avoid runtime indirection through a symbol, you might be
 305 ;;; able to do something with LOAD-TIME-VALUE or MAKE-LOAD-FORM.
 306 (defmacro defconstant-eqx (symbol expr eqx &optional doc)
 307   `(def!constant ,symbol
 308      (%defconstant-eqx-value ',symbol ,expr ,eqx)
 309      ,@(when doc (list doc))))
 310 (defun %defconstant-eqx-value (symbol expr eqx)
 311   (declare (type function eqx))
 312   (flet ((bummer (explanation)
 313            (error "~@<bad DEFCONSTANT-EQX ~S ~2I~_~S: ~2I~_~A ~S~:>"
 314                   symbol
 315                   expr
 316                   explanation
 317                   (symbol-value symbol))))
 318     (cond ((not (boundp symbol))
 319            expr)
 320           ((not (constantp symbol))
 321            (bummer "already bound as a non-constant"))
 322           ((not (funcall eqx (symbol-value symbol) expr))
 323            (bummer "already bound as a different constant value"))
 324           (t
 325            (symbol-value symbol)))))
 326 \f
 327 ;;; a helper function for various macros which expect clauses of a
 328 ;;; given length, etc.
 329 ;;;
 330 ;;; Return true if X is a proper list whose length is between MIN and
 331 ;;; MAX (inclusive).
 332 (defun proper-list-of-length-p (x min &optional (max min))
 333   ;; FIXME: This implementation will hang on circular list
 334   ;; structure. Since this is an error-checking utility, i.e. its
 335   ;; job is to deal with screwed-up input, it'd be good style to fix
 336   ;; it so that it can deal with circular list structure.
 337   (cond ((minusp max) nil)
 338         ((null x) (zerop min))
 339         ((consp x)
 340          (and (plusp max)
 341               (proper-list-of-length-p (cdr x)
 342                                        (if (plusp (1- min))
 343                                            (1- min)
 344                                            0)
 345                                        (1- max))))
 346         (t nil)))
 347
 348 (defun proper-list-p (x)
 349   (unless (consp x)
 350     (return-from proper-list-p (null x)))
 351   (let ((rabbit (cdr x))
 352         (turtle x))
 353     (flet ((pop-rabbit ()
 354              (when (eql rabbit turtle) ; circular
 355                (return-from proper-list-p nil))
 356              (when (atom rabbit)
 357                (return-from proper-list-p (null rabbit)))
 358              (pop rabbit)))
 359       (loop (pop-rabbit)
 360             (pop-rabbit)
 361             (pop turtle)))))
 362
 363 ;;; Helpers for defining error-signalling NOP's for "not supported
 364 ;;; here" operations.
 365 (defmacro define-unsupported-fun (name &optional
 366                                   (doc "Unsupported on this platform.")
 367                                   (control
 368                                    "~S is unsupported on this platform ~
 369                                     (OS, CPU, whatever)."
 370                                    controlp)
 371                                   arguments)
 372   `(defun ,name (&rest args)
 373     ,doc
 374     (declare (ignore args))
 375     (error 'unsupported-operator
 376      :format-control ,control
 377      :format-arguments (if ,controlp ',arguments (list ',name)))))